Remove generation of ms/version32.rc from Configure, use util/mkrc.pl
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3
4 ##  Configure -- OpenSSL source tree configuration script
5
6 require 5.10.0;
7 use strict;
8 use File::Basename;
9 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
10 use File::Path qw/mkpath/;
11
12 # see INSTALL for instructions.
13
14 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
15
16 # Options:
17 #
18 # --config      add the given configuration file, which will be read after
19 #               any "Configurations*" files that are found in the same
20 #               directory as this script.
21 # --prefix      prefix for the OpenSSL installation, which includes the
22 #               directories bin, lib, include, share/man, share/doc/openssl
23 #               This becomes the value of INSTALLTOP in Makefile
24 #               (Default: /usr/local)
25 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
26 #               If it's a relative directory, it will be added on the directory
27 #               given with --prefix.
28 #               This becomes the value of OPENSSLDIR in Makefile and in C.
29 #               (Default: PREFIX/ssl)
30 #
31 # --cross-compile-prefix Add specified prefix to binutils components.
32 #
33 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
34 #               interfaces deprecated as of the specified OpenSSL version.
35 #
36 # no-hw-xxx     do not compile support for specific crypto hardware.
37 #               Generic OpenSSL-style methods relating to this support
38 #               are always compiled but return NULL if the hardware
39 #               support isn't compiled.
40 # no-hw         do not compile support for any crypto hardware.
41 # [no-]threads  [don't] try to create a library that is suitable for
42 #               multithreaded applications (default is "threads" if we
43 #               know how to do it)
44 # [no-]shared   [don't] try to create shared libraries when supported.
45 # [no-]pic      [don't] try to build position independent code when supported.
46 #               If disabled, it also disables shared and dynamic-engine.
47 # no-asm        do not use assembler
48 # no-dso        do not compile in any native shared-library methods. This
49 #               will ensure that all methods just return NULL.
50 # no-egd        do not compile support for the entropy-gathering daemon APIs
51 # [no-]zlib     [don't] compile support for zlib compression.
52 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
53 #               library and will be loaded in run-time by the OpenSSL library.
54 # sctp          include SCTP support
55 # 386           generate 80386 code
56 # enable-weak-ssl-ciphers
57 #               Enable weak ciphers that are disabled by default. This currently
58 #               only includes RC4 based ciphers.
59 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
60 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
61 # -<xxx> +<xxx> compiler options are passed through
62 #
63 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
64 #               provided to stack calls. Generates unique stack functions for
65 #               each possible stack type.
66 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
67 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
68 # Following are set automatically by this script
69 #
70 # MD5_ASM       use some extra md5 assember,
71 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
72 # RMD160_ASM    use some extra ripemd160 assember,
73 # SHA256_ASM    sha256_block is implemented in assembler
74 # SHA512_ASM    sha512_block is implemented in assembler
75 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
76
77 # Minimum warning options... any contributions to OpenSSL should at least get
78 # past these.
79
80 my $gcc_devteam_warn = "-DPEDANTIC -DREF_DEBUG -DDEBUG_UNUSED -DBIO_DEBUG"
81         . " -pedantic"
82         . " -Wall"
83         . " -Wno-long-long"
84         . " -Wsign-compare"
85         . " -Wmissing-prototypes"
86         . " -Wshadow"
87         . " -Wformat"
88         . " -Wtype-limits"
89         . " -Werror"
90         ;
91
92 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
93 # TODO(openssl-team): fix problems and investigate if (at least) the
94 # following warnings can also be enabled:
95 #       -Wswitch-enum
96 #       -Wcast-align
97 #       -Wunreachable-code
98 #       -Wlanguage-extension-token -- no, we use asm()
99 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
100 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
101 my $clang_devteam_warn = ""
102         . " -Qunused-arguments"
103         . " -Wextra"
104         . " -Wno-unused-parameter"
105         . " -Wno-missing-field-initializers"
106         . " -Wno-language-extension-token"
107         . " -Wno-extended-offsetof"
108         . " -Wconditional-uninitialized"
109         . " -Wincompatible-pointer-types-discards-qualifiers"
110         . " -Wmissing-variable-declarations"
111         ;
112
113 # This adds backtrace information to the memory leak info.  Is only used
114 # when crypto-mdebug-backtrace is enabled.
115 my $memleak_devteam_backtrace = "-rdynamic";
116
117 my $strict_warnings = 0;
118
119 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
120 # which would cover all BSD flavors. -pthread applies to them all,
121 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
122 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
123 # which has to be accompanied by explicit -D_THREAD_SAFE and
124 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
125 # seems to be sufficient?
126 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
127
128 #
129 # API compability name to version number mapping.
130 #
131 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
132 my $apitable = {
133     "1.1.0" => "0x10100000L",
134     "1.0.0" => "0x10000000L",
135     "0.9.8" => "0x00908000L",
136 };
137
138 our %table = ();
139 our %config = ();
140 our %withargs = ();
141
142 # Forward declarations ###############################################
143
144 # read_config(filename)
145 #
146 # Reads a configuration file and populates %table with the contents
147 # (which the configuration file places in %targets).
148 sub read_config;
149
150 # resolve_config(target)
151 #
152 # Resolves all the late evalutations, inheritances and so on for the
153 # chosen target and any target it inherits from.
154 sub resolve_config;
155
156
157 # Information collection #############################################
158
159 # Unified build supports separate build dir
160 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
161 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
162 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
163
164 $config{sourcedir} = abs2rel($srcdir);
165 $config{builddir} = abs2rel($blddir);
166
167 # Collect version numbers
168 $config{version} = "unknown";
169 $config{version_num} = "unknown";
170 $config{shlib_version_number} = "unknown";
171 $config{shlib_version_history} = "unknown";
172
173 collect_information(
174     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
175     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
176     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
177     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
178     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
179     );
180 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
181
182 ($config{major}, $config{minor})
183     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
184 ($config{shlib_major}, $config{shlib_minor})
185     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
186 die "erroneous version information in opensslv.h: ",
187     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
188     if ($config{major} eq "" || $config{minor} eq ""
189         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
190
191 # Collect target configurations
192
193 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
194 foreach (sort glob($pattern) ) {
195     &read_config($_);
196 }
197
198
199 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
200
201 $config{prefix}="";
202 $config{openssldir}="";
203 $config{processor}="";
204 $config{libdir}="";
205 $config{cross_compile_prefix}="";
206 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
207 my $nofipscanistercheck=0;
208 $config{baseaddr}="0xFB00000";
209 my $auto_threads=1;    # enable threads automatically? true by default
210 my $default_ranlib;
211 $config{fips}=0;
212
213 # Top level directories to build
214 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
215 # crypto/ subdirectories to build
216 $config{sdirs} = [
217     "objects",
218     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2",
219     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
220     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
221     "buffer", "bio", "stack", "lhash", "rand", "err",
222     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
223     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
224     ];
225
226 # Known TLS and DTLS protocols
227 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
228 my @dtls = qw(dtls1 dtls1_2);
229
230 # Explicitelly known options that are possible to disable.  They can
231 # be regexps, and will be used like this: /^no-${option}$/
232 # For developers: keep it sorted alphabetically
233
234 my @disablables = (
235     "aes",
236     "afalgeng",
237     "asm",
238     "async",
239     "autoalginit",
240     "autoerrinit",
241     "bf",
242     "blake2",
243     "camellia",
244     "capieng",
245     "cast",
246     "chacha",
247     "cmac",
248     "cms",
249     "comp",
250     "crypto-mdebug",
251     "crypto-mdebug-backtrace",
252     "ct",
253     "deprecated",
254     "des",
255     "dgram",
256     "dh",
257     "dsa",
258     "dso",
259     "dtls",
260     "dynamic-engine",
261     "ec",
262     "ec2m",
263     "ecdh",
264     "ecdsa",
265     "ec_nistp_64_gcc_128",
266     "egd",
267     "engine",
268     "err",
269     "filenames",
270     "heartbeats",
271     "hmac",
272     "hw(-.+)?",
273     "idea",
274     "makedepend",
275     "md2",
276     "md4",
277     "md5",
278     "mdc2",
279     "md[-_]ghost94",
280     "multiblock",
281     "nextprotoneg",
282     "ocb",
283     "ocsp",
284     "pic",
285     "poly1305",
286     "posix-io",
287     "psk",
288     "rc2",
289     "rc4",
290     "rc5",
291     "rdrand",
292     "rfc3779",
293     "rijndael",                 # Old AES name
294     "ripemd",
295     "rmd160",
296     "rsa",
297     "scrypt",
298     "sct",
299     "sctp",
300     "seed",
301     "sha",
302     "shared",
303     "sock",
304     "srp",
305     "srtp",
306     "sse2",
307     "ssl",
308     "ssl-trace",
309     "static-engine",
310     "stdio",
311     "threads",
312     "tls",
313     "ts",
314     "ui",
315     "unit-test",
316     "whirlpool",
317     "weak-ssl-ciphers",
318     "zlib",
319     "zlib-dynamic",
320     );
321 foreach my $proto ((@tls, @dtls))
322         {
323         push(@disablables, $proto);
324         push(@disablables, "$proto-method");
325         }
326
327 my @deprecated_disablables = (
328     "ssl2",
329     );
330
331 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
332
333 our %disabled = ( # "what"         => "comment"
334                   "ec_nistp_64_gcc_128" => "default",
335                   "egd"                 => "default",
336                   "md2"                 => "default",
337                   "rc5"                 => "default",
338                   "sctp"                => "default",
339                   "shared"              => "default",
340                   "ssl-trace"           => "default",
341                   "ssl3"                => "default",
342                   "ssl3-method"         => "default",
343                   "unit-test"           => "default",
344                   "weak-ssl-ciphers"    => "default",
345                   "zlib"                => "default",
346                   "zlib-dynamic"        => "default",
347                   "crypto-mdebug"       => "default",
348                   "heartbeats"          => "default",
349                 );
350
351 # Note: => pair form used for aesthetics, not to truly make a hash table
352 my @disable_cascades = (
353     # "what"            => [ "cascade", ... ]
354     sub { $config{processor} eq "386" }
355                         => [ "sse2" ],
356     "ssl"               => [ "ssl3" ],
357     "ssl3-method"       => [ "ssl3" ],
358     "zlib"              => [ "zlib-dynamic" ],
359     "rijndael"          => [ "aes" ],
360     "des"               => [ "mdc2" ],
361     "ec"                => [ "ecdsa", "ecdh" ],
362
363     "dgram"             => [ "dtls" ],
364     "dtls"              => [ @dtls ],
365
366     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
367     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
368     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
369
370     # Additionally, SSL 3.0 requires either RSA or DSA+DH
371     sub { $disabled{rsa}
372           && ($disabled{dsa} || $disabled{dh}); }
373                         => [ "ssl" ],
374
375     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
376     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
377     # (XXX: We don't support PSK-only builds).
378     sub { $disabled{rsa}
379           && ($disabled{dsa} || $disabled{dh})
380           && ($disabled{ecdsa} || $disabled{ecdh}); }
381                         => [ "tls1", "tls1_1", "tls1_2",
382                              "dtls1", "dtls1_2" ],
383
384     "tls"               => [ @tls ],
385
386     # SRP and HEARTBEATS require TLSEXT
387     "tlsext"            => [ "srp", "heartbeats" ],
388
389     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
390
391     # Without DSO, we can't load dynamic engines, so don't build them dynamic
392     "dso"               => [ "dynamic-engine" ],
393
394     # Without position independent code, there can be no shared libraries or DSOs
395     "pic"               => [ "shared" ],
396     "shared"            => [ "dynamic-engine" ],
397     "engine"            => [ "afalgeng" ],
398     );
399
400 # Avoid protocol support holes.  Also disable all versions below N, if version
401 # N is disabled while N+1 is enabled.
402 #
403 my @list = (reverse @tls);
404 while ((my $first, my $second) = (shift @list, shift @list)) {
405     last unless @list;
406     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
407                               => [ @list ] );
408     unshift @list, $second;
409 }
410 my @list = (reverse @dtls);
411 while ((my $first, my $second) = (shift @list, shift @list)) {
412     last unless @list;
413     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
414                               => [ @list ] );
415     unshift @list, $second;
416 }
417
418 # Explicit "no-..." options will be collected in %disabled along with the defaults.
419 # To remove something from %disabled, use "enable-foo".
420 # For symmetry, "disable-foo" is a synonym for "no-foo".
421
422 my @generated_headers = (
423     "include/openssl/opensslconf.h",
424     "crypto/include/internal/bn_conf.h",
425     "crypto/include/internal/dso_conf.h"
426     );
427
428 my @generated_by_make_headers = (
429     "crypto/buildinf.h"
430     );
431
432
433 my $no_sse2=0;
434
435 &usage if ($#ARGV < 0);
436
437 my $user_cflags="";
438 my @user_defines=();
439 $config{openssl_api_defines}=[];
440 $config{openssl_algorithm_defines}=[];
441 $config{openssl_thread_defines}=[];
442 $config{openssl_sys_defines}=[];
443 $config{openssl_other_defines}=[];
444 my $libs="";
445 my $target="";
446 $config{options}="";
447 $config{build_type} = "release";
448
449 my $classic = 0;
450
451 my @argvcopy=@ARGV;
452
453 if (grep /^reconf(igure)?$/, @argvcopy) {
454     if (-f "./configdata.pm") {
455         my $file = "./configdata.pm";
456         unless (my $return = do $file) {
457             die "couldn't parse $file: $@" if $@;
458             die "couldn't do $file: $!"    unless defined $return;
459             die "couldn't run $file"       unless $return;
460         }
461
462         @argvcopy = defined($configdata::config{perlargv}) ?
463             @{$configdata::config{perlargv}} : ();
464         die "Incorrect data to reconfigure, please do a normal configuration\n"
465             if (grep(/^reconf/,@argvcopy));
466         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
467             if defined($configdata::config{cross_compile_prefix});
468         $ENV{CROSS_COMPILE} = $configdata::config{cc}
469             if defined($configdata::config{cc});
470
471         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
472         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
473             if $ENV{CROSS_COMPILE};
474         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
475     } elsif (open IN, "<Makefile") {
476         #
477         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
478         # centered information gathering the reading configdata.pm
479         #
480         while (<IN>) {
481             s|\R$||;
482             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
483                 # Older form, we split the string and hope for the best
484                 @argvcopy = split /\s+/, $_;
485                 die "Incorrect data to reconfigure, please do a normal configuration\n"
486                     if (grep(/^reconf/,@argvcopy));
487             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
488                 $ENV{CROSS_COMPILE}=$1;
489             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
490                 $ENV{CC}=$1;
491             }
492         }
493         #
494         # END OF TEMPORARY SECTION
495         #
496     } else {
497         die "Insufficient data to reconfigure, please do a normal configuration\n";
498     }
499 }
500
501 $config{perlargv} = [ @argvcopy ];
502
503 my %unsupported_options = ();
504 my %deprecated_options = ();
505 foreach (@argvcopy)
506         {
507         # VMS is a case insensitive environment, and depending on settings
508         # out of our control, we may receive options uppercased.  Let's
509         # downcase at least the part before any equal sign.
510         if ($^O eq "VMS")
511                 {
512                 s/^([^=]*)/lc($1)/e;
513                 }
514         s /^-no-/no-/; # some people just can't read the instructions
515
516         # rewrite some options in "enable-..." form
517         s /^-?-?shared$/enable-shared/;
518         s /^sctp$/enable-sctp/;
519         s /^threads$/enable-threads/;
520         s /^zlib$/enable-zlib/;
521         s /^zlib-dynamic$/enable-zlib-dynamic/;
522
523         if (/^(no|disable|enable)-(.+)$/)
524                 {
525                 my $word = $2;
526                 if (grep { $word =~ /^${_}$/ } @deprecated_disablables)
527                         {
528                         $deprecated_options{$_} = 1;
529                         next;
530                         }
531                 elsif (!grep { $word =~ /^${_}$/ } @disablables)
532                         {
533                         $unsupported_options{$_} = 1;
534                         next;
535                         }
536                 }
537         if (/^no-(.+)$/ || /^disable-(.+)$/)
538                 {
539                 foreach my $proto ((@tls, @dtls))
540                         {
541                         if ($1 eq "$proto-method")
542                                 {
543                                 $disabled{"$proto"} = "option($proto-method)";
544                                 last;
545                                 }
546                         }
547                 if ($1 eq "dtls")
548                         {
549                         foreach my $proto (@dtls)
550                                 {
551                                 $disabled{$proto} = "option(dtls)";
552                                 }
553                         }
554                 elsif ($1 eq "ssl")
555                         {
556                         # Last one of its kind
557                         $disabled{"ssl3"} = "option(ssl)";
558                         }
559                 elsif ($1 eq "tls")
560                         {
561                         # XXX: Tests will fail if all SSL/TLS
562                         # protocols are disabled.
563                         foreach my $proto (@tls)
564                                 {
565                                 $disabled{$proto} = "option(tls)";
566                                 }
567                         }
568                 elsif ($1 eq "static-engine")
569                         {
570                         delete $disabled{"dynamic-engine"};
571                         }
572                 elsif ($1 eq "dynamic-engine")
573                         {
574                         $disabled{"dynamic-engine"} = "option";
575                         }
576                 else
577                         {
578                         $disabled{$1} = "option";
579                         }
580                 # No longer an automatic choice
581                 $auto_threads = 0 if ($1 eq "threads");
582                 }
583         elsif (/^enable-(.+)$/)
584                 {
585                 if ($1 eq "static-engine")
586                         {
587                         $disabled{"dynamic-engine"} = "option";
588                         }
589                 elsif ($1 eq "dynamic-engine")
590                         {
591                         delete $disabled{"dynamic-engine"};
592                         }
593                 elsif ($1 eq "zlib-dynamic")
594                         {
595                         delete $disabled{"zlib"};
596                         }
597                 my $algo = $1;
598                 delete $disabled{$algo};
599
600                 # No longer an automatic choice
601                 $auto_threads = 0 if ($1 eq "threads");
602                 }
603         elsif (/^--strict-warnings$/)
604                 {
605                 $strict_warnings = 1;
606                 }
607         elsif (/^--debug$/)
608                 {
609                 $config{build_type} = "debug";
610                 }
611         elsif (/^--release$/)
612                 {
613                 $config{build_type} = "release";
614                 }
615         elsif (/^386$/)
616                 { $config{processor}=386; }
617         elsif (/^fips$/)
618                 {
619                 $config{fips}=1;
620                 }
621         elsif (/^rsaref$/)
622                 {
623                 # No RSAref support any more since it's not needed.
624                 # The check for the option is there so scripts aren't
625                 # broken
626                 }
627         elsif (/^nofipscanistercheck$/)
628                 {
629                 $config{fips} = 1;
630                 $nofipscanistercheck = 1;
631                 }
632         elsif (/^[-+]/)
633                 {
634                 if (/^--classic$/)
635                         {
636                         $classic=1;
637                         }
638                 elsif (/^--prefix=(.*)$/)
639                         {
640                         $config{prefix}=$1;
641                         die "Directory given with --prefix MUST be absolute\n"
642                                 unless file_name_is_absolute($config{prefix});
643                         }
644                 elsif (/^--api=(.*)$/)
645                         {
646                         $config{api}=$1;
647                         }
648                 elsif (/^--libdir=(.*)$/)
649                         {
650                         $config{libdir}=$1;
651                         }
652                 elsif (/^--openssldir=(.*)$/)
653                         {
654                         $config{openssldir}=$1;
655                         }
656                 elsif (/^--with-zlib-lib=(.*)$/)
657                         {
658                         $withargs{zlib_lib}=$1;
659                         }
660                 elsif (/^--with-zlib-include=(.*)$/)
661                         {
662                         $withargs{zlib_include}="-I$1";
663                         }
664                 elsif (/^--with-fipslibdir=(.*)$/)
665                         {
666                         $config{fipslibdir}="$1/";
667                         }
668                 elsif (/^--with-baseaddr=(.*)$/)
669                         {
670                         $config{baseaddr}="$1";
671                         }
672                 elsif (/^--cross-compile-prefix=(.*)$/)
673                         {
674                         $config{cross_compile_prefix}=$1;
675                         }
676                 elsif (/^--config=(.*)$/)
677                         {
678                         read_config $1;
679                         }
680                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
681                         {
682                         $libs.=$_." ";
683                         }
684                 elsif (/^-D(.*)$/)
685                         {
686                         push @user_defines, $1;
687                         }
688                 else    # common if (/^[-+]/), just pass down...
689                         {
690                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
691                         $user_cflags.=" ".$_;
692                         }
693                 }
694         else
695                 {
696                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
697                 $target=$_;
698                 }
699         unless ($_ eq $target || /^no-/ || /^disable-/)
700                 {
701                 # "no-..." follows later after implied disactivations
702                 # have been derived.  (Don't take this too seroiusly,
703                 # we really only write OPTIONS to the Makefile out of
704                 # nostalgia.)
705
706                 if ($config{options} eq "")
707                         { $config{options} = $_; }
708                 else
709                         { $config{options} .= " ".$_; }
710                 }
711
712         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
713                 die "***** Unsupported api compatibility level: $config{api}\n",
714         }
715
716         if (keys %deprecated_options)
717                 {
718                 warn "***** Deprecated options: ",
719                         join(", ", keys %deprecated_options), "\n";
720                 }
721         if (keys %unsupported_options)
722                 {
723                 die "***** Unsupported options: ",
724                         join(", ", keys %unsupported_options), "\n";
725                 }
726         }
727
728 if ($config{fips})
729         {
730         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
731         }
732 else
733         {
734         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
735         }
736
737 my @tocheckfor = (keys %disabled);
738 while (@tocheckfor) {
739     my %new_tocheckfor = ();
740     my @cascade_copy = (@disable_cascades);
741     while (@cascade_copy) {
742         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
743         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
744             map {
745                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
746             } grep { !defined($disabled{$_}) } @$descendents;
747         }
748     }
749     @tocheckfor = (keys %new_tocheckfor);
750 }
751
752 if ($target eq "TABLE") {
753     foreach (sort keys %table) {
754         print_table_entry($_, "TABLE");
755     }
756     exit 0;
757 }
758
759 if ($target eq "LIST") {
760     foreach (sort keys %table) {
761         print $_,"\n" unless $table{$_}->{template};
762     }
763     exit 0;
764 }
765
766 if ($target eq "HASH") {
767     print "%table = (\n";
768     foreach (sort keys %table) {
769         print_table_entry($_, "HASH");
770     }
771     exit 0;
772 }
773
774 # Backward compatibility?
775 if ($target =~ m/^CygWin32(-.*)$/) {
776     $target = "Cygwin".$1;
777 }
778
779 foreach (sort (keys %disabled))
780         {
781         $config{options} .= " no-$_";
782
783         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
784
785         if (/^dso$/)
786                 { }
787         elsif (/^threads$/)
788                 { }
789         elsif (/^shared$/)
790                 { }
791         elsif (/^pic$/)
792                 { }
793         elsif (/^zlib$/)
794                 { }
795         elsif (/^dynamic-engine$/)
796                 { }
797         elsif (/^makedepend$/)
798                 { }
799         elsif (/^zlib-dynamic$/)
800                 { }
801         elsif (/^sse2$/)
802                 { $no_sse2 = 1; }
803         elsif (/^engine$/)
804                 {
805                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
806                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
807                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
808                 }
809         else
810                 {
811                 my ($ALGO, $algo);
812                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
813
814                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/
815                                 || /^autoalginit/ || /^autoerrinit/)
816                         {
817                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
818                         print " OPENSSL_NO_$ALGO";
819
820                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
821                         }
822                 else
823                         {
824                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
825
826                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
827                         print " OPENSSL_NO_$ALGO";
828
829                         # fix-up crypto/directory name(s)
830                         $algo="whrlpool" if $algo eq "whirlpool";
831                         $algo="ripemd" if $algo eq "rmd160";
832                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
833
834                         print " (skip dir)";
835                         }
836                 }
837
838         print "\n";
839         }
840
841 print "Configuring for $target\n";
842
843 # Support for legacy targets having a name starting with 'debug-'
844 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
845 if ($d) {
846     $config{build_type} = "debug";
847
848     # If we do not find debug-foo in the table, the target is set to foo.
849     if (!$table{$target}) {
850         $target = $t;
851     }
852 }
853 $config{target} = $target;
854 my %target = resolve_config($target);
855
856 &usage if (!%target || $target{template});
857
858 %target = ( %{$table{DEFAULTS}}, %target );
859
860 $target{exe_extension}="";
861 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
862                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
863 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
864
865 ($target{shared_extension_simple}=$target{shared_extension})
866     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
867 $target{dso_extension}=$target{shared_extension_simple};
868 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
869     if ($config{target} =~ /^(?:Cygwin|mingw)/);
870
871
872 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
873     if $config{cross_compile_prefix} eq "";
874
875 # Allow overriding the names of some tools.  USE WITH CARE
876 $config{perl} =    $ENV{'PERL'}    || which("perl5") || which("perl") || "perl";
877 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
878 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  || which("ranlib") || "true";
879 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
880 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
881
882 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
883 # or release_ attributes.
884 # Do it in such a way that no spurious space is appended (hence the grep).
885 $config{defines} = [];
886 $config{cflags} = "";
887 $config{ex_libs} = "";
888 $config{shared_ldflag} = "";
889
890 # Make sure build_scheme is consistent.
891 $target{build_scheme} = [ $target{build_scheme} ]
892     if ref($target{build_scheme}) ne "ARRAY";
893
894 ###### TO BE REMOVED WHEN CLASSIC BUILD IS REMOVED
895 ######
896 ###### If the user has chosen --classic, we give it to them.
897 ###### If they try that with an out-of-source config, we complain.
898 if ($target{build_scheme}->[0] eq "unified" && $classic) {
899     die "Can't perform a classic build out of source tree\n"
900         if $srcdir ne $blddir;
901
902     $target{build_scheme} = { unix    => [ "unixmake" ],
903                               windows => undef,
904                               VMS     => undef } -> {$target{build_scheme}->[1]};
905
906     die "Classic mode unavailable on this platform\n"
907         unless defined($target{build_scheme});
908 }
909
910 my ($builder, $builder_platform, @builder_opts) =
911     @{$target{build_scheme}};
912
913 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
914         {
915         $config{cflags} .= " -mno-cygwin";
916         $config{shared_ldflag} .= " -mno-cygwin";
917         }
918
919 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
920         # minimally required architecture flags for assembly modules
921         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
922         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
923 }
924
925 my $no_shared_warn=0;
926 my $no_user_cflags=0;
927 my $no_user_defines=0;
928
929 # The DSO code currently always implements all functions so that no
930 # applications will have to worry about that from a compilation point
931 # of view. However, the "method"s may return zero unless that platform
932 # has support compiled in for them. Currently each method is enabled
933 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
934 # string entry into using the following logic;
935 if (!$disabled{dso} && $target{dso_scheme} ne "")
936         {
937         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
938         if ($target{dso_scheme} eq "DLFCN")
939                 {
940                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
941                 }
942         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
943                 {
944                 unshift @{$config{defines}}, "DSO_DLFCN";
945                 }
946         else
947                 {
948                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
949                 }
950         }
951
952 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
953
954 if ($disabled{asm})
955         {
956         if ($config{fips})
957                 {
958                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
959                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
960                 }
961         }
962
963 # If threads aren't disabled, check how possible they are
964 unless ($disabled{threads}) {
965     if ($auto_threads) {
966         # Enabled by default, disable it forcibly if unavailable
967         if ($target{thread_scheme} eq "(unknown)") {
968             $disabled{threads} = "unavailable";
969         }
970     } else {
971         # The user chose to enable threads explicitely, let's see
972         # if there's a chance that's possible
973         if ($target{thread_scheme} eq "(unknown)") {
974             # If the user asked for "threads" and we don't have internal
975             # knowledge how to do it, [s]he is expected to provide any
976             # system-dependent compiler options that are necessary.  We
977             # can't truly check that the given options are correct, but
978             # we expect the user to know what [s]He is doing.
979             if ($no_user_cflags && $no_user_defines) {
980                 die "You asked for multi-threading support, but didn't\n"
981                     ,"provide any system-specific compiler options\n";
982             }
983         }
984     }
985 }
986
987 # If threads still aren't disabled, add a C macro to ensure the source
988 # code knows about it.  Any other flag is taken care of by the configs.
989 unless($disabled{threads}) {
990     foreach (("defines", "openssl_thread_defines")) {
991         push @{$config{$_}}, "OPENSSL_THREADS";
992     }
993 }
994
995 # With "deprecated" disable all deprecated features.
996 if (defined($disabled{"deprecated"})) {
997         $config{api} = $maxapi;
998 }
999
1000 if ($target{shared_target} eq "")
1001         {
1002         $no_shared_warn = 1
1003             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1004                 && !$config{fips});
1005         $disabled{shared} = "no-shared-target";
1006         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1007             "no-shared-target";
1008         }
1009
1010 if ($disabled{"dynamic-engine"}) {
1011         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1012         $config{dynamic_engines} = 0;
1013 } else {
1014         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1015         $config{dynamic_engines} = 1;
1016 }
1017
1018 #
1019 # Platform fix-ups
1020 #
1021
1022 # This saves the build files from having to check
1023 if ($disabled{pic})
1024         {
1025         $target{shared_cflag} = $target{shared_ldflag} =
1026                 $target{shared_rcflag} = "";
1027         }
1028 else
1029         {
1030         push @{$config{defines}}, "OPENSSL_PIC";
1031         }
1032
1033 if ($target{sys_id} ne "")
1034         {
1035         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1036         }
1037
1038 unless ($disabled{asm}) {
1039     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1040     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1041
1042     # bn-586 is the only one implementing bn_*_part_words
1043     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1044     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1045
1046     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1047     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1048     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1049
1050     if ($config{fips}) {
1051         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1052     }
1053
1054     if ($target{sha1_asm_src}) {
1055         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1056         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1057         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1058     }
1059     if ($target{md5_asm_src}) {
1060         push @{$config{defines}}, "MD5_ASM";
1061     }
1062     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1063     if ($target{rmd160_asm_src}) {
1064         push @{$config{defines}}, "RMD160_ASM";
1065     }
1066     if ($target{aes_asm_src}) {
1067         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1068         # aes-ctr.fake is not a real file, only indication that assembler
1069         # module implements AES_ctr32_encrypt...
1070         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1071         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1072         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1073         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1074         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1075         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1076     }
1077     if ($target{wp_asm_src} =~ /mmx/) {
1078         if ($config{processor} eq "386") {
1079             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1080         } elsif (!$disabled{"whirlpool"}) {
1081             push @{$config{defines}}, "WHIRLPOOL_ASM";
1082         }
1083     }
1084     if ($target{modes_asm_src} =~ /ghash-/) {
1085         push @{$config{defines}}, "GHASH_ASM";
1086     }
1087     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1088         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1089     }
1090     if ($target{poly1305_asm_src} ne "") {
1091         push @{$config{defines}}, "POLY1305_ASM";
1092     }
1093 }
1094
1095 my $ecc = $target{cc};
1096 if ($^O ne "VMS" && !$disabled{makedepend}) {
1097     # Is the compiler gcc or clang?  $ecc is used below to see if
1098     # error-checking can be turned on.
1099     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1100     open(PIPE, "$ccpcc --version 2>&1 |");
1101     my $lines = 2;
1102     while ( <PIPE> ) {
1103         # Find the version number and save the major.
1104         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1105         my $compiler_major = $1;
1106         # We know that GNU C version 3 and up as well as all clang
1107         # versions support dependency generation
1108         $config{makedepprog} = $ccpcc
1109             if (/clang/ || (/gcc/ && $compiler_major > 3));
1110         $ecc = "clang" if /clang/;
1111         $ecc = "gcc" if /gcc/;
1112         last if ($config{makedepprog} || !$lines--);
1113     }
1114     close(PIPE);
1115
1116     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1117     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1118 }
1119
1120
1121
1122 # Deal with bn_ops ###################################################
1123
1124 $config{bn_ll}                  =0;
1125 $config{export_var_as_fn}       =0;
1126 my $def_int="unsigned int";
1127 $config{rc4_int}                =$def_int;
1128 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1129
1130 my $count = 0;
1131 foreach (sort split(/\s+/,$target{bn_ops})) {
1132     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1133     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1134     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1135     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1136     ($config{b64l},$config{b64},$config{b32})
1137         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1138     ($config{b64l},$config{b64},$config{b32})
1139         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1140     ($config{b64l},$config{b64},$config{b32})
1141         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1142 }
1143 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1144     if $count > 1;
1145
1146
1147 # Hack cflags for better warnings (dev option) #######################
1148
1149 # "Stringify" the C flags string.  This permits it to be made part of a string
1150 # and works as well on command lines.
1151 $config{cflags} =~ s/([\\\"])/\\$1/g;
1152
1153 if (defined($config{api})) {
1154     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1155     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1156     push @{$config{defines}}, $apiflag;
1157 }
1158
1159 if ($strict_warnings)
1160         {
1161         my $wopt;
1162         die "ERROR --strict-warnings requires gcc or clang"
1163             unless $ecc eq 'gcc' || $ecc eq 'clang';
1164         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1165                 {
1166                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1167                 }
1168         if ($ecc eq "clang")
1169                 {
1170                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1171                         {
1172                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1173                         }
1174                 }
1175         }
1176
1177 unless ($disabled{"crypto-mdebug-backtrace"})
1178         {
1179         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1180                 {
1181                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1182                 }
1183         if ($target =~ /^BSD-/)
1184                 {
1185                 $config{ex_libs} .= " -lexecinfo";
1186                 }
1187         }
1188
1189 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1190 else                    { $no_user_cflags=1;  }
1191 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1192 else               { $no_user_defines=1;    }
1193
1194 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1195
1196 unless ($disabled{afalgeng}) {
1197     $config{afalgeng}="";
1198     if ($target =~ m/^linux/) {
1199         my $minver = 4*10000 + 1*100 + 0;
1200         if ($config{cross_compile_prefix} eq "") {
1201             my $verstr = `uname -r`;
1202             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1203             ($mi2) = $mi2 =~ /(\d+)/;
1204             my $ver = $ma*10000 + $mi1*100 + $mi2;
1205             if ($ver < $minver) {
1206                 $disabled{afalgeng} = "too-old-kernel";
1207             } else {
1208                 push @{$config{engdirs}}, "afalg";
1209             }
1210         } else {
1211             $disabled{afalgeng} = "cross-compiling";
1212         }
1213     } else {
1214         $disabled{afalgeng}  = "not-linux";
1215     }
1216 }
1217
1218 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1219
1220 # If we use the unified build, collect information from build.info files
1221 my %unified_info = ();
1222
1223 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1224 if ($builder eq "unified") {
1225     # Store the name of the template file we will build the build file from
1226     # in %config.  This may be useful for the build file itself.
1227     my $build_file_template =
1228         catfile($srcdir, "Configurations",
1229                 $builder_platform."-".$target{build_file}.".tmpl");
1230     $build_file_template =
1231         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1232         if (! -f $build_file_template);
1233     $config{build_file_template} = $build_file_template;
1234
1235     use lib catdir(dirname(__FILE__),"util");
1236     use with_fallback qw(Text::Template);
1237
1238     sub cleandir {
1239         my $base = shift;
1240         my $dir = shift;
1241         my $relativeto = shift || ".";
1242
1243         $dir = catdir($base,$dir) unless isabsolute($dir);
1244
1245         # Make sure the directories we're building in exists
1246         mkpath($dir);
1247
1248         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1249         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1250         return $res;
1251     }
1252
1253     sub cleanfile {
1254         my $base = shift;
1255         my $file = shift;
1256         my $relativeto = shift || ".";
1257
1258         $file = catfile($base,$file) unless isabsolute($file);
1259
1260         my $d = dirname($file);
1261         my $f = basename($file);
1262
1263         # Make sure the directories we're building in exists
1264         mkpath($d);
1265
1266         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1267         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1268         return $res;
1269     }
1270
1271     my @build_infos = ( [ ".", "build.info" ] );
1272     foreach (@{$config{dirs}}) {
1273         push @build_infos, [ $_, "build.info" ]
1274             if (-f catfile($srcdir, $_, "build.info"));
1275     }
1276     foreach (@{$config{sdirs}}) {
1277         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1278             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1279     }
1280     foreach (@{$config{engdirs}}) {
1281         push @build_infos, [ catdir("engines", $_), "build.info" ]
1282             if (-f catfile($srcdir, "engines", $_, "build.info"));
1283     }
1284
1285     $config{build_infos} = [ ];
1286
1287     foreach (@build_infos) {
1288         my $sourced = catdir($srcdir, $_->[0]);
1289         my $buildd = catdir($blddir, $_->[0]);
1290
1291         mkpath($buildd);
1292
1293         my $f = $_->[1];
1294         # The basic things we're trying to build
1295         my @programs = ();
1296         my @libraries = ();
1297         my @engines = ();
1298         my @scripts = ();
1299         my @extra = ();
1300         my @overrides = ();
1301         my @intermediates = ();
1302         my @rawlines = ();
1303
1304         my %ordinals = ();
1305         my %sources = ();
1306         my %includes = ();
1307         my %depends = ();
1308         my %renames = ();
1309         my %sharednames = ();
1310         my %generate = ();
1311
1312         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1313         my $template = Text::Template->new(TYPE => 'FILE',
1314                                            SOURCE => catfile($sourced, $f));
1315         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1316         my @text =
1317             split /^/m,
1318             $template->fill_in(HASH => { config => \%config,
1319                                          target => \%target,
1320                                          disabled => \%disabled,
1321                                          builddir => abs2rel($buildd, $blddir),
1322                                          sourcedir => abs2rel($sourced, $blddir),
1323                                          buildtop => abs2rel($blddir, $blddir),
1324                                          sourcetop => abs2rel($srcdir, $blddir) },
1325                                DELIMITERS => [ "{-", "-}" ]);
1326
1327         # The top item of this stack has the following values
1328         # -2 positive already run and we found ELSE (following ELSIF should fail)
1329         # -1 positive already run (skip until ENDIF)
1330         # 0 negatives so far (if we're at a condition, check it)
1331         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1332         # 2 positive ELSE (following ELSIF should fail)
1333         my @skip = ();
1334         collect_information(
1335             collect_from_array([ @text ],
1336                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1337                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1338             # Info we're looking for
1339             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1340             => sub {
1341                 if (! @skip || $skip[$#skip] > 0) {
1342                     push @skip, !! $1;
1343                 } else {
1344                     push @skip, -1;
1345                 }
1346             },
1347             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1348             => sub { die "ELSIF out of scope" if ! @skip;
1349                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1350                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1351                      $skip[$#skip] = !! $1
1352                          if $skip[$#skip] == 0; },
1353             qr/^\s*ELSE\s*$/
1354             => sub { die "ELSE out of scope" if ! @skip;
1355                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1356                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1357             qr/^\s*ENDIF\s*$/
1358             => sub { die "ENDIF out of scope" if ! @skip;
1359                      pop @skip; },
1360             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1361             => sub { push @programs, split(/\s+/, $1)
1362                          if !@skip || $skip[$#skip] > 0 },
1363             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1364             => sub { push @libraries, split(/\s+/, $1)
1365                          if !@skip || $skip[$#skip] > 0 },
1366             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1367             => sub { push @engines, split(/\s+/, $1)
1368                          if !@skip || $skip[$#skip] > 0 },
1369             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1370             => sub { push @scripts, split(/\s+/, $1)
1371                          if !@skip || $skip[$#skip] > 0 },
1372             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1373             => sub { push @extra, split(/\s+/, $1)
1374                          if !@skip || $skip[$#skip] > 0 },
1375             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1376             => sub { push @overrides, split(/\s+/, $1)
1377                          if !@skip || $skip[$#skip] > 0 },
1378
1379             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1380             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1381                          if !@skip || $skip[$#skip] > 0 },
1382             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1383             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1384                          if !@skip || $skip[$#skip] > 0 },
1385             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1386             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1387                          if !@skip || $skip[$#skip] > 0 },
1388             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1389             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1390                          if !@skip || $skip[$#skip] > 0 },
1391             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1392             => sub { push @{$generate{$1}}, $2
1393                          if !@skip || $skip[$#skip] > 0 },
1394             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1395             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1396                          if !@skip || $skip[$#skip] > 0 },
1397             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1398             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1399                          if !@skip || $skip[$#skip] > 0 },
1400             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1401             => sub {
1402                 my $lineiterator = shift;
1403                 my $target_kind = $1;
1404                 while (defined $lineiterator->()) {
1405                     s|\R$||;
1406                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1407                         die "ENDRAW doesn't match BEGINRAW"
1408                             if $1 ne $target_kind;
1409                         last;
1410                     }
1411                     next if @skip && $skip[$#skip] <= 0;
1412                     push @rawlines,  $_
1413                         if ($target_kind eq $target{build_file}
1414                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1415                 }
1416             },
1417             qr/^(?:#.*|\s*)$/ => sub { },
1418             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1419             "BEFORE" => sub {
1420                 if ($buildinfo_debug) {
1421                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1422                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1423                 }
1424             },
1425             "AFTER" => sub {
1426                 if ($buildinfo_debug) {
1427                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1428                 }
1429             },
1430             );
1431         die "runaway IF?" if (@skip);
1432
1433         foreach (keys %renames) {
1434             die "$_ renamed to more than one thing: "
1435                 ,join(" ", @{$renames{$_}}),"\n"
1436                 if scalar @{$renames{$_}} > 1;
1437             my $dest = cleanfile($buildd, $_, $blddir);
1438             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1439             die "$dest renamed to more than one thing: "
1440                 ,$unified_info{rename}->{$dest}, $to
1441                 unless !defined($unified_info{rename}->{$dest})
1442                 or $unified_info{rename}->{$dest} eq $to;
1443             $unified_info{rename}->{$dest} = $to;
1444         }
1445
1446         foreach (@programs) {
1447             my $program = cleanfile($buildd, $_, $blddir);
1448             if ($unified_info{rename}->{$program}) {
1449                 $program = $unified_info{rename}->{$program};
1450             }
1451             $unified_info{programs}->{$program} = 1;
1452         }
1453
1454         foreach (@libraries) {
1455             my $library = cleanfile($buildd, $_, $blddir);
1456             if ($unified_info{rename}->{$library}) {
1457                 $library = $unified_info{rename}->{$library};
1458             }
1459             $unified_info{libraries}->{$library} = 1;
1460         }
1461
1462         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1463 ENGINES can only be used if configured with 'dynamic-engine'.
1464 This is usually a fault in a build.info file.
1465 EOF
1466         foreach (@engines) {
1467             my $library = cleanfile($buildd, $_, $blddir);
1468             if ($unified_info{rename}->{$library}) {
1469                 $library = $unified_info{rename}->{$library};
1470             }
1471             $unified_info{engines}->{$library} = 1;
1472         }
1473
1474         foreach (@scripts) {
1475             my $script = cleanfile($buildd, $_, $blddir);
1476             if ($unified_info{rename}->{$script}) {
1477                 $script = $unified_info{rename}->{$script};
1478             }
1479             $unified_info{scripts}->{$script} = 1;
1480         }
1481
1482         foreach (@extra) {
1483             my $extra = cleanfile($buildd, $_, $blddir);
1484             $unified_info{extra}->{$extra} = 1;
1485         }
1486
1487         foreach (@overrides) {
1488             my $override = cleanfile($buildd, $_, $blddir);
1489             $unified_info{overrides}->{$override} = 1;
1490         }
1491
1492         push @{$unified_info{rawlines}}, @rawlines;
1493
1494         unless ($disabled{shared}) {
1495             # Check sharednames.
1496             foreach (keys %sharednames) {
1497                 my $dest = cleanfile($buildd, $_, $blddir);
1498                 if ($unified_info{rename}->{$dest}) {
1499                     $dest = $unified_info{rename}->{$dest};
1500                 }
1501                 die "shared_name for $dest with multiple values: "
1502                     ,join(" ", @{$sharednames{$_}}),"\n"
1503                     if scalar @{$sharednames{$_}} > 1;
1504                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1505                 die "shared_name found for a library $dest that isn't defined\n"
1506                     unless $unified_info{libraries}->{$dest};
1507                 die "shared_name for $dest with multiple values: "
1508                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1509                     unless !defined($unified_info{sharednames}->{$dest})
1510                     or $unified_info{sharednames}->{$dest} eq $to;
1511                 $unified_info{sharednames}->{$dest} = $to;
1512             }
1513
1514             # Additionally, we set up sharednames for libraries that don't
1515             # have any, as themselves.
1516             foreach (keys %{$unified_info{libraries}}) {
1517                 if (!defined $unified_info{sharednames}->{$_}) {
1518                     $unified_info{sharednames}->{$_} = $_
1519                 }
1520             }
1521         }
1522
1523         foreach (keys %ordinals) {
1524             my $dest = $_;
1525             my $ddest = cleanfile($buildd, $_, $blddir);
1526             if ($unified_info{rename}->{$ddest}) {
1527                 $ddest = $unified_info{rename}->{$ddest};
1528             }
1529             foreach (@{$ordinals{$dest}}) {
1530                 my %known_ordinals =
1531                     (
1532                      crypto =>
1533                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1534                      ssl =>
1535                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1536                     );
1537                 my $o = $known_ordinals{$_};
1538                 die "Ordinals for $ddest defined more than once\n"
1539                     if $unified_info{ordinals}->{$ddest};
1540                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1541             }
1542         }
1543
1544         foreach (keys %sources) {
1545             my $dest = $_;
1546             my $ddest = cleanfile($buildd, $_, $blddir);
1547             if ($unified_info{rename}->{$ddest}) {
1548                 $ddest = $unified_info{rename}->{$ddest};
1549             }
1550             foreach (@{$sources{$dest}}) {
1551                 my $s = cleanfile($sourced, $_, $blddir);
1552
1553                 # If it isn't in the source tree, we assume it's generated
1554                 # in the build tree
1555                 if (! -f $s) {
1556                     $s = cleanfile($buildd, $_, $blddir);
1557                 }
1558                 # We recognise C and asm files
1559                 if ($s =~ /\.[csS]\b$/) {
1560                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1561                     $o = cleanfile($buildd, $o, $blddir);
1562                     $unified_info{sources}->{$ddest}->{$o} = 1;
1563                     $unified_info{sources}->{$o}->{$s} = 1;
1564                 } else {
1565                     $unified_info{sources}->{$ddest}->{$s} = 1;
1566                 }
1567             }
1568         }
1569
1570         foreach (keys %generate) {
1571             my $dest = $_;
1572             my $ddest = cleanfile($buildd, $_, $blddir);
1573             if ($unified_info{rename}->{$ddest}) {
1574                 $ddest = $unified_info{rename}->{$ddest};
1575             }
1576             die "more than one generator for $dest: "
1577                     ,join(" ", @{$generate{$_}}),"\n"
1578                     if scalar @{$generate{$_}} > 1;
1579             my @generator = split /\s+/, $generate{$dest}->[0];
1580             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1581             $unified_info{generate}->{$ddest} = [ @generator ];
1582         }
1583
1584         foreach (keys %depends) {
1585             my $dest = $_;
1586             my $ddest = cleanfile($buildd, $_, $blddir);
1587             if ($unified_info{rename}->{$ddest}) {
1588                 $ddest = $unified_info{rename}->{$ddest};
1589             }
1590             foreach (@{$depends{$dest}}) {
1591                 my $d = cleanfile($sourced, $_, $blddir);
1592
1593                 # If we know it's generated, or assume it is because we can't
1594                 # find it in the source tree, we set file we depend on to be
1595                 # in the build tree rather than the source tree, and assume
1596                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1597                 # section or in the Makefile template.
1598                 if (! -f $d
1599                     || (grep { $d eq $_ }
1600                         map { cleanfile($srcdir, $_, $blddir) }
1601                         (@generated_headers, @generated_by_make_headers))) {
1602                     $d = cleanfile($buildd, $_, $blddir);
1603                 }
1604                 # Take note if the file to depend on is being renamed
1605                 if ($unified_info{rename}->{$d}) {
1606                     $d = $unified_info{rename}->{$d};
1607                 }
1608                 $unified_info{depends}->{$ddest}->{$d} = 1;
1609                 # If we depend on a header file, let's make sure it
1610                 # can get included
1611                 if ($d =~ /\.h$/) {
1612                     my $i = dirname($d);
1613                     push @{$unified_info{includes}->{$ddest}}, $i
1614                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1615                 }
1616             }
1617         }
1618
1619         foreach (keys %includes) {
1620             my $dest = $_;
1621             my $ddest = cleanfile($buildd, $_, $blddir);
1622             if ($unified_info{rename}->{$ddest}) {
1623                 $ddest = $unified_info{rename}->{$ddest};
1624             }
1625             foreach (@{$includes{$dest}}) {
1626                 my $i = cleandir($sourced, $_, $blddir);
1627                 push @{$unified_info{includes}->{$ddest}}, $i
1628                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1629             }
1630         }
1631     }
1632
1633     ### Make unified_info a bit more efficient
1634     # One level structures
1635     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1636         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1637     }
1638     # Two level structures
1639     foreach my $l1 (("sources", "ldadd", "depends")) {
1640         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1641             $unified_info{$l1}->{$l2} =
1642                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1643         }
1644     }
1645 }
1646
1647 # For the schemes that need it, we provide the old *_obj configs
1648 # from the *_asm_obj ones
1649 foreach (grep /_(asm|aux)_src$/, keys %target) {
1650     my $src = $_;
1651     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1652     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1653 }
1654
1655 # Write down our configuration where it fits #########################
1656
1657 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1658 print OUT <<"EOF";
1659 package configdata;
1660
1661 use strict;
1662 use warnings;
1663
1664 use Exporter;
1665 #use vars qw(\@ISA \@EXPORT);
1666 our \@ISA = qw(Exporter);
1667 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1668
1669 EOF
1670 print OUT "our %config = (\n";
1671 foreach (sort keys %config) {
1672     if (ref($config{$_}) eq "ARRAY") {
1673         print OUT "  ", $_, " => [ ", join(", ",
1674                                            map { quotify("perl", $_) }
1675                                            @{$config{$_}}), " ],\n";
1676     } else {
1677         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1678     }
1679 }
1680 print OUT <<"EOF";
1681 );
1682
1683 EOF
1684 print OUT "our %target = (\n";
1685 foreach (sort keys %target) {
1686     if (ref($target{$_}) eq "ARRAY") {
1687         print OUT "  ", $_, " => [ ", join(", ",
1688                                            map { quotify("perl", $_) }
1689                                            @{$target{$_}}), " ],\n";
1690     } else {
1691         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1692     }
1693 }
1694 print OUT <<"EOF";
1695 );
1696
1697 EOF
1698 print OUT "our \%available_protocols = (\n";
1699 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1700 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1701 print OUT <<"EOF";
1702 );
1703
1704 EOF
1705 print OUT "our \@disablables = (\n";
1706 foreach (@disablables) {
1707     print OUT "  ", quotify("perl", $_), ",\n";
1708 }
1709 print OUT <<"EOF";
1710 );
1711
1712 EOF
1713 print OUT "our \%disabled = (\n";
1714 foreach (sort keys %disabled) {
1715     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1716 }
1717 print OUT <<"EOF";
1718 );
1719
1720 EOF
1721 print OUT "our %withargs = (\n";
1722 foreach (sort keys %withargs) {
1723     if (ref($withargs{$_}) eq "ARRAY") {
1724         print OUT "  ", $_, " => [ ", join(", ",
1725                                            map { quotify("perl", $_) }
1726                                            @{$withargs{$_}}), " ],\n";
1727     } else {
1728         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1729     }
1730 }
1731 print OUT <<"EOF";
1732 );
1733
1734 EOF
1735 if ($builder eq "unified") {
1736     my $recurse;
1737     $recurse = sub {
1738         my $indent = shift;
1739         foreach (@_) {
1740             if (ref $_ eq "ARRAY") {
1741                 print OUT " "x$indent, "[\n";
1742                 foreach (@$_) {
1743                     $recurse->($indent + 4, $_);
1744                 }
1745                 print OUT " "x$indent, "],\n";
1746             } elsif (ref $_ eq "HASH") {
1747                 my %h = %$_;
1748                 print OUT " "x$indent, "{\n";
1749                 foreach (sort keys %h) {
1750                     if (ref $h{$_} eq "") {
1751                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1752                     } else {
1753                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1754                         $recurse->($indent + 8, $h{$_});
1755                     }
1756                 }
1757                 print OUT " "x$indent, "},\n";
1758             } else {
1759                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1760             }
1761         }
1762     };
1763     print OUT "our %unified_info = (\n";
1764     foreach (sort keys %unified_info) {
1765         if (ref $unified_info{$_} eq "") {
1766             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1767         } else {
1768             print OUT " "x4, quotify("perl", $_), " =>\n";
1769             $recurse->(8, $unified_info{$_});
1770         }
1771     }
1772     print OUT <<"EOF";
1773 );
1774
1775 EOF
1776 }
1777 print OUT "1;\n";
1778 close(OUT);
1779
1780
1781 print "IsMK1MF       =", ($builder eq "mk1mf" ? "yes" : "no"), "\n";
1782 print "CC            =$target{cc}\n";
1783 print "CFLAG         =$target{cflags} $config{cflags}\n";
1784 print "SHARED_CFLAG  =$target{shared_cflag}\n";
1785 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
1786 print "LFLAG         =$target{lflags}\n";
1787 print "PLIB_LFLAG    =$target{plib_lflags}\n";
1788 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
1789 print "APPS_OBJ      =$target{apps_obj}\n";
1790 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1791 print "UPLINK_OBJ    =$target{uplink_obj}\n";
1792 print "BN_ASM        =$target{bn_obj}\n";
1793 print "EC_ASM        =$target{ec_obj}\n";
1794 print "DES_ENC       =$target{des_obj}\n";
1795 print "AES_ENC       =$target{aes_obj}\n";
1796 print "BF_ENC        =$target{bf_obj}\n";
1797 print "CAST_ENC      =$target{cast_obj}\n";
1798 print "RC4_ENC       =$target{rc4_obj}\n";
1799 print "RC5_ENC       =$target{rc5_obj}\n";
1800 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1801 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1802 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1803 print "CMLL_ENC      =$target{cmll_obj}\n";
1804 print "MODES_OBJ     =$target{modes_obj}\n";
1805 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1806 print "CHACHA_ENC    =$target{chacha_obj}\n";
1807 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1808 print "BLAKE2_OBJ    =$target{blake2_obj}\n";
1809 print "PROCESSOR     =$config{processor}\n";
1810 print "RANLIB        =$target{ranlib}\n";
1811 print "ARFLAGS       =$target{arflags}\n";
1812 print "PERL          =$config{perl}\n";
1813 print "\n";
1814 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1815 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1816 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1817 print "BN_LLONG mode\n" if $config{bn_ll};
1818 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} ne $def_int;
1819
1820 for (@generated_headers) {
1821     mkpath(catdir($blddir, dirname($_)));
1822     run_dofile(catfile($blddir, $_),
1823                catfile($srcdir, $_.".in"));
1824 }
1825
1826 ###
1827 ### When the old "unixmake" scheme goes away, so does this function
1828 ###
1829 sub build_Makefile {
1830     run_dofile("Makefile","Makefile.in");
1831
1832     # Copy all Makefile.in to Makefile (except top-level)
1833     use File::Find;
1834     use IO::File;
1835     find(
1836         {
1837             preprocess => sub {
1838                 grep(!/^\./, @_);
1839             },
1840             wanted => sub {
1841                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1842                 my $in = IO::File->new($_, "r") or
1843                     die sprintf "Error reading Makefile.in in %s: !$\n",
1844                     $File::Find::dir;
1845                 my $out = IO::File->new("Makefile", "w") or
1846                     die sprintf "Error writing Makefile in %s: !$\n",
1847                     $File::Find::dir;
1848                 print $out "# Generated from $_, do not edit\n";
1849                 while (my $line = <$in>) { print $out $line }
1850                 $in->close() or
1851                     die sprintf "Error reading Makefile.in in %s: !$\n",
1852                     $File::Find::dir;
1853                 $out->close() or
1854                     die sprintf "Error writing Makefile in %s: !$\n",
1855                     $File::Find::dir;
1856             },
1857         },
1858         ".");
1859 }
1860
1861 my %builders = (
1862     unified => sub {
1863         run_dofile(catfile($blddir, $target{build_file}),
1864                    $config{build_file_template},
1865                    catfile($srcdir, "Configurations", "common.tmpl"));
1866     },
1867     unixmake => sub {
1868         build_Makefile();
1869
1870         run_dofile("util/domd", "util/domd.in");
1871         chmod 0755, "util/domd";
1872     },
1873     mk1mf => sub {
1874         my $platform = shift;
1875         # The only reason we do this is to have something to build MINFO from
1876         build_Makefile();
1877     },
1878     );
1879
1880 $builders{$builder}->($builder_platform, @builder_opts);
1881
1882 print <<"EOF";
1883
1884 Configured for $target.
1885 EOF
1886
1887 print <<"EOF" if ($disabled{threads} eq "unavailable");
1888
1889 The library could not be configured for supporting multi-threaded
1890 applications as the compiler options required on this system are not known.
1891 See file INSTALL for details if you need multi-threading.
1892 EOF
1893
1894 print <<"EOF" if ($no_shared_warn);
1895
1896 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
1897 platform, so we will pretend you gave the option 'no-pic', which also disables
1898 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
1899 or position independent code, please let us know (but please first make sure
1900 you have tried with a current version of OpenSSL).
1901 EOF
1902
1903 exit(0);
1904
1905 ######################################################################
1906 #
1907 # Helpers and utility functions
1908 #
1909
1910 # Configuration file reading #########################################
1911
1912 # Note: All of the helper functions are for lazy evaluation.  They all
1913 # return a CODE ref, which will return the intended value when evaluated.
1914 # Thus, whenever there's mention of a returned value, it's about that
1915 # intended value.
1916
1917 # Helper function to implement conditional inheritance depending on the
1918 # value of $disabled{asm}.  Used in inherit_from values as follows:
1919 #
1920 #      inherit_from => [ "template", asm("asm_tmpl") ]
1921 #
1922 sub asm {
1923     my @x = @_;
1924     sub {
1925         $disabled{asm} ? () : @x;
1926     }
1927 }
1928
1929 # Helper function to implement conditional value variants, with a default
1930 # plus additional values based on the value of $config{build_type}.
1931 # Arguments are given in hash table form:
1932 #
1933 #       picker(default => "Basic string: ",
1934 #              debug   => "debug",
1935 #              release => "release")
1936 #
1937 # When configuring with --debug, the resulting string will be
1938 # "Basic string: debug", and when not, it will be "Basic string: release"
1939 #
1940 # This can be used to create variants of sets of flags according to the
1941 # build type:
1942 #
1943 #       cflags => picker(default => "-Wall",
1944 #                        debug   => "-g -O0",
1945 #                        release => "-O3")
1946 #
1947 sub picker {
1948     my %opts = @_;
1949     return sub { add($opts{default} || (),
1950                      $opts{$config{build_type}} || ())->(); }
1951 }
1952
1953 # Helper function to combine several values of different types into one.
1954 # This is useful if you want to combine a string with the result of a
1955 # lazy function, such as:
1956 #
1957 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
1958 #
1959 sub combine {
1960     my @stuff = @_;
1961     return sub { add(@stuff)->(); }
1962 }
1963
1964 # Helper function to implement conditional values depending on the value
1965 # of $disabled{threads}.  Can be used as follows:
1966 #
1967 #       cflags => combine("-Wall", threads("-pthread"))
1968 #
1969 sub threads {
1970     my @flags = @_;
1971     return sub { add($disabled{threads} ? () : @flags)->(); }
1972 }
1973
1974
1975
1976 our $add_called = 0;
1977 # Helper function to implement adding values to already existing configuration
1978 # values.  It handles elements that are ARRAYs, CODEs and scalars
1979 sub _add {
1980     my $separator = shift;
1981
1982     # If there's any ARRAY in the collection of values OR the separator
1983     # is undef, we will return an ARRAY of combined values, otherwise a
1984     # string of joined values with $separator as the separator.
1985     my $found_array = !defined($separator);
1986
1987     my @values =
1988         map {
1989             my $res = $_;
1990             while (ref($res) eq "CODE") {
1991                 $res = $res->();
1992             }
1993             if (defined($res)) {
1994                 if (ref($res) eq "ARRAY") {
1995                     $found_array = 1;
1996                     @$res;
1997                 } else {
1998                     $res;
1999                 }
2000             } else {
2001                 ();
2002             }
2003     } (@_);
2004
2005     $add_called = 1;
2006
2007     if ($found_array) {
2008         [ @values ];
2009     } else {
2010         join($separator, grep { defined($_) && $_ ne "" } @values);
2011     }
2012 }
2013 sub add_before {
2014     my $separator = " ";
2015     if (ref($_[$#_]) eq "HASH") {
2016         my $opts = pop;
2017         $separator = $opts->{separator};
2018     }
2019     my @x = @_;
2020     sub { _add($separator, @x, @_) };
2021 }
2022 sub add {
2023     my $separator = " ";
2024     if (ref($_[$#_]) eq "HASH") {
2025         my $opts = pop;
2026         $separator = $opts->{separator};
2027     }
2028     my @x = @_;
2029     sub { _add($separator, @_, @x) };
2030 }
2031
2032 # configuration reader, evaluates the input file as a perl script and expects
2033 # it to fill %targets with target configurations.  Those are then added to
2034 # %table.
2035 sub read_config {
2036     my $fname = shift;
2037     open(CONFFILE, "< $fname")
2038         or die "Can't open configuration file '$fname'!\n";
2039     my $x = $/;
2040     undef $/;
2041     my $content = <CONFFILE>;
2042     $/ = $x;
2043     close(CONFFILE);
2044     my %targets = ();
2045     {
2046         local %table = %::table;    # Protect %table from tampering
2047
2048         eval $content;
2049         warn $@ if $@;
2050     }
2051
2052     # For each target, check that it's configured with a hash table.
2053     foreach (keys %targets) {
2054         if (ref($targets{$_}) ne "HASH") {
2055             if (ref($targets{$_}) eq "") {
2056                 warn "Deprecated target configuration for $_, ignoring...\n";
2057             } else {
2058                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2059             }
2060             delete $targets{$_};
2061         }
2062     }
2063
2064     %table = (%table, %targets);
2065
2066 }
2067
2068 # configuration resolver.  Will only resolve all the lazy evalutation
2069 # codeblocks for the chozen target and all those it inherits from,
2070 # recursively
2071 sub resolve_config {
2072     my $target = shift;
2073     my @breadcrumbs = @_;
2074
2075 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2076
2077     if (grep { $_ eq $target } @breadcrumbs) {
2078         die "inherit_from loop!  target backtrace:\n  "
2079             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2080     }
2081
2082     if (!defined($table{$target})) {
2083         warn "Warning! target $target doesn't exist!\n";
2084         return ();
2085     }
2086     # Recurse through all inheritances.  They will be resolved on the
2087     # fly, so when this operation is done, they will all just be a
2088     # bunch of attributes with string values.
2089     # What we get here, though, are keys with references to lists of
2090     # the combined values of them all.  We will deal with lists after
2091     # this stage is done.
2092     my %combined_inheritance = ();
2093     if ($table{$target}->{inherit_from}) {
2094         my @inherit_from =
2095             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2096         foreach (@inherit_from) {
2097             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2098
2099             # 'template' is a marker that's considered private to
2100             # the config that had it.
2101             delete $inherited_config{template};
2102
2103             map {
2104                 if (!$combined_inheritance{$_}) {
2105                     $combined_inheritance{$_} = [];
2106                 }
2107                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2108             } keys %inherited_config;
2109         }
2110     }
2111
2112     # We won't need inherit_from in this target any more, since we've
2113     # resolved all the inheritances that lead to this
2114     delete $table{$target}->{inherit_from};
2115
2116     # Now is the time to deal with those lists.  Here's the place to
2117     # decide what shall be done with those lists, all based on the
2118     # values of the target we're currently dealing with.
2119     # - If a value is a coderef, it will be executed with the list of
2120     #   inherited values as arguments.
2121     # - If the corresponding key doesn't have a value at all or is the
2122     #   emoty string, the inherited value list will be run through the
2123     #   default combiner (below), and the result becomes this target's
2124     #   value.
2125     # - Otherwise, this target's value is assumed to be a string that
2126     #   will simply override the inherited list of values.
2127     my $default_combiner = add();
2128
2129     my %all_keys =
2130         map { $_ => 1 } (keys %combined_inheritance,
2131                          keys %{$table{$target}});
2132
2133     sub process_values {
2134         my $object    = shift;
2135         my $inherited = shift;  # Always a [ list ]
2136         my $target    = shift;
2137         my $entry     = shift;
2138
2139         $add_called = 0;
2140
2141         while(ref($object) eq "CODE") {
2142             $object = $object->(@$inherited);
2143         }
2144         if (!defined($object)) {
2145             return ();
2146         }
2147         elsif (ref($object) eq "ARRAY") {
2148             local $add_called;  # To make sure recursive calls don't affect it
2149             return [ map { process_values($_, $inherited, $target, $entry) }
2150                      @$object ];
2151         } elsif (ref($object) eq "") {
2152             return $object;
2153         } else {
2154             die "cannot handle reference type ",ref($object)
2155                 ," found in target ",$target," -> ",$entry,"\n";
2156         }
2157     }
2158
2159     foreach (sort keys %all_keys) {
2160         my $previous = $combined_inheritance{$_};
2161
2162         # Current target doesn't have a value for the current key?
2163         # Assign it the default combiner, the rest of this loop body
2164         # will handle it just like any other coderef.
2165         if (!exists $table{$target}->{$_}) {
2166             $table{$target}->{$_} = $default_combiner;
2167         }
2168
2169         $table{$target}->{$_} = process_values($table{$target}->{$_},
2170                                                $combined_inheritance{$_},
2171                                                $target, $_);
2172         unless(defined($table{$target}->{$_})) {
2173             delete $table{$target}->{$_};
2174         }
2175 #        if ($extra_checks &&
2176 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2177 #            warn "$_ got replaced in $target\n";
2178 #        }
2179     }
2180
2181     # Finally done, return the result.
2182     return %{$table{$target}};
2183 }
2184
2185 sub usage
2186         {
2187         print STDERR $usage;
2188         print STDERR "\npick os/compiler from:\n";
2189         my $j=0;
2190         my $i;
2191         my $k=0;
2192         foreach $i (sort keys %table)
2193                 {
2194                 next if $table{$i}->{template};
2195                 next if $i =~ /^debug/;
2196                 $k += length($i) + 1;
2197                 if ($k > 78)
2198                         {
2199                         print STDERR "\n";
2200                         $k=length($i);
2201                         }
2202                 print STDERR $i . " ";
2203                 }
2204         foreach $i (sort keys %table)
2205                 {
2206                 next if $table{$i}->{template};
2207                 next if $i !~ /^debug/;
2208                 $k += length($i) + 1;
2209                 if ($k > 78)
2210                         {
2211                         print STDERR "\n";
2212                         $k=length($i);
2213                         }
2214                 print STDERR $i . " ";
2215                 }
2216         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2217         exit(1);
2218         }
2219
2220 sub run_dofile
2221 {
2222     my $out = shift;
2223     my @templates = @_;
2224
2225     unlink $out || warn "Can't remove $out, $!"
2226         if -f $out;
2227     foreach (@templates) {
2228         die "Can't open $_, $!" unless -f $_;
2229     }
2230     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2231     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2232     system($cmd);
2233     exit 1 if $? != 0;
2234     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2235 }
2236
2237 # Configuration printer ##############################################
2238
2239 sub print_table_entry
2240 {
2241     my $target = shift;
2242     my %target = resolve_config($target);
2243     my $type = shift;
2244
2245     # Don't print the templates
2246     return if $target{template};
2247
2248     my @sequence = (
2249         "sys_id",
2250         "cc",
2251         "cflags",
2252         "defines",
2253         "unistd",
2254         "ld",
2255         "lflags",
2256         "plib_lflags",
2257         "ex_libs",
2258         "bn_ops",
2259         "cpuid_obj",
2260         "bn_obj",
2261         "ec_obj",
2262         "des_obj",
2263         "aes_obj",
2264         "bf_obj",
2265         "md5_obj",
2266         "sha1_obj",
2267         "cast_obj",
2268         "rc4_obj",
2269         "rmd160_obj",
2270         "rc5_obj",
2271         "wp_obj",
2272         "cmll_obj",
2273         "modes_obj",
2274         "padlock_obj",
2275         "thread_scheme",
2276         "perlasm_scheme",
2277         "dso_scheme",
2278         "shared_target",
2279         "shared_cflag",
2280         "shared_ldflag",
2281         "shared_rcflag",
2282         "shared_extension",
2283         "shared_extension_simple",
2284         "shared_import_extension",
2285         "dso_extension",
2286         "obj_extension",
2287         "exe_extension",
2288         "ranlib",
2289         "ar",
2290         "arflags",
2291         "multilib",
2292         "build_scheme",
2293         );
2294
2295     if ($type eq "TABLE") {
2296         print "\n";
2297         print "*** $target\n";
2298         foreach (@sequence) {
2299             if (ref($target{$_}) eq "ARRAY") {
2300                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2301             } else {
2302                 printf "\$%-12s = %s\n", $_, $target{$_};
2303             }
2304         }
2305     } elsif ($type eq "HASH") {
2306         my $largest =
2307             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2308         print "    '$target' => {\n";
2309         foreach (@sequence) {
2310             if ($target{$_}) {
2311                 if (ref($target{$_}) eq "ARRAY") {
2312                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2313                 } else {
2314                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2315                 }
2316             }
2317         }
2318         print "    },\n";
2319     }
2320 }
2321
2322 # Utility routines ###################################################
2323
2324 # On VMS, if the given file is a logical name, File::Spec::Functions
2325 # will consider it an absolute path.  There are cases when we want a
2326 # purely syntactic check without checking the environment.
2327 sub isabsolute {
2328     my $file = shift;
2329
2330     # On non-platforms, we just use file_name_is_absolute().
2331     return file_name_is_absolute($file) unless $^O eq "VMS";
2332
2333     # If the file spec includes a device or a directpry spec,
2334     # file_name_is_absolute() is perfectly safe.
2335     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2336
2337     # Here, we know the given file spec isn't absolute
2338     return 0;
2339 }
2340
2341 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2342 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2343 # realpath() requires that at least all path components except the last is an
2344 # existing directory.  On VMS, the last component of the directory spec must
2345 # exist.
2346 sub absolutedir {
2347     my $dir = shift;
2348
2349     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2350     # will return the volume name for the device, no matter what.  Also,
2351     # it will return an incorrect directory spec if the argument is a
2352     # directory that doesn't exist.
2353     if ($^O eq "VMS") {
2354         return rel2abs($dir);
2355     }
2356
2357     # We use realpath() on Unix, since no other will properly clean out
2358     # a directory spec.
2359     use Cwd qw/realpath/;
2360
2361     return realpath($dir);
2362 }
2363
2364 sub which
2365         {
2366         my($name)=@_;
2367         my $path;
2368         foreach $path (split /:/, $ENV{PATH})
2369                 {
2370                 my $fullpath = "$path/$name$target{exe_extension}";
2371                 if (-f $fullpath and -x $fullpath)
2372                         {
2373                         return $fullpath
2374                             unless ($name eq "perl" and
2375                                     system("$fullpath -e " . '\'exit($]<5.0);\''));
2376                         }
2377                 }
2378         }
2379
2380 sub quotify {
2381     my %processors = (
2382         perl    => sub { my $x = shift;
2383                          $x =~ s/([\\\$\@"])/\\$1/g;
2384                          return '"'.$x.'"'; },
2385         );
2386     my $for = shift;
2387     my $processor =
2388         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2389
2390     map { $processor->($_); } @_;
2391 }
2392
2393 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2394 # $filename is a file name to read from
2395 # $line_concat_cond_re is a regexp detecting a line continuation ending
2396 # $line_concat is a CODEref that takes care of concatenating two lines
2397 sub collect_from_file {
2398     my $filename = shift;
2399     my $line_concat_cond_re = shift;
2400     my $line_concat = shift;
2401
2402     open my $fh, $filename || die "unable to read $filename: $!\n";
2403     return sub {
2404         my $saved_line = "";
2405         $_ = "";
2406         while (<$fh>) {
2407             s|\R$||;
2408             if (defined $line_concat) {
2409                 $_ = $line_concat->($saved_line, $_);
2410                 $saved_line = "";
2411             }
2412             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2413                 $saved_line = $_;
2414                 next;
2415             }
2416             return $_;
2417         }
2418         die "$filename ending with continuation line\n" if $_;
2419         close $fh;
2420         return undef;
2421     }
2422 }
2423
2424 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2425 # $array is an ARRAYref of lines
2426 # $line_concat_cond_re is a regexp detecting a line continuation ending
2427 # $line_concat is a CODEref that takes care of concatenating two lines
2428 sub collect_from_array {
2429     my $array = shift;
2430     my $line_concat_cond_re = shift;
2431     my $line_concat = shift;
2432     my @array = (@$array);
2433
2434     return sub {
2435         my $saved_line = "";
2436         $_ = "";
2437         while (defined($_ = shift @array)) {
2438             s|\R$||;
2439             if (defined $line_concat) {
2440                 $_ = $line_concat->($saved_line, $_);
2441                 $saved_line = "";
2442             }
2443             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2444                 $saved_line = $_;
2445                 next;
2446             }
2447             return $_;
2448         }
2449         die "input text ending with continuation line\n" if $_;
2450         return undef;
2451     }
2452 }
2453
2454 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2455 # $lineiterator is a CODEref that delivers one line at a time.
2456 # All following arguments are regex/CODEref pairs, where the regexp detects a
2457 # line and the CODEref does something with the result of the regexp.
2458 sub collect_information {
2459     my $lineiterator = shift;
2460     my %collectors = @_;
2461
2462     while(defined($_ = $lineiterator->())) {
2463         s|\R$||;
2464         my $found = 0;
2465         if ($collectors{"BEFORE"}) {
2466             $collectors{"BEFORE"}->($_);
2467         }
2468         foreach my $re (keys %collectors) {
2469             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2470                 $collectors{$re}->($lineiterator);
2471                 $found = 1;
2472             };
2473         }
2474         if ($collectors{"OTHERWISE"}) {
2475             $collectors{"OTHERWISE"}->($lineiterator, $_)
2476                 unless $found || !defined $collectors{"OTHERWISE"};
2477         }
2478         if ($collectors{"AFTER"}) {
2479             $collectors{"AFTER"}->($_);
2480         }
2481     }
2482 }