Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1411         push @{$config{lib_defines}}, "RC4_ASM";
1412     }
1413     if ($target{rmd160_asm_src}) {
1414         push @{$config{lib_defines}}, "RMD160_ASM";
1415     }
1416     if ($target{wp_asm_src} =~ /mmx/) {
1417         if ($config{processor} eq "386") {
1418             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1419         } elsif (!$disabled{"whirlpool"}) {
1420             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1421         }
1422     }
1423     if ($target{modes_asm_src} =~ /ghash-/) {
1424         push @{$config{lib_defines}}, "GHASH_ASM";
1425     }
1426     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1427         push @{$config{dso_defines}}, "PADLOCK_ASM";
1428     }
1429     if ($target{poly1305_asm_src} ne "") {
1430         push @{$config{lib_defines}}, "POLY1305_ASM";
1431     }
1432 }
1433
1434 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1435 my %predefined_CXX = $config{CXX}
1436     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1437     : ();
1438
1439 # Check for makedepend capabilities.
1440 if (!$disabled{makedepend}) {
1441     if ($config{target} =~ /^(VC|vms)-/) {
1442         # For VC- and vms- targets, there's nothing more to do here.  The
1443         # functionality is hard coded in the corresponding build files for
1444         # cl (Windows) and CC/DECC (VMS).
1445     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1446              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1447         # We know that GNU C version 3 and up as well as all clang
1448         # versions support dependency generation, but Xcode did not
1449         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1450         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1451     } else {
1452         # In all other cases, we look for 'makedepend', and disable the
1453         # capability if not found.
1454         $config{makedepprog} = which('makedepend');
1455         disable('unavailable', 'makedepend') unless $config{makedepprog};
1456     }
1457 }
1458
1459 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1460     # probe for -Wa,--noexecstack option...
1461     if ($predefined_C{__clang__}) {
1462         # clang has builtin assembler, which doesn't recognize --help,
1463         # but it apparently recognizes the option in question on all
1464         # supported platforms even when it's meaningless. In other words
1465         # probe would fail, but probed option always accepted...
1466         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1467     } else {
1468         my $cc = $config{CROSS_COMPILE}.$config{CC};
1469         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1470         while(<PIPE>) {
1471             if (m/--noexecstack/) {
1472                 push @{$config{cflags}}, "-Wa,--noexecstack";
1473                 last;
1474             }
1475         }
1476         close(PIPE);
1477         unlink("null.$$.o");
1478     }
1479 }
1480
1481 # Deal with bn_ops ###################################################
1482
1483 $config{bn_ll}                  =0;
1484 $config{export_var_as_fn}       =0;
1485 my $def_int="unsigned int";
1486 $config{rc4_int}                =$def_int;
1487 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1488
1489 my $count = 0;
1490 foreach (sort split(/\s+/,$target{bn_ops})) {
1491     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1492     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1493     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1494     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1495     ($config{b64l},$config{b64},$config{b32})
1496         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1497     ($config{b64l},$config{b64},$config{b32})
1498         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1499     ($config{b64l},$config{b64},$config{b32})
1500         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1501 }
1502 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1503     if $count > 1;
1504
1505
1506 # Hack cflags for better warnings (dev option) #######################
1507
1508 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1509 # a string and works as well on command lines.
1510 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1511                         @{$config{cflags}} ];
1512 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1513                           @{$config{cxxflags}} ] if $config{CXX};
1514
1515 $config{openssl_api_defines} = [
1516     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1517 ];
1518
1519 my @strict_warnings_collection=();
1520 if ($strict_warnings)
1521         {
1522         my $wopt;
1523         my $gccver = $predefined_C{__GNUC__} // -1;
1524
1525         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1526             unless $gccver >= 4;
1527         push @strict_warnings_collection, @gcc_devteam_warn;
1528         push @strict_warnings_collection, @clang_devteam_warn
1529             if (defined($predefined_C{__clang__}));
1530         }
1531
1532 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1533     disable('static', 'pic', 'threads');
1534 }
1535
1536 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1537                               ? @strict_warnings_collection
1538                               : ( $_ ) }
1539                     @{$config{CFLAGS}} ];
1540
1541 unless ($disabled{"crypto-mdebug-backtrace"})
1542         {
1543         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1544                 {
1545                 push @{$config{cflags}}, $wopt
1546                         unless grep { $_ eq $wopt } @{$config{cflags}};
1547                 }
1548         if ($target =~ /^BSD-/)
1549                 {
1550                 push @{$config{ex_libs}}, "-lexecinfo";
1551                 }
1552         }
1553
1554 unless ($disabled{afalgeng}) {
1555     $config{afalgeng}="";
1556     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1557         my $minver = 4*10000 + 1*100 + 0;
1558         if ($config{CROSS_COMPILE} eq "") {
1559             my $verstr = `uname -r`;
1560             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1561             ($mi2) = $mi2 =~ /(\d+)/;
1562             my $ver = $ma*10000 + $mi1*100 + $mi2;
1563             if ($ver < $minver) {
1564                 disable('too-old-kernel', 'afalgeng');
1565             } else {
1566                 push @{$config{engdirs}}, "afalg";
1567             }
1568         } else {
1569             disable('cross-compiling', 'afalgeng');
1570         }
1571     } else {
1572         disable('not-linux', 'afalgeng');
1573     }
1574 }
1575
1576 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1577
1578 unless ($disabled{ktls}) {
1579     $config{ktls}="";
1580     if ($target =~ m/^linux/) {
1581         my $usr = "/usr/$config{cross_compile_prefix}";
1582         chop($usr);
1583         if ($config{cross_compile_prefix} eq "") {
1584             $usr = "/usr";
1585         }
1586         my $minver = (4 << 16) + (13 << 8) + 0;
1587         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1588
1589         if ($verstr[2] < $minver) {
1590             disable('too-old-kernel', 'ktls');
1591         }
1592     } else {
1593         disable('not-linux', 'ktls');
1594     }
1595 }
1596
1597 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1598
1599 # Get the extra flags used when building shared libraries and modules.  We
1600 # do this late because some of them depend on %disabled.
1601
1602 # Make the flags to build DSOs the same as for shared libraries unless they
1603 # are already defined
1604 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1605 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1606 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1607 {
1608     my $shared_info_pl =
1609         catfile(dirname($0), "Configurations", "shared-info.pl");
1610     my %shared_info = read_eval_file($shared_info_pl);
1611     push @{$target{_conf_fname_int}}, $shared_info_pl;
1612     my $si = $target{shared_target};
1613     while (ref $si ne "HASH") {
1614         last if ! defined $si;
1615         if (ref $si eq "CODE") {
1616             $si = $si->();
1617         } else {
1618             $si = $shared_info{$si};
1619         }
1620     }
1621
1622     # Some of the 'shared_target' values don't have any entries in
1623     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1624     # template knows how to handle this.  That is currently the case for
1625     # Windows and VMS.
1626     if (defined $si) {
1627         # Just as above, copy certain shared_* attributes to the corresponding
1628         # module_ attribute unless the latter is already defined
1629         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1630         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1631         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1632         foreach (sort keys %$si) {
1633             $target{$_} = defined $target{$_}
1634                 ? add($si->{$_})->($target{$_})
1635                 : $si->{$_};
1636         }
1637     }
1638 }
1639
1640 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1641
1642 # If we use the unified build, collect information from build.info files
1643 my %unified_info = ();
1644
1645 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1646 if ($builder eq "unified") {
1647     use with_fallback qw(Text::Template);
1648
1649     sub cleandir {
1650         my $base = shift;
1651         my $dir = shift;
1652         my $relativeto = shift || ".";
1653
1654         $dir = catdir($base,$dir) unless isabsolute($dir);
1655
1656         # Make sure the directories we're building in exists
1657         mkpath($dir);
1658
1659         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1660         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1661         return $res;
1662     }
1663
1664     sub cleanfile {
1665         my $base = shift;
1666         my $file = shift;
1667         my $relativeto = shift || ".";
1668
1669         $file = catfile($base,$file) unless isabsolute($file);
1670
1671         my $d = dirname($file);
1672         my $f = basename($file);
1673
1674         # Make sure the directories we're building in exists
1675         mkpath($d);
1676
1677         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1678         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1679         return $res;
1680     }
1681
1682     # Store the name of the template file we will build the build file from
1683     # in %config.  This may be useful for the build file itself.
1684     my @build_file_template_names =
1685         ( $builder_platform."-".$target{build_file}.".tmpl",
1686           $target{build_file}.".tmpl" );
1687     my @build_file_templates = ();
1688
1689     # First, look in the user provided directory, if given
1690     if (defined env($local_config_envname)) {
1691         @build_file_templates =
1692             map {
1693                 if ($^O eq 'VMS') {
1694                     # VMS environment variables are logical names,
1695                     # which can be used as is
1696                     $local_config_envname . ':' . $_;
1697                 } else {
1698                     catfile(env($local_config_envname), $_);
1699                 }
1700             }
1701             @build_file_template_names;
1702     }
1703     # Then, look in our standard directory
1704     push @build_file_templates,
1705         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1706           @build_file_template_names );
1707
1708     my $build_file_template;
1709     for $_ (@build_file_templates) {
1710         $build_file_template = $_;
1711         last if -f $build_file_template;
1712
1713         $build_file_template = undef;
1714     }
1715     if (!defined $build_file_template) {
1716         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1717     }
1718     $config{build_file_templates}
1719       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1720                     $blddir),
1721           $build_file_template,
1722           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1723                     $blddir) ];
1724
1725     my @build_dirs = ( [ ] );   # current directory
1726
1727     $config{build_infos} = [ ];
1728
1729     my %ordinals = ();
1730     while (@build_dirs) {
1731         my @curd = @{shift @build_dirs};
1732         my $sourced = catdir($srcdir, @curd);
1733         my $buildd = catdir($blddir, @curd);
1734
1735         my $unixdir = join('/', @curd);
1736         if (exists $skipdir{$unixdir}) {
1737             my $what = $skipdir{$unixdir};
1738             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1739             next;
1740         }
1741
1742         mkpath($buildd);
1743
1744         my $f = 'build.info';
1745         # The basic things we're trying to build
1746         my @programs = ();
1747         my @libraries = ();
1748         my @modules = ();
1749         my @scripts = ();
1750
1751         my %attributes = ();
1752         my %sources = ();
1753         my %shared_sources = ();
1754         my %includes = ();
1755         my %defines = ();
1756         my %depends = ();
1757         my %generate = ();
1758
1759         # Support for $variablename in build.info files.
1760         # Embedded perl code is the ultimate master, still.  If its output
1761         # contains a dollar sign, it had better be escaped, or it will be
1762         # taken for a variable name prefix.
1763         my %variables = ();
1764         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1765         my $expand_variables = sub {
1766             my $value = '';
1767             my $value_rest = shift;
1768
1769             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1770                 $value .= $`;
1771                 $value .= $variables{$1};
1772                 $value_rest = $';
1773             }
1774             return $value . $value_rest;
1775         };
1776
1777         # We want to detect configdata.pm in the source tree, so we
1778         # don't use it if the build tree is different.
1779         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1780
1781         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1782         my $template =
1783             Text::Template->new(TYPE => 'FILE',
1784                                 SOURCE => catfile($sourced, $f),
1785                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1786         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1787         my @text =
1788             split /^/m,
1789             $template->fill_in(HASH => { config => \%config,
1790                                          target => \%target,
1791                                          disabled => \%disabled,
1792                                          withargs => \%withargs,
1793                                          builddir => abs2rel($buildd, $blddir),
1794                                          sourcedir => abs2rel($sourced, $blddir),
1795                                          buildtop => abs2rel($blddir, $blddir),
1796                                          sourcetop => abs2rel($srcdir, $blddir) },
1797                                DELIMITERS => [ "{-", "-}" ]);
1798
1799         # The top item of this stack has the following values
1800         # -2 positive already run and we found ELSE (following ELSIF should fail)
1801         # -1 positive already run (skip until ENDIF)
1802         # 0 negatives so far (if we're at a condition, check it)
1803         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1804         # 2 positive ELSE (following ELSIF should fail)
1805         my @skip = ();
1806         collect_information(
1807             collect_from_array([ @text ],
1808                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1809                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1810             # Info we're looking for
1811             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1812             => sub {
1813                 if (! @skip || $skip[$#skip] > 0) {
1814                     push @skip, !! $expand_variables->($1);
1815                 } else {
1816                     push @skip, -1;
1817                 }
1818             },
1819             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1820             => sub { die "ELSIF out of scope" if ! @skip;
1821                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1822                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1823                      $skip[$#skip] = !! $expand_variables->($1)
1824                          if $skip[$#skip] == 0; },
1825             qr/^\s*ELSE\s*$/
1826             => sub { die "ELSE out of scope" if ! @skip;
1827                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1828                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1829             qr/^\s*ENDIF\s*$/
1830             => sub { die "ENDIF out of scope" if ! @skip;
1831                      pop @skip; },
1832             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1833             => sub {
1834                 if (!@skip || $skip[$#skip] > 0) {
1835                     my $n = $1;
1836                     my $v = $2;
1837                     $variables{$n} = $expand_variables->($v);
1838                 }
1839             },
1840             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1841             => sub {
1842                 if (!@skip || $skip[$#skip] > 0) {
1843                     foreach (tokenize($expand_variables->($1))) {
1844                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1845                     }
1846                 }
1847             },
1848             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1849             => sub {
1850                 if (!@skip || $skip[$#skip] > 0) {
1851                     my @a = tokenize($1, qr|\s*,\s*|);
1852                     my @p = tokenize($expand_variables->($2));
1853                     push @programs, @p;
1854                     foreach my $a (@a) {
1855                         my $ak = $a;
1856                         my $av = 1;
1857                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1858                             $ak = $1;
1859                             $av = $2;
1860                         }
1861                         foreach my $p (@p) {
1862                             $attributes{$p}->{$ak} = $av;
1863                         }
1864                     }
1865                 }
1866             },
1867             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1868             => sub {
1869                 if (!@skip || $skip[$#skip] > 0) {
1870                     my @a = tokenize($1, qr|\s*,\s*|);
1871                     my @l = tokenize($expand_variables->($2));
1872                     push @libraries, @l;
1873                     foreach my $a (@a) {
1874                         my $ak = $a;
1875                         my $av = 1;
1876                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1877                             $ak = $1;
1878                             $av = $2;
1879                         }
1880                         foreach my $l (@l) {
1881                             $attributes{$l}->{$ak} = $av;
1882                         }
1883                     }
1884                 }
1885             },
1886             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1887             => sub {
1888                 if (!@skip || $skip[$#skip] > 0) {
1889                     my @a = tokenize($1, qr|\s*,\s*|);
1890                     my @m = tokenize($expand_variables->($2));
1891                     push @modules, @m;
1892                     foreach my $a (@a) {
1893                         my $ak = $a;
1894                         my $av = 1;
1895                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1896                             $ak = $1;
1897                             $av = $2;
1898                         }
1899                         foreach my $m (@m) {
1900                             $attributes{$m}->{$ak} = $av;
1901                         }
1902                     }
1903                 }
1904             },
1905             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1906             => sub {
1907                 if (!@skip || $skip[$#skip] > 0) {
1908                     my @a = tokenize($1, qr|\s*,\s*|);
1909                     my @s = tokenize($expand_variables->($2));
1910                     push @scripts, @s;
1911                     foreach my $a (@a) {
1912                         my $ak = $a;
1913                         my $av = 1;
1914                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1915                             $ak = $1;
1916                             $av = $2;
1917                         }
1918                         foreach my $s (@s) {
1919                             $attributes{$s}->{$ak} = $av;
1920                         }
1921                     }
1922                 }
1923             },
1924
1925             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1926             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1927                          if !@skip || $skip[$#skip] > 0 },
1928             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1929             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1930                          if !@skip || $skip[$#skip] > 0 },
1931             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1932             => sub { push @{$shared_sources{$1}},
1933                          tokenize($expand_variables->($2))
1934                          if !@skip || $skip[$#skip] > 0 },
1935             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1936             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1937                          if !@skip || $skip[$#skip] > 0 },
1938             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1939             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1940                          if !@skip || $skip[$#skip] > 0 },
1941             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1942             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1943                          if !@skip || $skip[$#skip] > 0 },
1944             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1945             => sub { push @{$generate{$1}}, $2
1946                          if !@skip || $skip[$#skip] > 0 },
1947             qr/^\s*(?:#.*)?$/ => sub { },
1948             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1949             "BEFORE" => sub {
1950                 if ($buildinfo_debug) {
1951                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1952                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1953                 }
1954             },
1955             "AFTER" => sub {
1956                 if ($buildinfo_debug) {
1957                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1958                 }
1959             },
1960             );
1961         die "runaway IF?" if (@skip);
1962
1963         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1964                 and !$config{dynamic_engines}) {
1965             die <<"EOF"
1966 ENGINES can only be used if configured with 'dynamic-engine'.
1967 This is usually a fault in a build.info file.
1968 EOF
1969         }
1970
1971         foreach (keys %attributes) {
1972             my $dest = $_;
1973             my $ddest = cleanfile($buildd, $_, $blddir);
1974             foreach (keys %{$attributes{$dest} // {}}) {
1975                 $unified_info{attributes}->{$ddest}->{$_} =
1976                     $attributes{$dest}->{$_};
1977             }
1978         }
1979
1980         {
1981             my %infos = ( programs  => [ @programs  ],
1982                           libraries => [ @libraries ],
1983                           modules   => [ @modules   ],
1984                           scripts   => [ @scripts   ] );
1985             foreach my $k (keys %infos) {
1986                 foreach (@{$infos{$k}}) {
1987                     my $item = cleanfile($buildd, $_, $blddir);
1988                     $unified_info{$k}->{$item} = 1;
1989                 }
1990             }
1991         }
1992
1993         # Check that we haven't defined any library as both shared and
1994         # explicitly static.  That is forbidden.
1995         my @doubles = ();
1996         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1997             (my $l = $_) =~ s/\.a$//;
1998             push @doubles, $l if defined $unified_info{libraries}->{$l};
1999         }
2000         die "these libraries are both explicitly static and shared:\n  ",
2001             join(" ", @doubles), "\n"
2002             if @doubles;
2003
2004         foreach (keys %sources) {
2005             my $dest = $_;
2006             my $ddest = cleanfile($buildd, $_, $blddir);
2007             foreach (@{$sources{$dest}}) {
2008                 my $s = cleanfile($sourced, $_, $blddir);
2009
2010                 # If it isn't in the source tree, we assume it's generated
2011                 # in the build tree
2012                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2013                     $s = cleanfile($buildd, $_, $blddir);
2014                 }
2015                 # We recognise C++, C and asm files
2016                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2017                     my $o = $_;
2018                     $o =~ s/\.[csS]$/.o/; # C and assembler
2019                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2020                     $o = cleanfile($buildd, $o, $blddir);
2021                     $unified_info{sources}->{$ddest}->{$o} = -1;
2022                     $unified_info{sources}->{$o}->{$s} = -1;
2023                 } elsif ($s =~ /\.rc$/) {
2024                     # We also recognise resource files
2025                     my $o = $_;
2026                     $o =~ s/\.rc$/.res/; # Resource configuration
2027                     my $o = cleanfile($buildd, $o, $blddir);
2028                     $unified_info{sources}->{$ddest}->{$o} = -1;
2029                     $unified_info{sources}->{$o}->{$s} = -1;
2030                 } else {
2031                     $unified_info{sources}->{$ddest}->{$s} = 1;
2032                 }
2033             }
2034         }
2035
2036         foreach (keys %shared_sources) {
2037             my $dest = $_;
2038             my $ddest = cleanfile($buildd, $_, $blddir);
2039             foreach (@{$shared_sources{$dest}}) {
2040                 my $s = cleanfile($sourced, $_, $blddir);
2041
2042                 # If it isn't in the source tree, we assume it's generated
2043                 # in the build tree
2044                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2045                     $s = cleanfile($buildd, $_, $blddir);
2046                 }
2047
2048                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2049                     # We recognise C++, C and asm files
2050                     my $o = $_;
2051                     $o =~ s/\.[csS]$/.o/; # C and assembler
2052                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2053                     $o = cleanfile($buildd, $o, $blddir);
2054                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2055                     $unified_info{sources}->{$o}->{$s} = -1;
2056                 } elsif ($s =~ /\.rc$/) {
2057                     # We also recognise resource files
2058                     my $o = $_;
2059                     $o =~ s/\.rc$/.res/; # Resource configuration
2060                     my $o = cleanfile($buildd, $o, $blddir);
2061                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2062                     $unified_info{sources}->{$o}->{$s} = -1;
2063                 } elsif ($s =~ /\.ld$/) {
2064                     # We also recognise linker scripts (or corresponding)
2065                     # We know they are generated files
2066                     my $ld = cleanfile($buildd, $_, $blddir);
2067                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2068                 } else {
2069                     die "unrecognised source file type for shared library: $s\n";
2070                 }
2071             }
2072         }
2073
2074         foreach (keys %generate) {
2075             my $dest = $_;
2076             my $ddest = cleanfile($buildd, $_, $blddir);
2077             die "more than one generator for $dest: "
2078                     ,join(" ", @{$generate{$_}}),"\n"
2079                     if scalar @{$generate{$_}} > 1;
2080             my @generator = split /\s+/, $generate{$dest}->[0];
2081             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2082             $unified_info{generate}->{$ddest} = [ @generator ];
2083         }
2084
2085         foreach (keys %depends) {
2086             my $dest = $_;
2087             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2088
2089             # If the destination doesn't exist in source, it can only be
2090             # a generated file in the build tree.
2091             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2092                 $ddest = cleanfile($buildd, $_, $blddir);
2093             }
2094             foreach (@{$depends{$dest}}) {
2095                 my $d = cleanfile($sourced, $_, $blddir);
2096
2097                 # If we know it's generated, or assume it is because we can't
2098                 # find it in the source tree, we set file we depend on to be
2099                 # in the build tree rather than the source tree, and assume
2100                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2101                 # section or in the Makefile template.
2102                 if ($d eq $src_configdata
2103                     || ! -f $d
2104                     || (grep { $d eq $_ }
2105                         map { cleanfile($srcdir, $_, $blddir) }
2106                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2107                     $d = cleanfile($buildd, $_, $blddir);
2108                 }
2109                 # Take note if the file to depend on is being renamed
2110                 # Take extra care with files ending with .a, they should
2111                 # be treated without that extension, and the extension
2112                 # should be added back after treatment.
2113                 $d =~ /(\.a)?$/;
2114                 my $e = $1 // "";
2115                 $d = $`.$e;
2116                 $unified_info{depends}->{$ddest}->{$d} = 1;
2117             }
2118         }
2119
2120         foreach (keys %includes) {
2121             my $dest = $_;
2122             my $ddest = cleanfile($sourced, $_, $blddir);
2123
2124             # If the destination doesn't exist in source, it can only be
2125             # a generated file in the build tree.
2126             if ($ddest eq $src_configdata || ! -f $ddest) {
2127                 $ddest = cleanfile($buildd, $_, $blddir);
2128             }
2129             foreach (@{$includes{$dest}}) {
2130                 my $is = cleandir($sourced, $_, $blddir);
2131                 my $ib = cleandir($buildd, $_, $blddir);
2132                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2133                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2134                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2135                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2136             }
2137         }
2138
2139         foreach (keys %defines) {
2140             my $dest = $_;
2141             my $ddest = cleanfile($sourced, $_, $blddir);
2142
2143             # If the destination doesn't exist in source, it can only be
2144             # a generated file in the build tree.
2145             if (! -f $ddest) {
2146                 $ddest = cleanfile($buildd, $_, $blddir);
2147                 if ($unified_info{rename}->{$ddest}) {
2148                     $ddest = $unified_info{rename}->{$ddest};
2149                 }
2150             }
2151             foreach (@{$defines{$dest}}) {
2152                 m|^([^=]*)(=.*)?$|;
2153                 die "0 length macro name not permitted\n" if $1 eq "";
2154                 die "$1 defined more than once\n"
2155                     if defined $unified_info{defines}->{$ddest}->{$1};
2156                 $unified_info{defines}->{$ddest}->{$1} = $2;
2157             }
2158         }
2159     }
2160
2161     my $ordinals_text = join(', ', sort keys %ordinals);
2162     warn <<"EOF" if $ordinals_text;
2163
2164 WARNING: ORDINALS were specified for $ordinals_text
2165 They are ignored and should be replaced with a combination of GENERATE,
2166 DEPEND and SHARED_SOURCE.
2167 EOF
2168
2169
2170     # Go through the sources of all libraries and check that the same basename
2171     # doesn't appear more than once.  Some static library archivers depend on
2172     # them being unique.
2173     {
2174         my $err = 0;
2175         foreach my $prod (keys %{$unified_info{libraries}}) {
2176             my @prod_sources =
2177                 map { keys %{$unified_info{sources}->{$_}} }
2178                 keys %{$unified_info{sources}->{$prod}};
2179             my %srccnt = ();
2180
2181             # Count how many times a given each source basename
2182             # appears for each product.
2183             foreach my $src (@prod_sources) {
2184                 $srccnt{basename $src}++;
2185             }
2186
2187             foreach my $src (keys %srccnt) {
2188                 if ((my $cnt = $srccnt{$src}) > 1) {
2189                     print STDERR "$src appears $cnt times for the product $prod\n";
2190                     $err++
2191                 }
2192             }
2193         }
2194         die if $err > 0;
2195     }
2196
2197     # Massage the result
2198
2199     # If we depend on a header file or a perl module, add an inclusion of
2200     # its directory to allow smoothe inclusion
2201     foreach my $dest (keys %{$unified_info{depends}}) {
2202         next if $dest eq "";
2203         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2204             next unless $d =~ /\.(h|pm)$/;
2205             my $i = dirname($d);
2206             my $spot =
2207                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2208                 ? 'build' : 'source';
2209             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2210                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2211         }
2212     }
2213
2214     # Go through all intermediary files and change their names to something that
2215     # reflects what they will be built for.  Note that for some source files,
2216     # this leads to duplicate object files because they are used multiple times.
2217     # the goal is to rename all object files according to this scheme:
2218     #    {productname}-{midfix}-{origobjname}.[o|res]
2219     # the {midfix} is a keyword indicating the type of product, which is mostly
2220     # valuable for libraries since they come in two forms.
2221     #
2222     # This also reorganises the {sources} and {shared_sources} so that the
2223     # former only contains ALL object files that are supposed to end up in
2224     # static libraries and programs, while the latter contains ALL object files
2225     # that are supposed to end up in shared libraries and DSOs.
2226     # The main reason for having two different source structures is to allow
2227     # the same name to be used for the static and the shared variants of a
2228     # library.
2229     {
2230         # Take copies so we don't get interference from added stuff
2231         my %unified_copy = ();
2232         foreach (('sources', 'shared_sources')) {
2233             $unified_copy{$_} = { %{$unified_info{$_}} }
2234                 if defined($unified_info{$_});
2235             delete $unified_info{$_};
2236         }
2237         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2238             # $intent serves multi purposes:
2239             # - give a prefix for the new object files names
2240             # - in the case of libraries, rearrange the object files so static
2241             #   libraries use the 'sources' structure exclusively, while shared
2242             #   libraries use the 'shared_sources' structure exclusively.
2243             my $intent = {
2244                 programs  => { bin    => { src => [ 'sources' ],
2245                                            dst => 'sources' } },
2246                 libraries => { lib    => { src => [ 'sources' ],
2247                                            dst => 'sources' },
2248                                shlib  => { prodselect =>
2249                                                sub { grep !/\.a$/, @_ },
2250                                            src => [ 'sources',
2251                                                     'shared_sources' ],
2252                                            dst => 'shared_sources' } },
2253                 modules   => { dso    => { src => [ 'sources' ],
2254                                            dst => 'sources' } },
2255                 scripts   => { script => { src => [ 'sources' ],
2256                                            dst => 'sources' } }
2257                } -> {$prodtype};
2258             foreach my $kind (keys %$intent) {
2259                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2260                              && $disabled{shared});
2261
2262                 my @src = @{$intent->{$kind}->{src}};
2263                 my $dst = $intent->{$kind}->{dst};
2264                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2265                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2266                     # %prod_sources has all applicable objects as keys, and
2267                     # their corresponding sources as values
2268                     my %prod_sources =
2269                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2270                         map { keys %{$unified_copy{$_}->{$prod}} }
2271                         @src;
2272                     foreach (keys %prod_sources) {
2273                         # Only affect object files and resource files,
2274                         # the others simply get a new value
2275                         # (+1 instead of -1)
2276                         if ($_ =~ /\.(o|res)$/) {
2277                             (my $prodname = $prod) =~ s|\.a$||;
2278                             my $newobj =
2279                                 catfile(dirname($_),
2280                                         basename($prodname)
2281                                             . '-' . $kind
2282                                             . '-' . basename($_));
2283                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2284                             foreach my $src (@{$prod_sources{$_}}) {
2285                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2286                             }
2287                             # Adjust dependencies
2288                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2289                                 $unified_info{depends}->{$_}->{$deps} = -1;
2290                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2291                             }
2292                             # Adjust includes
2293                             foreach my $k (('source', 'build')) {
2294                                 next unless
2295                                     defined($unified_info{includes}->{$_}->{$k});
2296                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2297                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2298                             }
2299                         } else {
2300                             $unified_info{$dst}->{$prod}->{$_} = 1;
2301                         }
2302                     }
2303                 }
2304             }
2305         }
2306     }
2307
2308     # At this point, we have a number of sources with the value -1.  They
2309     # aren't part of the local build and are probably meant for a different
2310     # platform, and can therefore be cleaned away.  That happens when making
2311     # %unified_info more efficient below.
2312
2313     ### Make unified_info a bit more efficient
2314     # One level structures
2315     foreach (("programs", "libraries", "modules", "scripts")) {
2316         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2317     }
2318     # Two level structures
2319     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2320         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2321             my @items =
2322                 sort
2323                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2324                 keys %{$unified_info{$l1}->{$l2}};
2325             if (@items) {
2326                 $unified_info{$l1}->{$l2} = [ @items ];
2327             } else {
2328                 delete $unified_info{$l1}->{$l2};
2329             }
2330         }
2331     }
2332     # Defines
2333     foreach my $dest (sort keys %{$unified_info{defines}}) {
2334         $unified_info{defines}->{$dest}
2335             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2336                 sort keys %{$unified_info{defines}->{$dest}} ];
2337     }
2338     # Includes
2339     foreach my $dest (sort keys %{$unified_info{includes}}) {
2340         if (defined($unified_info{includes}->{$dest}->{build})) {
2341             my @source_includes = ();
2342             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2343                 if defined($unified_info{includes}->{$dest}->{source});
2344             $unified_info{includes}->{$dest} =
2345                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2346             foreach my $inc (@source_includes) {
2347                 push @{$unified_info{includes}->{$dest}}, $inc
2348                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2349             }
2350         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2351             $unified_info{includes}->{$dest} =
2352                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2353         } else {
2354             delete $unified_info{includes}->{$dest};
2355         }
2356     }
2357
2358     # For convenience collect information regarding directories where
2359     # files are generated, those generated files and the end product
2360     # they end up in where applicable.  Then, add build rules for those
2361     # directories
2362     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2363                      "dso" => [ @{$unified_info{modules}} ],
2364                      "bin" => [ @{$unified_info{programs}} ],
2365                      "script" => [ @{$unified_info{scripts}} ] );
2366     foreach my $type (keys %loopinfo) {
2367         foreach my $product (@{$loopinfo{$type}}) {
2368             my %dirs = ();
2369             my $pd = dirname($product);
2370
2371             foreach (@{$unified_info{sources}->{$product} // []},
2372                      @{$unified_info{shared_sources}->{$product} // []}) {
2373                 my $d = dirname($_);
2374
2375                 # We don't want to create targets for source directories
2376                 # when building out of source
2377                 next if ($config{sourcedir} ne $config{builddir}
2378                              && $d =~ m|^\Q$config{sourcedir}\E|);
2379                 # We already have a "test" target, and the current directory
2380                 # is just silly to make a target for
2381                 next if $d eq "test" || $d eq ".";
2382
2383                 $dirs{$d} = 1;
2384                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2385                     if $d ne $pd;
2386             }
2387             foreach (keys %dirs) {
2388                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2389                     $product;
2390             }
2391         }
2392     }
2393 }
2394
2395 # For the schemes that need it, we provide the old *_obj configs
2396 # from the *_asm_obj ones
2397 foreach (grep /_(asm|aux)_src$/, keys %target) {
2398     my $src = $_;
2399     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2400     $target{$obj} = $target{$src};
2401     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2402     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2403 }
2404
2405 # Write down our configuration where it fits #########################
2406
2407 print "Creating configdata.pm\n";
2408 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2409 print OUT <<"EOF";
2410 #! $config{HASHBANGPERL}
2411
2412 package configdata;
2413
2414 use strict;
2415 use warnings;
2416
2417 use Exporter;
2418 #use vars qw(\@ISA \@EXPORT);
2419 our \@ISA = qw(Exporter);
2420 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2421
2422 EOF
2423 print OUT "our %config = (\n";
2424 foreach (sort keys %config) {
2425     if (ref($config{$_}) eq "ARRAY") {
2426         print OUT "  ", $_, " => [ ", join(", ",
2427                                            map { quotify("perl", $_) }
2428                                            @{$config{$_}}), " ],\n";
2429     } elsif (ref($config{$_}) eq "HASH") {
2430         print OUT "  ", $_, " => {";
2431         if (scalar keys %{$config{$_}} > 0) {
2432             print OUT "\n";
2433             foreach my $key (sort keys %{$config{$_}}) {
2434                 print OUT "      ",
2435                     join(" => ",
2436                          quotify("perl", $key),
2437                          defined $config{$_}->{$key}
2438                              ? quotify("perl", $config{$_}->{$key})
2439                              : "undef");
2440                 print OUT ",\n";
2441             }
2442             print OUT "  ";
2443         }
2444         print OUT "},\n";
2445     } else {
2446         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2447     }
2448 }
2449 print OUT <<"EOF";
2450 );
2451
2452 EOF
2453 print OUT "our %target = (\n";
2454 foreach (sort keys %target) {
2455     if (ref($target{$_}) eq "ARRAY") {
2456         print OUT "  ", $_, " => [ ", join(", ",
2457                                            map { quotify("perl", $_) }
2458                                            @{$target{$_}}), " ],\n";
2459     } else {
2460         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2461     }
2462 }
2463 print OUT <<"EOF";
2464 );
2465
2466 EOF
2467 print OUT "our \%available_protocols = (\n";
2468 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2469 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2470 print OUT <<"EOF";
2471 );
2472
2473 EOF
2474 print OUT "our \@disablables = (\n";
2475 foreach (@disablables) {
2476     print OUT "  ", quotify("perl", $_), ",\n";
2477 }
2478 print OUT <<"EOF";
2479 );
2480
2481 EOF
2482 print OUT "# The following come from Configure's @disablables_int\n";
2483 print OUT "our \@disablables_int = (\n";
2484 foreach (@disablables_int) {
2485     print OUT "  ", quotify("perl", $_), ",\n";
2486 }
2487 print OUT <<"EOF";
2488 );
2489
2490 EOF
2491 print OUT "our \%disabled = (\n";
2492 foreach (sort keys %disabled) {
2493     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2494 }
2495 print OUT <<"EOF";
2496 );
2497
2498 EOF
2499 print OUT "our %withargs = (\n";
2500 foreach (sort keys %withargs) {
2501     if (ref($withargs{$_}) eq "ARRAY") {
2502         print OUT "  ", $_, " => [ ", join(", ",
2503                                            map { quotify("perl", $_) }
2504                                            @{$withargs{$_}}), " ],\n";
2505     } else {
2506         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2507     }
2508 }
2509 print OUT <<"EOF";
2510 );
2511
2512 EOF
2513 if ($builder eq "unified") {
2514     my $recurse;
2515     $recurse = sub {
2516         my $indent = shift;
2517         foreach (@_) {
2518             if (ref $_ eq "ARRAY") {
2519                 print OUT " "x$indent, "[\n";
2520                 foreach (@$_) {
2521                     $recurse->($indent + 4, $_);
2522                 }
2523                 print OUT " "x$indent, "],\n";
2524             } elsif (ref $_ eq "HASH") {
2525                 my %h = %$_;
2526                 print OUT " "x$indent, "{\n";
2527                 foreach (sort keys %h) {
2528                     if (ref $h{$_} eq "") {
2529                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2530                     } else {
2531                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2532                         $recurse->($indent + 8, $h{$_});
2533                     }
2534                 }
2535                 print OUT " "x$indent, "},\n";
2536             } else {
2537                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2538             }
2539         }
2540     };
2541     print OUT "our %unified_info = (\n";
2542     foreach (sort keys %unified_info) {
2543         if (ref $unified_info{$_} eq "") {
2544             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2545         } else {
2546             print OUT " "x4, quotify("perl", $_), " =>\n";
2547             $recurse->(8, $unified_info{$_});
2548         }
2549     }
2550     print OUT <<"EOF";
2551 );
2552
2553 EOF
2554 }
2555 print OUT
2556     "# The following data is only used when this files is use as a script\n";
2557 print OUT "my \@makevars = (\n";
2558 foreach (sort keys %user) {
2559     print OUT "    '",$_,"',\n";
2560 }
2561 print OUT ");\n";
2562 print OUT "my \%disabled_info = (\n";
2563 foreach my $what (sort keys %disabled_info) {
2564     print OUT "    '$what' => {\n";
2565     foreach my $info (sort keys %{$disabled_info{$what}}) {
2566         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2567             print OUT "        $info => [ ",
2568                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2569                 " ],\n";
2570         } else {
2571             print OUT "        $info => '", $disabled_info{$what}->{$info},
2572                 "',\n";
2573         }
2574     }
2575     print OUT "    },\n";
2576 }
2577 print OUT ");\n";
2578 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2579 print OUT << 'EOF';
2580 # If run directly, we can give some answers, and even reconfigure
2581 unless (caller) {
2582     use Getopt::Long;
2583     use File::Spec::Functions;
2584     use File::Basename;
2585     use Pod::Usage;
2586
2587     my $here = dirname($0);
2588
2589     my $dump = undef;
2590     my $cmdline = undef;
2591     my $options = undef;
2592     my $target = undef;
2593     my $envvars = undef;
2594     my $makevars = undef;
2595     my $buildparams = undef;
2596     my $reconf = undef;
2597     my $verbose = undef;
2598     my $help = undef;
2599     my $man = undef;
2600     GetOptions('dump|d'                 => \$dump,
2601                'command-line|c'         => \$cmdline,
2602                'options|o'              => \$options,
2603                'target|t'               => \$target,
2604                'environment|e'          => \$envvars,
2605                'make-variables|m'       => \$makevars,
2606                'build-parameters|b'     => \$buildparams,
2607                'reconfigure|reconf|r'   => \$reconf,
2608                'verbose|v'              => \$verbose,
2609                'help'                   => \$help,
2610                'man'                    => \$man)
2611         or die "Errors in command line arguments\n";
2612
2613     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2614             || $buildparams || $reconf || $verbose || $help || $man) {
2615         print STDERR <<"_____";
2616 You must give at least one option.
2617 For more information, do '$0 --help'
2618 _____
2619         exit(2);
2620     }
2621
2622     if ($help) {
2623         pod2usage(-exitval => 0,
2624                   -verbose => 1);
2625     }
2626     if ($man) {
2627         pod2usage(-exitval => 0,
2628                   -verbose => 2);
2629     }
2630     if ($dump || $cmdline) {
2631         print "\nCommand line (with current working directory = $here):\n\n";
2632         print '    ',join(' ',
2633                           $config{PERL},
2634                           catfile($config{sourcedir}, 'Configure'),
2635                           @{$config{perlargv}}), "\n";
2636         print "\nPerl information:\n\n";
2637         print '    ',$config{perl_cmd},"\n";
2638         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2639     }
2640     if ($dump || $options) {
2641         my $longest = 0;
2642         my $longest2 = 0;
2643         foreach my $what (@disablables) {
2644             $longest = length($what) if $longest < length($what);
2645             $longest2 = length($disabled{$what})
2646                 if $disabled{$what} && $longest2 < length($disabled{$what});
2647         }
2648         print "\nEnabled features:\n\n";
2649         foreach my $what (@disablables) {
2650             print "    $what\n" unless $disabled{$what};
2651         }
2652         print "\nDisabled features:\n\n";
2653         foreach my $what (@disablables) {
2654             if ($disabled{$what}) {
2655                 print "    $what", ' ' x ($longest - length($what) + 1),
2656                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2657                 print $disabled_info{$what}->{macro}
2658                     if $disabled_info{$what}->{macro};
2659                 print ' (skip ',
2660                     join(', ', @{$disabled_info{$what}->{skipped}}),
2661                     ')'
2662                     if $disabled_info{$what}->{skipped};
2663                 print "\n";
2664             }
2665         }
2666     }
2667     if ($dump || $target) {
2668         print "\nConfig target attributes:\n\n";
2669         foreach (sort keys %target) {
2670             next if $_ =~ m|^_| || $_ eq 'template';
2671             my $quotify = sub {
2672                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2673             };
2674             print '    ', $_, ' => ';
2675             if (ref($target{$_}) eq "ARRAY") {
2676                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2677             } else {
2678                 print $quotify->($target{$_}), ",\n"
2679             }
2680         }
2681     }
2682     if ($dump || $envvars) {
2683         print "\nRecorded environment:\n\n";
2684         foreach (sort keys %{$config{perlenv}}) {
2685             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2686         }
2687     }
2688     if ($dump || $makevars) {
2689         print "\nMakevars:\n\n";
2690         foreach my $var (@makevars) {
2691             my $prefix = '';
2692             $prefix = $config{CROSS_COMPILE}
2693                 if grep { $var eq $_ } @user_crossable;
2694             $prefix //= '';
2695             print '    ',$var,' ' x (16 - length $var),'= ',
2696                 (ref $config{$var} eq 'ARRAY'
2697                  ? join(' ', @{$config{$var}})
2698                  : $prefix.$config{$var}),
2699                 "\n"
2700                 if defined $config{$var};
2701         }
2702
2703         my @buildfile = ($config{builddir}, $config{build_file});
2704         unshift @buildfile, $here
2705             unless file_name_is_absolute($config{builddir});
2706         my $buildfile = canonpath(catdir(@buildfile));
2707         print <<"_____";
2708
2709 NOTE: These variables only represent the configuration view.  The build file
2710 template may have processed these variables further, please have a look at the
2711 build file for more exact data:
2712     $buildfile
2713 _____
2714     }
2715     if ($dump || $buildparams) {
2716         my @buildfile = ($config{builddir}, $config{build_file});
2717         unshift @buildfile, $here
2718             unless file_name_is_absolute($config{builddir});
2719         print "\nbuild file:\n\n";
2720         print "    ", canonpath(catfile(@buildfile)),"\n";
2721
2722         print "\nbuild file templates:\n\n";
2723         foreach (@{$config{build_file_templates}}) {
2724             my @tmpl = ($_);
2725             unshift @tmpl, $here
2726                 unless file_name_is_absolute($config{sourcedir});
2727             print '    ',canonpath(catfile(@tmpl)),"\n";
2728         }
2729     }
2730     if ($reconf) {
2731         if ($verbose) {
2732             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2733             foreach (sort keys %{$config{perlenv}}) {
2734                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2735             }
2736         }
2737
2738         chdir $here;
2739         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2740     }
2741 }
2742
2743 1;
2744
2745 __END__
2746
2747 =head1 NAME
2748
2749 configdata.pm - configuration data for OpenSSL builds
2750
2751 =head1 SYNOPSIS
2752
2753 Interactive:
2754
2755   perl configdata.pm [options]
2756
2757 As data bank module:
2758
2759   use configdata;
2760
2761 =head1 DESCRIPTION
2762
2763 This module can be used in two modes, interactively and as a module containing
2764 all the data recorded by OpenSSL's Configure script.
2765
2766 When used interactively, simply run it as any perl script, with at least one
2767 option, and you will get the information you ask for.  See L</OPTIONS> below.
2768
2769 When loaded as a module, you get a few databanks with useful information to
2770 perform build related tasks.  The databanks are:
2771
2772     %config             Configured things.
2773     %target             The OpenSSL config target with all inheritances
2774                         resolved.
2775     %disabled           The features that are disabled.
2776     @disablables        The list of features that can be disabled.
2777     %withargs           All data given through --with-THING options.
2778     %unified_info       All information that was computed from the build.info
2779                         files.
2780
2781 =head1 OPTIONS
2782
2783 =over 4
2784
2785 =item B<--help>
2786
2787 Print a brief help message and exit.
2788
2789 =item B<--man>
2790
2791 Print the manual page and exit.
2792
2793 =item B<--dump> | B<-d>
2794
2795 Print all relevant configuration data.  This is equivalent to B<--command-line>
2796 B<--options> B<--target> B<--environment> B<--make-variables>
2797 B<--build-parameters>.
2798
2799 =item B<--command-line> | B<-c>
2800
2801 Print the current configuration command line.
2802
2803 =item B<--options> | B<-o>
2804
2805 Print the features, both enabled and disabled, and display defined macro and
2806 skipped directories where applicable.
2807
2808 =item B<--target> | B<-t>
2809
2810 Print the config attributes for this config target.
2811
2812 =item B<--environment> | B<-e>
2813
2814 Print the environment variables and their values at the time of configuration.
2815
2816 =item B<--make-variables> | B<-m>
2817
2818 Print the main make variables generated in the current configuration
2819
2820 =item B<--build-parameters> | B<-b>
2821
2822 Print the build parameters, i.e. build file and build file templates.
2823
2824 =item B<--reconfigure> | B<--reconf> | B<-r>
2825
2826 Redo the configuration.
2827
2828 =item B<--verbose> | B<-v>
2829
2830 Verbose output.
2831
2832 =back
2833
2834 =cut
2835
2836 EOF
2837 close(OUT);
2838 if ($builder_platform eq 'unix') {
2839     my $mode = (0755 & ~umask);
2840     chmod $mode, 'configdata.pm'
2841         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2842 }
2843
2844 my %builders = (
2845     unified => sub {
2846         print 'Creating ',$target{build_file},"\n";
2847         run_dofile(catfile($blddir, $target{build_file}),
2848                    @{$config{build_file_templates}});
2849     },
2850     );
2851
2852 $builders{$builder}->($builder_platform, @builder_opts);
2853
2854 $SIG{__DIE__} = $orig_death_handler;
2855
2856 print <<"EOF" if ($disabled{threads} eq "unavailable");
2857
2858 The library could not be configured for supporting multi-threaded
2859 applications as the compiler options required on this system are not known.
2860 See file INSTALL for details if you need multi-threading.
2861 EOF
2862
2863 print <<"EOF" if ($no_shared_warn);
2864
2865 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2866 platform, so we will pretend you gave the option 'no-pic', which also disables
2867 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2868 or position independent code, please let us know (but please first make sure
2869 you have tried with a current version of OpenSSL).
2870 EOF
2871
2872 print <<"EOF";
2873
2874 **********************************************************************
2875 ***                                                                ***
2876 ***   OpenSSL has been successfully configured                     ***
2877 ***                                                                ***
2878 ***   If you encounter a problem while building, please open an    ***
2879 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2880 ***   and include the output from the following command:           ***
2881 ***                                                                ***
2882 ***       perl configdata.pm --dump                                ***
2883 ***                                                                ***
2884 ***   (If you are new to OpenSSL, you might want to consult the    ***
2885 ***   'Troubleshooting' section in the INSTALL file first)         ***
2886 ***                                                                ***
2887 **********************************************************************
2888 EOF
2889
2890 exit(0);
2891
2892 ######################################################################
2893 #
2894 # Helpers and utility functions
2895 #
2896
2897 # Death handler, to print a helpful message in case of failure #######
2898 #
2899 sub death_handler {
2900     die @_ if $^S;              # To prevent the added message in eval blocks
2901     my $build_file = $target{build_file} // "build file";
2902     my @message = ( <<"_____", @_ );
2903
2904 Failure!  $build_file wasn't produced.
2905 Please read INSTALL and associated NOTES files.  You may also have to look over
2906 your available compiler tool chain or change your configuration.
2907
2908 _____
2909
2910     # Dying is terminal, so it's ok to reset the signal handler here.
2911     $SIG{__DIE__} = $orig_death_handler;
2912     die @message;
2913 }
2914
2915 # Configuration file reading #########################################
2916
2917 # Note: All of the helper functions are for lazy evaluation.  They all
2918 # return a CODE ref, which will return the intended value when evaluated.
2919 # Thus, whenever there's mention of a returned value, it's about that
2920 # intended value.
2921
2922 # Helper function to implement conditional inheritance depending on the
2923 # value of $disabled{asm}.  Used in inherit_from values as follows:
2924 #
2925 #      inherit_from => [ "template", asm("asm_tmpl") ]
2926 #
2927 sub asm {
2928     my @x = @_;
2929     sub {
2930         $disabled{asm} ? () : @x;
2931     }
2932 }
2933
2934 # Helper function to implement conditional value variants, with a default
2935 # plus additional values based on the value of $config{build_type}.
2936 # Arguments are given in hash table form:
2937 #
2938 #       picker(default => "Basic string: ",
2939 #              debug   => "debug",
2940 #              release => "release")
2941 #
2942 # When configuring with --debug, the resulting string will be
2943 # "Basic string: debug", and when not, it will be "Basic string: release"
2944 #
2945 # This can be used to create variants of sets of flags according to the
2946 # build type:
2947 #
2948 #       cflags => picker(default => "-Wall",
2949 #                        debug   => "-g -O0",
2950 #                        release => "-O3")
2951 #
2952 sub picker {
2953     my %opts = @_;
2954     return sub { add($opts{default} || (),
2955                      $opts{$config{build_type}} || ())->(); }
2956 }
2957
2958 # Helper function to combine several values of different types into one.
2959 # This is useful if you want to combine a string with the result of a
2960 # lazy function, such as:
2961 #
2962 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2963 #
2964 sub combine {
2965     my @stuff = @_;
2966     return sub { add(@stuff)->(); }
2967 }
2968
2969 # Helper function to implement conditional values depending on the value
2970 # of $disabled{threads}.  Can be used as follows:
2971 #
2972 #       cflags => combine("-Wall", threads("-pthread"))
2973 #
2974 sub threads {
2975     my @flags = @_;
2976     return sub { add($disabled{threads} ? () : @flags)->(); }
2977 }
2978
2979 sub shared {
2980     my @flags = @_;
2981     return sub { add($disabled{shared} ? () : @flags)->(); }
2982 }
2983
2984 our $add_called = 0;
2985 # Helper function to implement adding values to already existing configuration
2986 # values.  It handles elements that are ARRAYs, CODEs and scalars
2987 sub _add {
2988     my $separator = shift;
2989
2990     # If there's any ARRAY in the collection of values OR the separator
2991     # is undef, we will return an ARRAY of combined values, otherwise a
2992     # string of joined values with $separator as the separator.
2993     my $found_array = !defined($separator);
2994
2995     my @values =
2996         map {
2997             my $res = $_;
2998             while (ref($res) eq "CODE") {
2999                 $res = $res->();
3000             }
3001             if (defined($res)) {
3002                 if (ref($res) eq "ARRAY") {
3003                     $found_array = 1;
3004                     @$res;
3005                 } else {
3006                     $res;
3007                 }
3008             } else {
3009                 ();
3010             }
3011     } (@_);
3012
3013     $add_called = 1;
3014
3015     if ($found_array) {
3016         [ @values ];
3017     } else {
3018         join($separator, grep { defined($_) && $_ ne "" } @values);
3019     }
3020 }
3021 sub add_before {
3022     my $separator = " ";
3023     if (ref($_[$#_]) eq "HASH") {
3024         my $opts = pop;
3025         $separator = $opts->{separator};
3026     }
3027     my @x = @_;
3028     sub { _add($separator, @x, @_) };
3029 }
3030 sub add {
3031     my $separator = " ";
3032     if (ref($_[$#_]) eq "HASH") {
3033         my $opts = pop;
3034         $separator = $opts->{separator};
3035     }
3036     my @x = @_;
3037     sub { _add($separator, @_, @x) };
3038 }
3039
3040 sub read_eval_file {
3041     my $fname = shift;
3042     my $content;
3043     my @result;
3044
3045     open F, "< $fname" or die "Can't open '$fname': $!\n";
3046     {
3047         undef local $/;
3048         $content = <F>;
3049     }
3050     close F;
3051     {
3052         local $@;
3053
3054         @result = ( eval $content );
3055         warn $@ if $@;
3056     }
3057     return wantarray ? @result : $result[0];
3058 }
3059
3060 # configuration reader, evaluates the input file as a perl script and expects
3061 # it to fill %targets with target configurations.  Those are then added to
3062 # %table.
3063 sub read_config {
3064     my $fname = shift;
3065     my %targets;
3066
3067     {
3068         # Protect certain tables from tampering
3069         local %table = ();
3070
3071         %targets = read_eval_file($fname);
3072     }
3073     my %preexisting = ();
3074     foreach (sort keys %targets) {
3075         $preexisting{$_} = 1 if $table{$_};
3076     }
3077     die <<"EOF",
3078 The following config targets from $fname
3079 shadow pre-existing config targets with the same name:
3080 EOF
3081         map { "  $_\n" } sort keys %preexisting
3082         if %preexisting;
3083
3084
3085     # For each target, check that it's configured with a hash table.
3086     foreach (keys %targets) {
3087         if (ref($targets{$_}) ne "HASH") {
3088             if (ref($targets{$_}) eq "") {
3089                 warn "Deprecated target configuration for $_, ignoring...\n";
3090             } else {
3091                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3092             }
3093             delete $targets{$_};
3094         } else {
3095             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3096         }
3097     }
3098
3099     %table = (%table, %targets);
3100
3101 }
3102
3103 # configuration resolver.  Will only resolve all the lazy evaluation
3104 # codeblocks for the chosen target and all those it inherits from,
3105 # recursively
3106 sub resolve_config {
3107     my $target = shift;
3108     my @breadcrumbs = @_;
3109
3110 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3111
3112     if (grep { $_ eq $target } @breadcrumbs) {
3113         die "inherit_from loop!  target backtrace:\n  "
3114             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3115     }
3116
3117     if (!defined($table{$target})) {
3118         warn "Warning! target $target doesn't exist!\n";
3119         return ();
3120     }
3121     # Recurse through all inheritances.  They will be resolved on the
3122     # fly, so when this operation is done, they will all just be a
3123     # bunch of attributes with string values.
3124     # What we get here, though, are keys with references to lists of
3125     # the combined values of them all.  We will deal with lists after
3126     # this stage is done.
3127     my %combined_inheritance = ();
3128     if ($table{$target}->{inherit_from}) {
3129         my @inherit_from =
3130             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3131         foreach (@inherit_from) {
3132             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3133
3134             # 'template' is a marker that's considered private to
3135             # the config that had it.
3136             delete $inherited_config{template};
3137
3138             foreach (keys %inherited_config) {
3139                 if (!$combined_inheritance{$_}) {
3140                     $combined_inheritance{$_} = [];
3141                 }
3142                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3143             }
3144         }
3145     }
3146
3147     # We won't need inherit_from in this target any more, since we've
3148     # resolved all the inheritances that lead to this
3149     delete $table{$target}->{inherit_from};
3150
3151     # Now is the time to deal with those lists.  Here's the place to
3152     # decide what shall be done with those lists, all based on the
3153     # values of the target we're currently dealing with.
3154     # - If a value is a coderef, it will be executed with the list of
3155     #   inherited values as arguments.
3156     # - If the corresponding key doesn't have a value at all or is the
3157     #   empty string, the inherited value list will be run through the
3158     #   default combiner (below), and the result becomes this target's
3159     #   value.
3160     # - Otherwise, this target's value is assumed to be a string that
3161     #   will simply override the inherited list of values.
3162     my $default_combiner = add();
3163
3164     my %all_keys =
3165         map { $_ => 1 } (keys %combined_inheritance,
3166                          keys %{$table{$target}});
3167
3168     sub process_values {
3169         my $object    = shift;
3170         my $inherited = shift;  # Always a [ list ]
3171         my $target    = shift;
3172         my $entry     = shift;
3173
3174         $add_called = 0;
3175
3176         while(ref($object) eq "CODE") {
3177             $object = $object->(@$inherited);
3178         }
3179         if (!defined($object)) {
3180             return ();
3181         }
3182         elsif (ref($object) eq "ARRAY") {
3183             local $add_called;  # To make sure recursive calls don't affect it
3184             return [ map { process_values($_, $inherited, $target, $entry) }
3185                      @$object ];
3186         } elsif (ref($object) eq "") {
3187             return $object;
3188         } else {
3189             die "cannot handle reference type ",ref($object)
3190                 ," found in target ",$target," -> ",$entry,"\n";
3191         }
3192     }
3193
3194     foreach (sort keys %all_keys) {
3195         my $previous = $combined_inheritance{$_};
3196
3197         # Current target doesn't have a value for the current key?
3198         # Assign it the default combiner, the rest of this loop body
3199         # will handle it just like any other coderef.
3200         if (!exists $table{$target}->{$_}) {
3201             $table{$target}->{$_} = $default_combiner;
3202         }
3203
3204         $table{$target}->{$_} = process_values($table{$target}->{$_},
3205                                                $combined_inheritance{$_},
3206                                                $target, $_);
3207         unless(defined($table{$target}->{$_})) {
3208             delete $table{$target}->{$_};
3209         }
3210 #        if ($extra_checks &&
3211 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3212 #            warn "$_ got replaced in $target\n";
3213 #        }
3214     }
3215
3216     # Finally done, return the result.
3217     return %{$table{$target}};
3218 }
3219
3220 sub usage
3221         {
3222         print STDERR $usage;
3223         print STDERR "\npick os/compiler from:\n";
3224         my $j=0;
3225         my $i;
3226         my $k=0;
3227         foreach $i (sort keys %table)
3228                 {
3229                 next if $table{$i}->{template};
3230                 next if $i =~ /^debug/;
3231                 $k += length($i) + 1;
3232                 if ($k > 78)
3233                         {
3234                         print STDERR "\n";
3235                         $k=length($i);
3236                         }
3237                 print STDERR $i . " ";
3238                 }
3239         foreach $i (sort keys %table)
3240                 {
3241                 next if $table{$i}->{template};
3242                 next if $i !~ /^debug/;
3243                 $k += length($i) + 1;
3244                 if ($k > 78)
3245                         {
3246                         print STDERR "\n";
3247                         $k=length($i);
3248                         }
3249                 print STDERR $i . " ";
3250                 }
3251         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3252         exit(1);
3253         }
3254
3255 sub run_dofile
3256 {
3257     my $out = shift;
3258     my @templates = @_;
3259
3260     unlink $out || warn "Can't remove $out, $!"
3261         if -f $out;
3262     foreach (@templates) {
3263         die "Can't open $_, $!" unless -f $_;
3264     }
3265     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3266     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3267     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3268     system($cmd);
3269     exit 1 if $? != 0;
3270     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3271 }
3272
3273 sub compiler_predefined {
3274     state %predefined;
3275     my $cc = shift;
3276
3277     return () if $^O eq 'VMS';
3278
3279     die 'compiler_predefined called without a compiler command'
3280         unless $cc;
3281
3282     if (! $predefined{$cc}) {
3283
3284         $predefined{$cc} = {};
3285
3286         # collect compiler pre-defines from gcc or gcc-alike...
3287         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3288         while (my $l = <PIPE>) {
3289             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3290             $predefined{$cc}->{$1} = $2 // '';
3291         }
3292         close(PIPE);
3293     }
3294
3295     return %{$predefined{$cc}};
3296 }
3297
3298 sub which
3299 {
3300     my ($name)=@_;
3301
3302     if (eval { require IPC::Cmd; 1; }) {
3303         IPC::Cmd->import();
3304         return scalar IPC::Cmd::can_run($name);
3305     } else {
3306         # if there is $directories component in splitpath,
3307         # then it's not something to test with $PATH...
3308         return $name if (File::Spec->splitpath($name))[1];
3309
3310         foreach (File::Spec->path()) {
3311             my $fullpath = catfile($_, "$name$target{exe_extension}");
3312             if (-f $fullpath and -x $fullpath) {
3313                 return $fullpath;
3314             }
3315         }
3316     }
3317 }
3318
3319 sub env
3320 {
3321     my $name = shift;
3322     my %opts = @_;
3323
3324     unless ($opts{cacheonly}) {
3325         # Note that if $ENV{$name} doesn't exist or is undefined,
3326         # $config{perlenv}->{$name} will be created with the value
3327         # undef.  This is intentional.
3328
3329         $config{perlenv}->{$name} = $ENV{$name}
3330             if ! exists $config{perlenv}->{$name};
3331     }
3332     return $config{perlenv}->{$name};
3333 }
3334
3335 # Configuration printer ##############################################
3336
3337 sub print_table_entry
3338 {
3339     local $now_printing = shift;
3340     my %target = resolve_config($now_printing);
3341     my $type = shift;
3342
3343     # Don't print the templates
3344     return if $target{template};
3345
3346     my @sequence = (
3347         "sys_id",
3348         "cpp",
3349         "cppflags",
3350         "defines",
3351         "includes",
3352         "cc",
3353         "cflags",
3354         "unistd",
3355         "ld",
3356         "lflags",
3357         "loutflag",
3358         "ex_libs",
3359         "bn_ops",
3360         "rc4_asm_src",
3361         "rmd160_asm_src",
3362         "rc5_asm_src",
3363         "wp_asm_src",
3364         "cmll_asm_src",
3365         "modes_asm_src",
3366         "padlock_asm_src",
3367         "chacha_asm_src",
3368         "poly1035_asm_src",
3369         "thread_scheme",
3370         "perlasm_scheme",
3371         "dso_scheme",
3372         "shared_target",
3373         "shared_cflag",
3374         "shared_defines",
3375         "shared_ldflag",
3376         "shared_rcflag",
3377         "shared_extension",
3378         "dso_extension",
3379         "obj_extension",
3380         "exe_extension",
3381         "ranlib",
3382         "ar",
3383         "arflags",
3384         "aroutflag",
3385         "rc",
3386         "rcflags",
3387         "rcoutflag",
3388         "mt",
3389         "mtflags",
3390         "mtinflag",
3391         "mtoutflag",
3392         "multilib",
3393         "build_scheme",
3394         );
3395
3396     if ($type eq "TABLE") {
3397         print "\n";
3398         print "*** $now_printing\n";
3399         foreach (@sequence) {
3400             if (ref($target{$_}) eq "ARRAY") {
3401                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3402             } else {
3403                 printf "\$%-12s = %s\n", $_, $target{$_};
3404             }
3405         }
3406     } elsif ($type eq "HASH") {
3407         my $largest =
3408             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3409         print "    '$now_printing' => {\n";
3410         foreach (@sequence) {
3411             if ($target{$_}) {
3412                 if (ref($target{$_}) eq "ARRAY") {
3413                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3414                 } else {
3415                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3416                 }
3417             }
3418         }
3419         print "    },\n";
3420     }
3421 }
3422
3423 # Utility routines ###################################################
3424
3425 # On VMS, if the given file is a logical name, File::Spec::Functions
3426 # will consider it an absolute path.  There are cases when we want a
3427 # purely syntactic check without checking the environment.
3428 sub isabsolute {
3429     my $file = shift;
3430
3431     # On non-platforms, we just use file_name_is_absolute().
3432     return file_name_is_absolute($file) unless $^O eq "VMS";
3433
3434     # If the file spec includes a device or a directory spec,
3435     # file_name_is_absolute() is perfectly safe.
3436     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3437
3438     # Here, we know the given file spec isn't absolute
3439     return 0;
3440 }
3441
3442 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3443 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3444 # realpath() requires that at least all path components except the last is an
3445 # existing directory.  On VMS, the last component of the directory spec must
3446 # exist.
3447 sub absolutedir {
3448     my $dir = shift;
3449
3450     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3451     # will return the volume name for the device, no matter what.  Also,
3452     # it will return an incorrect directory spec if the argument is a
3453     # directory that doesn't exist.
3454     if ($^O eq "VMS") {
3455         return rel2abs($dir);
3456     }
3457
3458     # We use realpath() on Unix, since no other will properly clean out
3459     # a directory spec.
3460     use Cwd qw/realpath/;
3461
3462     return realpath($dir);
3463 }
3464
3465 sub quotify {
3466     my %processors = (
3467         perl    => sub { my $x = shift;
3468                          $x =~ s/([\\\$\@"])/\\$1/g;
3469                          return '"'.$x.'"'; },
3470         maybeshell => sub { my $x = shift;
3471                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3472                             if ($x ne $y || $x =~ m|\s|) {
3473                                 return '"'.$y.'"';
3474                             } else {
3475                                 return $x;
3476                             }
3477                         },
3478         );
3479     my $for = shift;
3480     my $processor =
3481         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3482
3483     return map { $processor->($_); } @_;
3484 }
3485
3486 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3487 # $filename is a file name to read from
3488 # $line_concat_cond_re is a regexp detecting a line continuation ending
3489 # $line_concat is a CODEref that takes care of concatenating two lines
3490 sub collect_from_file {
3491     my $filename = shift;
3492     my $line_concat_cond_re = shift;
3493     my $line_concat = shift;
3494
3495     open my $fh, $filename || die "unable to read $filename: $!\n";
3496     return sub {
3497         my $saved_line = "";
3498         $_ = "";
3499         while (<$fh>) {
3500             s|\R$||;
3501             if (defined $line_concat) {
3502                 $_ = $line_concat->($saved_line, $_);
3503                 $saved_line = "";
3504             }
3505             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3506                 $saved_line = $_;
3507                 next;
3508             }
3509             return $_;
3510         }
3511         die "$filename ending with continuation line\n" if $_;
3512         close $fh;
3513         return undef;
3514     }
3515 }
3516
3517 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3518 # $array is an ARRAYref of lines
3519 # $line_concat_cond_re is a regexp detecting a line continuation ending
3520 # $line_concat is a CODEref that takes care of concatenating two lines
3521 sub collect_from_array {
3522     my $array = shift;
3523     my $line_concat_cond_re = shift;
3524     my $line_concat = shift;
3525     my @array = (@$array);
3526
3527     return sub {
3528         my $saved_line = "";
3529         $_ = "";
3530         while (defined($_ = shift @array)) {
3531             s|\R$||;
3532             if (defined $line_concat) {
3533                 $_ = $line_concat->($saved_line, $_);
3534                 $saved_line = "";
3535             }
3536             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3537                 $saved_line = $_;
3538                 next;
3539             }
3540             return $_;
3541         }
3542         die "input text ending with continuation line\n" if $_;
3543         return undef;
3544     }
3545 }
3546
3547 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3548 # $lineiterator is a CODEref that delivers one line at a time.
3549 # All following arguments are regex/CODEref pairs, where the regexp detects a
3550 # line and the CODEref does something with the result of the regexp.
3551 sub collect_information {
3552     my $lineiterator = shift;
3553     my %collectors = @_;
3554
3555     while(defined($_ = $lineiterator->())) {
3556         s|\R$||;
3557         my $found = 0;
3558         if ($collectors{"BEFORE"}) {
3559             $collectors{"BEFORE"}->($_);
3560         }
3561         foreach my $re (keys %collectors) {
3562             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3563                 $collectors{$re}->($lineiterator);
3564                 $found = 1;
3565             };
3566         }
3567         if ($collectors{"OTHERWISE"}) {
3568             $collectors{"OTHERWISE"}->($lineiterator, $_)
3569                 unless $found || !defined $collectors{"OTHERWISE"};
3570         }
3571         if ($collectors{"AFTER"}) {
3572             $collectors{"AFTER"}->($_);
3573         }
3574     }
3575 }
3576
3577 # tokenize($line)
3578 # tokenize($line,$separator)
3579 # $line is a line of text to split up into tokens
3580 # $separator [optional] is a regular expression that separates the tokens,
3581 # the default being spaces.  Do not use quotes of any kind as separators,
3582 # that will give undefined results.
3583 # Returns a list of tokens.
3584 #
3585 # Tokens are divided by separator (spaces by default).  If the tokens include
3586 # the separators, they have to be quoted with single or double quotes.
3587 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3588 # with backslash.
3589 # Basically, the same quoting rules apply for " and ' as in any
3590 # Unix shell.
3591 sub tokenize {
3592     my $line = my $debug_line = shift;
3593     my $separator = shift // qr|\s+|;
3594     my @result = ();
3595
3596     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3597         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3598     }
3599
3600     while ($line =~ s|^${separator}||, $line ne "") {
3601         my $token = "";
3602     again:
3603         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3604         $token .= $1;
3605         $line = $2.$';
3606
3607         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3608             $token .= $1;
3609             $line = $';
3610             goto again;
3611         } elsif ($line =~ m/^'([^']*)'/) {
3612             $token .= $1;
3613             $line = $';
3614             goto again;
3615         }
3616         push @result, $token;
3617     }
3618
3619     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3620         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3621         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3622     }
3623     return @result;
3624 }