Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2017 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 require 5.10.0;
  13 use strict;
  14 use Config;
  15 use File::Basename;
  16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  17 use File::Path qw/mkpath/;
  18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  19
  20 # see INSTALL for instructions.
  21
  22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  23
  24 # Options:
  25 #
  26 # --config      add the given configuration file, which will be read after
  27 #               any "Configurations*" files that are found in the same
  28 #               directory as this script.
  29 # --prefix      prefix for the OpenSSL installation, which includes the
  30 #               directories bin, lib, include, share/man, share/doc/openssl
  31 #               This becomes the value of INSTALLTOP in Makefile
  32 #               (Default: /usr/local)
  33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  34 #               If it's a relative directory, it will be added on the directory
  35 #               given with --prefix.
  36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  37 #               (Default: PREFIX/ssl)
  38 #
  39 # --cross-compile-prefix Add specified prefix to binutils components.
  40 #
  41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  42 #               interfaces deprecated as of the specified OpenSSL version.
  43 #
  44 # no-hw-xxx     do not compile support for specific crypto hardware.
  45 #               Generic OpenSSL-style methods relating to this support
  46 #               are always compiled but return NULL if the hardware
  47 #               support isn't compiled.
  48 # no-hw         do not compile support for any crypto hardware.
  49 # [no-]threads  [don't] try to create a library that is suitable for
  50 #               multithreaded applications (default is "threads" if we
  51 #               know how to do it)
  52 # [no-]shared   [don't] try to create shared libraries when supported.
  53 # [no-]pic      [don't] try to build position independent code when supported.
  54 #               If disabled, it also disables shared and dynamic-engine.
  55 # no-asm        do not use assembler
  56 # no-dso        do not compile in any native shared-library methods. This
  57 #               will ensure that all methods just return NULL.
  58 # no-egd        do not compile support for the entropy-gathering daemon APIs
  59 # [no-]zlib     [don't] compile support for zlib compression.
  60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  61 #               library and will be loaded in run-time by the OpenSSL library.
  62 # sctp          include SCTP support
  63 # enable-weak-ssl-ciphers
  64 #               Enable weak ciphers that are disabled by default. This currently
  65 #               only includes RC4 based ciphers.
  66 # 386           generate 80386 code in assembly modules
  67 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  68 #               mentioned '386' option implies this one
  69 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  70 # -<xxx> +<xxx> compiler options are passed through
  71 # -static       while -static is also a pass-through compiler option (and
  72 #               as such is limited to environments where it's actually
  73 #               meaningful), it triggers a number configuration options,
  74 #               namely no-dso, no-pic, no-shared and no-threads. It is
  75 #               argued that the only reason to produce statically linked
  76 #               binaries (and in context it means executables linked with
  77 #               -static flag, and not just executables linked with static
  78 #               libcrypto.a) is to eliminate dependency on specific run-time,
  79 #               a.k.a. libc version. The mentioned config options are meant
  80 #               to achieve just that. Unfortunately on Linux it's impossible
  81 #               to eliminate the dependency completely for openssl executable
  82 #               because of getaddrinfo and gethostbyname calls, which can
  83 #               invoke dynamically loadable library facility anyway to meet
  84 #               the lookup requests. For this reason on Linux statically
  85 #               linked openssl executable has rather debugging value than
  86 #               production quality.
  87 #
  88 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  89 #               provided to stack calls. Generates unique stack functions for
  90 #               each possible stack type.
  91 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  92 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  93 # Following are set automatically by this script
  94 #
  95 # MD5_ASM       use some extra md5 assembler,
  96 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  97 # RMD160_ASM    use some extra ripemd160 assembler,
  98 # SHA256_ASM    sha256_block is implemented in assembler
  99 # SHA512_ASM    sha512_block is implemented in assembler
 100 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 101
 102 # Minimum warning options... any contributions to OpenSSL should at least get
 103 # past these.
 104
 105 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 106 # -DPEDANTIC complements -pedantic and is meant to mask code that
 107 # is not strictly standard-compliant and/or implementation-specific,
 108 # e.g. inline assembly, disregards to alignment requirements, such
 109 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 110 # to be used even in sanitized builds, because sanitizer too is
 111 # supposed to and does take notice of non-standard behaviour. Then
 112 # -pedantic with pre-C9x compiler would also complain about 'long
 113 # long' not being supported. As 64-bit algorithms are common now,
 114 # it grew impossible to resolve this without sizeable additional
 115 # code, so we just tell compiler to be pedantic about everything
 116 # but 'long long' type.
 117
 118 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 119         . " -Wswitch"
 120         . " -DPEDANTIC -pedantic -Wno-long-long"
 121         . " -Wall"
 122         . " -Wsign-compare"
 123         . " -Wmissing-prototypes"
 124         . " -Wshadow"
 125         . " -Wformat"
 126         . " -Wtype-limits"
 127         . " -Wundef"
 128         . " -Werror"
 129         ;
 130
 131 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 132 # TODO(openssl-team): fix problems and investigate if (at least) the
 133 # following warnings can also be enabled:
 134 #       -Wcast-align
 135 #       -Wunreachable-code -- no, too ugly/compiler-specific
 136 #       -Wlanguage-extension-token -- no, we use asm()
 137 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 138 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 139 my $clang_devteam_warn = ""
 140         . " -Qunused-arguments"
 141         . " -Wextra"
 142         . " -Wswitch -Wswitch-default"
 143         . " -Wno-unused-parameter"
 144         . " -Wno-parentheses-equality"
 145         . " -Wno-missing-field-initializers"
 146         . " -Wno-language-extension-token"
 147         . " -Wno-extended-offsetof"
 148         . " -Wconditional-uninitialized"
 149         . " -Wincompatible-pointer-types-discards-qualifiers"
 150         . " -Wmissing-variable-declarations"
 151         . " -Wundef"
 152         ;
 153
 154 # This adds backtrace information to the memory leak info.  Is only used
 155 # when crypto-mdebug-backtrace is enabled.
 156 my $memleak_devteam_backtrace = "-rdynamic";
 157
 158 my $strict_warnings = 0;
 159
 160 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 161 # which would cover all BSD flavors. -pthread applies to them all,
 162 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 163 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 164 # which has to be accompanied by explicit -D_THREAD_SAFE and
 165 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 166 # seems to be sufficient?
 167 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 168
 169 #
 170 # API compatibility name to version number mapping.
 171 #
 172 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 173 my $apitable = {
 174     "1.1.0" => "0x10100000L",
 175     "1.0.0" => "0x10000000L",
 176     "0.9.8" => "0x00908000L",
 177 };
 178
 179 our %table = ();
 180 our %config = ();
 181 our %withargs = ();
 182
 183 # Forward declarations ###############################################
 184
 185 # read_config(filename)
 186 #
 187 # Reads a configuration file and populates %table with the contents
 188 # (which the configuration file places in %targets).
 189 sub read_config;
 190
 191 # resolve_config(target)
 192 #
 193 # Resolves all the late evaluations, inheritances and so on for the
 194 # chosen target and any target it inherits from.
 195 sub resolve_config;
 196
 197
 198 # Information collection #############################################
 199
 200 # Unified build supports separate build dir
 201 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 202 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 203 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 204
 205 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 206
 207 $config{sourcedir} = abs2rel($srcdir);
 208 $config{builddir} = abs2rel($blddir);
 209
 210 # Collect reconfiguration information if needed
 211 my @argvcopy=@ARGV;
 212
 213 if (grep /^reconf(igure)?$/, @argvcopy) {
 214     if (-f "./configdata.pm") {
 215         my $file = "./configdata.pm";
 216         unless (my $return = do $file) {
 217             die "couldn't parse $file: $@" if $@;
 218             die "couldn't do $file: $!"    unless defined $return;
 219             die "couldn't run $file"       unless $return;
 220         }
 221
 222         @argvcopy = defined($configdata::config{perlargv}) ?
 223             @{$configdata::config{perlargv}} : ();
 224         die "Incorrect data to reconfigure, please do a normal configuration\n"
 225             if (grep(/^reconf/,@argvcopy));
 226         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 227             if defined($configdata::config{cross_compile_prefix});
 228         $ENV{CC} = $configdata::config{cc}
 229             if defined($configdata::config{cc});
 230         $ENV{CXX} = $configdata::config{cxx}
 231             if defined($configdata::config{cxx});
 232         $ENV{BUILDFILE} = $configdata::config{build_file}
 233             if defined($configdata::config{build_file});
 234         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 235             if defined($configdata::config{local_config_dir});
 236
 237         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 238         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 239             if $ENV{CROSS_COMPILE};
 240         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 241         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
 242         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 243         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 244             if $ENV{$local_config_envname};
 245     } else {
 246         die "Insufficient data to reconfigure, please do a normal configuration\n";
 247     }
 248 }
 249
 250 $config{perlargv} = [ @argvcopy ];
 251
 252 # Collect version numbers
 253 $config{version} = "unknown";
 254 $config{version_num} = "unknown";
 255 $config{shlib_version_number} = "unknown";
 256 $config{shlib_version_history} = "unknown";
 257
 258 collect_information(
 259     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 260     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 261     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 262     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 263     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 264     );
 265 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 266
 267 ($config{major}, $config{minor})
 268     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 269 ($config{shlib_major}, $config{shlib_minor})
 270     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 271 die "erroneous version information in opensslv.h: ",
 272     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 273     if ($config{major} eq "" || $config{minor} eq ""
 274         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 275
 276 # Collect target configurations
 277
 278 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 279 foreach (sort glob($pattern)) {
 280     &read_config($_);
 281 }
 282
 283 if (defined $ENV{$local_config_envname}) {
 284     if ($^O eq 'VMS') {
 285         # VMS environment variables are logical names,
 286         # which can be used as is
 287         $pattern = $local_config_envname . ':' . '*.conf';
 288     } else {
 289         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 290     }
 291
 292     foreach (sort glob($pattern)) {
 293         &read_config($_);
 294     }
 295 }
 296
 297
 298 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 299
 300 $config{prefix}="";
 301 $config{openssldir}="";
 302 $config{processor}="";
 303 $config{libdir}="";
 304 $config{cross_compile_prefix}="";
 305 my $auto_threads=1;    # enable threads automatically? true by default
 306 my $default_ranlib;
 307
 308 # Top level directories to build
 309 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 310 # crypto/ subdirectories to build
 311 $config{sdirs} = [
 312     "objects",
 313     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash",
 314     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "chacha", "modes",
 315     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 316     "buffer", "bio", "stack", "lhash", "rand", "err",
 317     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 318     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 319     ];
 320 # test/ subdirectories to build
 321 $config{tdirs} = [ "ossl_shim" ];
 322
 323 # Known TLS and DTLS protocols
 324 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 325 my @dtls = qw(dtls1 dtls1_2);
 326
 327 # Explicitly known options that are possible to disable.  They can
 328 # be regexps, and will be used like this: /^no-${option}$/
 329 # For developers: keep it sorted alphabetically
 330
 331 my @disablables = (
 332     "afalgeng",
 333     "aria",
 334     "asan",
 335     "asm",
 336     "async",
 337     "autoalginit",
 338     "autoerrinit",
 339     "bf",
 340     "blake2",
 341     "camellia",
 342     "capieng",
 343     "cast",
 344     "chacha",
 345     "cmac",
 346     "cms",
 347     "comp",
 348     "crypto-mdebug",
 349     "crypto-mdebug-backtrace",
 350     "ct",
 351     "deprecated",
 352     "des",
 353     "dgram",
 354     "dh",
 355     "dsa",
 356     "dso",
 357     "dtls",
 358     "dynamic-engine",
 359     "ec",
 360     "ec2m",
 361     "ecdh",
 362     "ecdsa",
 363     "ec_nistp_64_gcc_128",
 364     "egd",
 365     "engine",
 366     "err",
 367     "external-tests",
 368     "filenames",
 369     "fuzz-libfuzzer",
 370     "fuzz-afl",
 371     "gost",
 372     "heartbeats",
 373     "hw(-.+)?",
 374     "idea",
 375     "makedepend",
 376     "md2",
 377     "md4",
 378     "mdc2",
 379     "msan",
 380     "multiblock",
 381     "nextprotoneg",
 382     "ocb",
 383     "ocsp",
 384     "pic",
 385     "poly1305",
 386     "posix-io",
 387     "psk",
 388     "rc2",
 389     "rc4",
 390     "rc5",
 391     "rdrand",
 392     "rfc3779",
 393     "rmd160",
 394     "scrypt",
 395     "sctp",
 396     "seed",
 397     "shared",
 398     "siphash",
 399     "sock",
 400     "srp",
 401     "srtp",
 402     "sse2",
 403     "ssl",
 404     "ssl-trace",
 405     "static-engine",
 406     "stdio",
 407     "tests",
 408     "threads",
 409     "tls",
 410     "ts",
 411     "ubsan",
 412     "ui",
 413     "unit-test",
 414     "whirlpool",
 415     "weak-ssl-ciphers",
 416     "zlib",
 417     "zlib-dynamic",
 418     );
 419 foreach my $proto ((@tls, @dtls))
 420         {
 421         push(@disablables, $proto);
 422         push(@disablables, "$proto-method");
 423         }
 424
 425 my %deprecated_disablables = (
 426     "ssl2" => undef,
 427     "buf-freelists" => undef,
 428     "ripemd" => "rmd160"
 429     );
 430
 431 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 432
 433 our %disabled = ( # "what"         => "comment"
 434                   "aria"                => "default",
 435                   "asan"                => "default",
 436                   "crypto-mdebug"       => "default",
 437                   "crypto-mdebug-backtrace" => "default",
 438                   "ec_nistp_64_gcc_128" => "default",
 439                   "egd"                 => "default",
 440                   "external-tests"      => "default",
 441                   "fuzz-libfuzzer"      => "default",
 442                   "fuzz-afl"            => "default",
 443                   "heartbeats"          => "default",
 444                   "md2"                 => "default",
 445                   "msan"                => "default",
 446                   "rc5"                 => "default",
 447                   "sctp"                => "default",
 448                   "ssl-trace"           => "default",
 449                   "ssl3"                => "default",
 450                   "ssl3-method"         => "default",
 451                   "ubsan"               => "default",
 452           #TODO(TLS1.3): Temporarily disabled while this is a WIP
 453                   "tls1_3"              => "default",
 454                   "unit-test"           => "default",
 455                   "weak-ssl-ciphers"    => "default",
 456                   "zlib"                => "default",
 457                   "zlib-dynamic"        => "default",
 458                 );
 459
 460 # Note: => pair form used for aesthetics, not to truly make a hash table
 461 my @disable_cascades = (
 462     # "what"            => [ "cascade", ... ]
 463     sub { $config{processor} eq "386" }
 464                         => [ "sse2" ],
 465     "ssl"               => [ "ssl3" ],
 466     "ssl3-method"       => [ "ssl3" ],
 467     "zlib"              => [ "zlib-dynamic" ],
 468     "des"               => [ "mdc2" ],
 469     "ec"                => [ "ecdsa", "ecdh" ],
 470
 471     "dgram"             => [ "dtls", "sctp" ],
 472     "sock"              => [ "dgram" ],
 473     "dtls"              => [ @dtls ],
 474     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 475                         => [ "dtls" ],
 476
 477     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 478     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 479     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 480
 481     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 482     sub { $disabled{rsa}
 483           && ($disabled{dsa} || $disabled{dh}); }
 484                         => [ "ssl" ],
 485
 486     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 487     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 488     # (XXX: We don't support PSK-only builds).
 489     sub { $disabled{rsa}
 490           && ($disabled{dsa} || $disabled{dh})
 491           && ($disabled{ecdsa} || $disabled{ecdh}); }
 492                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
 493                              "dtls1", "dtls1_2" ],
 494
 495     "tls"               => [ @tls ],
 496     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 497                         => [ "tls" ],
 498
 499     # SRP and HEARTBEATS require TLSEXT
 500     "tlsext"            => [ "srp", "heartbeats" ],
 501
 502     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 503
 504     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 505     "dso"               => [ "dynamic-engine" ],
 506
 507     # Without position independent code, there can be no shared libraries or DSOs
 508     "pic"               => [ "shared" ],
 509     "shared"            => [ "dynamic-engine" ],
 510     "engine"            => [ "afalgeng" ],
 511
 512     # no-autoalginit is only useful when building non-shared
 513     "autoalginit"       => [ "shared", "apps" ],
 514
 515     "stdio"             => [ "apps", "capieng" ],
 516     "apps"              => [ "tests" ],
 517     "comp"              => [ "zlib" ],
 518     "ec"                => [ "tls1_3" ],
 519     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 520
 521     sub { !$disabled{"msan"} } => [ "asm" ],
 522     );
 523
 524 # Avoid protocol support holes.  Also disable all versions below N, if version
 525 # N is disabled while N+1 is enabled.
 526 #
 527 my @list = (reverse @tls);
 528 while ((my $first, my $second) = (shift @list, shift @list)) {
 529     last unless @list;
 530     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 531                               => [ @list ] );
 532     unshift @list, $second;
 533 }
 534 my @list = (reverse @dtls);
 535 while ((my $first, my $second) = (shift @list, shift @list)) {
 536     last unless @list;
 537     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 538                               => [ @list ] );
 539     unshift @list, $second;
 540 }
 541
 542 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 543 # To remove something from %disabled, use "enable-foo".
 544 # For symmetry, "disable-foo" is a synonym for "no-foo".
 545
 546 my $no_sse2=0;
 547
 548 &usage if ($#ARGV < 0);
 549
 550 my $user_cflags="";
 551 my @user_defines=();
 552 $config{openssl_api_defines}=[];
 553 $config{openssl_algorithm_defines}=[];
 554 $config{openssl_thread_defines}=[];
 555 $config{openssl_sys_defines}=[];
 556 $config{openssl_other_defines}=[];
 557 my $libs="";
 558 my $target="";
 559 $config{options}="";
 560 $config{build_type} = "release";
 561
 562 my %unsupported_options = ();
 563 my %deprecated_options = ();
 564 while (@argvcopy)
 565         {
 566         $_ = shift @argvcopy;
 567         # VMS is a case insensitive environment, and depending on settings
 568         # out of our control, we may receive options uppercased.  Let's
 569         # downcase at least the part before any equal sign.
 570         if ($^O eq "VMS")
 571                 {
 572                 s/^([^=]*)/lc($1)/e;
 573                 }
 574         s /^-no-/no-/; # some people just can't read the instructions
 575
 576         # rewrite some options in "enable-..." form
 577         s /^-?-?shared$/enable-shared/;
 578         s /^sctp$/enable-sctp/;
 579         s /^threads$/enable-threads/;
 580         s /^zlib$/enable-zlib/;
 581         s /^zlib-dynamic$/enable-zlib-dynamic/;
 582
 583         if (/^(no|disable|enable)-(.+)$/)
 584                 {
 585                 my $word = $2;
 586                 if (!exists $deprecated_disablables{$word}
 587                         && !grep { $word =~ /^${_}$/ } @disablables)
 588                         {
 589                         $unsupported_options{$_} = 1;
 590                         next;
 591                         }
 592                 }
 593         if (/^no-(.+)$/ || /^disable-(.+)$/)
 594                 {
 595                 foreach my $proto ((@tls, @dtls))
 596                         {
 597                         if ($1 eq "$proto-method")
 598                                 {
 599                                 $disabled{"$proto"} = "option($proto-method)";
 600                                 last;
 601                                 }
 602                         }
 603                 if ($1 eq "dtls")
 604                         {
 605                         foreach my $proto (@dtls)
 606                                 {
 607                                 $disabled{$proto} = "option(dtls)";
 608                                 }
 609                         $disabled{"dtls"} = "option(dtls)";
 610                         }
 611                 elsif ($1 eq "ssl")
 612                         {
 613                         # Last one of its kind
 614                         $disabled{"ssl3"} = "option(ssl)";
 615                         }
 616                 elsif ($1 eq "tls")
 617                         {
 618                         # XXX: Tests will fail if all SSL/TLS
 619                         # protocols are disabled.
 620                         foreach my $proto (@tls)
 621                                 {
 622                                 $disabled{$proto} = "option(tls)";
 623                                 }
 624                         }
 625                 elsif ($1 eq "static-engine")
 626                         {
 627                         delete $disabled{"dynamic-engine"};
 628                         }
 629                 elsif ($1 eq "dynamic-engine")
 630                         {
 631                         $disabled{"dynamic-engine"} = "option";
 632                         }
 633                 elsif (exists $deprecated_disablables{$1})
 634                         {
 635                         $deprecated_options{$_} = 1;
 636                         if (defined $deprecated_disablables{$1})
 637                                 {
 638                                 $disabled{$deprecated_disablables{$1}} = "option";
 639                                 }
 640                         }
 641                 else
 642                         {
 643                         $disabled{$1} = "option";
 644                         }
 645                 # No longer an automatic choice
 646                 $auto_threads = 0 if ($1 eq "threads");
 647                 }
 648         elsif (/^enable-(.+)$/)
 649                 {
 650                 if ($1 eq "static-engine")
 651                         {
 652                         $disabled{"dynamic-engine"} = "option";
 653                         }
 654                 elsif ($1 eq "dynamic-engine")
 655                         {
 656                         delete $disabled{"dynamic-engine"};
 657                         }
 658                 elsif ($1 eq "zlib-dynamic")
 659                         {
 660                         delete $disabled{"zlib"};
 661                         }
 662                 my $algo = $1;
 663                 delete $disabled{$algo};
 664
 665                 # No longer an automatic choice
 666                 $auto_threads = 0 if ($1 eq "threads");
 667                 }
 668         elsif (/^--strict-warnings$/)
 669                 {
 670                 $strict_warnings = 1;
 671                 }
 672         elsif (/^--debug$/)
 673                 {
 674                 $config{build_type} = "debug";
 675                 }
 676         elsif (/^--release$/)
 677                 {
 678                 $config{build_type} = "release";
 679                 }
 680         elsif (/^386$/)
 681                 { $config{processor}=386; }
 682         elsif (/^fips$/)
 683                 {
 684                 die "FIPS mode not supported\n";
 685                 }
 686         elsif (/^rsaref$/)
 687                 {
 688                 # No RSAref support any more since it's not needed.
 689                 # The check for the option is there so scripts aren't
 690                 # broken
 691                 }
 692         elsif (/^nofipscanistercheck$/)
 693                 {
 694                 die "FIPS mode not supported\n";
 695                 }
 696         elsif (/^[-+]/)
 697                 {
 698                 if (/^--prefix=(.*)$/)
 699                         {
 700                         $config{prefix}=$1;
 701                         die "Directory given with --prefix MUST be absolute\n"
 702                                 unless file_name_is_absolute($config{prefix});
 703                         }
 704                 elsif (/^--api=(.*)$/)
 705                         {
 706                         $config{api}=$1;
 707                         }
 708                 elsif (/^--libdir=(.*)$/)
 709                         {
 710                         $config{libdir}=$1;
 711                         }
 712                 elsif (/^--openssldir=(.*)$/)
 713                         {
 714                         $config{openssldir}=$1;
 715                         }
 716                 elsif (/^--with-zlib-lib=(.*)$/)
 717                         {
 718                         $withargs{zlib_lib}=$1;
 719                         }
 720                 elsif (/^--with-zlib-include=(.*)$/)
 721                         {
 722                         $withargs{zlib_include}=$1;
 723                         }
 724                 elsif (/^--with-fuzzer-lib=(.*)$/)
 725                         {
 726                         $withargs{fuzzer_lib}=$1;
 727                         }
 728                 elsif (/^--with-fuzzer-include=(.*)$/)
 729                         {
 730                         $withargs{fuzzer_include}=$1;
 731                         }
 732                 elsif (/^--cross-compile-prefix=(.*)$/)
 733                         {
 734                         $config{cross_compile_prefix}=$1;
 735                         }
 736                 elsif (/^--config=(.*)$/)
 737                         {
 738                         read_config $1;
 739                         }
 740                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 741                         {
 742                         $libs.=$_." ";
 743                         }
 744                 elsif (/^-rpath$/ or /^-R$/)
 745                         # -rpath is the OSF1 rpath flag
 746                         # -R is the old Solaris rpath flag
 747                         {
 748                         my $rpath = shift(@argvcopy) || "";
 749                         $rpath .= " " if $rpath ne "";
 750                         $libs.=$_." ".$rpath;
 751                         }
 752                 elsif (/^-static$/)
 753                         {
 754                         $libs.=$_." ";
 755                         $disabled{"dso"} = "forced";
 756                         $disabled{"pic"} = "forced";
 757                         $disabled{"shared"} = "forced";
 758                         $disabled{"threads"} = "forced";
 759                         }
 760                 elsif (/^-D(.*)$/)
 761                         {
 762                         push @user_defines, $1;
 763                         }
 764                 else    # common if (/^[-+]/), just pass down...
 765                         {
 766                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 767                         $user_cflags.=" ".$_;
 768                         }
 769                 }
 770         else
 771                 {
 772                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 773                 $target=$_;
 774                 }
 775         unless ($_ eq $target || /^no-/ || /^disable-/)
 776                 {
 777                 # "no-..." follows later after implied disactivations
 778                 # have been derived.  (Don't take this too seriously,
 779                 # we really only write OPTIONS to the Makefile out of
 780                 # nostalgia.)
 781
 782                 if ($config{options} eq "")
 783                         { $config{options} = $_; }
 784                 else
 785                         { $config{options} .= " ".$_; }
 786                 }
 787
 788         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 789                 die "***** Unsupported api compatibility level: $config{api}\n",
 790         }
 791
 792         if (keys %deprecated_options)
 793                 {
 794                 warn "***** Deprecated options: ",
 795                         join(", ", keys %deprecated_options), "\n";
 796                 }
 797         if (keys %unsupported_options)
 798                 {
 799                 die "***** Unsupported options: ",
 800                         join(", ", keys %unsupported_options), "\n";
 801                 }
 802         }
 803
 804 if ($libs =~ /(^|\s)-Wl,-rpath,/
 805     && !$disabled{shared}
 806     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 807     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 808         "***** any of asan, msan or ubsan\n";
 809 }
 810
 811 my @tocheckfor = (keys %disabled);
 812 while (@tocheckfor) {
 813     my %new_tocheckfor = ();
 814     my @cascade_copy = (@disable_cascades);
 815     while (@cascade_copy) {
 816         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 817         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 818             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 819                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 820             }
 821         }
 822     }
 823     @tocheckfor = (keys %new_tocheckfor);
 824 }
 825
 826 our $die = sub { die @_; };
 827 if ($target eq "TABLE") {
 828     local $die = sub { warn @_; };
 829     foreach (sort keys %table) {
 830         print_table_entry($_, "TABLE");
 831     }
 832     exit 0;
 833 }
 834
 835 if ($target eq "LIST") {
 836     foreach (sort keys %table) {
 837         print $_,"\n" unless $table{$_}->{template};
 838     }
 839     exit 0;
 840 }
 841
 842 if ($target eq "HASH") {
 843     local $die = sub { warn @_; };
 844     print "%table = (\n";
 845     foreach (sort keys %table) {
 846         print_table_entry($_, "HASH");
 847     }
 848     exit 0;
 849 }
 850
 851 # Backward compatibility?
 852 if ($target =~ m/^CygWin32(-.*)$/) {
 853     $target = "Cygwin".$1;
 854 }
 855
 856 foreach (sort (keys %disabled))
 857         {
 858         $config{options} .= " no-$_";
 859
 860         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 861
 862         if (/^dso$/)
 863                 { }
 864         elsif (/^threads$/)
 865                 { }
 866         elsif (/^shared$/)
 867                 { }
 868         elsif (/^pic$/)
 869                 { }
 870         elsif (/^zlib$/)
 871                 { }
 872         elsif (/^dynamic-engine$/)
 873                 { }
 874         elsif (/^makedepend$/)
 875                 { }
 876         elsif (/^zlib-dynamic$/)
 877                 { }
 878         elsif (/^sse2$/)
 879                 { $no_sse2 = 1; }
 880         elsif (/^engine$/)
 881                 {
 882                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 883                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 884                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 885                 print " OPENSSL_NO_ENGINE (skip engines)";
 886                 }
 887         else
 888                 {
 889                 my ($WHAT, $what);
 890
 891                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 892
 893                 # Fix up C macro end names
 894                 $WHAT = "RMD160" if $what eq "ripemd";
 895
 896                 # fix-up crypto/directory name(s)
 897                 $what = "ripemd" if $what eq "rmd160";
 898                 $what = "whrlpool" if $what eq "whirlpool";
 899
 900                 if ($what ne "async" && $what ne "err"
 901                     && grep { $_ eq $what } @{$config{sdirs}})
 902                         {
 903                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 904                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 905
 906                         print " OPENSSL_NO_$WHAT (skip dir)";
 907                         }
 908                 else
 909                         {
 910                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 911                         print " OPENSSL_NO_$WHAT";
 912
 913                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 914                         }
 915                 }
 916
 917         print "\n";
 918         }
 919
 920 print "Configuring for $target\n";
 921 # Support for legacy targets having a name starting with 'debug-'
 922 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 923 if ($d) {
 924     $config{build_type} = "debug";
 925
 926     # If we do not find debug-foo in the table, the target is set to foo.
 927     if (!$table{$target}) {
 928         $target = $t;
 929     }
 930 }
 931 $config{target} = $target;
 932 my %target = resolve_config($target);
 933
 934 &usage if (!%target || $target{template});
 935
 936 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 937 $config{conf_files} = [ sort keys %conf_files ];
 938 %target = ( %{$table{DEFAULTS}}, %target );
 939
 940 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
 941 $target{exe_extension}="";
 942 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 943                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 944 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 945
 946 ($target{shared_extension_simple}=$target{shared_extension})
 947     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 948 $target{dso_extension}=$target{shared_extension_simple};
 949 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 950     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 951
 952
 953 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 954     if $config{cross_compile_prefix} eq "";
 955
 956 # Allow overriding the names of some tools.  USE WITH CARE
 957 # Note: only Unix cares about HASHBANGPERL...  that explains
 958 # the default string.
 959 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
 960 $config{hashbangperl} =
 961     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 962 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 963 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
 964 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 965                    (which("$config{cross_compile_prefix}ranlib") ?
 966                           "\$(CROSS_COMPILE)ranlib" : "true");
 967 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 968 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 969 $target{rc} =
 970     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 971
 972 # Allow overriding the build file name
 973 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 974
 975 # Cache information necessary for reconfiguration
 976 $config{cc} = $target{cc};
 977 $config{cxx} = $target{cxx};
 978 $config{build_file} = $target{build_file};
 979
 980 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 981 # or release_ attributes.
 982 # Do it in such a way that no spurious space is appended (hence the grep).
 983 $config{defines} = [];
 984 $config{cflags} = "";
 985 $config{cxxflags} = "";
 986 $config{ex_libs} = "";
 987 $config{shared_ldflag} = "";
 988
 989 # Make sure build_scheme is consistent.
 990 $target{build_scheme} = [ $target{build_scheme} ]
 991     if ref($target{build_scheme}) ne "ARRAY";
 992
 993 my ($builder, $builder_platform, @builder_opts) =
 994     @{$target{build_scheme}};
 995
 996 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
 997                       $builder_platform."-checker.pm")) {
 998     my $checker_path = catfile($srcdir, "Configurations", $checker);
 999     if (-f $checker_path) {
1000         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1001             ? sub { warn $@; } : sub { die $@; };
1002         if (! do $checker_path) {
1003             if ($@) {
1004                 $fn->($@);
1005             } elsif ($!) {
1006                 $fn->($!);
1007             } else {
1008                 $fn->("The detected tools didn't match the platform\n");
1009             }
1010         }
1011         last;
1012     }
1013 }
1014
1015 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1016
1017 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1018         {
1019         $config{cflags} .= " -mno-cygwin";
1020         $config{shared_ldflag} .= " -mno-cygwin";
1021         }
1022
1023 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1024         # minimally required architecture flags for assembly modules
1025         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1026         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1027 }
1028
1029 my $no_shared_warn=0;
1030 my $no_user_cflags=0;
1031 my $no_user_defines=0;
1032
1033 # The DSO code currently always implements all functions so that no
1034 # applications will have to worry about that from a compilation point
1035 # of view. However, the "method"s may return zero unless that platform
1036 # has support compiled in for them. Currently each method is enabled
1037 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1038 # string entry into using the following logic;
1039 if (!$disabled{dso} && $target{dso_scheme} ne "")
1040         {
1041         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1042         if ($target{dso_scheme} eq "DLFCN")
1043                 {
1044                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1045                 }
1046         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1047                 {
1048                 unshift @{$config{defines}}, "DSO_DLFCN";
1049                 }
1050         else
1051                 {
1052                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1053                 }
1054         }
1055
1056 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1057
1058 # If threads aren't disabled, check how possible they are
1059 unless ($disabled{threads}) {
1060     if ($auto_threads) {
1061         # Enabled by default, disable it forcibly if unavailable
1062         if ($target{thread_scheme} eq "(unknown)") {
1063             $disabled{threads} = "unavailable";
1064         }
1065     } else {
1066         # The user chose to enable threads explicitly, let's see
1067         # if there's a chance that's possible
1068         if ($target{thread_scheme} eq "(unknown)") {
1069             # If the user asked for "threads" and we don't have internal
1070             # knowledge how to do it, [s]he is expected to provide any
1071             # system-dependent compiler options that are necessary.  We
1072             # can't truly check that the given options are correct, but
1073             # we expect the user to know what [s]He is doing.
1074             if ($no_user_cflags && $no_user_defines) {
1075                 die "You asked for multi-threading support, but didn't\n"
1076                     ,"provide any system-specific compiler options\n";
1077             }
1078         }
1079     }
1080 }
1081
1082 # If threads still aren't disabled, add a C macro to ensure the source
1083 # code knows about it.  Any other flag is taken care of by the configs.
1084 unless($disabled{threads}) {
1085     foreach (("defines", "openssl_thread_defines")) {
1086         push @{$config{$_}}, "OPENSSL_THREADS";
1087     }
1088 }
1089
1090 # With "deprecated" disable all deprecated features.
1091 if (defined($disabled{"deprecated"})) {
1092         $config{api} = $maxapi;
1093 }
1094
1095 if ($target{shared_target} eq "")
1096         {
1097         $no_shared_warn = 1
1098             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1099         $disabled{shared} = "no-shared-target";
1100         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1101             "no-shared-target";
1102         }
1103
1104 if ($disabled{"dynamic-engine"}) {
1105         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1106         $config{dynamic_engines} = 0;
1107 } else {
1108         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1109         $config{dynamic_engines} = 1;
1110 }
1111
1112 unless ($disabled{asan}) {
1113     $config{cflags} .= "-fsanitize=address ";
1114 }
1115
1116 unless ($disabled{ubsan}) {
1117     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1118     # platforms.
1119     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1120 }
1121
1122 unless ($disabled{msan}) {
1123   $config{cflags} .= "-fsanitize=memory ";
1124 }
1125
1126 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1127         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1128     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1129 }
1130 #
1131 # Platform fix-ups
1132 #
1133
1134 # This saves the build files from having to check
1135 if ($disabled{pic})
1136         {
1137         $target{shared_cflag} = $target{shared_ldflag} =
1138                 $target{shared_rcflag} = "";
1139         }
1140 else
1141         {
1142         push @{$config{defines}}, "OPENSSL_PIC";
1143         }
1144
1145 if ($target{sys_id} ne "")
1146         {
1147         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1148         }
1149
1150 unless ($disabled{asm}) {
1151     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1152     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1153
1154     # bn-586 is the only one implementing bn_*_part_words
1155     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1156     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1157
1158     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1159     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1160     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1161
1162     if ($target{sha1_asm_src}) {
1163         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1164         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1165         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1166     }
1167     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1168         push @{$config{defines}}, "RC4_ASM";
1169     }
1170     if ($target{md5_asm_src}) {
1171         push @{$config{defines}}, "MD5_ASM";
1172     }
1173     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1174     if ($target{rmd160_asm_src}) {
1175         push @{$config{defines}}, "RMD160_ASM";
1176     }
1177     if ($target{aes_asm_src}) {
1178         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1179         # aes-ctr.fake is not a real file, only indication that assembler
1180         # module implements AES_ctr32_encrypt...
1181         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1182         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1183         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1184         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1185         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1186         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1187     }
1188     if ($target{wp_asm_src} =~ /mmx/) {
1189         if ($config{processor} eq "386") {
1190             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1191         } elsif (!$disabled{"whirlpool"}) {
1192             push @{$config{defines}}, "WHIRLPOOL_ASM";
1193         }
1194     }
1195     if ($target{modes_asm_src} =~ /ghash-/) {
1196         push @{$config{defines}}, "GHASH_ASM";
1197     }
1198     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1199         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1200     }
1201     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1202         push @{$config{defines}}, "PADLOCK_ASM";
1203     }
1204     if ($target{poly1305_asm_src} ne "") {
1205         push @{$config{defines}}, "POLY1305_ASM";
1206     }
1207 }
1208
1209 my $ecc = $target{cc};
1210 if ($^O ne "VMS" && !$disabled{makedepend}) {
1211     # Is the compiler gcc or clang?  $ecc is used below to see if
1212     # error-checking can be turned on.
1213     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1214     open(PIPE, "$ccpcc --version 2>&1 |");
1215     my $lines = 2;
1216     while ( <PIPE> ) {
1217         # Find the version number and save the major.
1218         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1219         my $compiler_major = $1;
1220         # We know that GNU C version 3 and up as well as all clang
1221         # versions support dependency generation
1222         $config{makedepprog} = $ccpcc
1223             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1224         $ecc = "clang" if /clang/;
1225         $ecc = "gcc" if /gcc/;
1226         last if ($config{makedepprog} || !$lines--);
1227     }
1228     close(PIPE);
1229
1230     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1231     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1232 }
1233
1234
1235
1236 # Deal with bn_ops ###################################################
1237
1238 $config{bn_ll}                  =0;
1239 $config{export_var_as_fn}       =0;
1240 my $def_int="unsigned int";
1241 $config{rc4_int}                =$def_int;
1242 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1243
1244 my $count = 0;
1245 foreach (sort split(/\s+/,$target{bn_ops})) {
1246     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1247     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1248     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1249     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1250     ($config{b64l},$config{b64},$config{b32})
1251         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1252     ($config{b64l},$config{b64},$config{b32})
1253         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1254     ($config{b64l},$config{b64},$config{b32})
1255         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1256 }
1257 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1258     if $count > 1;
1259
1260
1261 # Hack cflags for better warnings (dev option) #######################
1262
1263 # "Stringify" the C flags string.  This permits it to be made part of a string
1264 # and works as well on command lines.
1265 $config{cflags} =~ s/([\\\"])/\\$1/g;
1266
1267 if (defined($config{api})) {
1268     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1269     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1270     push @{$config{defines}}, $apiflag;
1271 }
1272
1273 if ($strict_warnings)
1274         {
1275         my $wopt;
1276         die "ERROR --strict-warnings requires gcc or clang"
1277             unless $ecc eq 'gcc' || $ecc eq 'clang';
1278         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1279                 {
1280                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1281                 }
1282         if ($ecc eq "clang")
1283                 {
1284                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1285                         {
1286                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1287                         }
1288                 }
1289         }
1290
1291 unless ($disabled{"crypto-mdebug-backtrace"})
1292         {
1293         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1294                 {
1295                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1296                 }
1297         if ($target =~ /^BSD-/)
1298                 {
1299                 $config{ex_libs} .= " -lexecinfo";
1300                 }
1301         }
1302
1303 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1304 else                    { $no_user_cflags=1;  }
1305 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1306 else               { $no_user_defines=1;    }
1307
1308 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1309
1310 unless ($disabled{afalgeng}) {
1311     $config{afalgeng}="";
1312     if ($target =~ m/^linux/) {
1313         my $minver = 4*10000 + 1*100 + 0;
1314         if ($config{cross_compile_prefix} eq "") {
1315             my $verstr = `uname -r`;
1316             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1317             ($mi2) = $mi2 =~ /(\d+)/;
1318             my $ver = $ma*10000 + $mi1*100 + $mi2;
1319             if ($ver < $minver) {
1320                 $disabled{afalgeng} = "too-old-kernel";
1321             } else {
1322                 push @{$config{engdirs}}, "afalg";
1323             }
1324         } else {
1325             $disabled{afalgeng} = "cross-compiling";
1326         }
1327     } else {
1328         $disabled{afalgeng}  = "not-linux";
1329     }
1330 }
1331
1332 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1333
1334 # If we use the unified build, collect information from build.info files
1335 my %unified_info = ();
1336
1337 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1338 if ($builder eq "unified") {
1339     use lib catdir(dirname(__FILE__),"util");
1340     use with_fallback qw(Text::Template);
1341
1342     sub cleandir {
1343         my $base = shift;
1344         my $dir = shift;
1345         my $relativeto = shift || ".";
1346
1347         $dir = catdir($base,$dir) unless isabsolute($dir);
1348
1349         # Make sure the directories we're building in exists
1350         mkpath($dir);
1351
1352         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1353         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1354         return $res;
1355     }
1356
1357     sub cleanfile {
1358         my $base = shift;
1359         my $file = shift;
1360         my $relativeto = shift || ".";
1361
1362         $file = catfile($base,$file) unless isabsolute($file);
1363
1364         my $d = dirname($file);
1365         my $f = basename($file);
1366
1367         # Make sure the directories we're building in exists
1368         mkpath($d);
1369
1370         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1371         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1372         return $res;
1373     }
1374
1375     # Store the name of the template file we will build the build file from
1376     # in %config.  This may be useful for the build file itself.
1377     my @build_file_template_names =
1378         ( $builder_platform."-".$target{build_file}.".tmpl",
1379           $target{build_file}.".tmpl" );
1380     my @build_file_templates = ();
1381
1382     # First, look in the user provided directory, if given
1383     if (defined $ENV{$local_config_envname}) {
1384         @build_file_templates =
1385             map {
1386                 if ($^O eq 'VMS') {
1387                     # VMS environment variables are logical names,
1388                     # which can be used as is
1389                     $local_config_envname . ':' . $_;
1390                 } else {
1391                     catfile($ENV{$local_config_envname}, $_);
1392                 }
1393             }
1394             @build_file_template_names;
1395     }
1396     # Then, look in our standard directory
1397     push @build_file_templates,
1398         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1399           @build_file_template_names );
1400
1401     my $build_file_template;
1402     for $_ (@build_file_templates) {
1403         $build_file_template = $_;
1404         last if -f $build_file_template;
1405
1406         $build_file_template = undef;
1407     }
1408     if (!defined $build_file_template) {
1409         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1410     }
1411     $config{build_file_templates}
1412       = [ $build_file_template,
1413           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1414                     $blddir) ];
1415
1416     my @build_infos = ( [ ".", "build.info" ] );
1417     foreach (@{$config{dirs}}) {
1418         push @build_infos, [ $_, "build.info" ]
1419             if (-f catfile($srcdir, $_, "build.info"));
1420     }
1421     foreach (@{$config{sdirs}}) {
1422         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1423             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1424     }
1425     foreach (@{$config{engdirs}}) {
1426         push @build_infos, [ catdir("engines", $_), "build.info" ]
1427             if (-f catfile($srcdir, "engines", $_, "build.info"));
1428     }
1429     foreach (@{$config{tdirs}}) {
1430         push @build_infos, [ catdir("test", $_), "build.info" ]
1431             if (-f catfile($srcdir, "test", $_, "build.info"));
1432     }
1433
1434     $config{build_infos} = [ ];
1435
1436     foreach (@build_infos) {
1437         my $sourced = catdir($srcdir, $_->[0]);
1438         my $buildd = catdir($blddir, $_->[0]);
1439
1440         mkpath($buildd);
1441
1442         my $f = $_->[1];
1443         # The basic things we're trying to build
1444         my @programs = ();
1445         my @programs_install = ();
1446         my @libraries = ();
1447         my @libraries_install = ();
1448         my @engines = ();
1449         my @engines_install = ();
1450         my @scripts = ();
1451         my @scripts_install = ();
1452         my @extra = ();
1453         my @overrides = ();
1454         my @intermediates = ();
1455         my @rawlines = ();
1456
1457         my %ordinals = ();
1458         my %sources = ();
1459         my %shared_sources = ();
1460         my %includes = ();
1461         my %depends = ();
1462         my %renames = ();
1463         my %sharednames = ();
1464         my %generate = ();
1465
1466         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1467         my $template = Text::Template->new(TYPE => 'FILE',
1468                                            SOURCE => catfile($sourced, $f));
1469         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1470         my @text =
1471             split /^/m,
1472             $template->fill_in(HASH => { config => \%config,
1473                                          target => \%target,
1474                                          disabled => \%disabled,
1475                                          withargs => \%withargs,
1476                                          builddir => abs2rel($buildd, $blddir),
1477                                          sourcedir => abs2rel($sourced, $blddir),
1478                                          buildtop => abs2rel($blddir, $blddir),
1479                                          sourcetop => abs2rel($srcdir, $blddir) },
1480                                DELIMITERS => [ "{-", "-}" ]);
1481
1482         # The top item of this stack has the following values
1483         # -2 positive already run and we found ELSE (following ELSIF should fail)
1484         # -1 positive already run (skip until ENDIF)
1485         # 0 negatives so far (if we're at a condition, check it)
1486         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1487         # 2 positive ELSE (following ELSIF should fail)
1488         my @skip = ();
1489         collect_information(
1490             collect_from_array([ @text ],
1491                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1492                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1493             # Info we're looking for
1494             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1495             => sub {
1496                 if (! @skip || $skip[$#skip] > 0) {
1497                     push @skip, !! $1;
1498                 } else {
1499                     push @skip, -1;
1500                 }
1501             },
1502             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1503             => sub { die "ELSIF out of scope" if ! @skip;
1504                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1505                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1506                      $skip[$#skip] = !! $1
1507                          if $skip[$#skip] == 0; },
1508             qr/^\s*ELSE\s*$/
1509             => sub { die "ELSE out of scope" if ! @skip;
1510                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1511                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1512             qr/^\s*ENDIF\s*$/
1513             => sub { die "ENDIF out of scope" if ! @skip;
1514                      pop @skip; },
1515             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1516             => sub {
1517                 if (!@skip || $skip[$#skip] > 0) {
1518                     my $install = $1;
1519                     my @x = tokenize($2);
1520                     push @programs, @x;
1521                     push @programs_install, @x unless $install;
1522                 }
1523             },
1524             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1525             => sub {
1526                 if (!@skip || $skip[$#skip] > 0) {
1527                     my $install = $1;
1528                     my @x = tokenize($2);
1529                     push @libraries, @x;
1530                     push @libraries_install, @x unless $install;
1531                 }
1532             },
1533             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1534             => sub {
1535                 if (!@skip || $skip[$#skip] > 0) {
1536                     my $install = $1;
1537                     my @x = tokenize($2);
1538                     push @engines, @x;
1539                     push @engines_install, @x unless $install;
1540                 }
1541             },
1542             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1543             => sub {
1544                 if (!@skip || $skip[$#skip] > 0) {
1545                     my $install = $1;
1546                     my @x = tokenize($2);
1547                     push @scripts, @x;
1548                     push @scripts_install, @x unless $install;
1549                 }
1550             },
1551             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1552             => sub { push @extra, tokenize($1)
1553                          if !@skip || $skip[$#skip] > 0 },
1554             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1555             => sub { push @overrides, tokenize($1)
1556                          if !@skip || $skip[$#skip] > 0 },
1557
1558             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1559             => sub { push @{$ordinals{$1}}, tokenize($2)
1560                          if !@skip || $skip[$#skip] > 0 },
1561             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1562             => sub { push @{$sources{$1}}, tokenize($2)
1563                          if !@skip || $skip[$#skip] > 0 },
1564             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1565             => sub { push @{$shared_sources{$1}}, tokenize($2)
1566                          if !@skip || $skip[$#skip] > 0 },
1567             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1568             => sub { push @{$includes{$1}}, tokenize($2)
1569                          if !@skip || $skip[$#skip] > 0 },
1570             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1571             => sub { push @{$depends{$1}}, tokenize($2)
1572                          if !@skip || $skip[$#skip] > 0 },
1573             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1574             => sub { push @{$generate{$1}}, $2
1575                          if !@skip || $skip[$#skip] > 0 },
1576             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1577             => sub { push @{$renames{$1}}, tokenize($2)
1578                          if !@skip || $skip[$#skip] > 0 },
1579             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1580             => sub { push @{$sharednames{$1}}, tokenize($2)
1581                          if !@skip || $skip[$#skip] > 0 },
1582             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1583             => sub {
1584                 my $lineiterator = shift;
1585                 my $target_kind = $1;
1586                 while (defined $lineiterator->()) {
1587                     s|\R$||;
1588                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1589                         die "ENDRAW doesn't match BEGINRAW"
1590                             if $1 ne $target_kind;
1591                         last;
1592                     }
1593                     next if @skip && $skip[$#skip] <= 0;
1594                     push @rawlines,  $_
1595                         if ($target_kind eq $target{build_file}
1596                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1597                 }
1598             },
1599             qr/^\s*(?:#.*)?$/ => sub { },
1600             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1601             "BEFORE" => sub {
1602                 if ($buildinfo_debug) {
1603                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1604                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1605                 }
1606             },
1607             "AFTER" => sub {
1608                 if ($buildinfo_debug) {
1609                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1610                 }
1611             },
1612             );
1613         die "runaway IF?" if (@skip);
1614
1615         foreach (keys %renames) {
1616             die "$_ renamed to more than one thing: "
1617                 ,join(" ", @{$renames{$_}}),"\n"
1618                 if scalar @{$renames{$_}} > 1;
1619             my $dest = cleanfile($buildd, $_, $blddir);
1620             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1621             die "$dest renamed to more than one thing: "
1622                 ,$unified_info{rename}->{$dest}, $to
1623                 unless !defined($unified_info{rename}->{$dest})
1624                 or $unified_info{rename}->{$dest} eq $to;
1625             $unified_info{rename}->{$dest} = $to;
1626         }
1627
1628         foreach (@programs) {
1629             my $program = cleanfile($buildd, $_, $blddir);
1630             if ($unified_info{rename}->{$program}) {
1631                 $program = $unified_info{rename}->{$program};
1632             }
1633             $unified_info{programs}->{$program} = 1;
1634         }
1635
1636         foreach (@programs_install) {
1637             my $program = cleanfile($buildd, $_, $blddir);
1638             if ($unified_info{rename}->{$program}) {
1639                 $program = $unified_info{rename}->{$program};
1640             }
1641             $unified_info{install}->{programs}->{$program} = 1;
1642         }
1643
1644         foreach (@libraries) {
1645             my $library = cleanfile($buildd, $_, $blddir);
1646             if ($unified_info{rename}->{$library}) {
1647                 $library = $unified_info{rename}->{$library};
1648             }
1649             $unified_info{libraries}->{$library} = 1;
1650         }
1651
1652         foreach (@libraries_install) {
1653             my $library = cleanfile($buildd, $_, $blddir);
1654             if ($unified_info{rename}->{$library}) {
1655                 $library = $unified_info{rename}->{$library};
1656             }
1657             $unified_info{install}->{libraries}->{$library} = 1;
1658         }
1659
1660         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1661 ENGINES can only be used if configured with 'dynamic-engine'.
1662 This is usually a fault in a build.info file.
1663 EOF
1664         foreach (@engines) {
1665             my $library = cleanfile($buildd, $_, $blddir);
1666             if ($unified_info{rename}->{$library}) {
1667                 $library = $unified_info{rename}->{$library};
1668             }
1669             $unified_info{engines}->{$library} = 1;
1670         }
1671
1672         foreach (@engines_install) {
1673             my $library = cleanfile($buildd, $_, $blddir);
1674             if ($unified_info{rename}->{$library}) {
1675                 $library = $unified_info{rename}->{$library};
1676             }
1677             $unified_info{install}->{engines}->{$library} = 1;
1678         }
1679
1680         foreach (@scripts) {
1681             my $script = cleanfile($buildd, $_, $blddir);
1682             if ($unified_info{rename}->{$script}) {
1683                 $script = $unified_info{rename}->{$script};
1684             }
1685             $unified_info{scripts}->{$script} = 1;
1686         }
1687
1688         foreach (@scripts_install) {
1689             my $script = cleanfile($buildd, $_, $blddir);
1690             if ($unified_info{rename}->{$script}) {
1691                 $script = $unified_info{rename}->{$script};
1692             }
1693             $unified_info{install}->{scripts}->{$script} = 1;
1694         }
1695
1696         foreach (@extra) {
1697             my $extra = cleanfile($buildd, $_, $blddir);
1698             $unified_info{extra}->{$extra} = 1;
1699         }
1700
1701         foreach (@overrides) {
1702             my $override = cleanfile($buildd, $_, $blddir);
1703             $unified_info{overrides}->{$override} = 1;
1704         }
1705
1706         push @{$unified_info{rawlines}}, @rawlines;
1707
1708         unless ($disabled{shared}) {
1709             # Check sharednames.
1710             foreach (keys %sharednames) {
1711                 my $dest = cleanfile($buildd, $_, $blddir);
1712                 if ($unified_info{rename}->{$dest}) {
1713                     $dest = $unified_info{rename}->{$dest};
1714                 }
1715                 die "shared_name for $dest with multiple values: "
1716                     ,join(" ", @{$sharednames{$_}}),"\n"
1717                     if scalar @{$sharednames{$_}} > 1;
1718                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1719                 die "shared_name found for a library $dest that isn't defined\n"
1720                     unless $unified_info{libraries}->{$dest};
1721                 die "shared_name for $dest with multiple values: "
1722                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1723                     unless !defined($unified_info{sharednames}->{$dest})
1724                     or $unified_info{sharednames}->{$dest} eq $to;
1725                 $unified_info{sharednames}->{$dest} = $to;
1726             }
1727
1728             # Additionally, we set up sharednames for libraries that don't
1729             # have any, as themselves.
1730             foreach (keys %{$unified_info{libraries}}) {
1731                 if (!defined $unified_info{sharednames}->{$_}) {
1732                     $unified_info{sharednames}->{$_} = $_
1733                 }
1734             }
1735         }
1736
1737         foreach (keys %ordinals) {
1738             my $dest = $_;
1739             my $ddest = cleanfile($buildd, $_, $blddir);
1740             if ($unified_info{rename}->{$ddest}) {
1741                 $ddest = $unified_info{rename}->{$ddest};
1742             }
1743             foreach (@{$ordinals{$dest}}) {
1744                 my %known_ordinals =
1745                     (
1746                      crypto =>
1747                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1748                      ssl =>
1749                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1750                     );
1751                 my $o = $known_ordinals{$_};
1752                 die "Ordinals for $ddest defined more than once\n"
1753                     if $unified_info{ordinals}->{$ddest};
1754                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1755             }
1756         }
1757
1758         foreach (keys %sources) {
1759             my $dest = $_;
1760             my $ddest = cleanfile($buildd, $_, $blddir);
1761             if ($unified_info{rename}->{$ddest}) {
1762                 $ddest = $unified_info{rename}->{$ddest};
1763             }
1764             foreach (@{$sources{$dest}}) {
1765                 my $s = cleanfile($sourced, $_, $blddir);
1766
1767                 # If it isn't in the source tree, we assume it's generated
1768                 # in the build tree
1769                 if (! -f $s) {
1770                     $s = cleanfile($buildd, $_, $blddir);
1771                 }
1772                 # We recognise C++, C and asm files
1773                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1774                     my $o = $_;
1775                     $o =~ s/\.[csS]$/.o/; # C and assembler
1776                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1777                     $o = cleanfile($buildd, $o, $blddir);
1778                     $unified_info{sources}->{$ddest}->{$o} = 1;
1779                     $unified_info{sources}->{$o}->{$s} = 1;
1780                 } else {
1781                     $unified_info{sources}->{$ddest}->{$s} = 1;
1782                 }
1783             }
1784         }
1785
1786         foreach (keys %shared_sources) {
1787             my $dest = $_;
1788             my $ddest = cleanfile($buildd, $_, $blddir);
1789             if ($unified_info{rename}->{$ddest}) {
1790                 $ddest = $unified_info{rename}->{$ddest};
1791             }
1792             foreach (@{$shared_sources{$dest}}) {
1793                 my $s = cleanfile($sourced, $_, $blddir);
1794
1795                 # If it isn't in the source tree, we assume it's generated
1796                 # in the build tree
1797                 if (! -f $s) {
1798                     $s = cleanfile($buildd, $_, $blddir);
1799                 }
1800                 # We recognise C++, C and asm files
1801                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1802                     my $o = $_;
1803                     $o =~ s/\.[csS]$/.o/; # C and assembler
1804                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1805                     $o = cleanfile($buildd, $o, $blddir);
1806                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1807                     $unified_info{sources}->{$o}->{$s} = 1;
1808                 } else {
1809                     die "unrecognised source file type for shared library: $s\n";
1810                 }
1811             }
1812         }
1813
1814         foreach (keys %generate) {
1815             my $dest = $_;
1816             my $ddest = cleanfile($buildd, $_, $blddir);
1817             if ($unified_info{rename}->{$ddest}) {
1818                 $ddest = $unified_info{rename}->{$ddest};
1819             }
1820             die "more than one generator for $dest: "
1821                     ,join(" ", @{$generate{$_}}),"\n"
1822                     if scalar @{$generate{$_}} > 1;
1823             my @generator = split /\s+/, $generate{$dest}->[0];
1824             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1825             $unified_info{generate}->{$ddest} = [ @generator ];
1826         }
1827
1828         foreach (keys %depends) {
1829             my $dest = $_;
1830             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1831
1832             # If the destination doesn't exist in source, it can only be
1833             # a generated file in the build tree.
1834             if ($ddest ne "" && ! -f $ddest) {
1835                 $ddest = cleanfile($buildd, $_, $blddir);
1836                 if ($unified_info{rename}->{$ddest}) {
1837                     $ddest = $unified_info{rename}->{$ddest};
1838                 }
1839             }
1840             foreach (@{$depends{$dest}}) {
1841                 my $d = cleanfile($sourced, $_, $blddir);
1842
1843                 # If we know it's generated, or assume it is because we can't
1844                 # find it in the source tree, we set file we depend on to be
1845                 # in the build tree rather than the source tree, and assume
1846                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1847                 # section or in the Makefile template.
1848                 if (! -f $d
1849                     || (grep { $d eq $_ }
1850                         map { cleanfile($srcdir, $_, $blddir) }
1851                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1852                     $d = cleanfile($buildd, $_, $blddir);
1853                 }
1854                 # Take note if the file to depend on is being renamed
1855                 # Take extra care with files ending with .a, they should
1856                 # be treated without that extension, and the extension
1857                 # should be added back after treatment.
1858                 $d =~ /(\.a)?$/;
1859                 my $e = $1 // "";
1860                 $d = $`;
1861                 if ($unified_info{rename}->{$d}) {
1862                     $d = $unified_info{rename}->{$d};
1863                 }
1864                 $d .= $e;
1865                 $unified_info{depends}->{$ddest}->{$d} = 1;
1866                 # If we depend on a header file or a perl module, let's make
1867                 # sure it can get included
1868                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1869                     my $i = dirname($d);
1870                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1871                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1872                 }
1873             }
1874         }
1875
1876         foreach (keys %includes) {
1877             my $dest = $_;
1878             my $ddest = cleanfile($sourced, $_, $blddir);
1879
1880             # If the destination doesn't exist in source, it can only be
1881             # a generated file in the build tree.
1882             if (! -f $ddest) {
1883                 $ddest = cleanfile($buildd, $_, $blddir);
1884                 if ($unified_info{rename}->{$ddest}) {
1885                     $ddest = $unified_info{rename}->{$ddest};
1886                 }
1887             }
1888             foreach (@{$includes{$dest}}) {
1889                 my $is = cleandir($sourced, $_, $blddir);
1890                 my $ib = cleandir($buildd, $_, $blddir);
1891                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1892                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1893                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1894                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1895             }
1896         }
1897     }
1898
1899     ### Make unified_info a bit more efficient
1900     # One level structures
1901     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1902         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1903     }
1904     # Two level structures
1905     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1906         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1907             $unified_info{$l1}->{$l2} =
1908                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1909         }
1910     }
1911     # Includes
1912     foreach my $dest (sort keys %{$unified_info{includes}}) {
1913         if (defined($unified_info{includes}->{$dest}->{build})) {
1914             my @source_includes =
1915                 ( @{$unified_info{includes}->{$dest}->{source}} );
1916             $unified_info{includes}->{$dest} =
1917                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1918             foreach my $inc (@source_includes) {
1919                 push @{$unified_info{includes}->{$dest}}, $inc
1920                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1921             }
1922         } else {
1923             $unified_info{includes}->{$dest} =
1924                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1925         }
1926     }
1927 }
1928
1929 # For the schemes that need it, we provide the old *_obj configs
1930 # from the *_asm_obj ones
1931 foreach (grep /_(asm|aux)_src$/, keys %target) {
1932     my $src = $_;
1933     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1934     $target{$obj} = $target{$src};
1935     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1936     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1937 }
1938
1939 # Write down our configuration where it fits #########################
1940
1941 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1942 print OUT <<"EOF";
1943 package configdata;
1944
1945 use strict;
1946 use warnings;
1947
1948 use Exporter;
1949 #use vars qw(\@ISA \@EXPORT);
1950 our \@ISA = qw(Exporter);
1951 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1952
1953 EOF
1954 print OUT "our %config = (\n";
1955 foreach (sort keys %config) {
1956     if (ref($config{$_}) eq "ARRAY") {
1957         print OUT "  ", $_, " => [ ", join(", ",
1958                                            map { quotify("perl", $_) }
1959                                            @{$config{$_}}), " ],\n";
1960     } else {
1961         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1962     }
1963 }
1964 print OUT <<"EOF";
1965 );
1966
1967 EOF
1968 print OUT "our %target = (\n";
1969 foreach (sort keys %target) {
1970     if (ref($target{$_}) eq "ARRAY") {
1971         print OUT "  ", $_, " => [ ", join(", ",
1972                                            map { quotify("perl", $_) }
1973                                            @{$target{$_}}), " ],\n";
1974     } else {
1975         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1976     }
1977 }
1978 print OUT <<"EOF";
1979 );
1980
1981 EOF
1982 print OUT "our \%available_protocols = (\n";
1983 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1984 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1985 print OUT <<"EOF";
1986 );
1987
1988 EOF
1989 print OUT "our \@disablables = (\n";
1990 foreach (@disablables) {
1991     print OUT "  ", quotify("perl", $_), ",\n";
1992 }
1993 print OUT <<"EOF";
1994 );
1995
1996 EOF
1997 print OUT "our \%disabled = (\n";
1998 foreach (sort keys %disabled) {
1999     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2000 }
2001 print OUT <<"EOF";
2002 );
2003
2004 EOF
2005 print OUT "our %withargs = (\n";
2006 foreach (sort keys %withargs) {
2007     if (ref($withargs{$_}) eq "ARRAY") {
2008         print OUT "  ", $_, " => [ ", join(", ",
2009                                            map { quotify("perl", $_) }
2010                                            @{$withargs{$_}}), " ],\n";
2011     } else {
2012         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2013     }
2014 }
2015 print OUT <<"EOF";
2016 );
2017
2018 EOF
2019 if ($builder eq "unified") {
2020     my $recurse;
2021     $recurse = sub {
2022         my $indent = shift;
2023         foreach (@_) {
2024             if (ref $_ eq "ARRAY") {
2025                 print OUT " "x$indent, "[\n";
2026                 foreach (@$_) {
2027                     $recurse->($indent + 4, $_);
2028                 }
2029                 print OUT " "x$indent, "],\n";
2030             } elsif (ref $_ eq "HASH") {
2031                 my %h = %$_;
2032                 print OUT " "x$indent, "{\n";
2033                 foreach (sort keys %h) {
2034                     if (ref $h{$_} eq "") {
2035                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2036                     } else {
2037                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2038                         $recurse->($indent + 8, $h{$_});
2039                     }
2040                 }
2041                 print OUT " "x$indent, "},\n";
2042             } else {
2043                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2044             }
2045         }
2046     };
2047     print OUT "our %unified_info = (\n";
2048     foreach (sort keys %unified_info) {
2049         if (ref $unified_info{$_} eq "") {
2050             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2051         } else {
2052             print OUT " "x4, quotify("perl", $_), " =>\n";
2053             $recurse->(8, $unified_info{$_});
2054         }
2055     }
2056     print OUT <<"EOF";
2057 );
2058
2059 EOF
2060 }
2061 print OUT "1;\n";
2062 close(OUT);
2063
2064 print "\n";
2065 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2066 print "PERL          =$config{perl}\n";
2067 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2068 print "HASHBANGPERL  =$config{hashbangperl}\n";
2069 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2070 print "CFLAG         =$target{cflags} $config{cflags}\n";
2071 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2072     if defined $target{cxx};
2073 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2074     if defined $target{cxx};
2075 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2076 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2077 #                             "$config{cross_compile_prefix}ranlib" :
2078 #                             "$target{ranlib}", "\n";
2079 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2080
2081 my %builders = (
2082     unified => sub {
2083         run_dofile(catfile($blddir, $target{build_file}),
2084                    @{$config{build_file_templates}});
2085     },
2086     );
2087
2088 $builders{$builder}->($builder_platform, @builder_opts);
2089
2090 print <<"EOF" if ($disabled{threads} eq "unavailable");
2091
2092 The library could not be configured for supporting multi-threaded
2093 applications as the compiler options required on this system are not known.
2094 See file INSTALL for details if you need multi-threading.
2095 EOF
2096
2097 print <<"EOF" if ($no_shared_warn);
2098
2099 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2100 platform, so we will pretend you gave the option 'no-pic', which also disables
2101 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2102 or position independent code, please let us know (but please first make sure
2103 you have tried with a current version of OpenSSL).
2104 EOF
2105
2106 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2107
2108 WARNING: there are indications that another build was made in the source
2109 directory.  This build may have picked up artifacts from that build, the
2110 safest course of action is to clean the source directory and redo this
2111 configuration.
2112 EOF
2113
2114 exit(0);
2115
2116 ######################################################################
2117 #
2118 # Helpers and utility functions
2119 #
2120
2121 # Configuration file reading #########################################
2122
2123 # Note: All of the helper functions are for lazy evaluation.  They all
2124 # return a CODE ref, which will return the intended value when evaluated.
2125 # Thus, whenever there's mention of a returned value, it's about that
2126 # intended value.
2127
2128 # Helper function to implement conditional inheritance depending on the
2129 # value of $disabled{asm}.  Used in inherit_from values as follows:
2130 #
2131 #      inherit_from => [ "template", asm("asm_tmpl") ]
2132 #
2133 sub asm {
2134     my @x = @_;
2135     sub {
2136         $disabled{asm} ? () : @x;
2137     }
2138 }
2139
2140 # Helper function to implement conditional value variants, with a default
2141 # plus additional values based on the value of $config{build_type}.
2142 # Arguments are given in hash table form:
2143 #
2144 #       picker(default => "Basic string: ",
2145 #              debug   => "debug",
2146 #              release => "release")
2147 #
2148 # When configuring with --debug, the resulting string will be
2149 # "Basic string: debug", and when not, it will be "Basic string: release"
2150 #
2151 # This can be used to create variants of sets of flags according to the
2152 # build type:
2153 #
2154 #       cflags => picker(default => "-Wall",
2155 #                        debug   => "-g -O0",
2156 #                        release => "-O3")
2157 #
2158 sub picker {
2159     my %opts = @_;
2160     return sub { add($opts{default} || (),
2161                      $opts{$config{build_type}} || ())->(); }
2162 }
2163
2164 # Helper function to combine several values of different types into one.
2165 # This is useful if you want to combine a string with the result of a
2166 # lazy function, such as:
2167 #
2168 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2169 #
2170 sub combine {
2171     my @stuff = @_;
2172     return sub { add(@stuff)->(); }
2173 }
2174
2175 # Helper function to implement conditional values depending on the value
2176 # of $disabled{threads}.  Can be used as follows:
2177 #
2178 #       cflags => combine("-Wall", threads("-pthread"))
2179 #
2180 sub threads {
2181     my @flags = @_;
2182     return sub { add($disabled{threads} ? () : @flags)->(); }
2183 }
2184
2185
2186
2187 our $add_called = 0;
2188 # Helper function to implement adding values to already existing configuration
2189 # values.  It handles elements that are ARRAYs, CODEs and scalars
2190 sub _add {
2191     my $separator = shift;
2192
2193     # If there's any ARRAY in the collection of values OR the separator
2194     # is undef, we will return an ARRAY of combined values, otherwise a
2195     # string of joined values with $separator as the separator.
2196     my $found_array = !defined($separator);
2197
2198     my @values =
2199         map {
2200             my $res = $_;
2201             while (ref($res) eq "CODE") {
2202                 $res = $res->();
2203             }
2204             if (defined($res)) {
2205                 if (ref($res) eq "ARRAY") {
2206                     $found_array = 1;
2207                     @$res;
2208                 } else {
2209                     $res;
2210                 }
2211             } else {
2212                 ();
2213             }
2214     } (@_);
2215
2216     $add_called = 1;
2217
2218     if ($found_array) {
2219         [ @values ];
2220     } else {
2221         join($separator, grep { defined($_) && $_ ne "" } @values);
2222     }
2223 }
2224 sub add_before {
2225     my $separator = " ";
2226     if (ref($_[$#_]) eq "HASH") {
2227         my $opts = pop;
2228         $separator = $opts->{separator};
2229     }
2230     my @x = @_;
2231     sub { _add($separator, @x, @_) };
2232 }
2233 sub add {
2234     my $separator = " ";
2235     if (ref($_[$#_]) eq "HASH") {
2236         my $opts = pop;
2237         $separator = $opts->{separator};
2238     }
2239     my @x = @_;
2240     sub { _add($separator, @_, @x) };
2241 }
2242
2243 # configuration reader, evaluates the input file as a perl script and expects
2244 # it to fill %targets with target configurations.  Those are then added to
2245 # %table.
2246 sub read_config {
2247     my $fname = shift;
2248     open(CONFFILE, "< $fname")
2249         or die "Can't open configuration file '$fname'!\n";
2250     my $x = $/;
2251     undef $/;
2252     my $content = <CONFFILE>;
2253     $/ = $x;
2254     close(CONFFILE);
2255     my %targets = ();
2256     {
2257         # Protect certain tables from tampering
2258         local %table = %::table;
2259
2260         eval $content;
2261         warn $@ if $@;
2262     }
2263
2264     # For each target, check that it's configured with a hash table.
2265     foreach (keys %targets) {
2266         if (ref($targets{$_}) ne "HASH") {
2267             if (ref($targets{$_}) eq "") {
2268                 warn "Deprecated target configuration for $_, ignoring...\n";
2269             } else {
2270                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2271             }
2272             delete $targets{$_};
2273         } else {
2274             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2275         }
2276     }
2277
2278     %table = (%table, %targets);
2279
2280 }
2281
2282 # configuration resolver.  Will only resolve all the lazy evaluation
2283 # codeblocks for the chosen target and all those it inherits from,
2284 # recursively
2285 sub resolve_config {
2286     my $target = shift;
2287     my @breadcrumbs = @_;
2288
2289 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2290
2291     if (grep { $_ eq $target } @breadcrumbs) {
2292         die "inherit_from loop!  target backtrace:\n  "
2293             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2294     }
2295
2296     if (!defined($table{$target})) {
2297         warn "Warning! target $target doesn't exist!\n";
2298         return ();
2299     }
2300     # Recurse through all inheritances.  They will be resolved on the
2301     # fly, so when this operation is done, they will all just be a
2302     # bunch of attributes with string values.
2303     # What we get here, though, are keys with references to lists of
2304     # the combined values of them all.  We will deal with lists after
2305     # this stage is done.
2306     my %combined_inheritance = ();
2307     if ($table{$target}->{inherit_from}) {
2308         my @inherit_from =
2309             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2310         foreach (@inherit_from) {
2311             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2312
2313             # 'template' is a marker that's considered private to
2314             # the config that had it.
2315             delete $inherited_config{template};
2316
2317             foreach (keys %inherited_config) {
2318                 if (!$combined_inheritance{$_}) {
2319                     $combined_inheritance{$_} = [];
2320                 }
2321                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2322             }
2323         }
2324     }
2325
2326     # We won't need inherit_from in this target any more, since we've
2327     # resolved all the inheritances that lead to this
2328     delete $table{$target}->{inherit_from};
2329
2330     # Now is the time to deal with those lists.  Here's the place to
2331     # decide what shall be done with those lists, all based on the
2332     # values of the target we're currently dealing with.
2333     # - If a value is a coderef, it will be executed with the list of
2334     #   inherited values as arguments.
2335     # - If the corresponding key doesn't have a value at all or is the
2336     #   empty string, the inherited value list will be run through the
2337     #   default combiner (below), and the result becomes this target's
2338     #   value.
2339     # - Otherwise, this target's value is assumed to be a string that
2340     #   will simply override the inherited list of values.
2341     my $default_combiner = add();
2342
2343     my %all_keys =
2344         map { $_ => 1 } (keys %combined_inheritance,
2345                          keys %{$table{$target}});
2346
2347     sub process_values {
2348         my $object    = shift;
2349         my $inherited = shift;  # Always a [ list ]
2350         my $target    = shift;
2351         my $entry     = shift;
2352
2353         $add_called = 0;
2354
2355         while(ref($object) eq "CODE") {
2356             $object = $object->(@$inherited);
2357         }
2358         if (!defined($object)) {
2359             return ();
2360         }
2361         elsif (ref($object) eq "ARRAY") {
2362             local $add_called;  # To make sure recursive calls don't affect it
2363             return [ map { process_values($_, $inherited, $target, $entry) }
2364                      @$object ];
2365         } elsif (ref($object) eq "") {
2366             return $object;
2367         } else {
2368             die "cannot handle reference type ",ref($object)
2369                 ," found in target ",$target," -> ",$entry,"\n";
2370         }
2371     }
2372
2373     foreach (sort keys %all_keys) {
2374         my $previous = $combined_inheritance{$_};
2375
2376         # Current target doesn't have a value for the current key?
2377         # Assign it the default combiner, the rest of this loop body
2378         # will handle it just like any other coderef.
2379         if (!exists $table{$target}->{$_}) {
2380             $table{$target}->{$_} = $default_combiner;
2381         }
2382
2383         $table{$target}->{$_} = process_values($table{$target}->{$_},
2384                                                $combined_inheritance{$_},
2385                                                $target, $_);
2386         unless(defined($table{$target}->{$_})) {
2387             delete $table{$target}->{$_};
2388         }
2389 #        if ($extra_checks &&
2390 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2391 #            warn "$_ got replaced in $target\n";
2392 #        }
2393     }
2394
2395     # Finally done, return the result.
2396     return %{$table{$target}};
2397 }
2398
2399 sub usage
2400         {
2401         print STDERR $usage;
2402         print STDERR "\npick os/compiler from:\n";
2403         my $j=0;
2404         my $i;
2405         my $k=0;
2406         foreach $i (sort keys %table)
2407                 {
2408                 next if $table{$i}->{template};
2409                 next if $i =~ /^debug/;
2410                 $k += length($i) + 1;
2411                 if ($k > 78)
2412                         {
2413                         print STDERR "\n";
2414                         $k=length($i);
2415                         }
2416                 print STDERR $i . " ";
2417                 }
2418         foreach $i (sort keys %table)
2419                 {
2420                 next if $table{$i}->{template};
2421                 next if $i !~ /^debug/;
2422                 $k += length($i) + 1;
2423                 if ($k > 78)
2424                         {
2425                         print STDERR "\n";
2426                         $k=length($i);
2427                         }
2428                 print STDERR $i . " ";
2429                 }
2430         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2431         exit(1);
2432         }
2433
2434 sub run_dofile
2435 {
2436     my $out = shift;
2437     my @templates = @_;
2438
2439     unlink $out || warn "Can't remove $out, $!"
2440         if -f $out;
2441     foreach (@templates) {
2442         die "Can't open $_, $!" unless -f $_;
2443     }
2444     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2445     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2446     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2447     system($cmd);
2448     exit 1 if $? != 0;
2449     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2450 }
2451
2452 sub which
2453 {
2454     my ($name)=@_;
2455
2456     if (eval { require IPC::Cmd; 1; }) {
2457         IPC::Cmd->import();
2458         return scalar IPC::Cmd::can_run($name);
2459     } else {
2460         # if there is $directories component in splitpath,
2461         # then it's not something to test with $PATH...
2462         return $name if (File::Spec->splitpath($name))[1];
2463
2464         foreach (File::Spec->path()) {
2465             my $fullpath = catfile($_, "$name$target{exe_extension}");
2466             if (-f $fullpath and -x $fullpath) {
2467                 return $fullpath;
2468             }
2469         }
2470     }
2471 }
2472
2473 # Configuration printer ##############################################
2474
2475 sub print_table_entry
2476 {
2477     my $target = shift;
2478     my %target = resolve_config($target);
2479     my $type = shift;
2480
2481     # Don't print the templates
2482     return if $target{template};
2483
2484     my @sequence = (
2485         "sys_id",
2486         "cc",
2487         "cflags",
2488         "defines",
2489         "unistd",
2490         "ld",
2491         "lflags",
2492         "loutflag",
2493         "plib_lflags",
2494         "ex_libs",
2495         "bn_ops",
2496         "apps_aux_src",
2497         "cpuid_asm_src",
2498         "uplink_aux_src",
2499         "bn_asm_src",
2500         "ec_asm_src",
2501         "des_asm_src",
2502         "aes_asm_src",
2503         "bf_asm_src",
2504         "md5_asm_src",
2505         "cast_asm_src",
2506         "sha1_asm_src",
2507         "rc4_asm_src",
2508         "rmd160_asm_src",
2509         "rc5_asm_src",
2510         "wp_asm_src",
2511         "cmll_asm_src",
2512         "modes_asm_src",
2513         "padlock_asm_src",
2514         "chacha_asm_src",
2515         "poly1035_asm_src",
2516         "thread_scheme",
2517         "perlasm_scheme",
2518         "dso_scheme",
2519         "shared_target",
2520         "shared_cflag",
2521         "shared_defines",
2522         "shared_ldflag",
2523         "shared_rcflag",
2524         "shared_extension",
2525         "dso_extension",
2526         "obj_extension",
2527         "exe_extension",
2528         "ranlib",
2529         "ar",
2530         "arflags",
2531         "aroutflag",
2532         "rc",
2533         "rcflags",
2534         "rcoutflag",
2535         "mt",
2536         "mtflags",
2537         "mtinflag",
2538         "mtoutflag",
2539         "multilib",
2540         "build_scheme",
2541         );
2542
2543     if ($type eq "TABLE") {
2544         print "\n";
2545         print "*** $target\n";
2546         foreach (@sequence) {
2547             if (ref($target{$_}) eq "ARRAY") {
2548                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2549             } else {
2550                 printf "\$%-12s = %s\n", $_, $target{$_};
2551             }
2552         }
2553     } elsif ($type eq "HASH") {
2554         my $largest =
2555             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2556         print "    '$target' => {\n";
2557         foreach (@sequence) {
2558             if ($target{$_}) {
2559                 if (ref($target{$_}) eq "ARRAY") {
2560                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2561                 } else {
2562                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2563                 }
2564             }
2565         }
2566         print "    },\n";
2567     }
2568 }
2569
2570 # Utility routines ###################################################
2571
2572 # On VMS, if the given file is a logical name, File::Spec::Functions
2573 # will consider it an absolute path.  There are cases when we want a
2574 # purely syntactic check without checking the environment.
2575 sub isabsolute {
2576     my $file = shift;
2577
2578     # On non-platforms, we just use file_name_is_absolute().
2579     return file_name_is_absolute($file) unless $^O eq "VMS";
2580
2581     # If the file spec includes a device or a directpry spec,
2582     # file_name_is_absolute() is perfectly safe.
2583     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2584
2585     # Here, we know the given file spec isn't absolute
2586     return 0;
2587 }
2588
2589 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2590 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2591 # realpath() requires that at least all path components except the last is an
2592 # existing directory.  On VMS, the last component of the directory spec must
2593 # exist.
2594 sub absolutedir {
2595     my $dir = shift;
2596
2597     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2598     # will return the volume name for the device, no matter what.  Also,
2599     # it will return an incorrect directory spec if the argument is a
2600     # directory that doesn't exist.
2601     if ($^O eq "VMS") {
2602         return rel2abs($dir);
2603     }
2604
2605     # We use realpath() on Unix, since no other will properly clean out
2606     # a directory spec.
2607     use Cwd qw/realpath/;
2608
2609     return realpath($dir);
2610 }
2611
2612 sub quotify {
2613     my %processors = (
2614         perl    => sub { my $x = shift;
2615                          $x =~ s/([\\\$\@"])/\\$1/g;
2616                          return '"'.$x.'"'; },
2617         maybeshell => sub { my $x = shift;
2618                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2619                             if ($x ne $y || $x =~ m|\s|) {
2620                                 return '"'.$y.'"';
2621                             } else {
2622                                 return $x;
2623                             }
2624                         },
2625         );
2626     my $for = shift;
2627     my $processor =
2628         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2629
2630     return map { $processor->($_); } @_;
2631 }
2632
2633 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2634 # $filename is a file name to read from
2635 # $line_concat_cond_re is a regexp detecting a line continuation ending
2636 # $line_concat is a CODEref that takes care of concatenating two lines
2637 sub collect_from_file {
2638     my $filename = shift;
2639     my $line_concat_cond_re = shift;
2640     my $line_concat = shift;
2641
2642     open my $fh, $filename || die "unable to read $filename: $!\n";
2643     return sub {
2644         my $saved_line = "";
2645         $_ = "";
2646         while (<$fh>) {
2647             s|\R$||;
2648             if (defined $line_concat) {
2649                 $_ = $line_concat->($saved_line, $_);
2650                 $saved_line = "";
2651             }
2652             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2653                 $saved_line = $_;
2654                 next;
2655             }
2656             return $_;
2657         }
2658         die "$filename ending with continuation line\n" if $_;
2659         close $fh;
2660         return undef;
2661     }
2662 }
2663
2664 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2665 # $array is an ARRAYref of lines
2666 # $line_concat_cond_re is a regexp detecting a line continuation ending
2667 # $line_concat is a CODEref that takes care of concatenating two lines
2668 sub collect_from_array {
2669     my $array = shift;
2670     my $line_concat_cond_re = shift;
2671     my $line_concat = shift;
2672     my @array = (@$array);
2673
2674     return sub {
2675         my $saved_line = "";
2676         $_ = "";
2677         while (defined($_ = shift @array)) {
2678             s|\R$||;
2679             if (defined $line_concat) {
2680                 $_ = $line_concat->($saved_line, $_);
2681                 $saved_line = "";
2682             }
2683             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2684                 $saved_line = $_;
2685                 next;
2686             }
2687             return $_;
2688         }
2689         die "input text ending with continuation line\n" if $_;
2690         return undef;
2691     }
2692 }
2693
2694 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2695 # $lineiterator is a CODEref that delivers one line at a time.
2696 # All following arguments are regex/CODEref pairs, where the regexp detects a
2697 # line and the CODEref does something with the result of the regexp.
2698 sub collect_information {
2699     my $lineiterator = shift;
2700     my %collectors = @_;
2701
2702     while(defined($_ = $lineiterator->())) {
2703         s|\R$||;
2704         my $found = 0;
2705         if ($collectors{"BEFORE"}) {
2706             $collectors{"BEFORE"}->($_);
2707         }
2708         foreach my $re (keys %collectors) {
2709             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2710                 $collectors{$re}->($lineiterator);
2711                 $found = 1;
2712             };
2713         }
2714         if ($collectors{"OTHERWISE"}) {
2715             $collectors{"OTHERWISE"}->($lineiterator, $_)
2716                 unless $found || !defined $collectors{"OTHERWISE"};
2717         }
2718         if ($collectors{"AFTER"}) {
2719             $collectors{"AFTER"}->($_);
2720         }
2721     }
2722 }
2723
2724 # tokenize($line)
2725 # $line is a line of text to split up into tokens
2726 # returns a list of tokens
2727 #
2728 # Tokens are divided by spaces.  If the tokens include spaces, they
2729 # have to be quoted with single or double quotes.  Double quotes
2730 # inside a double quoted token must be escaped.  Escaping is done
2731 # with backslash.
2732 # Basically, the same quoting rules apply for " and ' as in any
2733 # Unix shell.
2734 sub tokenize {
2735     my $line = my $debug_line = shift;
2736     my @result = ();
2737
2738     while ($line =~ s|^\s+||, $line ne "") {
2739         my $token = "";
2740         while ($line ne "" && $line !~ m|^\s|) {
2741             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2742                 $token .= $1;
2743                 $line = $';
2744             } elsif ($line =~ m/^'([^']*)'/) {
2745                 $token .= $1;
2746                 $line = $';
2747             } elsif ($line =~ m/^(\S+)/) {
2748                 $token .= $1;
2749                 $line = $';
2750             }
2751         }
2752         push @result, $token;
2753     }
2754
2755     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2756         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2757         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2758     }
2759     return @result;
2760 }