Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2020 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL.md for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Historical: if known directories in crypto/ have been removed, it means
 269 # that those sub-systems are disabled.
 270 # (the other option would be to removed them from the SUBDIRS statement in
 271 # crypto/build.info)
 272 # We reverse the input list for cosmetic purely reasons, to compensate that
 273 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 274 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 275                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 276                         'rc2', 'rc4', 'rc5', 'ripemd', 'rsa', 'seed', 'sha',
 277                         'sm2', 'sm3', 'sm4') ) {
 278     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 279 }
 280
 281 # Collect version numbers
 282 my %version = ();
 283
 284 collect_information(
 285     collect_from_file(catfile($srcdir,'VERSION')),
 286     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 287         sub {
 288             # Only define it if there is a value at all
 289             if ($2 ne '') {
 290                 my $k = $1;
 291                 my $v = $2;
 292                 # Some values are quoted.  Trim the quotes
 293                 $v = $1 if $v =~ /^"(.*)"$/;
 294                 $version{uc $k} = $v;
 295             }
 296         },
 297     "OTHERWISE" =>
 298         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 299     );
 300
 301 $config{major} = $version{MAJOR} // 'unknown';
 302 $config{minor} = $version{MINOR} // 'unknown';
 303 $config{patch} = $version{PATCH} // 'unknown';
 304 $config{prerelease} =
 305     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 306 $config{build_metadata} =
 307     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 308 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 309 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 310
 311 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 312 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 313
 314 die "erroneous version information in VERSION: ",
 315     "$config{version}, $config{shlib_version}\n"
 316     unless (defined $version{MAJOR}
 317             && defined $version{MINOR}
 318             && defined $version{PATCH}
 319             && defined $version{SHLIB_VERSION});
 320
 321 # Collect target configurations
 322
 323 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 324 foreach (sort glob($pattern)) {
 325     &read_config($_);
 326 }
 327
 328 if (defined env($local_config_envname)) {
 329     if ($^O eq 'VMS') {
 330         # VMS environment variables are logical names,
 331         # which can be used as is
 332         $pattern = $local_config_envname . ':' . '*.conf';
 333     } else {
 334         $pattern = catfile(env($local_config_envname), '*.conf');
 335     }
 336
 337     foreach (sort glob($pattern)) {
 338         &read_config($_);
 339     }
 340 }
 341
 342 # Save away perl command information
 343 $config{perl_cmd} = $^X;
 344 $config{perl_version} = $Config{version};
 345 $config{perl_archname} = $Config{archname};
 346
 347 $config{prefix}="";
 348 $config{openssldir}="";
 349 $config{processor}="";
 350 $config{libdir}="";
 351 my $auto_threads=1;    # enable threads automatically? true by default
 352 my $default_ranlib;
 353
 354 # Known TLS and DTLS protocols
 355 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 356 my @dtls = qw(dtls1 dtls1_2);
 357
 358 # Explicitly known options that are possible to disable.  They can
 359 # be regexps, and will be used like this: /^no-${option}$/
 360 # For developers: keep it sorted alphabetically
 361
 362 my @disablables = (
 363     "acvp_tests",
 364     "afalgeng",
 365     "aria",
 366     "asan",
 367     "asm",
 368     "async",
 369     "autoalginit",
 370     "autoerrinit",
 371     "autoload-config",
 372     "bf",
 373     "blake2",
 374     "buildtest-c++",
 375     "camellia",
 376     "capieng",
 377     "cast",
 378     "chacha",
 379     "cmac",
 380     "cmp",
 381     "cms",
 382     "comp",
 383     "crypto-mdebug",
 384     "ct",
 385     "deprecated",
 386     "des",
 387     "devcryptoeng",
 388     "dgram",
 389     "dh",
 390     "dsa",
 391     "dso",
 392     "dtls",
 393     "dynamic-engine",
 394     "ec",
 395     "ec2m",
 396     "ecdh",
 397     "ecdsa",
 398     "ec_nistp_64_gcc_128",
 399     "egd",
 400     "engine",
 401     "err",
 402     "external-tests",
 403     "filenames",
 404     "fips",
 405     "fuzz-libfuzzer",
 406     "fuzz-afl",
 407     "gost",
 408     "idea",
 409     "ktls",
 410     "legacy",
 411     "makedepend",
 412     "md2",
 413     "md4",
 414     "mdc2",
 415     "module",
 416     "msan",
 417     "multiblock",
 418     "nextprotoneg",
 419     "pinshared",
 420     "ocb",
 421     "ocsp",
 422     "padlockeng",
 423     "pic",
 424     "poly1305",
 425     "posix-io",
 426     "psk",
 427     "rc2",
 428     "rc4",
 429     "rc5",
 430     "rdrand",
 431     "rfc3779",
 432     "rmd160",
 433     "scrypt",
 434     "sctp",
 435     "secure-memory",
 436     "seed",
 437     "shared",
 438     "siphash",
 439     "siv",
 440     "sm2",
 441     "sm3",
 442     "sm4",
 443     "sock",
 444     "srp",
 445     "srtp",
 446     "sse2",
 447     "ssl",
 448     "ssl-trace",
 449     "static-engine",
 450     "stdio",
 451     "tests",
 452     "threads",
 453     "tls",
 454     "trace",
 455     "ts",
 456     "ubsan",
 457     "ui-console",
 458     "unit-test",
 459     "uplink",
 460     "whirlpool",
 461     "weak-ssl-ciphers",
 462     "zlib",
 463     "zlib-dynamic",
 464     );
 465 foreach my $proto ((@tls, @dtls))
 466         {
 467         push(@disablables, $proto);
 468         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 469         }
 470
 471 # Internal disablables, for aliasing purposes.  They serve no special
 472 # purpose here, but allow scripts to get to know them through configdata.pm,
 473 # where these are merged with @disablables.
 474 # The actual aliasing mechanism is done via %disable_cascades
 475 my @disablables_int = qw(
 476     crmf
 477     );
 478
 479 my %deprecated_disablables = (
 480     "ssl2" => undef,
 481     "buf-freelists" => undef,
 482     "crypto-mdebug-backtrace" => undef,
 483     "hw" => "hw",               # causes cascade, but no macro
 484     "hw-padlock" => "padlockeng",
 485     "ripemd" => "rmd160",
 486     "ui" => "ui-console",
 487     "heartbeats" => undef,
 488     );
 489
 490 # All of the following are disabled by default:
 491
 492 our %disabled = ( # "what"         => "comment"
 493                   "asan"                => "default",
 494                   "buildtest-c++"       => "default",
 495                   "crypto-mdebug"       => "default",
 496                   "crypto-mdebug-backtrace" => "default",
 497                   "devcryptoeng"        => "default",
 498                   "ec_nistp_64_gcc_128" => "default",
 499                   "egd"                 => "default",
 500                   "external-tests"      => "default",
 501                   "fuzz-libfuzzer"      => "default",
 502                   "fuzz-afl"            => "default",
 503                   "md2"                 => "default",
 504                   "msan"                => "default",
 505                   "rc5"                 => "default",
 506                   "sctp"                => "default",
 507                   "ssl-trace"           => "default",
 508                   "ssl3"                => "default",
 509                   "ssl3-method"         => "default",
 510                   "trace"               => "default",
 511                   "ubsan"               => "default",
 512                   "unit-test"           => "default",
 513                   "weak-ssl-ciphers"    => "default",
 514                   "zlib"                => "default",
 515                   "zlib-dynamic"        => "default",
 516                   "ktls"                => "default",
 517                 );
 518
 519 # Note: => pair form used for aesthetics, not to truly make a hash table
 520 my @disable_cascades = (
 521     # "what"            => [ "cascade", ... ]
 522     sub { $config{processor} eq "386" }
 523                         => [ "sse2" ],
 524     "ssl"               => [ "ssl3" ],
 525     "ssl3-method"       => [ "ssl3" ],
 526     "zlib"              => [ "zlib-dynamic" ],
 527     "des"               => [ "mdc2" ],
 528     "ec"                => [ "ecdsa", "ecdh", "sm2", "gost" ],
 529     sub { $disabled{"ec"} && $disabled{"dh"} }
 530                         => [ "tls1_3" ],
 531     "dgram"             => [ "dtls", "sctp" ],
 532     "sock"              => [ "dgram" ],
 533     "dtls"              => [ @dtls ],
 534     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 535                         => [ "dtls" ],
 536
 537     "tls"               => [ @tls ],
 538     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 539                         => [ "tls" ],
 540
 541     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 542
 543     # If no modules, then no dynamic engines either
 544     "module"            => [ "dynamic-engine" ],
 545
 546     # Without shared libraries, dynamic engines aren't possible.
 547     # This is due to them having to link with libcrypto and register features
 548     # using the ENGINE functionality, and since that relies on global tables,
 549     # those *have* to be exacty the same as the ones accessed from the app,
 550     # which cannot be guaranteed if shared libraries aren't present.
 551     # (note that even with shared libraries, both the app and dynamic engines
 552     # must be linked with the same library)
 553     "shared"            => [ "dynamic-engine", "uplink" ],
 554     "dso"               => [ "dynamic-engine", "module" ],
 555     # Other modules don't necessarily have to link with libcrypto, so shared
 556     # libraries do not have to be a condition to produce those.
 557
 558     # Without position independent code, there can be no shared libraries
 559     # or modules.
 560     "pic"               => [ "shared", "module" ],
 561
 562     "module"            => [ "fips" ],
 563
 564     "engine"            => [ grep /eng$/, @disablables ],
 565     "hw"                => [ "padlockeng" ],
 566
 567     # no-autoalginit is only useful when building non-shared
 568     "autoalginit"       => [ "shared", "apps" ],
 569
 570     "stdio"             => [ "apps", "capieng", "egd" ],
 571     "apps"              => [ "tests" ],
 572     "tests"             => [ "external-tests" ],
 573     "comp"              => [ "zlib" ],
 574     "sm3"               => [ "sm2" ],
 575     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 576
 577     sub { !$disabled{"msan"} } => [ "asm" ],
 578
 579     sub { $disabled{cmac}; } => [ "siv" ],
 580     "legacy"                 => [ "md2" ],
 581
 582     "cmp"               => [ "crmf" ],
 583
 584     # Padlock engine uses low-level AES APIs which are deprecated
 585     sub { $disabled{"deprecated-3.0"} }
 586           => [ "padlockeng" ]
 587     );
 588
 589 # Avoid protocol support holes.  Also disable all versions below N, if version
 590 # N is disabled while N+1 is enabled.
 591 #
 592 my @list = (reverse @tls);
 593 while ((my $first, my $second) = (shift @list, shift @list)) {
 594     last unless @list;
 595     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 596                               => [ @list ] );
 597     unshift @list, $second;
 598 }
 599 my @list = (reverse @dtls);
 600 while ((my $first, my $second) = (shift @list, shift @list)) {
 601     last unless @list;
 602     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 603                               => [ @list ] );
 604     unshift @list, $second;
 605 }
 606
 607 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 608 # To remove something from %disabled, use "enable-foo".
 609 # For symmetry, "disable-foo" is a synonym for "no-foo".
 610
 611 &usage if ($#ARGV < 0);
 612
 613 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 614 # platform specific list separators.  Users from those platforms should
 615 # recognise those separators from how you set up the PATH to find executables.
 616 # The default is the Unix like separator, :, but as an exception, we also
 617 # support the space as separator.
 618 my $list_separator_re =
 619     { VMS           => qr/(?<!\^),/,
 620       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 621 # All the "make variables" we support
 622 # Some get pre-populated for the sake of backward compatibility
 623 # (we supported those before the change to "make variable" support.
 624 my %user = (
 625     AR          => env('AR'),
 626     ARFLAGS     => [],
 627     AS          => undef,
 628     ASFLAGS     => [],
 629     CC          => env('CC'),
 630     CFLAGS      => [ env('CFLAGS') || () ],
 631     CXX         => env('CXX'),
 632     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 633     CPP         => undef,
 634     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 635     CPPDEFINES  => [],  # Alternative for -D
 636     CPPINCLUDES => [],  # Alternative for -I
 637     CROSS_COMPILE => env('CROSS_COMPILE'),
 638     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 639     LD          => undef,
 640     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 641     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 642     MT          => undef,
 643     MTFLAGS     => [],
 644     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 645     RANLIB      => env('RANLIB'),
 646     RC          => env('RC') || env('WINDRES'),
 647     RCFLAGS     => [ env('RCFLAGS') || () ],
 648     RM          => undef,
 649    );
 650 # Info about what "make variables" may be prefixed with the cross compiler
 651 # prefix.  This should NEVER mention any such variable with a list for value.
 652 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 653 # The same but for flags given as Configure options.  These are *additional*
 654 # input, as opposed to the VAR=string option that override the corresponding
 655 # config target attributes
 656 my %useradd = (
 657     CPPDEFINES  => [],
 658     CPPINCLUDES => [],
 659     CPPFLAGS    => [],
 660     CFLAGS      => [],
 661     CXXFLAGS    => [],
 662     LDFLAGS     => [],
 663     LDLIBS      => [],
 664     RCFLAGS     => [],
 665    );
 666
 667 my %user_synonyms = (
 668     HASHBANGPERL=> 'PERL',
 669     RC          => 'WINDRES',
 670    );
 671
 672 # Some target attributes have been renamed, this is the translation table
 673 my %target_attr_translate =(
 674     ar          => 'AR',
 675     as          => 'AS',
 676     cc          => 'CC',
 677     cxx         => 'CXX',
 678     cpp         => 'CPP',
 679     hashbangperl => 'HASHBANGPERL',
 680     ld          => 'LD',
 681     mt          => 'MT',
 682     ranlib      => 'RANLIB',
 683     rc          => 'RC',
 684     rm          => 'RM',
 685    );
 686
 687 # Initialisers coming from 'config' scripts
 688 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 689 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 690 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 691 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 692 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 693 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 694 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 695
 696 $config{openssl_api_defines}=[];
 697 $config{openssl_sys_defines}=[];
 698 $config{openssl_feature_defines}=[];
 699 $config{options}="";
 700 $config{build_type} = "release";
 701 my $target="";
 702
 703 my %cmdvars = ();               # Stores FOO='blah' type arguments
 704 my %unsupported_options = ();
 705 my %deprecated_options = ();
 706 # If you change this, update apps/version.c
 707 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 708 my @seed_sources = ();
 709 while (@argvcopy)
 710         {
 711         $_ = shift @argvcopy;
 712
 713         # Support env variable assignments among the options
 714         if (m|^(\w+)=(.+)?$|)
 715                 {
 716                 $cmdvars{$1} = $2;
 717                 # Every time a variable is given as a configuration argument,
 718                 # it acts as a reset if the variable.
 719                 if (exists $user{$1})
 720                         {
 721                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 722                         }
 723                 #if (exists $useradd{$1})
 724                 #       {
 725                 #       $useradd{$1} = [];
 726                 #       }
 727                 next;
 728                 }
 729
 730         # VMS is a case insensitive environment, and depending on settings
 731         # out of our control, we may receive options uppercased.  Let's
 732         # downcase at least the part before any equal sign.
 733         if ($^O eq "VMS")
 734                 {
 735                 s/^([^=]*)/lc($1)/e;
 736                 }
 737
 738         # some people just can't read the instructions, clang people have to...
 739         s/^-no-(?!integrated-as)/no-/;
 740
 741         # rewrite some options in "enable-..." form
 742         s /^-?-?shared$/enable-shared/;
 743         s /^sctp$/enable-sctp/;
 744         s /^threads$/enable-threads/;
 745         s /^zlib$/enable-zlib/;
 746         s /^zlib-dynamic$/enable-zlib-dynamic/;
 747
 748         if (/^(no|disable|enable)-(.+)$/)
 749                 {
 750                 my $word = $2;
 751                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 752                         && !exists $deprecated_disablables{$word}
 753                         && !grep { $word eq $_ } @disablables)
 754                         {
 755                         $unsupported_options{$_} = 1;
 756                         next;
 757                         }
 758                 }
 759         if (/^no-(.+)$/ || /^disable-(.+)$/)
 760                 {
 761                 foreach my $proto ((@tls, @dtls))
 762                         {
 763                         if ($1 eq "$proto-method")
 764                                 {
 765                                 $disabled{"$proto"} = "option($proto-method)";
 766                                 last;
 767                                 }
 768                         }
 769                 if ($1 eq "dtls")
 770                         {
 771                         foreach my $proto (@dtls)
 772                                 {
 773                                 $disabled{$proto} = "option(dtls)";
 774                                 }
 775                         $disabled{"dtls"} = "option(dtls)";
 776                         }
 777                 elsif ($1 eq "ssl")
 778                         {
 779                         # Last one of its kind
 780                         $disabled{"ssl3"} = "option(ssl)";
 781                         }
 782                 elsif ($1 eq "tls")
 783                         {
 784                         # XXX: Tests will fail if all SSL/TLS
 785                         # protocols are disabled.
 786                         foreach my $proto (@tls)
 787                                 {
 788                                 $disabled{$proto} = "option(tls)";
 789                                 }
 790                         }
 791                 elsif ($1 eq "static-engine")
 792                         {
 793                         delete $disabled{"dynamic-engine"};
 794                         }
 795                 elsif ($1 eq "dynamic-engine")
 796                         {
 797                         $disabled{"dynamic-engine"} = "option";
 798                         }
 799                 elsif (exists $deprecated_disablables{$1})
 800                         {
 801                         $deprecated_options{$_} = 1;
 802                         if (defined $deprecated_disablables{$1})
 803                                 {
 804                                 $disabled{$deprecated_disablables{$1}} = "option";
 805                                 }
 806                         }
 807                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 808                         {
 809                         $deprecated_options{$_} = 1;
 810                         }
 811                 else
 812                         {
 813                         $disabled{$1} = "option";
 814                         }
 815                 # No longer an automatic choice
 816                 $auto_threads = 0 if ($1 eq "threads");
 817                 }
 818         elsif (/^enable-(.+)$/)
 819                 {
 820                 if ($1 eq "static-engine")
 821                         {
 822                         $disabled{"dynamic-engine"} = "option";
 823                         }
 824                 elsif ($1 eq "dynamic-engine")
 825                         {
 826                         delete $disabled{"dynamic-engine"};
 827                         }
 828                 elsif ($1 eq "zlib-dynamic")
 829                         {
 830                         delete $disabled{"zlib"};
 831                         }
 832                 my $algo = $1;
 833                 delete $disabled{$algo};
 834
 835                 # No longer an automatic choice
 836                 $auto_threads = 0 if ($1 eq "threads");
 837                 }
 838         elsif (/^--strict-warnings$/)
 839                 {
 840                 # Pretend that our strict flags is a C flag, and replace it
 841                 # with the proper flags later on
 842                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 843                 $strict_warnings=1;
 844                 }
 845         elsif (/^--debug$/)
 846                 {
 847                 $config{build_type} = "debug";
 848                 }
 849         elsif (/^--release$/)
 850                 {
 851                 $config{build_type} = "release";
 852                 }
 853         elsif (/^386$/)
 854                 { $config{processor}=386; }
 855         elsif (/^fips$/)
 856                 {
 857                 die "FIPS mode not supported\n";
 858                 }
 859         elsif (/^rsaref$/)
 860                 {
 861                 # No RSAref support any more since it's not needed.
 862                 # The check for the option is there so scripts aren't
 863                 # broken
 864                 }
 865         elsif (/^nofipscanistercheck$/)
 866                 {
 867                 die "FIPS mode not supported\n";
 868                 }
 869         elsif (m|^[-+/]|)
 870                 {
 871                 if (/^--prefix=(.*)$/)
 872                         {
 873                         $config{prefix}=$1;
 874                         die "Directory given with --prefix MUST be absolute\n"
 875                                 unless file_name_is_absolute($config{prefix});
 876                         }
 877                 elsif (/^--api=(.*)$/)
 878                         {
 879                         my $api = $1;
 880                         die "Unknown API compatibility level $api"
 881                                 unless defined $apitable->{$api};
 882                         $config{api}=$apitable->{$api};
 883                         }
 884                 elsif (/^--libdir=(.*)$/)
 885                         {
 886                         $config{libdir}=$1;
 887                         }
 888                 elsif (/^--openssldir=(.*)$/)
 889                         {
 890                         $config{openssldir}=$1;
 891                         }
 892                 elsif (/^--with-zlib-lib=(.*)$/)
 893                         {
 894                         $withargs{zlib_lib}=$1;
 895                         }
 896                 elsif (/^--with-zlib-include=(.*)$/)
 897                         {
 898                         $withargs{zlib_include}=$1;
 899                         }
 900                 elsif (/^--with-fuzzer-lib=(.*)$/)
 901                         {
 902                         $withargs{fuzzer_lib}=$1;
 903                         }
 904                 elsif (/^--with-fuzzer-include=(.*)$/)
 905                         {
 906                         $withargs{fuzzer_include}=$1;
 907                         }
 908                 elsif (/^--with-rand-seed=(.*)$/)
 909                         {
 910                         foreach my $x (split(m|,|, $1))
 911                             {
 912                             die "Unknown --with-rand-seed choice $x\n"
 913                                 if ! grep { $x eq $_ } @known_seed_sources;
 914                             push @seed_sources, $x;
 915                             }
 916                         }
 917                 elsif (/^--cross-compile-prefix=(.*)$/)
 918                         {
 919                         $user{CROSS_COMPILE}=$1;
 920                         }
 921                 elsif (/^--config=(.*)$/)
 922                         {
 923                         read_config $1;
 924                         }
 925                 elsif (/^-l(.*)$/)
 926                         {
 927                         push @{$useradd{LDLIBS}}, $_;
 928                         }
 929                 elsif (/^-framework$/)
 930                         {
 931                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 932                         }
 933                 elsif (/^-L(.*)$/ or /^-Wl,/)
 934                         {
 935                         push @{$useradd{LDFLAGS}}, $_;
 936                         }
 937                 elsif (/^-rpath$/ or /^-R$/)
 938                         # -rpath is the OSF1 rpath flag
 939                         # -R is the old Solaris rpath flag
 940                         {
 941                         my $rpath = shift(@argvcopy) || "";
 942                         $rpath .= " " if $rpath ne "";
 943                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 944                         }
 945                 elsif (/^-static$/)
 946                         {
 947                         push @{$useradd{LDFLAGS}}, $_;
 948                         }
 949                 elsif (m|^[-/]D(.*)$|)
 950                         {
 951                         push @{$useradd{CPPDEFINES}}, $1;
 952                         }
 953                 elsif (m|^[-/]I(.*)$|)
 954                         {
 955                         push @{$useradd{CPPINCLUDES}}, $1;
 956                         }
 957                 elsif (/^-Wp,$/)
 958                         {
 959                         push @{$useradd{CPPFLAGS}}, $1;
 960                         }
 961                 else    # common if (/^[-+]/), just pass down...
 962                         {
 963                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 964                         # This provides a simple way to pass options with arguments separated
 965                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 966                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 967                         push @{$useradd{CFLAGS}}, $_;
 968                         push @{$useradd{CXXFLAGS}}, $_;
 969                         }
 970                 }
 971         elsif (m|^/|)
 972                 {
 973                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 974                 # This provides a simple way to pass options with arguments separated
 975                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 976                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 977                 push @{$useradd{CFLAGS}}, $_;
 978                 push @{$useradd{CXXFLAGS}}, $_;
 979                 }
 980         else
 981                 {
 982                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 983                 $target=$_;
 984                 }
 985         unless ($_ eq $target || /^no-/ || /^disable-/)
 986                 {
 987                 # "no-..." follows later after implied deactivations
 988                 # have been derived.  (Don't take this too seriously,
 989                 # we really only write OPTIONS to the Makefile out of
 990                 # nostalgia.)
 991
 992                 if ($config{options} eq "")
 993                         { $config{options} = $_; }
 994                 else
 995                         { $config{options} .= " ".$_; }
 996                 }
 997         }
 998
 999 if (keys %deprecated_options)
1000         {
1001         warn "***** Deprecated options: ",
1002                 join(", ", keys %deprecated_options), "\n";
1003         }
1004 if (keys %unsupported_options)
1005         {
1006         die "***** Unsupported options: ",
1007                 join(", ", keys %unsupported_options), "\n";
1008         }
1009
1010 # If any %useradd entry has been set, we must check that the "make
1011 # variables" haven't been set.  We start by checking of any %useradd entry
1012 # is set.
1013 if (grep { scalar @$_ > 0 } values %useradd) {
1014     # Hash of env / make variables names.  The possible values are:
1015     # 1 - "make vars"
1016     # 2 - %useradd entry set
1017     # 3 - both set
1018     my %detected_vars =
1019         map { my $v = 0;
1020               $v += 1 if $cmdvars{$_};
1021               $v += 2 if @{$useradd{$_}};
1022               $_ => $v }
1023         keys %useradd;
1024
1025     # If any of the corresponding "make variables" is set, we error
1026     if (grep { $_ & 1 } values %detected_vars) {
1027         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1028                                sort keys %detected_vars);
1029         die <<"_____";
1030 ***** Mixing make variables and additional compiler/linker flags as
1031 ***** configure command line option is not permitted.
1032 ***** Affected make variables: $names
1033 _____
1034     }
1035 }
1036
1037 # Check through all supported command line variables to see if any of them
1038 # were set, and canonicalise the values we got.  If no compiler or linker
1039 # flag or anything else that affects %useradd was set, we also check the
1040 # environment for values.
1041 my $anyuseradd =
1042     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1043 foreach (keys %user) {
1044     my $value = $cmdvars{$_};
1045     $value //= env($_) unless $anyuseradd;
1046     $value //=
1047         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1048     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1049         unless $anyuseradd;
1050
1051     if (defined $value) {
1052         if (ref $user{$_} eq 'ARRAY') {
1053             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1054                 $user{$_} = [ split /$list_separator_re/, $value ];
1055             } else {
1056                 $user{$_} = [ $value ];
1057             }
1058         } elsif (!defined $user{$_}) {
1059             $user{$_} = $value;
1060         }
1061     }
1062 }
1063
1064 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1065     && !$disabled{shared}
1066     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1067     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1068         "***** any of asan, msan or ubsan\n";
1069 }
1070
1071 sub disable {
1072     my $disable_type = shift;
1073
1074     for (@_) {
1075         $disabled{$_} = $disable_type;
1076     }
1077
1078     my @tocheckfor = (@_ ? @_ : keys %disabled);
1079     while (@tocheckfor) {
1080         my %new_tocheckfor = ();
1081         my @cascade_copy = (@disable_cascades);
1082         while (@cascade_copy) {
1083             my ($test, $descendents) =
1084                 (shift @cascade_copy, shift @cascade_copy);
1085             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1086                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1087                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1088                 }
1089             }
1090         }
1091         @tocheckfor = (keys %new_tocheckfor);
1092     }
1093 }
1094 disable();                     # First cascade run
1095
1096 our $die = sub { die @_; };
1097 if ($target eq "TABLE") {
1098     local $die = sub { warn @_; };
1099     foreach (sort keys %table) {
1100         print_table_entry($_, "TABLE");
1101     }
1102     exit 0;
1103 }
1104
1105 if ($target eq "LIST") {
1106     foreach (sort keys %table) {
1107         print $_,"\n" unless $table{$_}->{template};
1108     }
1109     exit 0;
1110 }
1111
1112 if ($target eq "HASH") {
1113     local $die = sub { warn @_; };
1114     print "%table = (\n";
1115     foreach (sort keys %table) {
1116         print_table_entry($_, "HASH");
1117     }
1118     exit 0;
1119 }
1120
1121 print "Configuring OpenSSL version $config{full_version} ";
1122 print "for target $target\n";
1123
1124 if (scalar(@seed_sources) == 0) {
1125     print "Using os-specific seed configuration\n";
1126     push @seed_sources, 'os';
1127 }
1128 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1129     delete $disabled{'egd'};
1130 }
1131 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1132     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1133     warn <<_____ if scalar(@seed_sources) == 1;
1134
1135 ============================== WARNING ===============================
1136 You have selected the --with-rand-seed=none option, which effectively
1137 disables automatic reseeding of the OpenSSL random generator.
1138 All operations depending on the random generator such as creating keys
1139 will not work unless the random generator is seeded manually by the
1140 application.
1141
1142 Please read the 'Note on random number generation' section in the
1143 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1144 details.
1145 ============================== WARNING ===============================
1146
1147 _____
1148 }
1149 push @{$config{openssl_feature_defines}},
1150      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1151         @seed_sources;
1152
1153 # Backward compatibility?
1154 if ($target =~ m/^CygWin32(-.*)$/) {
1155     $target = "Cygwin".$1;
1156 }
1157
1158 # Support for legacy targets having a name starting with 'debug-'
1159 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1160 if ($d) {
1161     $config{build_type} = "debug";
1162
1163     # If we do not find debug-foo in the table, the target is set to foo.
1164     if (!$table{$target}) {
1165         $target = $t;
1166     }
1167 }
1168
1169 &usage if !$table{$target} || $table{$target}->{template};
1170
1171 $config{target} = $target;
1172 my %target = resolve_config($target);
1173
1174 foreach (keys %target_attr_translate) {
1175     $target{$target_attr_translate{$_}} = $target{$_}
1176         if $target{$_};
1177     delete $target{$_};
1178 }
1179
1180 %target = ( %{$table{DEFAULTS}}, %target );
1181
1182 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1183 $config{conf_files} = [ sort keys %conf_files ];
1184
1185 # Using sub disable within these loops may prove fragile, so we run
1186 # a cascade afterwards
1187 foreach my $feature (@{$target{disable}}) {
1188     if (exists $deprecated_disablables{$feature}) {
1189         warn "***** config $target disables deprecated feature $feature\n";
1190     } elsif (!grep { $feature eq $_ } @disablables) {
1191         die "***** config $target disables unknown feature $feature\n";
1192     }
1193     $disabled{$feature} = 'config';
1194 }
1195 foreach my $feature (@{$target{enable}}) {
1196     if ("default" eq ($disabled{$feature} // "")) {
1197         if (exists $deprecated_disablables{$feature}) {
1198             warn "***** config $target enables deprecated feature $feature\n";
1199         } elsif (!grep { $feature eq $_ } @disablables) {
1200             die "***** config $target enables unknown feature $feature\n";
1201         }
1202         delete $disabled{$feature};
1203     }
1204 }
1205
1206 # If uplink_arch isn't defined, disable uplink
1207 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1208 # If asm_arch isn't defined, disable asm
1209 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1210
1211 disable();                      # Run a cascade now
1212
1213 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1214 $target{cxxflags}//=$target{cflags} if $target{CXX};
1215 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1216 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1217
1218 # Fill %config with values from %user, and in case those are undefined or
1219 # empty, use values from %target (acting as a default).
1220 foreach (keys %user) {
1221     my $ref_type = ref $user{$_};
1222
1223     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1224     # and a value that's to be coerced into that type.
1225     my $mkvalue = sub {
1226         my $type = shift;
1227         my $value = shift;
1228         my $undef_p = shift;
1229
1230         die "Too many arguments for \$mkvalue" if @_;
1231
1232         while (ref $value eq 'CODE') {
1233             $value = $value->();
1234         }
1235
1236         if ($type eq 'ARRAY') {
1237             return undef unless defined $value;
1238             return undef if ref $value ne 'ARRAY' && !$value;
1239             return undef if ref $value eq 'ARRAY' && !@$value;
1240             return [ $value ] unless ref $value eq 'ARRAY';
1241         }
1242         return undef unless $value;
1243         return $value;
1244     };
1245
1246     $config{$_} =
1247         $mkvalue->($ref_type, $user{$_})
1248         || $mkvalue->($ref_type, $target{$_});
1249     delete $config{$_} unless defined $config{$_};
1250 }
1251
1252 # Finish up %config by appending things the user gave us on the command line
1253 # apart from "make variables"
1254 foreach (keys %useradd) {
1255     # The must all be lists, so we assert that here
1256     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1257         unless ref $useradd{$_} eq 'ARRAY';
1258
1259     if (defined $config{$_}) {
1260         push @{$config{$_}}, @{$useradd{$_}};
1261     } else {
1262         $config{$_} = [ @{$useradd{$_}} ];
1263     }
1264 }
1265 # At this point, we can forget everything about %user and %useradd,
1266 # because it's now all been merged into the corresponding $config entry
1267
1268 # Allow overriding the build file name
1269 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1270
1271 # Make sure build_scheme is consistent.
1272 $target{build_scheme} = [ $target{build_scheme} ]
1273     if ref($target{build_scheme}) ne "ARRAY";
1274
1275 my ($builder, $builder_platform, @builder_opts) =
1276     @{$target{build_scheme}};
1277
1278 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1279                       $builder_platform."-checker.pm")) {
1280     my $checker_path = catfile($srcdir, "Configurations", $checker);
1281     if (-f $checker_path) {
1282         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1283             ? sub { warn $@; } : sub { die $@; };
1284         if (! do $checker_path) {
1285             if ($@) {
1286                 $fn->($@);
1287             } elsif ($!) {
1288                 $fn->($!);
1289             } else {
1290                 $fn->("The detected tools didn't match the platform\n");
1291             }
1292         }
1293         last;
1294     }
1295 }
1296
1297 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1298
1299 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1300         {
1301         push @{$config{cflags}}, "-mno-cygwin";
1302         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1303         push @{$config{shared_ldflag}}, "-mno-cygwin";
1304         }
1305
1306 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1307         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1308         # minimally required architecture flags for assembly modules
1309         my $value;
1310         $value = '-mips2' if ($target =~ /mips32/);
1311         $value = '-mips3' if ($target =~ /mips64/);
1312         unshift @{$config{cflags}}, $value;
1313         unshift @{$config{cxxflags}}, $value if $config{CXX};
1314 }
1315
1316 # If threads aren't disabled, check how possible they are
1317 unless ($disabled{threads}) {
1318     if ($auto_threads) {
1319         # Enabled by default, disable it forcibly if unavailable
1320         if ($target{thread_scheme} eq "(unknown)") {
1321             disable("unavailable", 'threads');
1322         }
1323     } else {
1324         # The user chose to enable threads explicitly, let's see
1325         # if there's a chance that's possible
1326         if ($target{thread_scheme} eq "(unknown)") {
1327             # If the user asked for "threads" and we don't have internal
1328             # knowledge how to do it, [s]he is expected to provide any
1329             # system-dependent compiler options that are necessary.  We
1330             # can't truly check that the given options are correct, but
1331             # we expect the user to know what [s]He is doing.
1332             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1333                 die "You asked for multi-threading support, but didn't\n"
1334                     ,"provide any system-specific compiler options\n";
1335             }
1336         }
1337     }
1338 }
1339
1340 # Find out if clang's sanitizers have been enabled with -fsanitize
1341 # flags and ensure that the corresponding %disabled elements area
1342 # removed to reflect that the sanitizers are indeed enabled.
1343 my %detected_sanitizers = ();
1344 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1345     (my $checks = $_) =~ s/^-fsanitize=//;
1346     foreach (split /,/, $checks) {
1347         my $d = { address       => 'asan',
1348                   undefined     => 'ubsan',
1349                   memory        => 'msan' } -> {$_};
1350         next unless defined $d;
1351
1352         $detected_sanitizers{$d} = 1;
1353         if (defined $disabled{$d}) {
1354             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1355                 if $disabled{$d} ne "default";
1356             delete $disabled{$d};
1357         }
1358     }
1359 }
1360
1361 # If threads still aren't disabled, add a C macro to ensure the source
1362 # code knows about it.  Any other flag is taken care of by the configs.
1363 unless($disabled{threads}) {
1364     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1365 }
1366
1367 my $no_shared_warn=0;
1368 if ($target{shared_target} eq "")
1369         {
1370         $no_shared_warn = 1
1371             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1372         disable('no-shared-target', 'pic');
1373         }
1374
1375 if ($disabled{"dynamic-engine"}) {
1376         $config{dynamic_engines} = 0;
1377 } else {
1378         $config{dynamic_engines} = 1;
1379 }
1380
1381 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1382     push @{$config{cflags}}, "-fsanitize=address";
1383 }
1384
1385 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1386     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1387     # platforms.
1388     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1389 }
1390
1391 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1392   push @{$config{cflags}}, "-fsanitize=memory";
1393 }
1394
1395 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1396         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1397     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1398     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1399 }
1400 #
1401 # Platform fix-ups
1402 #
1403
1404 # This saves the build files from having to check
1405 if ($disabled{pic})
1406         {
1407         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1408                     shared_defines shared_includes shared_ldflag
1409                     module_cflags module_cxxflags module_cppflags
1410                     module_defines module_includes module_lflags))
1411                 {
1412                 delete $config{$_};
1413                 $target{$_} = "";
1414                 }
1415         }
1416 else
1417         {
1418         push @{$config{lib_defines}}, "OPENSSL_PIC";
1419         }
1420
1421 if ($target{sys_id} ne "")
1422         {
1423         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1424         }
1425
1426 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1427 my %predefined_CXX = $config{CXX}
1428     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1429     : ();
1430
1431 unless ($disabled{asm}) {
1432     # big endian systems can use ELFv2 ABI
1433     if ($target eq "linux-ppc64") {
1434         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1435     }
1436 }
1437
1438 # Check for makedepend capabilities.
1439 if (!$disabled{makedepend}) {
1440     if ($config{target} =~ /^(VC|vms)-/) {
1441         # For VC- and vms- targets, there's nothing more to do here.  The
1442         # functionality is hard coded in the corresponding build files for
1443         # cl (Windows) and CC/DECC (VMS).
1444     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1445              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1446         # We know that GNU C version 3 and up as well as all clang
1447         # versions support dependency generation, but Xcode did not
1448         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1449         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1450     } else {
1451         # In all other cases, we look for 'makedepend', and disable the
1452         # capability if not found.
1453         $config{makedepprog} = which('makedepend');
1454         disable('unavailable', 'makedepend') unless $config{makedepprog};
1455     }
1456 }
1457
1458 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1459     # probe for -Wa,--noexecstack option...
1460     if ($predefined_C{__clang__}) {
1461         # clang has builtin assembler, which doesn't recognize --help,
1462         # but it apparently recognizes the option in question on all
1463         # supported platforms even when it's meaningless. In other words
1464         # probe would fail, but probed option always accepted...
1465         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1466     } else {
1467         my $cc = $config{CROSS_COMPILE}.$config{CC};
1468         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1469         while(<PIPE>) {
1470             if (m/--noexecstack/) {
1471                 push @{$config{cflags}}, "-Wa,--noexecstack";
1472                 last;
1473             }
1474         }
1475         close(PIPE);
1476         unlink("null.$$.o");
1477     }
1478 }
1479
1480 # Deal with bn_ops ###################################################
1481
1482 $config{bn_ll}                  =0;
1483 my $def_int="unsigned int";
1484 $config{rc4_int}                =$def_int;
1485 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1486
1487 my $count = 0;
1488 foreach (sort split(/\s+/,$target{bn_ops})) {
1489     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1490     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1491     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1492     ($config{b64l},$config{b64},$config{b32})
1493         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1494     ($config{b64l},$config{b64},$config{b32})
1495         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1496     ($config{b64l},$config{b64},$config{b32})
1497         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1498 }
1499 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1500     if $count > 1;
1501
1502 $config{api} = $config{major} * 10000 + $config{minor} * 100
1503     unless $config{api};
1504 foreach (keys %$apitable) {
1505     $disabled{"deprecated-$_"} = "deprecation"
1506         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1507 }
1508
1509 disable();                      # Run a cascade now
1510
1511 # Hack cflags for better warnings (dev option) #######################
1512
1513 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1514 # a string and works as well on command lines.
1515 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1516                         @{$config{cflags}} ];
1517 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1518                           @{$config{cxxflags}} ] if $config{CXX};
1519
1520 $config{openssl_api_defines} = [
1521     "OPENSSL_CONFIGURED_API=".$config{api},
1522 ];
1523
1524 my @strict_warnings_collection=();
1525 if ($strict_warnings)
1526         {
1527         my $wopt;
1528         my $gccver = $predefined_C{__GNUC__} // -1;
1529
1530         if ($gccver >= 4)
1531                 {
1532                 push @strict_warnings_collection, @gcc_devteam_warn;
1533                 push @strict_warnings_collection, @clang_devteam_warn
1534                     if (defined($predefined_C{__clang__}));
1535                 }
1536         elsif ($config{target} =~ /^VC-/)
1537                 {
1538                 push @strict_warnings_collection, @cl_devteam_warn;
1539                 }
1540         else
1541                 {
1542                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1543                 }
1544         }
1545
1546 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1547     disable('static', 'pic', 'threads');
1548 }
1549
1550 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1551                               ? @strict_warnings_collection
1552                               : ( $_ ) }
1553                     @{$config{CFLAGS}} ];
1554
1555 unless ($disabled{afalgeng}) {
1556     $config{afalgeng}="";
1557     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1558         my $minver = 4*10000 + 1*100 + 0;
1559         if ($config{CROSS_COMPILE} eq "") {
1560             my $verstr = `uname -r`;
1561             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1562             ($mi2) = $mi2 =~ /(\d+)/;
1563             my $ver = $ma*10000 + $mi1*100 + $mi2;
1564             if ($ver < $minver) {
1565                 disable('too-old-kernel', 'afalgeng');
1566             } else {
1567                 push @{$config{engdirs}}, "afalg";
1568             }
1569         } else {
1570             disable('cross-compiling', 'afalgeng');
1571         }
1572     } else {
1573         disable('not-linux', 'afalgeng');
1574     }
1575 }
1576
1577 unless ($disabled{devcryptoeng}) {
1578     if ($target =~ m/^BSD/) {
1579         my $maxver = 5*100 + 7;
1580         my $sysstr = `uname -s`;
1581         my $verstr = `uname -r`;
1582         $sysstr =~ s|\R$||;
1583         $verstr =~ s|\R$||;
1584         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1585         my $ver = $ma*100 + $mi;
1586         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1587             disable('too-new-kernel', 'devcryptoeng');
1588         }
1589     }
1590 }
1591
1592 unless ($disabled{ktls}) {
1593     $config{ktls}="";
1594     if ($target =~ m/^linux/) {
1595         my $usr = "/usr/$config{cross_compile_prefix}";
1596         chop($usr);
1597         if ($config{cross_compile_prefix} eq "") {
1598             $usr = "/usr";
1599         }
1600         my $minver = (4 << 16) + (13 << 8) + 0;
1601         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1602
1603         if ($verstr[2] < $minver) {
1604             disable('too-old-kernel', 'ktls');
1605         }
1606     } elsif ($target =~ m/^BSD/) {
1607         my $cc = $config{CROSS_COMPILE}.$config{CC};
1608         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1609         if ($? != 0) {
1610             disable('too-old-freebsd', 'ktls');
1611         }
1612     } else {
1613         disable('not-linux-or-freebsd', 'ktls');
1614     }
1615 }
1616
1617 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1618
1619 # Get the extra flags used when building shared libraries and modules.  We
1620 # do this late because some of them depend on %disabled.
1621
1622 # Make the flags to build DSOs the same as for shared libraries unless they
1623 # are already defined
1624 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1625 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1626 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1627 {
1628     my $shared_info_pl =
1629         catfile(dirname($0), "Configurations", "shared-info.pl");
1630     my %shared_info = read_eval_file($shared_info_pl);
1631     push @{$target{_conf_fname_int}}, $shared_info_pl;
1632     my $si = $target{shared_target};
1633     while (ref $si ne "HASH") {
1634         last if ! defined $si;
1635         if (ref $si eq "CODE") {
1636             $si = $si->();
1637         } else {
1638             $si = $shared_info{$si};
1639         }
1640     }
1641
1642     # Some of the 'shared_target' values don't have any entries in
1643     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1644     # template knows how to handle this.  That is currently the case for
1645     # Windows and VMS.
1646     if (defined $si) {
1647         # Just as above, copy certain shared_* attributes to the corresponding
1648         # module_ attribute unless the latter is already defined
1649         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1650         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1651         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1652         foreach (sort keys %$si) {
1653             $target{$_} = defined $target{$_}
1654                 ? add($si->{$_})->($target{$_})
1655                 : $si->{$_};
1656         }
1657     }
1658 }
1659
1660 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1661
1662 ######################################################################
1663 # Build up information for skipping certain directories depending on disabled
1664 # features, as well as setting up macros for disabled features.
1665
1666 # This is a tentative database of directories to skip.  Some entries may not
1667 # correspond to anything real, but that's ok, they will simply be ignored.
1668 # The actual processing of these entries is done in the build.info lookup
1669 # loop further down.
1670 #
1671 # The key is a Unix formatted path in the source tree, the value is an index
1672 # into %disabled_info, so any existing path gets added to a corresponding
1673 # 'skipped' entry in there with the list of skipped directories.
1674 my %skipdir = ();
1675 my %disabled_info = ();         # For configdata.pm
1676 foreach my $what (sort keys %disabled) {
1677     # There are deprecated disablables that translate to themselves.
1678     # They cause disabling cascades, but should otherwise not regiter.
1679     next if $deprecated_disablables{$what};
1680     # The generated $disabled{"deprecated-x.y"} entries are special
1681     # and treated properly elsewhere
1682     next if $what =~ m|^deprecated-|;
1683
1684     $config{options} .= " no-$what";
1685
1686     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1687                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1688                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1689         (my $WHAT = uc $what) =~ s|-|_|g;
1690         my $skipdir = $what;
1691
1692         # fix-up crypto/directory name(s)
1693         $skipdir = "ripemd" if $what eq "rmd160";
1694         $skipdir = "whrlpool" if $what eq "whirlpool";
1695
1696         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1697         push @{$config{openssl_feature_defines}}, $macro;
1698
1699         $skipdir{engines} = $what if $what eq 'engine';
1700         $skipdir{"crypto/$skipdir"} = $what
1701             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1702     }
1703 }
1704
1705 if ($disabled{"dynamic-engine"}) {
1706     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1707 } else {
1708     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1709 }
1710
1711 # If we use the unified build, collect information from build.info files
1712 my %unified_info = ();
1713
1714 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1715 if ($builder eq "unified") {
1716     use Text::Template 1.46;
1717
1718     sub cleandir {
1719         my $base = shift;
1720         my $dir = shift;
1721         my $relativeto = shift || ".";
1722
1723         $dir = catdir($base,$dir) unless isabsolute($dir);
1724
1725         # Make sure the directories we're building in exists
1726         mkpath($dir);
1727
1728         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1729         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1730         return $res;
1731     }
1732
1733     sub cleanfile {
1734         my $base = shift;
1735         my $file = shift;
1736         my $relativeto = shift || ".";
1737
1738         $file = catfile($base,$file) unless isabsolute($file);
1739
1740         my $d = dirname($file);
1741         my $f = basename($file);
1742
1743         # Make sure the directories we're building in exists
1744         mkpath($d);
1745
1746         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1747         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1748         return $res;
1749     }
1750
1751     # Store the name of the template file we will build the build file from
1752     # in %config.  This may be useful for the build file itself.
1753     my @build_file_template_names =
1754         ( $builder_platform."-".$target{build_file}.".tmpl",
1755           $target{build_file}.".tmpl" );
1756     my @build_file_templates = ();
1757
1758     # First, look in the user provided directory, if given
1759     if (defined env($local_config_envname)) {
1760         @build_file_templates =
1761             map {
1762                 if ($^O eq 'VMS') {
1763                     # VMS environment variables are logical names,
1764                     # which can be used as is
1765                     $local_config_envname . ':' . $_;
1766                 } else {
1767                     catfile(env($local_config_envname), $_);
1768                 }
1769             }
1770             @build_file_template_names;
1771     }
1772     # Then, look in our standard directory
1773     push @build_file_templates,
1774         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1775           @build_file_template_names );
1776
1777     my $build_file_template;
1778     for $_ (@build_file_templates) {
1779         $build_file_template = $_;
1780         last if -f $build_file_template;
1781
1782         $build_file_template = undef;
1783     }
1784     if (!defined $build_file_template) {
1785         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1786     }
1787     $config{build_file_templates}
1788       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1789                     $blddir),
1790           $build_file_template,
1791           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1792                     $blddir) ];
1793
1794     my @build_dirs = ( [ ] );   # current directory
1795
1796     $config{build_infos} = [ ];
1797
1798     my %ordinals = ();
1799     while (@build_dirs) {
1800         my @curd = @{shift @build_dirs};
1801         my $sourced = catdir($srcdir, @curd);
1802         my $buildd = catdir($blddir, @curd);
1803
1804         my $unixdir = join('/', @curd);
1805         if (exists $skipdir{$unixdir}) {
1806             my $what = $skipdir{$unixdir};
1807             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1808             next;
1809         }
1810
1811         mkpath($buildd);
1812
1813         my $f = 'build.info';
1814         # The basic things we're trying to build
1815         my @programs = ();
1816         my @libraries = ();
1817         my @modules = ();
1818         my @scripts = ();
1819
1820         my %sources = ();
1821         my %shared_sources = ();
1822         my %includes = ();
1823         my %defines = ();
1824         my %depends = ();
1825         my %generate = ();
1826         my %htmldocs = ();
1827         my %mandocs = ();
1828
1829         # Support for $variablename in build.info files.
1830         # Embedded perl code is the ultimate master, still.  If its output
1831         # contains a dollar sign, it had better be escaped, or it will be
1832         # taken for a variable name prefix.
1833         my %variables = ();
1834         # Variable name syntax
1835         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1836         # Value modifier syntaxes
1837         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1838         # Variable reference
1839         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1840         my $variable_w_mod_re =
1841             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1842         # Tie it all together
1843         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1844
1845         my $expand_variables = sub {
1846             my $value = '';
1847             my $value_rest = shift;
1848
1849             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1850                 print STDERR
1851                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1852             }
1853
1854             while ($value_rest =~ /${variable_re}/) {
1855                 # We must save important regexp values, because the next
1856                 # regexp clears them
1857                 my $mod = $+{MOD};
1858                 my $variable_value = $variables{$+{VARIABLE}};
1859
1860                 $value_rest = $';
1861                 $value .= $`;
1862
1863                 # Process modifier expressions, if present
1864                 if (defined $mod) {
1865                     if ($mod =~ /^${variable_subst_re}$/) {
1866                         my $re = $+{RE};
1867                         my $subst = $+{SUBST};
1868
1869                         $variable_value =~ s/\Q$re\E/$subst/g;
1870
1871                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1872                             print STDERR
1873                                 "DEBUG[\$expand_variables] ... and substituted ",
1874                                 "'$re' with '$subst'\n";
1875                         }
1876                     }
1877                 }
1878
1879                 $value .= $variable_value;
1880             }
1881             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1882                 print STDERR
1883                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
1884             }
1885             return $value . $value_rest;
1886         };
1887
1888         # Support for attributes in build.info files
1889         my %attributes = ();
1890         my $handle_attributes = sub {
1891             my $attr_str = shift;
1892             my $ref = shift;
1893             my @goals = @_;
1894
1895             return unless defined $attr_str;
1896
1897             my @a = tokenize($attr_str, qr|\s*,\s*|);
1898             foreach my $a (@a) {
1899                 my $ac = 1;
1900                 my $ak = $a;
1901                 my $av = 1;
1902                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1903                     $ac = ! $1;
1904                     $ak = $1;
1905                     $av = $2;
1906                 }
1907                 foreach my $g (@goals) {
1908                     if ($ac) {
1909                         $$ref->{$g}->{$ak} = $av;
1910                     } else {
1911                         delete $$ref->{$g}->{$ak};
1912                     }
1913                 }
1914             }
1915         };
1916
1917         # Support for pushing values on multiple indexes of a given hash
1918         # array.
1919         my $push_to = sub {
1920             my $valueref = shift;
1921             my $index_str = shift; # May be undef or empty
1922             my $attrref = shift;   # May be undef
1923             my $attr_str = shift;
1924             my @values = @_;
1925
1926             if (defined $index_str) {
1927                 my @indexes = ( '' );
1928                 if ($index_str !~ m|^\s*$|) {
1929                     @indexes = tokenize($index_str);
1930                 }
1931                 foreach (@indexes) {
1932                     push @{$valueref->{$_}}, @values;
1933                     if (defined $attrref) {
1934                         $handle_attributes->($attr_str, \$$attrref->{$_},
1935                                              @values);
1936                     }
1937                 }
1938             } else {
1939                 push @$valueref, @values;
1940                 $handle_attributes->($attr_str, $attrref, @values)
1941                     if defined $attrref;
1942             }
1943         };
1944
1945         # We want to detect configdata.pm in the source tree, so we
1946         # don't use it if the build tree is different.
1947         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1948
1949
1950         if ($buildinfo_debug) {
1951             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1952         }
1953         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1954         my $template =
1955             Text::Template->new(TYPE => 'FILE',
1956                                 SOURCE => catfile($sourced, $f),
1957                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1958         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1959         my @text =
1960             split /^/m,
1961             $template->fill_in(HASH => { config => \%config,
1962                                          target => \%target,
1963                                          disabled => \%disabled,
1964                                          withargs => \%withargs,
1965                                          builddir => abs2rel($buildd, $blddir),
1966                                          sourcedir => abs2rel($sourced, $blddir),
1967                                          buildtop => abs2rel($blddir, $blddir),
1968                                          sourcetop => abs2rel($srcdir, $blddir) },
1969                                DELIMITERS => [ "{-", "-}" ]);
1970
1971         # The top item of this stack has the following values
1972         # -2 positive already run and we found ELSE (following ELSIF should fail)
1973         # -1 positive already run (skip until ENDIF)
1974         # 0 negatives so far (if we're at a condition, check it)
1975         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1976         # 2 positive ELSE (following ELSIF should fail)
1977         my @skip = ();
1978
1979         # A few useful generic regexps
1980         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1981         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1982         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1983         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1984         collect_information(
1985             collect_from_array([ @text ],
1986                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1987                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1988             # Info we're looking for
1989             qr/^\s* IF ${cond_re} \s*$/x
1990             => sub {
1991                 if (! @skip || $skip[$#skip] > 0) {
1992                     push @skip, !! $expand_variables->($+{COND});
1993                 } else {
1994                     push @skip, -1;
1995                 }
1996             },
1997             qr/^\s* ELSIF ${cond_re} \s*$/x
1998             => sub { die "ELSIF out of scope" if ! @skip;
1999                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2000                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2001                      $skip[$#skip] = !! $expand_variables->($+{COND})
2002                          if $skip[$#skip] == 0; },
2003             qr/^\s* ELSE \s*$/x
2004             => sub { die "ELSE out of scope" if ! @skip;
2005                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2006                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2007             qr/^\s* ENDIF \s*$/x
2008             => sub { die "ENDIF out of scope" if ! @skip;
2009                      pop @skip; },
2010             qr/^\s* ${variable_re} \s* = ${value_re} $/x
2011             => sub {
2012                 if (!@skip || $skip[$#skip] > 0) {
2013                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2014                 }
2015             },
2016             qr/^\s* SUBDIRS \s* = ${value_re} $/x
2017             => sub {
2018                 if (!@skip || $skip[$#skip] > 0) {
2019                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2020                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2021                     }
2022                 }
2023             },
2024             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2025             => sub { $push_to->(\@programs, undef,
2026                                 \$attributes{programs}, $+{ATTRIBS},
2027                                 tokenize($expand_variables->($+{VALUE})))
2028                          if !@skip || $skip[$#skip] > 0; },
2029             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2030             => sub { $push_to->(\@libraries, undef,
2031                                 \$attributes{libraries}, $+{ATTRIBS},
2032                                 tokenize($expand_variables->($+{VALUE})))
2033                          if !@skip || $skip[$#skip] > 0; },
2034             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2035             => sub { $push_to->(\@modules, undef,
2036                                 \$attributes{modules}, $+{ATTRIBS},
2037                                 tokenize($expand_variables->($+{VALUE})))
2038                          if !@skip || $skip[$#skip] > 0; },
2039             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2040             => sub { $push_to->(\@scripts, undef,
2041                                 \$attributes{scripts}, $+{ATTRIBS},
2042                                 tokenize($expand_variables->($+{VALUE})))
2043                          if !@skip || $skip[$#skip] > 0; },
2044             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2045             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2046                                 undef, undef,
2047                                 tokenize($expand_variables->($+{VALUE})))
2048                          if !@skip || $skip[$#skip] > 0; },
2049             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2050             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2051                                 undef, undef,
2052                                 tokenize($expand_variables->($+{VALUE})))
2053                          if !@skip || $skip[$#skip] > 0; },
2054             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
2055             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2056                                 undef, undef,
2057                                 tokenize($expand_variables->($+{VALUE})))
2058                          if !@skip || $skip[$#skip] > 0; },
2059             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
2060             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2061                                 undef, undef,
2062                                 tokenize($expand_variables->($+{VALUE})))
2063                          if !@skip || $skip[$#skip] > 0; },
2064             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2065             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2066                                 undef, undef,
2067                                 tokenize($expand_variables->($+{VALUE})))
2068                          if !@skip || $skip[$#skip] > 0; },
2069             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2070             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2071                                 undef, undef,
2072                                 tokenize($expand_variables->($+{VALUE})))
2073                          if !@skip || $skip[$#skip] > 0; },
2074             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2075             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2076                                 \$attributes{depends}, $+{ATTRIBS},
2077                                 tokenize($expand_variables->($+{VALUE})))
2078                          if !@skip || $skip[$#skip] > 0; },
2079             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2080             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2081                                 undef, undef, $+{VALUE})
2082                          if !@skip || $skip[$#skip] > 0; },
2083             qr/^\s* (?:\#.*)? $/x => sub { },
2084             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2085             "BEFORE" => sub {
2086                 if ($buildinfo_debug) {
2087                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2088                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2089                 }
2090             },
2091             "AFTER" => sub {
2092                 if ($buildinfo_debug) {
2093                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2094                 }
2095             },
2096             );
2097         die "runaway IF?" if (@skip);
2098
2099         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2100                 and !$config{dynamic_engines}) {
2101             die <<"EOF"
2102 ENGINES can only be used if configured with 'dynamic-engine'.
2103 This is usually a fault in a build.info file.
2104 EOF
2105         }
2106
2107         {
2108             my %infos = ( programs  => [ @programs  ],
2109                           libraries => [ @libraries ],
2110                           modules   => [ @modules   ],
2111                           scripts   => [ @scripts   ] );
2112             foreach my $k (keys %infos) {
2113                 foreach (@{$infos{$k}}) {
2114                     my $item = cleanfile($buildd, $_, $blddir);
2115                     $unified_info{$k}->{$item} = 1;
2116
2117                     # Fix up associated attributes
2118                     $unified_info{attributes}->{$k}->{$item} =
2119                         $attributes{$k}->{$_}
2120                         if defined $attributes{$k}->{$_};
2121                 }
2122             }
2123         }
2124
2125         # Check that we haven't defined any library as both shared and
2126         # explicitly static.  That is forbidden.
2127         my @doubles = ();
2128         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2129             (my $l = $_) =~ s/\.a$//;
2130             push @doubles, $l if defined $unified_info{libraries}->{$l};
2131         }
2132         die "these libraries are both explicitly static and shared:\n  ",
2133             join(" ", @doubles), "\n"
2134             if @doubles;
2135
2136         foreach (keys %sources) {
2137             my $dest = $_;
2138             my $ddest = cleanfile($buildd, $_, $blddir);
2139             foreach (@{$sources{$dest}}) {
2140                 my $s = cleanfile($sourced, $_, $blddir);
2141
2142                 # If it's generated or we simply don't find it in the source
2143                 # tree, we assume it's in the build tree.
2144                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2145                     $s = cleanfile($buildd, $_, $blddir);
2146                 }
2147                 # We recognise C++, C and asm files
2148                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2149                     my $o = $_;
2150                     $o =~ s/\.[csS]$/.o/; # C and assembler
2151                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2152                     $o = cleanfile($buildd, $o, $blddir);
2153                     $unified_info{sources}->{$ddest}->{$o} = -1;
2154                     $unified_info{sources}->{$o}->{$s} = -1;
2155                 } elsif ($s =~ /\.rc$/) {
2156                     # We also recognise resource files
2157                     my $o = $_;
2158                     $o =~ s/\.rc$/.res/; # Resource configuration
2159                     my $o = cleanfile($buildd, $o, $blddir);
2160                     $unified_info{sources}->{$ddest}->{$o} = -1;
2161                     $unified_info{sources}->{$o}->{$s} = -1;
2162                 } else {
2163                     $unified_info{sources}->{$ddest}->{$s} = 1;
2164                 }
2165             }
2166         }
2167
2168         foreach (keys %shared_sources) {
2169             my $dest = $_;
2170             my $ddest = cleanfile($buildd, $_, $blddir);
2171             foreach (@{$shared_sources{$dest}}) {
2172                 my $s = cleanfile($sourced, $_, $blddir);
2173
2174                 # If it's generated or we simply don't find it in the source
2175                 # tree, we assume it's in the build tree.
2176                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2177                     $s = cleanfile($buildd, $_, $blddir);
2178                 }
2179
2180                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2181                     # We recognise C++, C and asm files
2182                     my $o = $_;
2183                     $o =~ s/\.[csS]$/.o/; # C and assembler
2184                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2185                     $o = cleanfile($buildd, $o, $blddir);
2186                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2187                     $unified_info{sources}->{$o}->{$s} = -1;
2188                 } elsif ($s =~ /\.rc$/) {
2189                     # We also recognise resource files
2190                     my $o = $_;
2191                     $o =~ s/\.rc$/.res/; # Resource configuration
2192                     my $o = cleanfile($buildd, $o, $blddir);
2193                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2194                     $unified_info{sources}->{$o}->{$s} = -1;
2195                 } elsif ($s =~ /\.ld$/) {
2196                     # We also recognise linker scripts (or corresponding)
2197                     # We know they are generated files
2198                     my $ld = cleanfile($buildd, $_, $blddir);
2199                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2200                 } else {
2201                     die "unrecognised source file type for shared library: $s\n";
2202                 }
2203             }
2204         }
2205
2206         foreach (keys %generate) {
2207             my $dest = $_;
2208             my $ddest = cleanfile($buildd, $_, $blddir);
2209             die "more than one generator for $dest: "
2210                 ,join(" ", @{$generate{$_}}),"\n"
2211                 if scalar @{$generate{$_}} > 1;
2212             my @generator = split /\s+/, $generate{$dest}->[0];
2213             my $gen = $generator[0];
2214             $generator[0] = cleanfile($sourced, $gen, $blddir);
2215
2216             # If the generator is itself generated, it's in the build tree
2217             if ($generate{$gen}) {
2218                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2219             }
2220
2221             $unified_info{generate}->{$ddest} = [ @generator ];
2222         }
2223
2224         foreach (keys %depends) {
2225             my $dest = $_;
2226             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2227
2228             # If the destination doesn't exist in source, it can only be
2229             # a generated file in the build tree.
2230             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2231                 $ddest = cleanfile($buildd, $_, $blddir);
2232             }
2233             foreach (@{$depends{$dest}}) {
2234                 my $d = cleanfile($sourced, $_, $blddir);
2235
2236                 # If we know it's generated, or assume it is because we can't
2237                 # find it in the source tree, we set file we depend on to be
2238                 # in the build tree rather than the source tree.
2239                 if ($d eq $src_configdata
2240                     || (grep { $d eq $_ }
2241                         map { cleanfile($srcdir, $_, $blddir) }
2242                         grep { /\.h$/ } keys %{$unified_info{generate}})
2243                     || ! -f $d) {
2244                     $d = cleanfile($buildd, $_, $blddir);
2245                 }
2246                 $unified_info{depends}->{$ddest}->{$d} = 1;
2247
2248                 # Fix up associated attributes
2249                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2250                     $attributes{depends}->{$dest}->{$_}
2251                     if defined $attributes{depends}->{$dest}->{$_};
2252             }
2253         }
2254
2255         foreach (keys %includes) {
2256             my $dest = $_;
2257             my $ddest = cleanfile($sourced, $_, $blddir);
2258
2259             # If the destination doesn't exist in source, it can only be
2260             # a generated file in the build tree.
2261             if ($ddest eq $src_configdata || ! -f $ddest) {
2262                 $ddest = cleanfile($buildd, $_, $blddir);
2263             }
2264             foreach (@{$includes{$dest}}) {
2265                 my $is = cleandir($sourced, $_, $blddir);
2266                 my $ib = cleandir($buildd, $_, $blddir);
2267                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2268                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2269                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2270                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2271             }
2272         }
2273
2274         foreach my $dest (keys %defines) {
2275             my $ddest;
2276
2277             if ($dest ne "") {
2278                 $ddest = cleanfile($sourced, $dest, $blddir);
2279
2280                 # If the destination doesn't exist in source, it can only
2281                 # be a generated file in the build tree.
2282                 if (! -f $ddest) {
2283                     $ddest = cleanfile($buildd, $dest, $blddir);
2284                 }
2285             }
2286             foreach my $v (@{$defines{$dest}}) {
2287                 $v =~ m|^([^=]*)(=.*)?$|;
2288                 die "0 length macro name not permitted\n" if $1 eq "";
2289                 if ($dest ne "") {
2290                     die "$1 defined more than once\n"
2291                         if defined $unified_info{defines}->{$ddest}->{$1};
2292                     $unified_info{defines}->{$ddest}->{$1} = $2;
2293                 } else {
2294                     die "$1 defined more than once\n"
2295                         if grep { $v eq $_ } @{$config{defines}};
2296                     push @{$config{defines}}, $v;
2297                 }
2298             }
2299         }
2300
2301         foreach my $section (keys %htmldocs) {
2302             foreach (@{$htmldocs{$section}}) {
2303                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2304                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2305             }
2306         }
2307
2308         foreach my $section (keys %mandocs) {
2309             foreach (@{$mandocs{$section}}) {
2310                 my $mandocs = cleanfile($buildd, $_, $blddir);
2311                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2312             }
2313         }
2314     }
2315
2316     my $ordinals_text = join(', ', sort keys %ordinals);
2317     warn <<"EOF" if $ordinals_text;
2318
2319 WARNING: ORDINALS were specified for $ordinals_text
2320 They are ignored and should be replaced with a combination of GENERATE,
2321 DEPEND and SHARED_SOURCE.
2322 EOF
2323
2324
2325     # Go through the sources of all libraries and check that the same basename
2326     # doesn't appear more than once.  Some static library archivers depend on
2327     # them being unique.
2328     {
2329         my $err = 0;
2330         foreach my $prod (keys %{$unified_info{libraries}}) {
2331             my @prod_sources =
2332                 map { keys %{$unified_info{sources}->{$_}} }
2333                 keys %{$unified_info{sources}->{$prod}};
2334             my %srccnt = ();
2335
2336             # Count how many times a given each source basename
2337             # appears for each product.
2338             foreach my $src (@prod_sources) {
2339                 $srccnt{basename $src}++;
2340             }
2341
2342             foreach my $src (keys %srccnt) {
2343                 if ((my $cnt = $srccnt{$src}) > 1) {
2344                     print STDERR "$src appears $cnt times for the product $prod\n";
2345                     $err++
2346                 }
2347             }
2348         }
2349         die if $err > 0;
2350     }
2351
2352     # Massage the result
2353
2354     # If we depend on a header file or a perl module, add an inclusion of
2355     # its directory to allow smoothe inclusion
2356     foreach my $dest (keys %{$unified_info{depends}}) {
2357         next if $dest eq "";
2358         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2359             next unless $d =~ /\.(h|pm)$/;
2360             my $i = dirname($d);
2361             my $spot =
2362                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2363                 ? 'build' : 'source';
2364             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2365                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2366         }
2367     }
2368
2369     # Go through all intermediary files and change their names to something that
2370     # reflects what they will be built for.  Note that for some source files,
2371     # this leads to duplicate object files because they are used multiple times.
2372     # the goal is to rename all object files according to this scheme:
2373     #    {productname}-{midfix}-{origobjname}.[o|res]
2374     # the {midfix} is a keyword indicating the type of product, which is mostly
2375     # valuable for libraries since they come in two forms.
2376     #
2377     # This also reorganises the {sources} and {shared_sources} so that the
2378     # former only contains ALL object files that are supposed to end up in
2379     # static libraries and programs, while the latter contains ALL object files
2380     # that are supposed to end up in shared libraries and DSOs.
2381     # The main reason for having two different source structures is to allow
2382     # the same name to be used for the static and the shared variants of a
2383     # library.
2384     {
2385         # Take copies so we don't get interference from added stuff
2386         my %unified_copy = ();
2387         foreach (('sources', 'shared_sources')) {
2388             $unified_copy{$_} = { %{$unified_info{$_}} }
2389                 if defined($unified_info{$_});
2390             delete $unified_info{$_};
2391         }
2392         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2393             # $intent serves multi purposes:
2394             # - give a prefix for the new object files names
2395             # - in the case of libraries, rearrange the object files so static
2396             #   libraries use the 'sources' structure exclusively, while shared
2397             #   libraries use the 'shared_sources' structure exclusively.
2398             my $intent = {
2399                 programs  => { bin    => { src => [ 'sources' ],
2400                                            dst => 'sources' } },
2401                 libraries => { lib    => { src => [ 'sources' ],
2402                                            dst => 'sources' },
2403                                shlib  => { prodselect =>
2404                                                sub { grep !/\.a$/, @_ },
2405                                            src => [ 'sources',
2406                                                     'shared_sources' ],
2407                                            dst => 'shared_sources' } },
2408                 modules   => { dso    => { src => [ 'sources' ],
2409                                            dst => 'sources' } },
2410                 scripts   => { script => { src => [ 'sources' ],
2411                                            dst => 'sources' } }
2412                } -> {$prodtype};
2413             foreach my $kind (keys %$intent) {
2414                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2415                              && $disabled{shared});
2416
2417                 my @src = @{$intent->{$kind}->{src}};
2418                 my $dst = $intent->{$kind}->{dst};
2419                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2420                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2421                     # %prod_sources has all applicable objects as keys, and
2422                     # their corresponding sources as values
2423                     my %prod_sources =
2424                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2425                         map { keys %{$unified_copy{$_}->{$prod}} }
2426                         @src;
2427                     foreach (keys %prod_sources) {
2428                         # Only affect object files and resource files,
2429                         # the others simply get a new value
2430                         # (+1 instead of -1)
2431                         if ($_ =~ /\.(o|res)$/) {
2432                             (my $prodname = $prod) =~ s|\.a$||;
2433                             my $newobj =
2434                                 catfile(dirname($_),
2435                                         basename($prodname)
2436                                             . '-' . $kind
2437                                             . '-' . basename($_));
2438                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2439                             foreach my $src (@{$prod_sources{$_}}) {
2440                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2441                             }
2442                             # Adjust dependencies
2443                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2444                                 $unified_info{depends}->{$_}->{$deps} = -1;
2445                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2446                             }
2447                             # Adjust includes
2448                             foreach my $k (('source', 'build')) {
2449                                 next unless
2450                                     defined($unified_info{includes}->{$_}->{$k});
2451                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2452                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2453                             }
2454                         } else {
2455                             $unified_info{$dst}->{$prod}->{$_} = 1;
2456                         }
2457                     }
2458                 }
2459             }
2460         }
2461     }
2462
2463     # At this point, we have a number of sources with the value -1.  They
2464     # aren't part of the local build and are probably meant for a different
2465     # platform, and can therefore be cleaned away.  That happens when making
2466     # %unified_info more efficient below.
2467
2468     ### Make unified_info a bit more efficient
2469     # One level structures
2470     foreach (("programs", "libraries", "modules", "scripts")) {
2471         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2472     }
2473     # Two level structures
2474     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2475                      "htmldocs", "mandocs")) {
2476         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2477             my @items =
2478                 sort
2479                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2480                 keys %{$unified_info{$l1}->{$l2}};
2481             if (@items) {
2482                 $unified_info{$l1}->{$l2} = [ @items ];
2483             } else {
2484                 delete $unified_info{$l1}->{$l2};
2485             }
2486         }
2487     }
2488     # Defines
2489     foreach my $dest (sort keys %{$unified_info{defines}}) {
2490         $unified_info{defines}->{$dest}
2491             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2492                 sort keys %{$unified_info{defines}->{$dest}} ];
2493     }
2494     # Includes
2495     foreach my $dest (sort keys %{$unified_info{includes}}) {
2496         if (defined($unified_info{includes}->{$dest}->{build})) {
2497             my @source_includes = ();
2498             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2499                 if defined($unified_info{includes}->{$dest}->{source});
2500             $unified_info{includes}->{$dest} =
2501                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2502             foreach my $inc (@source_includes) {
2503                 push @{$unified_info{includes}->{$dest}}, $inc
2504                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2505             }
2506         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2507             $unified_info{includes}->{$dest} =
2508                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2509         } else {
2510             delete $unified_info{includes}->{$dest};
2511         }
2512     }
2513
2514     # For convenience collect information regarding directories where
2515     # files are generated, those generated files and the end product
2516     # they end up in where applicable.  Then, add build rules for those
2517     # directories
2518     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2519                      "dso" => [ @{$unified_info{modules}} ],
2520                      "bin" => [ @{$unified_info{programs}} ],
2521                      "script" => [ @{$unified_info{scripts}} ],
2522                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2523                                   keys %{$unified_info{htmldocs} // {}}),
2524                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2525                                   keys %{$unified_info{mandocs} // {}}) ] );
2526     foreach my $type (keys %loopinfo) {
2527         foreach my $product (@{$loopinfo{$type}}) {
2528             my %dirs = ();
2529             my $pd = dirname($product);
2530
2531             foreach (@{$unified_info{sources}->{$product} // []},
2532                      @{$unified_info{shared_sources}->{$product} // []}) {
2533                 my $d = dirname($_);
2534
2535                 # We don't want to create targets for source directories
2536                 # when building out of source
2537                 next if ($config{sourcedir} ne $config{builddir}
2538                              && $d =~ m|^\Q$config{sourcedir}\E|);
2539                 # We already have a "test" target, and the current directory
2540                 # is just silly to make a target for
2541                 next if $d eq "test" || $d eq ".";
2542
2543                 $dirs{$d} = 1;
2544                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2545                     if $d ne $pd;
2546             }
2547             foreach (keys %dirs) {
2548                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2549                     $product;
2550             }
2551         }
2552     }
2553 }
2554
2555 # For the schemes that need it, we provide the old *_obj configs
2556 # from the *_asm_obj ones
2557 foreach (grep /_(asm|aux)_src$/, keys %target) {
2558     my $src = $_;
2559     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2560     $target{$obj} = $target{$src};
2561     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2562     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2563 }
2564
2565 # Write down our configuration where it fits #########################
2566
2567 my %template_vars = (
2568     config => \%config,
2569     target => \%target,
2570     disablables => \@disablables,
2571     disablables_int => \@disablables_int,
2572     disabled => \%disabled,
2573     withargs => \%withargs,
2574     unified_info => \%unified_info,
2575     tls => \@tls,
2576     dtls => \@dtls,
2577     makevars => [ sort keys %user ],
2578     disabled_info => \%disabled_info,
2579     user_crossable => \@user_crossable,
2580 );
2581 my $configdata_outname = 'configdata.pm';
2582 print "Creating $configdata_outname\n";
2583 open CONFIGDATA, ">$configdata_outname.new"
2584             or die "Trying to create $configdata_outname.new: $!";
2585 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2586 my $configdata_tmpl =
2587     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2588 $configdata_tmpl->fill_in(
2589     FILENAME => $configdata_tmplname,
2590     OUTPUT => \*CONFIGDATA,
2591     HASH => { %template_vars,
2592               autowarntext => [
2593                   'WARNING: do not edit!',
2594                   "Generated by Configure from $configdata_tmplname",
2595               ] }
2596 ) or die $Text::Template::ERROR;
2597 close CONFIGDATA;
2598 rename "$configdata_outname.new", $configdata_outname;
2599 if ($builder_platform eq 'unix') {
2600     my $mode = (0755 & ~umask);
2601     chmod $mode, 'configdata.pm'
2602         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2603 }
2604
2605 print "Running $configdata_outname\n";
2606 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2607 my $cmd = "$perlcmd $configdata_outname";
2608 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2609 system($cmd);
2610 exit 1 if $? != 0;
2611
2612 $SIG{__DIE__} = $orig_death_handler;
2613
2614 print <<"EOF" if ($disabled{threads} eq "unavailable");
2615
2616 The library could not be configured for supporting multi-threaded
2617 applications as the compiler options required on this system are not known.
2618 See file INSTALL.md for details if you need multi-threading.
2619 EOF
2620
2621 print <<"EOF" if ($no_shared_warn);
2622
2623 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2624 platform, so we will pretend you gave the option 'no-pic', which also disables
2625 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2626 or position independent code, please let us know (but please first make sure
2627 you have tried with a current version of OpenSSL).
2628 EOF
2629
2630 print <<"EOF";
2631
2632 **********************************************************************
2633 ***                                                                ***
2634 ***   OpenSSL has been successfully configured                     ***
2635 ***                                                                ***
2636 ***   If you encounter a problem while building, please open an    ***
2637 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2638 ***   and include the output from the following command:           ***
2639 ***                                                                ***
2640 ***       perl configdata.pm --dump                                ***
2641 ***                                                                ***
2642 ***   (If you are new to OpenSSL, you might want to consult the    ***
2643 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
2644 ***                                                                ***
2645 **********************************************************************
2646 EOF
2647
2648 exit(0);
2649
2650 ######################################################################
2651 #
2652 # Helpers and utility functions
2653 #
2654
2655 # Death handler, to print a helpful message in case of failure #######
2656 #
2657 sub death_handler {
2658     die @_ if $^S;              # To prevent the added message in eval blocks
2659     my $build_file = $target{build_file} // "build file";
2660     my @message = ( <<"_____", @_ );
2661
2662 Failure!  $build_file wasn't produced.
2663 Please read INSTALL.md and associated NOTES files.  You may also have to
2664 look over your available compiler tool chain or change your configuration.
2665
2666 _____
2667
2668     # Dying is terminal, so it's ok to reset the signal handler here.
2669     $SIG{__DIE__} = $orig_death_handler;
2670     die @message;
2671 }
2672
2673 # Configuration file reading #########################################
2674
2675 # Note: All of the helper functions are for lazy evaluation.  They all
2676 # return a CODE ref, which will return the intended value when evaluated.
2677 # Thus, whenever there's mention of a returned value, it's about that
2678 # intended value.
2679
2680 # Helper function to implement conditional value variants, with a default
2681 # plus additional values based on the value of $config{build_type}.
2682 # Arguments are given in hash table form:
2683 #
2684 #       picker(default => "Basic string: ",
2685 #              debug   => "debug",
2686 #              release => "release")
2687 #
2688 # When configuring with --debug, the resulting string will be
2689 # "Basic string: debug", and when not, it will be "Basic string: release"
2690 #
2691 # This can be used to create variants of sets of flags according to the
2692 # build type:
2693 #
2694 #       cflags => picker(default => "-Wall",
2695 #                        debug   => "-g -O0",
2696 #                        release => "-O3")
2697 #
2698 sub picker {
2699     my %opts = @_;
2700     return sub { add($opts{default} || (),
2701                      $opts{$config{build_type}} || ())->(); }
2702 }
2703
2704 # Helper function to combine several values of different types into one.
2705 # This is useful if you want to combine a string with the result of a
2706 # lazy function, such as:
2707 #
2708 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2709 #
2710 sub combine {
2711     my @stuff = @_;
2712     return sub { add(@stuff)->(); }
2713 }
2714
2715 # Helper function to implement conditional values depending on the value
2716 # of $disabled{threads}.  Can be used as follows:
2717 #
2718 #       cflags => combine("-Wall", threads("-pthread"))
2719 #
2720 sub threads {
2721     my @flags = @_;
2722     return sub { add($disabled{threads} ? () : @flags)->(); }
2723 }
2724
2725 sub shared {
2726     my @flags = @_;
2727     return sub { add($disabled{shared} ? () : @flags)->(); }
2728 }
2729
2730 our $add_called = 0;
2731 # Helper function to implement adding values to already existing configuration
2732 # values.  It handles elements that are ARRAYs, CODEs and scalars
2733 sub _add {
2734     my $separator = shift;
2735
2736     # If there's any ARRAY in the collection of values OR the separator
2737     # is undef, we will return an ARRAY of combined values, otherwise a
2738     # string of joined values with $separator as the separator.
2739     my $found_array = !defined($separator);
2740
2741     my @values =
2742         map {
2743             my $res = $_;
2744             while (ref($res) eq "CODE") {
2745                 $res = $res->();
2746             }
2747             if (defined($res)) {
2748                 if (ref($res) eq "ARRAY") {
2749                     $found_array = 1;
2750                     @$res;
2751                 } else {
2752                     $res;
2753                 }
2754             } else {
2755                 ();
2756             }
2757     } (@_);
2758
2759     $add_called = 1;
2760
2761     if ($found_array) {
2762         [ @values ];
2763     } else {
2764         join($separator, grep { defined($_) && $_ ne "" } @values);
2765     }
2766 }
2767 sub add_before {
2768     my $separator = " ";
2769     if (ref($_[$#_]) eq "HASH") {
2770         my $opts = pop;
2771         $separator = $opts->{separator};
2772     }
2773     my @x = @_;
2774     sub { _add($separator, @x, @_) };
2775 }
2776 sub add {
2777     my $separator = " ";
2778     if (ref($_[$#_]) eq "HASH") {
2779         my $opts = pop;
2780         $separator = $opts->{separator};
2781     }
2782     my @x = @_;
2783     sub { _add($separator, @_, @x) };
2784 }
2785
2786 sub read_eval_file {
2787     my $fname = shift;
2788     my $content;
2789     my @result;
2790
2791     open F, "< $fname" or die "Can't open '$fname': $!\n";
2792     {
2793         undef local $/;
2794         $content = <F>;
2795     }
2796     close F;
2797     {
2798         local $@;
2799
2800         @result = ( eval $content );
2801         warn $@ if $@;
2802     }
2803     return wantarray ? @result : $result[0];
2804 }
2805
2806 # configuration reader, evaluates the input file as a perl script and expects
2807 # it to fill %targets with target configurations.  Those are then added to
2808 # %table.
2809 sub read_config {
2810     my $fname = shift;
2811     my %targets;
2812
2813     {
2814         # Protect certain tables from tampering
2815         local %table = ();
2816
2817         %targets = read_eval_file($fname);
2818     }
2819     my %preexisting = ();
2820     foreach (sort keys %targets) {
2821         $preexisting{$_} = 1 if $table{$_};
2822     }
2823     die <<"EOF",
2824 The following config targets from $fname
2825 shadow pre-existing config targets with the same name:
2826 EOF
2827         map { "  $_\n" } sort keys %preexisting
2828         if %preexisting;
2829
2830
2831     # For each target, check that it's configured with a hash table.
2832     foreach (keys %targets) {
2833         if (ref($targets{$_}) ne "HASH") {
2834             if (ref($targets{$_}) eq "") {
2835                 warn "Deprecated target configuration for $_, ignoring...\n";
2836             } else {
2837                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2838             }
2839             delete $targets{$_};
2840         } else {
2841             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2842         }
2843     }
2844
2845     %table = (%table, %targets);
2846
2847 }
2848
2849 # configuration resolver.  Will only resolve all the lazy evaluation
2850 # codeblocks for the chosen target and all those it inherits from,
2851 # recursively
2852 sub resolve_config {
2853     my $target = shift;
2854     my @breadcrumbs = @_;
2855
2856 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2857
2858     if (grep { $_ eq $target } @breadcrumbs) {
2859         die "inherit_from loop!  target backtrace:\n  "
2860             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2861     }
2862
2863     if (!defined($table{$target})) {
2864         warn "Warning! target $target doesn't exist!\n";
2865         return ();
2866     }
2867     # Recurse through all inheritances.  They will be resolved on the
2868     # fly, so when this operation is done, they will all just be a
2869     # bunch of attributes with string values.
2870     # What we get here, though, are keys with references to lists of
2871     # the combined values of them all.  We will deal with lists after
2872     # this stage is done.
2873     my %combined_inheritance = ();
2874     if ($table{$target}->{inherit_from}) {
2875         my @inherit_from =
2876             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2877         foreach (@inherit_from) {
2878             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2879
2880             # 'template' is a marker that's considered private to
2881             # the config that had it.
2882             delete $inherited_config{template};
2883
2884             foreach (keys %inherited_config) {
2885                 if (!$combined_inheritance{$_}) {
2886                     $combined_inheritance{$_} = [];
2887                 }
2888                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2889             }
2890         }
2891     }
2892
2893     # We won't need inherit_from in this target any more, since we've
2894     # resolved all the inheritances that lead to this
2895     delete $table{$target}->{inherit_from};
2896
2897     # Now is the time to deal with those lists.  Here's the place to
2898     # decide what shall be done with those lists, all based on the
2899     # values of the target we're currently dealing with.
2900     # - If a value is a coderef, it will be executed with the list of
2901     #   inherited values as arguments.
2902     # - If the corresponding key doesn't have a value at all or is the
2903     #   empty string, the inherited value list will be run through the
2904     #   default combiner (below), and the result becomes this target's
2905     #   value.
2906     # - Otherwise, this target's value is assumed to be a string that
2907     #   will simply override the inherited list of values.
2908     my $default_combiner = add();
2909
2910     my %all_keys =
2911         map { $_ => 1 } (keys %combined_inheritance,
2912                          keys %{$table{$target}});
2913
2914     sub process_values {
2915         my $object    = shift;
2916         my $inherited = shift;  # Always a [ list ]
2917         my $target    = shift;
2918         my $entry     = shift;
2919
2920         $add_called = 0;
2921
2922         while(ref($object) eq "CODE") {
2923             $object = $object->(@$inherited);
2924         }
2925         if (!defined($object)) {
2926             return ();
2927         }
2928         elsif (ref($object) eq "ARRAY") {
2929             local $add_called;  # To make sure recursive calls don't affect it
2930             return [ map { process_values($_, $inherited, $target, $entry) }
2931                      @$object ];
2932         } elsif (ref($object) eq "") {
2933             return $object;
2934         } else {
2935             die "cannot handle reference type ",ref($object)
2936                 ," found in target ",$target," -> ",$entry,"\n";
2937         }
2938     }
2939
2940     foreach (sort keys %all_keys) {
2941         my $previous = $combined_inheritance{$_};
2942
2943         # Current target doesn't have a value for the current key?
2944         # Assign it the default combiner, the rest of this loop body
2945         # will handle it just like any other coderef.
2946         if (!exists $table{$target}->{$_}) {
2947             $table{$target}->{$_} = $default_combiner;
2948         }
2949
2950         $table{$target}->{$_} = process_values($table{$target}->{$_},
2951                                                $combined_inheritance{$_},
2952                                                $target, $_);
2953         unless(defined($table{$target}->{$_})) {
2954             delete $table{$target}->{$_};
2955         }
2956 #        if ($extra_checks &&
2957 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2958 #            warn "$_ got replaced in $target\n";
2959 #        }
2960     }
2961
2962     # Finally done, return the result.
2963     return %{$table{$target}};
2964 }
2965
2966 sub usage
2967         {
2968         print STDERR $usage;
2969         print STDERR "\npick os/compiler from:\n";
2970         my $j=0;
2971         my $i;
2972         my $k=0;
2973         foreach $i (sort keys %table)
2974                 {
2975                 next if $table{$i}->{template};
2976                 next if $i =~ /^debug/;
2977                 $k += length($i) + 1;
2978                 if ($k > 78)
2979                         {
2980                         print STDERR "\n";
2981                         $k=length($i);
2982                         }
2983                 print STDERR $i . " ";
2984                 }
2985         foreach $i (sort keys %table)
2986                 {
2987                 next if $table{$i}->{template};
2988                 next if $i !~ /^debug/;
2989                 $k += length($i) + 1;
2990                 if ($k > 78)
2991                         {
2992                         print STDERR "\n";
2993                         $k=length($i);
2994                         }
2995                 print STDERR $i . " ";
2996                 }
2997         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2998         exit(1);
2999         }
3000
3001 sub compiler_predefined {
3002     state %predefined;
3003     my $cc = shift;
3004
3005     return () if $^O eq 'VMS';
3006
3007     die 'compiler_predefined called without a compiler command'
3008         unless $cc;
3009
3010     if (! $predefined{$cc}) {
3011
3012         $predefined{$cc} = {};
3013
3014         # collect compiler pre-defines from gcc or gcc-alike...
3015         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3016         while (my $l = <PIPE>) {
3017             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3018             $predefined{$cc}->{$1} = $2 // '';
3019         }
3020         close(PIPE);
3021     }
3022
3023     return %{$predefined{$cc}};
3024 }
3025
3026 sub which
3027 {
3028     my ($name)=@_;
3029
3030     if (eval { require IPC::Cmd; 1; }) {
3031         IPC::Cmd->import();
3032         return scalar IPC::Cmd::can_run($name);
3033     } else {
3034         # if there is $directories component in splitpath,
3035         # then it's not something to test with $PATH...
3036         return $name if (File::Spec->splitpath($name))[1];
3037
3038         foreach (File::Spec->path()) {
3039             my $fullpath = catfile($_, "$name$target{exe_extension}");
3040             if (-f $fullpath and -x $fullpath) {
3041                 return $fullpath;
3042             }
3043         }
3044     }
3045 }
3046
3047 sub env
3048 {
3049     my $name = shift;
3050     my %opts = @_;
3051
3052     unless ($opts{cacheonly}) {
3053         # Note that if $ENV{$name} doesn't exist or is undefined,
3054         # $config{perlenv}->{$name} will be created with the value
3055         # undef.  This is intentional.
3056
3057         $config{perlenv}->{$name} = $ENV{$name}
3058             if ! exists $config{perlenv}->{$name};
3059     }
3060     return $config{perlenv}->{$name};
3061 }
3062
3063 # Configuration printer ##############################################
3064
3065 sub print_table_entry
3066 {
3067     local $now_printing = shift;
3068     my %target = resolve_config($now_printing);
3069     my $type = shift;
3070
3071     # Don't print the templates
3072     return if $target{template};
3073
3074     my @sequence = (
3075         "sys_id",
3076         "cpp",
3077         "cppflags",
3078         "defines",
3079         "includes",
3080         "cc",
3081         "cflags",
3082         "ld",
3083         "lflags",
3084         "loutflag",
3085         "ex_libs",
3086         "bn_ops",
3087         "poly1035_asm_src",
3088         "thread_scheme",
3089         "perlasm_scheme",
3090         "dso_scheme",
3091         "shared_target",
3092         "shared_cflag",
3093         "shared_defines",
3094         "shared_ldflag",
3095         "shared_rcflag",
3096         "shared_extension",
3097         "dso_extension",
3098         "obj_extension",
3099         "exe_extension",
3100         "ranlib",
3101         "ar",
3102         "arflags",
3103         "aroutflag",
3104         "rc",
3105         "rcflags",
3106         "rcoutflag",
3107         "mt",
3108         "mtflags",
3109         "mtinflag",
3110         "mtoutflag",
3111         "multilib",
3112         "build_scheme",
3113         );
3114
3115     if ($type eq "TABLE") {
3116         print "\n";
3117         print "*** $now_printing\n";
3118         foreach (@sequence) {
3119             if (ref($target{$_}) eq "ARRAY") {
3120                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3121             } else {
3122                 printf "\$%-12s = %s\n", $_, $target{$_};
3123             }
3124         }
3125     } elsif ($type eq "HASH") {
3126         my $largest =
3127             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3128         print "    '$now_printing' => {\n";
3129         foreach (@sequence) {
3130             if ($target{$_}) {
3131                 if (ref($target{$_}) eq "ARRAY") {
3132                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3133                 } else {
3134                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3135                 }
3136             }
3137         }
3138         print "    },\n";
3139     }
3140 }
3141
3142 # Utility routines ###################################################
3143
3144 # On VMS, if the given file is a logical name, File::Spec::Functions
3145 # will consider it an absolute path.  There are cases when we want a
3146 # purely syntactic check without checking the environment.
3147 sub isabsolute {
3148     my $file = shift;
3149
3150     # On non-platforms, we just use file_name_is_absolute().
3151     return file_name_is_absolute($file) unless $^O eq "VMS";
3152
3153     # If the file spec includes a device or a directory spec,
3154     # file_name_is_absolute() is perfectly safe.
3155     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3156
3157     # Here, we know the given file spec isn't absolute
3158     return 0;
3159 }
3160
3161 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3162 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3163 # realpath() requires that at least all path components except the last is an
3164 # existing directory.  On VMS, the last component of the directory spec must
3165 # exist.
3166 sub absolutedir {
3167     my $dir = shift;
3168
3169     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3170     # will return the volume name for the device, no matter what.  Also,
3171     # it will return an incorrect directory spec if the argument is a
3172     # directory that doesn't exist.
3173     if ($^O eq "VMS") {
3174         return rel2abs($dir);
3175     }
3176
3177     # We use realpath() on Unix, since no other will properly clean out
3178     # a directory spec.
3179     use Cwd qw/realpath/;
3180
3181     return realpath($dir);
3182 }
3183
3184 sub quotify {
3185     my %processors = (
3186         perl    => sub { my $x = shift;
3187                          $x =~ s/([\\\$\@"])/\\$1/g;
3188                          return '"'.$x.'"'; },
3189         maybeshell => sub { my $x = shift;
3190                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3191                             if ($x ne $y || $x =~ m|\s|) {
3192                                 return '"'.$y.'"';
3193                             } else {
3194                                 return $x;
3195                             }
3196                         },
3197         );
3198     my $for = shift;
3199     my $processor =
3200         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3201
3202     return map { $processor->($_); } @_;
3203 }
3204
3205 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3206 # $filename is a file name to read from
3207 # $line_concat_cond_re is a regexp detecting a line continuation ending
3208 # $line_concat is a CODEref that takes care of concatenating two lines
3209 sub collect_from_file {
3210     my $filename = shift;
3211     my $line_concat_cond_re = shift;
3212     my $line_concat = shift;
3213
3214     open my $fh, $filename || die "unable to read $filename: $!\n";
3215     return sub {
3216         my $saved_line = "";
3217         $_ = "";
3218         while (<$fh>) {
3219             s|\R$||;
3220             if (defined $line_concat) {
3221                 $_ = $line_concat->($saved_line, $_);
3222                 $saved_line = "";
3223             }
3224             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3225                 $saved_line = $_;
3226                 next;
3227             }
3228             return $_;
3229         }
3230         die "$filename ending with continuation line\n" if $_;
3231         close $fh;
3232         return undef;
3233     }
3234 }
3235
3236 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3237 # $array is an ARRAYref of lines
3238 # $line_concat_cond_re is a regexp detecting a line continuation ending
3239 # $line_concat is a CODEref that takes care of concatenating two lines
3240 sub collect_from_array {
3241     my $array = shift;
3242     my $line_concat_cond_re = shift;
3243     my $line_concat = shift;
3244     my @array = (@$array);
3245
3246     return sub {
3247         my $saved_line = "";
3248         $_ = "";
3249         while (defined($_ = shift @array)) {
3250             s|\R$||;
3251             if (defined $line_concat) {
3252                 $_ = $line_concat->($saved_line, $_);
3253                 $saved_line = "";
3254             }
3255             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3256                 $saved_line = $_;
3257                 next;
3258             }
3259             return $_;
3260         }
3261         die "input text ending with continuation line\n" if $_;
3262         return undef;
3263     }
3264 }
3265
3266 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3267 # $lineiterator is a CODEref that delivers one line at a time.
3268 # All following arguments are regex/CODEref pairs, where the regexp detects a
3269 # line and the CODEref does something with the result of the regexp.
3270 sub collect_information {
3271     my $lineiterator = shift;
3272     my %collectors = @_;
3273
3274     while(defined($_ = $lineiterator->())) {
3275         s|\R$||;
3276         my $found = 0;
3277         if ($collectors{"BEFORE"}) {
3278             $collectors{"BEFORE"}->($_);
3279         }
3280         foreach my $re (keys %collectors) {
3281             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3282                 $collectors{$re}->($lineiterator);
3283                 $found = 1;
3284             };
3285         }
3286         if ($collectors{"OTHERWISE"}) {
3287             $collectors{"OTHERWISE"}->($lineiterator, $_)
3288                 unless $found || !defined $collectors{"OTHERWISE"};
3289         }
3290         if ($collectors{"AFTER"}) {
3291             $collectors{"AFTER"}->($_);
3292         }
3293     }
3294 }
3295
3296 # tokenize($line)
3297 # tokenize($line,$separator)
3298 # $line is a line of text to split up into tokens
3299 # $separator [optional] is a regular expression that separates the tokens,
3300 # the default being spaces.  Do not use quotes of any kind as separators,
3301 # that will give undefined results.
3302 # Returns a list of tokens.
3303 #
3304 # Tokens are divided by separator (spaces by default).  If the tokens include
3305 # the separators, they have to be quoted with single or double quotes.
3306 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3307 # with backslash.
3308 # Basically, the same quoting rules apply for " and ' as in any
3309 # Unix shell.
3310 sub tokenize {
3311     my $line = my $debug_line = shift;
3312     my $separator = shift // qr|\s+|;
3313     my @result = ();
3314
3315     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3316         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3317     }
3318
3319     while ($line =~ s|^${separator}||, $line ne "") {
3320         my $token = "";
3321     again:
3322         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3323         $token .= $1;
3324         $line = $2.$';
3325
3326         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3327             $token .= $1;
3328             $line = $';
3329             goto again;
3330         } elsif ($line =~ m/^'([^']*)'/) {
3331             $token .= $1;
3332             $line = $';
3333             goto again;
3334         }
3335         push @result, $token;
3336     }
3337
3338     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3339         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3340         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3341     }
3342     return @result;
3343 }