Don't check the conditions to build e_afalg if configured "no-engine"
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3
4 ##
5 ##  Configure -- OpenSSL source tree configuration script
6 ##  If editing this file, run this command before committing
7 ##      make -f Makefile.in TABLE
8 ##
9
10 require 5.000;
11 use strict;
12 use File::Basename;
13 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
14 use File::Path qw/mkpath/;
15
16 # see INSTALL for instructions.
17
18 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
19
20 # Options:
21 #
22 # --config      add the given configuration file, which will be read after
23 #               any "Configurations*" files that are found in the same
24 #               directory as this script.
25 # --prefix      prefix for the OpenSSL installation, which includes the
26 #               directories bin, lib, include, share/man, share/doc/openssl
27 #               This becomes the value of INSTALLTOP in Makefile
28 #               (Default: /usr/local)
29 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
30 #               If it's a relative directory, it will be added on the directory
31 #               given with --prefix.
32 #               This becomes the value of OPENSSLDIR in Makefile and in C.
33 #               (Default: PREFIX/ssl)
34 #
35 # --cross-compile-prefix Add specified prefix to binutils components.
36 #
37 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
38 #               interfaces deprecated as of the specified OpenSSL version.
39 #
40 # no-hw-xxx     do not compile support for specific crypto hardware.
41 #               Generic OpenSSL-style methods relating to this support
42 #               are always compiled but return NULL if the hardware
43 #               support isn't compiled.
44 # no-hw         do not compile support for any crypto hardware.
45 # [no-]threads  [don't] try to create a library that is suitable for
46 #               multithreaded applications (default is "threads" if we
47 #               know how to do it)
48 # [no-]shared   [don't] try to create shared libraries when supported.
49 # [no-]pic      [don't] try to build position independent code when supported.
50 #               If disabled, it also disables shared and dynamic-engine.
51 # no-asm        do not use assembler
52 # no-dso        do not compile in any native shared-library methods. This
53 #               will ensure that all methods just return NULL.
54 # no-egd        do not compile support for the entropy-gathering daemon APIs
55 # [no-]zlib     [don't] compile support for zlib compression.
56 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
57 #               library and will be loaded in run-time by the OpenSSL library.
58 # sctp          include SCTP support
59 # 386           generate 80386 code
60 # enable-weak-ssl-ciphers
61 #               Enable weak ciphers that are disabled by default. This currently
62 #               only includes RC4 based ciphers.
63 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
64 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
65 # -<xxx> +<xxx> compiler options are passed through
66 #
67 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
68 #               provided to stack calls. Generates unique stack functions for
69 #               each possible stack type.
70 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
71 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
72 # Following are set automatically by this script
73 #
74 # MD5_ASM       use some extra md5 assember,
75 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
76 # RMD160_ASM    use some extra ripemd160 assember,
77 # SHA256_ASM    sha256_block is implemented in assembler
78 # SHA512_ASM    sha512_block is implemented in assembler
79 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
80
81 # Minimum warning options... any contributions to OpenSSL should at least get
82 # past these.
83
84 my $gcc_devteam_warn = "-DPEDANTIC -DREF_DEBUG -DDEBUG_UNUSED -DBIO_DEBUG"
85         . " -pedantic"
86         . " -Wall"
87         . " -Wno-long-long"
88         . " -Wsign-compare"
89         . " -Wmissing-prototypes"
90         . " -Wshadow"
91         . " -Wformat"
92         . " -Wtype-limits"
93         . " -Werror"
94         ;
95
96 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
97 # TODO(openssl-team): fix problems and investigate if (at least) the
98 # following warnings can also be enabled:
99 #       -Wswitch-enum
100 #       -Wcast-align
101 #       -Wunreachable-code
102 #       -Wlanguage-extension-token -- no, we use asm()
103 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
104 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
105 my $clang_devteam_warn = ""
106         . " -Qunused-arguments"
107         . " -Wextra"
108         . " -Wno-unused-parameter"
109         . " -Wno-missing-field-initializers"
110         . " -Wno-language-extension-token"
111         . " -Wno-extended-offsetof"
112         . " -Wconditional-uninitialized"
113         . " -Wincompatible-pointer-types-discards-qualifiers"
114         . " -Wmissing-variable-declarations"
115         ;
116
117 # This adds backtrace information to the memory leak info.  Is only used
118 # when crypto-mdebug-backtrace is enabled.
119 my $memleak_devteam_backtrace = "-rdynamic";
120
121 my $strict_warnings = 0;
122
123 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
124 # which would cover all BSD flavors. -pthread applies to them all,
125 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
126 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
127 # which has to be accompanied by explicit -D_THREAD_SAFE and
128 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
129 # seems to be sufficient?
130 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
131
132 #
133 # API compability name to version number mapping.
134 #
135 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
136 my $apitable = {
137     "1.1.0" => "0x10100000L",
138     "1.0.0" => "0x10000000L",
139     "0.9.8" => "0x00908000L",
140 };
141
142 our %table = ();
143 our %config = ();
144 our %withargs = ();
145
146 # Forward declarations ###############################################
147
148 # read_config(filename)
149 #
150 # Reads a configuration file and populates %table with the contents
151 # (which the configuration file places in %targets).
152 sub read_config;
153
154 # resolve_config(target)
155 #
156 # Resolves all the late evalutations, inheritances and so on for the
157 # chosen target and any target it inherits from.
158 sub resolve_config;
159
160
161 # Information collection #############################################
162
163 # Unified build supports separate build dir
164 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
165 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
166 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
167
168 $config{sourcedir} = abs2rel($srcdir);
169 $config{builddir} = abs2rel($blddir);
170
171 # Collect version numbers
172 $config{version} = "unknown";
173 $config{version_num} = "unknown";
174 $config{shlib_version_number} = "unknown";
175 $config{shlib_version_history} = "unknown";
176
177 collect_information(
178     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
179     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
180     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
181     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
182     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
183     );
184 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
185
186 ($config{major}, $config{minor})
187     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
188 ($config{shlib_major}, $config{shlib_minor})
189     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
190 die "erroneous version information in opensslv.h: ",
191     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
192     if ($config{major} eq "" || $config{minor} eq ""
193         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
194
195 # Collect target configurations
196
197 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
198 foreach (sort glob($pattern) ) {
199     &read_config($_);
200 }
201
202
203 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
204
205 $config{perl};
206 $config{prefix}="";
207 $config{openssldir}="";
208 $config{processor}="";
209 $config{libdir}="";
210 $config{cross_compile_prefix}="";
211 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
212 my $nofipscanistercheck=0;
213 $config{baseaddr}="0xFB00000";
214 my $auto_threads=1;    # enable threads automatically? true by default
215 my $default_ranlib;
216 $config{fips}=0;
217
218 # Top level directories to build
219 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
220 # crypto/ subdirectories to build
221 $config{sdirs} = [
222     "objects",
223     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305",
224     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
225     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
226     "buffer", "bio", "stack", "lhash", "rand", "err",
227     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
228     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
229     ];
230
231 # Known TLS and DTLS protocols
232 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
233 my @dtls = qw(dtls1 dtls1_2);
234
235 # Explicitelly known options that are possible to disable.  They can
236 # be regexps, and will be used like this: /^no-${option}$/
237 # For developers: keep it sorted alphabetically
238
239 my @disablables = (
240     "aes",
241     "asm",
242     "async",
243     "autoalginit",
244     "autoerrinit",
245     "bf",
246     "camellia",
247     "capieng",
248     "cast",
249     "chacha",
250     "cmac",
251     "cms",
252     "comp",
253     "crypto-mdebug",
254     "crypto-mdebug-backtrace",
255     "ct",
256     "deprecated",
257     "des",
258     "dgram",
259     "dh",
260     "dsa",
261     "dso",
262     "dtls",
263     "dynamic-engine",
264     "ec",
265     "ec2m",
266     "ecdh",
267     "ecdsa",
268     "ec_nistp_64_gcc_128",
269     "egd",
270     "engine",
271     "err",
272     "filenames",
273     "heartbeats",
274     "hmac",
275     "hw(-.+)?",
276     "idea",
277     "locking",
278     "makedepend",
279     "md2",
280     "md4",
281     "md5",
282     "mdc2",
283     "md[-_]ghost94",
284     "multiblock",
285     "nextprotoneg",
286     "ocb",
287     "ocsp",
288     "pic",
289     "poly1305",
290     "posix-io",
291     "psk",
292     "rc2",
293     "rc4",
294     "rc5",
295     "rdrand",
296     "rfc3779",
297     "rijndael",                 # Old AES name
298     "ripemd",
299     "rmd160",
300     "rsa",
301     "scrypt",
302     "sct",
303     "sctp",
304     "seed",
305     "sha",
306     "shared",
307     "sock",
308     "srp",
309     "srtp",
310     "sse2",
311     "ssl",
312     "ssl-trace",
313     "static-engine",
314     "stdio",
315     "threads",
316     "tls",
317     "ts",
318     "ui",
319     "unit-test",
320     "whirlpool",
321     "weak-ssl-ciphers",
322     "zlib",
323     "zlib-dynamic",
324     );
325 foreach my $proto ((@tls, @dtls))
326         {
327         push(@disablables, $proto);
328         push(@disablables, "$proto-method");
329         }
330
331 my @deprecated_disablables = (
332     "ssl2",
333     );
334
335 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
336
337 our %disabled = ( # "what"         => "comment"
338                   "ec_nistp_64_gcc_128" => "default",
339                   "egd"                 => "default",
340                   "md2"                 => "default",
341                   "rc5"                 => "default",
342                   "sctp"                => "default",
343                   "shared"              => "default",
344                   "ssl-trace"           => "default",
345                   "ssl3"                => "default",
346                   "ssl3-method"         => "default",
347                   "static-engine"       => "default",
348                   "unit-test"           => "default",
349                   "weak-ssl-ciphers"    => "default",
350                   "zlib"                => "default",
351                   "zlib-dynamic"        => "default",
352                   "crypto-mdebug"       => "default",
353                   "heartbeats"          => "default",
354                 );
355
356 # Note: => pair form used for aesthetics, not to truly make a hash table
357 my @disable_cascades = (
358     # "what"            => [ "cascade", ... ]
359     sub { $config{processor} eq "386" }
360                         => [ "sse2" ],
361     "ssl"               => [ "ssl3" ],
362     "ssl3-method"       => [ "ssl3" ],
363     "zlib"              => [ "zlib-dynamic" ],
364     "rijndael"          => [ "aes" ],
365     "des"               => [ "mdc2" ],
366     "ec"                => [ "ecdsa", "ecdh" ],
367
368     "dgram"             => [ "dtls" ],
369     "dtls"              => [ @dtls ],
370
371     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
372     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
373     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
374
375     # Additionally, SSL 3.0 requires either RSA or DSA+DH
376     sub { $disabled{rsa}
377           && ($disabled{dsa} || $disabled{dh}); }
378                         => [ "ssl" ],
379
380     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
381     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
382     # (XXX: We don't support PSK-only builds).
383     sub { $disabled{rsa}
384           && ($disabled{dsa} || $disabled{dh})
385           && ($disabled{ecdsa} || $disabled{ecdh}); }
386                         => [ "tls1", "tls1_1", "tls1_2",
387                              "dtls1", "dtls1_2" ],
388
389     "tls"               => [ @tls ],
390
391     # SRP and HEARTBEATS require TLSEXT
392     "tlsext"            => [ "srp", "heartbeats" ],
393
394     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
395
396     # Without DSO, we can't load dynamic engines, so don't build them dynamic
397     "dso"               => [ "dynamic-engine" ],
398
399     # Without position independent code, there can be no shared libraries or DSOs
400     "pic"               => [ "shared", "dynamic-engine" ],
401     );
402
403 # Avoid protocol support holes.  Also disable all versions below N, if version
404 # N is disabled while N+1 is enabled.
405 #
406 my @list = (reverse @tls);
407 while ((my $first, my $second) = (shift @list, shift @list)) {
408     last unless @list;
409     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
410                               => [ @list ] );
411     unshift @list, $second;
412 }
413 my @list = (reverse @dtls);
414 while ((my $first, my $second) = (shift @list, shift @list)) {
415     last unless @list;
416     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
417                               => [ @list ] );
418     unshift @list, $second;
419 }
420
421 # Explicit "no-..." options will be collected in %disabled along with the defaults.
422 # To remove something from %disabled, use "enable-foo".
423 # For symmetry, "disable-foo" is a synonym for "no-foo".
424
425 my @generated_headers = (
426     "include/openssl/opensslconf.h",
427     "crypto/include/internal/bn_conf.h",
428     "crypto/include/internal/dso_conf.h"
429     );
430
431 my @generated_by_make_headers = (
432     "crypto/buildinf.h"
433     );
434
435
436 my $no_sse2=0;
437
438 &usage if ($#ARGV < 0);
439
440 my $user_cflags="";
441 my @user_defines=();
442 $config{openssl_api_defines}=[];
443 $config{openssl_algorithm_defines}=[];
444 $config{openssl_thread_defines}=[];
445 $config{openssl_sys_defines}=[];
446 $config{openssl_other_defines}=[];
447 my $libs="";
448 my $target="";
449 $config{options}="";
450 $config{build_type} = "release";
451
452 my $classic = 0;
453
454 my @argvcopy=@ARGV;
455
456 if (grep /^reconf(igure)?$/, @argvcopy) {
457     if (-f "./configdata.pm") {
458         my $file = "./configdata.pm";
459         unless (my $return = do $file) {
460             die "couldn't parse $file: $@" if $@;
461             die "couldn't do $file: $!"    unless defined $return;
462             die "couldn't run $file"       unless $return;
463         }
464
465         @argvcopy = defined($configdata::config{perlargv}) ?
466             @{$configdata::config{perlargv}} : ();
467         die "Incorrect data to reconfigure, please do a normal configuration\n"
468             if (grep(/^reconf/,@argvcopy));
469         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
470             if defined($configdata::config{cross_compile_prefix});
471         $ENV{CROSS_COMPILE} = $configdata::config{cc}
472             if defined($configdata::config{cc});
473
474         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
475         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
476             if $ENV{CROSS_COMPILE};
477         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
478     } elsif (open IN, "<Makefile") {
479         #
480         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
481         # centered information gathering the reading configdata.pm
482         #
483         while (<IN>) {
484             s|\R$||;
485             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
486                 # Older form, we split the string and hope for the best
487                 @argvcopy = split /\s+/, $_;
488                 die "Incorrect data to reconfigure, please do a normal configuration\n"
489                     if (grep(/^reconf/,@argvcopy));
490             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
491                 $ENV{CROSS_COMPILE}=$1;
492             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
493                 $ENV{CC}=$1;
494             }
495         }
496         #
497         # END OF TEMPORARY SECTION
498         #
499     } else {
500         die "Insufficient data to reconfigure, please do a normal configuration\n";
501     }
502 }
503
504 $config{perlargv} = [ @argvcopy ];
505
506 my %unsupported_options = ();
507 my %deprecated_options = ();
508 foreach (@argvcopy)
509         {
510         # VMS is a case insensitive environment, and depending on settings
511         # out of our control, we may receive options uppercased.  Let's
512         # downcase at least the part before any equal sign.
513         if ($^O eq "VMS")
514                 {
515                 s/^([^=]*)/lc($1)/e;
516                 }
517         s /^-no-/no-/; # some people just can't read the instructions
518
519         # rewrite some options in "enable-..." form
520         s /^-?-?shared$/enable-shared/;
521         s /^sctp$/enable-sctp/;
522         s /^threads$/enable-threads/;
523         s /^zlib$/enable-zlib/;
524         s /^zlib-dynamic$/enable-zlib-dynamic/;
525
526         if (/^(no|disable|enable)-(.+)$/)
527                 {
528                 my $word = $2;
529                 if (grep { $word =~ /^${_}$/ } @deprecated_disablables)
530                         {
531                         $deprecated_options{$_} = 1;
532                         next;
533                         }
534                 elsif (!grep { $word =~ /^${_}$/ } @disablables)
535                         {
536                         $unsupported_options{$_} = 1;
537                         next;
538                         }
539                 }
540         if (/^no-(.+)$/ || /^disable-(.+)$/)
541                 {
542                 foreach my $proto ((@tls, @dtls))
543                         {
544                         if ($1 eq "$proto-method")
545                                 {
546                                 $disabled{"$proto"} = "option($proto-method)";
547                                 last;
548                                 }
549                         }
550                 if ($1 eq "dtls")
551                         {
552                         foreach my $proto (@dtls)
553                                 {
554                                 $disabled{$proto} = "option(dtls)";
555                                 }
556                         }
557                 elsif ($1 eq "ssl")
558                         {
559                         # Last one of its kind
560                         $disabled{"ssl3"} = "option(ssl)";
561                         }
562                 elsif ($1 eq "tls")
563                         {
564                         # XXX: Tests will fail if all SSL/TLS
565                         # protocols are disabled.
566                         foreach my $proto (@tls)
567                                 {
568                                 $disabled{$proto} = "option(tls)";
569                                 }
570                         }
571                 elsif ($1 eq "static-engine")
572                         {
573                         delete $disabled{"dynamic-engine"};
574                         }
575                 elsif ($1 eq "dynamic-engine")
576                         {
577                         $disabled{"dynamic-engine"} = "option";
578                         }
579                 else
580                         {
581                         $disabled{$1} = "option";
582                         }
583                 # No longer an automatic choice
584                 $auto_threads = 0 if ($1 eq "threads");
585                 }
586         elsif (/^enable-(.+)$/)
587                 {
588                 if ($1 eq "static-engine")
589                         {
590                         $disabled{"dynamic-engine"} = "option";
591                         }
592                 elsif ($1 eq "dynamic-engine")
593                         {
594                         delete $disabled{"dynamic-engine"};
595                         }
596                 elsif ($1 eq "zlib-dynamic")
597                         {
598                         delete $disabled{"zlib"};
599                         }
600                 my $algo = $1;
601                 delete $disabled{$algo};
602
603                 # No longer an automatic choice
604                 $auto_threads = 0 if ($1 eq "threads");
605                 }
606         elsif (/^--strict-warnings$/)
607                 {
608                 $strict_warnings = 1;
609                 }
610         elsif (/^--debug$/)
611                 {
612                 $config{build_type} = "debug";
613                 }
614         elsif (/^--release$/)
615                 {
616                 $config{build_type} = "release";
617                 }
618         elsif (/^386$/)
619                 { $config{processor}=386; }
620         elsif (/^fips$/)
621                 {
622                 $config{fips}=1;
623                 }
624         elsif (/^rsaref$/)
625                 {
626                 # No RSAref support any more since it's not needed.
627                 # The check for the option is there so scripts aren't
628                 # broken
629                 }
630         elsif (/^nofipscanistercheck$/)
631                 {
632                 $config{fips} = 1;
633                 $nofipscanistercheck = 1;
634                 }
635         elsif (/^[-+]/)
636                 {
637                 if (/^--classic$/)
638                         {
639                         $classic=1;
640                         }
641                 elsif (/^--prefix=(.*)$/)
642                         {
643                         $config{prefix}=$1;
644                         die "Directory given with --prefix MUST be absolute\n"
645                                 unless file_name_is_absolute($config{prefix});
646                         }
647                 elsif (/^--api=(.*)$/)
648                         {
649                         $config{api}=$1;
650                         }
651                 elsif (/^--libdir=(.*)$/)
652                         {
653                         $config{libdir}=$1;
654                         }
655                 elsif (/^--openssldir=(.*)$/)
656                         {
657                         $config{openssldir}=$1;
658                         }
659                 elsif (/^--with-zlib-lib=(.*)$/)
660                         {
661                         $withargs{zlib_lib}=$1;
662                         }
663                 elsif (/^--with-zlib-include=(.*)$/)
664                         {
665                         $withargs{zlib_include}="-I$1";
666                         }
667                 elsif (/^--with-fipslibdir=(.*)$/)
668                         {
669                         $config{fipslibdir}="$1/";
670                         }
671                 elsif (/^--with-baseaddr=(.*)$/)
672                         {
673                         $config{baseaddr}="$1";
674                         }
675                 elsif (/^--cross-compile-prefix=(.*)$/)
676                         {
677                         $config{cross_compile_prefix}=$1;
678                         }
679                 elsif (/^--config=(.*)$/)
680                         {
681                         read_config $1;
682                         }
683                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
684                         {
685                         $libs.=$_." ";
686                         }
687                 elsif (/^-D(.*)$/)
688                         {
689                         push @user_defines, $1;
690                         }
691                 else    # common if (/^[-+]/), just pass down...
692                         {
693                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
694                         $user_cflags.=" ".$_;
695                         }
696                 }
697         else
698                 {
699                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
700                 $target=$_;
701                 }
702         unless ($_ eq $target || /^no-/ || /^disable-/)
703                 {
704                 # "no-..." follows later after implied disactivations
705                 # have been derived.  (Don't take this too seroiusly,
706                 # we really only write OPTIONS to the Makefile out of
707                 # nostalgia.)
708
709                 if ($config{options} eq "")
710                         { $config{options} = $_; }
711                 else
712                         { $config{options} .= " ".$_; }
713                 }
714
715         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
716                 die "***** Unsupported api compatibility level: $config{api}\n",
717         }
718
719         if (keys %deprecated_options)
720                 {
721                 warn "***** Deprecated options: ",
722                         join(", ", keys %deprecated_options), "\n";
723                 }
724         if (keys %unsupported_options)
725                 {
726                 die "***** Unsupported options: ",
727                         join(", ", keys %unsupported_options), "\n";
728                 }
729         }
730
731 if ($config{fips})
732         {
733         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
734         }
735 else
736         {
737         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
738         }
739
740 my @tocheckfor = (keys %disabled);
741 while (@tocheckfor) {
742     my %new_tocheckfor = ();
743     my @cascade_copy = (@disable_cascades);
744     while (@cascade_copy) {
745         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
746         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
747             map {
748                 $new_tocheckfor{$_} => 1; $disabled{$_} = "forced";
749             } grep { !defined($disabled{$_}) } @$descendents;
750         }
751     }
752     @tocheckfor = (keys %new_tocheckfor);
753 }
754
755 if ($target eq "TABLE") {
756     foreach (sort keys %table) {
757         print_table_entry($_, "TABLE");
758     }
759     exit 0;
760 }
761
762 if ($target eq "LIST") {
763     foreach (sort keys %table) {
764         print $_,"\n" unless $table{$_}->{template};
765     }
766     exit 0;
767 }
768
769 if ($target eq "HASH") {
770     print "%table = (\n";
771     foreach (sort keys %table) {
772         print_table_entry($_, "HASH");
773     }
774     exit 0;
775 }
776
777 # Backward compatibility?
778 if ($target =~ m/^CygWin32(-.*)$/) {
779     $target = "Cygwin".$1;
780 }
781
782 foreach (sort (keys %disabled))
783         {
784         $config{options} .= " no-$_";
785
786         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
787
788         if (/^dso$/)
789                 { }
790         elsif (/^threads$/)
791                 { }
792         elsif (/^shared$/)
793                 { }
794         elsif (/^pic$/)
795                 { }
796         elsif (/^zlib$/)
797                 { }
798         elsif (/^dynamic-engine$/)
799                 { }
800         elsif (/^makedepend$/)
801                 { }
802         elsif (/^zlib-dynamic$/)
803                 { }
804         elsif (/^sse2$/)
805                 { $no_sse2 = 1; }
806         elsif (/^engine$/)
807                 {
808                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
809                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
810                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
811                 }
812         else
813                 {
814                 my ($ALGO, $algo);
815                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
816
817                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/
818                                 || /^autoalginit/ || /^autoerrinit/)
819                         {
820                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
821                         print " OPENSSL_NO_$ALGO";
822
823                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
824                         }
825                 else
826                         {
827                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
828
829                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
830                         print " OPENSSL_NO_$ALGO";
831
832                         # fix-up crypto/directory name(s)
833                         $algo="whrlpool" if $algo eq "whirlpool";
834                         $algo="ripemd" if $algo eq "rmd160";
835                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
836
837                         print " (skip dir)";
838                         }
839                 }
840
841         print "\n";
842         }
843
844 print "Configuring for $target\n";
845
846 # Support for legacy targets having a name starting with 'debug-'
847 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
848 if ($d) {
849     $config{build_type} = "debug";
850
851     # If we do not find debug-foo in the table, the target is set to foo.
852     if (!$table{$target}) {
853         $target = $t;
854     }
855 }
856 $config{target} = $target;
857 my %target = resolve_config($target);
858
859 &usage if (!%target || $target{template});
860
861 %target = ( %{$table{DEFAULTS}}, %target );
862
863 $target{exe_extension}="";
864 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
865                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
866 $target{exe_extension}=".nlm" if ($config{target} =~ /netware/);
867 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
868
869 ($target{shared_extension_simple}=$target{shared_extension})
870     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
871 $target{dso_extension}=$target{shared_extension_simple};
872 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
873     if ($config{target} =~ /^(?:Cygwin|mingw)/);
874
875
876 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
877     if $config{cross_compile_prefix} eq "";
878
879 # Allow overriding the names of some tools.  USE WITH CARE
880 $config{perl} =    $ENV{'PERL'}    || which("perl5") || which("perl") || "perl";
881 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
882 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  || which("ranlib") || "true";
883 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
884 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
885
886 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
887 # or release_ attributes.
888 # Do it in such a way that no spurious space is appended (hence the grep).
889 $config{defines} = [];
890 $config{cflags} = "";
891 $config{ex_libs} = "";
892 $config{shared_ldflag} = "";
893
894 # Make sure build_scheme is consistent.
895 $target{build_scheme} = [ $target{build_scheme} ]
896     if ref($target{build_scheme}) ne "ARRAY";
897
898 ###### TO BE REMOVED WHEN CLASSIC BUILD IS REMOVED
899 ######
900 ###### If the user has chosen --classic, we give it to them.
901 ###### If they try that with an out-of-source config, we complain.
902 if ($target{build_scheme}->[0] eq "unified" && $classic) {
903     die "Can't perform a classic build out of source tree\n"
904         if $srcdir ne $blddir;
905
906     $target{build_scheme} = { unix    => [ "unixmake" ],
907                               windows => [ "mk1mf", $target{build_scheme}->[2] ],
908                               VMS     => undef } -> {$target{build_scheme}->[1]};
909
910     die "Classic mode unavailable on this platform\n"
911         unless defined($target{build_scheme});
912 }
913
914 my ($builder, $builder_platform, @builder_opts) =
915     @{$target{build_scheme}};
916
917 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
918         {
919         $config{cflags} .= " -mno-cygwin";
920         $config{shared_ldflag} .= " -mno-cygwin";
921         }
922
923 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
924         # minimally required architecture flags for assembly modules
925         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
926         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
927 }
928
929 my $no_shared_warn=0;
930 my $no_user_cflags=0;
931 my $no_user_defines=0;
932
933 # The DSO code currently always implements all functions so that no
934 # applications will have to worry about that from a compilation point
935 # of view. However, the "method"s may return zero unless that platform
936 # has support compiled in for them. Currently each method is enabled
937 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
938 # string entry into using the following logic;
939 if (!$disabled{dso} && $target{dso_scheme} ne "")
940         {
941         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
942         if ($target{dso_scheme} eq "DLFCN")
943                 {
944                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
945                 }
946         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
947                 {
948                 unshift @{$config{defines}}, "DSO_DLFCN";
949                 }
950         else
951                 {
952                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
953                 }
954         }
955
956 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
957
958 if ($disabled{asm})
959         {
960         if ($config{fips})
961                 {
962                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
963                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
964                 }
965         }
966
967 # If threads aren't disabled, check how possible they are
968 unless ($disabled{threads}) {
969     if ($auto_threads) {
970         # Enabled by default, disable it forcibly if unavailable
971         if ($target{thread_scheme} eq "(unknown)") {
972             $disabled{threads} = "unavailable";
973         }
974     } else {
975         # The user chose to enable threads explicitely, let's see
976         # if there's a chance that's possible
977         if ($target{thread_scheme} eq "(unknown)") {
978             # If the user asked for "threads" and we don't have internal
979             # knowledge how to do it, [s]he is expected to provide any
980             # system-dependent compiler options that are necessary.  We
981             # can't truly check that the given options are correct, but
982             # we expect the user to know what [s]He is doing.
983             if ($no_user_cflags && $no_user_defines) {
984                 die "You asked for multi-threading support, but didn't\n"
985                     ,"provide any system-specific compiler options\n";
986             }
987         }
988     }
989 }
990
991 # If threads still aren't disabled, add a C macro to ensure the source
992 # code knows about it.  Any other flag is taken care of by the configs.
993 unless($disabled{threads}) {
994     foreach (("defines", "openssl_thread_defines")) {
995         push @{$config{$_}}, "OPENSSL_THREADS";
996     }
997 }
998
999 # With "deprecated" disable all deprecated features.
1000 if (defined($disabled{"deprecated"})) {
1001         $config{api} = $maxapi;
1002 }
1003
1004 if ($target{shared_target} eq "")
1005         {
1006         $no_shared_warn = 1
1007             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1008                 && !$config{fips});
1009         $disabled{shared} = "no-shared-target";
1010         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1011             "no-shared-target";
1012         }
1013
1014 if ($disabled{"dynamic-engine"}) {
1015         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1016         $config{dynamic_engines} = 0;
1017 } else {
1018         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1019         $config{dynamic_engines} = 1;
1020 }
1021
1022 #
1023 # Platform fix-ups
1024 #
1025
1026 # This saves the build files from having to check
1027 if ($disabled{pic})
1028         {
1029         $target{shared_cflag} = $target{shared_ldflag} =
1030                 $target{shared_rcflag} = "";
1031         }
1032 else
1033         {
1034         push @{$config{defines}}, "OPENSSL_PIC";
1035         }
1036
1037 if ($target{sys_id} ne "")
1038         {
1039         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1040         }
1041
1042 unless ($disabled{asm}) {
1043     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1044     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1045
1046     # bn-586 is the only one implementing bn_*_part_words
1047     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1048     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1049
1050     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1051     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1052     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1053
1054     if ($config{fips}) {
1055         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1056     }
1057
1058     if ($target{sha1_asm_src}) {
1059         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1060         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1061         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1062     }
1063     if ($target{md5_asm_src}) {
1064         push @{$config{defines}}, "MD5_ASM";
1065     }
1066     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1067     if ($target{rmd160_asm_src}) {
1068         push @{$config{defines}}, "RMD160_ASM";
1069     }
1070     if ($target{aes_asm_src}) {
1071         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1072         # aes-ctr.fake is not a real file, only indication that assembler
1073         # module implements AES_ctr32_encrypt...
1074         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1075         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1076         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1077         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1078         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1079         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1080     }
1081     if ($target{wp_asm_src} =~ /mmx/) {
1082         if ($config{processor} eq "386") {
1083             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1084         } elsif (!$disabled{"whirlpool"}) {
1085             push @{$config{defines}}, "WHIRLPOOL_ASM";
1086         }
1087     }
1088     if ($target{modes_asm_src} =~ /ghash-/) {
1089         push @{$config{defines}}, "GHASH_ASM";
1090     }
1091     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1092         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1093     }
1094     if ($target{poly1305_asm_src} ne "") {
1095         push @{$config{defines}}, "POLY1305_ASM";
1096     }
1097 }
1098
1099 my $ecc = $target{cc};
1100 if ($^O ne "VMS" && !$disabled{makedepend}) {
1101     # Is the compiler gcc or clang?  $ecc is used below to see if
1102     # error-checking can be turned on.
1103     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1104     $config{makedepprog} = which('makedepend');
1105     open(PIPE, "$ccpcc --version 2>&1 | head -2 |");
1106     while ( <PIPE> ) {
1107         # Find the version number and save the major.
1108         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1109         # We know that GNU C version 3 and up as well as all clang
1110         # versions support dependency generation
1111         $config{makedepprog} = $ccpcc if /clang/ || (/gcc/ && $1 > 3);
1112         $ecc = "clang" if /clang/;
1113         $ecc = "gcc" if /gcc/;
1114     }
1115     close(PIPE);
1116
1117     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1118 }
1119
1120
1121
1122 # Deal with bn_ops ###################################################
1123
1124 $config{bn_ll}                  =0;
1125 $config{export_var_as_fn}       =0;
1126 my $def_int="unsigned int";
1127 $config{rc4_int}                =$def_int;
1128 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1129
1130 my $count = 0;
1131 foreach (sort split(/\s+/,$target{bn_ops})) {
1132     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1133     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1134     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1135     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1136     ($config{b64l},$config{b64},$config{b32})
1137         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1138     ($config{b64l},$config{b64},$config{b32})
1139         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1140     ($config{b64l},$config{b64},$config{b32})
1141         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1142 }
1143 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1144     if $count > 1;
1145
1146
1147 # Hack cflags for better warnings (dev option) #######################
1148
1149 # "Stringify" the C flags string.  This permits it to be made part of a string
1150 # and works as well on command lines.
1151 $config{cflags} =~ s/([\\\"])/\\\1/g;
1152
1153 if (defined($config{api})) {
1154     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1155     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1156     push @{$config{defines}}, $apiflag;
1157 }
1158
1159 if ($strict_warnings)
1160         {
1161         my $wopt;
1162         die "ERROR --strict-warnings requires gcc or clang"
1163             unless $ecc eq 'gcc' || $ecc eq 'clang';
1164         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1165                 {
1166                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1167                 }
1168         if ($ecc eq "clang")
1169                 {
1170                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1171                         {
1172                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1173                         }
1174                 }
1175         }
1176
1177 unless ($disabled{"crypto-mdebug-backtrace"})
1178         {
1179         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1180                 {
1181                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1182                 }
1183         if ($target =~ /^BSD-/)
1184                 {
1185                 $config{ex_libs} .= " -lexecinfo";
1186                 }
1187         }
1188
1189 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1190 else                    { $no_user_cflags=1;  }
1191 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1192 else               { $no_user_defines=1;    }
1193
1194 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1195
1196 unless ($disabled{engine}) {
1197     $config{afalg}="";
1198     if ($target =~ m/^linux/) {
1199         my $minver = 4*10000 + 1*100 + 0;
1200         if ($config{cross_compile_prefix} eq "") {
1201             my $verstr = `uname -r`;
1202             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1203             ($mi2) = $mi2 =~ /(\d+)/;
1204             my $ver = $ma*10000 + $mi1*100 + $mi2;
1205             if ($ver < $minver) {
1206                 $disabled{afalg} = "too-old-kernel";
1207             } else {
1208                 push @{$config{engdirs}}, "afalg";
1209             }
1210         }
1211     } else {
1212         $disabled{afalg}  = "not-linux";
1213     }
1214 }
1215
1216 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalg});
1217
1218 # If we use the unified build, collect information from build.info files
1219 my %unified_info = ();
1220
1221 if ($builder eq "unified") {
1222     # Store the name of the template file we will build the build file from
1223     # in %config.  This may be useful for the build file itself.
1224     my $build_file_template =
1225         catfile($srcdir, "Configurations",
1226                 $builder_platform."-".$target{build_file}.".tmpl");
1227     $build_file_template =
1228         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1229         if (! -f $build_file_template);
1230     $config{build_file_template} = $build_file_template;
1231
1232     use lib catdir(dirname(__FILE__),"util");
1233     use with_fallback qw(Text::Template);
1234
1235     sub cleandir {
1236         my $base = shift;
1237         my $dir = shift;
1238         my $relativeto = shift || ".";
1239
1240         $dir = catdir($base,$dir) unless isabsolute($dir);
1241
1242         # Make sure the directories we're building in exists
1243         mkpath($dir);
1244
1245         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1246         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1247         return $res;
1248     }
1249
1250     sub cleanfile {
1251         my $base = shift;
1252         my $file = shift;
1253         my $relativeto = shift || ".";
1254
1255         $file = catfile($base,$file) unless isabsolute($file);
1256
1257         my $d = dirname($file);
1258         my $f = basename($file);
1259
1260         # Make sure the directories we're building in exists
1261         mkpath($d);
1262
1263         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1264         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1265         return $res;
1266     }
1267
1268     my @build_infos = ( [ ".", "build.info" ] );
1269     foreach (@{$config{dirs}}) {
1270         push @build_infos, [ $_, "build.info" ]
1271             if (-f catfile($srcdir, $_, "build.info"));
1272     }
1273     foreach (@{$config{sdirs}}) {
1274         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1275             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1276     }
1277     foreach (@{$config{engdirs}}) {
1278         push @build_infos, [ catdir("engines", $_), "build.info" ]
1279             if (-f catfile($srcdir, "engines", $_, "build.info"));
1280     }
1281
1282     $config{build_infos} = [ ];
1283
1284     foreach (@build_infos) {
1285         my $sourced = catdir($srcdir, $_->[0]);
1286         my $buildd = catdir($blddir, $_->[0]);
1287
1288         mkpath($buildd);
1289
1290         my $f = $_->[1];
1291         # The basic things we're trying to build
1292         my @programs = ();
1293         my @libraries = ();
1294         my @engines = ();
1295         my @scripts = ();
1296         my @extra = ();
1297         my @overrides = ();
1298         my @intermediates = ();
1299         my @rawlines = ();
1300
1301         my %ordinals = ();
1302         my %sources = ();
1303         my %includes = ();
1304         my %depends = ();
1305         my %renames = ();
1306         my %sharednames = ();
1307         my %generate = ();
1308
1309         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1310         my $template = Text::Template->new(TYPE => 'FILE',
1311                                            SOURCE => catfile($sourced, $f));
1312         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1313         my @text =
1314             split /^/m,
1315             $template->fill_in(HASH => { config => \%config,
1316                                          target => \%target,
1317                                          disabled => \%disabled,
1318                                          builddir => abs2rel($buildd, $blddir),
1319                                          sourcedir => abs2rel($sourced, $blddir),
1320                                          buildtop => abs2rel($blddir, $blddir),
1321                                          sourcetop => abs2rel($srcdir, $blddir) },
1322                                DELIMITERS => [ "{-", "-}" ]);
1323
1324         # The top item of this stack has the following values
1325         # -2 positive already run and we found ELSE (following ELSIF should fail)
1326         # -1 positive already run (skip until ENDIF)
1327         # 0 negatives so far (if we're at a condition, check it)
1328         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1329         # 2 positive ELSE (following ELSIF should fail)
1330         my @skip = ();
1331         collect_information(
1332             collect_from_array([ @text ],
1333                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1334                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1335             # Info we're looking for
1336             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1337             => sub { push @skip, !! $1; },
1338             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1339             => sub { die "ELSIF out of scope" if ! @skip;
1340                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1341                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1342                      $skip[$#skip] = !! $1
1343                          if $skip[$#skip] == 0; },
1344             qr/^\s*ELSE\s*$/
1345             => sub { die "ELSE out of scope" if ! @skip;
1346                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1347                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1348             qr/^\s*ENDIF\s*$/
1349             => sub { die "ENDIF out of scope" if ! @skip;
1350                      pop @skip; },
1351             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1352             => sub { push @programs, split(/\s+/, $1)
1353                          if !@skip || $skip[$#skip] > 0 },
1354             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1355             => sub { push @libraries, split(/\s+/, $1)
1356                          if !@skip || $skip[$#skip] > 0 },
1357             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1358             => sub { push @engines, split(/\s+/, $1)
1359                          if !@skip || $skip[$#skip] > 0 },
1360             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1361             => sub { push @scripts, split(/\s+/, $1)
1362                          if !@skip || $skip[$#skip] > 0 },
1363             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1364             => sub { push @extra, split(/\s+/, $1)
1365                          if !@skip || $skip[$#skip] > 0 },
1366             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1367             => sub { push @overrides, split(/\s+/, $1)
1368                          if !@skip || $skip[$#skip] > 0 },
1369
1370             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1371             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1372                          if !@skip || $skip[$#skip] > 0 },
1373             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1374             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1375                          if !@skip || $skip[$#skip] > 0 },
1376             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1377             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1378                          if !@skip || $skip[$#skip] > 0 },
1379             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1380             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1381                          if !@skip || $skip[$#skip] > 0 },
1382             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1383             => sub { push @{$generate{$1}}, $2
1384                          if !@skip || $skip[$#skip] > 0 },
1385             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1386             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1387                          if !@skip || $skip[$#skip] > 0 },
1388             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1389             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1390                          if !@skip || $skip[$#skip] > 0 },
1391             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1392             => sub {
1393                 my $lineiterator = shift;
1394                 my $target_kind = $1;
1395                 while (defined $lineiterator->()) {
1396                     s|\R$||;
1397                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1398                         die "ENDRAW doesn't match BEGINRAW"
1399                             if $1 ne $target_kind;
1400                         last;
1401                     }
1402                     next if @skip && $skip[$#skip] <= 0;
1403                     push @rawlines,  $_
1404                         if ($target_kind eq $target{build_file}
1405                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1406                 }
1407             },
1408             qr/^(?:#.*|\s*)$/ => sub { },
1409             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" }
1410             );
1411         die "runaway IF?" if (@skip);
1412
1413         foreach (keys %renames) {
1414             die "$_ renamed to more than one thing: "
1415                 ,join(" ", @{$renames{$_}}),"\n"
1416                 if scalar @{$renames{$_}} > 1;
1417             my $dest = cleanfile($buildd, $_, $blddir);
1418             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1419             die "$dest renamed to more than one thing: "
1420                 ,$unified_info{rename}->{$dest}, $to
1421                 unless !defined($unified_info{rename}->{$dest})
1422                 or $unified_info{rename}->{$dest} eq $to;
1423             $unified_info{rename}->{$dest} = $to;
1424         }
1425
1426         foreach (@programs) {
1427             my $program = cleanfile($buildd, $_, $blddir);
1428             if ($unified_info{rename}->{$program}) {
1429                 $program = $unified_info{rename}->{$program};
1430             }
1431             $unified_info{programs}->{$program} = 1;
1432         }
1433
1434         foreach (@libraries) {
1435             my $library = cleanfile($buildd, $_, $blddir);
1436             if ($unified_info{rename}->{$library}) {
1437                 $library = $unified_info{rename}->{$library};
1438             }
1439             $unified_info{libraries}->{$library} = 1;
1440         }
1441
1442         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1443 ENGINES can only be used if configured with 'dynamic-engine'.
1444 This is usually a fault in a build.info file.
1445 EOF
1446         foreach (@engines) {
1447             my $library = cleanfile($buildd, $_, $blddir);
1448             if ($unified_info{rename}->{$library}) {
1449                 $library = $unified_info{rename}->{$library};
1450             }
1451             $unified_info{engines}->{$library} = 1;
1452         }
1453
1454         foreach (@scripts) {
1455             my $script = cleanfile($buildd, $_, $blddir);
1456             if ($unified_info{rename}->{$script}) {
1457                 $script = $unified_info{rename}->{$script};
1458             }
1459             $unified_info{scripts}->{$script} = 1;
1460         }
1461
1462         foreach (@extra) {
1463             my $extra = cleanfile($buildd, $_, $blddir);
1464             $unified_info{extra}->{$extra} = 1;
1465         }
1466
1467         foreach (@overrides) {
1468             my $override = cleanfile($buildd, $_, $blddir);
1469             $unified_info{overrides}->{$override} = 1;
1470         }
1471
1472         push @{$unified_info{rawlines}}, @rawlines;
1473
1474         unless ($disabled{shared}) {
1475             # Check sharednames.
1476             foreach (keys %sharednames) {
1477                 my $dest = cleanfile($buildd, $_, $blddir);
1478                 if ($unified_info{rename}->{$dest}) {
1479                     $dest = $unified_info{rename}->{$dest};
1480                 }
1481                 die "shared_name for $dest with multiple values: "
1482                     ,join(" ", @{$sharednames{$_}}),"\n"
1483                     if scalar @{$sharednames{$_}} > 1;
1484                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1485                 die "shared_name found for a library $dest that isn't defined\n"
1486                     unless $unified_info{libraries}->{$dest};
1487                 die "shared_name for $dest with multiple values: "
1488                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1489                     unless !defined($unified_info{sharednames}->{$dest})
1490                     or $unified_info{sharednames}->{$dest} eq $to;
1491                 $unified_info{sharednames}->{$dest} = $to;
1492             }
1493
1494             # Additionally, we set up sharednames for libraries that don't
1495             # have any, as themselves.
1496             foreach (keys %{$unified_info{libraries}}) {
1497                 if (!defined $unified_info{sharednames}->{$_}) {
1498                     $unified_info{sharednames}->{$_} = $_
1499                 }
1500             }
1501         }
1502
1503         foreach (keys %ordinals) {
1504             my $dest = $_;
1505             my $ddest = cleanfile($buildd, $_, $blddir);
1506             if ($unified_info{rename}->{$ddest}) {
1507                 $ddest = $unified_info{rename}->{$ddest};
1508             }
1509             foreach (@{$ordinals{$dest}}) {
1510                 my %known_ordinals =
1511                     (
1512                      crypto =>
1513                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1514                      ssl =>
1515                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1516                     );
1517                 my $o = $known_ordinals{$_};
1518                 die "Ordinals for $ddest defined more than once\n"
1519                     if $unified_info{ordinals}->{$ddest};
1520                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1521             }
1522         }
1523
1524         foreach (keys %sources) {
1525             my $dest = $_;
1526             my $ddest = cleanfile($buildd, $_, $blddir);
1527             if ($unified_info{rename}->{$ddest}) {
1528                 $ddest = $unified_info{rename}->{$ddest};
1529             }
1530             foreach (@{$sources{$dest}}) {
1531                 my $s = cleanfile($sourced, $_, $blddir);
1532
1533                 # If it isn't in the source tree, we assume it's generated
1534                 # in the build tree
1535                 if (! -f $s) {
1536                     $s = cleanfile($buildd, $_, $blddir);
1537                 }
1538                 # We recognise C and asm files
1539                 if ($s =~ /\.[csS]\b$/) {
1540                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1541                     $o = cleanfile($buildd, $o, $blddir);
1542                     $unified_info{sources}->{$ddest}->{$o} = 1;
1543                     $unified_info{sources}->{$o}->{$s} = 1;
1544                 } else {
1545                     $unified_info{sources}->{$ddest}->{$s} = 1;
1546                 }
1547             }
1548         }
1549
1550         foreach (keys %generate) {
1551             my $dest = $_;
1552             my $ddest = cleanfile($buildd, $_, $blddir);
1553             if ($unified_info{rename}->{$ddest}) {
1554                 $ddest = $unified_info{rename}->{$ddest};
1555             }
1556             die "more than one generator for $dest: "
1557                     ,join(" ", @{$generate{$_}}),"\n"
1558                     if scalar @{$generate{$_}} > 1;
1559             my @generator = split /\s+/, $generate{$dest}->[0];
1560             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1561             $unified_info{generate}->{$ddest} = [ @generator ];
1562         }
1563
1564         foreach (keys %depends) {
1565             my $dest = $_;
1566             my $ddest = cleanfile($buildd, $_, $blddir);
1567             if ($unified_info{rename}->{$ddest}) {
1568                 $ddest = $unified_info{rename}->{$ddest};
1569             }
1570             foreach (@{$depends{$dest}}) {
1571                 my $d = cleanfile($sourced, $_, $blddir);
1572
1573                 # If we know it's generated, or assume it is because we can't
1574                 # find it in the source tree, we set file we depend on to be
1575                 # in the build tree rather than the source tree, and assume
1576                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1577                 # section or in the Makefile template.
1578                 if (! -f $d
1579                     || !(grep { $d eq $_ }
1580                          map { cleanfile($srcdir, $_, $blddir) }
1581                          (@generated_headers, @generated_by_make_headers))) {
1582                     $d = cleanfile($buildd, $_, $blddir);
1583                 }
1584                 # Take note if the file to depend on is being renamed
1585                 if ($unified_info{rename}->{$d}) {
1586                     $d = $unified_info{rename}->{$d};
1587                 }
1588                 $unified_info{depends}->{$ddest}->{$d} = 1;
1589                 # If we depend on a header file, let's make sure it
1590                 # can get included
1591                 if ($d =~ /\.h$/) {
1592                     my $i = dirname($d);
1593                     push @{$unified_info{includes}->{$ddest}}, $i
1594                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1595                 }
1596             }
1597         }
1598
1599         foreach (keys %includes) {
1600             my $dest = $_;
1601             my $ddest = cleanfile($buildd, $_, $blddir);
1602             if ($unified_info{rename}->{$ddest}) {
1603                 $ddest = $unified_info{rename}->{$ddest};
1604             }
1605             foreach (@{$includes{$dest}}) {
1606                 my $i = cleandir($sourced, $_, $blddir);
1607                 push @{$unified_info{includes}->{$ddest}}, $i
1608                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1609             }
1610         }
1611     }
1612
1613     ### Make unified_info a bit more efficient
1614     # One level structures
1615     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1616         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1617     }
1618     # Two level structures
1619     foreach my $l1 (("sources", "ldadd", "depends")) {
1620         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1621             $unified_info{$l1}->{$l2} =
1622                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1623         }
1624     }
1625 }
1626
1627 # For the schemes that need it, we provide the old *_obj configs
1628 # from the *_asm_obj ones
1629 foreach (grep /_(asm|aux)_src$/, keys %target) {
1630     my $src = $_;
1631     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1632     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1633 }
1634
1635 # Write down our configuration where it fits #########################
1636
1637 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1638 print OUT <<"EOF";
1639 package configdata;
1640
1641 use strict;
1642 use warnings;
1643
1644 use Exporter;
1645 #use vars qw(\@ISA \@EXPORT);
1646 our \@ISA = qw(Exporter);
1647 our \@EXPORT = qw(\%config \%target %disabled %withargs %unified_info);
1648
1649 EOF
1650 print OUT "our %config = (\n";
1651 foreach (sort keys %config) {
1652     if (ref($config{$_}) eq "ARRAY") {
1653         print OUT "  ", $_, " => [ ", join(", ",
1654                                            map { quotify("perl", $_) }
1655                                            @{$config{$_}}), " ],\n";
1656     } else {
1657         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1658     }
1659 }
1660 print OUT <<"EOF";
1661 );
1662
1663 EOF
1664 print OUT "our %target = (\n";
1665 foreach (sort keys %target) {
1666     if (ref($target{$_}) eq "ARRAY") {
1667         print OUT "  ", $_, " => [ ", join(", ",
1668                                            map { quotify("perl", $_) }
1669                                            @{$target{$_}}), " ],\n";
1670     } else {
1671         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1672     }
1673 }
1674 print OUT <<"EOF";
1675 );
1676
1677 EOF
1678 print OUT "our \%available_protocols = (\n";
1679 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1680 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1681 print OUT <<"EOF";
1682 );
1683
1684 EOF
1685 print OUT "our \%disabled = (\n";
1686 foreach (sort keys %disabled) {
1687     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1688 }
1689 print OUT <<"EOF";
1690 );
1691
1692 EOF
1693 print OUT "our %withargs = (\n";
1694 foreach (sort keys %withargs) {
1695     if (ref($withargs{$_}) eq "ARRAY") {
1696         print OUT "  ", $_, " => [ ", join(", ",
1697                                            map { quotify("perl", $_) }
1698                                            @{$withargs{$_}}), " ],\n";
1699     } else {
1700         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1701     }
1702 }
1703 print OUT <<"EOF";
1704 );
1705
1706 EOF
1707 if ($builder eq "unified") {
1708     my $recurse;
1709     $recurse = sub {
1710         my $indent = shift;
1711         foreach (@_) {
1712             if (ref $_ eq "ARRAY") {
1713                 print OUT " "x$indent, "[\n";
1714                 foreach (@$_) {
1715                     $recurse->($indent + 4, $_);
1716                 }
1717                 print OUT " "x$indent, "],\n";
1718             } elsif (ref $_ eq "HASH") {
1719                 my %h = %$_;
1720                 print OUT " "x$indent, "{\n";
1721                 foreach (sort keys %h) {
1722                     if (ref $h{$_} eq "") {
1723                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1724                     } else {
1725                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1726                         $recurse->($indent + 8, $h{$_});
1727                     }
1728                 }
1729                 print OUT " "x$indent, "},\n";
1730             } else {
1731                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1732             }
1733         }
1734     };
1735     print OUT "our %unified_info = (\n";
1736     foreach (sort keys %unified_info) {
1737         if (ref $unified_info{$_} eq "") {
1738             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1739         } else {
1740             print OUT " "x4, quotify("perl", $_), " =>\n";
1741             $recurse->(8, $unified_info{$_});
1742         }
1743     }
1744     print OUT <<"EOF";
1745 );
1746
1747 EOF
1748 }
1749 print OUT "1;\n";
1750 close(OUT);
1751
1752
1753 print "IsMK1MF       =", ($builder eq "mk1mf" ? "yes" : "no"), "\n";
1754 print "CC            =$target{cc}\n";
1755 print "CFLAG         =$target{cflags} $config{cflags}\n";
1756 print "SHARED_CFLAG  =$target{shared_cflag}\n";
1757 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
1758 print "LFLAG         =$target{lflags}\n";
1759 print "PLIB_LFLAG    =$target{plib_lflags}\n";
1760 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
1761 print "APPS_OBJ      =$target{apps_obj}\n";
1762 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1763 print "UPLINK_OBJ    =$target{uplink_obj}\n";
1764 print "BN_ASM        =$target{bn_obj}\n";
1765 print "EC_ASM        =$target{ec_obj}\n";
1766 print "DES_ENC       =$target{des_obj}\n";
1767 print "AES_ENC       =$target{aes_obj}\n";
1768 print "BF_ENC        =$target{bf_obj}\n";
1769 print "CAST_ENC      =$target{cast_obj}\n";
1770 print "RC4_ENC       =$target{rc4_obj}\n";
1771 print "RC5_ENC       =$target{rc5_obj}\n";
1772 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1773 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1774 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1775 print "CMLL_ENC      =$target{cmll_obj}\n";
1776 print "MODES_OBJ     =$target{modes_obj}\n";
1777 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1778 print "CHACHA_ENC    =$target{chacha_obj}\n";
1779 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1780 print "PROCESSOR     =$config{processor}\n";
1781 print "RANLIB        =$target{ranlib}\n";
1782 print "ARFLAGS       =$target{arflags}\n";
1783 print "PERL          =$config{perl}\n";
1784 print "\n";
1785 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1786 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1787 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1788 print "BN_LLONG mode\n" if $config{bn_ll};
1789 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} != $def_int;
1790
1791 for (@generated_headers) {
1792     mkpath(catdir($blddir, dirname($_)));
1793     run_dofile(catfile($blddir, $_),
1794                catfile($srcdir, $_.".in"));
1795 }
1796
1797 ###
1798 ### When the old "unixmake" scheme goes away, so does this function
1799 ###
1800 sub build_Makefile {
1801     run_dofile("Makefile","Makefile.in");
1802
1803     # Copy all Makefile.in to Makefile (except top-level)
1804     use File::Find;
1805     use IO::File;
1806     find(
1807         {
1808             preprocess => sub {
1809                 grep(!/^\./, @_);
1810             },
1811             wanted => sub {
1812                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1813                 my $in = IO::File->new($_, "r") or
1814                     die sprintf "Error reading Makefile.in in %s: !$\n",
1815                     $File::Find::dir;
1816                 my $out = IO::File->new("Makefile", "w") or
1817                     die sprintf "Error writing Makefile in %s: !$\n",
1818                     $File::Find::dir;
1819                 print $out "# Generated from $_, do not edit\n";
1820                 while (my $line = <$in>) { print $out $line }
1821                 $in->close() or
1822                     die sprintf "Error reading Makefile.in in %s: !$\n",
1823                     $File::Find::dir;
1824                 $out->close() or
1825                     die sprintf "Error writing Makefile in %s: !$\n",
1826                     $File::Find::dir;
1827             },
1828         },
1829         ".");
1830 }
1831
1832 my %builders = (
1833     unified => sub {
1834         run_dofile(catfile($blddir, $target{build_file}),
1835                    $config{build_file_template},
1836                    catfile($srcdir, "Configurations", "common.tmpl"));
1837     },
1838     unixmake => sub {
1839         build_Makefile();
1840
1841         run_dofile("util/domd", "util/domd.in");
1842         chmod 0755, "util/domd";
1843     },
1844     mk1mf => sub {
1845         my $platform = shift;
1846         # The only reason we do this is to have something to build MINFO from
1847         build_Makefile();
1848
1849         # create the ms/version32.rc file if needed
1850         if ($platform ne "netware") {
1851             my ($v1, $v2, $v3, $v4);
1852             if ($config{version_num} =~ /^0x([0-9a-f]{1})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{1})L$/i) {
1853                 $v1=hex $1;
1854                 $v2=hex $2;
1855                 $v3=hex $3;
1856                 $v4=hex $4;
1857             }
1858             open (OUT,">ms/version32.rc") || die "Can't open ms/version32.rc";
1859             print OUT <<"EOF";
1860 #include <winver.h>
1861
1862 LANGUAGE 0x09,0x01
1863
1864 1 VERSIONINFO
1865   FILEVERSION $v1,$v2,$v3,$v4
1866   PRODUCTVERSION $v1,$v2,$v3,$v4
1867   FILEFLAGSMASK 0x3fL
1868 #ifdef _DEBUG
1869   FILEFLAGS 0x01L
1870 #else
1871   FILEFLAGS 0x00L
1872 #endif
1873   FILEOS VOS__WINDOWS32
1874   FILETYPE VFT_DLL
1875   FILESUBTYPE 0x0L
1876 BEGIN
1877     BLOCK "StringFileInfo"
1878     BEGIN
1879         BLOCK "040904b0"
1880         BEGIN
1881             // Required:
1882             VALUE "CompanyName", "The OpenSSL Project, http://www.openssl.org/\\0"
1883             VALUE "FileDescription", "OpenSSL Shared Library\\0"
1884             VALUE "FileVersion", "$config{version}\\0"
1885 #if defined(CRYPTO)
1886             VALUE "InternalName", "libcrypto32\\0"
1887             VALUE "OriginalFilename", "libcrypto32.dll\\0"
1888 #elif defined(SSL)
1889             VALUE "InternalName", "libssl32\\0"
1890             VALUE "OriginalFilename", "libssl32.dll\\0"
1891 #endif
1892             VALUE "ProductName", "The OpenSSL Toolkit\\0"
1893             VALUE "ProductVersion", "$config{version}\\0"
1894             // Optional:
1895             //VALUE "Comments", "\\0"
1896             VALUE "LegalCopyright", "Copyright © 1998-2015 The OpenSSL Project. Copyright © 1995-1998 Eric A. Young, Tim J. Hudson. All rights reserved.\\0"
1897             //VALUE "LegalTrademarks", "\\0"
1898             //VALUE "PrivateBuild", "\\0"
1899             //VALUE "SpecialBuild", "\\0"
1900         END
1901     END
1902     BLOCK "VarFileInfo"
1903     BEGIN
1904         VALUE "Translation", 0x409, 0x4b0
1905     END
1906 END
1907 EOF
1908             close(OUT);
1909         }
1910     },
1911     );
1912
1913 $builders{$builder}->($builder_platform, @builder_opts);
1914
1915 print <<"EOF";
1916
1917 Configured for $target.
1918 EOF
1919
1920 print <<"EOF" if ($disabled{threads} eq "unavailable");
1921
1922 The library could not be configured for supporting multi-threaded
1923 applications as the compiler options required on this system are not known.
1924 See file INSTALL for details if you need multi-threading.
1925 EOF
1926
1927 print <<"EOF" if ($no_shared_warn);
1928
1929 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
1930 platform, so we will pretend you gave the option 'no-pic', which also disables
1931 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
1932 or position independent code, please let us know (but please first make sure
1933 you have tried with a current version of OpenSSL).
1934 EOF
1935
1936 exit(0);
1937
1938 ######################################################################
1939 #
1940 # Helpers and utility functions
1941 #
1942
1943 # Configuration file reading #########################################
1944
1945 # Helper function to implement conditional inheritance depending on the
1946 # value of $disabled{asm}.  Used in inherit_from values as follows:
1947 #
1948 #      inherit_from => [ "template", asm("asm_tmpl") ]
1949 #
1950 sub asm {
1951     my @x = @_;
1952     sub {
1953         $disabled{asm} ? () : @x;
1954     }
1955 }
1956
1957 our $add_called = 0;
1958 # Helper function to implement adding values to already existing configuration
1959 # values.  It handles elements that are ARRAYs, CODEs and scalars
1960 sub _add {
1961     my $separator = shift;
1962
1963     # If there's any ARRAY in the collection of values OR the separator
1964     # is undef, we will return an ARRAY of combined values, otherwise a
1965     # string of joined values with $separator as the separator.
1966     my $found_array = !defined($separator);
1967
1968     my @values =
1969         map {
1970             my $res = $_;
1971             while (ref($res) eq "CODE") {
1972                 $res = $res->();
1973             }
1974             if (defined($res)) {
1975                 if (ref($res) eq "ARRAY") {
1976                     $found_array = 1;
1977                     @$res;
1978                 } else {
1979                     $res;
1980                 }
1981             } else {
1982                 ();
1983             }
1984     } (@_);
1985
1986     $add_called = 1;
1987
1988     if ($found_array) {
1989         [ @values ];
1990     } else {
1991         join($separator, grep { defined($_) && $_ ne "" } @values);
1992     }
1993 }
1994 sub add_before {
1995     my $separator = " ";
1996     if (ref($_[$#_]) eq "HASH") {
1997         my $opts = pop;
1998         $separator = $opts->{separator};
1999     }
2000     my @x = @_;
2001     sub { _add($separator, @x, @_) };
2002 }
2003 sub add {
2004     my $separator = " ";
2005     if (ref($_[$#_]) eq "HASH") {
2006         my $opts = pop;
2007         $separator = $opts->{separator};
2008     }
2009     my @x = @_;
2010     sub { _add($separator, @_, @x) };
2011 }
2012
2013 # configuration reader, evaluates the input file as a perl script and expects
2014 # it to fill %targets with target configurations.  Those are then added to
2015 # %table.
2016 sub read_config {
2017     my $fname = shift;
2018     open(CONFFILE, "< $fname")
2019         or die "Can't open configuration file '$fname'!\n";
2020     my $x = $/;
2021     undef $/;
2022     my $content = <CONFFILE>;
2023     $/ = $x;
2024     close(CONFFILE);
2025     my %targets = ();
2026     {
2027         local %table = %::table;    # Protect %table from tampering
2028
2029         eval $content;
2030         warn $@ if $@;
2031     }
2032
2033     # For each target, check that it's configured with a hash table.
2034     foreach (keys %targets) {
2035         if (ref($targets{$_}) ne "HASH") {
2036             if (ref($targets{$_}) eq "") {
2037                 warn "Deprecated target configuration for $_, ignoring...\n";
2038             } else {
2039                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2040             }
2041             delete $targets{$_};
2042         }
2043     }
2044
2045     %table = (%table, %targets);
2046
2047 }
2048
2049 # configuration resolver.  Will only resolve all the lazy evalutation
2050 # codeblocks for the chozen target and all those it inherits from,
2051 # recursively
2052 sub resolve_config {
2053     my $target = shift;
2054     my @breadcrumbs = @_;
2055
2056     my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2057
2058     if (grep { $_ eq $target } @breadcrumbs) {
2059         die "inherit_from loop!  target backtrace:\n  "
2060             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2061     }
2062
2063     if (!defined($table{$target})) {
2064         warn "Warning! target $target doesn't exist!\n";
2065         return ();
2066     }
2067     # Recurse through all inheritances.  They will be resolved on the
2068     # fly, so when this operation is done, they will all just be a
2069     # bunch of attributes with string values.
2070     # What we get here, though, are keys with references to lists of
2071     # the combined values of them all.  We will deal with lists after
2072     # this stage is done.
2073     my %combined_inheritance = ();
2074     if ($table{$target}->{inherit_from}) {
2075         my @inherit_from =
2076             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2077         foreach (@inherit_from) {
2078             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2079
2080             # 'template' is a marker that's considered private to
2081             # the config that had it.
2082             delete $inherited_config{template};
2083
2084             map {
2085                 if (!$combined_inheritance{$_}) {
2086                     $combined_inheritance{$_} = [];
2087                 }
2088                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2089             } keys %inherited_config;
2090         }
2091     }
2092
2093     # We won't need inherit_from in this target any more, since we've
2094     # resolved all the inheritances that lead to this
2095     delete $table{$target}->{inherit_from};
2096
2097     # Now is the time to deal with those lists.  Here's the place to
2098     # decide what shall be done with those lists, all based on the
2099     # values of the target we're currently dealing with.
2100     # - If a value is a coderef, it will be executed with the list of
2101     #   inherited values as arguments.
2102     # - If the corresponding key doesn't have a value at all or is the
2103     #   emoty string, the inherited value list will be run through the
2104     #   default combiner (below), and the result becomes this target's
2105     #   value.
2106     # - Otherwise, this target's value is assumed to be a string that
2107     #   will simply override the inherited list of values.
2108     my $default_combiner = add();
2109
2110     my %all_keys =
2111         map { $_ => 1 } (keys %combined_inheritance,
2112                          keys %{$table{$target}});
2113
2114     sub process_values {
2115         my $object    = shift;
2116         my $inherited = shift;  # Always a [ list ]
2117         my $target    = shift;
2118         my $entry     = shift;
2119
2120         $add_called = 0;
2121
2122         while(ref($object) eq "CODE") {
2123             $object = $object->(@$inherited);
2124         }
2125         if (!defined($object)) {
2126             return ();
2127         }
2128         elsif (ref($object) eq "ARRAY") {
2129             local $add_called;  # To make sure recursive calls don't affect it
2130             return [ map { process_values($_, $inherited, $target, $entry) }
2131                      @$object ];
2132         } elsif (ref($object) eq "") {
2133             return $object;
2134         } else {
2135             die "cannot handle reference type ",ref($object)
2136                 ," found in target ",$target," -> ",$entry,"\n";
2137         }
2138     }
2139
2140     foreach (sort keys %all_keys) {
2141         my $previous = $combined_inheritance{$_};
2142
2143         # Current target doesn't have a value for the current key?
2144         # Assign it the default combiner, the rest of this loop body
2145         # will handle it just like any other coderef.
2146         if (!exists $table{$target}->{$_}) {
2147             $table{$target}->{$_} = $default_combiner;
2148         }
2149
2150         $table{$target}->{$_} = process_values($table{$target}->{$_},
2151                                                $combined_inheritance{$_},
2152                                                $target, $_);
2153         unless(defined($table{$target}->{$_})) {
2154             delete $table{$target}->{$_};
2155         }
2156         if ($extra_checks &&
2157             $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2158             warn "$_ got replaced in $target\n";
2159         }
2160     }
2161
2162     # Finally done, return the result.
2163     return %{$table{$target}};
2164 }
2165
2166 sub usage
2167         {
2168         print STDERR $usage;
2169         print STDERR "\npick os/compiler from:\n";
2170         my $j=0;
2171         my $i;
2172         my $k=0;
2173         foreach $i (sort keys %table)
2174                 {
2175                 next if $table{$i}->{template};
2176                 next if $i =~ /^debug/;
2177                 $k += length($i) + 1;
2178                 if ($k > 78)
2179                         {
2180                         print STDERR "\n";
2181                         $k=length($i);
2182                         }
2183                 print STDERR $i . " ";
2184                 }
2185         foreach $i (sort keys %table)
2186                 {
2187                 next if $table{$i}->{template};
2188                 next if $i !~ /^debug/;
2189                 $k += length($i) + 1;
2190                 if ($k > 78)
2191                         {
2192                         print STDERR "\n";
2193                         $k=length($i);
2194                         }
2195                 print STDERR $i . " ";
2196                 }
2197         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2198         exit(1);
2199         }
2200
2201 sub run_dofile()
2202 {
2203     my $out = shift;
2204     my @templates = @_;
2205
2206     unlink $out || warn "Can't remove $out, $!"
2207         if -f $out;
2208     foreach (@templates) {
2209         die "Can't open $_, $!" unless -f $_;
2210     }
2211     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2212     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2213     system($cmd);
2214     exit 1 if $? != 0;
2215     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2216 }
2217
2218 # Configuration printer ##############################################
2219
2220 sub print_table_entry
2221 {
2222     my $target = shift;
2223     my %target = resolve_config($target);
2224     my $type = shift;
2225
2226     # Don't print the templates
2227     return if $target{template};
2228
2229     my @sequence = (
2230         "sys_id",
2231         "cc",
2232         "cflags",
2233         "defines",
2234         "unistd",
2235         "ld",
2236         "lflags",
2237         "plib_lflags",
2238         "ex_libs",
2239         "bn_ops",
2240         "cpuid_obj",
2241         "bn_obj",
2242         "ec_obj",
2243         "des_obj",
2244         "aes_obj",
2245         "bf_obj",
2246         "md5_obj",
2247         "sha1_obj",
2248         "cast_obj",
2249         "rc4_obj",
2250         "rmd160_obj",
2251         "rc5_obj",
2252         "wp_obj",
2253         "cmll_obj",
2254         "modes_obj",
2255         "padlock_obj",
2256         "thread_scheme",
2257         "perlasm_scheme",
2258         "dso_scheme",
2259         "shared_target",
2260         "shared_cflag",
2261         "shared_ldflag",
2262         "shared_rcflag",
2263         "shared_extension",
2264         "shared_extension_simple",
2265         "shared_import_extension",
2266         "dso_extension",
2267         "obj_extension",
2268         "exe_extension",
2269         "ranlib",
2270         "ar",
2271         "arflags",
2272         "multilib",
2273         "build_scheme",
2274         );
2275
2276     if ($type eq "TABLE") {
2277         print "\n";
2278         print "*** $target\n";
2279         foreach (@sequence) {
2280             if (ref($target{$_}) eq "ARRAY") {
2281                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2282             } else {
2283                 printf "\$%-12s = %s\n", $_, $target{$_};
2284             }
2285         }
2286     } elsif ($type eq "HASH") {
2287         my $largest =
2288             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2289         print "    '$target' => {\n";
2290         foreach (@sequence) {
2291             if ($target{$_}) {
2292                 if (ref($target{$_}) eq "ARRAY") {
2293                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2294                 } else {
2295                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2296                 }
2297             }
2298         }
2299         print "    },\n";
2300     }
2301 }
2302
2303 # Utility routines ###################################################
2304
2305 # On VMS, if the given file is a logical name, File::Spec::Functions
2306 # will consider it an absolute path.  There are cases when we want a
2307 # purely syntactic check without checking the environment.
2308 sub isabsolute {
2309     my $file = shift;
2310
2311     # On non-platforms, we just use file_name_is_absolute().
2312     return file_name_is_absolute($file) unless $^O eq "VMS";
2313
2314     # If the file spec includes a device or a directpry spec,
2315     # file_name_is_absolute() is perfectly safe.
2316     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2317
2318     # Here, we know the given file spec isn't absolute
2319     return 0;
2320 }
2321
2322 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2323 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2324 # realpath() requires that at least all path components except the last is an
2325 # existing directory.  On VMS, the last component of the directory spec must
2326 # exist.
2327 sub absolutedir {
2328     my $dir = shift;
2329
2330     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2331     # will return the volume name for the device, no matter what.  Also,
2332     # it will return an incorrect directory spec if the argument is a
2333     # directory that doesn't exist.
2334     if ($^O eq "VMS") {
2335         return rel2abs($dir);
2336     }
2337
2338     # We use realpath() on Unix, since no other will properly clean out
2339     # a directory spec.
2340     use Cwd qw/realpath/;
2341
2342     return realpath($dir);
2343 }
2344
2345 sub which
2346         {
2347         my($name)=@_;
2348         my $path;
2349         foreach $path (split /:/, $ENV{PATH})
2350                 {
2351                 my $fullpath = "$path/$name$target{exe_extension}";
2352                 if (-f $fullpath and -x $fullpath)
2353                         {
2354                         return $fullpath
2355                             unless ($name eq "perl" and
2356                                     system("$fullpath -e " . '\'exit($]<5.0);\''));
2357                         }
2358                 }
2359         }
2360
2361 sub quotify {
2362     my %processors = (
2363         perl    => sub { my $x = shift;
2364                          $x =~ s/([\\\$\@"])/\\$1/g;
2365                          return '"'.$x.'"'; },
2366         );
2367     my $for = shift;
2368     my $processor =
2369         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2370
2371     map { $processor->($_); } @_;
2372 }
2373
2374 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2375 # $filename is a file name to read from
2376 # $line_concat_cond_re is a regexp detecting a line continuation ending
2377 # $line_concat is a CODEref that takes care of concatenating two lines
2378 sub collect_from_file {
2379     my $filename = shift;
2380     my $line_concat_cond_re = shift;
2381     my $line_concat = shift;
2382
2383     open my $fh, $filename || die "unable to read $filename: $!\n";
2384     return sub {
2385         my $saved_line = "";
2386         $_ = "";
2387         while (<$fh>) {
2388             s|\R$||;
2389             if (defined $line_concat) {
2390                 $_ = $line_concat->($saved_line, $_);
2391                 $saved_line = "";
2392             }
2393             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2394                 $saved_line = $_;
2395                 next;
2396             }
2397             return $_;
2398         }
2399         die "$filename ending with continuation line\n" if $_;
2400         close $fh;
2401         return undef;
2402     }
2403 }
2404
2405 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2406 # $array is an ARRAYref of lines
2407 # $line_concat_cond_re is a regexp detecting a line continuation ending
2408 # $line_concat is a CODEref that takes care of concatenating two lines
2409 sub collect_from_array {
2410     my $array = shift;
2411     my $line_concat_cond_re = shift;
2412     my $line_concat = shift;
2413     my @array = (@$array);
2414
2415     return sub {
2416         my $saved_line = "";
2417         $_ = "";
2418         while (defined($_ = shift @array)) {
2419             s|\R$||;
2420             if (defined $line_concat) {
2421                 $_ = $line_concat->($saved_line, $_);
2422                 $saved_line = "";
2423             }
2424             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2425                 $saved_line = $_;
2426                 next;
2427             }
2428             return $_;
2429         }
2430         die "input text ending with continuation line\n" if $_;
2431         return undef;
2432     }
2433 }
2434
2435 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2436 # $lineiterator is a CODEref that delivers one line at a time.
2437 # All following arguments are regex/CODEref pairs, where the regexp detects a
2438 # line and the CODEref does something with the result of the regexp.
2439 sub collect_information {
2440     my $lineiterator = shift;
2441     my %collectors = @_;
2442
2443     while(defined($_ = $lineiterator->())) {
2444         s|\R$||;
2445         my $found = 0;
2446         foreach my $re (keys %collectors) {
2447             if ($re ne "OTHERWISE" && /$re/) {
2448                 $collectors{$re}->($lineiterator);
2449                 $found = 1;
2450             };
2451         }
2452         if ($collectors{"OTHERWISE"}) {
2453             $collectors{"OTHERWISE"}->($lineiterator, $_)
2454                 unless $found || !defined $collectors{"OTHERWISE"};
2455         }
2456     }
2457 }