Ensure we get all the right defines for AES assembler in FIPS module
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $orig_death_handler = $SIG{__DIE__};
25 $SIG{__DIE__} = \&death_handler;
26
27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
28
29 # Options:
30 #
31 # --config      add the given configuration file, which will be read after
32 #               any "Configurations*" files that are found in the same
33 #               directory as this script.
34 # --prefix      prefix for the OpenSSL installation, which includes the
35 #               directories bin, lib, include, share/man, share/doc/openssl
36 #               This becomes the value of INSTALLTOP in Makefile
37 #               (Default: /usr/local)
38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
39 #               If it's a relative directory, it will be added on the directory
40 #               given with --prefix.
41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
42 #               (Default: PREFIX/ssl)
43 #
44 # --cross-compile-prefix Add specified prefix to binutils components.
45 #
46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
47 #               Do not compile support for interfaces deprecated as of the
48 #               specified OpenSSL version.
49 #
50 # no-hw-xxx     do not compile support for specific crypto hardware.
51 #               Generic OpenSSL-style methods relating to this support
52 #               are always compiled but return NULL if the hardware
53 #               support isn't compiled.
54 # no-hw         do not compile support for any crypto hardware.
55 # [no-]threads  [don't] try to create a library that is suitable for
56 #               multithreaded applications (default is "threads" if we
57 #               know how to do it)
58 # [no-]shared   [don't] try to create shared libraries when supported.
59 # [no-]pic      [don't] try to build position independent code when supported.
60 #               If disabled, it also disables shared and dynamic-engine.
61 # no-asm        do not use assembler
62 # no-egd        do not compile support for the entropy-gathering daemon APIs
63 # [no-]zlib     [don't] compile support for zlib compression.
64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
65 #               library and will be loaded in run-time by the OpenSSL library.
66 # sctp          include SCTP support
67 # enable-weak-ssl-ciphers
68 #               Enable weak ciphers that are disabled by default.
69 # 386           generate 80386 code in assembly modules
70 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
71 #               mentioned '386' option implies this one
72 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
73 # -<xxx> +<xxx> compiler options are passed through
74 # -static       while -static is also a pass-through compiler option (and
75 #               as such is limited to environments where it's actually
76 #               meaningful), it triggers a number configuration options,
77 #               namely no-pic, no-shared and no-threads. It is
78 #               argued that the only reason to produce statically linked
79 #               binaries (and in context it means executables linked with
80 #               -static flag, and not just executables linked with static
81 #               libcrypto.a) is to eliminate dependency on specific run-time,
82 #               a.k.a. libc version. The mentioned config options are meant
83 #               to achieve just that. Unfortunately on Linux it's impossible
84 #               to eliminate the dependency completely for openssl executable
85 #               because of getaddrinfo and gethostbyname calls, which can
86 #               invoke dynamically loadable library facility anyway to meet
87 #               the lookup requests. For this reason on Linux statically
88 #               linked openssl executable has rather debugging value than
89 #               production quality.
90 #
91 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
92 #               provided to stack calls. Generates unique stack functions for
93 #               each possible stack type.
94 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
95 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
96 # Following are set automatically by this script
97 #
98 # MD5_ASM       use some extra md5 assembler,
99 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
100 # RMD160_ASM    use some extra ripemd160 assembler,
101 # SHA256_ASM    sha256_block is implemented in assembler
102 # SHA512_ASM    sha512_block is implemented in assembler
103 # AES_ASM       AES_[en|de]crypt is implemented in assembler
104
105 # Minimum warning options... any contributions to OpenSSL should at least
106 # get past these.  Note that we only use these with C compilers, not with
107 # C++ compilers.
108
109 # DEBUG_UNUSED enables __owur (warn unused result) checks.
110 # -DPEDANTIC complements -pedantic and is meant to mask code that
111 # is not strictly standard-compliant and/or implementation-specific,
112 # e.g. inline assembly, disregards to alignment requirements, such
113 # that -pedantic would complain about. Incidentally -DPEDANTIC has
114 # to be used even in sanitized builds, because sanitizer too is
115 # supposed to and does take notice of non-standard behaviour. Then
116 # -pedantic with pre-C9x compiler would also complain about 'long
117 # long' not being supported. As 64-bit algorithms are common now,
118 # it grew impossible to resolve this without sizeable additional
119 # code, so we just tell compiler to be pedantic about everything
120 # but 'long long' type.
121
122 my @gcc_devteam_warn = qw(
123     -DDEBUG_UNUSED
124     -DPEDANTIC -pedantic -Wno-long-long
125     -Wall
126     -Wextra
127     -Wno-unused-parameter
128     -Wno-missing-field-initializers
129     -Wswitch
130     -Wsign-compare
131     -Wshadow
132     -Wformat
133     -Wtype-limits
134     -Wundef
135     -Werror
136     -Wmissing-prototypes
137     -Wstrict-prototypes
138 );
139
140 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
141 # TODO(openssl-team): fix problems and investigate if (at least) the
142 # following warnings can also be enabled:
143 #       -Wcast-align
144 #       -Wunreachable-code -- no, too ugly/compiler-specific
145 #       -Wlanguage-extension-token -- no, we use asm()
146 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
147 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
148 my @clang_devteam_warn = qw(
149     -Wswitch-default
150     -Wno-parentheses-equality
151     -Wno-language-extension-token
152     -Wno-extended-offsetof
153     -Wconditional-uninitialized
154     -Wincompatible-pointer-types-discards-qualifiers
155     -Wno-unknown-warning-option
156     -Wmissing-variable-declarations
157 );
158
159 # This adds backtrace information to the memory leak info.  Is only used
160 # when crypto-mdebug-backtrace is enabled.
161 my $memleak_devteam_backtrace = "-rdynamic";
162
163 my $strict_warnings = 0;
164
165 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
166 # which would cover all BSD flavors. -pthread applies to them all,
167 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
168 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
169 # which has to be accompanied by explicit -D_THREAD_SAFE and
170 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
171 # seems to be sufficient?
172 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
173
174 #
175 # API compatibility name to version number mapping.
176 #
177 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
178 my $apitable = {
179     "3.0.0" => 3,
180     "1.1.1" => 2,
181     "1.1.0" => 2,
182     "1.0.2" => 1,
183     "1.0.1" => 1,
184     "1.0.0" => 1,
185     "0.9.8" => 0,
186 };
187
188 our %table = ();
189 our %config = ();
190 our %withargs = ();
191 our $now_printing;      # set to current entry's name in print_table_entry
192                         # (todo: right thing would be to encapsulate name
193                         # into %target [class] and make print_table_entry
194                         # a method)
195
196 # Forward declarations ###############################################
197
198 # read_config(filename)
199 #
200 # Reads a configuration file and populates %table with the contents
201 # (which the configuration file places in %targets).
202 sub read_config;
203
204 # resolve_config(target)
205 #
206 # Resolves all the late evaluations, inheritances and so on for the
207 # chosen target and any target it inherits from.
208 sub resolve_config;
209
210
211 # Information collection #############################################
212
213 # Unified build supports separate build dir
214 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
215 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
216 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
217
218 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
219
220 $config{sourcedir} = abs2rel($srcdir);
221 $config{builddir} = abs2rel($blddir);
222
223 # Collect reconfiguration information if needed
224 my @argvcopy=@ARGV;
225
226 if (grep /^reconf(igure)?$/, @argvcopy) {
227     die "reconfiguring with other arguments present isn't supported"
228         if scalar @argvcopy > 1;
229     if (-f "./configdata.pm") {
230         my $file = "./configdata.pm";
231         unless (my $return = do $file) {
232             die "couldn't parse $file: $@" if $@;
233             die "couldn't do $file: $!"    unless defined $return;
234             die "couldn't run $file"       unless $return;
235         }
236
237         @argvcopy = defined($configdata::config{perlargv}) ?
238             @{$configdata::config{perlargv}} : ();
239         die "Incorrect data to reconfigure, please do a normal configuration\n"
240             if (grep(/^reconf/,@argvcopy));
241         $config{perlenv} = $configdata::config{perlenv} // {};
242     } else {
243         die "Insufficient data to reconfigure, please do a normal configuration\n";
244     }
245 }
246
247 $config{perlargv} = [ @argvcopy ];
248
249 # Collect version numbers
250 $config{major} = "unknown";
251 $config{minor} = "unknown";
252 $config{patch} = "unknown";
253 $config{prerelease} = "";
254 $config{build_metadata} = "";
255 $config{shlib_version} = "unknown";
256
257 collect_information(
258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
259     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
260         sub { $config{major} = $1; },
261     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
262         sub { $config{minor} = $1; },
263     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
264         sub { $config{patch} = $1; },
265     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
266         sub { $config{prerelease} = $1; },
267     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
268         sub { $config{build_metadata} = $1; },
269     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
270         sub { $config{shlib_version} = $1; },
271     );
272 die "erroneous version information in opensslv.h: ",
273     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
274     if ($config{major} eq "unknown"
275             || $config{minor} eq "unknown"
276             || $config{patch} eq "unknown"
277             || $config{shlib_version} eq "unknown");
278
279 $config{version} = "$config{major}.$config{minor}.$config{patch}";
280 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
281
282 # Collect target configurations
283
284 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
285 foreach (sort glob($pattern)) {
286     &read_config($_);
287 }
288
289 if (defined env($local_config_envname)) {
290     if ($^O eq 'VMS') {
291         # VMS environment variables are logical names,
292         # which can be used as is
293         $pattern = $local_config_envname . ':' . '*.conf';
294     } else {
295         $pattern = catfile(env($local_config_envname), '*.conf');
296     }
297
298     foreach (sort glob($pattern)) {
299         &read_config($_);
300     }
301 }
302
303 # Save away perl command information
304 $config{perl_cmd} = $^X;
305 $config{perl_version} = $Config{version};
306 $config{perl_archname} = $Config{archname};
307
308 $config{prefix}="";
309 $config{openssldir}="";
310 $config{processor}="";
311 $config{libdir}="";
312 my $auto_threads=1;    # enable threads automatically? true by default
313 my $default_ranlib;
314
315 # Known TLS and DTLS protocols
316 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
317 my @dtls = qw(dtls1 dtls1_2);
318
319 # Explicitly known options that are possible to disable.  They can
320 # be regexps, and will be used like this: /^no-${option}$/
321 # For developers: keep it sorted alphabetically
322
323 my @disablables = (
324     "ktls",
325     "afalgeng",
326     "aria",
327     "asan",
328     "asm",
329     "async",
330     "autoalginit",
331     "autoerrinit",
332     "autoload-config",
333     "bf",
334     "blake2",
335     "buildtest-c++",
336     "camellia",
337     "capieng",
338     "cast",
339     "chacha",
340     "cmac",
341     "cmp",
342     "cms",
343     "comp",
344     "crypto-mdebug",
345     "crypto-mdebug-backtrace",
346     "ct",
347     "deprecated",
348     "des",
349     "devcryptoeng",
350     "dgram",
351     "dh",
352     "dsa",
353     "dtls",
354     "dynamic-engine",
355     "ec",
356     "ec2m",
357     "ecdh",
358     "ecdsa",
359     "ec_nistp_64_gcc_128",
360     "egd",
361     "engine",
362     "err",
363     "external-tests",
364     "filenames",
365     "fips",
366     "fuzz-libfuzzer",
367     "fuzz-afl",
368     "gost",
369     "idea",
370     "legacy",
371     "makedepend",
372     "md2",
373     "md4",
374     "mdc2",
375     "module",
376     "msan",
377     "multiblock",
378     "nextprotoneg",
379     "pinshared",
380     "ocb",
381     "ocsp",
382     "padlockeng",
383     "pic",
384     "poly1305",
385     "posix-io",
386     "psk",
387     "rc2",
388     "rc4",
389     "rc5",
390     "rdrand",
391     "rfc3779",
392     "rmd160",
393     "scrypt",
394     "sctp",
395     "seed",
396     "shared",
397     "siphash",
398     "siv",
399     "sm2",
400     "sm3",
401     "sm4",
402     "sock",
403     "srp",
404     "srtp",
405     "sse2",
406     "ssl",
407     "ssl-trace",
408     "static-engine",
409     "stdio",
410     "tests",
411     "threads",
412     "tls",
413     "trace",
414     "ts",
415     "ubsan",
416     "ui-console",
417     "unit-test",
418     "whirlpool",
419     "weak-ssl-ciphers",
420     "zlib",
421     "zlib-dynamic",
422     );
423 foreach my $proto ((@tls, @dtls))
424         {
425         push(@disablables, $proto);
426         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
427         }
428
429 # Internal disablables, for aliasing purposes.  They serve no special
430 # purpose here, but allow scripts to get to know them through configdata.pm,
431 # where these are merged with @disablables.
432 # The actual aliasing mechanism is done via %disable_cascades
433 my @disablables_int = qw(
434     crmf
435     );
436
437 my %deprecated_disablables = (
438     "ssl2" => undef,
439     "buf-freelists" => undef,
440     "hw" => "hw",               # causes cascade, but no macro
441     "hw-padlock" => "padlockeng",
442     "ripemd" => "rmd160",
443     "ui" => "ui-console",
444     "dso" => undef,
445     "heartbeats" => undef,
446     );
447
448 # All of the following are disabled by default:
449
450 our %disabled = ( # "what"         => "comment"
451                   "asan"                => "default",
452                   "buildtest-c++"       => "default",
453                   "crypto-mdebug"       => "default",
454                   "crypto-mdebug-backtrace" => "default",
455                   "devcryptoeng"        => "default",
456                   "ec_nistp_64_gcc_128" => "default",
457                   "egd"                 => "default",
458                   "external-tests"      => "default",
459                   "fuzz-libfuzzer"      => "default",
460                   "fuzz-afl"            => "default",
461                   "md2"                 => "default",
462                   "msan"                => "default",
463                   "rc5"                 => "default",
464                   "sctp"                => "default",
465                   "ssl-trace"           => "default",
466                   "ssl3"                => "default",
467                   "ssl3-method"         => "default",
468                   "trace"               => "default",
469                   "ubsan"               => "default",
470                   "unit-test"           => "default",
471                   "weak-ssl-ciphers"    => "default",
472                   "zlib"                => "default",
473                   "zlib-dynamic"        => "default",
474                   "ktls"                => "default",
475                 );
476
477 # Note: => pair form used for aesthetics, not to truly make a hash table
478 my @disable_cascades = (
479     # "what"            => [ "cascade", ... ]
480     sub { $config{processor} eq "386" }
481                         => [ "sse2" ],
482     "ssl"               => [ "ssl3" ],
483     "ssl3-method"       => [ "ssl3" ],
484     "zlib"              => [ "zlib-dynamic" ],
485     "des"               => [ "mdc2" ],
486     "ec"                => [ "ecdsa", "ecdh" ],
487
488     "dgram"             => [ "dtls", "sctp" ],
489     "sock"              => [ "dgram" ],
490     "dtls"              => [ @dtls ],
491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
492                         => [ "dtls" ],
493
494     "tls"               => [ @tls ],
495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
496                         => [ "tls" ],
497
498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
499
500     # If no modules, then no dynamic engines either
501     "module"            => [ "dynamic-engine" ],
502
503     # Without shared libraries, dynamic engines aren't possible.
504     # This is due to them having to link with libcrypto and register features
505     # using the ENGINE functionality, and since that relies on global tables,
506     # those *have* to be exacty the same as the ones accessed from the app,
507     # which cannot be guaranteed if shared libraries aren't present.
508     # (note that even with shared libraries, both the app and dynamic engines
509     # must be linked with the same library)
510     "shared"            => [ "dynamic-engine" ],
511     # Other modules don't necessarily have to link with libcrypto, so shared
512     # libraries do not have to be a condition to produce those.
513
514     # Without position independent code, there can be no shared libraries
515     # or modules.
516     "pic"               => [ "shared", "module" ],
517
518     "module"            => [ "fips", "legacy" ],
519
520     "engine"            => [ grep /eng$/, @disablables ],
521     "hw"                => [ "padlockeng" ],
522
523     # no-autoalginit is only useful when building non-shared
524     "autoalginit"       => [ "shared", "apps" ],
525
526     "stdio"             => [ "apps", "capieng", "egd" ],
527     "apps"              => [ "tests" ],
528     "tests"             => [ "external-tests" ],
529     "comp"              => [ "zlib" ],
530     "ec"                => [ "tls1_3", "sm2" ],
531     "sm3"               => [ "sm2" ],
532     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
533
534     sub { !$disabled{"msan"} } => [ "asm" ],
535
536     sub { $disabled{cmac}; } => [ "siv" ],
537     "legacy"                 => [ "md2" ],
538
539     "cmp"               => [ "crmf" ],
540     );
541
542 # Avoid protocol support holes.  Also disable all versions below N, if version
543 # N is disabled while N+1 is enabled.
544 #
545 my @list = (reverse @tls);
546 while ((my $first, my $second) = (shift @list, shift @list)) {
547     last unless @list;
548     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
549                               => [ @list ] );
550     unshift @list, $second;
551 }
552 my @list = (reverse @dtls);
553 while ((my $first, my $second) = (shift @list, shift @list)) {
554     last unless @list;
555     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
556                               => [ @list ] );
557     unshift @list, $second;
558 }
559
560 # Explicit "no-..." options will be collected in %disabled along with the defaults.
561 # To remove something from %disabled, use "enable-foo".
562 # For symmetry, "disable-foo" is a synonym for "no-foo".
563
564 &usage if ($#ARGV < 0);
565
566 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
567 # platform specific list separators.  Users from those platforms should
568 # recognise those separators from how you set up the PATH to find executables.
569 # The default is the Unix like separator, :, but as an exception, we also
570 # support the space as separator.
571 my $list_separator_re =
572     { VMS           => qr/(?<!\^),/,
573       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
574 # All the "make variables" we support
575 # Some get pre-populated for the sake of backward compatibility
576 # (we supported those before the change to "make variable" support.
577 my %user = (
578     AR          => env('AR'),
579     ARFLAGS     => [],
580     AS          => undef,
581     ASFLAGS     => [],
582     CC          => env('CC'),
583     CFLAGS      => [ env('CFLAGS') || () ],
584     CXX         => env('CXX'),
585     CXXFLAGS    => [ env('CXXFLAGS') || () ],
586     CPP         => undef,
587     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
588     CPPDEFINES  => [],  # Alternative for -D
589     CPPINCLUDES => [],  # Alternative for -I
590     CROSS_COMPILE => env('CROSS_COMPILE'),
591     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
592     LD          => undef,
593     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
594     LDLIBS      => [ env('LDLIBS') || () ],  # -l
595     MT          => undef,
596     MTFLAGS     => [],
597     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
598     RANLIB      => env('RANLIB'),
599     RC          => env('RC') || env('WINDRES'),
600     RCFLAGS     => [ env('RCFLAGS') || () ],
601     RM          => undef,
602    );
603 # Info about what "make variables" may be prefixed with the cross compiler
604 # prefix.  This should NEVER mention any such variable with a list for value.
605 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
606 # The same but for flags given as Configure options.  These are *additional*
607 # input, as opposed to the VAR=string option that override the corresponding
608 # config target attributes
609 my %useradd = (
610     CPPDEFINES  => [],
611     CPPINCLUDES => [],
612     CPPFLAGS    => [],
613     CFLAGS      => [],
614     CXXFLAGS    => [],
615     LDFLAGS     => [],
616     LDLIBS      => [],
617     RCFLAGS     => [],
618    );
619
620 my %user_synonyms = (
621     HASHBANGPERL=> 'PERL',
622     RC          => 'WINDRES',
623    );
624
625 # Some target attributes have been renamed, this is the translation table
626 my %target_attr_translate =(
627     ar          => 'AR',
628     as          => 'AS',
629     cc          => 'CC',
630     cxx         => 'CXX',
631     cpp         => 'CPP',
632     hashbangperl => 'HASHBANGPERL',
633     ld          => 'LD',
634     mt          => 'MT',
635     ranlib      => 'RANLIB',
636     rc          => 'RC',
637     rm          => 'RM',
638    );
639
640 # Initialisers coming from 'config' scripts
641 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
642 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
643 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
644 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
645 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
646 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
647 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
648
649 $config{openssl_api_defines}=[];
650 $config{openssl_sys_defines}=[];
651 $config{openssl_feature_defines}=[];
652 $config{options}="";
653 $config{build_type} = "release";
654 my $target="";
655
656 my %cmdvars = ();               # Stores FOO='blah' type arguments
657 my %unsupported_options = ();
658 my %deprecated_options = ();
659 # If you change this, update apps/version.c
660 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
661 my @seed_sources = ();
662 while (@argvcopy)
663         {
664         $_ = shift @argvcopy;
665
666         # Support env variable assignments among the options
667         if (m|^(\w+)=(.+)?$|)
668                 {
669                 $cmdvars{$1} = $2;
670                 # Every time a variable is given as a configuration argument,
671                 # it acts as a reset if the variable.
672                 if (exists $user{$1})
673                         {
674                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
675                         }
676                 #if (exists $useradd{$1})
677                 #       {
678                 #       $useradd{$1} = [];
679                 #       }
680                 next;
681                 }
682
683         # VMS is a case insensitive environment, and depending on settings
684         # out of our control, we may receive options uppercased.  Let's
685         # downcase at least the part before any equal sign.
686         if ($^O eq "VMS")
687                 {
688                 s/^([^=]*)/lc($1)/e;
689                 }
690
691         # some people just can't read the instructions, clang people have to...
692         s/^-no-(?!integrated-as)/no-/;
693
694         # rewrite some options in "enable-..." form
695         s /^-?-?shared$/enable-shared/;
696         s /^sctp$/enable-sctp/;
697         s /^threads$/enable-threads/;
698         s /^zlib$/enable-zlib/;
699         s /^zlib-dynamic$/enable-zlib-dynamic/;
700
701         if (/^(no|disable|enable)-(.+)$/)
702                 {
703                 my $word = $2;
704                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
705                         && !exists $deprecated_disablables{$word}
706                         && !grep { $word eq $_ } @disablables)
707                         {
708                         $unsupported_options{$_} = 1;
709                         next;
710                         }
711                 }
712         if (/^no-(.+)$/ || /^disable-(.+)$/)
713                 {
714                 foreach my $proto ((@tls, @dtls))
715                         {
716                         if ($1 eq "$proto-method")
717                                 {
718                                 $disabled{"$proto"} = "option($proto-method)";
719                                 last;
720                                 }
721                         }
722                 if ($1 eq "dtls")
723                         {
724                         foreach my $proto (@dtls)
725                                 {
726                                 $disabled{$proto} = "option(dtls)";
727                                 }
728                         $disabled{"dtls"} = "option(dtls)";
729                         }
730                 elsif ($1 eq "ssl")
731                         {
732                         # Last one of its kind
733                         $disabled{"ssl3"} = "option(ssl)";
734                         }
735                 elsif ($1 eq "tls")
736                         {
737                         # XXX: Tests will fail if all SSL/TLS
738                         # protocols are disabled.
739                         foreach my $proto (@tls)
740                                 {
741                                 $disabled{$proto} = "option(tls)";
742                                 }
743                         }
744                 elsif ($1 eq "static-engine")
745                         {
746                         delete $disabled{"dynamic-engine"};
747                         }
748                 elsif ($1 eq "dynamic-engine")
749                         {
750                         $disabled{"dynamic-engine"} = "option";
751                         }
752                 elsif (exists $deprecated_disablables{$1})
753                         {
754                         $deprecated_options{$_} = 1;
755                         if (defined $deprecated_disablables{$1})
756                                 {
757                                 $disabled{$deprecated_disablables{$1}} = "option";
758                                 }
759                         }
760                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
761                         {
762                         $deprecated_options{$_} = 1;
763                         }
764                 else
765                         {
766                         $disabled{$1} = "option";
767                         }
768                 # No longer an automatic choice
769                 $auto_threads = 0 if ($1 eq "threads");
770                 }
771         elsif (/^enable-(.+)$/)
772                 {
773                 if ($1 eq "static-engine")
774                         {
775                         $disabled{"dynamic-engine"} = "option";
776                         }
777                 elsif ($1 eq "dynamic-engine")
778                         {
779                         delete $disabled{"dynamic-engine"};
780                         }
781                 elsif ($1 eq "zlib-dynamic")
782                         {
783                         delete $disabled{"zlib"};
784                         }
785                 my $algo = $1;
786                 delete $disabled{$algo};
787
788                 # No longer an automatic choice
789                 $auto_threads = 0 if ($1 eq "threads");
790                 }
791         elsif (/^--strict-warnings$/)
792                 {
793                 # Pretend that our strict flags is a C flag, and replace it
794                 # with the proper flags later on
795                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
796                 $strict_warnings=1;
797                 }
798         elsif (/^--debug$/)
799                 {
800                 $config{build_type} = "debug";
801                 }
802         elsif (/^--release$/)
803                 {
804                 $config{build_type} = "release";
805                 }
806         elsif (/^386$/)
807                 { $config{processor}=386; }
808         elsif (/^fips$/)
809                 {
810                 die "FIPS mode not supported\n";
811                 }
812         elsif (/^rsaref$/)
813                 {
814                 # No RSAref support any more since it's not needed.
815                 # The check for the option is there so scripts aren't
816                 # broken
817                 }
818         elsif (/^nofipscanistercheck$/)
819                 {
820                 die "FIPS mode not supported\n";
821                 }
822         elsif (/^[-+]/)
823                 {
824                 if (/^--prefix=(.*)$/)
825                         {
826                         $config{prefix}=$1;
827                         die "Directory given with --prefix MUST be absolute\n"
828                                 unless file_name_is_absolute($config{prefix});
829                         }
830                 elsif (/^--api=(.*)$/)
831                         {
832                         $config{api}=$1;
833                         }
834                 elsif (/^--libdir=(.*)$/)
835                         {
836                         $config{libdir}=$1;
837                         }
838                 elsif (/^--openssldir=(.*)$/)
839                         {
840                         $config{openssldir}=$1;
841                         }
842                 elsif (/^--with-zlib-lib=(.*)$/)
843                         {
844                         $withargs{zlib_lib}=$1;
845                         }
846                 elsif (/^--with-zlib-include=(.*)$/)
847                         {
848                         $withargs{zlib_include}=$1;
849                         }
850                 elsif (/^--with-fuzzer-lib=(.*)$/)
851                         {
852                         $withargs{fuzzer_lib}=$1;
853                         }
854                 elsif (/^--with-fuzzer-include=(.*)$/)
855                         {
856                         $withargs{fuzzer_include}=$1;
857                         }
858                 elsif (/^--with-rand-seed=(.*)$/)
859                         {
860                         foreach my $x (split(m|,|, $1))
861                             {
862                             die "Unknown --with-rand-seed choice $x\n"
863                                 if ! grep { $x eq $_ } @known_seed_sources;
864                             push @seed_sources, $x;
865                             }
866                         }
867                 elsif (/^--cross-compile-prefix=(.*)$/)
868                         {
869                         $user{CROSS_COMPILE}=$1;
870                         }
871                 elsif (/^--config=(.*)$/)
872                         {
873                         read_config $1;
874                         }
875                 elsif (/^-l(.*)$/)
876                         {
877                         push @{$useradd{LDLIBS}}, $_;
878                         }
879                 elsif (/^-framework$/)
880                         {
881                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
882                         }
883                 elsif (/^-L(.*)$/ or /^-Wl,/)
884                         {
885                         push @{$useradd{LDFLAGS}}, $_;
886                         }
887                 elsif (/^-rpath$/ or /^-R$/)
888                         # -rpath is the OSF1 rpath flag
889                         # -R is the old Solaris rpath flag
890                         {
891                         my $rpath = shift(@argvcopy) || "";
892                         $rpath .= " " if $rpath ne "";
893                         push @{$useradd{LDFLAGS}}, $_, $rpath;
894                         }
895                 elsif (/^-static$/)
896                         {
897                         push @{$useradd{LDFLAGS}}, $_;
898                         }
899                 elsif (/^-D(.*)$/)
900                         {
901                         push @{$useradd{CPPDEFINES}}, $1;
902                         }
903                 elsif (/^-I(.*)$/)
904                         {
905                         push @{$useradd{CPPINCLUDES}}, $1;
906                         }
907                 elsif (/^-Wp,$/)
908                         {
909                         push @{$useradd{CPPFLAGS}}, $1;
910                         }
911                 else    # common if (/^[-+]/), just pass down...
912                         {
913                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
914                         push @{$useradd{CFLAGS}}, $_;
915                         push @{$useradd{CXXFLAGS}}, $_;
916                         }
917                 }
918         else
919                 {
920                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
921                 $target=$_;
922                 }
923         unless ($_ eq $target || /^no-/ || /^disable-/)
924                 {
925                 # "no-..." follows later after implied deactivations
926                 # have been derived.  (Don't take this too seriously,
927                 # we really only write OPTIONS to the Makefile out of
928                 # nostalgia.)
929
930                 if ($config{options} eq "")
931                         { $config{options} = $_; }
932                 else
933                         { $config{options} .= " ".$_; }
934                 }
935         }
936
937 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
938         die "***** Unsupported api compatibility level: $config{api}\n",
939 }
940
941 if (keys %deprecated_options)
942         {
943         warn "***** Deprecated options: ",
944                 join(", ", keys %deprecated_options), "\n";
945         }
946 if (keys %unsupported_options)
947         {
948         die "***** Unsupported options: ",
949                 join(", ", keys %unsupported_options), "\n";
950         }
951
952 # If any %useradd entry has been set, we must check that the "make
953 # variables" haven't been set.  We start by checking of any %useradd entry
954 # is set.
955 if (grep { scalar @$_ > 0 } values %useradd) {
956     # Hash of env / make variables names.  The possible values are:
957     # 1 - "make vars"
958     # 2 - %useradd entry set
959     # 3 - both set
960     my %detected_vars =
961         map { my $v = 0;
962               $v += 1 if $cmdvars{$_};
963               $v += 2 if @{$useradd{$_}};
964               $_ => $v }
965         keys %useradd;
966
967     # If any of the corresponding "make variables" is set, we error
968     if (grep { $_ & 1 } values %detected_vars) {
969         my $names = join(', ', grep { $detected_vars{$_} > 0 }
970                                sort keys %detected_vars);
971         die <<"_____";
972 ***** Mixing make variables and additional compiler/linker flags as
973 ***** configure command line option is not permitted.
974 ***** Affected make variables: $names
975 _____
976     }
977 }
978
979 # Check through all supported command line variables to see if any of them
980 # were set, and canonicalise the values we got.  If no compiler or linker
981 # flag or anything else that affects %useradd was set, we also check the
982 # environment for values.
983 my $anyuseradd =
984     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
985 foreach (keys %user) {
986     my $value = $cmdvars{$_};
987     $value //= env($_) unless $anyuseradd;
988     $value //=
989         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
990     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
991         unless $anyuseradd;
992
993     if (defined $value) {
994         if (ref $user{$_} eq 'ARRAY') {
995             $user{$_} = [ split /$list_separator_re/, $value ];
996         } elsif (!defined $user{$_}) {
997             $user{$_} = $value;
998         }
999     }
1000 }
1001
1002 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1003     && !$disabled{shared}
1004     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1005     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1006         "***** any of asan, msan or ubsan\n";
1007 }
1008
1009 sub disable {
1010     my $disable_type = shift;
1011
1012     for (@_) {
1013         $disabled{$_} = $disable_type;
1014     }
1015
1016     my @tocheckfor = (@_ ? @_ : keys %disabled);
1017     while (@tocheckfor) {
1018         my %new_tocheckfor = ();
1019         my @cascade_copy = (@disable_cascades);
1020         while (@cascade_copy) {
1021             my ($test, $descendents) =
1022                 (shift @cascade_copy, shift @cascade_copy);
1023             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1024                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1025                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1026                 }
1027             }
1028         }
1029         @tocheckfor = (keys %new_tocheckfor);
1030     }
1031 }
1032 disable();                     # First cascade run
1033
1034 our $die = sub { die @_; };
1035 if ($target eq "TABLE") {
1036     local $die = sub { warn @_; };
1037     foreach (sort keys %table) {
1038         print_table_entry($_, "TABLE");
1039     }
1040     exit 0;
1041 }
1042
1043 if ($target eq "LIST") {
1044     foreach (sort keys %table) {
1045         print $_,"\n" unless $table{$_}->{template};
1046     }
1047     exit 0;
1048 }
1049
1050 if ($target eq "HASH") {
1051     local $die = sub { warn @_; };
1052     print "%table = (\n";
1053     foreach (sort keys %table) {
1054         print_table_entry($_, "HASH");
1055     }
1056     exit 0;
1057 }
1058
1059 print "Configuring OpenSSL version $config{full_version} ";
1060 print "for target $target\n";
1061
1062 if (scalar(@seed_sources) == 0) {
1063     print "Using os-specific seed configuration\n";
1064     push @seed_sources, 'os';
1065 }
1066 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1067     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1068     warn <<_____ if scalar(@seed_sources) == 1;
1069
1070 ============================== WARNING ===============================
1071 You have selected the --with-rand-seed=none option, which effectively
1072 disables automatic reseeding of the OpenSSL random generator.
1073 All operations depending on the random generator such as creating keys
1074 will not work unless the random generator is seeded manually by the
1075 application.
1076
1077 Please read the 'Note on random number generation' section in the
1078 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1079 ============================== WARNING ===============================
1080
1081 _____
1082 }
1083 push @{$config{openssl_feature_defines}},
1084      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1085         @seed_sources;
1086
1087 # Backward compatibility?
1088 if ($target =~ m/^CygWin32(-.*)$/) {
1089     $target = "Cygwin".$1;
1090 }
1091
1092 # Support for legacy targets having a name starting with 'debug-'
1093 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1094 if ($d) {
1095     $config{build_type} = "debug";
1096
1097     # If we do not find debug-foo in the table, the target is set to foo.
1098     if (!$table{$target}) {
1099         $target = $t;
1100     }
1101 }
1102
1103 &usage if !$table{$target} || $table{$target}->{template};
1104
1105 $config{target} = $target;
1106 my %target = resolve_config($target);
1107
1108 foreach (keys %target_attr_translate) {
1109     $target{$target_attr_translate{$_}} = $target{$_}
1110         if $target{$_};
1111     delete $target{$_};
1112 }
1113
1114 %target = ( %{$table{DEFAULTS}}, %target );
1115
1116 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1117 $config{conf_files} = [ sort keys %conf_files ];
1118
1119 # Using sub disable within these loops may prove fragile, so we run
1120 # a cascade afterwards
1121 foreach my $feature (@{$target{disable}}) {
1122     if (exists $deprecated_disablables{$feature}) {
1123         warn "***** config $target disables deprecated feature $feature\n";
1124     } elsif (!grep { $feature eq $_ } @disablables) {
1125         die "***** config $target disables unknown feature $feature\n";
1126     }
1127     $disabled{$feature} = 'config';
1128 }
1129 foreach my $feature (@{$target{enable}}) {
1130     if ("default" eq ($disabled{$feature} // "")) {
1131         if (exists $deprecated_disablables{$feature}) {
1132             warn "***** config $target enables deprecated feature $feature\n";
1133         } elsif (!grep { $feature eq $_ } @disablables) {
1134             die "***** config $target enables unknown feature $feature\n";
1135         }
1136         delete $disabled{$feature};
1137     }
1138 }
1139 disable();                      # Run a cascade now
1140
1141 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1142 $target{cxxflags}//=$target{cflags} if $target{CXX};
1143 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1144 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1145
1146 # Fill %config with values from %user, and in case those are undefined or
1147 # empty, use values from %target (acting as a default).
1148 foreach (keys %user) {
1149     my $ref_type = ref $user{$_};
1150
1151     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1152     # and a value that's to be coerced into that type.
1153     my $mkvalue = sub {
1154         my $type = shift;
1155         my $value = shift;
1156         my $undef_p = shift;
1157
1158         die "Too many arguments for \$mkvalue" if @_;
1159
1160         while (ref $value eq 'CODE') {
1161             $value = $value->();
1162         }
1163
1164         if ($type eq 'ARRAY') {
1165             return undef unless defined $value;
1166             return undef if ref $value ne 'ARRAY' && !$value;
1167             return undef if ref $value eq 'ARRAY' && !@$value;
1168             return [ $value ] unless ref $value eq 'ARRAY';
1169         }
1170         return undef unless $value;
1171         return $value;
1172     };
1173
1174     $config{$_} =
1175         $mkvalue->($ref_type, $user{$_})
1176         || $mkvalue->($ref_type, $target{$_});
1177     delete $config{$_} unless defined $config{$_};
1178 }
1179
1180 # Finish up %config by appending things the user gave us on the command line
1181 # apart from "make variables"
1182 foreach (keys %useradd) {
1183     # The must all be lists, so we assert that here
1184     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1185         unless ref $useradd{$_} eq 'ARRAY';
1186
1187     if (defined $config{$_}) {
1188         push @{$config{$_}}, @{$useradd{$_}};
1189     } else {
1190         $config{$_} = [ @{$useradd{$_}} ];
1191     }
1192 }
1193 # At this point, we can forget everything about %user and %useradd,
1194 # because it's now all been merged into the corresponding $config entry
1195
1196 # Allow overriding the build file name
1197 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1198
1199 ######################################################################
1200 # Build up information for skipping certain directories depending on disabled
1201 # features, as well as setting up macros for disabled features.
1202
1203 # This is a tentative database of directories to skip.  Some entries may not
1204 # correspond to anything real, but that's ok, they will simply be ignored.
1205 # The actual processing of these entries is done in the build.info lookup
1206 # loop further down.
1207 #
1208 # The key is a Unix formated path in the source tree, the value is an index
1209 # into %disabled_info, so any existing path gets added to a corresponding
1210 # 'skipped' entry in there with the list of skipped directories.
1211 my %skipdir = ();
1212 my %disabled_info = ();         # For configdata.pm
1213 foreach my $what (sort keys %disabled) {
1214     # There are deprecated disablables that translate to themselves.
1215     # They cause disabling cascades, but should otherwise not regiter.
1216     next if $deprecated_disablables{$what};
1217
1218     $config{options} .= " no-$what";
1219
1220     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1221                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1222                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1223         (my $WHAT = uc $what) =~ s|-|_|g;
1224         my $skipdir = $what;
1225
1226         # fix-up crypto/directory name(s)
1227         $skipdir = "ripemd" if $what eq "rmd160";
1228         $skipdir = "whrlpool" if $what eq "whirlpool";
1229
1230         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1231         push @{$config{openssl_feature_defines}}, $macro;
1232
1233         $skipdir{engines} = $what if $what eq 'engine';
1234         $skipdir{"crypto/$skipdir"} = $what
1235             unless $what eq 'async' || $what eq 'err';
1236     }
1237 }
1238
1239 # Make sure build_scheme is consistent.
1240 $target{build_scheme} = [ $target{build_scheme} ]
1241     if ref($target{build_scheme}) ne "ARRAY";
1242
1243 my ($builder, $builder_platform, @builder_opts) =
1244     @{$target{build_scheme}};
1245
1246 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1247                       $builder_platform."-checker.pm")) {
1248     my $checker_path = catfile($srcdir, "Configurations", $checker);
1249     if (-f $checker_path) {
1250         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1251             ? sub { warn $@; } : sub { die $@; };
1252         if (! do $checker_path) {
1253             if ($@) {
1254                 $fn->($@);
1255             } elsif ($!) {
1256                 $fn->($!);
1257             } else {
1258                 $fn->("The detected tools didn't match the platform\n");
1259             }
1260         }
1261         last;
1262     }
1263 }
1264
1265 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1266
1267 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1268         {
1269         push @{$config{cflags}}, "-mno-cygwin";
1270         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1271         push @{$config{shared_ldflag}}, "-mno-cygwin";
1272         }
1273
1274 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1275         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1276         # minimally required architecture flags for assembly modules
1277         my $value;
1278         $value = '-mips2' if ($target =~ /mips32/);
1279         $value = '-mips3' if ($target =~ /mips64/);
1280         unshift @{$config{cflags}}, $value;
1281         unshift @{$config{cxxflags}}, $value if $config{CXX};
1282 }
1283
1284 # If threads aren't disabled, check how possible they are
1285 unless ($disabled{threads}) {
1286     if ($auto_threads) {
1287         # Enabled by default, disable it forcibly if unavailable
1288         if ($target{thread_scheme} eq "(unknown)") {
1289             disable("unavailable", 'threads');
1290         }
1291     } else {
1292         # The user chose to enable threads explicitly, let's see
1293         # if there's a chance that's possible
1294         if ($target{thread_scheme} eq "(unknown)") {
1295             # If the user asked for "threads" and we don't have internal
1296             # knowledge how to do it, [s]he is expected to provide any
1297             # system-dependent compiler options that are necessary.  We
1298             # can't truly check that the given options are correct, but
1299             # we expect the user to know what [s]He is doing.
1300             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1301                 die "You asked for multi-threading support, but didn't\n"
1302                     ,"provide any system-specific compiler options\n";
1303             }
1304         }
1305     }
1306 }
1307
1308 # Find out if clang's sanitizers have been enabled with -fsanitize
1309 # flags and ensure that the corresponding %disabled elements area
1310 # removed to reflect that the sanitizers are indeed enabled.
1311 my %detected_sanitizers = ();
1312 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1313     (my $checks = $_) =~ s/^-fsanitize=//;
1314     foreach (split /,/, $checks) {
1315         my $d = { address       => 'asan',
1316                   undefined     => 'ubsan',
1317                   memory        => 'msan' } -> {$_};
1318         next unless defined $d;
1319
1320         $detected_sanitizers{$d} = 1;
1321         if (defined $disabled{$d}) {
1322             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1323                 if $disabled{$d} ne "default";
1324             delete $disabled{$d};
1325         }
1326     }
1327 }
1328
1329 # If threads still aren't disabled, add a C macro to ensure the source
1330 # code knows about it.  Any other flag is taken care of by the configs.
1331 unless($disabled{threads}) {
1332     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1333 }
1334
1335 # With "deprecated" disable all deprecated features.
1336 if (defined($disabled{"deprecated"})) {
1337         $config{api} = $maxapi;
1338 }
1339
1340 my $no_shared_warn=0;
1341 if ($target{shared_target} eq "")
1342         {
1343         $no_shared_warn = 1
1344             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1345         disable('no-shared-target', 'pic');
1346         }
1347
1348 if ($disabled{"dynamic-engine"}) {
1349         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1350         $config{dynamic_engines} = 0;
1351 } else {
1352         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1353         $config{dynamic_engines} = 1;
1354 }
1355
1356 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1357     push @{$config{cflags}}, "-fsanitize=address";
1358 }
1359
1360 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1361     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1362     # platforms.
1363     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1364 }
1365
1366 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1367   push @{$config{cflags}}, "-fsanitize=memory";
1368 }
1369
1370 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1371         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1372     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1373     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1374 }
1375 #
1376 # Platform fix-ups
1377 #
1378
1379 # This saves the build files from having to check
1380 if ($disabled{pic})
1381         {
1382         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1383                     shared_defines shared_includes shared_ldflag
1384                     module_cflags module_cxxflags module_cppflags
1385                     module_defines module_includes module_lflags))
1386                 {
1387                 delete $config{$_};
1388                 $target{$_} = "";
1389                 }
1390         }
1391 else
1392         {
1393         push @{$config{lib_defines}}, "OPENSSL_PIC";
1394         }
1395
1396 if ($target{sys_id} ne "")
1397         {
1398         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1399         }
1400
1401 unless ($disabled{asm}) {
1402     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1403     if ($target{cpuid_asm_src} ne "mem_clr.c") {
1404         push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ";
1405         push @{$config{module_defines}}, "OPENSSL_CPUID_OBJ";
1406     }
1407
1408     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1409
1410     # bn-586 is the only one implementing bn_*_part_words
1411     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1412     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1413
1414     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1415     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1416     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1417     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1418
1419     if ($target{sha1_asm_src}) {
1420         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1421         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1422         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1423     }
1424     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1425         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1426     }
1427     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1428         push @{$config{lib_defines}}, "RC4_ASM";
1429     }
1430     if ($target{md5_asm_src}) {
1431         push @{$config{lib_defines}}, "MD5_ASM";
1432     }
1433     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1434     if ($target{rmd160_asm_src}) {
1435         push @{$config{lib_defines}}, "RMD160_ASM";
1436     }
1437     if ($target{aes_asm_src}) {
1438         if ($target{aes_asm_src} =~ m/\baes-/) {
1439             push @{$config{lib_defines}}, "AES_ASM";
1440             push @{$config{module_defines}}, "AES_ASM";
1441         }
1442         # aes-ctr.fake is not a real file, only indication that assembler
1443         # module implements AES_ctr32_encrypt...
1444         if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//) {
1445             push @{$config{lib_defines}}, "AES_CTR_ASM";
1446             push @{$config{module_defines}}, "AES_CTR_ASM";
1447         }
1448         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1449         if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//) {
1450             push @{$config{lib_defines}}, "AES_XTS_ASM";
1451             push @{$config{module_defines}}, "AES_XTS_ASM";
1452         }
1453         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1454         if ($target{aes_asm_src} =~ m/vpaes/) {
1455             push @{$config{lib_defines}}, "VPAES_ASM";
1456             push @{$config{module_defines}}, "VPAES_ASM";
1457         }
1458         if ($target{aes_asm_src} =~ m/bsaes/) {
1459             push @{$config{lib_defines}}, "BSAES_ASM";
1460             push @{$config{module_defines}}, "BSAES_ASM";
1461         }
1462     }
1463     if ($target{wp_asm_src} =~ /mmx/) {
1464         if ($config{processor} eq "386") {
1465             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1466         } elsif (!$disabled{"whirlpool"}) {
1467             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1468         }
1469     }
1470     if ($target{modes_asm_src} =~ /ghash-/) {
1471         push @{$config{lib_defines}}, "GHASH_ASM";
1472     }
1473     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1474         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1475     }
1476     if ($target{ec_asm_src} =~ /x25519/) {
1477         push @{$config{lib_defines}}, "X25519_ASM";
1478     }
1479     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1480         push @{$config{dso_defines}}, "PADLOCK_ASM";
1481     }
1482     if ($target{poly1305_asm_src} ne "") {
1483         push @{$config{lib_defines}}, "POLY1305_ASM";
1484     }
1485 }
1486
1487 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1488 my %predefined_CXX = $config{CXX}
1489     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1490     : ();
1491
1492 # Check for makedepend capabilities.
1493 if (!$disabled{makedepend}) {
1494     if ($config{target} =~ /^(VC|vms)-/) {
1495         # For VC- and vms- targets, there's nothing more to do here.  The
1496         # functionality is hard coded in the corresponding build files for
1497         # cl (Windows) and CC/DECC (VMS).
1498     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1499              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1500         # We know that GNU C version 3 and up as well as all clang
1501         # versions support dependency generation, but Xcode did not
1502         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1503         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1504     } else {
1505         # In all other cases, we look for 'makedepend', and disable the
1506         # capability if not found.
1507         $config{makedepprog} = which('makedepend');
1508         disable('unavailable', 'makedepend') unless $config{makedepprog};
1509     }
1510 }
1511
1512 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1513     # probe for -Wa,--noexecstack option...
1514     if ($predefined_C{__clang__}) {
1515         # clang has builtin assembler, which doesn't recognize --help,
1516         # but it apparently recognizes the option in question on all
1517         # supported platforms even when it's meaningless. In other words
1518         # probe would fail, but probed option always accepted...
1519         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1520     } else {
1521         my $cc = $config{CROSS_COMPILE}.$config{CC};
1522         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1523         while(<PIPE>) {
1524             if (m/--noexecstack/) {
1525                 push @{$config{cflags}}, "-Wa,--noexecstack";
1526                 last;
1527             }
1528         }
1529         close(PIPE);
1530         unlink("null.$$.o");
1531     }
1532 }
1533
1534 # Deal with bn_ops ###################################################
1535
1536 $config{bn_ll}                  =0;
1537 $config{export_var_as_fn}       =0;
1538 my $def_int="unsigned int";
1539 $config{rc4_int}                =$def_int;
1540 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1541
1542 my $count = 0;
1543 foreach (sort split(/\s+/,$target{bn_ops})) {
1544     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1545     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1546     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1547     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1548     ($config{b64l},$config{b64},$config{b32})
1549         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1550     ($config{b64l},$config{b64},$config{b32})
1551         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1552     ($config{b64l},$config{b64},$config{b32})
1553         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1554 }
1555 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1556     if $count > 1;
1557
1558
1559 # Hack cflags for better warnings (dev option) #######################
1560
1561 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1562 # a string and works as well on command lines.
1563 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1564                         @{$config{cflags}} ];
1565 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1566                           @{$config{cxxflags}} ] if $config{CXX};
1567
1568 $config{openssl_api_defines} = [
1569     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1570 ];
1571
1572 my @strict_warnings_collection=();
1573 if ($strict_warnings)
1574         {
1575         my $wopt;
1576         my $gccver = $predefined_C{__GNUC__} // -1;
1577
1578         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1579             unless $gccver >= 4;
1580         push @strict_warnings_collection, @gcc_devteam_warn;
1581         push @strict_warnings_collection, @clang_devteam_warn
1582             if (defined($predefined_C{__clang__}));
1583         }
1584
1585 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1586     disable('static', 'pic', 'threads');
1587 }
1588
1589 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1590                               ? @strict_warnings_collection
1591                               : ( $_ ) }
1592                     @{$config{CFLAGS}} ];
1593
1594 unless ($disabled{"crypto-mdebug-backtrace"})
1595         {
1596         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1597                 {
1598                 push @{$config{cflags}}, $wopt
1599                         unless grep { $_ eq $wopt } @{$config{cflags}};
1600                 }
1601         if ($target =~ /^BSD-/)
1602                 {
1603                 push @{$config{ex_libs}}, "-lexecinfo";
1604                 }
1605         }
1606
1607 unless ($disabled{afalgeng}) {
1608     $config{afalgeng}="";
1609     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1610         my $minver = 4*10000 + 1*100 + 0;
1611         if ($config{CROSS_COMPILE} eq "") {
1612             my $verstr = `uname -r`;
1613             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1614             ($mi2) = $mi2 =~ /(\d+)/;
1615             my $ver = $ma*10000 + $mi1*100 + $mi2;
1616             if ($ver < $minver) {
1617                 disable('too-old-kernel', 'afalgeng');
1618             } else {
1619                 push @{$config{engdirs}}, "afalg";
1620             }
1621         } else {
1622             disable('cross-compiling', 'afalgeng');
1623         }
1624     } else {
1625         disable('not-linux', 'afalgeng');
1626     }
1627 }
1628
1629 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1630
1631 unless ($disabled{ktls}) {
1632     $config{ktls}="";
1633     if ($target =~ m/^linux/) {
1634         my $usr = "/usr/$config{cross_compile_prefix}";
1635         chop($usr);
1636         if ($config{cross_compile_prefix} eq "") {
1637             $usr = "/usr";
1638         }
1639         my $minver = (4 << 16) + (13 << 8) + 0;
1640         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1641
1642         if ($verstr[2] < $minver) {
1643             disable('too-old-kernel', 'ktls');
1644         }
1645     } else {
1646         disable('not-linux', 'ktls');
1647     }
1648 }
1649
1650 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1651
1652 # Get the extra flags used when building shared libraries and modules.  We
1653 # do this late because some of them depend on %disabled.
1654
1655 # Make the flags to build DSOs the same as for shared libraries unless they
1656 # are already defined
1657 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1658 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1659 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1660 {
1661     my $shared_info_pl =
1662         catfile(dirname($0), "Configurations", "shared-info.pl");
1663     my %shared_info = read_eval_file($shared_info_pl);
1664     push @{$target{_conf_fname_int}}, $shared_info_pl;
1665     my $si = $target{shared_target};
1666     while (ref $si ne "HASH") {
1667         last if ! defined $si;
1668         if (ref $si eq "CODE") {
1669             $si = $si->();
1670         } else {
1671             $si = $shared_info{$si};
1672         }
1673     }
1674
1675     # Some of the 'shared_target' values don't have any entries in
1676     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1677     # template knows how to handle this.  That is currently the case for
1678     # Windows and VMS.
1679     if (defined $si) {
1680         # Just as above, copy certain shared_* attributes to the corresponding
1681         # module_ attribute unless the latter is already defined
1682         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1683         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1684         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1685         foreach (sort keys %$si) {
1686             $target{$_} = defined $target{$_}
1687                 ? add($si->{$_})->($target{$_})
1688                 : $si->{$_};
1689         }
1690     }
1691 }
1692
1693 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1694
1695 # If we use the unified build, collect information from build.info files
1696 my %unified_info = ();
1697
1698 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1699 if ($builder eq "unified") {
1700     use with_fallback qw(Text::Template);
1701
1702     sub cleandir {
1703         my $base = shift;
1704         my $dir = shift;
1705         my $relativeto = shift || ".";
1706
1707         $dir = catdir($base,$dir) unless isabsolute($dir);
1708
1709         # Make sure the directories we're building in exists
1710         mkpath($dir);
1711
1712         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1713         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1714         return $res;
1715     }
1716
1717     sub cleanfile {
1718         my $base = shift;
1719         my $file = shift;
1720         my $relativeto = shift || ".";
1721
1722         $file = catfile($base,$file) unless isabsolute($file);
1723
1724         my $d = dirname($file);
1725         my $f = basename($file);
1726
1727         # Make sure the directories we're building in exists
1728         mkpath($d);
1729
1730         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1731         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1732         return $res;
1733     }
1734
1735     # Store the name of the template file we will build the build file from
1736     # in %config.  This may be useful for the build file itself.
1737     my @build_file_template_names =
1738         ( $builder_platform."-".$target{build_file}.".tmpl",
1739           $target{build_file}.".tmpl" );
1740     my @build_file_templates = ();
1741
1742     # First, look in the user provided directory, if given
1743     if (defined env($local_config_envname)) {
1744         @build_file_templates =
1745             map {
1746                 if ($^O eq 'VMS') {
1747                     # VMS environment variables are logical names,
1748                     # which can be used as is
1749                     $local_config_envname . ':' . $_;
1750                 } else {
1751                     catfile(env($local_config_envname), $_);
1752                 }
1753             }
1754             @build_file_template_names;
1755     }
1756     # Then, look in our standard directory
1757     push @build_file_templates,
1758         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1759           @build_file_template_names );
1760
1761     my $build_file_template;
1762     for $_ (@build_file_templates) {
1763         $build_file_template = $_;
1764         last if -f $build_file_template;
1765
1766         $build_file_template = undef;
1767     }
1768     if (!defined $build_file_template) {
1769         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1770     }
1771     $config{build_file_templates}
1772       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1773                     $blddir),
1774           $build_file_template,
1775           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1776                     $blddir) ];
1777
1778     my @build_dirs = ( [ ] );   # current directory
1779
1780     $config{build_infos} = [ ];
1781
1782     my %ordinals = ();
1783     while (@build_dirs) {
1784         my @curd = @{shift @build_dirs};
1785         my $sourced = catdir($srcdir, @curd);
1786         my $buildd = catdir($blddir, @curd);
1787
1788         my $unixdir = join('/', @curd);
1789         if (exists $skipdir{$unixdir}) {
1790             my $what = $skipdir{$unixdir};
1791             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1792             next;
1793         }
1794
1795         mkpath($buildd);
1796
1797         my $f = 'build.info';
1798         # The basic things we're trying to build
1799         my @programs = ();
1800         my @libraries = ();
1801         my @modules = ();
1802         my @scripts = ();
1803
1804         my %attributes = ();
1805         my %sources = ();
1806         my %shared_sources = ();
1807         my %includes = ();
1808         my %defines = ();
1809         my %depends = ();
1810         my %generate = ();
1811
1812         # We want to detect configdata.pm in the source tree, so we
1813         # don't use it if the build tree is different.
1814         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1815
1816         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1817         my $template =
1818             Text::Template->new(TYPE => 'FILE',
1819                                 SOURCE => catfile($sourced, $f),
1820                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1821         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1822         my @text =
1823             split /^/m,
1824             $template->fill_in(HASH => { config => \%config,
1825                                          target => \%target,
1826                                          disabled => \%disabled,
1827                                          withargs => \%withargs,
1828                                          builddir => abs2rel($buildd, $blddir),
1829                                          sourcedir => abs2rel($sourced, $blddir),
1830                                          buildtop => abs2rel($blddir, $blddir),
1831                                          sourcetop => abs2rel($srcdir, $blddir) },
1832                                DELIMITERS => [ "{-", "-}" ]);
1833
1834         # The top item of this stack has the following values
1835         # -2 positive already run and we found ELSE (following ELSIF should fail)
1836         # -1 positive already run (skip until ENDIF)
1837         # 0 negatives so far (if we're at a condition, check it)
1838         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1839         # 2 positive ELSE (following ELSIF should fail)
1840         my @skip = ();
1841         collect_information(
1842             collect_from_array([ @text ],
1843                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1844                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1845             # Info we're looking for
1846             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1847             => sub {
1848                 if (! @skip || $skip[$#skip] > 0) {
1849                     push @skip, !! $1;
1850                 } else {
1851                     push @skip, -1;
1852                 }
1853             },
1854             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1855             => sub { die "ELSIF out of scope" if ! @skip;
1856                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1857                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1858                      $skip[$#skip] = !! $1
1859                          if $skip[$#skip] == 0; },
1860             qr/^\s*ELSE\s*$/
1861             => sub { die "ELSE out of scope" if ! @skip;
1862                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1863                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1864             qr/^\s*ENDIF\s*$/
1865             => sub { die "ENDIF out of scope" if ! @skip;
1866                      pop @skip; },
1867             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1868             => sub {
1869                 if (!@skip || $skip[$#skip] > 0) {
1870                     foreach (tokenize($1)) {
1871                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1872                     }
1873                 }
1874             },
1875             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1876             => sub {
1877                 if (!@skip || $skip[$#skip] > 0) {
1878                     my @a = tokenize($1, qr|\s*,\s*|);
1879                     my @p = tokenize($2);
1880                     push @programs, @p;
1881                     foreach my $a (@a) {
1882                         my $ak = $a;
1883                         my $av = 1;
1884                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1885                             $ak = $1;
1886                             $av = $2;
1887                         }
1888                         foreach my $p (@p) {
1889                             $attributes{$p}->{$ak} = $av;
1890                         }
1891                     }
1892                 }
1893             },
1894             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1895             => sub {
1896                 if (!@skip || $skip[$#skip] > 0) {
1897                     my @a = tokenize($1, qr|\s*,\s*|);
1898                     my @l = tokenize($2);
1899                     push @libraries, @l;
1900                     foreach my $a (@a) {
1901                         my $ak = $a;
1902                         my $av = 1;
1903                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1904                             $ak = $1;
1905                             $av = $2;
1906                         }
1907                         foreach my $l (@l) {
1908                             $attributes{$l}->{$ak} = $av;
1909                         }
1910                     }
1911                 }
1912             },
1913             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1914             => sub {
1915                 if (!@skip || $skip[$#skip] > 0) {
1916                     my @a = tokenize($1, qr|\s*,\s*|);
1917                     my @m = tokenize($2);
1918                     push @modules, @m;
1919                     foreach my $a (@a) {
1920                         my $ak = $a;
1921                         my $av = 1;
1922                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1923                             $ak = $1;
1924                             $av = $2;
1925                         }
1926                         foreach my $m (@m) {
1927                             $attributes{$m}->{$ak} = $av;
1928                         }
1929                     }
1930                 }
1931             },
1932             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1933             => sub {
1934                 if (!@skip || $skip[$#skip] > 0) {
1935                     my @a = tokenize($1, qr|\s*,\s*|);
1936                     my @s = tokenize($2);
1937                     push @scripts, @s;
1938                     foreach my $a (@a) {
1939                         my $ak = $a;
1940                         my $av = 1;
1941                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1942                             $ak = $1;
1943                             $av = $2;
1944                         }
1945                         foreach my $s (@s) {
1946                             $attributes{$s}->{$ak} = $av;
1947                         }
1948                     }
1949                 }
1950             },
1951
1952             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1953             => sub { push @{$ordinals{$1}}, tokenize($2)
1954                          if !@skip || $skip[$#skip] > 0 },
1955             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1956             => sub { push @{$sources{$1}}, tokenize($2)
1957                          if !@skip || $skip[$#skip] > 0 },
1958             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1959             => sub { push @{$shared_sources{$1}}, tokenize($2)
1960                          if !@skip || $skip[$#skip] > 0 },
1961             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1962             => sub { push @{$includes{$1}}, tokenize($2)
1963                          if !@skip || $skip[$#skip] > 0 },
1964             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1965             => sub { push @{$defines{$1}}, tokenize($2)
1966                          if !@skip || $skip[$#skip] > 0 },
1967             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1968             => sub { push @{$depends{$1}}, tokenize($2)
1969                          if !@skip || $skip[$#skip] > 0 },
1970             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1971             => sub { push @{$generate{$1}}, $2
1972                          if !@skip || $skip[$#skip] > 0 },
1973             qr/^\s*(?:#.*)?$/ => sub { },
1974             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1975             "BEFORE" => sub {
1976                 if ($buildinfo_debug) {
1977                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1978                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1979                 }
1980             },
1981             "AFTER" => sub {
1982                 if ($buildinfo_debug) {
1983                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1984                 }
1985             },
1986             );
1987         die "runaway IF?" if (@skip);
1988
1989         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1990                 and !$config{dynamic_engines}) {
1991             die <<"EOF"
1992 ENGINES can only be used if configured with 'dynamic-engine'.
1993 This is usually a fault in a build.info file.
1994 EOF
1995         }
1996
1997         foreach (keys %attributes) {
1998             my $dest = $_;
1999             my $ddest = cleanfile($buildd, $_, $blddir);
2000             foreach (keys %{$attributes{$dest} // {}}) {
2001                 $unified_info{attributes}->{$ddest}->{$_} =
2002                     $attributes{$dest}->{$_};
2003             }
2004         }
2005
2006         {
2007             my %infos = ( programs  => [ @programs  ],
2008                           libraries => [ @libraries ],
2009                           modules   => [ @modules   ],
2010                           scripts   => [ @scripts   ] );
2011             foreach my $k (keys %infos) {
2012                 foreach (@{$infos{$k}}) {
2013                     my $item = cleanfile($buildd, $_, $blddir);
2014                     $unified_info{$k}->{$item} = 1;
2015                 }
2016             }
2017         }
2018
2019         # Check that we haven't defined any library as both shared and
2020         # explicitly static.  That is forbidden.
2021         my @doubles = ();
2022         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2023             (my $l = $_) =~ s/\.a$//;
2024             push @doubles, $l if defined $unified_info{libraries}->{$l};
2025         }
2026         die "these libraries are both explicitly static and shared:\n  ",
2027             join(" ", @doubles), "\n"
2028             if @doubles;
2029
2030         foreach (keys %sources) {
2031             my $dest = $_;
2032             my $ddest = cleanfile($buildd, $_, $blddir);
2033             foreach (@{$sources{$dest}}) {
2034                 my $s = cleanfile($sourced, $_, $blddir);
2035
2036                 # If it isn't in the source tree, we assume it's generated
2037                 # in the build tree
2038                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2039                     $s = cleanfile($buildd, $_, $blddir);
2040                 }
2041                 # We recognise C++, C and asm files
2042                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2043                     my $o = $_;
2044                     $o =~ s/\.[csS]$/.o/; # C and assembler
2045                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2046                     $o = cleanfile($buildd, $o, $blddir);
2047                     $unified_info{sources}->{$ddest}->{$o} = -1;
2048                     $unified_info{sources}->{$o}->{$s} = -1;
2049                 } elsif ($s =~ /\.rc$/) {
2050                     # We also recognise resource files
2051                     my $o = $_;
2052                     $o =~ s/\.rc$/.res/; # Resource configuration
2053                     my $o = cleanfile($buildd, $o, $blddir);
2054                     $unified_info{sources}->{$ddest}->{$o} = -1;
2055                     $unified_info{sources}->{$o}->{$s} = -1;
2056                 } else {
2057                     $unified_info{sources}->{$ddest}->{$s} = 1;
2058                 }
2059             }
2060         }
2061
2062         foreach (keys %shared_sources) {
2063             my $dest = $_;
2064             my $ddest = cleanfile($buildd, $_, $blddir);
2065             foreach (@{$shared_sources{$dest}}) {
2066                 my $s = cleanfile($sourced, $_, $blddir);
2067
2068                 # If it isn't in the source tree, we assume it's generated
2069                 # in the build tree
2070                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2071                     $s = cleanfile($buildd, $_, $blddir);
2072                 }
2073
2074                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2075                     # We recognise C++, C and asm files
2076                     my $o = $_;
2077                     $o =~ s/\.[csS]$/.o/; # C and assembler
2078                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2079                     $o = cleanfile($buildd, $o, $blddir);
2080                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2081                     $unified_info{sources}->{$o}->{$s} = -1;
2082                 } elsif ($s =~ /\.rc$/) {
2083                     # We also recognise resource files
2084                     my $o = $_;
2085                     $o =~ s/\.rc$/.res/; # Resource configuration
2086                     my $o = cleanfile($buildd, $o, $blddir);
2087                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2088                     $unified_info{sources}->{$o}->{$s} = -1;
2089                 } elsif ($s =~ /\.ld$/) {
2090                     # We also recognise linker scripts (or corresponding)
2091                     # We know they are generated files
2092                     my $ld = cleanfile($buildd, $_, $blddir);
2093                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2094                 } else {
2095                     die "unrecognised source file type for shared library: $s\n";
2096                 }
2097             }
2098         }
2099
2100         foreach (keys %generate) {
2101             my $dest = $_;
2102             my $ddest = cleanfile($buildd, $_, $blddir);
2103             die "more than one generator for $dest: "
2104                     ,join(" ", @{$generate{$_}}),"\n"
2105                     if scalar @{$generate{$_}} > 1;
2106             my @generator = split /\s+/, $generate{$dest}->[0];
2107             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2108             $unified_info{generate}->{$ddest} = [ @generator ];
2109         }
2110
2111         foreach (keys %depends) {
2112             my $dest = $_;
2113             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2114
2115             # If the destination doesn't exist in source, it can only be
2116             # a generated file in the build tree.
2117             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2118                 $ddest = cleanfile($buildd, $_, $blddir);
2119             }
2120             foreach (@{$depends{$dest}}) {
2121                 my $d = cleanfile($sourced, $_, $blddir);
2122
2123                 # If we know it's generated, or assume it is because we can't
2124                 # find it in the source tree, we set file we depend on to be
2125                 # in the build tree rather than the source tree, and assume
2126                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2127                 # section or in the Makefile template.
2128                 if ($d eq $src_configdata
2129                     || ! -f $d
2130                     || (grep { $d eq $_ }
2131                         map { cleanfile($srcdir, $_, $blddir) }
2132                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2133                     $d = cleanfile($buildd, $_, $blddir);
2134                 }
2135                 # Take note if the file to depend on is being renamed
2136                 # Take extra care with files ending with .a, they should
2137                 # be treated without that extension, and the extension
2138                 # should be added back after treatment.
2139                 $d =~ /(\.a)?$/;
2140                 my $e = $1 // "";
2141                 $d = $`.$e;
2142                 $unified_info{depends}->{$ddest}->{$d} = 1;
2143             }
2144         }
2145
2146         foreach (keys %includes) {
2147             my $dest = $_;
2148             my $ddest = cleanfile($sourced, $_, $blddir);
2149
2150             # If the destination doesn't exist in source, it can only be
2151             # a generated file in the build tree.
2152             if ($ddest eq $src_configdata || ! -f $ddest) {
2153                 $ddest = cleanfile($buildd, $_, $blddir);
2154             }
2155             foreach (@{$includes{$dest}}) {
2156                 my $is = cleandir($sourced, $_, $blddir);
2157                 my $ib = cleandir($buildd, $_, $blddir);
2158                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2159                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2160                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2161                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2162             }
2163         }
2164
2165         foreach (keys %defines) {
2166             my $dest = $_;
2167             my $ddest = cleanfile($sourced, $_, $blddir);
2168
2169             # If the destination doesn't exist in source, it can only be
2170             # a generated file in the build tree.
2171             if (! -f $ddest) {
2172                 $ddest = cleanfile($buildd, $_, $blddir);
2173                 if ($unified_info{rename}->{$ddest}) {
2174                     $ddest = $unified_info{rename}->{$ddest};
2175                 }
2176             }
2177             foreach (@{$defines{$dest}}) {
2178                 m|^([^=]*)(=.*)?$|;
2179                 die "0 length macro name not permitted\n" if $1 eq "";
2180                 die "$1 defined more than once\n"
2181                     if defined $unified_info{defines}->{$ddest}->{$1};
2182                 $unified_info{defines}->{$ddest}->{$1} = $2;
2183             }
2184         }
2185     }
2186
2187     my $ordinals_text = join(', ', sort keys %ordinals);
2188     warn <<"EOF" if $ordinals_text;
2189
2190 WARNING: ORDINALS were specified for $ordinals_text
2191 They are ignored and should be replaced with a combination of GENERATE,
2192 DEPEND and SHARED_SOURCE.
2193 EOF
2194
2195     # Massage the result
2196
2197     # If we depend on a header file or a perl module, add an inclusion of
2198     # its directory to allow smoothe inclusion
2199     foreach my $dest (keys %{$unified_info{depends}}) {
2200         next if $dest eq "";
2201         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2202             next unless $d =~ /\.(h|pm)$/;
2203             my $i = dirname($d);
2204             my $spot =
2205                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2206                 ? 'build' : 'source';
2207             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2208                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2209         }
2210     }
2211
2212     # Go through all intermediary files and change their names to something that
2213     # reflects what they will be built for.  Note that for some source files,
2214     # this leads to duplicate object files because they are used multiple times.
2215     # the goal is to rename all object files according to this scheme:
2216     #    {productname}-{midfix}-{origobjname}.[o|res]
2217     # the {midfix} is a keyword indicating the type of product, which is mostly
2218     # valuable for libraries since they come in two forms.
2219     #
2220     # This also reorganises the {sources} and {shared_sources} so that the
2221     # former only contains ALL object files that are supposed to end up in
2222     # static libraries and programs, while the latter contains ALL object files
2223     # that are supposed to end up in shared libraries and DSOs.
2224     # The main reason for having two different source structures is to allow
2225     # the same name to be used for the static and the shared variants of a
2226     # library.
2227     {
2228         # Take copies so we don't get interference from added stuff
2229         my %unified_copy = ();
2230         foreach (('sources', 'shared_sources')) {
2231             $unified_copy{$_} = { %{$unified_info{$_}} }
2232                 if defined($unified_info{$_});
2233             delete $unified_info{$_};
2234         }
2235         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2236             # $intent serves multi purposes:
2237             # - give a prefix for the new object files names
2238             # - in the case of libraries, rearrange the object files so static
2239             #   libraries use the 'sources' structure exclusively, while shared
2240             #   libraries use the 'shared_sources' structure exclusively.
2241             my $intent = {
2242                 programs  => { bin    => { src => [ 'sources' ],
2243                                            dst => 'sources' } },
2244                 libraries => { lib    => { src => [ 'sources' ],
2245                                            dst => 'sources' },
2246                                shlib  => { prodselect =>
2247                                                sub { grep !/\.a$/, @_ },
2248                                            src => [ 'sources',
2249                                                     'shared_sources' ],
2250                                            dst => 'shared_sources' } },
2251                 modules   => { dso    => { src => [ 'sources' ],
2252                                            dst => 'sources' } },
2253                 scripts   => { script => { src => [ 'sources' ],
2254                                            dst => 'sources' } }
2255                } -> {$prodtype};
2256             foreach my $kind (keys %$intent) {
2257                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2258                              && $disabled{shared});
2259
2260                 my @src = @{$intent->{$kind}->{src}};
2261                 my $dst = $intent->{$kind}->{dst};
2262                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2263                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2264                     # %prod_sources has all applicable objects as keys, and
2265                     # their corresponding sources as values
2266                     my %prod_sources =
2267                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2268                         map { keys %{$unified_copy{$_}->{$prod}} }
2269                         @src;
2270                     foreach (keys %prod_sources) {
2271                         # Only affect object files and resource files,
2272                         # the others simply get a new value
2273                         # (+1 instead of -1)
2274                         if ($_ =~ /\.(o|res)$/) {
2275                             (my $prodname = $prod) =~ s|\.a$||;
2276                             my $newobj =
2277                                 catfile(dirname($_),
2278                                         basename($prodname)
2279                                             . '-' . $kind
2280                                             . '-' . basename($_));
2281                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2282                             foreach my $src (@{$prod_sources{$_}}) {
2283                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2284                             }
2285                             # Adjust dependencies
2286                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2287                                 $unified_info{depends}->{$_}->{$deps} = -1;
2288                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2289                             }
2290                             # Adjust includes
2291                             foreach my $k (('source', 'build')) {
2292                                 next unless
2293                                     defined($unified_info{includes}->{$_}->{$k});
2294                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2295                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2296                             }
2297                         } else {
2298                             $unified_info{$dst}->{$prod}->{$_} = 1;
2299                         }
2300                     }
2301                 }
2302             }
2303         }
2304     }
2305     # At this point, we have a number of sources with the value -1.  They
2306     # aren't part of the local build and are probably meant for a different
2307     # platform, and can therefore be cleaned away.  That happens when making
2308     # %unified_info more efficient below.
2309
2310     ### Make unified_info a bit more efficient
2311     # One level structures
2312     foreach (("programs", "libraries", "modules", "scripts")) {
2313         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2314     }
2315     # Two level structures
2316     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2317         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2318             my @items =
2319                 sort
2320                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2321                 keys %{$unified_info{$l1}->{$l2}};
2322             if (@items) {
2323                 $unified_info{$l1}->{$l2} = [ @items ];
2324             } else {
2325                 delete $unified_info{$l1}->{$l2};
2326             }
2327         }
2328     }
2329     # Defines
2330     foreach my $dest (sort keys %{$unified_info{defines}}) {
2331         $unified_info{defines}->{$dest}
2332             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2333                 sort keys %{$unified_info{defines}->{$dest}} ];
2334     }
2335     # Includes
2336     foreach my $dest (sort keys %{$unified_info{includes}}) {
2337         if (defined($unified_info{includes}->{$dest}->{build})) {
2338             my @source_includes = ();
2339             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2340                 if defined($unified_info{includes}->{$dest}->{source});
2341             $unified_info{includes}->{$dest} =
2342                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2343             foreach my $inc (@source_includes) {
2344                 push @{$unified_info{includes}->{$dest}}, $inc
2345                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2346             }
2347         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2348             $unified_info{includes}->{$dest} =
2349                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2350         } else {
2351             delete $unified_info{includes}->{$dest};
2352         }
2353     }
2354
2355     # For convenience collect information regarding directories where
2356     # files are generated, those generated files and the end product
2357     # they end up in where applicable.  Then, add build rules for those
2358     # directories
2359     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2360                      "dso" => [ @{$unified_info{modules}} ],
2361                      "bin" => [ @{$unified_info{programs}} ],
2362                      "script" => [ @{$unified_info{scripts}} ] );
2363     foreach my $type (keys %loopinfo) {
2364         foreach my $product (@{$loopinfo{$type}}) {
2365             my %dirs = ();
2366             my $pd = dirname($product);
2367
2368             foreach (@{$unified_info{sources}->{$product} // []},
2369                      @{$unified_info{shared_sources}->{$product} // []}) {
2370                 my $d = dirname($_);
2371
2372                 # We don't want to create targets for source directories
2373                 # when building out of source
2374                 next if ($config{sourcedir} ne $config{builddir}
2375                              && $d =~ m|^\Q$config{sourcedir}\E|);
2376                 # We already have a "test" target, and the current directory
2377                 # is just silly to make a target for
2378                 next if $d eq "test" || $d eq ".";
2379
2380                 $dirs{$d} = 1;
2381                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2382                     if $d ne $pd;
2383             }
2384             foreach (keys %dirs) {
2385                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2386                     $product;
2387             }
2388         }
2389     }
2390 }
2391
2392 # For the schemes that need it, we provide the old *_obj configs
2393 # from the *_asm_obj ones
2394 foreach (grep /_(asm|aux)_src$/, keys %target) {
2395     my $src = $_;
2396     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2397     $target{$obj} = $target{$src};
2398     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2399     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2400 }
2401
2402 # Write down our configuration where it fits #########################
2403
2404 print "Creating configdata.pm\n";
2405 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2406 print OUT <<"EOF";
2407 #! $config{HASHBANGPERL}
2408
2409 package configdata;
2410
2411 use strict;
2412 use warnings;
2413
2414 use Exporter;
2415 #use vars qw(\@ISA \@EXPORT);
2416 our \@ISA = qw(Exporter);
2417 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2418
2419 EOF
2420 print OUT "our %config = (\n";
2421 foreach (sort keys %config) {
2422     if (ref($config{$_}) eq "ARRAY") {
2423         print OUT "  ", $_, " => [ ", join(", ",
2424                                            map { quotify("perl", $_) }
2425                                            @{$config{$_}}), " ],\n";
2426     } elsif (ref($config{$_}) eq "HASH") {
2427         print OUT "  ", $_, " => {";
2428         if (scalar keys %{$config{$_}} > 0) {
2429             print OUT "\n";
2430             foreach my $key (sort keys %{$config{$_}}) {
2431                 print OUT "      ",
2432                     join(" => ",
2433                          quotify("perl", $key),
2434                          defined $config{$_}->{$key}
2435                              ? quotify("perl", $config{$_}->{$key})
2436                              : "undef");
2437                 print OUT ",\n";
2438             }
2439             print OUT "  ";
2440         }
2441         print OUT "},\n";
2442     } else {
2443         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2444     }
2445 }
2446 print OUT <<"EOF";
2447 );
2448
2449 EOF
2450 print OUT "our %target = (\n";
2451 foreach (sort keys %target) {
2452     if (ref($target{$_}) eq "ARRAY") {
2453         print OUT "  ", $_, " => [ ", join(", ",
2454                                            map { quotify("perl", $_) }
2455                                            @{$target{$_}}), " ],\n";
2456     } else {
2457         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2458     }
2459 }
2460 print OUT <<"EOF";
2461 );
2462
2463 EOF
2464 print OUT "our \%available_protocols = (\n";
2465 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2466 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2467 print OUT <<"EOF";
2468 );
2469
2470 EOF
2471 print OUT "our \@disablables = (\n";
2472 foreach (@disablables) {
2473     print OUT "  ", quotify("perl", $_), ",\n";
2474 }
2475 print OUT <<"EOF";
2476 );
2477
2478 EOF
2479 print OUT "# The following come from Configure's @disablables_int\n";
2480 print OUT "our \@disablables_int = (\n";
2481 foreach (@disablables_int) {
2482     print OUT "  ", quotify("perl", $_), ",\n";
2483 }
2484 print OUT <<"EOF";
2485 );
2486
2487 EOF
2488 print OUT "our \%disabled = (\n";
2489 foreach (sort keys %disabled) {
2490     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2491 }
2492 print OUT <<"EOF";
2493 );
2494
2495 EOF
2496 print OUT "our %withargs = (\n";
2497 foreach (sort keys %withargs) {
2498     if (ref($withargs{$_}) eq "ARRAY") {
2499         print OUT "  ", $_, " => [ ", join(", ",
2500                                            map { quotify("perl", $_) }
2501                                            @{$withargs{$_}}), " ],\n";
2502     } else {
2503         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2504     }
2505 }
2506 print OUT <<"EOF";
2507 );
2508
2509 EOF
2510 if ($builder eq "unified") {
2511     my $recurse;
2512     $recurse = sub {
2513         my $indent = shift;
2514         foreach (@_) {
2515             if (ref $_ eq "ARRAY") {
2516                 print OUT " "x$indent, "[\n";
2517                 foreach (@$_) {
2518                     $recurse->($indent + 4, $_);
2519                 }
2520                 print OUT " "x$indent, "],\n";
2521             } elsif (ref $_ eq "HASH") {
2522                 my %h = %$_;
2523                 print OUT " "x$indent, "{\n";
2524                 foreach (sort keys %h) {
2525                     if (ref $h{$_} eq "") {
2526                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2527                     } else {
2528                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2529                         $recurse->($indent + 8, $h{$_});
2530                     }
2531                 }
2532                 print OUT " "x$indent, "},\n";
2533             } else {
2534                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2535             }
2536         }
2537     };
2538     print OUT "our %unified_info = (\n";
2539     foreach (sort keys %unified_info) {
2540         if (ref $unified_info{$_} eq "") {
2541             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2542         } else {
2543             print OUT " "x4, quotify("perl", $_), " =>\n";
2544             $recurse->(8, $unified_info{$_});
2545         }
2546     }
2547     print OUT <<"EOF";
2548 );
2549
2550 EOF
2551 }
2552 print OUT
2553     "# The following data is only used when this files is use as a script\n";
2554 print OUT "my \@makevars = (\n";
2555 foreach (sort keys %user) {
2556     print OUT "    '",$_,"',\n";
2557 }
2558 print OUT ");\n";
2559 print OUT "my \%disabled_info = (\n";
2560 foreach my $what (sort keys %disabled_info) {
2561     print OUT "    '$what' => {\n";
2562     foreach my $info (sort keys %{$disabled_info{$what}}) {
2563         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2564             print OUT "        $info => [ ",
2565                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2566                 " ],\n";
2567         } else {
2568             print OUT "        $info => '", $disabled_info{$what}->{$info},
2569                 "',\n";
2570         }
2571     }
2572     print OUT "    },\n";
2573 }
2574 print OUT ");\n";
2575 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2576 print OUT << 'EOF';
2577 # If run directly, we can give some answers, and even reconfigure
2578 unless (caller) {
2579     use Getopt::Long;
2580     use File::Spec::Functions;
2581     use File::Basename;
2582     use Pod::Usage;
2583
2584     my $here = dirname($0);
2585
2586     my $dump = undef;
2587     my $cmdline = undef;
2588     my $options = undef;
2589     my $target = undef;
2590     my $envvars = undef;
2591     my $makevars = undef;
2592     my $buildparams = undef;
2593     my $reconf = undef;
2594     my $verbose = undef;
2595     my $help = undef;
2596     my $man = undef;
2597     GetOptions('dump|d'                 => \$dump,
2598                'command-line|c'         => \$cmdline,
2599                'options|o'              => \$options,
2600                'target|t'               => \$target,
2601                'environment|e'          => \$envvars,
2602                'make-variables|m'       => \$makevars,
2603                'build-parameters|b'     => \$buildparams,
2604                'reconfigure|reconf|r'   => \$reconf,
2605                'verbose|v'              => \$verbose,
2606                'help'                   => \$help,
2607                'man'                    => \$man)
2608         or die "Errors in command line arguments\n";
2609
2610     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2611             || $buildparams || $reconf || $verbose || $help || $man) {
2612         print STDERR <<"_____";
2613 You must give at least one option.
2614 For more information, do '$0 --help'
2615 _____
2616         exit(2);
2617     }
2618
2619     if ($help) {
2620         pod2usage(-exitval => 0,
2621                   -verbose => 1);
2622     }
2623     if ($man) {
2624         pod2usage(-exitval => 0,
2625                   -verbose => 2);
2626     }
2627     if ($dump || $cmdline) {
2628         print "\nCommand line (with current working directory = $here):\n\n";
2629         print '    ',join(' ',
2630                           $config{PERL},
2631                           catfile($config{sourcedir}, 'Configure'),
2632                           @{$config{perlargv}}), "\n";
2633         print "\nPerl information:\n\n";
2634         print '    ',$config{perl_cmd},"\n";
2635         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2636     }
2637     if ($dump || $options) {
2638         my $longest = 0;
2639         my $longest2 = 0;
2640         foreach my $what (@disablables) {
2641             $longest = length($what) if $longest < length($what);
2642             $longest2 = length($disabled{$what})
2643                 if $disabled{$what} && $longest2 < length($disabled{$what});
2644         }
2645         print "\nEnabled features:\n\n";
2646         foreach my $what (@disablables) {
2647             print "    $what\n" unless $disabled{$what};
2648         }
2649         print "\nDisabled features:\n\n";
2650         foreach my $what (@disablables) {
2651             if ($disabled{$what}) {
2652                 print "    $what", ' ' x ($longest - length($what) + 1),
2653                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2654                 print $disabled_info{$what}->{macro}
2655                     if $disabled_info{$what}->{macro};
2656                 print ' (skip ',
2657                     join(', ', @{$disabled_info{$what}->{skipped}}),
2658                     ')'
2659                     if $disabled_info{$what}->{skipped};
2660                 print "\n";
2661             }
2662         }
2663     }
2664     if ($dump || $target) {
2665         print "\nConfig target attributes:\n\n";
2666         foreach (sort keys %target) {
2667             next if $_ =~ m|^_| || $_ eq 'template';
2668             my $quotify = sub {
2669                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2670             };
2671             print '    ', $_, ' => ';
2672             if (ref($target{$_}) eq "ARRAY") {
2673                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2674             } else {
2675                 print $quotify->($target{$_}), ",\n"
2676             }
2677         }
2678     }
2679     if ($dump || $envvars) {
2680         print "\nRecorded environment:\n\n";
2681         foreach (sort keys %{$config{perlenv}}) {
2682             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2683         }
2684     }
2685     if ($dump || $makevars) {
2686         print "\nMakevars:\n\n";
2687         foreach my $var (@makevars) {
2688             my $prefix = '';
2689             $prefix = $config{CROSS_COMPILE}
2690                 if grep { $var eq $_ } @user_crossable;
2691             $prefix //= '';
2692             print '    ',$var,' ' x (16 - length $var),'= ',
2693                 (ref $config{$var} eq 'ARRAY'
2694                  ? join(' ', @{$config{$var}})
2695                  : $prefix.$config{$var}),
2696                 "\n"
2697                 if defined $config{$var};
2698         }
2699
2700         my @buildfile = ($config{builddir}, $config{build_file});
2701         unshift @buildfile, $here
2702             unless file_name_is_absolute($config{builddir});
2703         my $buildfile = canonpath(catdir(@buildfile));
2704         print <<"_____";
2705
2706 NOTE: These variables only represent the configuration view.  The build file
2707 template may have processed these variables further, please have a look at the
2708 build file for more exact data:
2709     $buildfile
2710 _____
2711     }
2712     if ($dump || $buildparams) {
2713         my @buildfile = ($config{builddir}, $config{build_file});
2714         unshift @buildfile, $here
2715             unless file_name_is_absolute($config{builddir});
2716         print "\nbuild file:\n\n";
2717         print "    ", canonpath(catfile(@buildfile)),"\n";
2718
2719         print "\nbuild file templates:\n\n";
2720         foreach (@{$config{build_file_templates}}) {
2721             my @tmpl = ($_);
2722             unshift @tmpl, $here
2723                 unless file_name_is_absolute($config{sourcedir});
2724             print '    ',canonpath(catfile(@tmpl)),"\n";
2725         }
2726     }
2727     if ($reconf) {
2728         if ($verbose) {
2729             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2730             foreach (sort keys %{$config{perlenv}}) {
2731                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2732             }
2733         }
2734
2735         chdir $here;
2736         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2737     }
2738 }
2739
2740 1;
2741
2742 __END__
2743
2744 =head1 NAME
2745
2746 configdata.pm - configuration data for OpenSSL builds
2747
2748 =head1 SYNOPSIS
2749
2750 Interactive:
2751
2752   perl configdata.pm [options]
2753
2754 As data bank module:
2755
2756   use configdata;
2757
2758 =head1 DESCRIPTION
2759
2760 This module can be used in two modes, interactively and as a module containing
2761 all the data recorded by OpenSSL's Configure script.
2762
2763 When used interactively, simply run it as any perl script, with at least one
2764 option, and you will get the information you ask for.  See L</OPTIONS> below.
2765
2766 When loaded as a module, you get a few databanks with useful information to
2767 perform build related tasks.  The databanks are:
2768
2769     %config             Configured things.
2770     %target             The OpenSSL config target with all inheritances
2771                         resolved.
2772     %disabled           The features that are disabled.
2773     @disablables        The list of features that can be disabled.
2774     %withargs           All data given through --with-THING options.
2775     %unified_info       All information that was computed from the build.info
2776                         files.
2777
2778 =head1 OPTIONS
2779
2780 =over 4
2781
2782 =item B<--help>
2783
2784 Print a brief help message and exit.
2785
2786 =item B<--man>
2787
2788 Print the manual page and exit.
2789
2790 =item B<--dump> | B<-d>
2791
2792 Print all relevant configuration data.  This is equivalent to B<--command-line>
2793 B<--options> B<--target> B<--environment> B<--make-variables>
2794 B<--build-parameters>.
2795
2796 =item B<--command-line> | B<-c>
2797
2798 Print the current configuration command line.
2799
2800 =item B<--options> | B<-o>
2801
2802 Print the features, both enabled and disabled, and display defined macro and
2803 skipped directories where applicable.
2804
2805 =item B<--target> | B<-t>
2806
2807 Print the config attributes for this config target.
2808
2809 =item B<--environment> | B<-e>
2810
2811 Print the environment variables and their values at the time of configuration.
2812
2813 =item B<--make-variables> | B<-m>
2814
2815 Print the main make variables generated in the current configuration
2816
2817 =item B<--build-parameters> | B<-b>
2818
2819 Print the build parameters, i.e. build file and build file templates.
2820
2821 =item B<--reconfigure> | B<--reconf> | B<-r>
2822
2823 Redo the configuration.
2824
2825 =item B<--verbose> | B<-v>
2826
2827 Verbose output.
2828
2829 =back
2830
2831 =cut
2832
2833 EOF
2834 close(OUT);
2835 if ($builder_platform eq 'unix') {
2836     my $mode = (0755 & ~umask);
2837     chmod $mode, 'configdata.pm'
2838         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2839 }
2840
2841 my %builders = (
2842     unified => sub {
2843         print 'Creating ',$target{build_file},"\n";
2844         run_dofile(catfile($blddir, $target{build_file}),
2845                    @{$config{build_file_templates}});
2846     },
2847     );
2848
2849 $builders{$builder}->($builder_platform, @builder_opts);
2850
2851 $SIG{__DIE__} = $orig_death_handler;
2852
2853 print <<"EOF" if ($disabled{threads} eq "unavailable");
2854
2855 The library could not be configured for supporting multi-threaded
2856 applications as the compiler options required on this system are not known.
2857 See file INSTALL for details if you need multi-threading.
2858 EOF
2859
2860 print <<"EOF" if ($no_shared_warn);
2861
2862 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2863 platform, so we will pretend you gave the option 'no-pic', which also disables
2864 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2865 or position independent code, please let us know (but please first make sure
2866 you have tried with a current version of OpenSSL).
2867 EOF
2868
2869 print <<"EOF";
2870
2871 **********************************************************************
2872 ***                                                                ***
2873 ***   OpenSSL has been successfully configured                     ***
2874 ***                                                                ***
2875 ***   If you encounter a problem while building, please open an    ***
2876 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2877 ***   and include the output from the following command:           ***
2878 ***                                                                ***
2879 ***       perl configdata.pm --dump                                ***
2880 ***                                                                ***
2881 ***   (If you are new to OpenSSL, you might want to consult the    ***
2882 ***   'Troubleshooting' section in the INSTALL file first)         ***
2883 ***                                                                ***
2884 **********************************************************************
2885 EOF
2886
2887 exit(0);
2888
2889 ######################################################################
2890 #
2891 # Helpers and utility functions
2892 #
2893
2894 # Death handler, to print a helpful message in case of failure #######
2895 #
2896 sub death_handler {
2897     die @_ if $^S;              # To prevent the added message in eval blocks
2898     my $build_file = $target{build_file} // "build file";
2899     my @message = ( <<"_____", @_ );
2900
2901 Failure!  $build_file wasn't produced.
2902 Please read INSTALL and associated NOTES files.  You may also have to look over
2903 your available compiler tool chain or change your configuration.
2904
2905 _____
2906
2907     # Dying is terminal, so it's ok to reset the signal handler here.
2908     $SIG{__DIE__} = $orig_death_handler;
2909     die @message;
2910 }
2911
2912 # Configuration file reading #########################################
2913
2914 # Note: All of the helper functions are for lazy evaluation.  They all
2915 # return a CODE ref, which will return the intended value when evaluated.
2916 # Thus, whenever there's mention of a returned value, it's about that
2917 # intended value.
2918
2919 # Helper function to implement conditional inheritance depending on the
2920 # value of $disabled{asm}.  Used in inherit_from values as follows:
2921 #
2922 #      inherit_from => [ "template", asm("asm_tmpl") ]
2923 #
2924 sub asm {
2925     my @x = @_;
2926     sub {
2927         $disabled{asm} ? () : @x;
2928     }
2929 }
2930
2931 # Helper function to implement conditional value variants, with a default
2932 # plus additional values based on the value of $config{build_type}.
2933 # Arguments are given in hash table form:
2934 #
2935 #       picker(default => "Basic string: ",
2936 #              debug   => "debug",
2937 #              release => "release")
2938 #
2939 # When configuring with --debug, the resulting string will be
2940 # "Basic string: debug", and when not, it will be "Basic string: release"
2941 #
2942 # This can be used to create variants of sets of flags according to the
2943 # build type:
2944 #
2945 #       cflags => picker(default => "-Wall",
2946 #                        debug   => "-g -O0",
2947 #                        release => "-O3")
2948 #
2949 sub picker {
2950     my %opts = @_;
2951     return sub { add($opts{default} || (),
2952                      $opts{$config{build_type}} || ())->(); }
2953 }
2954
2955 # Helper function to combine several values of different types into one.
2956 # This is useful if you want to combine a string with the result of a
2957 # lazy function, such as:
2958 #
2959 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2960 #
2961 sub combine {
2962     my @stuff = @_;
2963     return sub { add(@stuff)->(); }
2964 }
2965
2966 # Helper function to implement conditional values depending on the value
2967 # of $disabled{threads}.  Can be used as follows:
2968 #
2969 #       cflags => combine("-Wall", threads("-pthread"))
2970 #
2971 sub threads {
2972     my @flags = @_;
2973     return sub { add($disabled{threads} ? () : @flags)->(); }
2974 }
2975
2976 sub shared {
2977     my @flags = @_;
2978     return sub { add($disabled{shared} ? () : @flags)->(); }
2979 }
2980
2981 our $add_called = 0;
2982 # Helper function to implement adding values to already existing configuration
2983 # values.  It handles elements that are ARRAYs, CODEs and scalars
2984 sub _add {
2985     my $separator = shift;
2986
2987     # If there's any ARRAY in the collection of values OR the separator
2988     # is undef, we will return an ARRAY of combined values, otherwise a
2989     # string of joined values with $separator as the separator.
2990     my $found_array = !defined($separator);
2991
2992     my @values =
2993         map {
2994             my $res = $_;
2995             while (ref($res) eq "CODE") {
2996                 $res = $res->();
2997             }
2998             if (defined($res)) {
2999                 if (ref($res) eq "ARRAY") {
3000                     $found_array = 1;
3001                     @$res;
3002                 } else {
3003                     $res;
3004                 }
3005             } else {
3006                 ();
3007             }
3008     } (@_);
3009
3010     $add_called = 1;
3011
3012     if ($found_array) {
3013         [ @values ];
3014     } else {
3015         join($separator, grep { defined($_) && $_ ne "" } @values);
3016     }
3017 }
3018 sub add_before {
3019     my $separator = " ";
3020     if (ref($_[$#_]) eq "HASH") {
3021         my $opts = pop;
3022         $separator = $opts->{separator};
3023     }
3024     my @x = @_;
3025     sub { _add($separator, @x, @_) };
3026 }
3027 sub add {
3028     my $separator = " ";
3029     if (ref($_[$#_]) eq "HASH") {
3030         my $opts = pop;
3031         $separator = $opts->{separator};
3032     }
3033     my @x = @_;
3034     sub { _add($separator, @_, @x) };
3035 }
3036
3037 sub read_eval_file {
3038     my $fname = shift;
3039     my $content;
3040     my @result;
3041
3042     open F, "< $fname" or die "Can't open '$fname': $!\n";
3043     {
3044         undef local $/;
3045         $content = <F>;
3046     }
3047     close F;
3048     {
3049         local $@;
3050
3051         @result = ( eval $content );
3052         warn $@ if $@;
3053     }
3054     return wantarray ? @result : $result[0];
3055 }
3056
3057 # configuration reader, evaluates the input file as a perl script and expects
3058 # it to fill %targets with target configurations.  Those are then added to
3059 # %table.
3060 sub read_config {
3061     my $fname = shift;
3062     my %targets;
3063
3064     {
3065         # Protect certain tables from tampering
3066         local %table = ();
3067
3068         %targets = read_eval_file($fname);
3069     }
3070     my %preexisting = ();
3071     foreach (sort keys %targets) {
3072         $preexisting{$_} = 1 if $table{$_};
3073     }
3074     die <<"EOF",
3075 The following config targets from $fname
3076 shadow pre-existing config targets with the same name:
3077 EOF
3078         map { "  $_\n" } sort keys %preexisting
3079         if %preexisting;
3080
3081
3082     # For each target, check that it's configured with a hash table.
3083     foreach (keys %targets) {
3084         if (ref($targets{$_}) ne "HASH") {
3085             if (ref($targets{$_}) eq "") {
3086                 warn "Deprecated target configuration for $_, ignoring...\n";
3087             } else {
3088                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3089             }
3090             delete $targets{$_};
3091         } else {
3092             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3093         }
3094     }
3095
3096     %table = (%table, %targets);
3097
3098 }
3099
3100 # configuration resolver.  Will only resolve all the lazy evaluation
3101 # codeblocks for the chosen target and all those it inherits from,
3102 # recursively
3103 sub resolve_config {
3104     my $target = shift;
3105     my @breadcrumbs = @_;
3106
3107 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3108
3109     if (grep { $_ eq $target } @breadcrumbs) {
3110         die "inherit_from loop!  target backtrace:\n  "
3111             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3112     }
3113
3114     if (!defined($table{$target})) {
3115         warn "Warning! target $target doesn't exist!\n";
3116         return ();
3117     }
3118     # Recurse through all inheritances.  They will be resolved on the
3119     # fly, so when this operation is done, they will all just be a
3120     # bunch of attributes with string values.
3121     # What we get here, though, are keys with references to lists of
3122     # the combined values of them all.  We will deal with lists after
3123     # this stage is done.
3124     my %combined_inheritance = ();
3125     if ($table{$target}->{inherit_from}) {
3126         my @inherit_from =
3127             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3128         foreach (@inherit_from) {
3129             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3130
3131             # 'template' is a marker that's considered private to
3132             # the config that had it.
3133             delete $inherited_config{template};
3134
3135             foreach (keys %inherited_config) {
3136                 if (!$combined_inheritance{$_}) {
3137                     $combined_inheritance{$_} = [];
3138                 }
3139                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3140             }
3141         }
3142     }
3143
3144     # We won't need inherit_from in this target any more, since we've
3145     # resolved all the inheritances that lead to this
3146     delete $table{$target}->{inherit_from};
3147
3148     # Now is the time to deal with those lists.  Here's the place to
3149     # decide what shall be done with those lists, all based on the
3150     # values of the target we're currently dealing with.
3151     # - If a value is a coderef, it will be executed with the list of
3152     #   inherited values as arguments.
3153     # - If the corresponding key doesn't have a value at all or is the
3154     #   empty string, the inherited value list will be run through the
3155     #   default combiner (below), and the result becomes this target's
3156     #   value.
3157     # - Otherwise, this target's value is assumed to be a string that
3158     #   will simply override the inherited list of values.
3159     my $default_combiner = add();
3160
3161     my %all_keys =
3162         map { $_ => 1 } (keys %combined_inheritance,
3163                          keys %{$table{$target}});
3164
3165     sub process_values {
3166         my $object    = shift;
3167         my $inherited = shift;  # Always a [ list ]
3168         my $target    = shift;
3169         my $entry     = shift;
3170
3171         $add_called = 0;
3172
3173         while(ref($object) eq "CODE") {
3174             $object = $object->(@$inherited);
3175         }
3176         if (!defined($object)) {
3177             return ();
3178         }
3179         elsif (ref($object) eq "ARRAY") {
3180             local $add_called;  # To make sure recursive calls don't affect it
3181             return [ map { process_values($_, $inherited, $target, $entry) }
3182                      @$object ];
3183         } elsif (ref($object) eq "") {
3184             return $object;
3185         } else {
3186             die "cannot handle reference type ",ref($object)
3187                 ," found in target ",$target," -> ",$entry,"\n";
3188         }
3189     }
3190
3191     foreach (sort keys %all_keys) {
3192         my $previous = $combined_inheritance{$_};
3193
3194         # Current target doesn't have a value for the current key?
3195         # Assign it the default combiner, the rest of this loop body
3196         # will handle it just like any other coderef.
3197         if (!exists $table{$target}->{$_}) {
3198             $table{$target}->{$_} = $default_combiner;
3199         }
3200
3201         $table{$target}->{$_} = process_values($table{$target}->{$_},
3202                                                $combined_inheritance{$_},
3203                                                $target, $_);
3204         unless(defined($table{$target}->{$_})) {
3205             delete $table{$target}->{$_};
3206         }
3207 #        if ($extra_checks &&
3208 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3209 #            warn "$_ got replaced in $target\n";
3210 #        }
3211     }
3212
3213     # Finally done, return the result.
3214     return %{$table{$target}};
3215 }
3216
3217 sub usage
3218         {
3219         print STDERR $usage;
3220         print STDERR "\npick os/compiler from:\n";
3221         my $j=0;
3222         my $i;
3223         my $k=0;
3224         foreach $i (sort keys %table)
3225                 {
3226                 next if $table{$i}->{template};
3227                 next if $i =~ /^debug/;
3228                 $k += length($i) + 1;
3229                 if ($k > 78)
3230                         {
3231                         print STDERR "\n";
3232                         $k=length($i);
3233                         }
3234                 print STDERR $i . " ";
3235                 }
3236         foreach $i (sort keys %table)
3237                 {
3238                 next if $table{$i}->{template};
3239                 next if $i !~ /^debug/;
3240                 $k += length($i) + 1;
3241                 if ($k > 78)
3242                         {
3243                         print STDERR "\n";
3244                         $k=length($i);
3245                         }
3246                 print STDERR $i . " ";
3247                 }
3248         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3249         exit(1);
3250         }
3251
3252 sub run_dofile
3253 {
3254     my $out = shift;
3255     my @templates = @_;
3256
3257     unlink $out || warn "Can't remove $out, $!"
3258         if -f $out;
3259     foreach (@templates) {
3260         die "Can't open $_, $!" unless -f $_;
3261     }
3262     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3263     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3264     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3265     system($cmd);
3266     exit 1 if $? != 0;
3267     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3268 }
3269
3270 sub compiler_predefined {
3271     state %predefined;
3272     my $cc = shift;
3273
3274     return () if $^O eq 'VMS';
3275
3276     die 'compiler_predefined called without a compiler command'
3277         unless $cc;
3278
3279     if (! $predefined{$cc}) {
3280
3281         $predefined{$cc} = {};
3282
3283         # collect compiler pre-defines from gcc or gcc-alike...
3284         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3285         while (my $l = <PIPE>) {
3286             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3287             $predefined{$cc}->{$1} = $2 // '';
3288         }
3289         close(PIPE);
3290     }
3291
3292     return %{$predefined{$cc}};
3293 }
3294
3295 sub which
3296 {
3297     my ($name)=@_;
3298
3299     if (eval { require IPC::Cmd; 1; }) {
3300         IPC::Cmd->import();
3301         return scalar IPC::Cmd::can_run($name);
3302     } else {
3303         # if there is $directories component in splitpath,
3304         # then it's not something to test with $PATH...
3305         return $name if (File::Spec->splitpath($name))[1];
3306
3307         foreach (File::Spec->path()) {
3308             my $fullpath = catfile($_, "$name$target{exe_extension}");
3309             if (-f $fullpath and -x $fullpath) {
3310                 return $fullpath;
3311             }
3312         }
3313     }
3314 }
3315
3316 sub env
3317 {
3318     my $name = shift;
3319     my %opts = @_;
3320
3321     unless ($opts{cacheonly}) {
3322         # Note that if $ENV{$name} doesn't exist or is undefined,
3323         # $config{perlenv}->{$name} will be created with the value
3324         # undef.  This is intentional.
3325
3326         $config{perlenv}->{$name} = $ENV{$name}
3327             if ! exists $config{perlenv}->{$name};
3328     }
3329     return $config{perlenv}->{$name};
3330 }
3331
3332 # Configuration printer ##############################################
3333
3334 sub print_table_entry
3335 {
3336     local $now_printing = shift;
3337     my %target = resolve_config($now_printing);
3338     my $type = shift;
3339
3340     # Don't print the templates
3341     return if $target{template};
3342
3343     my @sequence = (
3344         "sys_id",
3345         "cpp",
3346         "cppflags",
3347         "defines",
3348         "includes",
3349         "cc",
3350         "cflags",
3351         "unistd",
3352         "ld",
3353         "lflags",
3354         "loutflag",
3355         "ex_libs",
3356         "bn_ops",
3357         "apps_aux_src",
3358         "cpuid_asm_src",
3359         "uplink_aux_src",
3360         "bn_asm_src",
3361         "ec_asm_src",
3362         "des_asm_src",
3363         "aes_asm_src",
3364         "bf_asm_src",
3365         "md5_asm_src",
3366         "cast_asm_src",
3367         "sha1_asm_src",
3368         "rc4_asm_src",
3369         "rmd160_asm_src",
3370         "rc5_asm_src",
3371         "wp_asm_src",
3372         "cmll_asm_src",
3373         "modes_asm_src",
3374         "padlock_asm_src",
3375         "chacha_asm_src",
3376         "poly1035_asm_src",
3377         "thread_scheme",
3378         "perlasm_scheme",
3379         "dso_scheme",
3380         "shared_target",
3381         "shared_cflag",
3382         "shared_defines",
3383         "shared_ldflag",
3384         "shared_rcflag",
3385         "shared_extension",
3386         "dso_extension",
3387         "obj_extension",
3388         "exe_extension",
3389         "ranlib",
3390         "ar",
3391         "arflags",
3392         "aroutflag",
3393         "rc",
3394         "rcflags",
3395         "rcoutflag",
3396         "mt",
3397         "mtflags",
3398         "mtinflag",
3399         "mtoutflag",
3400         "multilib",
3401         "build_scheme",
3402         );
3403
3404     if ($type eq "TABLE") {
3405         print "\n";
3406         print "*** $now_printing\n";
3407         foreach (@sequence) {
3408             if (ref($target{$_}) eq "ARRAY") {
3409                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3410             } else {
3411                 printf "\$%-12s = %s\n", $_, $target{$_};
3412             }
3413         }
3414     } elsif ($type eq "HASH") {
3415         my $largest =
3416             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3417         print "    '$now_printing' => {\n";
3418         foreach (@sequence) {
3419             if ($target{$_}) {
3420                 if (ref($target{$_}) eq "ARRAY") {
3421                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3422                 } else {
3423                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3424                 }
3425             }
3426         }
3427         print "    },\n";
3428     }
3429 }
3430
3431 # Utility routines ###################################################
3432
3433 # On VMS, if the given file is a logical name, File::Spec::Functions
3434 # will consider it an absolute path.  There are cases when we want a
3435 # purely syntactic check without checking the environment.
3436 sub isabsolute {
3437     my $file = shift;
3438
3439     # On non-platforms, we just use file_name_is_absolute().
3440     return file_name_is_absolute($file) unless $^O eq "VMS";
3441
3442     # If the file spec includes a device or a directory spec,
3443     # file_name_is_absolute() is perfectly safe.
3444     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3445
3446     # Here, we know the given file spec isn't absolute
3447     return 0;
3448 }
3449
3450 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3451 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3452 # realpath() requires that at least all path components except the last is an
3453 # existing directory.  On VMS, the last component of the directory spec must
3454 # exist.
3455 sub absolutedir {
3456     my $dir = shift;
3457
3458     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3459     # will return the volume name for the device, no matter what.  Also,
3460     # it will return an incorrect directory spec if the argument is a
3461     # directory that doesn't exist.
3462     if ($^O eq "VMS") {
3463         return rel2abs($dir);
3464     }
3465
3466     # We use realpath() on Unix, since no other will properly clean out
3467     # a directory spec.
3468     use Cwd qw/realpath/;
3469
3470     return realpath($dir);
3471 }
3472
3473 sub quotify {
3474     my %processors = (
3475         perl    => sub { my $x = shift;
3476                          $x =~ s/([\\\$\@"])/\\$1/g;
3477                          return '"'.$x.'"'; },
3478         maybeshell => sub { my $x = shift;
3479                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3480                             if ($x ne $y || $x =~ m|\s|) {
3481                                 return '"'.$y.'"';
3482                             } else {
3483                                 return $x;
3484                             }
3485                         },
3486         );
3487     my $for = shift;
3488     my $processor =
3489         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3490
3491     return map { $processor->($_); } @_;
3492 }
3493
3494 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3495 # $filename is a file name to read from
3496 # $line_concat_cond_re is a regexp detecting a line continuation ending
3497 # $line_concat is a CODEref that takes care of concatenating two lines
3498 sub collect_from_file {
3499     my $filename = shift;
3500     my $line_concat_cond_re = shift;
3501     my $line_concat = shift;
3502
3503     open my $fh, $filename || die "unable to read $filename: $!\n";
3504     return sub {
3505         my $saved_line = "";
3506         $_ = "";
3507         while (<$fh>) {
3508             s|\R$||;
3509             if (defined $line_concat) {
3510                 $_ = $line_concat->($saved_line, $_);
3511                 $saved_line = "";
3512             }
3513             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3514                 $saved_line = $_;
3515                 next;
3516             }
3517             return $_;
3518         }
3519         die "$filename ending with continuation line\n" if $_;
3520         close $fh;
3521         return undef;
3522     }
3523 }
3524
3525 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3526 # $array is an ARRAYref of lines
3527 # $line_concat_cond_re is a regexp detecting a line continuation ending
3528 # $line_concat is a CODEref that takes care of concatenating two lines
3529 sub collect_from_array {
3530     my $array = shift;
3531     my $line_concat_cond_re = shift;
3532     my $line_concat = shift;
3533     my @array = (@$array);
3534
3535     return sub {
3536         my $saved_line = "";
3537         $_ = "";
3538         while (defined($_ = shift @array)) {
3539             s|\R$||;
3540             if (defined $line_concat) {
3541                 $_ = $line_concat->($saved_line, $_);
3542                 $saved_line = "";
3543             }
3544             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3545                 $saved_line = $_;
3546                 next;
3547             }
3548             return $_;
3549         }
3550         die "input text ending with continuation line\n" if $_;
3551         return undef;
3552     }
3553 }
3554
3555 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3556 # $lineiterator is a CODEref that delivers one line at a time.
3557 # All following arguments are regex/CODEref pairs, where the regexp detects a
3558 # line and the CODEref does something with the result of the regexp.
3559 sub collect_information {
3560     my $lineiterator = shift;
3561     my %collectors = @_;
3562
3563     while(defined($_ = $lineiterator->())) {
3564         s|\R$||;