Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-dso        do not compile in any native shared-library methods. This
  63 #               will ensure that all methods just return NULL.
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # enable-weak-ssl-ciphers
  70 #               Enable weak ciphers that are disabled by default.
  71 # 386           generate 80386 code in assembly modules
  72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  73 #               mentioned '386' option implies this one
  74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  75 # -<xxx> +<xxx> compiler options are passed through
  76 # -static       while -static is also a pass-through compiler option (and
  77 #               as such is limited to environments where it's actually
  78 #               meaningful), it triggers a number configuration options,
  79 #               namely no-dso, no-pic, no-shared and no-threads. It is
  80 #               argued that the only reason to produce statically linked
  81 #               binaries (and in context it means executables linked with
  82 #               -static flag, and not just executables linked with static
  83 #               libcrypto.a) is to eliminate dependency on specific run-time,
  84 #               a.k.a. libc version. The mentioned config options are meant
  85 #               to achieve just that. Unfortunately on Linux it's impossible
  86 #               to eliminate the dependency completely for openssl executable
  87 #               because of getaddrinfo and gethostbyname calls, which can
  88 #               invoke dynamically loadable library facility anyway to meet
  89 #               the lookup requests. For this reason on Linux statically
  90 #               linked openssl executable has rather debugging value than
  91 #               production quality.
  92 #
  93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  94 #               provided to stack calls. Generates unique stack functions for
  95 #               each possible stack type.
  96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  98 # Following are set automatically by this script
  99 #
 100 # MD5_ASM       use some extra md5 assembler,
 101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 102 # RMD160_ASM    use some extra ripemd160 assembler,
 103 # SHA256_ASM    sha256_block is implemented in assembler
 104 # SHA512_ASM    sha512_block is implemented in assembler
 105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 106
 107 # Minimum warning options... any contributions to OpenSSL should at least get
 108 # past these.
 109
 110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 111 # -DPEDANTIC complements -pedantic and is meant to mask code that
 112 # is not strictly standard-compliant and/or implementation-specific,
 113 # e.g. inline assembly, disregards to alignment requirements, such
 114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 115 # to be used even in sanitized builds, because sanitizer too is
 116 # supposed to and does take notice of non-standard behaviour. Then
 117 # -pedantic with pre-C9x compiler would also complain about 'long
 118 # long' not being supported. As 64-bit algorithms are common now,
 119 # it grew impossible to resolve this without sizeable additional
 120 # code, so we just tell compiler to be pedantic about everything
 121 # but 'long long' type.
 122
 123 my %gcc_devteam_warn = ();
 124 {
 125     my @common = qw( -DDEBUG_UNUSED
 126                      -DPEDANTIC -pedantic -Wno-long-long
 127                      -Wall
 128                      -Wextra
 129                      -Wno-unused-parameter
 130                      -Wno-missing-field-initializers
 131                      -Wswitch
 132                      -Wsign-compare
 133                      -Wshadow
 134                      -Wformat
 135                      -Wtype-limits
 136                      -Wundef
 137                      -Werror );
 138     %gcc_devteam_warn = (
 139         CFLAGS          => [ @common, qw( -Wmissing-prototypes
 140                                           -Wstrict-prototypes ) ],
 141         CXXFLAGS        => [ @common ]
 142     );
 143 }
 144
 145 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 146 # TODO(openssl-team): fix problems and investigate if (at least) the
 147 # following warnings can also be enabled:
 148 #       -Wcast-align
 149 #       -Wunreachable-code -- no, too ugly/compiler-specific
 150 #       -Wlanguage-extension-token -- no, we use asm()
 151 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 152 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 153 my %clang_devteam_warn = ();
 154 {
 155     my @common = qw( -Wswitch-default
 156                      -Wno-parentheses-equality
 157                      -Wno-language-extension-token
 158                      -Wno-extended-offsetof
 159                      -Wconditional-uninitialized
 160                      -Wincompatible-pointer-types-discards-qualifiers
 161                      -Wno-unknown-warning-option );
 162     %clang_devteam_warn = (
 163         CFLAGS          => [ @common, qw( -Wmissing-variable-declarations ) ],
 164         CXXFLAGS        => [ @common ]
 165     );
 166 }
 167
 168 # This adds backtrace information to the memory leak info.  Is only used
 169 # when crypto-mdebug-backtrace is enabled.
 170 my $memleak_devteam_backtrace = "-rdynamic";
 171
 172 my $strict_warnings = 0;
 173
 174 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 175 # which would cover all BSD flavors. -pthread applies to them all,
 176 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 177 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 178 # which has to be accompanied by explicit -D_THREAD_SAFE and
 179 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 180 # seems to be sufficient?
 181 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 182
 183 #
 184 # API compatibility name to version number mapping.
 185 #
 186 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 187 my $apitable = {
 188     "3.0.0" => 3,
 189     "1.1.1" => 2,
 190     "1.1.0" => 2,
 191     "1.0.2" => 1,
 192     "1.0.1" => 1,
 193     "1.0.0" => 1,
 194     "0.9.8" => 0,
 195 };
 196
 197 our %table = ();
 198 our %config = ();
 199 our %withargs = ();
 200 our $now_printing;      # set to current entry's name in print_table_entry
 201                         # (todo: right thing would be to encapsulate name
 202                         # into %target [class] and make print_table_entry
 203                         # a method)
 204
 205 # Forward declarations ###############################################
 206
 207 # read_config(filename)
 208 #
 209 # Reads a configuration file and populates %table with the contents
 210 # (which the configuration file places in %targets).
 211 sub read_config;
 212
 213 # resolve_config(target)
 214 #
 215 # Resolves all the late evaluations, inheritances and so on for the
 216 # chosen target and any target it inherits from.
 217 sub resolve_config;
 218
 219
 220 # Information collection #############################################
 221
 222 # Unified build supports separate build dir
 223 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 224 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 225 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 226
 227 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 228
 229 $config{sourcedir} = abs2rel($srcdir);
 230 $config{builddir} = abs2rel($blddir);
 231
 232 # Collect reconfiguration information if needed
 233 my @argvcopy=@ARGV;
 234
 235 if (grep /^reconf(igure)?$/, @argvcopy) {
 236     die "reconfiguring with other arguments present isn't supported"
 237         if scalar @argvcopy > 1;
 238     if (-f "./configdata.pm") {
 239         my $file = "./configdata.pm";
 240         unless (my $return = do $file) {
 241             die "couldn't parse $file: $@" if $@;
 242             die "couldn't do $file: $!"    unless defined $return;
 243             die "couldn't run $file"       unless $return;
 244         }
 245
 246         @argvcopy = defined($configdata::config{perlargv}) ?
 247             @{$configdata::config{perlargv}} : ();
 248         die "Incorrect data to reconfigure, please do a normal configuration\n"
 249             if (grep(/^reconf/,@argvcopy));
 250         $config{perlenv} = $configdata::config{perlenv} // {};
 251     } else {
 252         die "Insufficient data to reconfigure, please do a normal configuration\n";
 253     }
 254 }
 255
 256 $config{perlargv} = [ @argvcopy ];
 257
 258 # Collect version numbers
 259 $config{major} = "unknown";
 260 $config{minor} = "unknown";
 261 $config{patch} = "unknown";
 262 $config{prerelease} = "";
 263 $config{build_metadata} = "";
 264 $config{shlib_version} = "unknown";
 265
 266 collect_information(
 267     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 268     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 269         sub { $config{major} = $1; },
 270     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 271         sub { $config{minor} = $1; },
 272     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 273         sub { $config{patch} = $1; },
 274     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 275         sub { $config{prerelease} = $1; },
 276     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 277         sub { $config{build_metadata} = $1; },
 278     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 279         sub { $config{shlib_version} = $1; },
 280     );
 281 die "erroneous version information in opensslv.h: ",
 282     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 283     if ($config{major} eq "unknown"
 284             || $config{minor} eq "unknown"
 285             || $config{patch} eq "unknown"
 286             || $config{shlib_version} eq "unknown");
 287
 288 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 289 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 290
 291 # Collect target configurations
 292
 293 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 294 foreach (sort glob($pattern)) {
 295     &read_config($_);
 296 }
 297
 298 if (defined env($local_config_envname)) {
 299     if ($^O eq 'VMS') {
 300         # VMS environment variables are logical names,
 301         # which can be used as is
 302         $pattern = $local_config_envname . ':' . '*.conf';
 303     } else {
 304         $pattern = catfile(env($local_config_envname), '*.conf');
 305     }
 306
 307     foreach (sort glob($pattern)) {
 308         &read_config($_);
 309     }
 310 }
 311
 312 # Save away perl command information
 313 $config{perl_cmd} = $^X;
 314 $config{perl_version} = $Config{version};
 315 $config{perl_archname} = $Config{archname};
 316
 317 $config{prefix}="";
 318 $config{openssldir}="";
 319 $config{processor}="";
 320 $config{libdir}="";
 321 my $auto_threads=1;    # enable threads automatically? true by default
 322 my $default_ranlib;
 323
 324 # Known TLS and DTLS protocols
 325 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 326 my @dtls = qw(dtls1 dtls1_2);
 327
 328 # Explicitly known options that are possible to disable.  They can
 329 # be regexps, and will be used like this: /^no-${option}$/
 330 # For developers: keep it sorted alphabetically
 331
 332 my @disablables = (
 333     "ktls",
 334     "afalgeng",
 335     "aria",
 336     "asan",
 337     "asm",
 338     "async",
 339     "autoalginit",
 340     "autoerrinit",
 341     "autoload-config",
 342     "bf",
 343     "blake2",
 344     "buildtest-c++",
 345     "camellia",
 346     "capieng",
 347     "cast",
 348     "chacha",
 349     "cmac",
 350     "cms",
 351     "comp",
 352     "crmf",
 353     "crypto-mdebug",
 354     "crypto-mdebug-backtrace",
 355     "ct",
 356     "deprecated",
 357     "des",
 358     "devcryptoeng",
 359     "dgram",
 360     "dh",
 361     "dsa",
 362     "dso",
 363     "dtls",
 364     "dynamic-engine",
 365     "ec",
 366     "ec2m",
 367     "ecdh",
 368     "ecdsa",
 369     "ec_nistp_64_gcc_128",
 370     "egd",
 371     "engine",
 372     "err",
 373     "external-tests",
 374     "filenames",
 375     "fuzz-libfuzzer",
 376     "fuzz-afl",
 377     "gost",
 378     "heartbeats",
 379     "idea",
 380     "makedepend",
 381     "md2",
 382     "md4",
 383     "mdc2",
 384     "msan",
 385     "multiblock",
 386     "nextprotoneg",
 387     "pinshared",
 388     "ocb",
 389     "ocsp",
 390     "padlockeng",
 391     "pic",
 392     "poly1305",
 393     "posix-io",
 394     "psk",
 395     "rc2",
 396     "rc4",
 397     "rc5",
 398     "rdrand",
 399     "rfc3779",
 400     "rmd160",
 401     "scrypt",
 402     "sctp",
 403     "seed",
 404     "shared",
 405     "siphash",
 406     "siv",
 407     "sm2",
 408     "sm3",
 409     "sm4",
 410     "sock",
 411     "srp",
 412     "srtp",
 413     "sse2",
 414     "ssl",
 415     "ssl-trace",
 416     "static-engine",
 417     "stdio",
 418     "tests",
 419     "threads",
 420     "tls",
 421     "trace",
 422     "ts",
 423     "ubsan",
 424     "ui-console",
 425     "unit-test",
 426     "whirlpool",
 427     "weak-ssl-ciphers",
 428     "zlib",
 429     "zlib-dynamic",
 430     );
 431 foreach my $proto ((@tls, @dtls))
 432         {
 433         push(@disablables, $proto);
 434         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 435         }
 436
 437 my %deprecated_disablables = (
 438     "ssl2" => undef,
 439     "buf-freelists" => undef,
 440     "hw" => "hw",               # causes cascade, but no macro
 441     "hw-padlock" => "padlockeng",
 442     "ripemd" => "rmd160",
 443     "ui" => "ui-console",
 444     );
 445
 446 # All of the following are disabled by default:
 447
 448 our %disabled = ( # "what"         => "comment"
 449                   "asan"                => "default",
 450                   "buildtest-c++"       => "default",
 451                   "crypto-mdebug"       => "default",
 452                   "crypto-mdebug-backtrace" => "default",
 453                   "devcryptoeng"        => "default",
 454                   "ec_nistp_64_gcc_128" => "default",
 455                   "egd"                 => "default",
 456                   "external-tests"      => "default",
 457                   "fuzz-libfuzzer"      => "default",
 458                   "fuzz-afl"            => "default",
 459                   "heartbeats"          => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "ubsan"               => "default",
 468                   "unit-test"           => "default",
 469                   "weak-ssl-ciphers"    => "default",
 470                   "zlib"                => "default",
 471                   "zlib-dynamic"        => "default",
 472                   "ktls"                => "default",
 473                 );
 474
 475 # Note: => pair form used for aesthetics, not to truly make a hash table
 476 my @disable_cascades = (
 477     # "what"            => [ "cascade", ... ]
 478     sub { $config{processor} eq "386" }
 479                         => [ "sse2" ],
 480     "ssl"               => [ "ssl3" ],
 481     "ssl3-method"       => [ "ssl3" ],
 482     "zlib"              => [ "zlib-dynamic" ],
 483     "des"               => [ "mdc2" ],
 484     "ec"                => [ "ecdsa", "ecdh" ],
 485
 486     "dgram"             => [ "dtls", "sctp" ],
 487     "sock"              => [ "dgram" ],
 488     "dtls"              => [ @dtls ],
 489     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 490                         => [ "dtls" ],
 491
 492     "tls"               => [ @tls ],
 493     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 494                         => [ "tls" ],
 495
 496     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 497
 498     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 499     "dso"               => [ "dynamic-engine" ],
 500
 501     # Without position independent code, there can be no shared libraries or DSOs
 502     "pic"               => [ "shared" ],
 503     "shared"            => [ "dynamic-engine" ],
 504
 505     "engine"            => [ grep /eng$/, @disablables ],
 506     "hw"                => [ "padlockeng" ],
 507
 508     # no-autoalginit is only useful when building non-shared
 509     "autoalginit"       => [ "shared", "apps" ],
 510
 511     "stdio"             => [ "apps", "capieng", "egd" ],
 512     "apps"              => [ "tests" ],
 513     "tests"             => [ "external-tests" ],
 514     "comp"              => [ "zlib" ],
 515     "ec"                => [ "tls1_3", "sm2" ],
 516     "sm3"               => [ "sm2" ],
 517     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 518
 519     sub { !$disabled{"msan"} } => [ "asm" ],
 520
 521     sub { $disabled{cmac}; } => [ "siv" ],
 522     );
 523
 524 # Avoid protocol support holes.  Also disable all versions below N, if version
 525 # N is disabled while N+1 is enabled.
 526 #
 527 my @list = (reverse @tls);
 528 while ((my $first, my $second) = (shift @list, shift @list)) {
 529     last unless @list;
 530     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 531                               => [ @list ] );
 532     unshift @list, $second;
 533 }
 534 my @list = (reverse @dtls);
 535 while ((my $first, my $second) = (shift @list, shift @list)) {
 536     last unless @list;
 537     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 538                               => [ @list ] );
 539     unshift @list, $second;
 540 }
 541
 542 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 543 # To remove something from %disabled, use "enable-foo".
 544 # For symmetry, "disable-foo" is a synonym for "no-foo".
 545
 546 &usage if ($#ARGV < 0);
 547
 548 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 549 # platform specific list separators.  Users from those platforms should
 550 # recognise those separators from how you set up the PATH to find executables.
 551 # The default is the Unix like separator, :, but as an exception, we also
 552 # support the space as separator.
 553 my $list_separator_re =
 554     { VMS           => qr/(?<!\^),/,
 555       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 556 # All the "make variables" we support
 557 # Some get pre-populated for the sake of backward compatibility
 558 # (we supported those before the change to "make variable" support.
 559 my %user = (
 560     AR          => env('AR'),
 561     ARFLAGS     => [],
 562     AS          => undef,
 563     ASFLAGS     => [],
 564     CC          => env('CC'),
 565     CFLAGS      => [ env('CFLAGS') || () ],
 566     CXX         => env('CXX'),
 567     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 568     CPP         => undef,
 569     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 570     CPPDEFINES  => [],  # Alternative for -D
 571     CPPINCLUDES => [],  # Alternative for -I
 572     CROSS_COMPILE => env('CROSS_COMPILE'),
 573     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 574     LD          => undef,
 575     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 576     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 577     MT          => undef,
 578     MTFLAGS     => [],
 579     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 580     RANLIB      => env('RANLIB'),
 581     RC          => env('RC') || env('WINDRES'),
 582     RCFLAGS     => [],
 583     RM          => undef,
 584    );
 585 # Info about what "make variables" may be prefixed with the cross compiler
 586 # prefix.  This should NEVER mention any such variable with a list for value.
 587 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 588 # The same but for flags given as Configure options.  These are *additional*
 589 # input, as opposed to the VAR=string option that override the corresponding
 590 # config target attributes
 591 my %useradd = (
 592     CPPDEFINES  => [],
 593     CPPINCLUDES => [],
 594     CPPFLAGS    => [],
 595     CFLAGS      => [],
 596     CXXFLAGS    => [],
 597     LDFLAGS     => [],
 598     LDLIBS      => [],
 599    );
 600
 601 my %user_synonyms = (
 602     HASHBANGPERL=> 'PERL',
 603     RC          => 'WINDRES',
 604    );
 605
 606 # Some target attributes have been renamed, this is the translation table
 607 my %target_attr_translate =(
 608     ar          => 'AR',
 609     as          => 'AS',
 610     cc          => 'CC',
 611     cxx         => 'CXX',
 612     cpp         => 'CPP',
 613     hashbangperl => 'HASHBANGPERL',
 614     ld          => 'LD',
 615     mt          => 'MT',
 616     ranlib      => 'RANLIB',
 617     rc          => 'RC',
 618     rm          => 'RM',
 619    );
 620
 621 # Initialisers coming from 'config' scripts
 622 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 623 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 624 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 625 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 626 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 627 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 628 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 629
 630 $config{openssl_api_defines}=[];
 631 $config{openssl_sys_defines}=[];
 632 $config{openssl_feature_defines}=[];
 633 $config{options}="";
 634 $config{build_type} = "release";
 635 my $target="";
 636
 637 my %cmdvars = ();               # Stores FOO='blah' type arguments
 638 my %unsupported_options = ();
 639 my %deprecated_options = ();
 640 # If you change this, update apps/version.c
 641 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 642 my @seed_sources = ();
 643 while (@argvcopy)
 644         {
 645         $_ = shift @argvcopy;
 646
 647         # Support env variable assignments among the options
 648         if (m|^(\w+)=(.+)?$|)
 649                 {
 650                 $cmdvars{$1} = $2;
 651                 # Every time a variable is given as a configuration argument,
 652                 # it acts as a reset if the variable.
 653                 if (exists $user{$1})
 654                         {
 655                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 656                         }
 657                 #if (exists $useradd{$1})
 658                 #       {
 659                 #       $useradd{$1} = [];
 660                 #       }
 661                 next;
 662                 }
 663
 664         # VMS is a case insensitive environment, and depending on settings
 665         # out of our control, we may receive options uppercased.  Let's
 666         # downcase at least the part before any equal sign.
 667         if ($^O eq "VMS")
 668                 {
 669                 s/^([^=]*)/lc($1)/e;
 670                 }
 671
 672         # some people just can't read the instructions, clang people have to...
 673         s/^-no-(?!integrated-as)/no-/;
 674
 675         # rewrite some options in "enable-..." form
 676         s /^-?-?shared$/enable-shared/;
 677         s /^sctp$/enable-sctp/;
 678         s /^threads$/enable-threads/;
 679         s /^zlib$/enable-zlib/;
 680         s /^zlib-dynamic$/enable-zlib-dynamic/;
 681
 682         if (/^(no|disable|enable)-(.+)$/)
 683                 {
 684                 my $word = $2;
 685                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 686                         && !exists $deprecated_disablables{$word}
 687                         && !grep { $word eq $_ } @disablables)
 688                         {
 689                         $unsupported_options{$_} = 1;
 690                         next;
 691                         }
 692                 }
 693         if (/^no-(.+)$/ || /^disable-(.+)$/)
 694                 {
 695                 foreach my $proto ((@tls, @dtls))
 696                         {
 697                         if ($1 eq "$proto-method")
 698                                 {
 699                                 $disabled{"$proto"} = "option($proto-method)";
 700                                 last;
 701                                 }
 702                         }
 703                 if ($1 eq "dtls")
 704                         {
 705                         foreach my $proto (@dtls)
 706                                 {
 707                                 $disabled{$proto} = "option(dtls)";
 708                                 }
 709                         $disabled{"dtls"} = "option(dtls)";
 710                         }
 711                 elsif ($1 eq "ssl")
 712                         {
 713                         # Last one of its kind
 714                         $disabled{"ssl3"} = "option(ssl)";
 715                         }
 716                 elsif ($1 eq "tls")
 717                         {
 718                         # XXX: Tests will fail if all SSL/TLS
 719                         # protocols are disabled.
 720                         foreach my $proto (@tls)
 721                                 {
 722                                 $disabled{$proto} = "option(tls)";
 723                                 }
 724                         }
 725                 elsif ($1 eq "static-engine")
 726                         {
 727                         delete $disabled{"dynamic-engine"};
 728                         }
 729                 elsif ($1 eq "dynamic-engine")
 730                         {
 731                         $disabled{"dynamic-engine"} = "option";
 732                         }
 733                 elsif (exists $deprecated_disablables{$1})
 734                         {
 735                         $deprecated_options{$_} = 1;
 736                         if (defined $deprecated_disablables{$1})
 737                                 {
 738                                 $disabled{$deprecated_disablables{$1}} = "option";
 739                                 }
 740                         }
 741                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 742                         {
 743                         $deprecated_options{$_} = 1;
 744                         }
 745                 else
 746                         {
 747                         $disabled{$1} = "option";
 748                         }
 749                 # No longer an automatic choice
 750                 $auto_threads = 0 if ($1 eq "threads");
 751                 }
 752         elsif (/^enable-(.+)$/)
 753                 {
 754                 if ($1 eq "static-engine")
 755                         {
 756                         $disabled{"dynamic-engine"} = "option";
 757                         }
 758                 elsif ($1 eq "dynamic-engine")
 759                         {
 760                         delete $disabled{"dynamic-engine"};
 761                         }
 762                 elsif ($1 eq "zlib-dynamic")
 763                         {
 764                         delete $disabled{"zlib"};
 765                         }
 766                 my $algo = $1;
 767                 delete $disabled{$algo};
 768
 769                 # No longer an automatic choice
 770                 $auto_threads = 0 if ($1 eq "threads");
 771                 }
 772         elsif (/^--strict-warnings$/)
 773                 {
 774                 # Pretend that our strict flags is a C flag, and replace it
 775                 # with the proper flags later on
 776                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 777                 push @{$useradd{CXXFLAGS}}, '--ossl-strict-warnings';
 778                 $strict_warnings=1;
 779                 }
 780         elsif (/^--debug$/)
 781                 {
 782                 $config{build_type} = "debug";
 783                 }
 784         elsif (/^--release$/)
 785                 {
 786                 $config{build_type} = "release";
 787                 }
 788         elsif (/^386$/)
 789                 { $config{processor}=386; }
 790         elsif (/^fips$/)
 791                 {
 792                 die "FIPS mode not supported\n";
 793                 }
 794         elsif (/^rsaref$/)
 795                 {
 796                 # No RSAref support any more since it's not needed.
 797                 # The check for the option is there so scripts aren't
 798                 # broken
 799                 }
 800         elsif (/^nofipscanistercheck$/)
 801                 {
 802                 die "FIPS mode not supported\n";
 803                 }
 804         elsif (/^[-+]/)
 805                 {
 806                 if (/^--prefix=(.*)$/)
 807                         {
 808                         $config{prefix}=$1;
 809                         die "Directory given with --prefix MUST be absolute\n"
 810                                 unless file_name_is_absolute($config{prefix});
 811                         }
 812                 elsif (/^--api=(.*)$/)
 813                         {
 814                         $config{api}=$1;
 815                         }
 816                 elsif (/^--libdir=(.*)$/)
 817                         {
 818                         $config{libdir}=$1;
 819                         }
 820                 elsif (/^--openssldir=(.*)$/)
 821                         {
 822                         $config{openssldir}=$1;
 823                         }
 824                 elsif (/^--with-zlib-lib=(.*)$/)
 825                         {
 826                         $withargs{zlib_lib}=$1;
 827                         }
 828                 elsif (/^--with-zlib-include=(.*)$/)
 829                         {
 830                         $withargs{zlib_include}=$1;
 831                         }
 832                 elsif (/^--with-fuzzer-lib=(.*)$/)
 833                         {
 834                         $withargs{fuzzer_lib}=$1;
 835                         }
 836                 elsif (/^--with-fuzzer-include=(.*)$/)
 837                         {
 838                         $withargs{fuzzer_include}=$1;
 839                         }
 840                 elsif (/^--with-rand-seed=(.*)$/)
 841                         {
 842                         foreach my $x (split(m|,|, $1))
 843                             {
 844                             die "Unknown --with-rand-seed choice $x\n"
 845                                 if ! grep { $x eq $_ } @known_seed_sources;
 846                             push @seed_sources, $x;
 847                             }
 848                         }
 849                 elsif (/^--cross-compile-prefix=(.*)$/)
 850                         {
 851                         $user{CROSS_COMPILE}=$1;
 852                         }
 853                 elsif (/^--config=(.*)$/)
 854                         {
 855                         read_config $1;
 856                         }
 857                 elsif (/^-l(.*)$/)
 858                         {
 859                         push @{$useradd{LDLIBS}}, $_;
 860                         }
 861                 elsif (/^-framework$/)
 862                         {
 863                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 864                         }
 865                 elsif (/^-L(.*)$/ or /^-Wl,/)
 866                         {
 867                         push @{$useradd{LDFLAGS}}, $_;
 868                         }
 869                 elsif (/^-rpath$/ or /^-R$/)
 870                         # -rpath is the OSF1 rpath flag
 871                         # -R is the old Solaris rpath flag
 872                         {
 873                         my $rpath = shift(@argvcopy) || "";
 874                         $rpath .= " " if $rpath ne "";
 875                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 876                         }
 877                 elsif (/^-static$/)
 878                         {
 879                         push @{$useradd{LDFLAGS}}, $_;
 880                         $disabled{"dso"} = "forced";
 881                         $disabled{"pic"} = "forced";
 882                         $disabled{"shared"} = "forced";
 883                         $disabled{"threads"} = "forced";
 884                         }
 885                 elsif (/^-D(.*)$/)
 886                         {
 887                         push @{$useradd{CPPDEFINES}}, $1;
 888                         }
 889                 elsif (/^-I(.*)$/)
 890                         {
 891                         push @{$useradd{CPPINCLUDES}}, $1;
 892                         }
 893                 elsif (/^-Wp,$/)
 894                         {
 895                         push @{$useradd{CPPFLAGS}}, $1;
 896                         }
 897                 else    # common if (/^[-+]/), just pass down...
 898                         {
 899                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 900                         push @{$useradd{CFLAGS}}, $_;
 901                         push @{$useradd{CXXFLAGS}}, $_;
 902                         }
 903                 }
 904         else
 905                 {
 906                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 907                 $target=$_;
 908                 }
 909         unless ($_ eq $target || /^no-/ || /^disable-/)
 910                 {
 911                 # "no-..." follows later after implied deactivations
 912                 # have been derived.  (Don't take this too seriously,
 913                 # we really only write OPTIONS to the Makefile out of
 914                 # nostalgia.)
 915
 916                 if ($config{options} eq "")
 917                         { $config{options} = $_; }
 918                 else
 919                         { $config{options} .= " ".$_; }
 920                 }
 921         }
 922
 923 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 924         die "***** Unsupported api compatibility level: $config{api}\n",
 925 }
 926
 927 if (keys %deprecated_options)
 928         {
 929         warn "***** Deprecated options: ",
 930                 join(", ", keys %deprecated_options), "\n";
 931         }
 932 if (keys %unsupported_options)
 933         {
 934         die "***** Unsupported options: ",
 935                 join(", ", keys %unsupported_options), "\n";
 936         }
 937
 938 # If any %useradd entry has been set, we must check that the "make
 939 # variables" haven't been set.  We start by checking of any %useradd entry
 940 # is set.
 941 if (grep { scalar @$_ > 0 } values %useradd) {
 942     # Hash of env / make variables names.  The possible values are:
 943     # 1 - "make vars"
 944     # 2 - %useradd entry set
 945     # 3 - both set
 946     my %detected_vars =
 947         map { my $v = 0;
 948               $v += 1 if $cmdvars{$_};
 949               $v += 2 if @{$useradd{$_}};
 950               $_ => $v }
 951         keys %useradd;
 952
 953     # If any of the corresponding "make variables" is set, we error
 954     if (grep { $_ & 1 } values %detected_vars) {
 955         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 956                                sort keys %detected_vars);
 957         die <<"_____";
 958 ***** Mixing make variables and additional compiler/linker flags as
 959 ***** configure command line option is not permitted.
 960 ***** Affected make variables: $names
 961 _____
 962     }
 963 }
 964
 965 # Check through all supported command line variables to see if any of them
 966 # were set, and canonicalise the values we got.  If no compiler or linker
 967 # flag or anything else that affects %useradd was set, we also check the
 968 # environment for values.
 969 my $anyuseradd =
 970     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 971 foreach (keys %user) {
 972     my $value = $cmdvars{$_};
 973     $value //= env($_) unless $anyuseradd;
 974     $value //=
 975         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 976     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 977         unless $anyuseradd;
 978
 979     if (defined $value) {
 980         if (ref $user{$_} eq 'ARRAY') {
 981             $user{$_} = [ split /$list_separator_re/, $value ];
 982         } elsif (!defined $user{$_}) {
 983             $user{$_} = $value;
 984         }
 985     }
 986 }
 987
 988 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 989     && !$disabled{shared}
 990     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 991     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 992         "***** any of asan, msan or ubsan\n";
 993 }
 994
 995 my @tocheckfor = (keys %disabled);
 996 while (@tocheckfor) {
 997     my %new_tocheckfor = ();
 998     my @cascade_copy = (@disable_cascades);
 999     while (@cascade_copy) {
1000         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
1001         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1002             foreach(grep { !defined($disabled{$_}) } @$descendents) {
1003                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
1004             }
1005         }
1006     }
1007     @tocheckfor = (keys %new_tocheckfor);
1008 }
1009
1010 our $die = sub { die @_; };
1011 if ($target eq "TABLE") {
1012     local $die = sub { warn @_; };
1013     foreach (sort keys %table) {
1014         print_table_entry($_, "TABLE");
1015     }
1016     exit 0;
1017 }
1018
1019 if ($target eq "LIST") {
1020     foreach (sort keys %table) {
1021         print $_,"\n" unless $table{$_}->{template};
1022     }
1023     exit 0;
1024 }
1025
1026 if ($target eq "HASH") {
1027     local $die = sub { warn @_; };
1028     print "%table = (\n";
1029     foreach (sort keys %table) {
1030         print_table_entry($_, "HASH");
1031     }
1032     exit 0;
1033 }
1034
1035 print "Configuring OpenSSL version $config{full_version} ";
1036 print "for target $target\n";
1037
1038 if (scalar(@seed_sources) == 0) {
1039     print "Using os-specific seed configuration\n";
1040     push @seed_sources, 'os';
1041 }
1042 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1043     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1044     warn <<_____ if scalar(@seed_sources) == 1;
1045
1046 ============================== WARNING ===============================
1047 You have selected the --with-rand-seed=none option, which effectively
1048 disables automatic reseeding of the OpenSSL random generator.
1049 All operations depending on the random generator such as creating keys
1050 will not work unless the random generator is seeded manually by the
1051 application.
1052
1053 Please read the 'Note on random number generation' section in the
1054 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1055 ============================== WARNING ===============================
1056
1057 _____
1058 }
1059 push @{$config{openssl_feature_defines}},
1060      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1061         @seed_sources;
1062
1063 # Backward compatibility?
1064 if ($target =~ m/^CygWin32(-.*)$/) {
1065     $target = "Cygwin".$1;
1066 }
1067
1068 # Support for legacy targets having a name starting with 'debug-'
1069 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1070 if ($d) {
1071     $config{build_type} = "debug";
1072
1073     # If we do not find debug-foo in the table, the target is set to foo.
1074     if (!$table{$target}) {
1075         $target = $t;
1076     }
1077 }
1078
1079 &usage if !$table{$target} || $table{$target}->{template};
1080
1081 $config{target} = $target;
1082 my %target = resolve_config($target);
1083
1084 foreach (keys %target_attr_translate) {
1085     $target{$target_attr_translate{$_}} = $target{$_}
1086         if $target{$_};
1087     delete $target{$_};
1088 }
1089
1090 %target = ( %{$table{DEFAULTS}}, %target );
1091
1092 # Make the flags to build DSOs the same as for shared libraries unless they
1093 # are already defined
1094 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1095 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1096 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1097 {
1098     my $shared_info_pl =
1099         catfile(dirname($0), "Configurations", "shared-info.pl");
1100     my %shared_info = read_eval_file($shared_info_pl);
1101     push @{$target{_conf_fname_int}}, $shared_info_pl;
1102     my $si = $target{shared_target};
1103     while (ref $si ne "HASH") {
1104         last if ! defined $si;
1105         if (ref $si eq "CODE") {
1106             $si = $si->();
1107         } else {
1108             $si = $shared_info{$si};
1109         }
1110     }
1111
1112     # Some of the 'shared_target' values don't have any entried in
1113     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1114     # template knows how to handle this.  That is currently the case for
1115     # Windows and VMS.
1116     if (defined $si) {
1117         # Just as above, copy certain shared_* attributes to the corresponding
1118         # module_ attribute unless the latter is already defined
1119         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1120         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1121         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1122         foreach (sort keys %$si) {
1123             $target{$_} = defined $target{$_}
1124                 ? add($si->{$_})->($target{$_})
1125                 : $si->{$_};
1126         }
1127     }
1128 }
1129
1130 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1131 $config{conf_files} = [ sort keys %conf_files ];
1132
1133 foreach my $feature (@{$target{disable}}) {
1134     if (exists $deprecated_disablables{$feature}) {
1135         warn "***** config $target disables deprecated feature $feature\n";
1136     } elsif (!grep { $feature eq $_ } @disablables) {
1137         die "***** config $target disables unknown feature $feature\n";
1138     }
1139     $disabled{$feature} = 'config';
1140 }
1141 foreach my $feature (@{$target{enable}}) {
1142     if ("default" eq ($disabled{$feature} // "")) {
1143         if (exists $deprecated_disablables{$feature}) {
1144             warn "***** config $target enables deprecated feature $feature\n";
1145         } elsif (!grep { $feature eq $_ } @disablables) {
1146             die "***** config $target enables unknown feature $feature\n";
1147         }
1148         delete $disabled{$feature};
1149     }
1150 }
1151
1152 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1153 $target{cxxflags}//=$target{cflags} if $target{CXX};
1154 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1155 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1156
1157 # Fill %config with values from %user, and in case those are undefined or
1158 # empty, use values from %target (acting as a default).
1159 foreach (keys %user) {
1160     my $ref_type = ref $user{$_};
1161
1162     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1163     # and a value that's to be coerced into that type.
1164     my $mkvalue = sub {
1165         my $type = shift;
1166         my $value = shift;
1167         my $undef_p = shift;
1168
1169         die "Too many arguments for \$mkvalue" if @_;
1170
1171         while (ref $value eq 'CODE') {
1172             $value = $value->();
1173         }
1174
1175         if ($type eq 'ARRAY') {
1176             return undef unless defined $value;
1177             return undef if ref $value ne 'ARRAY' && !$value;
1178             return undef if ref $value eq 'ARRAY' && !@$value;
1179             return [ $value ] unless ref $value eq 'ARRAY';
1180         }
1181         return undef unless $value;
1182         return $value;
1183     };
1184
1185     $config{$_} =
1186         $mkvalue->($ref_type, $user{$_})
1187         || $mkvalue->($ref_type, $target{$_});
1188     delete $config{$_} unless defined $config{$_};
1189 }
1190
1191 # Allow overriding the build file name
1192 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1193
1194 ######################################################################
1195 # Build up information for skipping certain directories depending on disabled
1196 # features, as well as setting up macros for disabled features.
1197
1198 # This is a tentative database of directories to skip.  Some entries may not
1199 # correspond to anything real, but that's ok, they will simply be ignored.
1200 # The actual processing of these entries is done in the build.info lookup
1201 # loop further down.
1202 #
1203 # The key is a Unix formated path in the source tree, the value is an index
1204 # into %disabled_info, so any existing path gets added to a corresponding
1205 # 'skipped' entry in there with the list of skipped directories.
1206 my %skipdir = ();
1207 my %disabled_info = ();         # For configdata.pm
1208 foreach my $what (sort keys %disabled) {
1209     # There are deprecated disablables that translate to themselves.
1210     # They cause disabling cascades, but should otherwise not regiter.
1211     next if $deprecated_disablables{$what};
1212
1213     $config{options} .= " no-$what";
1214
1215     if (!grep { $what eq $_ } ( 'buildtest-c++', 'dso', 'threads', 'shared',
1216                                 'pic', 'dynamic-engine', 'makedepend',
1217                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1218         (my $WHAT = uc $what) =~ s|-|_|g;
1219         my $skipdir = $what;
1220
1221         # fix-up crypto/directory name(s)
1222         $skipdir = "ripemd" if $what eq "rmd160";
1223         $skipdir = "whrlpool" if $what eq "whirlpool";
1224
1225         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1226         push @{$config{openssl_feature_defines}}, $macro;
1227
1228         $skipdir{engines} = $what if $what eq 'engine';
1229         $skipdir{"crypto/$skipdir"} = $what
1230             unless $what eq 'async' || $what eq 'err';
1231     }
1232 }
1233
1234 # Make sure build_scheme is consistent.
1235 $target{build_scheme} = [ $target{build_scheme} ]
1236     if ref($target{build_scheme}) ne "ARRAY";
1237
1238 my ($builder, $builder_platform, @builder_opts) =
1239     @{$target{build_scheme}};
1240
1241 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1242                       $builder_platform."-checker.pm")) {
1243     my $checker_path = catfile($srcdir, "Configurations", $checker);
1244     if (-f $checker_path) {
1245         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1246             ? sub { warn $@; } : sub { die $@; };
1247         if (! do $checker_path) {
1248             if ($@) {
1249                 $fn->($@);
1250             } elsif ($!) {
1251                 $fn->($!);
1252             } else {
1253                 $fn->("The detected tools didn't match the platform\n");
1254             }
1255         }
1256         last;
1257     }
1258 }
1259
1260 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1261
1262 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1263         {
1264         push @{$config{cflags}}, "-mno-cygwin";
1265         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1266         push @{$config{shared_ldflag}}, "-mno-cygwin";
1267         }
1268
1269 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1270         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1271                                             @{$useradd{CFLAGS}})) {
1272         # minimally required architecture flags for assembly modules
1273         my $value;
1274         $value = '-mips2' if ($target =~ /mips32/);
1275         $value = '-mips3' if ($target =~ /mips64/);
1276         unshift @{$config{cflags}}, $value;
1277         unshift @{$config{cxxflags}}, $value if $config{CXX};
1278 }
1279
1280 # If threads aren't disabled, check how possible they are
1281 unless ($disabled{threads}) {
1282     if ($auto_threads) {
1283         # Enabled by default, disable it forcibly if unavailable
1284         if ($target{thread_scheme} eq "(unknown)") {
1285             $disabled{threads} = "unavailable";
1286         }
1287     } else {
1288         # The user chose to enable threads explicitly, let's see
1289         # if there's a chance that's possible
1290         if ($target{thread_scheme} eq "(unknown)") {
1291             # If the user asked for "threads" and we don't have internal
1292             # knowledge how to do it, [s]he is expected to provide any
1293             # system-dependent compiler options that are necessary.  We
1294             # can't truly check that the given options are correct, but
1295             # we expect the user to know what [s]He is doing.
1296             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1297                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1298                 die "You asked for multi-threading support, but didn't\n"
1299                     ,"provide any system-specific compiler options\n";
1300             }
1301         }
1302     }
1303 }
1304
1305 # If threads still aren't disabled, add a C macro to ensure the source
1306 # code knows about it.  Any other flag is taken care of by the configs.
1307 unless($disabled{threads}) {
1308     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1309 }
1310
1311 # With "deprecated" disable all deprecated features.
1312 if (defined($disabled{"deprecated"})) {
1313         $config{api} = $maxapi;
1314 }
1315
1316 my $no_shared_warn=0;
1317 if ($target{shared_target} eq "")
1318         {
1319         $no_shared_warn = 1
1320             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1321         $disabled{shared} = "no-shared-target";
1322         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1323             "no-shared-target";
1324         }
1325
1326 if ($disabled{"dynamic-engine"}) {
1327         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1328         $config{dynamic_engines} = 0;
1329 } else {
1330         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1331         $config{dynamic_engines} = 1;
1332 }
1333
1334 unless ($disabled{asan}) {
1335     push @{$config{cflags}}, "-fsanitize=address";
1336     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1337 }
1338
1339 unless ($disabled{ubsan}) {
1340     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1341     # platforms.
1342     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1343     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1344         if $config{CXX};
1345 }
1346
1347 unless ($disabled{msan}) {
1348   push @{$config{cflags}}, "-fsanitize=memory";
1349   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1350 }
1351
1352 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1353         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1354     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1355     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1356 }
1357 #
1358 # Platform fix-ups
1359 #
1360
1361 # This saves the build files from having to check
1362 if ($disabled{pic})
1363         {
1364         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1365                     shared_defines shared_includes shared_ldflag
1366                     module_cflags module_cxxflags module_cppflags
1367                     module_defines module_includes module_lflags))
1368                 {
1369                 delete $config{$_};
1370                 $target{$_} = "";
1371                 }
1372         }
1373 else
1374         {
1375         push @{$config{lib_defines}}, "OPENSSL_PIC";
1376         }
1377
1378 if ($target{sys_id} ne "")
1379         {
1380         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1381         }
1382
1383 unless ($disabled{asm}) {
1384     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1385     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1386
1387     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1388
1389     # bn-586 is the only one implementing bn_*_part_words
1390     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1391     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1392
1393     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1394     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1395     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1396     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1397
1398     if ($target{sha1_asm_src}) {
1399         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1400         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1401         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1402     }
1403     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1404         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1405     }
1406     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1407         push @{$config{lib_defines}}, "RC4_ASM";
1408     }
1409     if ($target{md5_asm_src}) {
1410         push @{$config{lib_defines}}, "MD5_ASM";
1411     }
1412     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1413     if ($target{rmd160_asm_src}) {
1414         push @{$config{lib_defines}}, "RMD160_ASM";
1415     }
1416     if ($target{aes_asm_src}) {
1417         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1418         # aes-ctr.fake is not a real file, only indication that assembler
1419         # module implements AES_ctr32_encrypt...
1420         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1421         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1422         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1423         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1424         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1425         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1426     }
1427     if ($target{wp_asm_src} =~ /mmx/) {
1428         if ($config{processor} eq "386") {
1429             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1430         } elsif (!$disabled{"whirlpool"}) {
1431             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1432         }
1433     }
1434     if ($target{modes_asm_src} =~ /ghash-/) {
1435         push @{$config{lib_defines}}, "GHASH_ASM";
1436     }
1437     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1438         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1439     }
1440     if ($target{ec_asm_src} =~ /x25519/) {
1441         push @{$config{lib_defines}}, "X25519_ASM";
1442     }
1443     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1444         push @{$config{dso_defines}}, "PADLOCK_ASM";
1445     }
1446     if ($target{poly1305_asm_src} ne "") {
1447         push @{$config{lib_defines}}, "POLY1305_ASM";
1448     }
1449 }
1450
1451 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1452 my %predefined_CXX = $config{CXX}
1453     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1454     : ();
1455
1456 # Check for makedepend capabilities.
1457 if (!$disabled{makedepend}) {
1458     if ($config{target} =~ /^(VC|vms)-/) {
1459         # For VC- and vms- targets, there's nothing more to do here.  The
1460         # functionality is hard coded in the corresponding build files for
1461         # cl (Windows) and CC/DECC (VMS).
1462     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1463              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1464         # We know that GNU C version 3 and up as well as all clang
1465         # versions support dependency generation, but Xcode did not
1466         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1467         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1468     } else {
1469         # In all other cases, we look for 'makedepend', and disable the
1470         # capability if not found.
1471         $config{makedepprog} = which('makedepend');
1472         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1473     }
1474 }
1475
1476 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1477     # probe for -Wa,--noexecstack option...
1478     if ($predefined_C{__clang__}) {
1479         # clang has builtin assembler, which doesn't recognize --help,
1480         # but it apparently recognizes the option in question on all
1481         # supported platforms even when it's meaningless. In other words
1482         # probe would fail, but probed option always accepted...
1483         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1484     } else {
1485         my $cc = $config{CROSS_COMPILE}.$config{CC};
1486         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1487         while(<PIPE>) {
1488             if (m/--noexecstack/) {
1489                 push @{$config{cflags}}, "-Wa,--noexecstack";
1490                 last;
1491             }
1492         }
1493         close(PIPE);
1494         unlink("null.$$.o");
1495     }
1496 }
1497
1498 # Deal with bn_ops ###################################################
1499
1500 $config{bn_ll}                  =0;
1501 $config{export_var_as_fn}       =0;
1502 my $def_int="unsigned int";
1503 $config{rc4_int}                =$def_int;
1504 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1505
1506 my $count = 0;
1507 foreach (sort split(/\s+/,$target{bn_ops})) {
1508     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1509     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1510     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1511     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1512     ($config{b64l},$config{b64},$config{b32})
1513         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1514     ($config{b64l},$config{b64},$config{b32})
1515         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1516     ($config{b64l},$config{b64},$config{b32})
1517         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1518 }
1519 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1520     if $count > 1;
1521
1522
1523 # Hack cflags for better warnings (dev option) #######################
1524
1525 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1526 # a string and works as well on command lines.
1527 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1528                         @{$config{cflags}} ];
1529 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1530                           @{$config{cxxflags}} ] if $config{CXX};
1531
1532 $config{openssl_api_defines} = [
1533     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1534 ];
1535
1536 my %strict_warnings_collection=( CFLAGS => [], CXXFLAGS => []);
1537 if ($strict_warnings)
1538         {
1539         my $wopt;
1540         my $gccver = $predefined_C{__GNUC__} // -1;
1541         my $gxxver = $predefined_CXX{__GNUC__} // -1;
1542
1543         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1544             unless $gccver >= 4;
1545         warn "WARNING --strict-warnings requires g++[>=4] or g++-alike"
1546             unless $gxxver >= 4;
1547         foreach (qw(CFLAGS CXXFLAGS))
1548                 {
1549                 push @{$strict_warnings_collection{$_}},
1550                         @{$gcc_devteam_warn{$_}};
1551                 }
1552         push @{$strict_warnings_collection{CFLAGS}},
1553                 @{$clang_devteam_warn{CFLAGS}}
1554                         if (defined($predefined_C{__clang__}));
1555         push @{$strict_warnings_collection{CXXFLAGS}},
1556                 @{$clang_devteam_warn{CXXFLAGS}}
1557                         if (defined($predefined_CXX{__clang__}));
1558         }
1559 foreach my $idx (qw(CFLAGS CXXFLAGS))
1560         {
1561         $useradd{$idx} = [ map { $_ eq '--ossl-strict-warnings'
1562                                      ? @{$strict_warnings_collection{$idx}}
1563                                      : ( $_ ) }
1564                                @{$useradd{$idx}} ];
1565         }
1566
1567 unless ($disabled{"crypto-mdebug-backtrace"})
1568         {
1569         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1570                 {
1571                 push @{$config{cflags}}, $wopt
1572                         unless grep { $_ eq $wopt } @{$config{cflags}};
1573                 push @{$config{cxxflags}}, $wopt
1574                         if ($config{CXX}
1575                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1576                 }
1577         if ($target =~ /^BSD-/)
1578                 {
1579                 push @{$config{ex_libs}}, "-lexecinfo";
1580                 }
1581         }
1582
1583 unless ($disabled{afalgeng}) {
1584     $config{afalgeng}="";
1585     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1586         my $minver = 4*10000 + 1*100 + 0;
1587         if ($config{CROSS_COMPILE} eq "") {
1588             my $verstr = `uname -r`;
1589             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1590             ($mi2) = $mi2 =~ /(\d+)/;
1591             my $ver = $ma*10000 + $mi1*100 + $mi2;
1592             if ($ver < $minver) {
1593                 $disabled{afalgeng} = "too-old-kernel";
1594             } else {
1595                 push @{$config{engdirs}}, "afalg";
1596             }
1597         } else {
1598             $disabled{afalgeng} = "cross-compiling";
1599         }
1600     } else {
1601         $disabled{afalgeng}  = "not-linux";
1602     }
1603 }
1604
1605 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1606
1607 unless ($disabled{ktls}) {
1608     $config{ktls}="";
1609     if ($target =~ m/^linux/) {
1610         my $usr = "/usr/$config{cross_compile_prefix}";
1611         chop($usr);
1612         if ($config{cross_compile_prefix} eq "") {
1613             $usr = "/usr";
1614         }
1615         my $minver = (4 << 16) + (13 << 8) + 0;
1616         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1617
1618         if ($verstr[2] < $minver) {
1619             $disabled{ktls} = "too-old-kernel";
1620         }
1621     } else {
1622         $disabled{ktls}  = "not-linux";
1623     }
1624 }
1625
1626 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1627
1628 # Finish up %config by appending things the user gave us on the command line
1629 # apart from "make variables"
1630 foreach (keys %useradd) {
1631     # The must all be lists, so we assert that here
1632     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1633         unless ref $useradd{$_} eq 'ARRAY';
1634
1635     if (defined $config{$_}) {
1636         push @{$config{$_}}, @{$useradd{$_}};
1637     } else {
1638         $config{$_} = [ @{$useradd{$_}} ];
1639     }
1640 }
1641
1642 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1643
1644 # If we use the unified build, collect information from build.info files
1645 my %unified_info = ();
1646
1647 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1648 if ($builder eq "unified") {
1649     use with_fallback qw(Text::Template);
1650
1651     sub cleandir {
1652         my $base = shift;
1653         my $dir = shift;
1654         my $relativeto = shift || ".";
1655
1656         $dir = catdir($base,$dir) unless isabsolute($dir);
1657
1658         # Make sure the directories we're building in exists
1659         mkpath($dir);
1660
1661         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1662         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1663         return $res;
1664     }
1665
1666     sub cleanfile {
1667         my $base = shift;
1668         my $file = shift;
1669         my $relativeto = shift || ".";
1670
1671         $file = catfile($base,$file) unless isabsolute($file);
1672
1673         my $d = dirname($file);
1674         my $f = basename($file);
1675
1676         # Make sure the directories we're building in exists
1677         mkpath($d);
1678
1679         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1680         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1681         return $res;
1682     }
1683
1684     # Store the name of the template file we will build the build file from
1685     # in %config.  This may be useful for the build file itself.
1686     my @build_file_template_names =
1687         ( $builder_platform."-".$target{build_file}.".tmpl",
1688           $target{build_file}.".tmpl" );
1689     my @build_file_templates = ();
1690
1691     # First, look in the user provided directory, if given
1692     if (defined env($local_config_envname)) {
1693         @build_file_templates =
1694             map {
1695                 if ($^O eq 'VMS') {
1696                     # VMS environment variables are logical names,
1697                     # which can be used as is
1698                     $local_config_envname . ':' . $_;
1699                 } else {
1700                     catfile(env($local_config_envname), $_);
1701                 }
1702             }
1703             @build_file_template_names;
1704     }
1705     # Then, look in our standard directory
1706     push @build_file_templates,
1707         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1708           @build_file_template_names );
1709
1710     my $build_file_template;
1711     for $_ (@build_file_templates) {
1712         $build_file_template = $_;
1713         last if -f $build_file_template;
1714
1715         $build_file_template = undef;
1716     }
1717     if (!defined $build_file_template) {
1718         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1719     }
1720     $config{build_file_templates}
1721       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1722                     $blddir),
1723           $build_file_template,
1724           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1725                     $blddir) ];
1726
1727     my @build_dirs = ( [ ] );   # current directory
1728
1729     $config{build_infos} = [ ];
1730
1731     my %ordinals = ();
1732     while (@build_dirs) {
1733         my @curd = @{shift @build_dirs};
1734         my $sourced = catdir($srcdir, @curd);
1735         my $buildd = catdir($blddir, @curd);
1736
1737         my $unixdir = join('/', @curd);
1738         if (exists $skipdir{$unixdir}) {
1739             my $what = $skipdir{$unixdir};
1740             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1741             next;
1742         }
1743
1744         mkpath($buildd);
1745
1746         my $f = 'build.info';
1747         # The basic things we're trying to build
1748         my @programs = ();
1749         my @libraries = ();
1750         my @modules = ();
1751         my @scripts = ();
1752
1753         my %attributes = ();
1754         my %sources = ();
1755         my %shared_sources = ();
1756         my %includes = ();
1757         my %defines = ();
1758         my %depends = ();
1759         my %generate = ();
1760
1761         # We want to detect configdata.pm in the source tree, so we
1762         # don't use it if the build tree is different.
1763         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1764
1765         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1766         my $template =
1767             Text::Template->new(TYPE => 'FILE',
1768                                 SOURCE => catfile($sourced, $f),
1769                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1770         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1771         my @text =
1772             split /^/m,
1773             $template->fill_in(HASH => { config => \%config,
1774                                          target => \%target,
1775                                          disabled => \%disabled,
1776                                          withargs => \%withargs,
1777                                          builddir => abs2rel($buildd, $blddir),
1778                                          sourcedir => abs2rel($sourced, $blddir),
1779                                          buildtop => abs2rel($blddir, $blddir),
1780                                          sourcetop => abs2rel($srcdir, $blddir) },
1781                                DELIMITERS => [ "{-", "-}" ]);
1782
1783         # The top item of this stack has the following values
1784         # -2 positive already run and we found ELSE (following ELSIF should fail)
1785         # -1 positive already run (skip until ENDIF)
1786         # 0 negatives so far (if we're at a condition, check it)
1787         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1788         # 2 positive ELSE (following ELSIF should fail)
1789         my @skip = ();
1790         collect_information(
1791             collect_from_array([ @text ],
1792                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1793                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1794             # Info we're looking for
1795             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1796             => sub {
1797                 if (! @skip || $skip[$#skip] > 0) {
1798                     push @skip, !! $1;
1799                 } else {
1800                     push @skip, -1;
1801                 }
1802             },
1803             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1804             => sub { die "ELSIF out of scope" if ! @skip;
1805                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1806                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1807                      $skip[$#skip] = !! $1
1808                          if $skip[$#skip] == 0; },
1809             qr/^\s*ELSE\s*$/
1810             => sub { die "ELSE out of scope" if ! @skip;
1811                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1812                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1813             qr/^\s*ENDIF\s*$/
1814             => sub { die "ENDIF out of scope" if ! @skip;
1815                      pop @skip; },
1816             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1817             => sub {
1818                 if (!@skip || $skip[$#skip] > 0) {
1819                     foreach (tokenize($1)) {
1820                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1821                     }
1822                 }
1823             },
1824             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1825             => sub {
1826                 if (!@skip || $skip[$#skip] > 0) {
1827                     my @a = tokenize($1, qr|\s*,\s*|);
1828                     my @p = tokenize($2);
1829                     push @programs, @p;
1830                     foreach my $a (@a) {
1831                         my $ak = $a;
1832                         my $av = 1;
1833                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1834                             $ak = $1;
1835                             $av = $2;
1836                         }
1837                         foreach my $p (@p) {
1838                             $attributes{$p}->{$ak} = $av;
1839                         }
1840                     }
1841                 }
1842             },
1843             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1844             => sub {
1845                 if (!@skip || $skip[$#skip] > 0) {
1846                     my @a = tokenize($1, qr|\s*,\s*|);
1847                     my @l = tokenize($2);
1848                     push @libraries, @l;
1849                     foreach my $a (@a) {
1850                         my $ak = $a;
1851                         my $av = 1;
1852                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1853                             $ak = $1;
1854                             $av = $2;
1855                         }
1856                         foreach my $l (@l) {
1857                             $attributes{$l}->{$ak} = $av;
1858                         }
1859                     }
1860                 }
1861             },
1862             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1863             => sub {
1864                 if (!@skip || $skip[$#skip] > 0) {
1865                     my @a = tokenize($1, qr|\s*,\s*|);
1866                     my @m = tokenize($2);
1867                     push @modules, @m;
1868                     foreach my $a (@a) {
1869                         my $ak = $a;
1870                         my $av = 1;
1871                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1872                             $ak = $1;
1873                             $av = $2;
1874                         }
1875                         foreach my $m (@m) {
1876                             $attributes{$m}->{$ak} = $av;
1877                         }
1878                     }
1879                 }
1880             },
1881             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1882             => sub {
1883                 if (!@skip || $skip[$#skip] > 0) {
1884                     my @a = tokenize($1, qr|\s*,\s*|);
1885                     my @s = tokenize($2);
1886                     push @scripts, @s;
1887                     foreach my $a (@a) {
1888                         my $ak = $a;
1889                         my $av = 1;
1890                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1891                             $ak = $1;
1892                             $av = $2;
1893                         }
1894                         foreach my $s (@s) {
1895                             $attributes{$s}->{$ak} = $av;
1896                         }
1897                     }
1898                 }
1899             },
1900
1901             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1902             => sub { push @{$ordinals{$1}}, tokenize($2)
1903                          if !@skip || $skip[$#skip] > 0 },
1904             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1905             => sub { push @{$sources{$1}}, tokenize($2)
1906                          if !@skip || $skip[$#skip] > 0 },
1907             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1908             => sub { push @{$shared_sources{$1}}, tokenize($2)
1909                          if !@skip || $skip[$#skip] > 0 },
1910             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1911             => sub { push @{$includes{$1}}, tokenize($2)
1912                          if !@skip || $skip[$#skip] > 0 },
1913             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1914             => sub { push @{$defines{$1}}, tokenize($2)
1915                          if !@skip || $skip[$#skip] > 0 },
1916             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1917             => sub { push @{$depends{$1}}, tokenize($2)
1918                          if !@skip || $skip[$#skip] > 0 },
1919             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1920             => sub { push @{$generate{$1}}, $2
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*(?:#.*)?$/ => sub { },
1923             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1924             "BEFORE" => sub {
1925                 if ($buildinfo_debug) {
1926                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1927                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1928                 }
1929             },
1930             "AFTER" => sub {
1931                 if ($buildinfo_debug) {
1932                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1933                 }
1934             },
1935             );
1936         die "runaway IF?" if (@skip);
1937
1938         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1939                 and !$config{dynamic_engines}) {
1940             die <<"EOF"
1941 ENGINES can only be used if configured with 'dynamic-engine'.
1942 This is usually a fault in a build.info file.
1943 EOF
1944         }
1945
1946         foreach (keys %attributes) {
1947             my $dest = $_;
1948             my $ddest = cleanfile($buildd, $_, $blddir);
1949             foreach (keys %{$attributes{$dest} // {}}) {
1950                 $unified_info{attributes}->{$ddest}->{$_} =
1951                     $attributes{$dest}->{$_};
1952             }
1953         }
1954
1955         {
1956             my %infos = ( programs  => [ @programs  ],
1957                           libraries => [ @libraries ],
1958                           modules   => [ @modules   ],
1959                           scripts   => [ @scripts   ] );
1960             foreach my $k (keys %infos) {
1961                 foreach (@{$infos{$k}}) {
1962                     my $item = cleanfile($buildd, $_, $blddir);
1963                     $unified_info{$k}->{$item} = 1;
1964                 }
1965             }
1966         }
1967
1968         # Check that we haven't defined any library as both shared and
1969         # explicitly static.  That is forbidden.
1970         my @doubles = ();
1971         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1972             (my $l = $_) =~ s/\.a$//;
1973             push @doubles, $l if defined $unified_info{libraries}->{$l};
1974         }
1975         die "these libraries are both explicitly static and shared:\n  ",
1976             join(" ", @doubles), "\n"
1977             if @doubles;
1978
1979         foreach (keys %sources) {
1980             my $dest = $_;
1981             my $ddest = cleanfile($buildd, $_, $blddir);
1982             foreach (@{$sources{$dest}}) {
1983                 my $s = cleanfile($sourced, $_, $blddir);
1984
1985                 # If it isn't in the source tree, we assume it's generated
1986                 # in the build tree
1987                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1988                     $s = cleanfile($buildd, $_, $blddir);
1989                 }
1990                 # We recognise C++, C and asm files
1991                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1992                     my $o = $_;
1993                     $o =~ s/\.[csS]$/.o/; # C and assembler
1994                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1995                     $o = cleanfile($buildd, $o, $blddir);
1996                     $unified_info{sources}->{$ddest}->{$o} = -1;
1997                     $unified_info{sources}->{$o}->{$s} = -1;
1998                 } elsif ($s =~ /\.rc$/) {
1999                     # We also recognise resource files
2000                     my $o = $_;
2001                     $o =~ s/\.rc$/.res/; # Resource configuration
2002                     my $o = cleanfile($buildd, $o, $blddir);
2003                     $unified_info{sources}->{$ddest}->{$o} = -1;
2004                     $unified_info{sources}->{$o}->{$s} = -1;
2005                 } else {
2006                     $unified_info{sources}->{$ddest}->{$s} = 1;
2007                 }
2008             }
2009         }
2010
2011         foreach (keys %shared_sources) {
2012             my $dest = $_;
2013             my $ddest = cleanfile($buildd, $_, $blddir);
2014             foreach (@{$shared_sources{$dest}}) {
2015                 my $s = cleanfile($sourced, $_, $blddir);
2016
2017                 # If it isn't in the source tree, we assume it's generated
2018                 # in the build tree
2019                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2020                     $s = cleanfile($buildd, $_, $blddir);
2021                 }
2022
2023                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2024                     # We recognise C++, C and asm files
2025                     my $o = $_;
2026                     $o =~ s/\.[csS]$/.o/; # C and assembler
2027                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2028                     $o = cleanfile($buildd, $o, $blddir);
2029                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2030                     $unified_info{sources}->{$o}->{$s} = -1;
2031                 } elsif ($s =~ /\.rc$/) {
2032                     # We also recognise resource files
2033                     my $o = $_;
2034                     $o =~ s/\.rc$/.res/; # Resource configuration
2035                     my $o = cleanfile($buildd, $o, $blddir);
2036                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2037                     $unified_info{sources}->{$o}->{$s} = -1;
2038                 } elsif ($s =~ /\.ld$/) {
2039                     # We also recognise linker scripts (or corresponding)
2040                     # We know they are generated files
2041                     my $ld = cleanfile($buildd, $_, $blddir);
2042                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2043                 } else {
2044                     die "unrecognised source file type for shared library: $s\n";
2045                 }
2046             }
2047         }
2048
2049         foreach (keys %generate) {
2050             my $dest = $_;
2051             my $ddest = cleanfile($buildd, $_, $blddir);
2052             die "more than one generator for $dest: "
2053                     ,join(" ", @{$generate{$_}}),"\n"
2054                     if scalar @{$generate{$_}} > 1;
2055             my @generator = split /\s+/, $generate{$dest}->[0];
2056             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2057             $unified_info{generate}->{$ddest} = [ @generator ];
2058         }
2059
2060         foreach (keys %depends) {
2061             my $dest = $_;
2062             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2063
2064             # If the destination doesn't exist in source, it can only be
2065             # a generated file in the build tree.
2066             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2067                 $ddest = cleanfile($buildd, $_, $blddir);
2068             }
2069             foreach (@{$depends{$dest}}) {
2070                 my $d = cleanfile($sourced, $_, $blddir);
2071
2072                 # If we know it's generated, or assume it is because we can't
2073                 # find it in the source tree, we set file we depend on to be
2074                 # in the build tree rather than the source tree, and assume
2075                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2076                 # section or in the Makefile template.
2077                 if ($d eq $src_configdata
2078                     || ! -f $d
2079                     || (grep { $d eq $_ }
2080                         map { cleanfile($srcdir, $_, $blddir) }
2081                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2082                     $d = cleanfile($buildd, $_, $blddir);
2083                 }
2084                 # Take note if the file to depend on is being renamed
2085                 # Take extra care with files ending with .a, they should
2086                 # be treated without that extension, and the extension
2087                 # should be added back after treatment.
2088                 $d =~ /(\.a)?$/;
2089                 my $e = $1 // "";
2090                 $d = $`.$e;
2091                 $unified_info{depends}->{$ddest}->{$d} = 1;
2092             }
2093         }
2094
2095         foreach (keys %includes) {
2096             my $dest = $_;
2097             my $ddest = cleanfile($sourced, $_, $blddir);
2098
2099             # If the destination doesn't exist in source, it can only be
2100             # a generated file in the build tree.
2101             if ($ddest eq $src_configdata || ! -f $ddest) {
2102                 $ddest = cleanfile($buildd, $_, $blddir);
2103             }
2104             foreach (@{$includes{$dest}}) {
2105                 my $is = cleandir($sourced, $_, $blddir);
2106                 my $ib = cleandir($buildd, $_, $blddir);
2107                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2108                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2109                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2110                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2111             }
2112         }
2113
2114         foreach (keys %defines) {
2115             my $dest = $_;
2116             my $ddest = cleanfile($sourced, $_, $blddir);
2117
2118             # If the destination doesn't exist in source, it can only be
2119             # a generated file in the build tree.
2120             if (! -f $ddest) {
2121                 $ddest = cleanfile($buildd, $_, $blddir);
2122                 if ($unified_info{rename}->{$ddest}) {
2123                     $ddest = $unified_info{rename}->{$ddest};
2124                 }
2125             }
2126             foreach (@{$defines{$dest}}) {
2127                 m|^([^=]*)(=.*)?$|;
2128                 die "0 length macro name not permitted\n" if $1 eq "";
2129                 die "$1 defined more than once\n"
2130                     if defined $unified_info{defines}->{$ddest}->{$1};
2131                 $unified_info{defines}->{$ddest}->{$1} = $2;
2132             }
2133         }
2134     }
2135
2136     my $ordinals_text = join(', ', sort keys %ordinals);
2137     warn <<"EOF" if $ordinals_text;
2138
2139 WARNING: ORDINALS were specified for $ordinals_text
2140 They are ignored and should be replaced with a combination of GENERATE,
2141 DEPEND and SHARED_SOURCE.
2142 EOF
2143
2144     # Massage the result
2145
2146     # If we depend on a header file or a perl module, add an inclusion of
2147     # its directory to allow smoothe inclusion
2148     foreach my $dest (keys %{$unified_info{depends}}) {
2149         next if $dest eq "";
2150         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2151             next unless $d =~ /\.(h|pm)$/;
2152             my $i = dirname($d);
2153             my $spot =
2154                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2155                 ? 'build' : 'source';
2156             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2157                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2158         }
2159     }
2160
2161     # Go through all intermediary files and change their names to something that
2162     # reflects what they will be built for.  Note that for some source files,
2163     # this leads to duplicate object files because they are used multiple times.
2164     # the goal is to rename all object files according to this scheme:
2165     #    {productname}-{midfix}-{origobjname}.[o|res]
2166     # the {midfix} is a keyword indicating the type of product, which is mostly
2167     # valuable for libraries since they come in two forms.
2168     #
2169     # This also reorganises the {sources} and {shared_sources} so that the
2170     # former only contains ALL object files that are supposed to end up in
2171     # static libraries and programs, while the latter contains ALL object files
2172     # that are supposed to end up in shared libraries and DSOs.
2173     # The main reason for having two different source structures is to allow
2174     # the same name to be used for the static and the shared variants of a
2175     # library.
2176     {
2177         # Take copies so we don't get interference from added stuff
2178         my %unified_copy = ();
2179         foreach (('sources', 'shared_sources')) {
2180             $unified_copy{$_} = { %{$unified_info{$_}} }
2181                 if defined($unified_info{$_});
2182             delete $unified_info{$_};
2183         }
2184         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2185             # $intent serves multi purposes:
2186             # - give a prefix for the new object files names
2187             # - in the case of libraries, rearrange the object files so static
2188             #   libraries use the 'sources' structure exclusively, while shared
2189             #   libraries use the 'shared_sources' structure exclusively.
2190             my $intent = {
2191                 programs  => { bin    => { src => [ 'sources' ],
2192                                            dst => 'sources' } },
2193                 libraries => { lib    => { src => [ 'sources' ],
2194                                            dst => 'sources' },
2195                                shlib  => { prodselect =>
2196                                                sub { grep !/\.a$/, @_ },
2197                                            src => [ 'sources',
2198                                                     'shared_sources' ],
2199                                            dst => 'shared_sources' } },
2200                 modules   => { dso    => { src => [ 'sources',
2201                                                     'shared_sources' ],
2202                                            dst => 'shared_sources' } },
2203                 scripts   => { script => { src => [ 'sources' ],
2204                                            dst => 'sources' } }
2205                } -> {$prodtype};
2206             foreach my $kind (keys %$intent) {
2207                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2208                              && $disabled{shared});
2209
2210                 my @src = @{$intent->{$kind}->{src}};
2211                 my $dst = $intent->{$kind}->{dst};
2212                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2213                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2214                     # %prod_sources has all applicable objects as keys, and
2215                     # their corresponding sources as values
2216                     my %prod_sources =
2217                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2218                         map { keys %{$unified_copy{$_}->{$prod}} }
2219                         @src;
2220                     foreach (keys %prod_sources) {
2221                         # Only affect object files and resource files,
2222                         # the others simply get a new value
2223                         # (+1 instead of -1)
2224                         if ($_ =~ /\.(o|res)$/) {
2225                             (my $prodname = $prod) =~ s|\.a$||;
2226                             my $newobj =
2227                                 catfile(dirname($_),
2228                                         basename($prodname)
2229                                             . '-' . $kind
2230                                             . '-' . basename($_));
2231                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2232                             foreach my $src (@{$prod_sources{$_}}) {
2233                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2234                             }
2235                             # Adjust dependencies
2236                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2237                                 $unified_info{depends}->{$_}->{$deps} = -1;
2238                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2239                             }
2240                             # Adjust includes
2241                             foreach my $k (('source', 'build')) {
2242                                 next unless
2243                                     defined($unified_info{includes}->{$_}->{$k});
2244                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2245                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2246                             }
2247                         } else {
2248                             $unified_info{$dst}->{$prod}->{$_} = 1;
2249                         }
2250                     }
2251                 }
2252             }
2253         }
2254     }
2255     # At this point, we have a number of sources with the value -1.  They
2256     # aren't part of the local build and are probably meant for a different
2257     # platform, and can therefore be cleaned away.  That happens when making
2258     # %unified_info more efficient below.
2259
2260     ### Make unified_info a bit more efficient
2261     # One level structures
2262     foreach (("programs", "libraries", "modules", "scripts")) {
2263         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2264     }
2265     # Two level structures
2266     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2267         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2268             my @items =
2269                 sort
2270                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2271                 keys %{$unified_info{$l1}->{$l2}};
2272             if (@items) {
2273                 $unified_info{$l1}->{$l2} = [ @items ];
2274             } else {
2275                 delete $unified_info{$l1}->{$l2};
2276             }
2277         }
2278     }
2279     # Defines
2280     foreach my $dest (sort keys %{$unified_info{defines}}) {
2281         $unified_info{defines}->{$dest}
2282             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2283                 sort keys %{$unified_info{defines}->{$dest}} ];
2284     }
2285     # Includes
2286     foreach my $dest (sort keys %{$unified_info{includes}}) {
2287         if (defined($unified_info{includes}->{$dest}->{build})) {
2288             my @source_includes = ();
2289             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2290                 if defined($unified_info{includes}->{$dest}->{source});
2291             $unified_info{includes}->{$dest} =
2292                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2293             foreach my $inc (@source_includes) {
2294                 push @{$unified_info{includes}->{$dest}}, $inc
2295                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2296             }
2297         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2298             $unified_info{includes}->{$dest} =
2299                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2300         } else {
2301             delete $unified_info{includes}->{$dest};
2302         }
2303     }
2304
2305     # For convenience collect information regarding directories where
2306     # files are generated, those generated files and the end product
2307     # they end up in where applicable.  Then, add build rules for those
2308     # directories
2309     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2310                      "dso" => [ @{$unified_info{modules}} ],
2311                      "bin" => [ @{$unified_info{programs}} ],
2312                      "script" => [ @{$unified_info{scripts}} ] );
2313     foreach my $type (keys %loopinfo) {
2314         foreach my $product (@{$loopinfo{$type}}) {
2315             my %dirs = ();
2316             my $pd = dirname($product);
2317
2318             foreach (@{$unified_info{sources}->{$product} // []},
2319                      @{$unified_info{shared_sources}->{$product} // []}) {
2320                 my $d = dirname($_);
2321
2322                 # We don't want to create targets for source directories
2323                 # when building out of source
2324                 next if ($config{sourcedir} ne $config{builddir}
2325                              && $d =~ m|^\Q$config{sourcedir}\E|);
2326                 # We already have a "test" target, and the current directory
2327                 # is just silly to make a target for
2328                 next if $d eq "test" || $d eq ".";
2329
2330                 $dirs{$d} = 1;
2331                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2332                     if $d ne $pd;
2333             }
2334             foreach (keys %dirs) {
2335                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2336                     $product;
2337             }
2338         }
2339     }
2340 }
2341
2342 # For the schemes that need it, we provide the old *_obj configs
2343 # from the *_asm_obj ones
2344 foreach (grep /_(asm|aux)_src$/, keys %target) {
2345     my $src = $_;
2346     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2347     $target{$obj} = $target{$src};
2348     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2349     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2350 }
2351
2352 # Write down our configuration where it fits #########################
2353
2354 print "Creating configdata.pm\n";
2355 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2356 print OUT <<"EOF";
2357 #! $config{HASHBANGPERL}
2358
2359 package configdata;
2360
2361 use strict;
2362 use warnings;
2363
2364 use Exporter;
2365 #use vars qw(\@ISA \@EXPORT);
2366 our \@ISA = qw(Exporter);
2367 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2368
2369 EOF
2370 print OUT "our %config = (\n";
2371 foreach (sort keys %config) {
2372     if (ref($config{$_}) eq "ARRAY") {
2373         print OUT "  ", $_, " => [ ", join(", ",
2374                                            map { quotify("perl", $_) }
2375                                            @{$config{$_}}), " ],\n";
2376     } elsif (ref($config{$_}) eq "HASH") {
2377         print OUT "  ", $_, " => {";
2378         if (scalar keys %{$config{$_}} > 0) {
2379             print OUT "\n";
2380             foreach my $key (sort keys %{$config{$_}}) {
2381                 print OUT "      ",
2382                     join(" => ",
2383                          quotify("perl", $key),
2384                          defined $config{$_}->{$key}
2385                              ? quotify("perl", $config{$_}->{$key})
2386                              : "undef");
2387                 print OUT ",\n";
2388             }
2389             print OUT "  ";
2390         }
2391         print OUT "},\n";
2392     } else {
2393         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2394     }
2395 }
2396 print OUT <<"EOF";
2397 );
2398
2399 EOF
2400 print OUT "our %target = (\n";
2401 foreach (sort keys %target) {
2402     if (ref($target{$_}) eq "ARRAY") {
2403         print OUT "  ", $_, " => [ ", join(", ",
2404                                            map { quotify("perl", $_) }
2405                                            @{$target{$_}}), " ],\n";
2406     } else {
2407         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2408     }
2409 }
2410 print OUT <<"EOF";
2411 );
2412
2413 EOF
2414 print OUT "our \%available_protocols = (\n";
2415 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2416 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2417 print OUT <<"EOF";
2418 );
2419
2420 EOF
2421 print OUT "our \@disablables = (\n";
2422 foreach (@disablables) {
2423     print OUT "  ", quotify("perl", $_), ",\n";
2424 }
2425 print OUT <<"EOF";
2426 );
2427
2428 EOF
2429 print OUT "our \%disabled = (\n";
2430 foreach (sort keys %disabled) {
2431     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2432 }
2433 print OUT <<"EOF";
2434 );
2435
2436 EOF
2437 print OUT "our %withargs = (\n";
2438 foreach (sort keys %withargs) {
2439     if (ref($withargs{$_}) eq "ARRAY") {
2440         print OUT "  ", $_, " => [ ", join(", ",
2441                                            map { quotify("perl", $_) }
2442                                            @{$withargs{$_}}), " ],\n";
2443     } else {
2444         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2445     }
2446 }
2447 print OUT <<"EOF";
2448 );
2449
2450 EOF
2451 if ($builder eq "unified") {
2452     my $recurse;
2453     $recurse = sub {
2454         my $indent = shift;
2455         foreach (@_) {
2456             if (ref $_ eq "ARRAY") {
2457                 print OUT " "x$indent, "[\n";
2458                 foreach (@$_) {
2459                     $recurse->($indent + 4, $_);
2460                 }
2461                 print OUT " "x$indent, "],\n";
2462             } elsif (ref $_ eq "HASH") {
2463                 my %h = %$_;
2464                 print OUT " "x$indent, "{\n";
2465                 foreach (sort keys %h) {
2466                     if (ref $h{$_} eq "") {
2467                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2468                     } else {
2469                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2470                         $recurse->($indent + 8, $h{$_});
2471                     }
2472                 }
2473                 print OUT " "x$indent, "},\n";
2474             } else {
2475                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2476             }
2477         }
2478     };
2479     print OUT "our %unified_info = (\n";
2480     foreach (sort keys %unified_info) {
2481         if (ref $unified_info{$_} eq "") {
2482             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2483         } else {
2484             print OUT " "x4, quotify("perl", $_), " =>\n";
2485             $recurse->(8, $unified_info{$_});
2486         }
2487     }
2488     print OUT <<"EOF";
2489 );
2490
2491 EOF
2492 }
2493 print OUT
2494     "# The following data is only used when this files is use as a script\n";
2495 print OUT "my \@makevars = (\n";
2496 foreach (sort keys %user) {
2497     print OUT "    '",$_,"',\n";
2498 }
2499 print OUT ");\n";
2500 print OUT "my \%disabled_info = (\n";
2501 foreach my $what (sort keys %disabled_info) {
2502     print OUT "    '$what' => {\n";
2503     foreach my $info (sort keys %{$disabled_info{$what}}) {
2504         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2505             print OUT "        $info => [ ",
2506                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2507                 " ],\n";
2508         } else {
2509             print OUT "        $info => '", $disabled_info{$what}->{$info},
2510                 "',\n";
2511         }
2512     }
2513     print OUT "    },\n";
2514 }
2515 print OUT ");\n";
2516 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2517 print OUT << 'EOF';
2518 # If run directly, we can give some answers, and even reconfigure
2519 unless (caller) {
2520     use Getopt::Long;
2521     use File::Spec::Functions;
2522     use File::Basename;
2523     use Pod::Usage;
2524
2525     my $here = dirname($0);
2526
2527     my $dump = undef;
2528     my $cmdline = undef;
2529     my $options = undef;
2530     my $target = undef;
2531     my $envvars = undef;
2532     my $makevars = undef;
2533     my $buildparams = undef;
2534     my $reconf = undef;
2535     my $verbose = undef;
2536     my $help = undef;
2537     my $man = undef;
2538     GetOptions('dump|d'                 => \$dump,
2539                'command-line|c'         => \$cmdline,
2540                'options|o'              => \$options,
2541                'target|t'               => \$target,
2542                'environment|e'          => \$envvars,
2543                'make-variables|m'       => \$makevars,
2544                'build-parameters|b'     => \$buildparams,
2545                'reconfigure|reconf|r'   => \$reconf,
2546                'verbose|v'              => \$verbose,
2547                'help'                   => \$help,
2548                'man'                    => \$man)
2549         or die "Errors in command line arguments\n";
2550
2551     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2552             || $buildparams || $reconf || $verbose || $help || $man) {
2553         print STDERR <<"_____";
2554 You must give at least one option.
2555 For more information, do '$0 --help'
2556 _____
2557         exit(2);
2558     }
2559
2560     if ($help) {
2561         pod2usage(-exitval => 0,
2562                   -verbose => 1);
2563     }
2564     if ($man) {
2565         pod2usage(-exitval => 0,
2566                   -verbose => 2);
2567     }
2568     if ($dump || $cmdline) {
2569         print "\nCommand line (with current working directory = $here):\n\n";
2570         print '    ',join(' ',
2571                           $config{PERL},
2572                           catfile($config{sourcedir}, 'Configure'),
2573                           @{$config{perlargv}}), "\n";
2574         print "\nPerl information:\n\n";
2575         print '    ',$config{perl_cmd},"\n";
2576         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2577     }
2578     if ($dump || $options) {
2579         my $longest = 0;
2580         my $longest2 = 0;
2581         foreach my $what (@disablables) {
2582             $longest = length($what) if $longest < length($what);
2583             $longest2 = length($disabled{$what})
2584                 if $disabled{$what} && $longest2 < length($disabled{$what});
2585         }
2586         print "\nEnabled features:\n\n";
2587         foreach my $what (@disablables) {
2588             print "    $what\n" unless $disabled{$what};
2589         }
2590         print "\nDisabled features:\n\n";
2591         foreach my $what (@disablables) {
2592             if ($disabled{$what}) {
2593                 print "    $what", ' ' x ($longest - length($what) + 1),
2594                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2595                 print $disabled_info{$what}->{macro}
2596                     if $disabled_info{$what}->{macro};
2597                 print ' (skip ',
2598                     join(', ', @{$disabled_info{$what}->{skipped}}),
2599                     ')'
2600                     if $disabled_info{$what}->{skipped};
2601                 print "\n";
2602             }
2603         }
2604     }
2605     if ($dump || $target) {
2606         print "\nConfig target attributes:\n\n";
2607         foreach (sort keys %target) {
2608             next if $_ =~ m|^_| || $_ eq 'template';
2609             my $quotify = sub {
2610                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2611             };
2612             print '    ', $_, ' => ';
2613             if (ref($target{$_}) eq "ARRAY") {
2614                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2615             } else {
2616                 print $quotify->($target{$_}), ",\n"
2617             }
2618         }
2619     }
2620     if ($dump || $envvars) {
2621         print "\nRecorded environment:\n\n";
2622         foreach (sort keys %{$config{perlenv}}) {
2623             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2624         }
2625     }
2626     if ($dump || $makevars) {
2627         print "\nMakevars:\n\n";
2628         foreach my $var (@makevars) {
2629             my $prefix = '';
2630             $prefix = $config{CROSS_COMPILE}
2631                 if grep { $var eq $_ } @user_crossable;
2632             $prefix //= '';
2633             print '    ',$var,' ' x (16 - length $var),'= ',
2634                 (ref $config{$var} eq 'ARRAY'
2635                  ? join(' ', @{$config{$var}})
2636                  : $prefix.$config{$var}),
2637                 "\n"
2638                 if defined $config{$var};
2639         }
2640
2641         my @buildfile = ($config{builddir}, $config{build_file});
2642         unshift @buildfile, $here
2643             unless file_name_is_absolute($config{builddir});
2644         my $buildfile = canonpath(catdir(@buildfile));
2645         print <<"_____";
2646
2647 NOTE: These variables only represent the configuration view.  The build file
2648 template may have processed these variables further, please have a look at the
2649 build file for more exact data:
2650     $buildfile
2651 _____
2652     }
2653     if ($dump || $buildparams) {
2654         my @buildfile = ($config{builddir}, $config{build_file});
2655         unshift @buildfile, $here
2656             unless file_name_is_absolute($config{builddir});
2657         print "\nbuild file:\n\n";
2658         print "    ", canonpath(catfile(@buildfile)),"\n";
2659
2660         print "\nbuild file templates:\n\n";
2661         foreach (@{$config{build_file_templates}}) {
2662             my @tmpl = ($_);
2663             unshift @tmpl, $here
2664                 unless file_name_is_absolute($config{sourcedir});
2665             print '    ',canonpath(catfile(@tmpl)),"\n";
2666         }
2667     }
2668     if ($reconf) {
2669         if ($verbose) {
2670             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2671             foreach (sort keys %{$config{perlenv}}) {
2672                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2673             }
2674         }
2675
2676         chdir $here;
2677         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2678     }
2679 }
2680
2681 1;
2682
2683 __END__
2684
2685 =head1 NAME
2686
2687 configdata.pm - configuration data for OpenSSL builds
2688
2689 =head1 SYNOPSIS
2690
2691 Interactive:
2692
2693   perl configdata.pm [options]
2694
2695 As data bank module:
2696
2697   use configdata;
2698
2699 =head1 DESCRIPTION
2700
2701 This module can be used in two modes, interactively and as a module containing
2702 all the data recorded by OpenSSL's Configure script.
2703
2704 When used interactively, simply run it as any perl script, with at least one
2705 option, and you will get the information you ask for.  See L</OPTIONS> below.
2706
2707 When loaded as a module, you get a few databanks with useful information to
2708 perform build related tasks.  The databanks are:
2709
2710     %config             Configured things.
2711     %target             The OpenSSL config target with all inheritances
2712                         resolved.
2713     %disabled           The features that are disabled.
2714     @disablables        The list of features that can be disabled.
2715     %withargs           All data given through --with-THING options.
2716     %unified_info       All information that was computed from the build.info
2717                         files.
2718
2719 =head1 OPTIONS
2720
2721 =over 4
2722
2723 =item B<--help>
2724
2725 Print a brief help message and exit.
2726
2727 =item B<--man>
2728
2729 Print the manual page and exit.
2730
2731 =item B<--dump> | B<-d>
2732
2733 Print all relevant configuration data.  This is equivalent to B<--command-line>
2734 B<--options> B<--target> B<--environment> B<--make-variables>
2735 B<--build-parameters>.
2736
2737 =item B<--command-line> | B<-c>
2738
2739 Print the current configuration command line.
2740
2741 =item B<--options> | B<-o>
2742
2743 Print the features, both enabled and disabled, and display defined macro and
2744 skipped directories where applicable.
2745
2746 =item B<--target> | B<-t>
2747
2748 Print the config attributes for this config target.
2749
2750 =item B<--environment> | B<-e>
2751
2752 Print the environment variables and their values at the time of configuration.
2753
2754 =item B<--make-variables> | B<-m>
2755
2756 Print the main make variables generated in the current configuration
2757
2758 =item B<--build-parameters> | B<-b>
2759
2760 Print the build parameters, i.e. build file and build file templates.
2761
2762 =item B<--reconfigure> | B<--reconf> | B<-r>
2763
2764 Redo the configuration.
2765
2766 =item B<--verbose> | B<-v>
2767
2768 Verbose output.
2769
2770 =back
2771
2772 =cut
2773
2774 EOF
2775 close(OUT);
2776 if ($builder_platform eq 'unix') {
2777     my $mode = (0755 & ~umask);
2778     chmod $mode, 'configdata.pm'
2779         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2780 }
2781
2782 my %builders = (
2783     unified => sub {
2784         print 'Creating ',$target{build_file},"\n";
2785         run_dofile(catfile($blddir, $target{build_file}),
2786                    @{$config{build_file_templates}});
2787     },
2788     );
2789
2790 $builders{$builder}->($builder_platform, @builder_opts);
2791
2792 $SIG{__DIE__} = $orig_death_handler;
2793
2794 print <<"EOF" if ($disabled{threads} eq "unavailable");
2795
2796 The library could not be configured for supporting multi-threaded
2797 applications as the compiler options required on this system are not known.
2798 See file INSTALL for details if you need multi-threading.
2799 EOF
2800
2801 print <<"EOF" if ($no_shared_warn);
2802
2803 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2804 platform, so we will pretend you gave the option 'no-pic', which also disables
2805 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2806 or position independent code, please let us know (but please first make sure
2807 you have tried with a current version of OpenSSL).
2808 EOF
2809
2810 print <<"EOF";
2811
2812 **********************************************************************
2813 ***                                                                ***
2814 ***   OpenSSL has been successfully configured                     ***
2815 ***                                                                ***
2816 ***   If you encounter a problem while building, please open an    ***
2817 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2818 ***   and include the output from the following command:           ***
2819 ***                                                                ***
2820 ***       perl configdata.pm --dump                                ***
2821 ***                                                                ***
2822 ***   (If you are new to OpenSSL, you might want to consult the    ***
2823 ***   'Troubleshooting' section in the INSTALL file first)         ***
2824 ***                                                                ***
2825 **********************************************************************
2826 EOF
2827
2828 exit(0);
2829
2830 ######################################################################
2831 #
2832 # Helpers and utility functions
2833 #
2834
2835 # Death handler, to print a helpful message in case of failure #######
2836 #
2837 sub death_handler {
2838     die @_ if $^S;              # To prevent the added message in eval blocks
2839     my $build_file = $target{build_file} // "build file";
2840     my @message = ( <<"_____", @_ );
2841
2842 Failure!  $build_file wasn't produced.
2843 Please read INSTALL and associated NOTES files.  You may also have to look over
2844 your available compiler tool chain or change your configuration.
2845
2846 _____
2847
2848     # Dying is terminal, so it's ok to reset the signal handler here.
2849     $SIG{__DIE__} = $orig_death_handler;
2850     die @message;
2851 }
2852
2853 # Configuration file reading #########################################
2854
2855 # Note: All of the helper functions are for lazy evaluation.  They all
2856 # return a CODE ref, which will return the intended value when evaluated.
2857 # Thus, whenever there's mention of a returned value, it's about that
2858 # intended value.
2859
2860 # Helper function to implement conditional inheritance depending on the
2861 # value of $disabled{asm}.  Used in inherit_from values as follows:
2862 #
2863 #      inherit_from => [ "template", asm("asm_tmpl") ]
2864 #
2865 sub asm {
2866     my @x = @_;
2867     sub {
2868         $disabled{asm} ? () : @x;
2869     }
2870 }
2871
2872 # Helper function to implement conditional value variants, with a default
2873 # plus additional values based on the value of $config{build_type}.
2874 # Arguments are given in hash table form:
2875 #
2876 #       picker(default => "Basic string: ",
2877 #              debug   => "debug",
2878 #              release => "release")
2879 #
2880 # When configuring with --debug, the resulting string will be
2881 # "Basic string: debug", and when not, it will be "Basic string: release"
2882 #
2883 # This can be used to create variants of sets of flags according to the
2884 # build type:
2885 #
2886 #       cflags => picker(default => "-Wall",
2887 #                        debug   => "-g -O0",
2888 #                        release => "-O3")
2889 #
2890 sub picker {
2891     my %opts = @_;
2892     return sub { add($opts{default} || (),
2893                      $opts{$config{build_type}} || ())->(); }
2894 }
2895
2896 # Helper function to combine several values of different types into one.
2897 # This is useful if you want to combine a string with the result of a
2898 # lazy function, such as:
2899 #
2900 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2901 #
2902 sub combine {
2903     my @stuff = @_;
2904     return sub { add(@stuff)->(); }
2905 }
2906
2907 # Helper function to implement conditional values depending on the value
2908 # of $disabled{threads}.  Can be used as follows:
2909 #
2910 #       cflags => combine("-Wall", threads("-pthread"))
2911 #
2912 sub threads {
2913     my @flags = @_;
2914     return sub { add($disabled{threads} ? () : @flags)->(); }
2915 }
2916
2917 sub shared {
2918     my @flags = @_;
2919     return sub { add($disabled{shared} ? () : @flags)->(); }
2920 }
2921
2922 our $add_called = 0;
2923 # Helper function to implement adding values to already existing configuration
2924 # values.  It handles elements that are ARRAYs, CODEs and scalars
2925 sub _add {
2926     my $separator = shift;
2927
2928     # If there's any ARRAY in the collection of values OR the separator
2929     # is undef, we will return an ARRAY of combined values, otherwise a
2930     # string of joined values with $separator as the separator.
2931     my $found_array = !defined($separator);
2932
2933     my @values =
2934         map {
2935             my $res = $_;
2936             while (ref($res) eq "CODE") {
2937                 $res = $res->();
2938             }
2939             if (defined($res)) {
2940                 if (ref($res) eq "ARRAY") {
2941                     $found_array = 1;
2942                     @$res;
2943                 } else {
2944                     $res;
2945                 }
2946             } else {
2947                 ();
2948             }
2949     } (@_);
2950
2951     $add_called = 1;
2952
2953     if ($found_array) {
2954         [ @values ];
2955     } else {
2956         join($separator, grep { defined($_) && $_ ne "" } @values);
2957     }
2958 }
2959 sub add_before {
2960     my $separator = " ";
2961     if (ref($_[$#_]) eq "HASH") {
2962         my $opts = pop;
2963         $separator = $opts->{separator};
2964     }
2965     my @x = @_;
2966     sub { _add($separator, @x, @_) };
2967 }
2968 sub add {
2969     my $separator = " ";
2970     if (ref($_[$#_]) eq "HASH") {
2971         my $opts = pop;
2972         $separator = $opts->{separator};
2973     }
2974     my @x = @_;
2975     sub { _add($separator, @_, @x) };
2976 }
2977
2978 sub read_eval_file {
2979     my $fname = shift;
2980     my $content;
2981     my @result;
2982
2983     open F, "< $fname" or die "Can't open '$fname': $!\n";
2984     {
2985         undef local $/;
2986         $content = <F>;
2987     }
2988     close F;
2989     {
2990         local $@;
2991
2992         @result = ( eval $content );
2993         warn $@ if $@;
2994     }
2995     return wantarray ? @result : $result[0];
2996 }
2997
2998 # configuration reader, evaluates the input file as a perl script and expects
2999 # it to fill %targets with target configurations.  Those are then added to
3000 # %table.
3001 sub read_config {
3002     my $fname = shift;
3003     my %targets;
3004
3005     {
3006         # Protect certain tables from tampering
3007         local %table = ();
3008
3009         %targets = read_eval_file($fname);
3010     }
3011     my %preexisting = ();
3012     foreach (sort keys %targets) {
3013         $preexisting{$_} = 1 if $table{$_};
3014     }
3015     die <<"EOF",
3016 The following config targets from $fname
3017 shadow pre-existing config targets with the same name:
3018 EOF
3019         map { "  $_\n" } sort keys %preexisting
3020         if %preexisting;
3021
3022
3023     # For each target, check that it's configured with a hash table.
3024     foreach (keys %targets) {
3025         if (ref($targets{$_}) ne "HASH") {
3026             if (ref($targets{$_}) eq "") {
3027                 warn "Deprecated target configuration for $_, ignoring...\n";
3028             } else {
3029                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3030             }
3031             delete $targets{$_};
3032         } else {
3033             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3034         }
3035     }
3036
3037     %table = (%table, %targets);
3038
3039 }
3040
3041 # configuration resolver.  Will only resolve all the lazy evaluation
3042 # codeblocks for the chosen target and all those it inherits from,
3043 # recursively
3044 sub resolve_config {
3045     my $target = shift;
3046     my @breadcrumbs = @_;
3047
3048 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3049
3050     if (grep { $_ eq $target } @breadcrumbs) {
3051         die "inherit_from loop!  target backtrace:\n  "
3052             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3053     }
3054
3055     if (!defined($table{$target})) {
3056         warn "Warning! target $target doesn't exist!\n";
3057         return ();
3058     }
3059     # Recurse through all inheritances.  They will be resolved on the
3060     # fly, so when this operation is done, they will all just be a
3061     # bunch of attributes with string values.
3062     # What we get here, though, are keys with references to lists of
3063     # the combined values of them all.  We will deal with lists after
3064     # this stage is done.
3065     my %combined_inheritance = ();
3066     if ($table{$target}->{inherit_from}) {
3067         my @inherit_from =
3068             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3069         foreach (@inherit_from) {
3070             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3071
3072             # 'template' is a marker that's considered private to
3073             # the config that had it.
3074             delete $inherited_config{template};
3075
3076             foreach (keys %inherited_config) {
3077                 if (!$combined_inheritance{$_}) {
3078                     $combined_inheritance{$_} = [];
3079                 }
3080                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3081             }
3082         }
3083     }
3084
3085     # We won't need inherit_from in this target any more, since we've
3086     # resolved all the inheritances that lead to this
3087     delete $table{$target}->{inherit_from};
3088
3089     # Now is the time to deal with those lists.  Here's the place to
3090     # decide what shall be done with those lists, all based on the
3091     # values of the target we're currently dealing with.
3092     # - If a value is a coderef, it will be executed with the list of
3093     #   inherited values as arguments.
3094     # - If the corresponding key doesn't have a value at all or is the
3095     #   empty string, the inherited value list will be run through the
3096     #   default combiner (below), and the result becomes this target's
3097     #   value.
3098     # - Otherwise, this target's value is assumed to be a string that
3099     #   will simply override the inherited list of values.
3100     my $default_combiner = add();
3101
3102     my %all_keys =
3103         map { $_ => 1 } (keys %combined_inheritance,
3104                          keys %{$table{$target}});
3105
3106     sub process_values {
3107         my $object    = shift;
3108         my $inherited = shift;  # Always a [ list ]
3109         my $target    = shift;
3110         my $entry     = shift;
3111
3112         $add_called = 0;
3113
3114         while(ref($object) eq "CODE") {
3115             $object = $object->(@$inherited);
3116         }
3117         if (!defined($object)) {
3118             return ();
3119         }
3120         elsif (ref($object) eq "ARRAY") {
3121             local $add_called;  # To make sure recursive calls don't affect it
3122             return [ map { process_values($_, $inherited, $target, $entry) }
3123                      @$object ];
3124         } elsif (ref($object) eq "") {
3125             return $object;
3126         } else {
3127             die "cannot handle reference type ",ref($object)
3128                 ," found in target ",$target," -> ",$entry,"\n";
3129         }
3130     }
3131
3132     foreach (sort keys %all_keys) {
3133         my $previous = $combined_inheritance{$_};
3134
3135         # Current target doesn't have a value for the current key?
3136         # Assign it the default combiner, the rest of this loop body
3137         # will handle it just like any other coderef.
3138         if (!exists $table{$target}->{$_}) {
3139             $table{$target}->{$_} = $default_combiner;
3140         }
3141
3142         $table{$target}->{$_} = process_values($table{$target}->{$_},
3143                                                $combined_inheritance{$_},
3144                                                $target, $_);
3145         unless(defined($table{$target}->{$_})) {
3146             delete $table{$target}->{$_};
3147         }
3148 #        if ($extra_checks &&
3149 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3150 #            warn "$_ got replaced in $target\n";
3151 #        }
3152     }
3153
3154     # Finally done, return the result.
3155     return %{$table{$target}};
3156 }
3157
3158 sub usage
3159         {
3160         print STDERR $usage;
3161         print STDERR "\npick os/compiler from:\n";
3162         my $j=0;
3163         my $i;
3164         my $k=0;
3165         foreach $i (sort keys %table)
3166                 {
3167                 next if $table{$i}->{template};
3168                 next if $i =~ /^debug/;
3169                 $k += length($i) + 1;
3170                 if ($k > 78)
3171                         {
3172                         print STDERR "\n";
3173                         $k=length($i);
3174                         }
3175                 print STDERR $i . " ";
3176                 }
3177         foreach $i (sort keys %table)
3178                 {
3179                 next if $table{$i}->{template};
3180                 next if $i !~ /^debug/;
3181                 $k += length($i) + 1;
3182                 if ($k > 78)
3183                         {
3184                         print STDERR "\n";
3185                         $k=length($i);
3186                         }
3187                 print STDERR $i . " ";
3188                 }
3189         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3190         exit(1);
3191         }
3192
3193 sub run_dofile
3194 {
3195     my $out = shift;
3196     my @templates = @_;
3197
3198     unlink $out || warn "Can't remove $out, $!"
3199         if -f $out;
3200     foreach (@templates) {
3201         die "Can't open $_, $!" unless -f $_;
3202     }
3203     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3204     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3205     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3206     system($cmd);
3207     exit 1 if $? != 0;
3208     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3209 }
3210
3211 sub compiler_predefined {
3212     state %predefined;
3213     my $cc = shift;
3214
3215     return () if $^O eq 'VMS';
3216
3217     die 'compiler_predefined called without a compiler command'
3218         unless $cc;
3219
3220     if (! $predefined{$cc}) {
3221
3222         $predefined{$cc} = {};
3223
3224         # collect compiler pre-defines from gcc or gcc-alike...
3225         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3226         while (my $l = <PIPE>) {
3227             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3228             $predefined{$cc}->{$1} = $2 // '';
3229         }
3230         close(PIPE);
3231     }
3232
3233     return %{$predefined{$cc}};
3234 }
3235
3236 sub which
3237 {
3238     my ($name)=@_;
3239
3240     if (eval { require IPC::Cmd; 1; }) {
3241         IPC::Cmd->import();
3242         return scalar IPC::Cmd::can_run($name);
3243     } else {
3244         # if there is $directories component in splitpath,
3245         # then it's not something to test with $PATH...
3246         return $name if (File::Spec->splitpath($name))[1];
3247
3248         foreach (File::Spec->path()) {
3249             my $fullpath = catfile($_, "$name$target{exe_extension}");
3250             if (-f $fullpath and -x $fullpath) {
3251                 return $fullpath;
3252             }
3253         }
3254     }
3255 }
3256
3257 sub env
3258 {
3259     my $name = shift;
3260     my %opts = @_;
3261
3262     unless ($opts{cacheonly}) {
3263         # Note that if $ENV{$name} doesn't exist or is undefined,
3264         # $config{perlenv}->{$name} will be created with the value
3265         # undef.  This is intentional.
3266
3267         $config{perlenv}->{$name} = $ENV{$name}
3268             if ! exists $config{perlenv}->{$name};
3269     }
3270     return $config{perlenv}->{$name};
3271 }
3272
3273 # Configuration printer ##############################################
3274
3275 sub print_table_entry
3276 {
3277     local $now_printing = shift;
3278     my %target = resolve_config($now_printing);
3279     my $type = shift;
3280
3281     # Don't print the templates
3282     return if $target{template};
3283
3284     my @sequence = (
3285         "sys_id",
3286         "cpp",
3287         "cppflags",
3288         "defines",
3289         "includes",
3290         "cc",
3291         "cflags",
3292         "unistd",
3293         "ld",
3294         "lflags",
3295         "loutflag",
3296         "ex_libs",
3297         "bn_ops",
3298         "apps_aux_src",
3299         "cpuid_asm_src",
3300         "uplink_aux_src",
3301         "bn_asm_src",
3302         "ec_asm_src",
3303         "des_asm_src",
3304         "aes_asm_src",
3305         "bf_asm_src",
3306         "md5_asm_src",
3307         "cast_asm_src",
3308         "sha1_asm_src",
3309         "rc4_asm_src",
3310         "rmd160_asm_src",
3311         "rc5_asm_src",
3312         "wp_asm_src",
3313         "cmll_asm_src",
3314         "modes_asm_src",
3315         "padlock_asm_src",
3316         "chacha_asm_src",
3317         "poly1035_asm_src",
3318         "thread_scheme",
3319         "perlasm_scheme",
3320         "dso_scheme",
3321         "shared_target",
3322         "shared_cflag",
3323         "shared_defines",
3324         "shared_ldflag",
3325         "shared_rcflag",
3326         "shared_extension",
3327         "dso_extension",
3328         "obj_extension",
3329         "exe_extension",
3330         "ranlib",
3331         "ar",
3332         "arflags",
3333         "aroutflag",
3334         "rc",
3335         "rcflags",
3336         "rcoutflag",
3337         "mt",
3338         "mtflags",
3339         "mtinflag",
3340         "mtoutflag",
3341         "multilib",
3342         "build_scheme",
3343         );
3344
3345     if ($type eq "TABLE") {
3346         print "\n";
3347         print "*** $now_printing\n";
3348         foreach (@sequence) {
3349             if (ref($target{$_}) eq "ARRAY") {
3350                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3351             } else {
3352                 printf "\$%-12s = %s\n", $_, $target{$_};
3353             }
3354         }
3355     } elsif ($type eq "HASH") {
3356         my $largest =
3357             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3358         print "    '$now_printing' => {\n";
3359         foreach (@sequence) {
3360             if ($target{$_}) {
3361                 if (ref($target{$_}) eq "ARRAY") {
3362                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3363                 } else {
3364                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3365                 }
3366             }
3367         }
3368         print "    },\n";
3369     }
3370 }
3371
3372 # Utility routines ###################################################
3373
3374 # On VMS, if the given file is a logical name, File::Spec::Functions
3375 # will consider it an absolute path.  There are cases when we want a
3376 # purely syntactic check without checking the environment.
3377 sub isabsolute {
3378     my $file = shift;
3379
3380     # On non-platforms, we just use file_name_is_absolute().
3381     return file_name_is_absolute($file) unless $^O eq "VMS";
3382
3383     # If the file spec includes a device or a directory spec,
3384     # file_name_is_absolute() is perfectly safe.
3385     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3386
3387     # Here, we know the given file spec isn't absolute
3388     return 0;
3389 }
3390
3391 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3392 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3393 # realpath() requires that at least all path components except the last is an
3394 # existing directory.  On VMS, the last component of the directory spec must
3395 # exist.
3396 sub absolutedir {
3397     my $dir = shift;
3398
3399     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3400     # will return the volume name for the device, no matter what.  Also,
3401     # it will return an incorrect directory spec if the argument is a
3402     # directory that doesn't exist.
3403     if ($^O eq "VMS") {
3404         return rel2abs($dir);
3405     }
3406
3407     # We use realpath() on Unix, since no other will properly clean out
3408     # a directory spec.
3409     use Cwd qw/realpath/;
3410
3411     return realpath($dir);
3412 }
3413
3414 sub quotify {
3415     my %processors = (
3416         perl    => sub { my $x = shift;
3417                          $x =~ s/([\\\$\@"])/\\$1/g;
3418                          return '"'.$x.'"'; },
3419         maybeshell => sub { my $x = shift;
3420                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3421                             if ($x ne $y || $x =~ m|\s|) {
3422                                 return '"'.$y.'"';
3423                             } else {
3424                                 return $x;
3425                             }
3426                         },
3427         );
3428     my $for = shift;
3429     my $processor =
3430         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3431
3432     return map { $processor->($_); } @_;
3433 }
3434
3435 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3436 # $filename is a file name to read from
3437 # $line_concat_cond_re is a regexp detecting a line continuation ending
3438 # $line_concat is a CODEref that takes care of concatenating two lines
3439 sub collect_from_file {
3440     my $filename = shift;
3441     my $line_concat_cond_re = shift;
3442     my $line_concat = shift;
3443
3444     open my $fh, $filename || die "unable to read $filename: $!\n";
3445     return sub {
3446         my $saved_line = "";
3447         $_ = "";
3448         while (<$fh>) {
3449             s|\R$||;
3450             if (defined $line_concat) {
3451                 $_ = $line_concat->($saved_line, $_);
3452                 $saved_line = "";
3453             }
3454             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3455                 $saved_line = $_;
3456                 next;
3457             }
3458             return $_;
3459         }
3460         die "$filename ending with continuation line\n" if $_;
3461         close $fh;
3462         return undef;
3463     }
3464 }
3465
3466 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3467 # $array is an ARRAYref of lines
3468 # $line_concat_cond_re is a regexp detecting a line continuation ending
3469 # $line_concat is a CODEref that takes care of concatenating two lines
3470 sub collect_from_array {
3471     my $array = shift;
3472     my $line_concat_cond_re = shift;
3473     my $line_concat = shift;
3474     my @array = (@$array);
3475
3476     return sub {
3477         my $saved_line = "";
3478         $_ = "";
3479         while (defined($_ = shift @array)) {
3480             s|\R$||;
3481             if (defined $line_concat) {
3482                 $_ = $line_concat->($saved_line, $_);
3483                 $saved_line = "";
3484             }
3485             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3486                 $saved_line = $_;
3487                 next;
3488             }
3489             return $_;
3490         }
3491         die "input text ending with continuation line\n" if $_;
3492         return undef;
3493     }
3494 }
3495
3496 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3497 # $lineiterator is a CODEref that delivers one line at a time.
3498 # All following arguments are regex/CODEref pairs, where the regexp detects a
3499 # line and the CODEref does something with the result of the regexp.
3500 sub collect_information {
3501     my $lineiterator = shift;
3502     my %collectors = @_;
3503
3504     while(defined($_ = $lineiterator->())) {
3505         s|\R$||;
3506         my $found = 0;
3507         if ($collectors{"BEFORE"}) {
3508             $collectors{"BEFORE"}->($_);
3509         }
3510         foreach my $re (keys %collectors) {
3511             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3512                 $collectors{$re}->($lineiterator);
3513                 $found = 1;
3514             };
3515         }
3516         if ($collectors{"OTHERWISE"}) {
3517             $collectors{"OTHERWISE"}->($lineiterator, $_)
3518                 unless $found || !defined $collectors{"OTHERWISE"};
3519         }
3520         if ($collectors{"AFTER"}) {
3521             $collectors{"AFTER"}->($_);
3522         }
3523     }
3524 }
3525
3526 # tokenize($line)
3527 # tokenize($line,$separator)
3528 # $line is a line of text to split up into tokens
3529 # $separator [optional] is a regular expression that separates the tokens,
3530 # the default being spaces.  Do not use quotes of any kind as separators,
3531 # that will give undefined results.
3532 # Returns a list of tokens.
3533 #
3534 # Tokens are divided by separator (spaces by default).  If the tokens include
3535 # the separators, they have to be quoted with single or double quotes.
3536 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3537 # with backslash.
3538 # Basically, the same quoting rules apply for " and ' as in any
3539 # Unix shell.
3540 sub tokenize {
3541     my $line = my $debug_line = shift;
3542     my $separator = shift // qr|\s+|;
3543     my @result = ();
3544
3545     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3546         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3547     }
3548
3549     while ($line =~ s|^${separator}||, $line ne "") {
3550         my $token = "";
3551     again:
3552         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3553         $token .= $1;
3554         $line = $2.$';
3555
3556         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3557             $token .= $1;
3558             $line = $';
3559             goto again;
3560         } elsif ($line =~ m/^'([^']*)'/) {
3561             $token .= $1;
3562             $line = $';
3563             goto again;
3564         }
3565         push @result, $token;
3566     }
3567
3568     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3569         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3570         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3571     }
3572     return @result;
3573 }