Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  25
  26 # Options:
  27 #
  28 # --config      add the given configuration file, which will be read after
  29 #               any "Configurations*" files that are found in the same
  30 #               directory as this script.
  31 # --prefix      prefix for the OpenSSL installation, which includes the
  32 #               directories bin, lib, include, share/man, share/doc/openssl
  33 #               This becomes the value of INSTALLTOP in Makefile
  34 #               (Default: /usr/local)
  35 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  36 #               If it's a relative directory, it will be added on the directory
  37 #               given with --prefix.
  38 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  39 #               (Default: PREFIX/ssl)
  40 #
  41 # --cross-compile-prefix Add specified prefix to binutils components.
  42 #
  43 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  44 #               interfaces deprecated as of the specified OpenSSL version.
  45 #
  46 # no-hw-xxx     do not compile support for specific crypto hardware.
  47 #               Generic OpenSSL-style methods relating to this support
  48 #               are always compiled but return NULL if the hardware
  49 #               support isn't compiled.
  50 # no-hw         do not compile support for any crypto hardware.
  51 # [no-]threads  [don't] try to create a library that is suitable for
  52 #               multithreaded applications (default is "threads" if we
  53 #               know how to do it)
  54 # [no-]shared   [don't] try to create shared libraries when supported.
  55 # [no-]pic      [don't] try to build position independent code when supported.
  56 #               If disabled, it also disables shared and dynamic-engine.
  57 # no-asm        do not use assembler
  58 # no-dso        do not compile in any native shared-library methods. This
  59 #               will ensure that all methods just return NULL.
  60 # no-egd        do not compile support for the entropy-gathering daemon APIs
  61 # [no-]zlib     [don't] compile support for zlib compression.
  62 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  63 #               library and will be loaded in run-time by the OpenSSL library.
  64 # sctp          include SCTP support
  65 # enable-weak-ssl-ciphers
  66 #               Enable weak ciphers that are disabled by default.
  67 # 386           generate 80386 code in assembly modules
  68 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  69 #               mentioned '386' option implies this one
  70 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  71 # -<xxx> +<xxx> compiler options are passed through
  72 # -static       while -static is also a pass-through compiler option (and
  73 #               as such is limited to environments where it's actually
  74 #               meaningful), it triggers a number configuration options,
  75 #               namely no-dso, no-pic, no-shared and no-threads. It is
  76 #               argued that the only reason to produce statically linked
  77 #               binaries (and in context it means executables linked with
  78 #               -static flag, and not just executables linked with static
  79 #               libcrypto.a) is to eliminate dependency on specific run-time,
  80 #               a.k.a. libc version. The mentioned config options are meant
  81 #               to achieve just that. Unfortunately on Linux it's impossible
  82 #               to eliminate the dependency completely for openssl executable
  83 #               because of getaddrinfo and gethostbyname calls, which can
  84 #               invoke dynamically loadable library facility anyway to meet
  85 #               the lookup requests. For this reason on Linux statically
  86 #               linked openssl executable has rather debugging value than
  87 #               production quality.
  88 #
  89 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  90 #               provided to stack calls. Generates unique stack functions for
  91 #               each possible stack type.
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least get
 104 # past these.
 105
 106 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 107 # -DPEDANTIC complements -pedantic and is meant to mask code that
 108 # is not strictly standard-compliant and/or implementation-specific,
 109 # e.g. inline assembly, disregards to alignment requirements, such
 110 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 111 # to be used even in sanitized builds, because sanitizer too is
 112 # supposed to and does take notice of non-standard behaviour. Then
 113 # -pedantic with pre-C9x compiler would also complain about 'long
 114 # long' not being supported. As 64-bit algorithms are common now,
 115 # it grew impossible to resolve this without sizeable additional
 116 # code, so we just tell compiler to be pedantic about everything
 117 # but 'long long' type.
 118
 119 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 120         . " -DPEDANTIC -pedantic -Wno-long-long"
 121         . " -Wall"
 122         . " -Wextra"
 123         . " -Wno-unused-parameter"
 124         . " -Wno-missing-field-initializers"
 125         . " -Wswitch"
 126         . " -Wsign-compare"
 127         . " -Wmissing-prototypes"
 128         . " -Wshadow"
 129         . " -Wformat"
 130         . " -Wtype-limits"
 131         . " -Wundef"
 132         . " -Werror"
 133         ;
 134
 135 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 136 # TODO(openssl-team): fix problems and investigate if (at least) the
 137 # following warnings can also be enabled:
 138 #       -Wcast-align
 139 #       -Wunreachable-code -- no, too ugly/compiler-specific
 140 #       -Wlanguage-extension-token -- no, we use asm()
 141 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 142 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 143 my $clang_devteam_warn = ""
 144         . " -Wswitch-default"
 145         . " -Wno-parentheses-equality"
 146         . " -Wno-language-extension-token"
 147         . " -Wno-extended-offsetof"
 148         . " -Wconditional-uninitialized"
 149         . " -Wincompatible-pointer-types-discards-qualifiers"
 150         . " -Wmissing-variable-declarations"
 151         . " -Wno-unknown-warning-option"
 152         ;
 153
 154 # This adds backtrace information to the memory leak info.  Is only used
 155 # when crypto-mdebug-backtrace is enabled.
 156 my $memleak_devteam_backtrace = "-rdynamic";
 157
 158 my $strict_warnings = 0;
 159
 160 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 161 # which would cover all BSD flavors. -pthread applies to them all,
 162 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 163 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 164 # which has to be accompanied by explicit -D_THREAD_SAFE and
 165 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 166 # seems to be sufficient?
 167 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 168
 169 #
 170 # API compatibility name to version number mapping.
 171 #
 172 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 173 my $apitable = {
 174     "1.1.0" => "0x10100000L",
 175     "1.0.0" => "0x10000000L",
 176     "0.9.8" => "0x00908000L",
 177 };
 178
 179 our %table = ();
 180 our %config = ();
 181 our %withargs = ();
 182
 183 # Forward declarations ###############################################
 184
 185 # read_config(filename)
 186 #
 187 # Reads a configuration file and populates %table with the contents
 188 # (which the configuration file places in %targets).
 189 sub read_config;
 190
 191 # resolve_config(target)
 192 #
 193 # Resolves all the late evaluations, inheritances and so on for the
 194 # chosen target and any target it inherits from.
 195 sub resolve_config;
 196
 197
 198 # Information collection #############################################
 199
 200 # Unified build supports separate build dir
 201 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 202 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 203 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 204
 205 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 206
 207 $config{sourcedir} = abs2rel($srcdir);
 208 $config{builddir} = abs2rel($blddir);
 209
 210 # Collect reconfiguration information if needed
 211 my @argvcopy=@ARGV;
 212
 213 if (grep /^reconf(igure)?$/, @argvcopy) {
 214     die "reconfiguring with other arguments present isn't supported"
 215         if scalar @argvcopy > 1;
 216     if (-f "./configdata.pm") {
 217         my $file = "./configdata.pm";
 218         unless (my $return = do $file) {
 219             die "couldn't parse $file: $@" if $@;
 220             die "couldn't do $file: $!"    unless defined $return;
 221             die "couldn't run $file"       unless $return;
 222         }
 223
 224         @argvcopy = defined($configdata::config{perlargv}) ?
 225             @{$configdata::config{perlargv}} : ();
 226         die "Incorrect data to reconfigure, please do a normal configuration\n"
 227             if (grep(/^reconf/,@argvcopy));
 228         $config{perlenv} = $configdata::config{perlenv} // {};
 229     } else {
 230         die "Insufficient data to reconfigure, please do a normal configuration\n";
 231     }
 232 }
 233
 234 $config{perlargv} = [ @argvcopy ];
 235
 236 # Collect version numbers
 237 $config{version} = "unknown";
 238 $config{version_num} = "unknown";
 239 $config{shlib_version_number} = "unknown";
 240 $config{shlib_version_history} = "unknown";
 241
 242 collect_information(
 243     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 244     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 245     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 246     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 247     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 248     );
 249 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 250
 251 ($config{major}, $config{minor})
 252     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 253 ($config{shlib_major}, $config{shlib_minor})
 254     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 255 die "erroneous version information in opensslv.h: ",
 256     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 257     if ($config{major} eq "" || $config{minor} eq ""
 258         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 259
 260 # Collect target configurations
 261
 262 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 263 foreach (sort glob($pattern)) {
 264     &read_config($_);
 265 }
 266
 267 if (defined env($local_config_envname)) {
 268     if ($^O eq 'VMS') {
 269         # VMS environment variables are logical names,
 270         # which can be used as is
 271         $pattern = $local_config_envname . ':' . '*.conf';
 272     } else {
 273         $pattern = catfile(env($local_config_envname), '*.conf');
 274     }
 275
 276     foreach (sort glob($pattern)) {
 277         &read_config($_);
 278     }
 279 }
 280
 281 $config{prefix}="";
 282 $config{openssldir}="";
 283 $config{processor}="";
 284 $config{libdir}="";
 285 $config{cross_compile_prefix}="";
 286 my $auto_threads=1;    # enable threads automatically? true by default
 287 my $default_ranlib;
 288
 289 # Top level directories to build
 290 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 291 # crypto/ subdirectories to build
 292 $config{sdirs} = [
 293     "objects",
 294     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash", "sm3",
 295     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "sm4", "chacha", "modes",
 296     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 297     "buffer", "bio", "stack", "lhash", "rand", "err",
 298     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 299     "cms", "ts", "srp", "cmac", "ct", "async", "kdf", "store"
 300     ];
 301 # test/ subdirectories to build
 302 $config{tdirs} = [ "ossl_shim" ];
 303
 304 # Known TLS and DTLS protocols
 305 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 306 my @dtls = qw(dtls1 dtls1_2);
 307
 308 # Explicitly known options that are possible to disable.  They can
 309 # be regexps, and will be used like this: /^no-${option}$/
 310 # For developers: keep it sorted alphabetically
 311
 312 my @disablables = (
 313     "afalgeng",
 314     "aria",
 315     "asan",
 316     "asm",
 317     "async",
 318     "autoalginit",
 319     "autoerrinit",
 320     "bf",
 321     "blake2",
 322     "camellia",
 323     "capieng",
 324     "cast",
 325     "chacha",
 326     "cmac",
 327     "cms",
 328     "comp",
 329     "crypto-mdebug",
 330     "crypto-mdebug-backtrace",
 331     "ct",
 332     "deprecated",
 333     "des",
 334     "devcryptoeng",
 335     "dgram",
 336     "dh",
 337     "dsa",
 338     "dso",
 339     "dtls",
 340     "dynamic-engine",
 341     "ec",
 342     "ec2m",
 343     "ecdh",
 344     "ecdsa",
 345     "ec_nistp_64_gcc_128",
 346     "egd",
 347     "engine",
 348     "err",
 349     "external-tests",
 350     "filenames",
 351     "fuzz-libfuzzer",
 352     "fuzz-afl",
 353     "gost",
 354     "heartbeats",
 355     "hw(-.+)?",
 356     "idea",
 357     "makedepend",
 358     "md2",
 359     "md4",
 360     "mdc2",
 361     "msan",
 362     "multiblock",
 363     "nextprotoneg",
 364     "ocb",
 365     "ocsp",
 366     "pic",
 367     "poly1305",
 368     "posix-io",
 369     "psk",
 370     "rc2",
 371     "rc4",
 372     "rc5",
 373     "rdrand",
 374     "rfc3779",
 375     "rmd160",
 376     "scrypt",
 377     "sctp",
 378     "seed",
 379     "shared",
 380     "siphash",
 381     "sm3",
 382     "sm4",
 383     "sock",
 384     "srp",
 385     "srtp",
 386     "sse2",
 387     "ssl",
 388     "ssl-trace",
 389     "static-engine",
 390     "stdio",
 391     "tests",
 392     "threads",
 393     "tls",
 394     "tls13downgrade",
 395     "ts",
 396     "ubsan",
 397     "ui-console",
 398     "unit-test",
 399     "whirlpool",
 400     "weak-ssl-ciphers",
 401     "zlib",
 402     "zlib-dynamic",
 403     );
 404 foreach my $proto ((@tls, @dtls))
 405         {
 406         push(@disablables, $proto);
 407         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 408         }
 409
 410 my %deprecated_disablables = (
 411     "ssl2" => undef,
 412     "buf-freelists" => undef,
 413     "ripemd" => "rmd160",
 414     "ui" => "ui-console",
 415     );
 416
 417 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 418
 419 our %disabled = ( # "what"         => "comment"
 420                   "asan"                => "default",
 421                   "crypto-mdebug"       => "default",
 422                   "crypto-mdebug-backtrace" => "default",
 423                   "devcryptoeng"        => "default",
 424                   "ec_nistp_64_gcc_128" => "default",
 425                   "egd"                 => "default",
 426                   "external-tests"      => "default",
 427                   "fuzz-libfuzzer"      => "default",
 428                   "fuzz-afl"            => "default",
 429                   "heartbeats"          => "default",
 430                   "md2"                 => "default",
 431                   "msan"                => "default",
 432                   "rc5"                 => "default",
 433                   "sctp"                => "default",
 434                   "ssl-trace"           => "default",
 435                   "ssl3"                => "default",
 436                   "ssl3-method"         => "default",
 437                   "ubsan"               => "default",
 438           #TODO(TLS1.3): Temporarily disabled while this is a WIP
 439                   "tls1_3"              => "default",
 440                   "tls13downgrade"      => "default",
 441                   "unit-test"           => "default",
 442                   "weak-ssl-ciphers"    => "default",
 443                   "zlib"                => "default",
 444                   "zlib-dynamic"        => "default",
 445                 );
 446
 447 # Note: => pair form used for aesthetics, not to truly make a hash table
 448 my @disable_cascades = (
 449     # "what"            => [ "cascade", ... ]
 450     sub { $config{processor} eq "386" }
 451                         => [ "sse2" ],
 452     "ssl"               => [ "ssl3" ],
 453     "ssl3-method"       => [ "ssl3" ],
 454     "zlib"              => [ "zlib-dynamic" ],
 455     "des"               => [ "mdc2" ],
 456     "ec"                => [ "ecdsa", "ecdh" ],
 457
 458     "dgram"             => [ "dtls", "sctp" ],
 459     "sock"              => [ "dgram" ],
 460     "dtls"              => [ @dtls ],
 461     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 462                         => [ "dtls" ],
 463
 464     "tls"               => [ @tls ],
 465     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 466                         => [ "tls" ],
 467
 468     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 469
 470     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 471     "dso"               => [ "dynamic-engine" ],
 472
 473     # Without position independent code, there can be no shared libraries or DSOs
 474     "pic"               => [ "shared" ],
 475     "shared"            => [ "dynamic-engine" ],
 476     "engine"            => [ "afalgeng", "devcryptoeng" ],
 477
 478     # no-autoalginit is only useful when building non-shared
 479     "autoalginit"       => [ "shared", "apps" ],
 480
 481     "stdio"             => [ "apps", "capieng", "egd" ],
 482     "apps"              => [ "tests" ],
 483     "tests"             => [ "external-tests" ],
 484     "comp"              => [ "zlib" ],
 485     "ec"                => [ "tls1_3" ],
 486     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 487
 488     sub { !$disabled{"msan"} } => [ "asm" ],
 489     );
 490
 491 # Avoid protocol support holes.  Also disable all versions below N, if version
 492 # N is disabled while N+1 is enabled.
 493 #
 494 my @list = (reverse @tls);
 495 while ((my $first, my $second) = (shift @list, shift @list)) {
 496     last unless @list;
 497     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 498                               => [ @list ] );
 499     unshift @list, $second;
 500 }
 501 my @list = (reverse @dtls);
 502 while ((my $first, my $second) = (shift @list, shift @list)) {
 503     last unless @list;
 504     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 505                               => [ @list ] );
 506     unshift @list, $second;
 507 }
 508
 509 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 510 # To remove something from %disabled, use "enable-foo".
 511 # For symmetry, "disable-foo" is a synonym for "no-foo".
 512
 513 &usage if ($#ARGV < 0);
 514
 515 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 516 # platform specific list separators.  Users from those platforms should
 517 # recognise those separators from how you set up the PATH to find executables.
 518 # The default is the Unix like separator, :, but as an exception, we also
 519 # support the space as separator.
 520 my $list_separator_re =
 521     { VMS           => qr/(?<!\^),/,
 522       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 523 # All the "make variables" we support
 524 my %user = (
 525     AR          => undef,
 526     ARFLAGS     => [],
 527     AS          => undef,
 528     ASFLAGS     => [],
 529     CC          => undef,
 530     CFLAGS      => [],
 531     CXX         => undef,
 532     CXXFLAGS    => [],
 533     CPP         => undef,
 534     CPPFLAGS    => [],  # -D, -I, -Wp,
 535     CPPDEFINES  => [],  # Alternative for -D
 536     CPPINCLUDES => [],  # Alternative for -I
 537     HASHBANGPERL=> undef,
 538     LD          => undef,
 539     LDFLAGS     => [],  # -L, -Wl,
 540     LDLIBS      => [],  # -l
 541     MT          => undef,
 542     MTFLAGS     => [],
 543     RANLIB      => undef,
 544     RC          => undef,
 545     RCFLAGS     => [],
 546     RM          => undef,
 547    );
 548 # The same but for flags given as Configure options.  These are *additional*
 549 # input, as opposed to the VAR=string option that override the corresponding
 550 # config target attributes
 551 my %useradd = (
 552     CPPDEFINES  => [],
 553     CPPINCLUDES => [],
 554     CPPFLAGS    => [],
 555     CFLAGS      => [],
 556     CXXFLAGS    => [],
 557     LDFLAGS     => [],
 558     LDLIBS      => [],
 559    );
 560
 561 my %user_synonyms = (
 562     HASHBANGPERL=> 'PERL',
 563     RC          => 'WINDRES',
 564    );
 565 my %user_to_target = (
 566     # If not given here, the value is the lc of the key
 567     CPPDEFINES  => 'defines',
 568     CPPINCLUDES => 'includes',
 569     LDFLAGS     => 'lflags',
 570     LDLIBS      => 'ex_libs',
 571    );
 572
 573 $config{openssl_api_defines}=[];
 574 $config{openssl_algorithm_defines}=[];
 575 $config{openssl_thread_defines}=[];
 576 $config{openssl_sys_defines}=[];
 577 $config{openssl_other_defines}=[];
 578 $config{options}="";
 579 $config{build_type} = "release";
 580 my $target="";
 581
 582 my %unsupported_options = ();
 583 my %deprecated_options = ();
 584 # If you change this, update apps/version.c
 585 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 586 my @seed_sources = ();
 587 while (@argvcopy)
 588         {
 589         $_ = shift @argvcopy;
 590
 591         # Support env variable assignments among the options
 592         if (m|^(\w+)=(.+)?$|)
 593                 {
 594                 $config{perlenv}->{$1} = $2;
 595                 # Every time a variable is given as a configuration argument,
 596                 # it acts as a reset if the variable.
 597                 if (exists $user{$1})
 598                         {
 599                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 600                         }
 601                 if (exists $useradd{$1})
 602                         {
 603                         $useradd{$1} = [];
 604                         }
 605                 next;
 606                 }
 607
 608         # VMS is a case insensitive environment, and depending on settings
 609         # out of our control, we may receive options uppercased.  Let's
 610         # downcase at least the part before any equal sign.
 611         if ($^O eq "VMS")
 612                 {
 613                 s/^([^=]*)/lc($1)/e;
 614                 }
 615         s /^-no-/no-/; # some people just can't read the instructions
 616
 617         # rewrite some options in "enable-..." form
 618         s /^-?-?shared$/enable-shared/;
 619         s /^sctp$/enable-sctp/;
 620         s /^threads$/enable-threads/;
 621         s /^zlib$/enable-zlib/;
 622         s /^zlib-dynamic$/enable-zlib-dynamic/;
 623
 624         if (/^(no|disable|enable)-(.+)$/)
 625                 {
 626                 my $word = $2;
 627                 if (!exists $deprecated_disablables{$word}
 628                         && !grep { $word =~ /^${_}$/ } @disablables)
 629                         {
 630                         $unsupported_options{$_} = 1;
 631                         next;
 632                         }
 633                 }
 634         if (/^no-(.+)$/ || /^disable-(.+)$/)
 635                 {
 636                 foreach my $proto ((@tls, @dtls))
 637                         {
 638                         if ($1 eq "$proto-method")
 639                                 {
 640                                 $disabled{"$proto"} = "option($proto-method)";
 641                                 last;
 642                                 }
 643                         }
 644                 if ($1 eq "dtls")
 645                         {
 646                         foreach my $proto (@dtls)
 647                                 {
 648                                 $disabled{$proto} = "option(dtls)";
 649                                 }
 650                         $disabled{"dtls"} = "option(dtls)";
 651                         }
 652                 elsif ($1 eq "ssl")
 653                         {
 654                         # Last one of its kind
 655                         $disabled{"ssl3"} = "option(ssl)";
 656                         }
 657                 elsif ($1 eq "tls")
 658                         {
 659                         # XXX: Tests will fail if all SSL/TLS
 660                         # protocols are disabled.
 661                         foreach my $proto (@tls)
 662                                 {
 663                                 $disabled{$proto} = "option(tls)";
 664                                 }
 665                         }
 666                 elsif ($1 eq "static-engine")
 667                         {
 668                         delete $disabled{"dynamic-engine"};
 669                         }
 670                 elsif ($1 eq "dynamic-engine")
 671                         {
 672                         $disabled{"dynamic-engine"} = "option";
 673                         }
 674                 elsif (exists $deprecated_disablables{$1})
 675                         {
 676                         $deprecated_options{$_} = 1;
 677                         if (defined $deprecated_disablables{$1})
 678                                 {
 679                                 $disabled{$deprecated_disablables{$1}} = "option";
 680                                 }
 681                         }
 682                 else
 683                         {
 684                         $disabled{$1} = "option";
 685                         }
 686                 # No longer an automatic choice
 687                 $auto_threads = 0 if ($1 eq "threads");
 688                 }
 689         elsif (/^enable-(.+)$/)
 690                 {
 691                 if ($1 eq "static-engine")
 692                         {
 693                         $disabled{"dynamic-engine"} = "option";
 694                         }
 695                 elsif ($1 eq "dynamic-engine")
 696                         {
 697                         delete $disabled{"dynamic-engine"};
 698                         }
 699                 elsif ($1 eq "zlib-dynamic")
 700                         {
 701                         delete $disabled{"zlib"};
 702                         }
 703                 my $algo = $1;
 704                 delete $disabled{$algo};
 705
 706                 # No longer an automatic choice
 707                 $auto_threads = 0 if ($1 eq "threads");
 708                 }
 709         elsif (/^--strict-warnings$/)
 710                 {
 711                 $strict_warnings = 1;
 712                 }
 713         elsif (/^--debug$/)
 714                 {
 715                 $config{build_type} = "debug";
 716                 }
 717         elsif (/^--release$/)
 718                 {
 719                 $config{build_type} = "release";
 720                 }
 721         elsif (/^386$/)
 722                 { $config{processor}=386; }
 723         elsif (/^fips$/)
 724                 {
 725                 die "FIPS mode not supported\n";
 726                 }
 727         elsif (/^rsaref$/)
 728                 {
 729                 # No RSAref support any more since it's not needed.
 730                 # The check for the option is there so scripts aren't
 731                 # broken
 732                 }
 733         elsif (/^nofipscanistercheck$/)
 734                 {
 735                 die "FIPS mode not supported\n";
 736                 }
 737         elsif (/^[-+]/)
 738                 {
 739                 if (/^--prefix=(.*)$/)
 740                         {
 741                         $config{prefix}=$1;
 742                         die "Directory given with --prefix MUST be absolute\n"
 743                                 unless file_name_is_absolute($config{prefix});
 744                         }
 745                 elsif (/^--api=(.*)$/)
 746                         {
 747                         $config{api}=$1;
 748                         }
 749                 elsif (/^--libdir=(.*)$/)
 750                         {
 751                         $config{libdir}=$1;
 752                         }
 753                 elsif (/^--openssldir=(.*)$/)
 754                         {
 755                         $config{openssldir}=$1;
 756                         }
 757                 elsif (/^--with-zlib-lib=(.*)$/)
 758                         {
 759                         $withargs{zlib_lib}=$1;
 760                         }
 761                 elsif (/^--with-zlib-include=(.*)$/)
 762                         {
 763                         $withargs{zlib_include}=$1;
 764                         }
 765                 elsif (/^--with-fuzzer-lib=(.*)$/)
 766                         {
 767                         $withargs{fuzzer_lib}=$1;
 768                         }
 769                 elsif (/^--with-fuzzer-include=(.*)$/)
 770                         {
 771                         $withargs{fuzzer_include}=$1;
 772                         }
 773                 elsif (/^--with-rand-seed=(.*)$/)
 774                         {
 775                         foreach my $x (split(m|,|, $1))
 776                             {
 777                             die "Unknown --with-rand-seed choice $x\n"
 778                                 if ! grep { $x eq $_ } @known_seed_sources;
 779                             push @seed_sources, $x;
 780                             }
 781                         }
 782                 elsif (/^--cross-compile-prefix=(.*)$/)
 783                         {
 784                         $config{cross_compile_prefix}=$1;
 785                         }
 786                 elsif (/^--config=(.*)$/)
 787                         {
 788                         read_config $1;
 789                         }
 790                 elsif (/^-L(.*)$/)
 791                         {
 792                         push @{$useradd{LDFLAGS}}, $_;
 793                         }
 794                 elsif (/^-l(.*)$/ or /^-Wl,/)
 795                         {
 796                         push @{$useradd{LDLIBS}}, $_;
 797                         }
 798                 elsif (/^-framework$/)
 799                         {
 800                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 801                         }
 802                 elsif (/^-rpath$/ or /^-R$/)
 803                         # -rpath is the OSF1 rpath flag
 804                         # -R is the old Solaris rpath flag
 805                         {
 806                         my $rpath = shift(@argvcopy) || "";
 807                         $rpath .= " " if $rpath ne "";
 808                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 809                         }
 810                 elsif (/^-static$/)
 811                         {
 812                         push @{$useradd{LDFLAGS}}, $_;
 813                         $disabled{"dso"} = "forced";
 814                         $disabled{"pic"} = "forced";
 815                         $disabled{"shared"} = "forced";
 816                         $disabled{"threads"} = "forced";
 817                         }
 818                 elsif (/^-D(.*)$/)
 819                         {
 820                         push @{$useradd{CPPDEFINES}}, $1;
 821                         }
 822                 elsif (/^-I(.*)$/)
 823                         {
 824                         push @{$useradd{CPPINCLUDES}}, $1;
 825                         }
 826                 elsif (/^-Wp,$/)
 827                         {
 828                         push @{$useradd{CPPFLAGS}}, $1;
 829                         }
 830                 else    # common if (/^[-+]/), just pass down...
 831                         {
 832                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 833                         push @{$useradd{CFLAGS}}, $_;
 834                         push @{$useradd{CXXFLAGS}}, $_;
 835                         }
 836                 }
 837         else
 838                 {
 839                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 840                 $target=$_;
 841                 }
 842         unless ($_ eq $target || /^no-/ || /^disable-/)
 843                 {
 844                 # "no-..." follows later after implied deactivations
 845                 # have been derived.  (Don't take this too seriously,
 846                 # we really only write OPTIONS to the Makefile out of
 847                 # nostalgia.)
 848
 849                 if ($config{options} eq "")
 850                         { $config{options} = $_; }
 851                 else
 852                         { $config{options} .= " ".$_; }
 853                 }
 854
 855         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 856                 die "***** Unsupported api compatibility level: $config{api}\n",
 857         }
 858
 859         if (keys %deprecated_options)
 860                 {
 861                 warn "***** Deprecated options: ",
 862                         join(", ", keys %deprecated_options), "\n";
 863                 }
 864         if (keys %unsupported_options)
 865                 {
 866                 die "***** Unsupported options: ",
 867                         join(", ", keys %unsupported_options), "\n";
 868                 }
 869         }
 870
 871 foreach (keys %user) {
 872     my $value = env($_);
 873     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef;
 874
 875     if (defined $value) {
 876         if (ref $user{$_} eq 'ARRAY') {
 877             $user{$_} = [ split /$list_separator_re/, $value ];
 878         } elsif (!defined $user{$_}) {
 879             $user{$_} = $value;
 880         }
 881     }
 882 }
 883
 884 if (grep { $_ =~ /(^|\s)-Wl,-rpath,/ } ($user{LDLIBS} ? @{$user{LDLIBS}} : ())
 885     && !$disabled{shared}
 886     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 887     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 888         "***** any of asan, msan or ubsan\n";
 889 }
 890
 891 if (scalar(@seed_sources) == 0) {
 892     print "Using implicit seed configuration\n";
 893     push @seed_sources, 'os';
 894 }
 895 die "Cannot seed with none and anything else"
 896     if scalar(grep { $_ eq 'none' } @seed_sources) > 0
 897         && scalar(@seed_sources) > 1;
 898 push @{$config{openssl_other_defines}},
 899      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
 900         @seed_sources;
 901
 902 my @tocheckfor = (keys %disabled);
 903 while (@tocheckfor) {
 904     my %new_tocheckfor = ();
 905     my @cascade_copy = (@disable_cascades);
 906     while (@cascade_copy) {
 907         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 908         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 909             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 910                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 911             }
 912         }
 913     }
 914     @tocheckfor = (keys %new_tocheckfor);
 915 }
 916
 917 our $die = sub { die @_; };
 918 if ($target eq "TABLE") {
 919     local $die = sub { warn @_; };
 920     foreach (sort keys %table) {
 921         print_table_entry($_, "TABLE");
 922     }
 923     exit 0;
 924 }
 925
 926 if ($target eq "LIST") {
 927     foreach (sort keys %table) {
 928         print $_,"\n" unless $table{$_}->{template};
 929     }
 930     exit 0;
 931 }
 932
 933 if ($target eq "HASH") {
 934     local $die = sub { warn @_; };
 935     print "%table = (\n";
 936     foreach (sort keys %table) {
 937         print_table_entry($_, "HASH");
 938     }
 939     exit 0;
 940 }
 941
 942 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 943 print "for $target\n";
 944
 945 # Backward compatibility?
 946 if ($target =~ m/^CygWin32(-.*)$/) {
 947     $target = "Cygwin".$1;
 948 }
 949
 950 # Support for legacy targets having a name starting with 'debug-'
 951 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 952 if ($d) {
 953     $config{build_type} = "debug";
 954
 955     # If we do not find debug-foo in the table, the target is set to foo.
 956     if (!$table{$target}) {
 957         $target = $t;
 958     }
 959 }
 960 $config{target} = $target;
 961 my %target = resolve_config($target);
 962
 963 &usage if (!%target || $target{template});
 964
 965 %target = ( %{$table{DEFAULTS}}, %target );
 966
 967 # Make the flags to build DSOs the same as for shared libraries unless they
 968 # are already defined
 969 $target{dso_cflags} = $target{shared_cflag} unless defined $target{dso_cflags};
 970 $target{dso_cxxflags} = $target{shared_cxxflag} unless defined $target{dso_cxxflags};
 971 $target{dso_lflags} = $target{shared_ldflag} unless defined $target{dso_lflags};
 972 {
 973     my $shared_info_pl =
 974         catfile(dirname($0), "Configurations", "shared-info.pl");
 975     my %shared_info = read_eval_file($shared_info_pl);
 976     push @{$target{_conf_fname_int}}, $shared_info_pl;
 977     my $si = $target{shared_target};
 978     while (ref $si ne "HASH") {
 979         last if ! defined $si;
 980         if (ref $si eq "CODE") {
 981             $si = $si->();
 982         } else {
 983             $si = $shared_info{$si};
 984         }
 985     }
 986
 987     # Some of the 'shared_target' values don't have any entried in
 988     # %shared_info.  That's perfectly fine, AS LONG AS the build file
 989     # template knows how to handle this.  That is currently the case for
 990     # Windows and VMS.
 991     if (defined $si) {
 992         # Just as above, copy certain shared_* attributes to the corresponding
 993         # dso_ attribute unless the latter is already defined
 994         $si->{dso_cflags} = $si->{shared_cflag} unless defined $si->{dso_cflags};
 995         $si->{dso_cxxflags} = $si->{shared_cxxflag} unless defined $si->{dso_cxxflags};
 996         $si->{dso_lflags} = $si->{shared_ldflag} unless defined $si->{dso_lflags};
 997         foreach (sort keys %$si) {
 998             $target{$_} = defined $target{$_}
 999                 ? add($si->{$_})->($target{$_})
1000                 : $si->{$_};
1001         }
1002     }
1003 }
1004
1005 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1006 $config{conf_files} = [ sort keys %conf_files ];
1007
1008 foreach my $feature (@{$target{disable}}) {
1009     if (exists $deprecated_disablables{$feature}) {
1010         warn "***** config $target disables deprecated feature $feature\n";
1011     } elsif (!grep { $feature eq $_ } @disablables) {
1012         die "***** config $target disables unknown feature $feature\n";
1013     }
1014     $disabled{$feature} = 'config';
1015 }
1016 foreach my $feature (@{$target{enable}}) {
1017     if ("default" eq ($disabled{$_} // "")) {
1018         if (exists $deprecated_disablables{$feature}) {
1019             warn "***** config $target enables deprecated feature $feature\n";
1020         } elsif (!grep { $feature eq $_ } @disablables) {
1021             die "***** config $target enables unknown feature $feature\n";
1022         }
1023         delete $disabled{$_};
1024     }
1025 }
1026
1027 $target{cxxflags}//=$target{cflags} if $target{cxx};
1028 $target{exe_extension}="";
1029 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1030                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1031 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1032
1033 ($target{shared_extension_simple}=$target{shared_extension})
1034     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||;
1035 $target{dso_extension}=$target{shared_extension_simple};
1036 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1037     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1038
1039
1040 $config{cross_compile_prefix} = env('CROSS_COMPILE')
1041     if $config{cross_compile_prefix} eq "";
1042
1043 # Allow overriding the names of some tools.  USE WITH CARE
1044 # Note: only Unix cares about HASHBANGPERL...  that explains
1045 # the default string.
1046 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
1047 foreach (keys %user) {
1048     my $target_key = $user_to_target{$_} // lc $_;
1049     my $ref_type = ref $user{$_};
1050
1051     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1052     # and a value that's to be coerced into that type.
1053     my $mkvalue = sub {
1054         my $type = shift;
1055         my $value = shift;
1056         my $undef_p = shift;
1057
1058         die "Too many arguments for \$mkvalue" if @_;
1059
1060         while (ref $value eq 'CODE') {
1061             $value = $value->();
1062         }
1063
1064         if ($type eq 'ARRAY') {
1065             return undef unless defined $value;
1066             return undef if ref $value ne 'ARRAY' && !$value;
1067             return undef if ref $value eq 'ARRAY' && !@$value;
1068             return [ $value ] unless ref $value eq 'ARRAY';
1069         }
1070         return undef unless $value;
1071         return $value;
1072     };
1073
1074     $config{$target_key} =
1075         $mkvalue->($ref_type, $user{$_})
1076         || $mkvalue->($ref_type, $target{$target_key});
1077     if (defined $useradd{$_} && @{$useradd{$_}}) {
1078         if (defined $config{$target_key}) {
1079             push @{$config{$target_key}}, @{$useradd{$_}};
1080         } else {
1081             $config{$target_key} = [ @{$useradd{$_}} ];
1082         }
1083     }
1084     delete $config{$target_key} unless defined $config{$target_key};
1085 }
1086 $config{plib_lflags} = [ $target{plib_lflags} ];
1087
1088 # Allow overriding the build file name
1089 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1090
1091 # ALL USE OF %useradd MUST BE DONE FROM HERE ON
1092 %useradd = undef;
1093
1094 my %disabled_info = ();         # For configdata.pm
1095 foreach my $what (sort keys %disabled) {
1096     $config{options} .= " no-$what";
1097
1098     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1099                                 'dynamic-engine', 'makedepend',
1100                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1101         (my $WHAT = uc $what) =~ s|-|_|g;
1102
1103         # Fix up C macro end names
1104         $WHAT = "RMD160" if $what eq "ripemd";
1105
1106         # fix-up crypto/directory name(s)
1107         $what = "ripemd" if $what eq "rmd160";
1108         $what = "whrlpool" if $what eq "whirlpool";
1109
1110         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1111
1112         if ((grep { $what eq $_ } @{$config{sdirs}})
1113                 && $what ne 'async' && $what ne 'err') {
1114             @{$config{sdirs}} = grep { $what ne $_} @{$config{sdirs}};
1115             $disabled_info{$what}->{skipped} = [ catdir('crypto', $what) ];
1116
1117             if ($what ne 'engine') {
1118                 push @{$config{openssl_algorithm_defines}}, $macro;
1119             } else {
1120                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
1121                 push @{$disabled_info{engine}->{skipped}}, catdir('engines');
1122                 push @{$config{openssl_other_defines}}, $macro;
1123             }
1124         } else {
1125             push @{$config{openssl_other_defines}}, $macro;
1126         }
1127
1128     }
1129 }
1130
1131 # Make sure build_scheme is consistent.
1132 $target{build_scheme} = [ $target{build_scheme} ]
1133     if ref($target{build_scheme}) ne "ARRAY";
1134
1135 my ($builder, $builder_platform, @builder_opts) =
1136     @{$target{build_scheme}};
1137
1138 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1139                       $builder_platform."-checker.pm")) {
1140     my $checker_path = catfile($srcdir, "Configurations", $checker);
1141     if (-f $checker_path) {
1142         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1143             ? sub { warn $@; } : sub { die $@; };
1144         if (! do $checker_path) {
1145             if ($@) {
1146                 $fn->($@);
1147             } elsif ($!) {
1148                 $fn->($!);
1149             } else {
1150                 $fn->("The detected tools didn't match the platform\n");
1151             }
1152         }
1153         last;
1154     }
1155 }
1156
1157 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1158
1159 if ($target =~ /^mingw/ && `$config{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1160         {
1161         push @{$config{cflags}}, "-mno-cygwin";
1162         push @{$config{cxxflags}}, "-mno-cygwin" if $config{cxx};
1163         push @{$config{shared_ldflag}}, "-mno-cygwin";
1164         }
1165
1166 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1167         && !grep { $_ !~ /-m(ips|arch=)/ } @{$user{CFLAGS}}) {
1168         # minimally required architecture flags for assembly modules
1169         my $value;
1170         $value = '-mips2' if ($target =~ /mips32/);
1171         $value = '-mips3' if ($target =~ /mips64/);
1172         unshift @{$config{cflags}}, $value;
1173         unshift @{$config{cxxflags}}, $value if $config{cxx};
1174 }
1175
1176 # The DSO code currently always implements all functions so that no
1177 # applications will have to worry about that from a compilation point
1178 # of view. However, the "method"s may return zero unless that platform
1179 # has support compiled in for them. Currently each method is enabled
1180 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1181 # string entry into using the following logic;
1182 if (!$disabled{dso} && $target{dso_scheme} ne "")
1183         {
1184         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1185         if ($target{dso_scheme} eq "DLFCN")
1186                 {
1187                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1188                 }
1189         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1190                 {
1191                 unshift @{$config{defines}}, "DSO_DLFCN";
1192                 }
1193         else
1194                 {
1195                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1196                 }
1197         }
1198
1199 # If threads aren't disabled, check how possible they are
1200 unless ($disabled{threads}) {
1201     if ($auto_threads) {
1202         # Enabled by default, disable it forcibly if unavailable
1203         if ($target{thread_scheme} eq "(unknown)") {
1204             $disabled{threads} = "unavailable";
1205         }
1206     } else {
1207         # The user chose to enable threads explicitly, let's see
1208         # if there's a chance that's possible
1209         if ($target{thread_scheme} eq "(unknown)") {
1210             # If the user asked for "threads" and we don't have internal
1211             # knowledge how to do it, [s]he is expected to provide any
1212             # system-dependent compiler options that are necessary.  We
1213             # can't truly check that the given options are correct, but
1214             # we expect the user to know what [s]He is doing.
1215             if (!@{$user{CFLAGS}} && !@{$user{CPPDEFINES}}) {
1216                 die "You asked for multi-threading support, but didn't\n"
1217                     ,"provide any system-specific compiler options\n";
1218             }
1219         }
1220     }
1221 }
1222
1223 # If threads still aren't disabled, add a C macro to ensure the source
1224 # code knows about it.  Any other flag is taken care of by the configs.
1225 unless($disabled{threads}) {
1226     push @{$config{openssl_thread_defines}}, "OPENSSL_THREADS";
1227 }
1228
1229 # With "deprecated" disable all deprecated features.
1230 if (defined($disabled{"deprecated"})) {
1231         $config{api} = $maxapi;
1232 }
1233
1234 my $no_shared_warn=0;
1235 if ($target{shared_target} eq "")
1236         {
1237         $no_shared_warn = 1
1238             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1239         $disabled{shared} = "no-shared-target";
1240         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1241             "no-shared-target";
1242         }
1243
1244 if ($disabled{"dynamic-engine"}) {
1245         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1246         $config{dynamic_engines} = 0;
1247 } else {
1248         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1249         $config{dynamic_engines} = 1;
1250 }
1251
1252 unless ($disabled{asan}) {
1253     push @{$config{cflags}}, "-fsanitize=address";
1254     push @{$config{cxxflags}}, "-fsanitize=address" if $config{cxx};
1255 }
1256
1257 unless ($disabled{ubsan}) {
1258     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1259     # platforms.
1260     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1261     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1262         if $config{cxx};
1263 }
1264
1265 unless ($disabled{msan}) {
1266   push @{$config{cflags}}, "-fsanitize=memory";
1267   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{cxx};
1268 }
1269
1270 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1271         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1272     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1273     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{cxx};
1274 }
1275 #
1276 # Platform fix-ups
1277 #
1278
1279 # This saves the build files from having to check
1280 if ($disabled{pic})
1281         {
1282         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1283                     shared_defines shared_includes shared_ldflag
1284                     dso_cflags dso_cxxflags dso_cppflags
1285                     dso_defines dso_includes dso_lflags))
1286                 {
1287                 delete $config{$_};
1288                 $target{$_} = "";
1289                 }
1290         }
1291 else
1292         {
1293         push @{$config{defines}}, "OPENSSL_PIC";
1294         }
1295
1296 if ($target{sys_id} ne "")
1297         {
1298         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1299         }
1300
1301 unless ($disabled{asm}) {
1302     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1303     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1304
1305     # bn-586 is the only one implementing bn_*_part_words
1306     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1307     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1308
1309     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1310     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1311     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1312
1313     if ($target{sha1_asm_src}) {
1314         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1315         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1316         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1317     }
1318     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1319         push @{$config{defines}}, "RC4_ASM";
1320     }
1321     if ($target{md5_asm_src}) {
1322         push @{$config{defines}}, "MD5_ASM";
1323     }
1324     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1325     if ($target{rmd160_asm_src}) {
1326         push @{$config{defines}}, "RMD160_ASM";
1327     }
1328     if ($target{aes_asm_src}) {
1329         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1330         # aes-ctr.fake is not a real file, only indication that assembler
1331         # module implements AES_ctr32_encrypt...
1332         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1333         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1334         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1335         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1336         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1337         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1338     }
1339     if ($target{wp_asm_src} =~ /mmx/) {
1340         if ($config{processor} eq "386") {
1341             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1342         } elsif (!$disabled{"whirlpool"}) {
1343             push @{$config{defines}}, "WHIRLPOOL_ASM";
1344         }
1345     }
1346     if ($target{modes_asm_src} =~ /ghash-/) {
1347         push @{$config{defines}}, "GHASH_ASM";
1348     }
1349     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1350         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1351     }
1352     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1353         push @{$config{defines}}, "PADLOCK_ASM";
1354     }
1355     if ($target{poly1305_asm_src} ne "") {
1356         push @{$config{defines}}, "POLY1305_ASM";
1357     }
1358 }
1359
1360 my %predefined = compiler_predefined($config{cc});
1361
1362 # Check for makedepend capabilities.
1363 if (!$disabled{makedepend}) {
1364     if ($config{target} =~ /^(VC|vms)-/) {
1365         # For VC- and vms- targets, there's nothing more to do here.  The
1366         # functionality is hard coded in the corresponding build files for
1367         # cl (Windows) and CC/DECC (VMS).
1368     } elsif ($predefined{__GNUC__} >= 3) {
1369         # We know that GNU C version 3 and up as well as all clang
1370         # versions support dependency generation
1371         $config{makedepprog} = "\$(CROSS_COMPILE)$config{cc}";
1372     } else {
1373         # In all other cases, we look for 'makedepend', and disable the
1374         # capability if not found.
1375         $config{makedepprog} = which('makedepend');
1376         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1377     }
1378 }
1379
1380
1381 # Deal with bn_ops ###################################################
1382
1383 $config{bn_ll}                  =0;
1384 $config{export_var_as_fn}       =0;
1385 my $def_int="unsigned int";
1386 $config{rc4_int}                =$def_int;
1387 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1388
1389 my $count = 0;
1390 foreach (sort split(/\s+/,$target{bn_ops})) {
1391     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1392     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1393     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1394     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1395     ($config{b64l},$config{b64},$config{b32})
1396         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1397     ($config{b64l},$config{b64},$config{b32})
1398         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1399     ($config{b64l},$config{b64},$config{b32})
1400         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1401 }
1402 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1403     if $count > 1;
1404
1405
1406 # Hack cflags for better warnings (dev option) #######################
1407
1408 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1409 # a string and works as well on command lines.
1410 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1411                         @{$config{cflags}} ];
1412 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1413                           @{$config{cxxflags}} ] if $config{cxx};
1414
1415 if (defined($config{api})) {
1416     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1417     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1418     push @{$config{defines}}, $apiflag;
1419 }
1420
1421 if (defined($predefined{__clang__}) && !$disabled{asm}) {
1422     push @{$config{cflags}}, "-Qunused-arguments";
1423     push @{$config{cxxflags}}, "-Qunused-arguments" if $config{cxx};
1424 }
1425
1426 if ($strict_warnings)
1427         {
1428         my $wopt;
1429         my $gccver = $predefined{__GNUC__} // -1;
1430
1431         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1432             unless $gccver >= 4;
1433         $gcc_devteam_warn .= " -Wmisleading-indentation" if $gccver >= 6;
1434         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1435                 {
1436                 push @{$config{cflags}}, $wopt
1437                         unless grep { $_ eq $wopt } @{$config{cflags}};
1438                 push @{$config{cxxflags}}, $wopt
1439                         if ($config{cxx}
1440                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1441                 }
1442         if (defined($predefined{__clang__}))
1443                 {
1444                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1445                         {
1446                         push @{$config{cflags}}, $wopt
1447                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1448                         push @{$config{cxxflags}}, $wopt
1449                                 if ($config{cxx}
1450                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1451                         }
1452                 }
1453         }
1454
1455 unless ($disabled{"crypto-mdebug-backtrace"})
1456         {
1457         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1458                 {
1459                 push @{$config{cflags}}, $wopt
1460                         unless grep { $_ eq $wopt } @{$config{cflags}};
1461                 push @{$config{cxxflags}}, $wopt
1462                         if ($config{cxx}
1463                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1464                 }
1465         if ($target =~ /^BSD-/)
1466                 {
1467                 push @{$config{ex_libs}}, "-lexecinfo";
1468                 }
1469         }
1470
1471 unless ($disabled{afalgeng}) {
1472     $config{afalgeng}="";
1473     if ($target =~ m/^linux/) {
1474         my $minver = 4*10000 + 1*100 + 0;
1475         if ($config{cross_compile_prefix} eq "") {
1476             my $verstr = `uname -r`;
1477             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1478             ($mi2) = $mi2 =~ /(\d+)/;
1479             my $ver = $ma*10000 + $mi1*100 + $mi2;
1480             if ($ver < $minver) {
1481                 $disabled{afalgeng} = "too-old-kernel";
1482             } else {
1483                 push @{$config{engdirs}}, "afalg";
1484             }
1485         } else {
1486             $disabled{afalgeng} = "cross-compiling";
1487         }
1488     } else {
1489         $disabled{afalgeng}  = "not-linux";
1490     }
1491 }
1492
1493 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1494
1495 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1496
1497 # If we use the unified build, collect information from build.info files
1498 my %unified_info = ();
1499
1500 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1501 if ($builder eq "unified") {
1502     use with_fallback qw(Text::Template);
1503
1504     sub cleandir {
1505         my $base = shift;
1506         my $dir = shift;
1507         my $relativeto = shift || ".";
1508
1509         $dir = catdir($base,$dir) unless isabsolute($dir);
1510
1511         # Make sure the directories we're building in exists
1512         mkpath($dir);
1513
1514         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1515         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1516         return $res;
1517     }
1518
1519     sub cleanfile {
1520         my $base = shift;
1521         my $file = shift;
1522         my $relativeto = shift || ".";
1523
1524         $file = catfile($base,$file) unless isabsolute($file);
1525
1526         my $d = dirname($file);
1527         my $f = basename($file);
1528
1529         # Make sure the directories we're building in exists
1530         mkpath($d);
1531
1532         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1533         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1534         return $res;
1535     }
1536
1537     # Store the name of the template file we will build the build file from
1538     # in %config.  This may be useful for the build file itself.
1539     my @build_file_template_names =
1540         ( $builder_platform."-".$target{build_file}.".tmpl",
1541           $target{build_file}.".tmpl" );
1542     my @build_file_templates = ();
1543
1544     # First, look in the user provided directory, if given
1545     if (defined env($local_config_envname)) {
1546         @build_file_templates =
1547             map {
1548                 if ($^O eq 'VMS') {
1549                     # VMS environment variables are logical names,
1550                     # which can be used as is
1551                     $local_config_envname . ':' . $_;
1552                 } else {
1553                     catfile(env($local_config_envname), $_);
1554                 }
1555             }
1556             @build_file_template_names;
1557     }
1558     # Then, look in our standard directory
1559     push @build_file_templates,
1560         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1561           @build_file_template_names );
1562
1563     my $build_file_template;
1564     for $_ (@build_file_templates) {
1565         $build_file_template = $_;
1566         last if -f $build_file_template;
1567
1568         $build_file_template = undef;
1569     }
1570     if (!defined $build_file_template) {
1571         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1572     }
1573     $config{build_file_templates}
1574       = [ $build_file_template,
1575           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1576                     $blddir) ];
1577
1578     my @build_infos = ( [ ".", "build.info" ] );
1579     foreach (@{$config{dirs}}) {
1580         push @build_infos, [ $_, "build.info" ]
1581             if (-f catfile($srcdir, $_, "build.info"));
1582     }
1583     foreach (@{$config{sdirs}}) {
1584         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1585             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1586     }
1587     foreach (@{$config{engdirs}}) {
1588         push @build_infos, [ catdir("engines", $_), "build.info" ]
1589             if (-f catfile($srcdir, "engines", $_, "build.info"));
1590     }
1591     foreach (@{$config{tdirs}}) {
1592         push @build_infos, [ catdir("test", $_), "build.info" ]
1593             if (-f catfile($srcdir, "test", $_, "build.info"));
1594     }
1595
1596     $config{build_infos} = [ ];
1597
1598     my %ordinals = ();
1599     foreach (@build_infos) {
1600         my $sourced = catdir($srcdir, $_->[0]);
1601         my $buildd = catdir($blddir, $_->[0]);
1602
1603         mkpath($buildd);
1604
1605         my $f = $_->[1];
1606         # The basic things we're trying to build
1607         my @programs = ();
1608         my @programs_install = ();
1609         my @libraries = ();
1610         my @libraries_install = ();
1611         my @engines = ();
1612         my @engines_install = ();
1613         my @scripts = ();
1614         my @scripts_install = ();
1615         my @extra = ();
1616         my @overrides = ();
1617         my @intermediates = ();
1618         my @rawlines = ();
1619
1620         my %sources = ();
1621         my %shared_sources = ();
1622         my %includes = ();
1623         my %depends = ();
1624         my %renames = ();
1625         my %sharednames = ();
1626         my %generate = ();
1627
1628         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1629         my $template =
1630             Text::Template->new(TYPE => 'FILE',
1631                                 SOURCE => catfile($sourced, $f),
1632                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1633         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1634         my @text =
1635             split /^/m,
1636             $template->fill_in(HASH => { config => \%config,
1637                                          target => \%target,
1638                                          disabled => \%disabled,
1639                                          withargs => \%withargs,
1640                                          builddir => abs2rel($buildd, $blddir),
1641                                          sourcedir => abs2rel($sourced, $blddir),
1642                                          buildtop => abs2rel($blddir, $blddir),
1643                                          sourcetop => abs2rel($srcdir, $blddir) },
1644                                DELIMITERS => [ "{-", "-}" ]);
1645
1646         # The top item of this stack has the following values
1647         # -2 positive already run and we found ELSE (following ELSIF should fail)
1648         # -1 positive already run (skip until ENDIF)
1649         # 0 negatives so far (if we're at a condition, check it)
1650         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1651         # 2 positive ELSE (following ELSIF should fail)
1652         my @skip = ();
1653         collect_information(
1654             collect_from_array([ @text ],
1655                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1656                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1657             # Info we're looking for
1658             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1659             => sub {
1660                 if (! @skip || $skip[$#skip] > 0) {
1661                     push @skip, !! $1;
1662                 } else {
1663                     push @skip, -1;
1664                 }
1665             },
1666             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1667             => sub { die "ELSIF out of scope" if ! @skip;
1668                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1669                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1670                      $skip[$#skip] = !! $1
1671                          if $skip[$#skip] == 0; },
1672             qr/^\s*ELSE\s*$/
1673             => sub { die "ELSE out of scope" if ! @skip;
1674                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1675                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1676             qr/^\s*ENDIF\s*$/
1677             => sub { die "ENDIF out of scope" if ! @skip;
1678                      pop @skip; },
1679             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1680             => sub {
1681                 if (!@skip || $skip[$#skip] > 0) {
1682                     my $install = $1;
1683                     my @x = tokenize($2);
1684                     push @programs, @x;
1685                     push @programs_install, @x unless $install;
1686                 }
1687             },
1688             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1689             => sub {
1690                 if (!@skip || $skip[$#skip] > 0) {
1691                     my $install = $1;
1692                     my @x = tokenize($2);
1693                     push @libraries, @x;
1694                     push @libraries_install, @x unless $install;
1695                 }
1696             },
1697             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1698             => sub {
1699                 if (!@skip || $skip[$#skip] > 0) {
1700                     my $install = $1;
1701                     my @x = tokenize($2);
1702                     push @engines, @x;
1703                     push @engines_install, @x unless $install;
1704                 }
1705             },
1706             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1707             => sub {
1708                 if (!@skip || $skip[$#skip] > 0) {
1709                     my $install = $1;
1710                     my @x = tokenize($2);
1711                     push @scripts, @x;
1712                     push @scripts_install, @x unless $install;
1713                 }
1714             },
1715             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1716             => sub { push @extra, tokenize($1)
1717                          if !@skip || $skip[$#skip] > 0 },
1718             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1719             => sub { push @overrides, tokenize($1)
1720                          if !@skip || $skip[$#skip] > 0 },
1721
1722             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1723             => sub { push @{$ordinals{$1}}, tokenize($2)
1724                          if !@skip || $skip[$#skip] > 0 },
1725             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1726             => sub { push @{$sources{$1}}, tokenize($2)
1727                          if !@skip || $skip[$#skip] > 0 },
1728             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1729             => sub { push @{$shared_sources{$1}}, tokenize($2)
1730                          if !@skip || $skip[$#skip] > 0 },
1731             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1732             => sub { push @{$includes{$1}}, tokenize($2)
1733                          if !@skip || $skip[$#skip] > 0 },
1734             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1735             => sub { push @{$depends{$1}}, tokenize($2)
1736                          if !@skip || $skip[$#skip] > 0 },
1737             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1738             => sub { push @{$generate{$1}}, $2
1739                          if !@skip || $skip[$#skip] > 0 },
1740             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1741             => sub { push @{$renames{$1}}, tokenize($2)
1742                          if !@skip || $skip[$#skip] > 0 },
1743             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1744             => sub { push @{$sharednames{$1}}, tokenize($2)
1745                          if !@skip || $skip[$#skip] > 0 },
1746             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1747             => sub {
1748                 my $lineiterator = shift;
1749                 my $target_kind = $1;
1750                 while (defined $lineiterator->()) {
1751                     s|\R$||;
1752                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1753                         die "ENDRAW doesn't match BEGINRAW"
1754                             if $1 ne $target_kind;
1755                         last;
1756                     }
1757                     next if @skip && $skip[$#skip] <= 0;
1758                     push @rawlines,  $_
1759                         if ($target_kind eq $target{build_file}
1760                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1761                 }
1762             },
1763             qr/^\s*(?:#.*)?$/ => sub { },
1764             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1765             "BEFORE" => sub {
1766                 if ($buildinfo_debug) {
1767                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1768                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1769                 }
1770             },
1771             "AFTER" => sub {
1772                 if ($buildinfo_debug) {
1773                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1774                 }
1775             },
1776             );
1777         die "runaway IF?" if (@skip);
1778
1779         foreach (keys %renames) {
1780             die "$_ renamed to more than one thing: "
1781                 ,join(" ", @{$renames{$_}}),"\n"
1782                 if scalar @{$renames{$_}} > 1;
1783             my $dest = cleanfile($buildd, $_, $blddir);
1784             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1785             die "$dest renamed to more than one thing: "
1786                 ,$unified_info{rename}->{$dest}, $to
1787                 unless !defined($unified_info{rename}->{$dest})
1788                 or $unified_info{rename}->{$dest} eq $to;
1789             $unified_info{rename}->{$dest} = $to;
1790         }
1791
1792         foreach (@programs) {
1793             my $program = cleanfile($buildd, $_, $blddir);
1794             if ($unified_info{rename}->{$program}) {
1795                 $program = $unified_info{rename}->{$program};
1796             }
1797             $unified_info{programs}->{$program} = 1;
1798         }
1799
1800         foreach (@programs_install) {
1801             my $program = cleanfile($buildd, $_, $blddir);
1802             if ($unified_info{rename}->{$program}) {
1803                 $program = $unified_info{rename}->{$program};
1804             }
1805             $unified_info{install}->{programs}->{$program} = 1;
1806         }
1807
1808         foreach (@libraries) {
1809             my $library = cleanfile($buildd, $_, $blddir);
1810             if ($unified_info{rename}->{$library}) {
1811                 $library = $unified_info{rename}->{$library};
1812             }
1813             $unified_info{libraries}->{$library} = 1;
1814         }
1815
1816         foreach (@libraries_install) {
1817             my $library = cleanfile($buildd, $_, $blddir);
1818             if ($unified_info{rename}->{$library}) {
1819                 $library = $unified_info{rename}->{$library};
1820             }
1821             $unified_info{install}->{libraries}->{$library} = 1;
1822         }
1823
1824         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1825 ENGINES can only be used if configured with 'dynamic-engine'.
1826 This is usually a fault in a build.info file.
1827 EOF
1828         foreach (@engines) {
1829             my $library = cleanfile($buildd, $_, $blddir);
1830             if ($unified_info{rename}->{$library}) {
1831                 $library = $unified_info{rename}->{$library};
1832             }
1833             $unified_info{engines}->{$library} = 1;
1834         }
1835
1836         foreach (@engines_install) {
1837             my $library = cleanfile($buildd, $_, $blddir);
1838             if ($unified_info{rename}->{$library}) {
1839                 $library = $unified_info{rename}->{$library};
1840             }
1841             $unified_info{install}->{engines}->{$library} = 1;
1842         }
1843
1844         foreach (@scripts) {
1845             my $script = cleanfile($buildd, $_, $blddir);
1846             if ($unified_info{rename}->{$script}) {
1847                 $script = $unified_info{rename}->{$script};
1848             }
1849             $unified_info{scripts}->{$script} = 1;
1850         }
1851
1852         foreach (@scripts_install) {
1853             my $script = cleanfile($buildd, $_, $blddir);
1854             if ($unified_info{rename}->{$script}) {
1855                 $script = $unified_info{rename}->{$script};
1856             }
1857             $unified_info{install}->{scripts}->{$script} = 1;
1858         }
1859
1860         foreach (@extra) {
1861             my $extra = cleanfile($buildd, $_, $blddir);
1862             $unified_info{extra}->{$extra} = 1;
1863         }
1864
1865         foreach (@overrides) {
1866             my $override = cleanfile($buildd, $_, $blddir);
1867             $unified_info{overrides}->{$override} = 1;
1868         }
1869
1870         push @{$unified_info{rawlines}}, @rawlines;
1871
1872         unless ($disabled{shared}) {
1873             # Check sharednames.
1874             foreach (keys %sharednames) {
1875                 my $dest = cleanfile($buildd, $_, $blddir);
1876                 if ($unified_info{rename}->{$dest}) {
1877                     $dest = $unified_info{rename}->{$dest};
1878                 }
1879                 die "shared_name for $dest with multiple values: "
1880                     ,join(" ", @{$sharednames{$_}}),"\n"
1881                     if scalar @{$sharednames{$_}} > 1;
1882                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1883                 die "shared_name found for a library $dest that isn't defined\n"
1884                     unless $unified_info{libraries}->{$dest};
1885                 die "shared_name for $dest with multiple values: "
1886                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1887                     unless !defined($unified_info{sharednames}->{$dest})
1888                     or $unified_info{sharednames}->{$dest} eq $to;
1889                 $unified_info{sharednames}->{$dest} = $to;
1890             }
1891
1892             # Additionally, we set up sharednames for libraries that don't
1893             # have any, as themselves.  Only for libraries that aren't
1894             # explicitly static.
1895             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1896                 if (!defined $unified_info{sharednames}->{$_}) {
1897                     $unified_info{sharednames}->{$_} = $_
1898                 }
1899             }
1900
1901             # Check that we haven't defined any library as both shared and
1902             # explicitly static.  That is forbidden.
1903             my @doubles = ();
1904             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1905                 (my $l = $_) =~ s/\.a$//;
1906                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1907             }
1908             die "these libraries are both explicitly static and shared:\n  ",
1909                 join(" ", @doubles), "\n"
1910                 if @doubles;
1911         }
1912
1913         foreach (keys %sources) {
1914             my $dest = $_;
1915             my $ddest = cleanfile($buildd, $_, $blddir);
1916             if ($unified_info{rename}->{$ddest}) {
1917                 $ddest = $unified_info{rename}->{$ddest};
1918             }
1919             foreach (@{$sources{$dest}}) {
1920                 my $s = cleanfile($sourced, $_, $blddir);
1921
1922                 # If it isn't in the source tree, we assume it's generated
1923                 # in the build tree
1924                 if (! -f $s) {
1925                     $s = cleanfile($buildd, $_, $blddir);
1926                 }
1927                 # We recognise C++, C and asm files
1928                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1929                     my $o = $_;
1930                     $o =~ s/\.[csS]$/.o/; # C and assembler
1931                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1932                     $o = cleanfile($buildd, $o, $blddir);
1933                     $unified_info{sources}->{$ddest}->{$o} = 1;
1934                     $unified_info{sources}->{$o}->{$s} = 1;
1935                 } else {
1936                     $unified_info{sources}->{$ddest}->{$s} = 1;
1937                 }
1938             }
1939         }
1940
1941         foreach (keys %shared_sources) {
1942             my $dest = $_;
1943             my $ddest = cleanfile($buildd, $_, $blddir);
1944             if ($unified_info{rename}->{$ddest}) {
1945                 $ddest = $unified_info{rename}->{$ddest};
1946             }
1947             foreach (@{$shared_sources{$dest}}) {
1948                 my $s = cleanfile($sourced, $_, $blddir);
1949
1950                 # If it isn't in the source tree, we assume it's generated
1951                 # in the build tree
1952                 if (! -f $s) {
1953                     $s = cleanfile($buildd, $_, $blddir);
1954                 }
1955
1956                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1957                     # We recognise C++, C and asm files
1958                     my $o = $_;
1959                     $o =~ s/\.[csS]$/.o/; # C and assembler
1960                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1961                     $o = cleanfile($buildd, $o, $blddir);
1962                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1963                     $unified_info{sources}->{$o}->{$s} = 1;
1964                 } elsif ($s =~ /\.rc$/) {
1965                     # We also recognise resource files
1966                     my $o = $_;
1967                     $o =~ s/\.rc$/.res/; # Resource configuration
1968                     my $o = cleanfile($buildd, $o, $blddir);
1969                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1970                     $unified_info{sources}->{$o}->{$s} = 1;
1971                 } elsif ($s =~ /\.(def|map|opt)$/) {
1972                     # We also recognise .def / .map / .opt files
1973                     # We know they are generated files
1974                     my $def = cleanfile($buildd, $s, $blddir);
1975                     $unified_info{shared_sources}->{$ddest}->{$def} = 1;
1976                 } else {
1977                     die "unrecognised source file type for shared library: $s\n";
1978                 }
1979             }
1980         }
1981
1982         foreach (keys %generate) {
1983             my $dest = $_;
1984             my $ddest = cleanfile($buildd, $_, $blddir);
1985             if ($unified_info{rename}->{$ddest}) {
1986                 $ddest = $unified_info{rename}->{$ddest};
1987             }
1988             die "more than one generator for $dest: "
1989                     ,join(" ", @{$generate{$_}}),"\n"
1990                     if scalar @{$generate{$_}} > 1;
1991             my @generator = split /\s+/, $generate{$dest}->[0];
1992             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1993             $unified_info{generate}->{$ddest} = [ @generator ];
1994         }
1995
1996         foreach (keys %depends) {
1997             my $dest = $_;
1998             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1999
2000             # If the destination doesn't exist in source, it can only be
2001             # a generated file in the build tree.
2002             if ($ddest ne "" && ! -f $ddest) {
2003                 $ddest = cleanfile($buildd, $_, $blddir);
2004                 if ($unified_info{rename}->{$ddest}) {
2005                     $ddest = $unified_info{rename}->{$ddest};
2006                 }
2007             }
2008             foreach (@{$depends{$dest}}) {
2009                 my $d = cleanfile($sourced, $_, $blddir);
2010
2011                 # If we know it's generated, or assume it is because we can't
2012                 # find it in the source tree, we set file we depend on to be
2013                 # in the build tree rather than the source tree, and assume
2014                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2015                 # section or in the Makefile template.
2016                 if (! -f $d
2017                     || (grep { $d eq $_ }
2018                         map { cleanfile($srcdir, $_, $blddir) }
2019                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2020                     $d = cleanfile($buildd, $_, $blddir);
2021                 }
2022                 # Take note if the file to depend on is being renamed
2023                 # Take extra care with files ending with .a, they should
2024                 # be treated without that extension, and the extension
2025                 # should be added back after treatment.
2026                 $d =~ /(\.a)?$/;
2027                 my $e = $1 // "";
2028                 $d = $`;
2029                 if ($unified_info{rename}->{$d}) {
2030                     $d = $unified_info{rename}->{$d};
2031                 }
2032                 $d .= $e;
2033                 $unified_info{depends}->{$ddest}->{$d} = 1;
2034             }
2035         }
2036
2037         foreach (keys %includes) {
2038             my $dest = $_;
2039             my $ddest = cleanfile($sourced, $_, $blddir);
2040
2041             # If the destination doesn't exist in source, it can only be
2042             # a generated file in the build tree.
2043             if (! -f $ddest) {
2044                 $ddest = cleanfile($buildd, $_, $blddir);
2045                 if ($unified_info{rename}->{$ddest}) {
2046                     $ddest = $unified_info{rename}->{$ddest};
2047                 }
2048             }
2049             foreach (@{$includes{$dest}}) {
2050                 my $is = cleandir($sourced, $_, $blddir);
2051                 my $ib = cleandir($buildd, $_, $blddir);
2052                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2053                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2054                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2055                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2056             }
2057         }
2058     }
2059
2060     my $ordinals_text = join(', ', sort keys %ordinals);
2061     warn <<"EOF" if $ordinals_text;
2062
2063 WARNING: ORDINALS were specified for $ordinals_text
2064 They are ignored and should be replaced with a combination of GENERATE,
2065 DEPEND and SHARED_SOURCE.
2066 EOF
2067
2068     # Massage the result
2069
2070     # If we depend on a header file or a perl module, add an inclusion of
2071     # its directory to allow smoothe inclusion
2072     foreach my $dest (keys %{$unified_info{depends}}) {
2073         next if $dest eq "";
2074         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2075             next unless $d =~ /\.(h|pm)$/;
2076             if ($d eq "configdata.pm"
2077                     || defined($unified_info{generate}->{$d})) {
2078                 my $i = cleandir($blddir, dirname($d));
2079                 push @{$unified_info{includes}->{$dest}->{build}}, $i
2080                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{build}};
2081             } else {
2082                 my $i = cleandir($srcdir, dirname($d));
2083                 push @{$unified_info{includes}->{$dest}->{source}}, $i
2084                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{source}};
2085             }
2086         }
2087     }
2088
2089     # Trickle down includes placed on libraries, engines and programs to
2090     # their sources (i.e. object files)
2091     foreach my $dest (keys %{$unified_info{engines}},
2092                       keys %{$unified_info{libraries}},
2093                       keys %{$unified_info{programs}}) {
2094         foreach my $k (("source", "build")) {
2095             next unless defined($unified_info{includes}->{$dest}->{$k});
2096             my @incs = reverse @{$unified_info{includes}->{$dest}->{$k}};
2097             foreach my $obj (grep /\.o$/,
2098                              (keys %{$unified_info{sources}->{$dest}},
2099                               keys %{$unified_info{shared_sources}->{$dest}})) {
2100                 foreach my $inc (@incs) {
2101                     unshift @{$unified_info{includes}->{$obj}->{$k}}, $inc
2102                         unless grep { $_ eq $inc } @{$unified_info{includes}->{$obj}->{$k}};
2103                 }
2104             }
2105         }
2106         delete $unified_info{includes}->{$dest};
2107     }
2108
2109     ### Make unified_info a bit more efficient
2110     # One level structures
2111     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2112         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2113     }
2114     # Two level structures
2115     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2116         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2117             $unified_info{$l1}->{$l2} =
2118                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
2119         }
2120     }
2121     # Includes
2122     foreach my $dest (sort keys %{$unified_info{includes}}) {
2123         if (defined($unified_info{includes}->{$dest}->{build})) {
2124             my @source_includes = ();
2125             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2126                 if defined($unified_info{includes}->{$dest}->{source});
2127             $unified_info{includes}->{$dest} =
2128                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2129             foreach my $inc (@source_includes) {
2130                 push @{$unified_info{includes}->{$dest}}, $inc
2131                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2132             }
2133         } else {
2134             $unified_info{includes}->{$dest} =
2135                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2136         }
2137     }
2138 }
2139
2140 # For the schemes that need it, we provide the old *_obj configs
2141 # from the *_asm_obj ones
2142 foreach (grep /_(asm|aux)_src$/, keys %target) {
2143     my $src = $_;
2144     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2145     $target{$obj} = $target{$src};
2146     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2147     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2148 }
2149
2150 # Write down our configuration where it fits #########################
2151
2152 print "Creating configdata.pm\n";
2153 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2154 print OUT <<"EOF";
2155 #! $config{hashbangperl}
2156
2157 package configdata;
2158
2159 use strict;
2160 use warnings;
2161
2162 use Exporter;
2163 #use vars qw(\@ISA \@EXPORT);
2164 our \@ISA = qw(Exporter);
2165 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2166
2167 EOF
2168 print OUT "our %config = (\n";
2169 foreach (sort keys %config) {
2170     if (ref($config{$_}) eq "ARRAY") {
2171         print OUT "  ", $_, " => [ ", join(", ",
2172                                            map { quotify("perl", $_) }
2173                                            @{$config{$_}}), " ],\n";
2174     } elsif (ref($config{$_}) eq "HASH") {
2175         print OUT "  ", $_, " => {";
2176         if (scalar keys %{$config{$_}} > 0) {
2177             print OUT "\n";
2178             foreach my $key (sort keys %{$config{$_}}) {
2179                 print OUT "      ",
2180                     join(" => ",
2181                          quotify("perl", $key),
2182                          defined $config{$_}->{$key}
2183                              ? quotify("perl", $config{$_}->{$key})
2184                              : "undef");
2185                 print OUT ",\n";
2186             }
2187             print OUT "  ";
2188         }
2189         print OUT "},\n";
2190     } else {
2191         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2192     }
2193 }
2194 print OUT <<"EOF";
2195 );
2196
2197 EOF
2198 print OUT "our %target = (\n";
2199 foreach (sort keys %target) {
2200     if (ref($target{$_}) eq "ARRAY") {
2201         print OUT "  ", $_, " => [ ", join(", ",
2202                                            map { quotify("perl", $_) }
2203                                            @{$target{$_}}), " ],\n";
2204     } else {
2205         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2206     }
2207 }
2208 print OUT <<"EOF";
2209 );
2210
2211 EOF
2212 print OUT "our \%available_protocols = (\n";
2213 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2214 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2215 print OUT <<"EOF";
2216 );
2217
2218 EOF
2219 print OUT "our \@disablables = (\n";
2220 foreach (@disablables) {
2221     print OUT "  ", quotify("perl", $_), ",\n";
2222 }
2223 print OUT <<"EOF";
2224 );
2225
2226 EOF
2227 print OUT "our \%disabled = (\n";
2228 foreach (sort keys %disabled) {
2229     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2230 }
2231 print OUT <<"EOF";
2232 );
2233
2234 EOF
2235 print OUT "our %withargs = (\n";
2236 foreach (sort keys %withargs) {
2237     if (ref($withargs{$_}) eq "ARRAY") {
2238         print OUT "  ", $_, " => [ ", join(", ",
2239                                            map { quotify("perl", $_) }
2240                                            @{$withargs{$_}}), " ],\n";
2241     } else {
2242         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2243     }
2244 }
2245 print OUT <<"EOF";
2246 );
2247
2248 EOF
2249 if ($builder eq "unified") {
2250     my $recurse;
2251     $recurse = sub {
2252         my $indent = shift;
2253         foreach (@_) {
2254             if (ref $_ eq "ARRAY") {
2255                 print OUT " "x$indent, "[\n";
2256                 foreach (@$_) {
2257                     $recurse->($indent + 4, $_);
2258                 }
2259                 print OUT " "x$indent, "],\n";
2260             } elsif (ref $_ eq "HASH") {
2261                 my %h = %$_;
2262                 print OUT " "x$indent, "{\n";
2263                 foreach (sort keys %h) {
2264                     if (ref $h{$_} eq "") {
2265                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2266                     } else {
2267                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2268                         $recurse->($indent + 8, $h{$_});
2269                     }
2270                 }
2271                 print OUT " "x$indent, "},\n";
2272             } else {
2273                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2274             }
2275         }
2276     };
2277     print OUT "our %unified_info = (\n";
2278     foreach (sort keys %unified_info) {
2279         if (ref $unified_info{$_} eq "") {
2280             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2281         } else {
2282             print OUT " "x4, quotify("perl", $_), " =>\n";
2283             $recurse->(8, $unified_info{$_});
2284         }
2285     }
2286     print OUT <<"EOF";
2287 );
2288
2289 EOF
2290 }
2291 print OUT "my \%makevars = (\n";
2292 foreach (sort keys %user) {
2293     print OUT '    ',$_,' ' x (20 - length $_),'=> ',
2294         "'",$user_to_target{$_} || lc $_,"',\n";
2295 }
2296 print OUT ");\n";
2297 print OUT "my \%disabled_info = (\n";
2298 foreach my $what (sort keys %disabled_info) {
2299     print OUT "    '$what' => {\n";
2300     foreach my $info (sort keys %{$disabled_info{$what}}) {
2301         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2302             print OUT "        $info => [ ",
2303                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2304                 " ],\n";
2305         } else {
2306             print OUT "        $info => '", $disabled_info{$what}->{$info},
2307                 "',\n";
2308         }
2309     }
2310     print OUT "    },\n";
2311 }
2312 print OUT ");\n";
2313 print OUT << 'EOF';
2314 # If run directly, we can give some answers, and even reconfigure
2315 unless (caller) {
2316     use Getopt::Long;
2317     use File::Spec::Functions;
2318     use File::Basename;
2319     use Pod::Usage;
2320
2321     my $here = dirname($0);
2322
2323     my $dump = undef;
2324     my $cmdline = undef;
2325     my $options = undef;
2326     my $envvars = undef;
2327     my $makevars = undef;
2328     my $buildparams = undef;
2329     my $reconf = undef;
2330     my $verbose = undef;
2331     my $help = undef;
2332     my $man = undef;
2333     GetOptions('dump|d'                 => \$dump,
2334                'command-line|c'         => \$cmdline,
2335                'options|o'              => \$options,
2336                'environment|e'          => \$envvars,
2337                'make-variables|m'       => \$makevars,
2338                'build-parameters|b'     => \$buildparams,
2339                'reconfigure|reconf|r'   => \$reconf,
2340                'verbose|v'              => \$verbose,
2341                'help'                   => \$help,
2342                'man'                    => \$man)
2343         or die "Errors in command line arguments\n";
2344
2345     unless ($dump || $cmdline || $options || $envvars || $makevars
2346             || $buildparams || $reconf || $verbose || $help || $man) {
2347         print STDERR <<"_____";
2348 You must give at least one option.
2349 For more information, do '$0 --help'
2350 _____
2351         exit(2);
2352     }
2353
2354     if ($help) {
2355         pod2usage(-exitval => 0,
2356                   -verbose => 1);
2357     }
2358     if ($man) {
2359         pod2usage(-exitval => 0,
2360                   -verbose => 2);
2361     }
2362     if ($dump || $cmdline) {
2363         print "\n(with current working directory = $here)";
2364         print "\nCommand line:\n\n";
2365         print '    ',join(' ',
2366                           $config{perl},
2367                           catfile($config{sourcedir}, 'Configure'),
2368                           @{$config{perlargv}}), "\n";
2369     }
2370     if ($dump || $options) {
2371         my $longest = 0;
2372         foreach my $what (@disablables) {
2373             $longest = length($what) if $longest < length($what);
2374         }
2375         print "\nEnabled features:\n\n";
2376         foreach my $what (@disablables) {
2377             print "    $what\n" unless $disabled{$what};
2378         }
2379         print "\nDisabled features:\n\n";
2380         foreach my $what (@disablables) {
2381             if ($disabled{$what}) {
2382                 print "    $what", ' ' x ($longest - length($what) + 1),
2383                     "[$disabled{$what}]", ' ' x (10 - length($disabled{$what}));
2384                 print $disabled_info{$what}->{macro}
2385                     if $disabled_info{$what}->{macro};
2386                 print ' (skip ',
2387                     join(', ', @{$disabled_info{$what}->{skipped}}),
2388                     ')'
2389                     if $disabled_info{$what}->{skipped};
2390                 print "\n";
2391             }
2392         }
2393     }
2394     if ($dump || $envvars) {
2395         print "\nRecorded environment:\n\n";
2396         foreach (sort keys %{$config{perlenv}}) {
2397             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2398         }
2399     }
2400     if ($dump || $makevars) {
2401         print "\nMakevars:\n\n";
2402         foreach (sort keys %makevars) {
2403             print '    ',$_,' ' x (16 - length $_),'= ',
2404                 (ref $config{$makevars{$_}} eq 'ARRAY'
2405                  ? join(' ', @{$config{$makevars{$_}}})
2406                  : $config{$makevars{$_}}),
2407                 "\n"
2408                 if defined $config{$makevars{$_}};
2409         }
2410
2411         my @buildfile = ($config{builddir}, $config{build_file});
2412         unshift @buildfile, $here
2413             unless file_name_is_absolute($config{builddir});
2414         my $buildfile = canonpath(catdir(@buildfile));
2415         print <<"_____";
2416
2417 NOTE: These variables only represent the configuration view.  The build file
2418 template may have processed these variables further, please have a look at the
2419 build file for more exact data:
2420     $buildfile
2421 _____
2422     }
2423     if ($dump || $buildparams) {
2424         my @buildfile = ($config{builddir}, $config{build_file});
2425         unshift @buildfile, $here
2426             unless file_name_is_absolute($config{builddir});
2427         print "\nbuild file:\n\n";
2428         print "    ", canonpath(catfile(@buildfile)),"\n";
2429
2430         print "\nbuild file templates:\n\n";
2431         foreach (@{$config{build_file_templates}}) {
2432             my @tmpl = ($_);
2433             unshift @tmpl, $here
2434                 unless file_name_is_absolute($config{sourcedir});
2435             print '    ',canonpath(catfile(@tmpl)),"\n";
2436         }
2437     }
2438     if ($reconf) {
2439         if ($verbose) {
2440             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2441             foreach (sort keys %{$config{perlenv}}) {
2442                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2443             }
2444         }
2445
2446         chdir $here;
2447         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2448     }
2449 }
2450
2451 1;
2452
2453 __END__
2454
2455 =head1 NAME
2456
2457 configdata.pm - configuration data for OpenSSL builds
2458
2459 =head1 SYNOPSIS
2460
2461 Interactive:
2462
2463   perl configdata.pm [options]
2464
2465 As data bank module:
2466
2467   use configdata;
2468
2469 =head1 DESCRIPTION
2470
2471 This module can be used in two modes, interactively and as a module containing
2472 all the data recorded by OpenSSL's Configure script.
2473
2474 When used interactively, simply run it as any perl script, with at least one
2475 option, and you will get the information you ask for.  See L</OPTIONS> below.
2476
2477 When loaded as a module, you get a few databanks with useful information to
2478 perform build related tasks.  The databanks are:
2479
2480     %config             Configured things.
2481     %target             The OpenSSL config target with all inheritances
2482                         resolved.
2483     %disabled           The features that are disabled.
2484     @disablables        The list of features that can be disabled.
2485     %withargs           All data given through --with-THING options.
2486     %unified_info       All information that was computed from the build.info
2487                         files.
2488
2489 =head1 OPTIONS
2490
2491 =over 4
2492
2493 =item B<--help>
2494
2495 Print a brief help message and exit.
2496
2497 =item B<--man>
2498
2499 Print the manual page and exit.
2500
2501 =item B<--dump> | B<-c>
2502
2503 Print all relevant configuration data.  This is equivalent to B<--command-line>
2504 B<--options> B<--environment> B<--make-variables> B<--build-parameters>.
2505
2506 =item B<--command-line> | B<-c>
2507
2508 Print the current configuration command line.
2509
2510 =item B<--options> | B<-o>
2511
2512 Print the features, both enabled and disabled, and display defined macro and
2513 skipped directories where applicable.
2514
2515 =item B<--environment> | B<-e>
2516
2517 Print the environment variables and their values at the time of configuration.
2518
2519 =item B<--make-variables> | B<-m>
2520
2521 Print the main make variables generated in the current configuration
2522
2523 =item B<--build-parameters> | B<-b>
2524
2525 Print the build parameters, i.e. build file and build file templates.
2526
2527 =item B<--reconfigure> | B<--reconf> | B<-r>
2528
2529 Redo the configuration.
2530
2531 =item B<--verbose> | B<-v>
2532
2533 Verbose output.
2534
2535 =back
2536
2537 =cut
2538
2539 EOF
2540 close(OUT);
2541 if ($builder_platform eq 'unix') {
2542     my $mode = (0755 & ~umask);
2543     chmod $mode, 'configdata.pm'
2544         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2545 }
2546
2547 my %builders = (
2548     unified => sub {
2549         print 'Creating ',$target{build_file},"\n";
2550         run_dofile(catfile($blddir, $target{build_file}),
2551                    @{$config{build_file_templates}});
2552     },
2553     );
2554
2555 $builders{$builder}->($builder_platform, @builder_opts);
2556
2557 # Show a note on the use of configdata.pm, but ONLY for release 1.1.1
2558 # (i.e. this message disappears with the following update, 1.1.1a)
2559 print <<"EOF" if ($config{version_num} =~ m|^0x1010100.L$|);
2560
2561 NOTE: Starting with OpenSSL 1.1.1, 'Configure' doesn't display all the disabled
2562 options or the "make variables" with their values.  Instead, you must use
2563 'configdata.pm' as a script to get a display of the configuration data.  For
2564 help, please do this:
2565
2566         perl configdata.pm --help
2567 EOF
2568 print <<"EOF" if ($disabled{threads} eq "unavailable");
2569
2570 The library could not be configured for supporting multi-threaded
2571 applications as the compiler options required on this system are not known.
2572 See file INSTALL for details if you need multi-threading.
2573 EOF
2574
2575 print <<"EOF" if ($no_shared_warn);
2576
2577 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2578 platform, so we will pretend you gave the option 'no-pic', which also disables
2579 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2580 or position independent code, please let us know (but please first make sure
2581 you have tried with a current version of OpenSSL).
2582 EOF
2583
2584 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2585
2586 WARNING: there are indications that another build was made in the source
2587 directory.  This build may have picked up artifacts from that build, the
2588 safest course of action is to clean the source directory and redo this
2589 configuration.
2590 EOF
2591
2592 exit(0);
2593
2594 ######################################################################
2595 #
2596 # Helpers and utility functions
2597 #
2598
2599 # Configuration file reading #########################################
2600
2601 # Note: All of the helper functions are for lazy evaluation.  They all
2602 # return a CODE ref, which will return the intended value when evaluated.
2603 # Thus, whenever there's mention of a returned value, it's about that
2604 # intended value.
2605
2606 # Helper function to implement conditional inheritance depending on the
2607 # value of $disabled{asm}.  Used in inherit_from values as follows:
2608 #
2609 #      inherit_from => [ "template", asm("asm_tmpl") ]
2610 #
2611 sub asm {
2612     my @x = @_;
2613     sub {
2614         $disabled{asm} ? () : @x;
2615     }
2616 }
2617
2618 # Helper function to implement conditional value variants, with a default
2619 # plus additional values based on the value of $config{build_type}.
2620 # Arguments are given in hash table form:
2621 #
2622 #       picker(default => "Basic string: ",
2623 #              debug   => "debug",
2624 #              release => "release")
2625 #
2626 # When configuring with --debug, the resulting string will be
2627 # "Basic string: debug", and when not, it will be "Basic string: release"
2628 #
2629 # This can be used to create variants of sets of flags according to the
2630 # build type:
2631 #
2632 #       cflags => picker(default => "-Wall",
2633 #                        debug   => "-g -O0",
2634 #                        release => "-O3")
2635 #
2636 sub picker {
2637     my %opts = @_;
2638     return sub { add($opts{default} || (),
2639                      $opts{$config{build_type}} || ())->(); }
2640 }
2641
2642 # Helper function to combine several values of different types into one.
2643 # This is useful if you want to combine a string with the result of a
2644 # lazy function, such as:
2645 #
2646 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2647 #
2648 sub combine {
2649     my @stuff = @_;
2650     return sub { add(@stuff)->(); }
2651 }
2652
2653 # Helper function to implement conditional values depending on the value
2654 # of $disabled{threads}.  Can be used as follows:
2655 #
2656 #       cflags => combine("-Wall", threads("-pthread"))
2657 #
2658 sub threads {
2659     my @flags = @_;
2660     return sub { add($disabled{threads} ? () : @flags)->(); }
2661 }
2662
2663
2664
2665 our $add_called = 0;
2666 # Helper function to implement adding values to already existing configuration
2667 # values.  It handles elements that are ARRAYs, CODEs and scalars
2668 sub _add {
2669     my $separator = shift;
2670
2671     # If there's any ARRAY in the collection of values OR the separator
2672     # is undef, we will return an ARRAY of combined values, otherwise a
2673     # string of joined values with $separator as the separator.
2674     my $found_array = !defined($separator);
2675
2676     my @values =
2677         map {
2678             my $res = $_;
2679             while (ref($res) eq "CODE") {
2680                 $res = $res->();
2681             }
2682             if (defined($res)) {
2683                 if (ref($res) eq "ARRAY") {
2684                     $found_array = 1;
2685                     @$res;
2686                 } else {
2687                     $res;
2688                 }
2689             } else {
2690                 ();
2691             }
2692     } (@_);
2693
2694     $add_called = 1;
2695
2696     if ($found_array) {
2697         [ @values ];
2698     } else {
2699         join($separator, grep { defined($_) && $_ ne "" } @values);
2700     }
2701 }
2702 sub add_before {
2703     my $separator = " ";
2704     if (ref($_[$#_]) eq "HASH") {
2705         my $opts = pop;
2706         $separator = $opts->{separator};
2707     }
2708     my @x = @_;
2709     sub { _add($separator, @x, @_) };
2710 }
2711 sub add {
2712     my $separator = " ";
2713     if (ref($_[$#_]) eq "HASH") {
2714         my $opts = pop;
2715         $separator = $opts->{separator};
2716     }
2717     my @x = @_;
2718     sub { _add($separator, @_, @x) };
2719 }
2720
2721 sub read_eval_file {
2722     my $fname = shift;
2723     my $content;
2724     my @result;
2725
2726     open F, "< $fname" or die "Can't open '$fname': $!\n";
2727     {
2728         undef local $/;
2729         $content = <F>;
2730     }
2731     close F;
2732     {
2733         local $@;
2734
2735         @result = ( eval $content );
2736         warn $@ if $@;
2737     }
2738     return wantarray ? @result : $result[0];
2739 }
2740
2741 # configuration reader, evaluates the input file as a perl script and expects
2742 # it to fill %targets with target configurations.  Those are then added to
2743 # %table.
2744 sub read_config {
2745     my $fname = shift;
2746     my %targets;
2747
2748     {
2749         # Protect certain tables from tampering
2750         local %table = ();
2751
2752         %targets = read_eval_file($fname);
2753     }
2754     my %preexisting = ();
2755     foreach (sort keys %targets) {
2756         $preexisting{$_} = 1 if $table{$_};
2757     }
2758     die <<"EOF",
2759 The following config targets from $fname
2760 shadow pre-existing config targets with the same name:
2761 EOF
2762         map { "  $_\n" } sort keys %preexisting
2763         if %preexisting;
2764
2765
2766     # For each target, check that it's configured with a hash table.
2767     foreach (keys %targets) {
2768         if (ref($targets{$_}) ne "HASH") {
2769             if (ref($targets{$_}) eq "") {
2770                 warn "Deprecated target configuration for $_, ignoring...\n";
2771             } else {
2772                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2773             }
2774             delete $targets{$_};
2775         } else {
2776             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2777         }
2778     }
2779
2780     %table = (%table, %targets);
2781
2782 }
2783
2784 # configuration resolver.  Will only resolve all the lazy evaluation
2785 # codeblocks for the chosen target and all those it inherits from,
2786 # recursively
2787 sub resolve_config {
2788     my $target = shift;
2789     my @breadcrumbs = @_;
2790
2791 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2792
2793     if (grep { $_ eq $target } @breadcrumbs) {
2794         die "inherit_from loop!  target backtrace:\n  "
2795             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2796     }
2797
2798     if (!defined($table{$target})) {
2799         warn "Warning! target $target doesn't exist!\n";
2800         return ();
2801     }
2802     # Recurse through all inheritances.  They will be resolved on the
2803     # fly, so when this operation is done, they will all just be a
2804     # bunch of attributes with string values.
2805     # What we get here, though, are keys with references to lists of
2806     # the combined values of them all.  We will deal with lists after
2807     # this stage is done.
2808     my %combined_inheritance = ();
2809     if ($table{$target}->{inherit_from}) {
2810         my @inherit_from =
2811             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2812         foreach (@inherit_from) {
2813             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2814
2815             # 'template' is a marker that's considered private to
2816             # the config that had it.
2817             delete $inherited_config{template};
2818
2819             foreach (keys %inherited_config) {
2820                 if (!$combined_inheritance{$_}) {
2821                     $combined_inheritance{$_} = [];
2822                 }
2823                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2824             }
2825         }
2826     }
2827
2828     # We won't need inherit_from in this target any more, since we've
2829     # resolved all the inheritances that lead to this
2830     delete $table{$target}->{inherit_from};
2831
2832     # Now is the time to deal with those lists.  Here's the place to
2833     # decide what shall be done with those lists, all based on the
2834     # values of the target we're currently dealing with.
2835     # - If a value is a coderef, it will be executed with the list of
2836     #   inherited values as arguments.
2837     # - If the corresponding key doesn't have a value at all or is the
2838     #   empty string, the inherited value list will be run through the
2839     #   default combiner (below), and the result becomes this target's
2840     #   value.
2841     # - Otherwise, this target's value is assumed to be a string that
2842     #   will simply override the inherited list of values.
2843     my $default_combiner = add();
2844
2845     my %all_keys =
2846         map { $_ => 1 } (keys %combined_inheritance,
2847                          keys %{$table{$target}});
2848
2849     sub process_values {
2850         my $object    = shift;
2851         my $inherited = shift;  # Always a [ list ]
2852         my $target    = shift;
2853         my $entry     = shift;
2854
2855         $add_called = 0;
2856
2857         while(ref($object) eq "CODE") {
2858             $object = $object->(@$inherited);
2859         }
2860         if (!defined($object)) {
2861             return ();
2862         }
2863         elsif (ref($object) eq "ARRAY") {
2864             local $add_called;  # To make sure recursive calls don't affect it
2865             return [ map { process_values($_, $inherited, $target, $entry) }
2866                      @$object ];
2867         } elsif (ref($object) eq "") {
2868             return $object;
2869         } else {
2870             die "cannot handle reference type ",ref($object)
2871                 ," found in target ",$target," -> ",$entry,"\n";
2872         }
2873     }
2874
2875     foreach (sort keys %all_keys) {
2876         my $previous = $combined_inheritance{$_};
2877
2878         # Current target doesn't have a value for the current key?
2879         # Assign it the default combiner, the rest of this loop body
2880         # will handle it just like any other coderef.
2881         if (!exists $table{$target}->{$_}) {
2882             $table{$target}->{$_} = $default_combiner;
2883         }
2884
2885         $table{$target}->{$_} = process_values($table{$target}->{$_},
2886                                                $combined_inheritance{$_},
2887                                                $target, $_);
2888         unless(defined($table{$target}->{$_})) {
2889             delete $table{$target}->{$_};
2890         }
2891 #        if ($extra_checks &&
2892 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2893 #            warn "$_ got replaced in $target\n";
2894 #        }
2895     }
2896
2897     # Finally done, return the result.
2898     return %{$table{$target}};
2899 }
2900
2901 sub usage
2902         {
2903         print STDERR $usage;
2904         print STDERR "\npick os/compiler from:\n";
2905         my $j=0;
2906         my $i;
2907         my $k=0;
2908         foreach $i (sort keys %table)
2909                 {
2910                 next if $table{$i}->{template};
2911                 next if $i =~ /^debug/;
2912                 $k += length($i) + 1;
2913                 if ($k > 78)
2914                         {
2915                         print STDERR "\n";
2916                         $k=length($i);
2917                         }
2918                 print STDERR $i . " ";
2919                 }
2920         foreach $i (sort keys %table)
2921                 {
2922                 next if $table{$i}->{template};
2923                 next if $i !~ /^debug/;
2924                 $k += length($i) + 1;
2925                 if ($k > 78)
2926                         {
2927                         print STDERR "\n";
2928                         $k=length($i);
2929                         }
2930                 print STDERR $i . " ";
2931                 }
2932         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2933         exit(1);
2934         }
2935
2936 sub run_dofile
2937 {
2938     my $out = shift;
2939     my @templates = @_;
2940
2941     unlink $out || warn "Can't remove $out, $!"
2942         if -f $out;
2943     foreach (@templates) {
2944         die "Can't open $_, $!" unless -f $_;
2945     }
2946     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2947     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2948     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2949     system($cmd);
2950     exit 1 if $? != 0;
2951     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2952 }
2953
2954 sub compiler_predefined {
2955     state %predefined;
2956     my $default_compiler = shift;
2957
2958     return () if $^O eq 'VMS';
2959
2960     die 'compiler_predefines called without a default compiler'
2961         unless $default_compiler;
2962
2963     if (! $predefined{$default_compiler}) {
2964         my $cc = "$config{cross_compile_prefix}$default_compiler";
2965
2966         $predefined{$default_compiler} = {};
2967
2968         # collect compiler pre-defines from gcc or gcc-alike...
2969         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2970         while (my $l = <PIPE>) {
2971             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2972             $predefined{$default_compiler}->{$1} = $2 // '';
2973         }
2974         close(PIPE);
2975     }
2976
2977     return %{$predefined{$default_compiler}};
2978 }
2979
2980 sub which
2981 {
2982     my ($name)=@_;
2983
2984     if (eval { require IPC::Cmd; 1; }) {
2985         IPC::Cmd->import();
2986         return scalar IPC::Cmd::can_run($name);
2987     } else {
2988         # if there is $directories component in splitpath,
2989         # then it's not something to test with $PATH...
2990         return $name if (File::Spec->splitpath($name))[1];
2991
2992         foreach (File::Spec->path()) {
2993             my $fullpath = catfile($_, "$name$target{exe_extension}");
2994             if (-f $fullpath and -x $fullpath) {
2995                 return $fullpath;
2996             }
2997         }
2998     }
2999 }
3000
3001 sub env
3002 {
3003     my $name = shift;
3004
3005     # Note that if $ENV{$name} doesn't exist or is undefined,
3006     # $config{perlenv}->{$name} will be created with the value
3007     # undef.  This is intentional.
3008
3009     $config{perlenv}->{$name} = $ENV{$name}
3010         if ! exists $config{perlenv}->{$name};
3011     return $config{perlenv}->{$name};
3012 }
3013
3014 # Configuration printer ##############################################
3015
3016 sub print_table_entry
3017 {
3018     my $target = shift;
3019     my %target = resolve_config($target);
3020     my $type = shift;
3021
3022     # Don't print the templates
3023     return if $target{template};
3024
3025     my @sequence = (
3026         "sys_id",
3027         "cpp",
3028         "cppflags",
3029         "defines",
3030         "includes",
3031         "cc",
3032         "cflags",
3033         "unistd",
3034         "ld",
3035         "lflags",
3036         "loutflag",
3037         "plib_lflags",
3038         "ex_libs",
3039         "bn_ops",
3040         "apps_aux_src",
3041         "cpuid_asm_src",
3042         "uplink_aux_src",
3043         "bn_asm_src",
3044         "ec_asm_src",
3045         "des_asm_src",
3046         "aes_asm_src",
3047         "bf_asm_src",
3048         "md5_asm_src",
3049         "cast_asm_src",
3050         "sha1_asm_src",
3051         "rc4_asm_src",
3052         "rmd160_asm_src",
3053         "rc5_asm_src",
3054         "wp_asm_src",
3055         "cmll_asm_src",
3056         "modes_asm_src",
3057         "padlock_asm_src",
3058         "chacha_asm_src",
3059         "poly1035_asm_src",
3060         "thread_scheme",
3061         "perlasm_scheme",
3062         "dso_scheme",
3063         "shared_target",
3064         "shared_cflag",
3065         "shared_defines",
3066         "shared_ldflag",
3067         "shared_rcflag",
3068         "shared_extension",
3069         "dso_extension",
3070         "obj_extension",
3071         "exe_extension",
3072         "ranlib",
3073         "ar",
3074         "arflags",
3075         "aroutflag",
3076         "rc",
3077         "rcflags",
3078         "rcoutflag",
3079         "mt",
3080         "mtflags",
3081         "mtinflag",
3082         "mtoutflag",
3083         "multilib",
3084         "build_scheme",
3085         );
3086
3087     if ($type eq "TABLE") {
3088         print "\n";
3089         print "*** $target\n";
3090         foreach (@sequence) {
3091             if (ref($target{$_}) eq "ARRAY") {
3092                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3093             } else {
3094                 printf "\$%-12s = %s\n", $_, $target{$_};
3095             }
3096         }
3097     } elsif ($type eq "HASH") {
3098         my $largest =
3099             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3100         print "    '$target' => {\n";
3101         foreach (@sequence) {
3102             if ($target{$_}) {
3103                 if (ref($target{$_}) eq "ARRAY") {
3104                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3105                 } else {
3106                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3107                 }
3108             }
3109         }
3110         print "    },\n";
3111     }
3112 }
3113
3114 # Utility routines ###################################################
3115
3116 # On VMS, if the given file is a logical name, File::Spec::Functions
3117 # will consider it an absolute path.  There are cases when we want a
3118 # purely syntactic check without checking the environment.
3119 sub isabsolute {
3120     my $file = shift;
3121
3122     # On non-platforms, we just use file_name_is_absolute().
3123     return file_name_is_absolute($file) unless $^O eq "VMS";
3124
3125     # If the file spec includes a device or a directory spec,
3126     # file_name_is_absolute() is perfectly safe.
3127     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3128
3129     # Here, we know the given file spec isn't absolute
3130     return 0;
3131 }
3132
3133 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3134 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3135 # realpath() requires that at least all path components except the last is an
3136 # existing directory.  On VMS, the last component of the directory spec must
3137 # exist.
3138 sub absolutedir {
3139     my $dir = shift;
3140
3141     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3142     # will return the volume name for the device, no matter what.  Also,
3143     # it will return an incorrect directory spec if the argument is a
3144     # directory that doesn't exist.
3145     if ($^O eq "VMS") {
3146         return rel2abs($dir);
3147     }
3148
3149     # We use realpath() on Unix, since no other will properly clean out
3150     # a directory spec.
3151     use Cwd qw/realpath/;
3152
3153     return realpath($dir);
3154 }
3155
3156 sub quotify {
3157     my %processors = (
3158         perl    => sub { my $x = shift;
3159                          $x =~ s/([\\\$\@"])/\\$1/g;
3160                          return '"'.$x.'"'; },
3161         maybeshell => sub { my $x = shift;
3162                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3163                             if ($x ne $y || $x =~ m|\s|) {
3164                                 return '"'.$y.'"';
3165                             } else {
3166                                 return $x;
3167                             }
3168                         },
3169         );
3170     my $for = shift;
3171     my $processor =
3172         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3173
3174     return map { $processor->($_); } @_;
3175 }
3176
3177 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3178 # $filename is a file name to read from
3179 # $line_concat_cond_re is a regexp detecting a line continuation ending
3180 # $line_concat is a CODEref that takes care of concatenating two lines
3181 sub collect_from_file {
3182     my $filename = shift;
3183     my $line_concat_cond_re = shift;
3184     my $line_concat = shift;
3185
3186     open my $fh, $filename || die "unable to read $filename: $!\n";
3187     return sub {
3188         my $saved_line = "";
3189         $_ = "";
3190         while (<$fh>) {
3191             s|\R$||;
3192             if (defined $line_concat) {
3193                 $_ = $line_concat->($saved_line, $_);
3194                 $saved_line = "";
3195             }
3196             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3197                 $saved_line = $_;
3198                 next;
3199             }
3200             return $_;
3201         }
3202         die "$filename ending with continuation line\n" if $_;
3203         close $fh;
3204         return undef;
3205     }
3206 }
3207
3208 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3209 # $array is an ARRAYref of lines
3210 # $line_concat_cond_re is a regexp detecting a line continuation ending
3211 # $line_concat is a CODEref that takes care of concatenating two lines
3212 sub collect_from_array {
3213     my $array = shift;
3214     my $line_concat_cond_re = shift;
3215     my $line_concat = shift;
3216     my @array = (@$array);
3217
3218     return sub {
3219         my $saved_line = "";
3220         $_ = "";
3221         while (defined($_ = shift @array)) {
3222             s|\R$||;
3223             if (defined $line_concat) {
3224                 $_ = $line_concat->($saved_line, $_);
3225                 $saved_line = "";
3226             }
3227             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3228                 $saved_line = $_;
3229                 next;
3230             }
3231             return $_;
3232         }
3233         die "input text ending with continuation line\n" if $_;
3234         return undef;
3235     }
3236 }
3237
3238 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3239 # $lineiterator is a CODEref that delivers one line at a time.
3240 # All following arguments are regex/CODEref pairs, where the regexp detects a
3241 # line and the CODEref does something with the result of the regexp.
3242 sub collect_information {
3243     my $lineiterator = shift;
3244     my %collectors = @_;
3245
3246     while(defined($_ = $lineiterator->())) {
3247         s|\R$||;
3248         my $found = 0;
3249         if ($collectors{"BEFORE"}) {
3250             $collectors{"BEFORE"}->($_);
3251         }
3252         foreach my $re (keys %collectors) {
3253             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3254                 $collectors{$re}->($lineiterator);
3255                 $found = 1;
3256             };
3257         }
3258         if ($collectors{"OTHERWISE"}) {
3259             $collectors{"OTHERWISE"}->($lineiterator, $_)
3260                 unless $found || !defined $collectors{"OTHERWISE"};
3261         }
3262         if ($collectors{"AFTER"}) {
3263             $collectors{"AFTER"}->($_);
3264         }
3265     }
3266 }
3267
3268 # tokenize($line)
3269 # $line is a line of text to split up into tokens
3270 # returns a list of tokens
3271 #
3272 # Tokens are divided by spaces.  If the tokens include spaces, they
3273 # have to be quoted with single or double quotes.  Double quotes
3274 # inside a double quoted token must be escaped.  Escaping is done
3275 # with backslash.
3276 # Basically, the same quoting rules apply for " and ' as in any
3277 # Unix shell.
3278 sub tokenize {
3279     my $line = my $debug_line = shift;
3280     my @result = ();
3281
3282     while ($line =~ s|^\s+||, $line ne "") {
3283         my $token = "";
3284         while ($line ne "" && $line !~ m|^\s|) {
3285             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3286                 $token .= $1;
3287                 $line = $';
3288             } elsif ($line =~ m/^'([^']*)'/) {
3289                 $token .= $1;
3290                 $line = $';
3291             } elsif ($line =~ m/^(\S+)/) {
3292                 $token .= $1;
3293                 $line = $';
3294             }
3295         }
3296         push @result, $token;
3297     }
3298
3299     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3300         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3301         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3302     }
3303     return @result;
3304 }