Move poly1305_asm_src file information to build.info files
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $orig_death_handler = $SIG{__DIE__};
25 $SIG{__DIE__} = \&death_handler;
26
27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
28
29 # Options:
30 #
31 # --config      add the given configuration file, which will be read after
32 #               any "Configurations*" files that are found in the same
33 #               directory as this script.
34 # --prefix      prefix for the OpenSSL installation, which includes the
35 #               directories bin, lib, include, share/man, share/doc/openssl
36 #               This becomes the value of INSTALLTOP in Makefile
37 #               (Default: /usr/local)
38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
39 #               If it's a relative directory, it will be added on the directory
40 #               given with --prefix.
41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
42 #               (Default: PREFIX/ssl)
43 #
44 # --cross-compile-prefix Add specified prefix to binutils components.
45 #
46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
47 #               Do not compile support for interfaces deprecated as of the
48 #               specified OpenSSL version.
49 #
50 # no-hw-xxx     do not compile support for specific crypto hardware.
51 #               Generic OpenSSL-style methods relating to this support
52 #               are always compiled but return NULL if the hardware
53 #               support isn't compiled.
54 # no-hw         do not compile support for any crypto hardware.
55 # [no-]threads  [don't] try to create a library that is suitable for
56 #               multithreaded applications (default is "threads" if we
57 #               know how to do it)
58 # [no-]shared   [don't] try to create shared libraries when supported.
59 # [no-]pic      [don't] try to build position independent code when supported.
60 #               If disabled, it also disables shared and dynamic-engine.
61 # no-asm        do not use assembler
62 # no-egd        do not compile support for the entropy-gathering daemon APIs
63 # [no-]zlib     [don't] compile support for zlib compression.
64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
65 #               library and will be loaded in run-time by the OpenSSL library.
66 # sctp          include SCTP support
67 # no-uplink     Don't build support for UPLINK interface.
68 # enable-weak-ssl-ciphers
69 #               Enable weak ciphers that are disabled by default.
70 # 386           generate 80386 code in assembly modules
71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
72 #               mentioned '386' option implies this one
73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
74 # -<xxx> +<xxx> compiler options are passed through
75 # -static       while -static is also a pass-through compiler option (and
76 #               as such is limited to environments where it's actually
77 #               meaningful), it triggers a number configuration options,
78 #               namely no-pic, no-shared and no-threads. It is
79 #               argued that the only reason to produce statically linked
80 #               binaries (and in context it means executables linked with
81 #               -static flag, and not just executables linked with static
82 #               libcrypto.a) is to eliminate dependency on specific run-time,
83 #               a.k.a. libc version. The mentioned config options are meant
84 #               to achieve just that. Unfortunately on Linux it's impossible
85 #               to eliminate the dependency completely for openssl executable
86 #               because of getaddrinfo and gethostbyname calls, which can
87 #               invoke dynamically loadable library facility anyway to meet
88 #               the lookup requests. For this reason on Linux statically
89 #               linked openssl executable has rather debugging value than
90 #               production quality.
91 #
92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
94 # Following are set automatically by this script
95 #
96 # MD5_ASM       use some extra md5 assembler,
97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
98 # RMD160_ASM    use some extra ripemd160 assembler,
99 # SHA256_ASM    sha256_block is implemented in assembler
100 # SHA512_ASM    sha512_block is implemented in assembler
101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
102
103 # Minimum warning options... any contributions to OpenSSL should at least
104 # get past these.  Note that we only use these with C compilers, not with
105 # C++ compilers.
106
107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
108 # -DPEDANTIC complements -pedantic and is meant to mask code that
109 # is not strictly standard-compliant and/or implementation-specific,
110 # e.g. inline assembly, disregards to alignment requirements, such
111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
112 # to be used even in sanitized builds, because sanitizer too is
113 # supposed to and does take notice of non-standard behaviour. Then
114 # -pedantic with pre-C9x compiler would also complain about 'long
115 # long' not being supported. As 64-bit algorithms are common now,
116 # it grew impossible to resolve this without sizeable additional
117 # code, so we just tell compiler to be pedantic about everything
118 # but 'long long' type.
119
120 my @gcc_devteam_warn = qw(
121     -DDEBUG_UNUSED
122     -DPEDANTIC -pedantic -Wno-long-long
123     -Wall
124     -Wextra
125     -Wno-unused-parameter
126     -Wno-missing-field-initializers
127     -Wswitch
128     -Wsign-compare
129     -Wshadow
130     -Wformat
131     -Wtype-limits
132     -Wundef
133     -Werror
134     -Wmissing-prototypes
135     -Wstrict-prototypes
136 );
137
138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
139 # TODO(openssl-team): fix problems and investigate if (at least) the
140 # following warnings can also be enabled:
141 #       -Wcast-align
142 #       -Wunreachable-code -- no, too ugly/compiler-specific
143 #       -Wlanguage-extension-token -- no, we use asm()
144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
146 my @clang_devteam_warn = qw(
147     -Wswitch-default
148     -Wno-parentheses-equality
149     -Wno-language-extension-token
150     -Wno-extended-offsetof
151     -Wconditional-uninitialized
152     -Wincompatible-pointer-types-discards-qualifiers
153     -Wno-unknown-warning-option
154     -Wmissing-variable-declarations
155 );
156
157 # This adds backtrace information to the memory leak info.  Is only used
158 # when crypto-mdebug-backtrace is enabled.
159 my $memleak_devteam_backtrace = "-rdynamic";
160
161 my $strict_warnings = 0;
162
163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
164 # which would cover all BSD flavors. -pthread applies to them all,
165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
167 # which has to be accompanied by explicit -D_THREAD_SAFE and
168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
169 # seems to be sufficient?
170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
171
172 #
173 # API compatibility name to version number mapping.
174 #
175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
176 my $apitable = {
177     "3.0.0" => 3,
178     "1.1.1" => 2,
179     "1.1.0" => 2,
180     "1.0.2" => 1,
181     "1.0.1" => 1,
182     "1.0.0" => 1,
183     "0.9.8" => 0,
184 };
185
186 our %table = ();
187 our %config = ();
188 our %withargs = ();
189 our $now_printing;      # set to current entry's name in print_table_entry
190                         # (todo: right thing would be to encapsulate name
191                         # into %target [class] and make print_table_entry
192                         # a method)
193
194 # Forward declarations ###############################################
195
196 # read_config(filename)
197 #
198 # Reads a configuration file and populates %table with the contents
199 # (which the configuration file places in %targets).
200 sub read_config;
201
202 # resolve_config(target)
203 #
204 # Resolves all the late evaluations, inheritances and so on for the
205 # chosen target and any target it inherits from.
206 sub resolve_config;
207
208
209 # Information collection #############################################
210
211 # Unified build supports separate build dir
212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
215
216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
217
218 $config{sourcedir} = abs2rel($srcdir);
219 $config{builddir} = abs2rel($blddir);
220
221 # Collect reconfiguration information if needed
222 my @argvcopy=@ARGV;
223
224 if (grep /^reconf(igure)?$/, @argvcopy) {
225     die "reconfiguring with other arguments present isn't supported"
226         if scalar @argvcopy > 1;
227     if (-f "./configdata.pm") {
228         my $file = "./configdata.pm";
229         unless (my $return = do $file) {
230             die "couldn't parse $file: $@" if $@;
231             die "couldn't do $file: $!"    unless defined $return;
232             die "couldn't run $file"       unless $return;
233         }
234
235         @argvcopy = defined($configdata::config{perlargv}) ?
236             @{$configdata::config{perlargv}} : ();
237         die "Incorrect data to reconfigure, please do a normal configuration\n"
238             if (grep(/^reconf/,@argvcopy));
239         $config{perlenv} = $configdata::config{perlenv} // {};
240     } else {
241         die "Insufficient data to reconfigure, please do a normal configuration\n";
242     }
243 }
244
245 $config{perlargv} = [ @argvcopy ];
246
247 # Collect version numbers
248 $config{major} = "unknown";
249 $config{minor} = "unknown";
250 $config{patch} = "unknown";
251 $config{prerelease} = "";
252 $config{build_metadata} = "";
253 $config{shlib_version} = "unknown";
254
255 collect_information(
256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
258         sub { $config{major} = $1; },
259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
260         sub { $config{minor} = $1; },
261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
262         sub { $config{patch} = $1; },
263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
264         sub { $config{prerelease} = $1; },
265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
266         sub { $config{build_metadata} = $1; },
267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
268         sub { $config{shlib_version} = $1; },
269     );
270 die "erroneous version information in opensslv.h: ",
271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
272     if ($config{major} eq "unknown"
273             || $config{minor} eq "unknown"
274             || $config{patch} eq "unknown"
275             || $config{shlib_version} eq "unknown");
276
277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
279
280 # Collect target configurations
281
282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
283 foreach (sort glob($pattern)) {
284     &read_config($_);
285 }
286
287 if (defined env($local_config_envname)) {
288     if ($^O eq 'VMS') {
289         # VMS environment variables are logical names,
290         # which can be used as is
291         $pattern = $local_config_envname . ':' . '*.conf';
292     } else {
293         $pattern = catfile(env($local_config_envname), '*.conf');
294     }
295
296     foreach (sort glob($pattern)) {
297         &read_config($_);
298     }
299 }
300
301 # Save away perl command information
302 $config{perl_cmd} = $^X;
303 $config{perl_version} = $Config{version};
304 $config{perl_archname} = $Config{archname};
305
306 $config{prefix}="";
307 $config{openssldir}="";
308 $config{processor}="";
309 $config{libdir}="";
310 my $auto_threads=1;    # enable threads automatically? true by default
311 my $default_ranlib;
312
313 # Known TLS and DTLS protocols
314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
315 my @dtls = qw(dtls1 dtls1_2);
316
317 # Explicitly known options that are possible to disable.  They can
318 # be regexps, and will be used like this: /^no-${option}$/
319 # For developers: keep it sorted alphabetically
320
321 my @disablables = (
322     "ktls",
323     "afalgeng",
324     "aria",
325     "asan",
326     "asm",
327     "async",
328     "autoalginit",
329     "autoerrinit",
330     "autoload-config",
331     "bf",
332     "blake2",
333     "buildtest-c++",
334     "camellia",
335     "capieng",
336     "cast",
337     "chacha",
338     "cmac",
339     "cmp",
340     "cms",
341     "comp",
342     "crypto-mdebug",
343     "crypto-mdebug-backtrace",
344     "ct",
345     "deprecated",
346     "des",
347     "devcryptoeng",
348     "dgram",
349     "dh",
350     "dsa",
351     "dtls",
352     "dynamic-engine",
353     "ec",
354     "ec2m",
355     "ecdh",
356     "ecdsa",
357     "ec_nistp_64_gcc_128",
358     "egd",
359     "engine",
360     "err",
361     "external-tests",
362     "filenames",
363     "fips",
364     "fuzz-libfuzzer",
365     "fuzz-afl",
366     "gost",
367     "idea",
368     "legacy",
369     "makedepend",
370     "md2",
371     "md4",
372     "mdc2",
373     "module",
374     "msan",
375     "multiblock",
376     "nextprotoneg",
377     "pinshared",
378     "ocb",
379     "ocsp",
380     "padlockeng",
381     "pic",
382     "poly1305",
383     "posix-io",
384     "psk",
385     "rc2",
386     "rc4",
387     "rc5",
388     "rdrand",
389     "rfc3779",
390     "rmd160",
391     "scrypt",
392     "sctp",
393     "seed",
394     "shared",
395     "siphash",
396     "siv",
397     "sm2",
398     "sm3",
399     "sm4",
400     "sock",
401     "srp",
402     "srtp",
403     "sse2",
404     "ssl",
405     "ssl-trace",
406     "static-engine",
407     "stdio",
408     "tests",
409     "threads",
410     "tls",
411     "trace",
412     "ts",
413     "ubsan",
414     "ui-console",
415     "unit-test",
416     "uplink",
417     "whirlpool",
418     "weak-ssl-ciphers",
419     "zlib",
420     "zlib-dynamic",
421     );
422 foreach my $proto ((@tls, @dtls))
423         {
424         push(@disablables, $proto);
425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
426         }
427
428 # Internal disablables, for aliasing purposes.  They serve no special
429 # purpose here, but allow scripts to get to know them through configdata.pm,
430 # where these are merged with @disablables.
431 # The actual aliasing mechanism is done via %disable_cascades
432 my @disablables_int = qw(
433     crmf
434     );
435
436 my %deprecated_disablables = (
437     "ssl2" => undef,
438     "buf-freelists" => undef,
439     "hw" => "hw",               # causes cascade, but no macro
440     "hw-padlock" => "padlockeng",
441     "ripemd" => "rmd160",
442     "ui" => "ui-console",
443     "dso" => undef,
444     "heartbeats" => undef,
445     );
446
447 # All of the following are disabled by default:
448
449 our %disabled = ( # "what"         => "comment"
450                   "asan"                => "default",
451                   "buildtest-c++"       => "default",
452                   "crypto-mdebug"       => "default",
453                   "crypto-mdebug-backtrace" => "default",
454                   "devcryptoeng"        => "default",
455                   "ec_nistp_64_gcc_128" => "default",
456                   "egd"                 => "default",
457                   "external-tests"      => "default",
458                   "fuzz-libfuzzer"      => "default",
459                   "fuzz-afl"            => "default",
460                   "md2"                 => "default",
461                   "msan"                => "default",
462                   "rc5"                 => "default",
463                   "sctp"                => "default",
464                   "ssl-trace"           => "default",
465                   "ssl3"                => "default",
466                   "ssl3-method"         => "default",
467                   "trace"               => "default",
468                   "ubsan"               => "default",
469                   "unit-test"           => "default",
470                   "weak-ssl-ciphers"    => "default",
471                   "zlib"                => "default",
472                   "zlib-dynamic"        => "default",
473                   "ktls"                => "default",
474                 );
475
476 # Note: => pair form used for aesthetics, not to truly make a hash table
477 my @disable_cascades = (
478     # "what"            => [ "cascade", ... ]
479     sub { $config{processor} eq "386" }
480                         => [ "sse2" ],
481     "ssl"               => [ "ssl3" ],
482     "ssl3-method"       => [ "ssl3" ],
483     "zlib"              => [ "zlib-dynamic" ],
484     "des"               => [ "mdc2" ],
485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
486     sub { $disabled{"ec"} && $disabled{"dh"} }
487                         => [ "tls1_3" ],
488     "dgram"             => [ "dtls", "sctp" ],
489     "sock"              => [ "dgram" ],
490     "dtls"              => [ @dtls ],
491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
492                         => [ "dtls" ],
493
494     "tls"               => [ @tls ],
495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
496                         => [ "tls" ],
497
498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
499
500     # If no modules, then no dynamic engines either
501     "module"            => [ "dynamic-engine" ],
502
503     # Without shared libraries, dynamic engines aren't possible.
504     # This is due to them having to link with libcrypto and register features
505     # using the ENGINE functionality, and since that relies on global tables,
506     # those *have* to be exacty the same as the ones accessed from the app,
507     # which cannot be guaranteed if shared libraries aren't present.
508     # (note that even with shared libraries, both the app and dynamic engines
509     # must be linked with the same library)
510     "shared"            => [ "dynamic-engine", "uplink" ],
511     # Other modules don't necessarily have to link with libcrypto, so shared
512     # libraries do not have to be a condition to produce those.
513
514     # Without position independent code, there can be no shared libraries
515     # or modules.
516     "pic"               => [ "shared", "module" ],
517
518     "module"            => [ "fips", "legacy" ],
519
520     "engine"            => [ grep /eng$/, @disablables ],
521     "hw"                => [ "padlockeng" ],
522
523     # no-autoalginit is only useful when building non-shared
524     "autoalginit"       => [ "shared", "apps" ],
525
526     "stdio"             => [ "apps", "capieng", "egd" ],
527     "apps"              => [ "tests" ],
528     "tests"             => [ "external-tests" ],
529     "comp"              => [ "zlib" ],
530     "sm3"               => [ "sm2" ],
531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
532
533     sub { !$disabled{"msan"} } => [ "asm" ],
534
535     sub { $disabled{cmac}; } => [ "siv" ],
536     "legacy"                 => [ "md2" ],
537
538     "cmp"               => [ "crmf" ],
539     );
540
541 # Avoid protocol support holes.  Also disable all versions below N, if version
542 # N is disabled while N+1 is enabled.
543 #
544 my @list = (reverse @tls);
545 while ((my $first, my $second) = (shift @list, shift @list)) {
546     last unless @list;
547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
548                               => [ @list ] );
549     unshift @list, $second;
550 }
551 my @list = (reverse @dtls);
552 while ((my $first, my $second) = (shift @list, shift @list)) {
553     last unless @list;
554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
555                               => [ @list ] );
556     unshift @list, $second;
557 }
558
559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
560 # To remove something from %disabled, use "enable-foo".
561 # For symmetry, "disable-foo" is a synonym for "no-foo".
562
563 &usage if ($#ARGV < 0);
564
565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
566 # platform specific list separators.  Users from those platforms should
567 # recognise those separators from how you set up the PATH to find executables.
568 # The default is the Unix like separator, :, but as an exception, we also
569 # support the space as separator.
570 my $list_separator_re =
571     { VMS           => qr/(?<!\^),/,
572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
573 # All the "make variables" we support
574 # Some get pre-populated for the sake of backward compatibility
575 # (we supported those before the change to "make variable" support.
576 my %user = (
577     AR          => env('AR'),
578     ARFLAGS     => [],
579     AS          => undef,
580     ASFLAGS     => [],
581     CC          => env('CC'),
582     CFLAGS      => [ env('CFLAGS') || () ],
583     CXX         => env('CXX'),
584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
585     CPP         => undef,
586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
587     CPPDEFINES  => [],  # Alternative for -D
588     CPPINCLUDES => [],  # Alternative for -I
589     CROSS_COMPILE => env('CROSS_COMPILE'),
590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
591     LD          => undef,
592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
594     MT          => undef,
595     MTFLAGS     => [],
596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
597     RANLIB      => env('RANLIB'),
598     RC          => env('RC') || env('WINDRES'),
599     RCFLAGS     => [ env('RCFLAGS') || () ],
600     RM          => undef,
601    );
602 # Info about what "make variables" may be prefixed with the cross compiler
603 # prefix.  This should NEVER mention any such variable with a list for value.
604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
605 # The same but for flags given as Configure options.  These are *additional*
606 # input, as opposed to the VAR=string option that override the corresponding
607 # config target attributes
608 my %useradd = (
609     CPPDEFINES  => [],
610     CPPINCLUDES => [],
611     CPPFLAGS    => [],
612     CFLAGS      => [],
613     CXXFLAGS    => [],
614     LDFLAGS     => [],
615     LDLIBS      => [],
616     RCFLAGS     => [],
617    );
618
619 my %user_synonyms = (
620     HASHBANGPERL=> 'PERL',
621     RC          => 'WINDRES',
622    );
623
624 # Some target attributes have been renamed, this is the translation table
625 my %target_attr_translate =(
626     ar          => 'AR',
627     as          => 'AS',
628     cc          => 'CC',
629     cxx         => 'CXX',
630     cpp         => 'CPP',
631     hashbangperl => 'HASHBANGPERL',
632     ld          => 'LD',
633     mt          => 'MT',
634     ranlib      => 'RANLIB',
635     rc          => 'RC',
636     rm          => 'RM',
637    );
638
639 # Initialisers coming from 'config' scripts
640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
647
648 $config{openssl_api_defines}=[];
649 $config{openssl_sys_defines}=[];
650 $config{openssl_feature_defines}=[];
651 $config{options}="";
652 $config{build_type} = "release";
653 my $target="";
654
655 my %cmdvars = ();               # Stores FOO='blah' type arguments
656 my %unsupported_options = ();
657 my %deprecated_options = ();
658 # If you change this, update apps/version.c
659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
660 my @seed_sources = ();
661 while (@argvcopy)
662         {
663         $_ = shift @argvcopy;
664
665         # Support env variable assignments among the options
666         if (m|^(\w+)=(.+)?$|)
667                 {
668                 $cmdvars{$1} = $2;
669                 # Every time a variable is given as a configuration argument,
670                 # it acts as a reset if the variable.
671                 if (exists $user{$1})
672                         {
673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
674                         }
675                 #if (exists $useradd{$1})
676                 #       {
677                 #       $useradd{$1} = [];
678                 #       }
679                 next;
680                 }
681
682         # VMS is a case insensitive environment, and depending on settings
683         # out of our control, we may receive options uppercased.  Let's
684         # downcase at least the part before any equal sign.
685         if ($^O eq "VMS")
686                 {
687                 s/^([^=]*)/lc($1)/e;
688                 }
689
690         # some people just can't read the instructions, clang people have to...
691         s/^-no-(?!integrated-as)/no-/;
692
693         # rewrite some options in "enable-..." form
694         s /^-?-?shared$/enable-shared/;
695         s /^sctp$/enable-sctp/;
696         s /^threads$/enable-threads/;
697         s /^zlib$/enable-zlib/;
698         s /^zlib-dynamic$/enable-zlib-dynamic/;
699
700         if (/^(no|disable|enable)-(.+)$/)
701                 {
702                 my $word = $2;
703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
704                         && !exists $deprecated_disablables{$word}
705                         && !grep { $word eq $_ } @disablables)
706                         {
707                         $unsupported_options{$_} = 1;
708                         next;
709                         }
710                 }
711         if (/^no-(.+)$/ || /^disable-(.+)$/)
712                 {
713                 foreach my $proto ((@tls, @dtls))
714                         {
715                         if ($1 eq "$proto-method")
716                                 {
717                                 $disabled{"$proto"} = "option($proto-method)";
718                                 last;
719                                 }
720                         }
721                 if ($1 eq "dtls")
722                         {
723                         foreach my $proto (@dtls)
724                                 {
725                                 $disabled{$proto} = "option(dtls)";
726                                 }
727                         $disabled{"dtls"} = "option(dtls)";
728                         }
729                 elsif ($1 eq "ssl")
730                         {
731                         # Last one of its kind
732                         $disabled{"ssl3"} = "option(ssl)";
733                         }
734                 elsif ($1 eq "tls")
735                         {
736                         # XXX: Tests will fail if all SSL/TLS
737                         # protocols are disabled.
738                         foreach my $proto (@tls)
739                                 {
740                                 $disabled{$proto} = "option(tls)";
741                                 }
742                         }
743                 elsif ($1 eq "static-engine")
744                         {
745                         delete $disabled{"dynamic-engine"};
746                         }
747                 elsif ($1 eq "dynamic-engine")
748                         {
749                         $disabled{"dynamic-engine"} = "option";
750                         }
751                 elsif (exists $deprecated_disablables{$1})
752                         {
753                         $deprecated_options{$_} = 1;
754                         if (defined $deprecated_disablables{$1})
755                                 {
756                                 $disabled{$deprecated_disablables{$1}} = "option";
757                                 }
758                         }
759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
760                         {
761                         $deprecated_options{$_} = 1;
762                         }
763                 else
764                         {
765                         $disabled{$1} = "option";
766                         }
767                 # No longer an automatic choice
768                 $auto_threads = 0 if ($1 eq "threads");
769                 }
770         elsif (/^enable-(.+)$/)
771                 {
772                 if ($1 eq "static-engine")
773                         {
774                         $disabled{"dynamic-engine"} = "option";
775                         }
776                 elsif ($1 eq "dynamic-engine")
777                         {
778                         delete $disabled{"dynamic-engine"};
779                         }
780                 elsif ($1 eq "zlib-dynamic")
781                         {
782                         delete $disabled{"zlib"};
783                         }
784                 my $algo = $1;
785                 delete $disabled{$algo};
786
787                 # No longer an automatic choice
788                 $auto_threads = 0 if ($1 eq "threads");
789                 }
790         elsif (/^--strict-warnings$/)
791                 {
792                 # Pretend that our strict flags is a C flag, and replace it
793                 # with the proper flags later on
794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
795                 $strict_warnings=1;
796                 }
797         elsif (/^--debug$/)
798                 {
799                 $config{build_type} = "debug";
800                 }
801         elsif (/^--release$/)
802                 {
803                 $config{build_type} = "release";
804                 }
805         elsif (/^386$/)
806                 { $config{processor}=386; }
807         elsif (/^fips$/)
808                 {
809                 die "FIPS mode not supported\n";
810                 }
811         elsif (/^rsaref$/)
812                 {
813                 # No RSAref support any more since it's not needed.
814                 # The check for the option is there so scripts aren't
815                 # broken
816                 }
817         elsif (/^nofipscanistercheck$/)
818                 {
819                 die "FIPS mode not supported\n";
820                 }
821         elsif (/^[-+]/)
822                 {
823                 if (/^--prefix=(.*)$/)
824                         {
825                         $config{prefix}=$1;
826                         die "Directory given with --prefix MUST be absolute\n"
827                                 unless file_name_is_absolute($config{prefix});
828                         }
829                 elsif (/^--api=(.*)$/)
830                         {
831                         $config{api}=$1;
832                         }
833                 elsif (/^--libdir=(.*)$/)
834                         {
835                         $config{libdir}=$1;
836                         }
837                 elsif (/^--openssldir=(.*)$/)
838                         {
839                         $config{openssldir}=$1;
840                         }
841                 elsif (/^--with-zlib-lib=(.*)$/)
842                         {
843                         $withargs{zlib_lib}=$1;
844                         }
845                 elsif (/^--with-zlib-include=(.*)$/)
846                         {
847                         $withargs{zlib_include}=$1;
848                         }
849                 elsif (/^--with-fuzzer-lib=(.*)$/)
850                         {
851                         $withargs{fuzzer_lib}=$1;
852                         }
853                 elsif (/^--with-fuzzer-include=(.*)$/)
854                         {
855                         $withargs{fuzzer_include}=$1;
856                         }
857                 elsif (/^--with-rand-seed=(.*)$/)
858                         {
859                         foreach my $x (split(m|,|, $1))
860                             {
861                             die "Unknown --with-rand-seed choice $x\n"
862                                 if ! grep { $x eq $_ } @known_seed_sources;
863                             push @seed_sources, $x;
864                             }
865                         }
866                 elsif (/^--cross-compile-prefix=(.*)$/)
867                         {
868                         $user{CROSS_COMPILE}=$1;
869                         }
870                 elsif (/^--config=(.*)$/)
871                         {
872                         read_config $1;
873                         }
874                 elsif (/^-l(.*)$/)
875                         {
876                         push @{$useradd{LDLIBS}}, $_;
877                         }
878                 elsif (/^-framework$/)
879                         {
880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
881                         }
882                 elsif (/^-L(.*)$/ or /^-Wl,/)
883                         {
884                         push @{$useradd{LDFLAGS}}, $_;
885                         }
886                 elsif (/^-rpath$/ or /^-R$/)
887                         # -rpath is the OSF1 rpath flag
888                         # -R is the old Solaris rpath flag
889                         {
890                         my $rpath = shift(@argvcopy) || "";
891                         $rpath .= " " if $rpath ne "";
892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
893                         }
894                 elsif (/^-static$/)
895                         {
896                         push @{$useradd{LDFLAGS}}, $_;
897                         }
898                 elsif (/^-D(.*)$/)
899                         {
900                         push @{$useradd{CPPDEFINES}}, $1;
901                         }
902                 elsif (/^-I(.*)$/)
903                         {
904                         push @{$useradd{CPPINCLUDES}}, $1;
905                         }
906                 elsif (/^-Wp,$/)
907                         {
908                         push @{$useradd{CPPFLAGS}}, $1;
909                         }
910                 else    # common if (/^[-+]/), just pass down...
911                         {
912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
913                         push @{$useradd{CFLAGS}}, $_;
914                         push @{$useradd{CXXFLAGS}}, $_;
915                         }
916                 }
917         else
918                 {
919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
920                 $target=$_;
921                 }
922         unless ($_ eq $target || /^no-/ || /^disable-/)
923                 {
924                 # "no-..." follows later after implied deactivations
925                 # have been derived.  (Don't take this too seriously,
926                 # we really only write OPTIONS to the Makefile out of
927                 # nostalgia.)
928
929                 if ($config{options} eq "")
930                         { $config{options} = $_; }
931                 else
932                         { $config{options} .= " ".$_; }
933                 }
934         }
935
936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
937         die "***** Unsupported api compatibility level: $config{api}\n",
938 }
939
940 if (keys %deprecated_options)
941         {
942         warn "***** Deprecated options: ",
943                 join(", ", keys %deprecated_options), "\n";
944         }
945 if (keys %unsupported_options)
946         {
947         die "***** Unsupported options: ",
948                 join(", ", keys %unsupported_options), "\n";
949         }
950
951 # If any %useradd entry has been set, we must check that the "make
952 # variables" haven't been set.  We start by checking of any %useradd entry
953 # is set.
954 if (grep { scalar @$_ > 0 } values %useradd) {
955     # Hash of env / make variables names.  The possible values are:
956     # 1 - "make vars"
957     # 2 - %useradd entry set
958     # 3 - both set
959     my %detected_vars =
960         map { my $v = 0;
961               $v += 1 if $cmdvars{$_};
962               $v += 2 if @{$useradd{$_}};
963               $_ => $v }
964         keys %useradd;
965
966     # If any of the corresponding "make variables" is set, we error
967     if (grep { $_ & 1 } values %detected_vars) {
968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
969                                sort keys %detected_vars);
970         die <<"_____";
971 ***** Mixing make variables and additional compiler/linker flags as
972 ***** configure command line option is not permitted.
973 ***** Affected make variables: $names
974 _____
975     }
976 }
977
978 # Check through all supported command line variables to see if any of them
979 # were set, and canonicalise the values we got.  If no compiler or linker
980 # flag or anything else that affects %useradd was set, we also check the
981 # environment for values.
982 my $anyuseradd =
983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
984 foreach (keys %user) {
985     my $value = $cmdvars{$_};
986     $value //= env($_) unless $anyuseradd;
987     $value //=
988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
990         unless $anyuseradd;
991
992     if (defined $value) {
993         if (ref $user{$_} eq 'ARRAY') {
994             $user{$_} = [ split /$list_separator_re/, $value ];
995         } elsif (!defined $user{$_}) {
996             $user{$_} = $value;
997         }
998     }
999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1411         push @{$config{dso_defines}}, "PADLOCK_ASM";
1412     }
1413 }
1414
1415 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1416 my %predefined_CXX = $config{CXX}
1417     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1418     : ();
1419
1420 # Check for makedepend capabilities.
1421 if (!$disabled{makedepend}) {
1422     if ($config{target} =~ /^(VC|vms)-/) {
1423         # For VC- and vms- targets, there's nothing more to do here.  The
1424         # functionality is hard coded in the corresponding build files for
1425         # cl (Windows) and CC/DECC (VMS).
1426     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1427              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1428         # We know that GNU C version 3 and up as well as all clang
1429         # versions support dependency generation, but Xcode did not
1430         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1431         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1432     } else {
1433         # In all other cases, we look for 'makedepend', and disable the
1434         # capability if not found.
1435         $config{makedepprog} = which('makedepend');
1436         disable('unavailable', 'makedepend') unless $config{makedepprog};
1437     }
1438 }
1439
1440 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1441     # probe for -Wa,--noexecstack option...
1442     if ($predefined_C{__clang__}) {
1443         # clang has builtin assembler, which doesn't recognize --help,
1444         # but it apparently recognizes the option in question on all
1445         # supported platforms even when it's meaningless. In other words
1446         # probe would fail, but probed option always accepted...
1447         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1448     } else {
1449         my $cc = $config{CROSS_COMPILE}.$config{CC};
1450         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1451         while(<PIPE>) {
1452             if (m/--noexecstack/) {
1453                 push @{$config{cflags}}, "-Wa,--noexecstack";
1454                 last;
1455             }
1456         }
1457         close(PIPE);
1458         unlink("null.$$.o");
1459     }
1460 }
1461
1462 # Deal with bn_ops ###################################################
1463
1464 $config{bn_ll}                  =0;
1465 $config{export_var_as_fn}       =0;
1466 my $def_int="unsigned int";
1467 $config{rc4_int}                =$def_int;
1468 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1469
1470 my $count = 0;
1471 foreach (sort split(/\s+/,$target{bn_ops})) {
1472     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1473     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1474     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1475     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1476     ($config{b64l},$config{b64},$config{b32})
1477         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1478     ($config{b64l},$config{b64},$config{b32})
1479         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1480     ($config{b64l},$config{b64},$config{b32})
1481         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1482 }
1483 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1484     if $count > 1;
1485
1486
1487 # Hack cflags for better warnings (dev option) #######################
1488
1489 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1490 # a string and works as well on command lines.
1491 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1492                         @{$config{cflags}} ];
1493 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1494                           @{$config{cxxflags}} ] if $config{CXX};
1495
1496 $config{openssl_api_defines} = [
1497     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1498 ];
1499
1500 my @strict_warnings_collection=();
1501 if ($strict_warnings)
1502         {
1503         my $wopt;
1504         my $gccver = $predefined_C{__GNUC__} // -1;
1505
1506         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1507             unless $gccver >= 4;
1508         push @strict_warnings_collection, @gcc_devteam_warn;
1509         push @strict_warnings_collection, @clang_devteam_warn
1510             if (defined($predefined_C{__clang__}));
1511         }
1512
1513 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1514     disable('static', 'pic', 'threads');
1515 }
1516
1517 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1518                               ? @strict_warnings_collection
1519                               : ( $_ ) }
1520                     @{$config{CFLAGS}} ];
1521
1522 unless ($disabled{"crypto-mdebug-backtrace"})
1523         {
1524         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1525                 {
1526                 push @{$config{cflags}}, $wopt
1527                         unless grep { $_ eq $wopt } @{$config{cflags}};
1528                 }
1529         if ($target =~ /^BSD-/)
1530                 {
1531                 push @{$config{ex_libs}}, "-lexecinfo";
1532                 }
1533         }
1534
1535 unless ($disabled{afalgeng}) {
1536     $config{afalgeng}="";
1537     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1538         my $minver = 4*10000 + 1*100 + 0;
1539         if ($config{CROSS_COMPILE} eq "") {
1540             my $verstr = `uname -r`;
1541             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1542             ($mi2) = $mi2 =~ /(\d+)/;
1543             my $ver = $ma*10000 + $mi1*100 + $mi2;
1544             if ($ver < $minver) {
1545                 disable('too-old-kernel', 'afalgeng');
1546             } else {
1547                 push @{$config{engdirs}}, "afalg";
1548             }
1549         } else {
1550             disable('cross-compiling', 'afalgeng');
1551         }
1552     } else {
1553         disable('not-linux', 'afalgeng');
1554     }
1555 }
1556
1557 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1558
1559 unless ($disabled{ktls}) {
1560     $config{ktls}="";
1561     if ($target =~ m/^linux/) {
1562         my $usr = "/usr/$config{cross_compile_prefix}";
1563         chop($usr);
1564         if ($config{cross_compile_prefix} eq "") {
1565             $usr = "/usr";
1566         }
1567         my $minver = (4 << 16) + (13 << 8) + 0;
1568         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1569
1570         if ($verstr[2] < $minver) {
1571             disable('too-old-kernel', 'ktls');
1572         }
1573     } else {
1574         disable('not-linux', 'ktls');
1575     }
1576 }
1577
1578 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1579
1580 # Get the extra flags used when building shared libraries and modules.  We
1581 # do this late because some of them depend on %disabled.
1582
1583 # Make the flags to build DSOs the same as for shared libraries unless they
1584 # are already defined
1585 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1586 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1587 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1588 {
1589     my $shared_info_pl =
1590         catfile(dirname($0), "Configurations", "shared-info.pl");
1591     my %shared_info = read_eval_file($shared_info_pl);
1592     push @{$target{_conf_fname_int}}, $shared_info_pl;
1593     my $si = $target{shared_target};
1594     while (ref $si ne "HASH") {
1595         last if ! defined $si;
1596         if (ref $si eq "CODE") {
1597             $si = $si->();
1598         } else {
1599             $si = $shared_info{$si};
1600         }
1601     }
1602
1603     # Some of the 'shared_target' values don't have any entries in
1604     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1605     # template knows how to handle this.  That is currently the case for
1606     # Windows and VMS.
1607     if (defined $si) {
1608         # Just as above, copy certain shared_* attributes to the corresponding
1609         # module_ attribute unless the latter is already defined
1610         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1611         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1612         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1613         foreach (sort keys %$si) {
1614             $target{$_} = defined $target{$_}
1615                 ? add($si->{$_})->($target{$_})
1616                 : $si->{$_};
1617         }
1618     }
1619 }
1620
1621 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1622
1623 # If we use the unified build, collect information from build.info files
1624 my %unified_info = ();
1625
1626 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1627 if ($builder eq "unified") {
1628     use with_fallback qw(Text::Template);
1629
1630     sub cleandir {
1631         my $base = shift;
1632         my $dir = shift;
1633         my $relativeto = shift || ".";
1634
1635         $dir = catdir($base,$dir) unless isabsolute($dir);
1636
1637         # Make sure the directories we're building in exists
1638         mkpath($dir);
1639
1640         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1641         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1642         return $res;
1643     }
1644
1645     sub cleanfile {
1646         my $base = shift;
1647         my $file = shift;
1648         my $relativeto = shift || ".";
1649
1650         $file = catfile($base,$file) unless isabsolute($file);
1651
1652         my $d = dirname($file);
1653         my $f = basename($file);
1654
1655         # Make sure the directories we're building in exists
1656         mkpath($d);
1657
1658         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1659         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1660         return $res;
1661     }
1662
1663     # Store the name of the template file we will build the build file from
1664     # in %config.  This may be useful for the build file itself.
1665     my @build_file_template_names =
1666         ( $builder_platform."-".$target{build_file}.".tmpl",
1667           $target{build_file}.".tmpl" );
1668     my @build_file_templates = ();
1669
1670     # First, look in the user provided directory, if given
1671     if (defined env($local_config_envname)) {
1672         @build_file_templates =
1673             map {
1674                 if ($^O eq 'VMS') {
1675                     # VMS environment variables are logical names,
1676                     # which can be used as is
1677                     $local_config_envname . ':' . $_;
1678                 } else {
1679                     catfile(env($local_config_envname), $_);
1680                 }
1681             }
1682             @build_file_template_names;
1683     }
1684     # Then, look in our standard directory
1685     push @build_file_templates,
1686         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1687           @build_file_template_names );
1688
1689     my $build_file_template;
1690     for $_ (@build_file_templates) {
1691         $build_file_template = $_;
1692         last if -f $build_file_template;
1693
1694         $build_file_template = undef;
1695     }
1696     if (!defined $build_file_template) {
1697         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1698     }
1699     $config{build_file_templates}
1700       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1701                     $blddir),
1702           $build_file_template,
1703           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1704                     $blddir) ];
1705
1706     my @build_dirs = ( [ ] );   # current directory
1707
1708     $config{build_infos} = [ ];
1709
1710     my %ordinals = ();
1711     while (@build_dirs) {
1712         my @curd = @{shift @build_dirs};
1713         my $sourced = catdir($srcdir, @curd);
1714         my $buildd = catdir($blddir, @curd);
1715
1716         my $unixdir = join('/', @curd);
1717         if (exists $skipdir{$unixdir}) {
1718             my $what = $skipdir{$unixdir};
1719             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1720             next;
1721         }
1722
1723         mkpath($buildd);
1724
1725         my $f = 'build.info';
1726         # The basic things we're trying to build
1727         my @programs = ();
1728         my @libraries = ();
1729         my @modules = ();
1730         my @scripts = ();
1731
1732         my %attributes = ();
1733         my %sources = ();
1734         my %shared_sources = ();
1735         my %includes = ();
1736         my %defines = ();
1737         my %depends = ();
1738         my %generate = ();
1739
1740         # Support for $variablename in build.info files.
1741         # Embedded perl code is the ultimate master, still.  If its output
1742         # contains a dollar sign, it had better be escaped, or it will be
1743         # taken for a variable name prefix.
1744         my %variables = ();
1745         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1746         my $expand_variables = sub {
1747             my $value = '';
1748             my $value_rest = shift;
1749
1750             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1751                 $value .= $`;
1752                 $value .= $variables{$1};
1753                 $value_rest = $';
1754             }
1755             return $value . $value_rest;
1756         };
1757
1758         # We want to detect configdata.pm in the source tree, so we
1759         # don't use it if the build tree is different.
1760         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1761
1762         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1763         my $template =
1764             Text::Template->new(TYPE => 'FILE',
1765                                 SOURCE => catfile($sourced, $f),
1766                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1767         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1768         my @text =
1769             split /^/m,
1770             $template->fill_in(HASH => { config => \%config,
1771                                          target => \%target,
1772                                          disabled => \%disabled,
1773                                          withargs => \%withargs,
1774                                          builddir => abs2rel($buildd, $blddir),
1775                                          sourcedir => abs2rel($sourced, $blddir),
1776                                          buildtop => abs2rel($blddir, $blddir),
1777                                          sourcetop => abs2rel($srcdir, $blddir) },
1778                                DELIMITERS => [ "{-", "-}" ]);
1779
1780         # The top item of this stack has the following values
1781         # -2 positive already run and we found ELSE (following ELSIF should fail)
1782         # -1 positive already run (skip until ENDIF)
1783         # 0 negatives so far (if we're at a condition, check it)
1784         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1785         # 2 positive ELSE (following ELSIF should fail)
1786         my @skip = ();
1787         collect_information(
1788             collect_from_array([ @text ],
1789                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1790                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1791             # Info we're looking for
1792             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1793             => sub {
1794                 if (! @skip || $skip[$#skip] > 0) {
1795                     push @skip, !! $expand_variables->($1);
1796                 } else {
1797                     push @skip, -1;
1798                 }
1799             },
1800             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1801             => sub { die "ELSIF out of scope" if ! @skip;
1802                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1803                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1804                      $skip[$#skip] = !! $expand_variables->($1)
1805                          if $skip[$#skip] == 0; },
1806             qr/^\s*ELSE\s*$/
1807             => sub { die "ELSE out of scope" if ! @skip;
1808                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1809                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1810             qr/^\s*ENDIF\s*$/
1811             => sub { die "ENDIF out of scope" if ! @skip;
1812                      pop @skip; },
1813             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1814             => sub {
1815                 if (!@skip || $skip[$#skip] > 0) {
1816                     my $n = $1;
1817                     my $v = $2;
1818                     $variables{$n} = $expand_variables->($v);
1819                 }
1820             },
1821             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1822             => sub {
1823                 if (!@skip || $skip[$#skip] > 0) {
1824                     foreach (tokenize($expand_variables->($1))) {
1825                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1826                     }
1827                 }
1828             },
1829             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1830             => sub {
1831                 if (!@skip || $skip[$#skip] > 0) {
1832                     my @a = tokenize($1, qr|\s*,\s*|);
1833                     my @p = tokenize($expand_variables->($2));
1834                     push @programs, @p;
1835                     foreach my $a (@a) {
1836                         my $ak = $a;
1837                         my $av = 1;
1838                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1839                             $ak = $1;
1840                             $av = $2;
1841                         }
1842                         foreach my $p (@p) {
1843                             $attributes{$p}->{$ak} = $av;
1844                         }
1845                     }
1846                 }
1847             },
1848             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1849             => sub {
1850                 if (!@skip || $skip[$#skip] > 0) {
1851                     my @a = tokenize($1, qr|\s*,\s*|);
1852                     my @l = tokenize($expand_variables->($2));
1853                     push @libraries, @l;
1854                     foreach my $a (@a) {
1855                         my $ak = $a;
1856                         my $av = 1;
1857                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1858                             $ak = $1;
1859                             $av = $2;
1860                         }
1861                         foreach my $l (@l) {
1862                             $attributes{$l}->{$ak} = $av;
1863                         }
1864                     }
1865                 }
1866             },
1867             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1868             => sub {
1869                 if (!@skip || $skip[$#skip] > 0) {
1870                     my @a = tokenize($1, qr|\s*,\s*|);
1871                     my @m = tokenize($expand_variables->($2));
1872                     push @modules, @m;
1873                     foreach my $a (@a) {
1874                         my $ak = $a;
1875                         my $av = 1;
1876                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1877                             $ak = $1;
1878                             $av = $2;
1879                         }
1880                         foreach my $m (@m) {
1881                             $attributes{$m}->{$ak} = $av;
1882                         }
1883                     }
1884                 }
1885             },
1886             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1887             => sub {
1888                 if (!@skip || $skip[$#skip] > 0) {
1889                     my @a = tokenize($1, qr|\s*,\s*|);
1890                     my @s = tokenize($expand_variables->($2));
1891                     push @scripts, @s;
1892                     foreach my $a (@a) {
1893                         my $ak = $a;
1894                         my $av = 1;
1895                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1896                             $ak = $1;
1897                             $av = $2;
1898                         }
1899                         foreach my $s (@s) {
1900                             $attributes{$s}->{$ak} = $av;
1901                         }
1902                     }
1903                 }
1904             },
1905
1906             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1907             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1908                          if !@skip || $skip[$#skip] > 0 },
1909             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1910             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1911                          if !@skip || $skip[$#skip] > 0 },
1912             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1913             => sub { push @{$shared_sources{$1}},
1914                          tokenize($expand_variables->($2))
1915                          if !@skip || $skip[$#skip] > 0 },
1916             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1917             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1918                          if !@skip || $skip[$#skip] > 0 },
1919             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1920             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1923             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1926             => sub { push @{$generate{$1}}, $2
1927                          if !@skip || $skip[$#skip] > 0 },
1928             qr/^\s*(?:#.*)?$/ => sub { },
1929             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1930             "BEFORE" => sub {
1931                 if ($buildinfo_debug) {
1932                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1933                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1934                 }
1935             },
1936             "AFTER" => sub {
1937                 if ($buildinfo_debug) {
1938                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1939                 }
1940             },
1941             );
1942         die "runaway IF?" if (@skip);
1943
1944         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1945                 and !$config{dynamic_engines}) {
1946             die <<"EOF"
1947 ENGINES can only be used if configured with 'dynamic-engine'.
1948 This is usually a fault in a build.info file.
1949 EOF
1950         }
1951
1952         foreach (keys %attributes) {
1953             my $dest = $_;
1954             my $ddest = cleanfile($buildd, $_, $blddir);
1955             foreach (keys %{$attributes{$dest} // {}}) {
1956                 $unified_info{attributes}->{$ddest}->{$_} =
1957                     $attributes{$dest}->{$_};
1958             }
1959         }
1960
1961         {
1962             my %infos = ( programs  => [ @programs  ],
1963                           libraries => [ @libraries ],
1964                           modules   => [ @modules   ],
1965                           scripts   => [ @scripts   ] );
1966             foreach my $k (keys %infos) {
1967                 foreach (@{$infos{$k}}) {
1968                     my $item = cleanfile($buildd, $_, $blddir);
1969                     $unified_info{$k}->{$item} = 1;
1970                 }
1971             }
1972         }
1973
1974         # Check that we haven't defined any library as both shared and
1975         # explicitly static.  That is forbidden.
1976         my @doubles = ();
1977         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1978             (my $l = $_) =~ s/\.a$//;
1979             push @doubles, $l if defined $unified_info{libraries}->{$l};
1980         }
1981         die "these libraries are both explicitly static and shared:\n  ",
1982             join(" ", @doubles), "\n"
1983             if @doubles;
1984
1985         foreach (keys %sources) {
1986             my $dest = $_;
1987             my $ddest = cleanfile($buildd, $_, $blddir);
1988             foreach (@{$sources{$dest}}) {
1989                 my $s = cleanfile($sourced, $_, $blddir);
1990
1991                 # If it isn't in the source tree, we assume it's generated
1992                 # in the build tree
1993                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1994                     $s = cleanfile($buildd, $_, $blddir);
1995                 }
1996                 # We recognise C++, C and asm files
1997                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1998                     my $o = $_;
1999                     $o =~ s/\.[csS]$/.o/; # C and assembler
2000                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2001                     $o = cleanfile($buildd, $o, $blddir);
2002                     $unified_info{sources}->{$ddest}->{$o} = -1;
2003                     $unified_info{sources}->{$o}->{$s} = -1;
2004                 } elsif ($s =~ /\.rc$/) {
2005                     # We also recognise resource files
2006                     my $o = $_;
2007                     $o =~ s/\.rc$/.res/; # Resource configuration
2008                     my $o = cleanfile($buildd, $o, $blddir);
2009                     $unified_info{sources}->{$ddest}->{$o} = -1;
2010                     $unified_info{sources}->{$o}->{$s} = -1;
2011                 } else {
2012                     $unified_info{sources}->{$ddest}->{$s} = 1;
2013                 }
2014             }
2015         }
2016
2017         foreach (keys %shared_sources) {
2018             my $dest = $_;
2019             my $ddest = cleanfile($buildd, $_, $blddir);
2020             foreach (@{$shared_sources{$dest}}) {
2021                 my $s = cleanfile($sourced, $_, $blddir);
2022
2023                 # If it isn't in the source tree, we assume it's generated
2024                 # in the build tree
2025                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2026                     $s = cleanfile($buildd, $_, $blddir);
2027                 }
2028
2029                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2030                     # We recognise C++, C and asm files
2031                     my $o = $_;
2032                     $o =~ s/\.[csS]$/.o/; # C and assembler
2033                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2034                     $o = cleanfile($buildd, $o, $blddir);
2035                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2036                     $unified_info{sources}->{$o}->{$s} = -1;
2037                 } elsif ($s =~ /\.rc$/) {
2038                     # We also recognise resource files
2039                     my $o = $_;
2040                     $o =~ s/\.rc$/.res/; # Resource configuration
2041                     my $o = cleanfile($buildd, $o, $blddir);
2042                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2043                     $unified_info{sources}->{$o}->{$s} = -1;
2044                 } elsif ($s =~ /\.ld$/) {
2045                     # We also recognise linker scripts (or corresponding)
2046                     # We know they are generated files
2047                     my $ld = cleanfile($buildd, $_, $blddir);
2048                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2049                 } else {
2050                     die "unrecognised source file type for shared library: $s\n";
2051                 }
2052             }
2053         }
2054
2055         foreach (keys %generate) {
2056             my $dest = $_;
2057             my $ddest = cleanfile($buildd, $_, $blddir);
2058             die "more than one generator for $dest: "
2059                     ,join(" ", @{$generate{$_}}),"\n"
2060                     if scalar @{$generate{$_}} > 1;
2061             my @generator = split /\s+/, $generate{$dest}->[0];
2062             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2063             $unified_info{generate}->{$ddest} = [ @generator ];
2064         }
2065
2066         foreach (keys %depends) {
2067             my $dest = $_;
2068             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2069
2070             # If the destination doesn't exist in source, it can only be
2071             # a generated file in the build tree.
2072             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2073                 $ddest = cleanfile($buildd, $_, $blddir);
2074             }
2075             foreach (@{$depends{$dest}}) {
2076                 my $d = cleanfile($sourced, $_, $blddir);
2077
2078                 # If we know it's generated, or assume it is because we can't
2079                 # find it in the source tree, we set file we depend on to be
2080                 # in the build tree rather than the source tree, and assume
2081                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2082                 # section or in the Makefile template.
2083                 if ($d eq $src_configdata
2084                     || ! -f $d
2085                     || (grep { $d eq $_ }
2086                         map { cleanfile($srcdir, $_, $blddir) }
2087                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2088                     $d = cleanfile($buildd, $_, $blddir);
2089                 }
2090                 # Take note if the file to depend on is being renamed
2091                 # Take extra care with files ending with .a, they should
2092                 # be treated without that extension, and the extension
2093                 # should be added back after treatment.
2094                 $d =~ /(\.a)?$/;
2095                 my $e = $1 // "";
2096                 $d = $`.$e;
2097                 $unified_info{depends}->{$ddest}->{$d} = 1;
2098             }
2099         }
2100
2101         foreach (keys %includes) {
2102             my $dest = $_;
2103             my $ddest = cleanfile($sourced, $_, $blddir);
2104
2105             # If the destination doesn't exist in source, it can only be
2106             # a generated file in the build tree.
2107             if ($ddest eq $src_configdata || ! -f $ddest) {
2108                 $ddest = cleanfile($buildd, $_, $blddir);
2109             }
2110             foreach (@{$includes{$dest}}) {
2111                 my $is = cleandir($sourced, $_, $blddir);
2112                 my $ib = cleandir($buildd, $_, $blddir);
2113                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2114                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2115                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2116                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2117             }
2118         }
2119
2120         foreach (keys %defines) {
2121             my $dest = $_;
2122             my $ddest = cleanfile($sourced, $_, $blddir);
2123
2124             # If the destination doesn't exist in source, it can only be
2125             # a generated file in the build tree.
2126             if (! -f $ddest) {
2127                 $ddest = cleanfile($buildd, $_, $blddir);
2128                 if ($unified_info{rename}->{$ddest}) {
2129                     $ddest = $unified_info{rename}->{$ddest};
2130                 }
2131             }
2132             foreach (@{$defines{$dest}}) {
2133                 m|^([^=]*)(=.*)?$|;
2134                 die "0 length macro name not permitted\n" if $1 eq "";
2135                 die "$1 defined more than once\n"
2136                     if defined $unified_info{defines}->{$ddest}->{$1};
2137                 $unified_info{defines}->{$ddest}->{$1} = $2;
2138             }
2139         }
2140     }
2141
2142     my $ordinals_text = join(', ', sort keys %ordinals);
2143     warn <<"EOF" if $ordinals_text;
2144
2145 WARNING: ORDINALS were specified for $ordinals_text
2146 They are ignored and should be replaced with a combination of GENERATE,
2147 DEPEND and SHARED_SOURCE.
2148 EOF
2149
2150
2151     # Go through the sources of all libraries and check that the same basename
2152     # doesn't appear more than once.  Some static library archivers depend on
2153     # them being unique.
2154     {
2155         my $err = 0;
2156         foreach my $prod (keys %{$unified_info{libraries}}) {
2157             my @prod_sources =
2158                 map { keys %{$unified_info{sources}->{$_}} }
2159                 keys %{$unified_info{sources}->{$prod}};
2160             my %srccnt = ();
2161
2162             # Count how many times a given each source basename
2163             # appears for each product.
2164             foreach my $src (@prod_sources) {
2165                 $srccnt{basename $src}++;
2166             }
2167
2168             foreach my $src (keys %srccnt) {
2169                 if ((my $cnt = $srccnt{$src}) > 1) {
2170                     print STDERR "$src appears $cnt times for the product $prod\n";
2171                     $err++
2172                 }
2173             }
2174         }
2175         die if $err > 0;
2176     }
2177
2178     # Massage the result
2179
2180     # If we depend on a header file or a perl module, add an inclusion of
2181     # its directory to allow smoothe inclusion
2182     foreach my $dest (keys %{$unified_info{depends}}) {
2183         next if $dest eq "";
2184         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2185             next unless $d =~ /\.(h|pm)$/;
2186             my $i = dirname($d);
2187             my $spot =
2188                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2189                 ? 'build' : 'source';
2190             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2191                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2192         }
2193     }
2194
2195     # Go through all intermediary files and change their names to something that
2196     # reflects what they will be built for.  Note that for some source files,
2197     # this leads to duplicate object files because they are used multiple times.
2198     # the goal is to rename all object files according to this scheme:
2199     #    {productname}-{midfix}-{origobjname}.[o|res]
2200     # the {midfix} is a keyword indicating the type of product, which is mostly
2201     # valuable for libraries since they come in two forms.
2202     #
2203     # This also reorganises the {sources} and {shared_sources} so that the
2204     # former only contains ALL object files that are supposed to end up in
2205     # static libraries and programs, while the latter contains ALL object files
2206     # that are supposed to end up in shared libraries and DSOs.
2207     # The main reason for having two different source structures is to allow
2208     # the same name to be used for the static and the shared variants of a
2209     # library.
2210     {
2211         # Take copies so we don't get interference from added stuff
2212         my %unified_copy = ();
2213         foreach (('sources', 'shared_sources')) {
2214             $unified_copy{$_} = { %{$unified_info{$_}} }
2215                 if defined($unified_info{$_});
2216             delete $unified_info{$_};
2217         }
2218         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2219             # $intent serves multi purposes:
2220             # - give a prefix for the new object files names
2221             # - in the case of libraries, rearrange the object files so static
2222             #   libraries use the 'sources' structure exclusively, while shared
2223             #   libraries use the 'shared_sources' structure exclusively.
2224             my $intent = {
2225                 programs  => { bin    => { src => [ 'sources' ],
2226                                            dst => 'sources' } },
2227                 libraries => { lib    => { src => [ 'sources' ],
2228                                            dst => 'sources' },
2229                                shlib  => { prodselect =>
2230                                                sub { grep !/\.a$/, @_ },
2231                                            src => [ 'sources',
2232                                                     'shared_sources' ],
2233                                            dst => 'shared_sources' } },
2234                 modules   => { dso    => { src => [ 'sources' ],
2235                                            dst => 'sources' } },
2236                 scripts   => { script => { src => [ 'sources' ],
2237                                            dst => 'sources' } }
2238                } -> {$prodtype};
2239             foreach my $kind (keys %$intent) {
2240                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2241                              && $disabled{shared});
2242
2243                 my @src = @{$intent->{$kind}->{src}};
2244                 my $dst = $intent->{$kind}->{dst};
2245                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2246                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2247                     # %prod_sources has all applicable objects as keys, and
2248                     # their corresponding sources as values
2249                     my %prod_sources =
2250                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2251                         map { keys %{$unified_copy{$_}->{$prod}} }
2252                         @src;
2253                     foreach (keys %prod_sources) {
2254                         # Only affect object files and resource files,
2255                         # the others simply get a new value
2256                         # (+1 instead of -1)
2257                         if ($_ =~ /\.(o|res)$/) {
2258                             (my $prodname = $prod) =~ s|\.a$||;
2259                             my $newobj =
2260                                 catfile(dirname($_),
2261                                         basename($prodname)
2262                                             . '-' . $kind
2263                                             . '-' . basename($_));
2264                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2265                             foreach my $src (@{$prod_sources{$_}}) {
2266                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2267                             }
2268                             # Adjust dependencies
2269                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2270                                 $unified_info{depends}->{$_}->{$deps} = -1;
2271                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2272                             }
2273                             # Adjust includes
2274                             foreach my $k (('source', 'build')) {
2275                                 next unless
2276                                     defined($unified_info{includes}->{$_}->{$k});
2277                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2278                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2279                             }
2280                         } else {
2281                             $unified_info{$dst}->{$prod}->{$_} = 1;
2282                         }
2283                     }
2284                 }
2285             }
2286         }
2287     }
2288
2289     # At this point, we have a number of sources with the value -1.  They
2290     # aren't part of the local build and are probably meant for a different
2291     # platform, and can therefore be cleaned away.  That happens when making
2292     # %unified_info more efficient below.
2293
2294     ### Make unified_info a bit more efficient
2295     # One level structures
2296     foreach (("programs", "libraries", "modules", "scripts")) {
2297         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2298     }
2299     # Two level structures
2300     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2301         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2302             my @items =
2303                 sort
2304                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2305                 keys %{$unified_info{$l1}->{$l2}};
2306             if (@items) {
2307                 $unified_info{$l1}->{$l2} = [ @items ];
2308             } else {
2309                 delete $unified_info{$l1}->{$l2};
2310             }
2311         }
2312     }
2313     # Defines
2314     foreach my $dest (sort keys %{$unified_info{defines}}) {
2315         $unified_info{defines}->{$dest}
2316             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2317                 sort keys %{$unified_info{defines}->{$dest}} ];
2318     }
2319     # Includes
2320     foreach my $dest (sort keys %{$unified_info{includes}}) {
2321         if (defined($unified_info{includes}->{$dest}->{build})) {
2322             my @source_includes = ();
2323             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2324                 if defined($unified_info{includes}->{$dest}->{source});
2325             $unified_info{includes}->{$dest} =
2326                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2327             foreach my $inc (@source_includes) {
2328                 push @{$unified_info{includes}->{$dest}}, $inc
2329                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2330             }
2331         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2332             $unified_info{includes}->{$dest} =
2333                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2334         } else {
2335             delete $unified_info{includes}->{$dest};
2336         }
2337     }
2338
2339     # For convenience collect information regarding directories where
2340     # files are generated, those generated files and the end product
2341     # they end up in where applicable.  Then, add build rules for those
2342     # directories
2343     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2344                      "dso" => [ @{$unified_info{modules}} ],
2345                      "bin" => [ @{$unified_info{programs}} ],
2346                      "script" => [ @{$unified_info{scripts}} ] );
2347     foreach my $type (keys %loopinfo) {
2348         foreach my $product (@{$loopinfo{$type}}) {
2349             my %dirs = ();
2350             my $pd = dirname($product);
2351
2352             foreach (@{$unified_info{sources}->{$product} // []},
2353                      @{$unified_info{shared_sources}->{$product} // []}) {
2354                 my $d = dirname($_);
2355
2356                 # We don't want to create targets for source directories
2357                 # when building out of source
2358                 next if ($config{sourcedir} ne $config{builddir}
2359                              && $d =~ m|^\Q$config{sourcedir}\E|);
2360                 # We already have a "test" target, and the current directory
2361                 # is just silly to make a target for
2362                 next if $d eq "test" || $d eq ".";
2363
2364                 $dirs{$d} = 1;
2365                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2366                     if $d ne $pd;
2367             }
2368             foreach (keys %dirs) {
2369                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2370                     $product;
2371             }
2372         }
2373     }
2374 }
2375
2376 # For the schemes that need it, we provide the old *_obj configs
2377 # from the *_asm_obj ones
2378 foreach (grep /_(asm|aux)_src$/, keys %target) {
2379     my $src = $_;
2380     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2381     $target{$obj} = $target{$src};
2382     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2383     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2384 }
2385
2386 # Write down our configuration where it fits #########################
2387
2388 print "Creating configdata.pm\n";
2389 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2390 print OUT <<"EOF";
2391 #! $config{HASHBANGPERL}
2392
2393 package configdata;
2394
2395 use strict;
2396 use warnings;
2397
2398 use Exporter;
2399 #use vars qw(\@ISA \@EXPORT);
2400 our \@ISA = qw(Exporter);
2401 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2402
2403 EOF
2404 print OUT "our %config = (\n";
2405 foreach (sort keys %config) {
2406     if (ref($config{$_}) eq "ARRAY") {
2407         print OUT "  ", $_, " => [ ", join(", ",
2408                                            map { quotify("perl", $_) }
2409                                            @{$config{$_}}), " ],\n";
2410     } elsif (ref($config{$_}) eq "HASH") {
2411         print OUT "  ", $_, " => {";
2412         if (scalar keys %{$config{$_}} > 0) {
2413             print OUT "\n";
2414             foreach my $key (sort keys %{$config{$_}}) {
2415                 print OUT "      ",
2416                     join(" => ",
2417                          quotify("perl", $key),
2418                          defined $config{$_}->{$key}
2419                              ? quotify("perl", $config{$_}->{$key})
2420                              : "undef");
2421                 print OUT ",\n";
2422             }
2423             print OUT "  ";
2424         }
2425         print OUT "},\n";
2426     } else {
2427         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2428     }
2429 }
2430 print OUT <<"EOF";
2431 );
2432
2433 EOF
2434 print OUT "our %target = (\n";
2435 foreach (sort keys %target) {
2436     if (ref($target{$_}) eq "ARRAY") {
2437         print OUT "  ", $_, " => [ ", join(", ",
2438                                            map { quotify("perl", $_) }
2439                                            @{$target{$_}}), " ],\n";
2440     } else {
2441         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2442     }
2443 }
2444 print OUT <<"EOF";
2445 );
2446
2447 EOF
2448 print OUT "our \%available_protocols = (\n";
2449 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2450 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2451 print OUT <<"EOF";
2452 );
2453
2454 EOF
2455 print OUT "our \@disablables = (\n";
2456 foreach (@disablables) {
2457     print OUT "  ", quotify("perl", $_), ",\n";
2458 }
2459 print OUT <<"EOF";
2460 );
2461
2462 EOF
2463 print OUT "# The following come from Configure's @disablables_int\n";
2464 print OUT "our \@disablables_int = (\n";
2465 foreach (@disablables_int) {
2466     print OUT "  ", quotify("perl", $_), ",\n";
2467 }
2468 print OUT <<"EOF";
2469 );
2470
2471 EOF
2472 print OUT "our \%disabled = (\n";
2473 foreach (sort keys %disabled) {
2474     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2475 }
2476 print OUT <<"EOF";
2477 );
2478
2479 EOF
2480 print OUT "our %withargs = (\n";
2481 foreach (sort keys %withargs) {
2482     if (ref($withargs{$_}) eq "ARRAY") {
2483         print OUT "  ", $_, " => [ ", join(", ",
2484                                            map { quotify("perl", $_) }
2485                                            @{$withargs{$_}}), " ],\n";
2486     } else {
2487         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2488     }
2489 }
2490 print OUT <<"EOF";
2491 );
2492
2493 EOF
2494 if ($builder eq "unified") {
2495     my $recurse;
2496     $recurse = sub {
2497         my $indent = shift;
2498         foreach (@_) {
2499             if (ref $_ eq "ARRAY") {
2500                 print OUT " "x$indent, "[\n";
2501                 foreach (@$_) {
2502                     $recurse->($indent + 4, $_);
2503                 }
2504                 print OUT " "x$indent, "],\n";
2505             } elsif (ref $_ eq "HASH") {
2506                 my %h = %$_;
2507                 print OUT " "x$indent, "{\n";
2508                 foreach (sort keys %h) {
2509                     if (ref $h{$_} eq "") {
2510                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2511                     } else {
2512                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2513                         $recurse->($indent + 8, $h{$_});
2514                     }
2515                 }
2516                 print OUT " "x$indent, "},\n";
2517             } else {
2518                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2519             }
2520         }
2521     };
2522     print OUT "our %unified_info = (\n";
2523     foreach (sort keys %unified_info) {
2524         if (ref $unified_info{$_} eq "") {
2525             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2526         } else {
2527             print OUT " "x4, quotify("perl", $_), " =>\n";
2528             $recurse->(8, $unified_info{$_});
2529         }
2530     }
2531     print OUT <<"EOF";
2532 );
2533
2534 EOF
2535 }
2536 print OUT
2537     "# The following data is only used when this files is use as a script\n";
2538 print OUT "my \@makevars = (\n";
2539 foreach (sort keys %user) {
2540     print OUT "    '",$_,"',\n";
2541 }
2542 print OUT ");\n";
2543 print OUT "my \%disabled_info = (\n";
2544 foreach my $what (sort keys %disabled_info) {
2545     print OUT "    '$what' => {\n";
2546     foreach my $info (sort keys %{$disabled_info{$what}}) {
2547         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2548             print OUT "        $info => [ ",
2549                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2550                 " ],\n";
2551         } else {
2552             print OUT "        $info => '", $disabled_info{$what}->{$info},
2553                 "',\n";
2554         }
2555     }
2556     print OUT "    },\n";
2557 }
2558 print OUT ");\n";
2559 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2560 print OUT << 'EOF';
2561 # If run directly, we can give some answers, and even reconfigure
2562 unless (caller) {
2563     use Getopt::Long;
2564     use File::Spec::Functions;
2565     use File::Basename;
2566     use Pod::Usage;
2567
2568     my $here = dirname($0);
2569
2570     my $dump = undef;
2571     my $cmdline = undef;
2572     my $options = undef;
2573     my $target = undef;
2574     my $envvars = undef;
2575     my $makevars = undef;
2576     my $buildparams = undef;
2577     my $reconf = undef;
2578     my $verbose = undef;
2579     my $help = undef;
2580     my $man = undef;
2581     GetOptions('dump|d'                 => \$dump,
2582                'command-line|c'         => \$cmdline,
2583                'options|o'              => \$options,
2584                'target|t'               => \$target,
2585                'environment|e'          => \$envvars,
2586                'make-variables|m'       => \$makevars,
2587                'build-parameters|b'     => \$buildparams,
2588                'reconfigure|reconf|r'   => \$reconf,
2589                'verbose|v'              => \$verbose,
2590                'help'                   => \$help,
2591                'man'                    => \$man)
2592         or die "Errors in command line arguments\n";
2593
2594     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2595             || $buildparams || $reconf || $verbose || $help || $man) {
2596         print STDERR <<"_____";
2597 You must give at least one option.
2598 For more information, do '$0 --help'
2599 _____
2600         exit(2);
2601     }
2602
2603     if ($help) {
2604         pod2usage(-exitval => 0,
2605                   -verbose => 1);
2606     }
2607     if ($man) {
2608         pod2usage(-exitval => 0,
2609                   -verbose => 2);
2610     }
2611     if ($dump || $cmdline) {
2612         print "\nCommand line (with current working directory = $here):\n\n";
2613         print '    ',join(' ',
2614                           $config{PERL},
2615                           catfile($config{sourcedir}, 'Configure'),
2616                           @{$config{perlargv}}), "\n";
2617         print "\nPerl information:\n\n";
2618         print '    ',$config{perl_cmd},"\n";
2619         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2620     }
2621     if ($dump || $options) {
2622         my $longest = 0;
2623         my $longest2 = 0;
2624         foreach my $what (@disablables) {
2625             $longest = length($what) if $longest < length($what);
2626             $longest2 = length($disabled{$what})
2627                 if $disabled{$what} && $longest2 < length($disabled{$what});
2628         }
2629         print "\nEnabled features:\n\n";
2630         foreach my $what (@disablables) {
2631             print "    $what\n" unless $disabled{$what};
2632         }
2633         print "\nDisabled features:\n\n";
2634         foreach my $what (@disablables) {
2635             if ($disabled{$what}) {
2636                 print "    $what", ' ' x ($longest - length($what) + 1),
2637                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2638                 print $disabled_info{$what}->{macro}
2639                     if $disabled_info{$what}->{macro};
2640                 print ' (skip ',
2641                     join(', ', @{$disabled_info{$what}->{skipped}}),
2642                     ')'
2643                     if $disabled_info{$what}->{skipped};
2644                 print "\n";
2645             }
2646         }
2647     }
2648     if ($dump || $target) {
2649         print "\nConfig target attributes:\n\n";
2650         foreach (sort keys %target) {
2651             next if $_ =~ m|^_| || $_ eq 'template';
2652             my $quotify = sub {
2653                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2654             };
2655             print '    ', $_, ' => ';
2656             if (ref($target{$_}) eq "ARRAY") {
2657                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2658             } else {
2659                 print $quotify->($target{$_}), ",\n"
2660             }
2661         }
2662     }
2663     if ($dump || $envvars) {
2664         print "\nRecorded environment:\n\n";
2665         foreach (sort keys %{$config{perlenv}}) {
2666             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2667         }
2668     }
2669     if ($dump || $makevars) {
2670         print "\nMakevars:\n\n";
2671         foreach my $var (@makevars) {
2672             my $prefix = '';
2673             $prefix = $config{CROSS_COMPILE}
2674                 if grep { $var eq $_ } @user_crossable;
2675             $prefix //= '';
2676             print '    ',$var,' ' x (16 - length $var),'= ',
2677                 (ref $config{$var} eq 'ARRAY'
2678                  ? join(' ', @{$config{$var}})
2679                  : $prefix.$config{$var}),
2680                 "\n"
2681                 if defined $config{$var};
2682         }
2683
2684         my @buildfile = ($config{builddir}, $config{build_file});
2685         unshift @buildfile, $here
2686             unless file_name_is_absolute($config{builddir});
2687         my $buildfile = canonpath(catdir(@buildfile));
2688         print <<"_____";
2689
2690 NOTE: These variables only represent the configuration view.  The build file
2691 template may have processed these variables further, please have a look at the
2692 build file for more exact data:
2693     $buildfile
2694 _____
2695     }
2696     if ($dump || $buildparams) {
2697         my @buildfile = ($config{builddir}, $config{build_file});
2698         unshift @buildfile, $here
2699             unless file_name_is_absolute($config{builddir});
2700         print "\nbuild file:\n\n";
2701         print "    ", canonpath(catfile(@buildfile)),"\n";
2702
2703         print "\nbuild file templates:\n\n";
2704         foreach (@{$config{build_file_templates}}) {
2705             my @tmpl = ($_);
2706             unshift @tmpl, $here
2707                 unless file_name_is_absolute($config{sourcedir});
2708             print '    ',canonpath(catfile(@tmpl)),"\n";
2709         }
2710     }
2711     if ($reconf) {
2712         if ($verbose) {
2713             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2714             foreach (sort keys %{$config{perlenv}}) {
2715                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2716             }
2717         }
2718
2719         chdir $here;
2720         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2721     }
2722 }
2723
2724 1;
2725
2726 __END__
2727
2728 =head1 NAME
2729
2730 configdata.pm - configuration data for OpenSSL builds
2731
2732 =head1 SYNOPSIS
2733
2734 Interactive:
2735
2736   perl configdata.pm [options]
2737
2738 As data bank module:
2739
2740   use configdata;
2741
2742 =head1 DESCRIPTION
2743
2744 This module can be used in two modes, interactively and as a module containing
2745 all the data recorded by OpenSSL's Configure script.
2746
2747 When used interactively, simply run it as any perl script, with at least one
2748 option, and you will get the information you ask for.  See L</OPTIONS> below.
2749
2750 When loaded as a module, you get a few databanks with useful information to
2751 perform build related tasks.  The databanks are:
2752
2753     %config             Configured things.
2754     %target             The OpenSSL config target with all inheritances
2755                         resolved.
2756     %disabled           The features that are disabled.
2757     @disablables        The list of features that can be disabled.
2758     %withargs           All data given through --with-THING options.
2759     %unified_info       All information that was computed from the build.info
2760                         files.
2761
2762 =head1 OPTIONS
2763
2764 =over 4
2765
2766 =item B<--help>
2767
2768 Print a brief help message and exit.
2769
2770 =item B<--man>
2771
2772 Print the manual page and exit.
2773
2774 =item B<--dump> | B<-d>
2775
2776 Print all relevant configuration data.  This is equivalent to B<--command-line>
2777 B<--options> B<--target> B<--environment> B<--make-variables>
2778 B<--build-parameters>.
2779
2780 =item B<--command-line> | B<-c>
2781
2782 Print the current configuration command line.
2783
2784 =item B<--options> | B<-o>
2785
2786 Print the features, both enabled and disabled, and display defined macro and
2787 skipped directories where applicable.
2788
2789 =item B<--target> | B<-t>
2790
2791 Print the config attributes for this config target.
2792
2793 =item B<--environment> | B<-e>
2794
2795 Print the environment variables and their values at the time of configuration.
2796
2797 =item B<--make-variables> | B<-m>
2798
2799 Print the main make variables generated in the current configuration
2800
2801 =item B<--build-parameters> | B<-b>
2802
2803 Print the build parameters, i.e. build file and build file templates.
2804
2805 =item B<--reconfigure> | B<--reconf> | B<-r>
2806
2807 Redo the configuration.
2808
2809 =item B<--verbose> | B<-v>
2810
2811 Verbose output.
2812
2813 =back
2814
2815 =cut
2816
2817 EOF
2818 close(OUT);
2819 if ($builder_platform eq 'unix') {
2820     my $mode = (0755 & ~umask);
2821     chmod $mode, 'configdata.pm'
2822         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2823 }
2824
2825 my %builders = (
2826     unified => sub {
2827         print 'Creating ',$target{build_file},"\n";
2828         run_dofile(catfile($blddir, $target{build_file}),
2829                    @{$config{build_file_templates}});
2830     },
2831     );
2832
2833 $builders{$builder}->($builder_platform, @builder_opts);
2834
2835 $SIG{__DIE__} = $orig_death_handler;
2836
2837 print <<"EOF" if ($disabled{threads} eq "unavailable");
2838
2839 The library could not be configured for supporting multi-threaded
2840 applications as the compiler options required on this system are not known.
2841 See file INSTALL for details if you need multi-threading.
2842 EOF
2843
2844 print <<"EOF" if ($no_shared_warn);
2845
2846 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2847 platform, so we will pretend you gave the option 'no-pic', which also disables
2848 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2849 or position independent code, please let us know (but please first make sure
2850 you have tried with a current version of OpenSSL).
2851 EOF
2852
2853 print <<"EOF";
2854
2855 **********************************************************************
2856 ***                                                                ***
2857 ***   OpenSSL has been successfully configured                     ***
2858 ***                                                                ***
2859 ***   If you encounter a problem while building, please open an    ***
2860 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2861 ***   and include the output from the following command:           ***
2862 ***                                                                ***
2863 ***       perl configdata.pm --dump                                ***
2864 ***                                                                ***
2865 ***   (If you are new to OpenSSL, you might want to consult the    ***
2866 ***   'Troubleshooting' section in the INSTALL file first)         ***
2867 ***                                                                ***
2868 **********************************************************************
2869 EOF
2870
2871 exit(0);
2872
2873 ######################################################################
2874 #
2875 # Helpers and utility functions
2876 #
2877
2878 # Death handler, to print a helpful message in case of failure #######
2879 #
2880 sub death_handler {
2881     die @_ if $^S;              # To prevent the added message in eval blocks
2882     my $build_file = $target{build_file} // "build file";
2883     my @message = ( <<"_____", @_ );
2884
2885 Failure!  $build_file wasn't produced.
2886 Please read INSTALL and associated NOTES files.  You may also have to look over
2887 your available compiler tool chain or change your configuration.
2888
2889 _____
2890
2891     # Dying is terminal, so it's ok to reset the signal handler here.
2892     $SIG{__DIE__} = $orig_death_handler;
2893     die @message;
2894 }
2895
2896 # Configuration file reading #########################################
2897
2898 # Note: All of the helper functions are for lazy evaluation.  They all
2899 # return a CODE ref, which will return the intended value when evaluated.
2900 # Thus, whenever there's mention of a returned value, it's about that
2901 # intended value.
2902
2903 # Helper function to implement conditional inheritance depending on the
2904 # value of $disabled{asm}.  Used in inherit_from values as follows:
2905 #
2906 #      inherit_from => [ "template", asm("asm_tmpl") ]
2907 #
2908 sub asm {
2909     my @x = @_;
2910     sub {
2911         $disabled{asm} ? () : @x;
2912     }
2913 }
2914
2915 # Helper function to implement conditional value variants, with a default
2916 # plus additional values based on the value of $config{build_type}.
2917 # Arguments are given in hash table form:
2918 #
2919 #       picker(default => "Basic string: ",
2920 #              debug   => "debug",
2921 #              release => "release")
2922 #
2923 # When configuring with --debug, the resulting string will be
2924 # "Basic string: debug", and when not, it will be "Basic string: release"
2925 #
2926 # This can be used to create variants of sets of flags according to the
2927 # build type:
2928 #
2929 #       cflags => picker(default => "-Wall",
2930 #                        debug   => "-g -O0",
2931 #                        release => "-O3")
2932 #
2933 sub picker {
2934     my %opts = @_;
2935     return sub { add($opts{default} || (),
2936                      $opts{$config{build_type}} || ())->(); }
2937 }
2938
2939 # Helper function to combine several values of different types into one.
2940 # This is useful if you want to combine a string with the result of a
2941 # lazy function, such as:
2942 #
2943 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2944 #
2945 sub combine {
2946     my @stuff = @_;
2947     return sub { add(@stuff)->(); }
2948 }
2949
2950 # Helper function to implement conditional values depending on the value
2951 # of $disabled{threads}.  Can be used as follows:
2952 #
2953 #       cflags => combine("-Wall", threads("-pthread"))
2954 #
2955 sub threads {
2956     my @flags = @_;
2957     return sub { add($disabled{threads} ? () : @flags)->(); }
2958 }
2959
2960 sub shared {
2961     my @flags = @_;
2962     return sub { add($disabled{shared} ? () : @flags)->(); }
2963 }
2964
2965 our $add_called = 0;
2966 # Helper function to implement adding values to already existing configuration
2967 # values.  It handles elements that are ARRAYs, CODEs and scalars
2968 sub _add {
2969     my $separator = shift;
2970
2971     # If there's any ARRAY in the collection of values OR the separator
2972     # is undef, we will return an ARRAY of combined values, otherwise a
2973     # string of joined values with $separator as the separator.
2974     my $found_array = !defined($separator);
2975
2976     my @values =
2977         map {
2978             my $res = $_;
2979             while (ref($res) eq "CODE") {
2980                 $res = $res->();
2981             }
2982             if (defined($res)) {
2983                 if (ref($res) eq "ARRAY") {
2984                     $found_array = 1;
2985                     @$res;
2986                 } else {
2987                     $res;
2988                 }
2989             } else {
2990                 ();
2991             }
2992     } (@_);
2993
2994     $add_called = 1;
2995
2996     if ($found_array) {
2997         [ @values ];
2998     } else {
2999         join($separator, grep { defined($_) && $_ ne "" } @values);
3000     }
3001 }
3002 sub add_before {
3003     my $separator = " ";
3004     if (ref($_[$#_]) eq "HASH") {
3005         my $opts = pop;
3006         $separator = $opts->{separator};
3007     }
3008     my @x = @_;
3009     sub { _add($separator, @x, @_) };
3010 }
3011 sub add {
3012     my $separator = " ";
3013     if (ref($_[$#_]) eq "HASH") {
3014         my $opts = pop;
3015         $separator = $opts->{separator};
3016     }
3017     my @x = @_;
3018     sub { _add($separator, @_, @x) };
3019 }
3020
3021 sub read_eval_file {
3022     my $fname = shift;
3023     my $content;
3024     my @result;
3025
3026     open F, "< $fname" or die "Can't open '$fname': $!\n";
3027     {
3028         undef local $/;
3029         $content = <F>;
3030     }
3031     close F;
3032     {
3033         local $@;
3034
3035         @result = ( eval $content );
3036         warn $@ if $@;
3037     }
3038     return wantarray ? @result : $result[0];
3039 }
3040
3041 # configuration reader, evaluates the input file as a perl script and expects
3042 # it to fill %targets with target configurations.  Those are then added to
3043 # %table.
3044 sub read_config {
3045     my $fname = shift;
3046     my %targets;
3047
3048     {
3049         # Protect certain tables from tampering
3050         local %table = ();
3051
3052         %targets = read_eval_file($fname);
3053     }
3054     my %preexisting = ();
3055     foreach (sort keys %targets) {
3056         $preexisting{$_} = 1 if $table{$_};
3057     }
3058     die <<"EOF",
3059 The following config targets from $fname
3060 shadow pre-existing config targets with the same name:
3061 EOF
3062         map { "  $_\n" } sort keys %preexisting
3063         if %preexisting;
3064
3065
3066     # For each target, check that it's configured with a hash table.
3067     foreach (keys %targets) {
3068         if (ref($targets{$_}) ne "HASH") {
3069             if (ref($targets{$_}) eq "") {
3070                 warn "Deprecated target configuration for $_, ignoring...\n";
3071             } else {
3072                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3073             }
3074             delete $targets{$_};
3075         } else {
3076             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3077         }
3078     }
3079
3080     %table = (%table, %targets);
3081
3082 }
3083
3084 # configuration resolver.  Will only resolve all the lazy evaluation
3085 # codeblocks for the chosen target and all those it inherits from,
3086 # recursively
3087 sub resolve_config {
3088     my $target = shift;
3089     my @breadcrumbs = @_;
3090
3091 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3092
3093     if (grep { $_ eq $target } @breadcrumbs) {
3094         die "inherit_from loop!  target backtrace:\n  "
3095             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3096     }
3097
3098     if (!defined($table{$target})) {
3099         warn "Warning! target $target doesn't exist!\n";
3100         return ();
3101     }
3102     # Recurse through all inheritances.  They will be resolved on the
3103     # fly, so when this operation is done, they will all just be a
3104     # bunch of attributes with string values.
3105     # What we get here, though, are keys with references to lists of
3106     # the combined values of them all.  We will deal with lists after
3107     # this stage is done.
3108     my %combined_inheritance = ();
3109     if ($table{$target}->{inherit_from}) {
3110         my @inherit_from =
3111             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3112         foreach (@inherit_from) {
3113             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3114
3115             # 'template' is a marker that's considered private to
3116             # the config that had it.
3117             delete $inherited_config{template};
3118
3119             foreach (keys %inherited_config) {
3120                 if (!$combined_inheritance{$_}) {
3121                     $combined_inheritance{$_} = [];
3122                 }
3123                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3124             }
3125         }
3126     }
3127
3128     # We won't need inherit_from in this target any more, since we've
3129     # resolved all the inheritances that lead to this
3130     delete $table{$target}->{inherit_from};
3131
3132     # Now is the time to deal with those lists.  Here's the place to
3133     # decide what shall be done with those lists, all based on the
3134     # values of the target we're currently dealing with.
3135     # - If a value is a coderef, it will be executed with the list of
3136     #   inherited values as arguments.
3137     # - If the corresponding key doesn't have a value at all or is the
3138     #   empty string, the inherited value list will be run through the
3139     #   default combiner (below), and the result becomes this target's
3140     #   value.
3141     # - Otherwise, this target's value is assumed to be a string that
3142     #   will simply override the inherited list of values.
3143     my $default_combiner = add();
3144
3145     my %all_keys =
3146         map { $_ => 1 } (keys %combined_inheritance,
3147                          keys %{$table{$target}});
3148
3149     sub process_values {
3150         my $object    = shift;
3151         my $inherited = shift;  # Always a [ list ]
3152         my $target    = shift;
3153         my $entry     = shift;
3154
3155         $add_called = 0;
3156
3157         while(ref($object) eq "CODE") {
3158             $object = $object->(@$inherited);
3159         }
3160         if (!defined($object)) {
3161             return ();
3162         }
3163         elsif (ref($object) eq "ARRAY") {
3164             local $add_called;  # To make sure recursive calls don't affect it
3165             return [ map { process_values($_, $inherited, $target, $entry) }
3166                      @$object ];
3167         } elsif (ref($object) eq "") {
3168             return $object;
3169         } else {
3170             die "cannot handle reference type ",ref($object)
3171                 ," found in target ",$target," -> ",$entry,"\n";
3172         }
3173     }
3174
3175     foreach (sort keys %all_keys) {
3176         my $previous = $combined_inheritance{$_};
3177
3178         # Current target doesn't have a value for the current key?
3179         # Assign it the default combiner, the rest of this loop body
3180         # will handle it just like any other coderef.
3181         if (!exists $table{$target}->{$_}) {
3182             $table{$target}->{$_} = $default_combiner;
3183         }
3184
3185         $table{$target}->{$_} = process_values($table{$target}->{$_},
3186                                                $combined_inheritance{$_},
3187                                                $target, $_);
3188         unless(defined($table{$target}->{$_})) {
3189             delete $table{$target}->{$_};
3190         }
3191 #        if ($extra_checks &&
3192 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3193 #            warn "$_ got replaced in $target\n";
3194 #        }
3195     }
3196
3197     # Finally done, return the result.
3198     return %{$table{$target}};
3199 }
3200
3201 sub usage
3202         {
3203         print STDERR $usage;
3204         print STDERR "\npick os/compiler from:\n";
3205         my $j=0;
3206         my $i;
3207         my $k=0;
3208         foreach $i (sort keys %table)
3209                 {
3210                 next if $table{$i}->{template};
3211                 next if $i =~ /^debug/;
3212                 $k += length($i) + 1;
3213                 if ($k > 78)
3214                         {
3215                         print STDERR "\n";
3216                         $k=length($i);
3217                         }
3218                 print STDERR $i . " ";
3219                 }
3220         foreach $i (sort keys %table)
3221                 {
3222                 next if $table{$i}->{template};
3223                 next if $i !~ /^debug/;
3224                 $k += length($i) + 1;
3225                 if ($k > 78)
3226                         {
3227                         print STDERR "\n";
3228                         $k=length($i);
3229                         }
3230                 print STDERR $i . " ";
3231                 }
3232         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3233         exit(1);
3234         }
3235
3236 sub run_dofile
3237 {
3238     my $out = shift;
3239     my @templates = @_;
3240
3241     unlink $out || warn "Can't remove $out, $!"
3242         if -f $out;
3243     foreach (@templates) {
3244         die "Can't open $_, $!" unless -f $_;
3245     }
3246     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3247     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3248     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3249     system($cmd);
3250     exit 1 if $? != 0;
3251     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3252 }
3253
3254 sub compiler_predefined {
3255     state %predefined;
3256     my $cc = shift;
3257
3258     return () if $^O eq 'VMS';
3259
3260     die 'compiler_predefined called without a compiler command'
3261         unless $cc;
3262
3263     if (! $predefined{$cc}) {
3264
3265         $predefined{$cc} = {};
3266
3267         # collect compiler pre-defines from gcc or gcc-alike...
3268         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3269         while (my $l = <PIPE>) {
3270             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3271             $predefined{$cc}->{$1} = $2 // '';
3272         }
3273         close(PIPE);
3274     }
3275
3276     return %{$predefined{$cc}};
3277 }
3278
3279 sub which
3280 {
3281     my ($name)=@_;
3282
3283     if (eval { require IPC::Cmd; 1; }) {
3284         IPC::Cmd->import();
3285         return scalar IPC::Cmd::can_run($name);
3286     } else {
3287         # if there is $directories component in splitpath,
3288         # then it's not something to test with $PATH...
3289         return $name if (File::Spec->splitpath($name))[1];
3290
3291         foreach (File::Spec->path()) {
3292             my $fullpath = catfile($_, "$name$target{exe_extension}");
3293             if (-f $fullpath and -x $fullpath) {
3294                 return $fullpath;
3295             }
3296         }
3297     }
3298 }
3299
3300 sub env
3301 {
3302     my $name = shift;
3303     my %opts = @_;
3304
3305     unless ($opts{cacheonly}) {
3306         # Note that if $ENV{$name} doesn't exist or is undefined,
3307         # $config{perlenv}->{$name} will be created with the value
3308         # undef.  This is intentional.
3309
3310         $config{perlenv}->{$name} = $ENV{$name}
3311             if ! exists $config{perlenv}->{$name};
3312     }
3313     return $config{perlenv}->{$name};
3314 }
3315
3316 # Configuration printer ##############################################
3317
3318 sub print_table_entry
3319 {
3320     local $now_printing = shift;
3321     my %target = resolve_config($now_printing);
3322     my $type = shift;
3323
3324     # Don't print the templates
3325     return if $target{template};
3326
3327     my @sequence = (
3328         "sys_id",
3329         "cpp",
3330         "cppflags",
3331         "defines",
3332         "includes",
3333         "cc",
3334         "cflags",
3335         "unistd",
3336         "ld",
3337         "lflags",
3338         "loutflag",
3339         "ex_libs",
3340         "bn_ops",
3341         "padlock_asm_src",
3342         "poly1035_asm_src",
3343         "thread_scheme",
3344         "perlasm_scheme",
3345         "dso_scheme",
3346         "shared_target",
3347         "shared_cflag",
3348         "shared_defines",
3349         "shared_ldflag",
3350         "shared_rcflag",
3351         "shared_extension",
3352         "dso_extension",
3353         "obj_extension",
3354         "exe_extension",
3355         "ranlib",
3356         "ar",
3357         "arflags",
3358         "aroutflag",
3359         "rc",
3360         "rcflags",
3361         "rcoutflag",
3362         "mt",
3363         "mtflags",
3364         "mtinflag",
3365         "mtoutflag",
3366         "multilib",
3367         "build_scheme",
3368         );
3369
3370     if ($type eq "TABLE") {
3371         print "\n";
3372         print "*** $now_printing\n";
3373         foreach (@sequence) {
3374             if (ref($target{$_}) eq "ARRAY") {
3375                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3376             } else {
3377                 printf "\$%-12s = %s\n", $_, $target{$_};
3378             }
3379         }
3380     } elsif ($type eq "HASH") {
3381         my $largest =
3382             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3383         print "    '$now_printing' => {\n";
3384         foreach (@sequence) {
3385             if ($target{$_}) {
3386                 if (ref($target{$_}) eq "ARRAY") {
3387                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3388                 } else {
3389                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3390                 }
3391             }
3392         }
3393         print "    },\n";
3394     }
3395 }
3396
3397 # Utility routines ###################################################
3398
3399 # On VMS, if the given file is a logical name, File::Spec::Functions
3400 # will consider it an absolute path.  There are cases when we want a
3401 # purely syntactic check without checking the environment.
3402 sub isabsolute {
3403     my $file = shift;
3404
3405     # On non-platforms, we just use file_name_is_absolute().
3406     return file_name_is_absolute($file) unless $^O eq "VMS";
3407
3408     # If the file spec includes a device or a directory spec,
3409     # file_name_is_absolute() is perfectly safe.
3410     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3411
3412     # Here, we know the given file spec isn't absolute
3413     return 0;
3414 }
3415
3416 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3417 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3418 # realpath() requires that at least all path components except the last is an
3419 # existing directory.  On VMS, the last component of the directory spec must
3420 # exist.
3421 sub absolutedir {
3422     my $dir = shift;
3423
3424     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3425     # will return the volume name for the device, no matter what.  Also,
3426     # it will return an incorrect directory spec if the argument is a
3427     # directory that doesn't exist.
3428     if ($^O eq "VMS") {
3429         return rel2abs($dir);
3430     }
3431
3432     # We use realpath() on Unix, since no other will properly clean out
3433     # a directory spec.
3434     use Cwd qw/realpath/;
3435
3436     return realpath($dir);
3437 }
3438
3439 sub quotify {
3440     my %processors = (
3441         perl    => sub { my $x = shift;
3442                          $x =~ s/([\\\$\@"])/\\$1/g;
3443                          return '"'.$x.'"'; },
3444         maybeshell => sub { my $x = shift;
3445                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3446                             if ($x ne $y || $x =~ m|\s|) {
3447                                 return '"'.$y.'"';
3448                             } else {
3449                                 return $x;
3450                             }
3451                         },
3452         );
3453     my $for = shift;
3454     my $processor =
3455         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3456
3457     return map { $processor->($_); } @_;
3458 }
3459
3460 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3461 # $filename is a file name to read from
3462 # $line_concat_cond_re is a regexp detecting a line continuation ending
3463 # $line_concat is a CODEref that takes care of concatenating two lines
3464 sub collect_from_file {
3465     my $filename = shift;
3466     my $line_concat_cond_re = shift;
3467     my $line_concat = shift;
3468
3469     open my $fh, $filename || die "unable to read $filename: $!\n";
3470     return sub {
3471         my $saved_line = "";
3472         $_ = "";
3473         while (<$fh>) {
3474             s|\R$||;
3475             if (defined $line_concat) {
3476                 $_ = $line_concat->($saved_line, $_);
3477                 $saved_line = "";
3478             }
3479             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3480                 $saved_line = $_;
3481                 next;
3482             }
3483             return $_;
3484         }
3485         die "$filename ending with continuation line\n" if $_;
3486         close $fh;
3487         return undef;
3488     }
3489 }
3490
3491 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3492 # $array is an ARRAYref of lines
3493 # $line_concat_cond_re is a regexp detecting a line continuation ending
3494 # $line_concat is a CODEref that takes care of concatenating two lines
3495 sub collect_from_array {
3496     my $array = shift;
3497     my $line_concat_cond_re = shift;
3498     my $line_concat = shift;
3499     my @array = (@$array);
3500
3501     return sub {
3502         my $saved_line = "";
3503         $_ = "";
3504         while (defined($_ = shift @array)) {
3505             s|\R$||;
3506             if (defined $line_concat) {
3507                 $_ = $line_concat->($saved_line, $_);
3508                 $saved_line = "";
3509             }
3510             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3511                 $saved_line = $_;
3512                 next;
3513             }
3514             return $_;
3515         }
3516         die "input text ending with continuation line\n" if $_;
3517         return undef;
3518     }
3519 }
3520
3521 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3522 # $lineiterator is a CODEref that delivers one line at a time.
3523 # All following arguments are regex/CODEref pairs, where the regexp detects a
3524 # line and the CODEref does something with the result of the regexp.
3525 sub collect_information {
3526     my $lineiterator = shift;
3527     my %collectors = @_;
3528
3529     while(defined($_ = $lineiterator->())) {
3530         s|\R$||;
3531         my $found = 0;
3532         if ($collectors{"BEFORE"}) {
3533             $collectors{"BEFORE"}->($_);
3534         }
3535         foreach my $re (keys %collectors) {
3536             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3537                 $collectors{$re}->($lineiterator);
3538                 $found = 1;
3539             };
3540         }
3541         if ($collectors{"OTHERWISE"}) {
3542             $collectors{"OTHERWISE"}->($lineiterator, $_)
3543                 unless $found || !defined $collectors{"OTHERWISE"};
3544         }
3545         if ($collectors{"AFTER"}) {
3546             $collectors{"AFTER"}->($_);
3547         }
3548     }
3549 }
3550
3551 # tokenize($line)
3552 # tokenize($line,$separator)
3553 # $line is a line of text to split up into tokens
3554 # $separator [optional] is a regular expression that separates the tokens,
3555 # the default being spaces.  Do not use quotes of any kind as separators,
3556 # that will give undefined results.
3557 # Returns a list of tokens.
3558 #
3559 # Tokens are divided by separator (spaces by default).  If the tokens include
3560 # the separators, they have to be quoted with single or double quotes.
3561 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3562 # with backslash.
3563 # Basically, the same quoting rules apply for " and ' as in any