Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407 }
1408
1409 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1410 my %predefined_CXX = $config{CXX}
1411     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1412     : ();
1413
1414 # Check for makedepend capabilities.
1415 if (!$disabled{makedepend}) {
1416     if ($config{target} =~ /^(VC|vms)-/) {
1417         # For VC- and vms- targets, there's nothing more to do here.  The
1418         # functionality is hard coded in the corresponding build files for
1419         # cl (Windows) and CC/DECC (VMS).
1420     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1421              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1422         # We know that GNU C version 3 and up as well as all clang
1423         # versions support dependency generation, but Xcode did not
1424         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1425         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1426     } else {
1427         # In all other cases, we look for 'makedepend', and disable the
1428         # capability if not found.
1429         $config{makedepprog} = which('makedepend');
1430         disable('unavailable', 'makedepend') unless $config{makedepprog};
1431     }
1432 }
1433
1434 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1435     # probe for -Wa,--noexecstack option...
1436     if ($predefined_C{__clang__}) {
1437         # clang has builtin assembler, which doesn't recognize --help,
1438         # but it apparently recognizes the option in question on all
1439         # supported platforms even when it's meaningless. In other words
1440         # probe would fail, but probed option always accepted...
1441         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1442     } else {
1443         my $cc = $config{CROSS_COMPILE}.$config{CC};
1444         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1445         while(<PIPE>) {
1446             if (m/--noexecstack/) {
1447                 push @{$config{cflags}}, "-Wa,--noexecstack";
1448                 last;
1449             }
1450         }
1451         close(PIPE);
1452         unlink("null.$$.o");
1453     }
1454 }
1455
1456 # Deal with bn_ops ###################################################
1457
1458 $config{bn_ll}                  =0;
1459 $config{export_var_as_fn}       =0;
1460 my $def_int="unsigned int";
1461 $config{rc4_int}                =$def_int;
1462 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1463
1464 my $count = 0;
1465 foreach (sort split(/\s+/,$target{bn_ops})) {
1466     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1467     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1468     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1469     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1470     ($config{b64l},$config{b64},$config{b32})
1471         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1472     ($config{b64l},$config{b64},$config{b32})
1473         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1474     ($config{b64l},$config{b64},$config{b32})
1475         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1476 }
1477 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1478     if $count > 1;
1479
1480
1481 # Hack cflags for better warnings (dev option) #######################
1482
1483 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1484 # a string and works as well on command lines.
1485 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1486                         @{$config{cflags}} ];
1487 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1488                           @{$config{cxxflags}} ] if $config{CXX};
1489
1490 $config{openssl_api_defines} = [
1491     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1492 ];
1493
1494 my @strict_warnings_collection=();
1495 if ($strict_warnings)
1496         {
1497         my $wopt;
1498         my $gccver = $predefined_C{__GNUC__} // -1;
1499
1500         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1501             unless $gccver >= 4;
1502         push @strict_warnings_collection, @gcc_devteam_warn;
1503         push @strict_warnings_collection, @clang_devteam_warn
1504             if (defined($predefined_C{__clang__}));
1505         }
1506
1507 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1508     disable('static', 'pic', 'threads');
1509 }
1510
1511 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1512                               ? @strict_warnings_collection
1513                               : ( $_ ) }
1514                     @{$config{CFLAGS}} ];
1515
1516 unless ($disabled{"crypto-mdebug-backtrace"})
1517         {
1518         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1519                 {
1520                 push @{$config{cflags}}, $wopt
1521                         unless grep { $_ eq $wopt } @{$config{cflags}};
1522                 }
1523         if ($target =~ /^BSD-/)
1524                 {
1525                 push @{$config{ex_libs}}, "-lexecinfo";
1526                 }
1527         }
1528
1529 unless ($disabled{afalgeng}) {
1530     $config{afalgeng}="";
1531     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1532         my $minver = 4*10000 + 1*100 + 0;
1533         if ($config{CROSS_COMPILE} eq "") {
1534             my $verstr = `uname -r`;
1535             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1536             ($mi2) = $mi2 =~ /(\d+)/;
1537             my $ver = $ma*10000 + $mi1*100 + $mi2;
1538             if ($ver < $minver) {
1539                 disable('too-old-kernel', 'afalgeng');
1540             } else {
1541                 push @{$config{engdirs}}, "afalg";
1542             }
1543         } else {
1544             disable('cross-compiling', 'afalgeng');
1545         }
1546     } else {
1547         disable('not-linux', 'afalgeng');
1548     }
1549 }
1550
1551 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1552
1553 unless ($disabled{ktls}) {
1554     $config{ktls}="";
1555     if ($target =~ m/^linux/) {
1556         my $usr = "/usr/$config{cross_compile_prefix}";
1557         chop($usr);
1558         if ($config{cross_compile_prefix} eq "") {
1559             $usr = "/usr";
1560         }
1561         my $minver = (4 << 16) + (13 << 8) + 0;
1562         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1563
1564         if ($verstr[2] < $minver) {
1565             disable('too-old-kernel', 'ktls');
1566         }
1567     } else {
1568         disable('not-linux', 'ktls');
1569     }
1570 }
1571
1572 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1573
1574 # Get the extra flags used when building shared libraries and modules.  We
1575 # do this late because some of them depend on %disabled.
1576
1577 # Make the flags to build DSOs the same as for shared libraries unless they
1578 # are already defined
1579 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1580 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1581 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1582 {
1583     my $shared_info_pl =
1584         catfile(dirname($0), "Configurations", "shared-info.pl");
1585     my %shared_info = read_eval_file($shared_info_pl);
1586     push @{$target{_conf_fname_int}}, $shared_info_pl;
1587     my $si = $target{shared_target};
1588     while (ref $si ne "HASH") {
1589         last if ! defined $si;
1590         if (ref $si eq "CODE") {
1591             $si = $si->();
1592         } else {
1593             $si = $shared_info{$si};
1594         }
1595     }
1596
1597     # Some of the 'shared_target' values don't have any entries in
1598     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1599     # template knows how to handle this.  That is currently the case for
1600     # Windows and VMS.
1601     if (defined $si) {
1602         # Just as above, copy certain shared_* attributes to the corresponding
1603         # module_ attribute unless the latter is already defined
1604         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1605         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1606         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1607         foreach (sort keys %$si) {
1608             $target{$_} = defined $target{$_}
1609                 ? add($si->{$_})->($target{$_})
1610                 : $si->{$_};
1611         }
1612     }
1613 }
1614
1615 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1616
1617 # If we use the unified build, collect information from build.info files
1618 my %unified_info = ();
1619
1620 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1621 if ($builder eq "unified") {
1622     use with_fallback qw(Text::Template);
1623
1624     sub cleandir {
1625         my $base = shift;
1626         my $dir = shift;
1627         my $relativeto = shift || ".";
1628
1629         $dir = catdir($base,$dir) unless isabsolute($dir);
1630
1631         # Make sure the directories we're building in exists
1632         mkpath($dir);
1633
1634         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1635         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1636         return $res;
1637     }
1638
1639     sub cleanfile {
1640         my $base = shift;
1641         my $file = shift;
1642         my $relativeto = shift || ".";
1643
1644         $file = catfile($base,$file) unless isabsolute($file);
1645
1646         my $d = dirname($file);
1647         my $f = basename($file);
1648
1649         # Make sure the directories we're building in exists
1650         mkpath($d);
1651
1652         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1653         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1654         return $res;
1655     }
1656
1657     # Store the name of the template file we will build the build file from
1658     # in %config.  This may be useful for the build file itself.
1659     my @build_file_template_names =
1660         ( $builder_platform."-".$target{build_file}.".tmpl",
1661           $target{build_file}.".tmpl" );
1662     my @build_file_templates = ();
1663
1664     # First, look in the user provided directory, if given
1665     if (defined env($local_config_envname)) {
1666         @build_file_templates =
1667             map {
1668                 if ($^O eq 'VMS') {
1669                     # VMS environment variables are logical names,
1670                     # which can be used as is
1671                     $local_config_envname . ':' . $_;
1672                 } else {
1673                     catfile(env($local_config_envname), $_);
1674                 }
1675             }
1676             @build_file_template_names;
1677     }
1678     # Then, look in our standard directory
1679     push @build_file_templates,
1680         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1681           @build_file_template_names );
1682
1683     my $build_file_template;
1684     for $_ (@build_file_templates) {
1685         $build_file_template = $_;
1686         last if -f $build_file_template;
1687
1688         $build_file_template = undef;
1689     }
1690     if (!defined $build_file_template) {
1691         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1692     }
1693     $config{build_file_templates}
1694       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1695                     $blddir),
1696           $build_file_template,
1697           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1698                     $blddir) ];
1699
1700     my @build_dirs = ( [ ] );   # current directory
1701
1702     $config{build_infos} = [ ];
1703
1704     my %ordinals = ();
1705     while (@build_dirs) {
1706         my @curd = @{shift @build_dirs};
1707         my $sourced = catdir($srcdir, @curd);
1708         my $buildd = catdir($blddir, @curd);
1709
1710         my $unixdir = join('/', @curd);
1711         if (exists $skipdir{$unixdir}) {
1712             my $what = $skipdir{$unixdir};
1713             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1714             next;
1715         }
1716
1717         mkpath($buildd);
1718
1719         my $f = 'build.info';
1720         # The basic things we're trying to build
1721         my @programs = ();
1722         my @libraries = ();
1723         my @modules = ();
1724         my @scripts = ();
1725
1726         my %attributes = ();
1727         my %sources = ();
1728         my %shared_sources = ();
1729         my %includes = ();
1730         my %defines = ();
1731         my %depends = ();
1732         my %generate = ();
1733
1734         # Support for $variablename in build.info files.
1735         # Embedded perl code is the ultimate master, still.  If its output
1736         # contains a dollar sign, it had better be escaped, or it will be
1737         # taken for a variable name prefix.
1738         my %variables = ();
1739         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1740         my $expand_variables = sub {
1741             my $value = '';
1742             my $value_rest = shift;
1743
1744             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1745                 $value .= $`;
1746                 $value .= $variables{$1};
1747                 $value_rest = $';
1748             }
1749             return $value . $value_rest;
1750         };
1751
1752         # We want to detect configdata.pm in the source tree, so we
1753         # don't use it if the build tree is different.
1754         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1755
1756         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1757         my $template =
1758             Text::Template->new(TYPE => 'FILE',
1759                                 SOURCE => catfile($sourced, $f),
1760                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1761         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1762         my @text =
1763             split /^/m,
1764             $template->fill_in(HASH => { config => \%config,
1765                                          target => \%target,
1766                                          disabled => \%disabled,
1767                                          withargs => \%withargs,
1768                                          builddir => abs2rel($buildd, $blddir),
1769                                          sourcedir => abs2rel($sourced, $blddir),
1770                                          buildtop => abs2rel($blddir, $blddir),
1771                                          sourcetop => abs2rel($srcdir, $blddir) },
1772                                DELIMITERS => [ "{-", "-}" ]);
1773
1774         # The top item of this stack has the following values
1775         # -2 positive already run and we found ELSE (following ELSIF should fail)
1776         # -1 positive already run (skip until ENDIF)
1777         # 0 negatives so far (if we're at a condition, check it)
1778         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1779         # 2 positive ELSE (following ELSIF should fail)
1780         my @skip = ();
1781         collect_information(
1782             collect_from_array([ @text ],
1783                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1784                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1785             # Info we're looking for
1786             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1787             => sub {
1788                 if (! @skip || $skip[$#skip] > 0) {
1789                     push @skip, !! $expand_variables->($1);
1790                 } else {
1791                     push @skip, -1;
1792                 }
1793             },
1794             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1795             => sub { die "ELSIF out of scope" if ! @skip;
1796                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1797                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1798                      $skip[$#skip] = !! $expand_variables->($1)
1799                          if $skip[$#skip] == 0; },
1800             qr/^\s*ELSE\s*$/
1801             => sub { die "ELSE out of scope" if ! @skip;
1802                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1803                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1804             qr/^\s*ENDIF\s*$/
1805             => sub { die "ENDIF out of scope" if ! @skip;
1806                      pop @skip; },
1807             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1808             => sub {
1809                 if (!@skip || $skip[$#skip] > 0) {
1810                     my $n = $1;
1811                     my $v = $2;
1812                     $variables{$n} = $expand_variables->($v);
1813                 }
1814             },
1815             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1816             => sub {
1817                 if (!@skip || $skip[$#skip] > 0) {
1818                     foreach (tokenize($expand_variables->($1))) {
1819                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1820                     }
1821                 }
1822             },
1823             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1824             => sub {
1825                 if (!@skip || $skip[$#skip] > 0) {
1826                     my @a = tokenize($1, qr|\s*,\s*|);
1827                     my @p = tokenize($expand_variables->($2));
1828                     push @programs, @p;
1829                     foreach my $a (@a) {
1830                         my $ak = $a;
1831                         my $av = 1;
1832                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1833                             $ak = $1;
1834                             $av = $2;
1835                         }
1836                         foreach my $p (@p) {
1837                             $attributes{$p}->{$ak} = $av;
1838                         }
1839                     }
1840                 }
1841             },
1842             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1843             => sub {
1844                 if (!@skip || $skip[$#skip] > 0) {
1845                     my @a = tokenize($1, qr|\s*,\s*|);
1846                     my @l = tokenize($expand_variables->($2));
1847                     push @libraries, @l;
1848                     foreach my $a (@a) {
1849                         my $ak = $a;
1850                         my $av = 1;
1851                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1852                             $ak = $1;
1853                             $av = $2;
1854                         }
1855                         foreach my $l (@l) {
1856                             $attributes{$l}->{$ak} = $av;
1857                         }
1858                     }
1859                 }
1860             },
1861             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1862             => sub {
1863                 if (!@skip || $skip[$#skip] > 0) {
1864                     my @a = tokenize($1, qr|\s*,\s*|);
1865                     my @m = tokenize($expand_variables->($2));
1866                     push @modules, @m;
1867                     foreach my $a (@a) {
1868                         my $ak = $a;
1869                         my $av = 1;
1870                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1871                             $ak = $1;
1872                             $av = $2;
1873                         }
1874                         foreach my $m (@m) {
1875                             $attributes{$m}->{$ak} = $av;
1876                         }
1877                     }
1878                 }
1879             },
1880             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1881             => sub {
1882                 if (!@skip || $skip[$#skip] > 0) {
1883                     my @a = tokenize($1, qr|\s*,\s*|);
1884                     my @s = tokenize($expand_variables->($2));
1885                     push @scripts, @s;
1886                     foreach my $a (@a) {
1887                         my $ak = $a;
1888                         my $av = 1;
1889                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1890                             $ak = $1;
1891                             $av = $2;
1892                         }
1893                         foreach my $s (@s) {
1894                             $attributes{$s}->{$ak} = $av;
1895                         }
1896                     }
1897                 }
1898             },
1899
1900             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1901             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1902                          if !@skip || $skip[$#skip] > 0 },
1903             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1904             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1905                          if !@skip || $skip[$#skip] > 0 },
1906             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1907             => sub { push @{$shared_sources{$1}},
1908                          tokenize($expand_variables->($2))
1909                          if !@skip || $skip[$#skip] > 0 },
1910             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1911             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1912                          if !@skip || $skip[$#skip] > 0 },
1913             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1914             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1915                          if !@skip || $skip[$#skip] > 0 },
1916             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1917             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1918                          if !@skip || $skip[$#skip] > 0 },
1919             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1920             => sub { push @{$generate{$1}}, $2
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*(?:#.*)?$/ => sub { },
1923             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1924             "BEFORE" => sub {
1925                 if ($buildinfo_debug) {
1926                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1927                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1928                 }
1929             },
1930             "AFTER" => sub {
1931                 if ($buildinfo_debug) {
1932                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1933                 }
1934             },
1935             );
1936         die "runaway IF?" if (@skip);
1937
1938         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1939                 and !$config{dynamic_engines}) {
1940             die <<"EOF"
1941 ENGINES can only be used if configured with 'dynamic-engine'.
1942 This is usually a fault in a build.info file.
1943 EOF
1944         }
1945
1946         foreach (keys %attributes) {
1947             my $dest = $_;
1948             my $ddest = cleanfile($buildd, $_, $blddir);
1949             foreach (keys %{$attributes{$dest} // {}}) {
1950                 $unified_info{attributes}->{$ddest}->{$_} =
1951                     $attributes{$dest}->{$_};
1952             }
1953         }
1954
1955         {
1956             my %infos = ( programs  => [ @programs  ],
1957                           libraries => [ @libraries ],
1958                           modules   => [ @modules   ],
1959                           scripts   => [ @scripts   ] );
1960             foreach my $k (keys %infos) {
1961                 foreach (@{$infos{$k}}) {
1962                     my $item = cleanfile($buildd, $_, $blddir);
1963                     $unified_info{$k}->{$item} = 1;
1964                 }
1965             }
1966         }
1967
1968         # Check that we haven't defined any library as both shared and
1969         # explicitly static.  That is forbidden.
1970         my @doubles = ();
1971         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1972             (my $l = $_) =~ s/\.a$//;
1973             push @doubles, $l if defined $unified_info{libraries}->{$l};
1974         }
1975         die "these libraries are both explicitly static and shared:\n  ",
1976             join(" ", @doubles), "\n"
1977             if @doubles;
1978
1979         foreach (keys %sources) {
1980             my $dest = $_;
1981             my $ddest = cleanfile($buildd, $_, $blddir);
1982             foreach (@{$sources{$dest}}) {
1983                 my $s = cleanfile($sourced, $_, $blddir);
1984
1985                 # If it isn't in the source tree, we assume it's generated
1986                 # in the build tree
1987                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1988                     $s = cleanfile($buildd, $_, $blddir);
1989                 }
1990                 # We recognise C++, C and asm files
1991                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1992                     my $o = $_;
1993                     $o =~ s/\.[csS]$/.o/; # C and assembler
1994                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1995                     $o = cleanfile($buildd, $o, $blddir);
1996                     $unified_info{sources}->{$ddest}->{$o} = -1;
1997                     $unified_info{sources}->{$o}->{$s} = -1;
1998                 } elsif ($s =~ /\.rc$/) {
1999                     # We also recognise resource files
2000                     my $o = $_;
2001                     $o =~ s/\.rc$/.res/; # Resource configuration
2002                     my $o = cleanfile($buildd, $o, $blddir);
2003                     $unified_info{sources}->{$ddest}->{$o} = -1;
2004                     $unified_info{sources}->{$o}->{$s} = -1;
2005                 } else {
2006                     $unified_info{sources}->{$ddest}->{$s} = 1;
2007                 }
2008             }
2009         }
2010
2011         foreach (keys %shared_sources) {
2012             my $dest = $_;
2013             my $ddest = cleanfile($buildd, $_, $blddir);
2014             foreach (@{$shared_sources{$dest}}) {
2015                 my $s = cleanfile($sourced, $_, $blddir);
2016
2017                 # If it isn't in the source tree, we assume it's generated
2018                 # in the build tree
2019                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2020                     $s = cleanfile($buildd, $_, $blddir);
2021                 }
2022
2023                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2024                     # We recognise C++, C and asm files
2025                     my $o = $_;
2026                     $o =~ s/\.[csS]$/.o/; # C and assembler
2027                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2028                     $o = cleanfile($buildd, $o, $blddir);
2029                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2030                     $unified_info{sources}->{$o}->{$s} = -1;
2031                 } elsif ($s =~ /\.rc$/) {
2032                     # We also recognise resource files
2033                     my $o = $_;
2034                     $o =~ s/\.rc$/.res/; # Resource configuration
2035                     my $o = cleanfile($buildd, $o, $blddir);
2036                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2037                     $unified_info{sources}->{$o}->{$s} = -1;
2038                 } elsif ($s =~ /\.ld$/) {
2039                     # We also recognise linker scripts (or corresponding)
2040                     # We know they are generated files
2041                     my $ld = cleanfile($buildd, $_, $blddir);
2042                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2043                 } else {
2044                     die "unrecognised source file type for shared library: $s\n";
2045                 }
2046             }
2047         }
2048
2049         foreach (keys %generate) {
2050             my $dest = $_;
2051             my $ddest = cleanfile($buildd, $_, $blddir);
2052             die "more than one generator for $dest: "
2053                     ,join(" ", @{$generate{$_}}),"\n"
2054                     if scalar @{$generate{$_}} > 1;
2055             my @generator = split /\s+/, $generate{$dest}->[0];
2056             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2057             $unified_info{generate}->{$ddest} = [ @generator ];
2058         }
2059
2060         foreach (keys %depends) {
2061             my $dest = $_;
2062             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2063
2064             # If the destination doesn't exist in source, it can only be
2065             # a generated file in the build tree.
2066             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2067                 $ddest = cleanfile($buildd, $_, $blddir);
2068             }
2069             foreach (@{$depends{$dest}}) {
2070                 my $d = cleanfile($sourced, $_, $blddir);
2071
2072                 # If we know it's generated, or assume it is because we can't
2073                 # find it in the source tree, we set file we depend on to be
2074                 # in the build tree rather than the source tree, and assume
2075                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2076                 # section or in the Makefile template.
2077                 if ($d eq $src_configdata
2078                     || ! -f $d
2079                     || (grep { $d eq $_ }
2080                         map { cleanfile($srcdir, $_, $blddir) }
2081                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2082                     $d = cleanfile($buildd, $_, $blddir);
2083                 }
2084                 # Take note if the file to depend on is being renamed
2085                 # Take extra care with files ending with .a, they should
2086                 # be treated without that extension, and the extension
2087                 # should be added back after treatment.
2088                 $d =~ /(\.a)?$/;
2089                 my $e = $1 // "";
2090                 $d = $`.$e;
2091                 $unified_info{depends}->{$ddest}->{$d} = 1;
2092             }
2093         }
2094
2095         foreach (keys %includes) {
2096             my $dest = $_;
2097             my $ddest = cleanfile($sourced, $_, $blddir);
2098
2099             # If the destination doesn't exist in source, it can only be
2100             # a generated file in the build tree.
2101             if ($ddest eq $src_configdata || ! -f $ddest) {
2102                 $ddest = cleanfile($buildd, $_, $blddir);
2103             }
2104             foreach (@{$includes{$dest}}) {
2105                 my $is = cleandir($sourced, $_, $blddir);
2106                 my $ib = cleandir($buildd, $_, $blddir);
2107                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2108                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2109                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2110                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2111             }
2112         }
2113
2114         foreach (keys %defines) {
2115             my $dest = $_;
2116             my $ddest = cleanfile($sourced, $_, $blddir);
2117
2118             # If the destination doesn't exist in source, it can only be
2119             # a generated file in the build tree.
2120             if (! -f $ddest) {
2121                 $ddest = cleanfile($buildd, $_, $blddir);
2122                 if ($unified_info{rename}->{$ddest}) {
2123                     $ddest = $unified_info{rename}->{$ddest};
2124                 }
2125             }
2126             foreach (@{$defines{$dest}}) {
2127                 m|^([^=]*)(=.*)?$|;
2128                 die "0 length macro name not permitted\n" if $1 eq "";
2129                 die "$1 defined more than once\n"
2130                     if defined $unified_info{defines}->{$ddest}->{$1};
2131                 $unified_info{defines}->{$ddest}->{$1} = $2;
2132             }
2133         }
2134     }
2135
2136     my $ordinals_text = join(', ', sort keys %ordinals);
2137     warn <<"EOF" if $ordinals_text;
2138
2139 WARNING: ORDINALS were specified for $ordinals_text
2140 They are ignored and should be replaced with a combination of GENERATE,
2141 DEPEND and SHARED_SOURCE.
2142 EOF
2143
2144
2145     # Go through the sources of all libraries and check that the same basename
2146     # doesn't appear more than once.  Some static library archivers depend on
2147     # them being unique.
2148     {
2149         my $err = 0;
2150         foreach my $prod (keys %{$unified_info{libraries}}) {
2151             my @prod_sources =
2152                 map { keys %{$unified_info{sources}->{$_}} }
2153                 keys %{$unified_info{sources}->{$prod}};
2154             my %srccnt = ();
2155
2156             # Count how many times a given each source basename
2157             # appears for each product.
2158             foreach my $src (@prod_sources) {
2159                 $srccnt{basename $src}++;
2160             }
2161
2162             foreach my $src (keys %srccnt) {
2163                 if ((my $cnt = $srccnt{$src}) > 1) {
2164                     print STDERR "$src appears $cnt times for the product $prod\n";
2165                     $err++
2166                 }
2167             }
2168         }
2169         die if $err > 0;
2170     }
2171
2172     # Massage the result
2173
2174     # If we depend on a header file or a perl module, add an inclusion of
2175     # its directory to allow smoothe inclusion
2176     foreach my $dest (keys %{$unified_info{depends}}) {
2177         next if $dest eq "";
2178         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2179             next unless $d =~ /\.(h|pm)$/;
2180             my $i = dirname($d);
2181             my $spot =
2182                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2183                 ? 'build' : 'source';
2184             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2185                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2186         }
2187     }
2188
2189     # Go through all intermediary files and change their names to something that
2190     # reflects what they will be built for.  Note that for some source files,
2191     # this leads to duplicate object files because they are used multiple times.
2192     # the goal is to rename all object files according to this scheme:
2193     #    {productname}-{midfix}-{origobjname}.[o|res]
2194     # the {midfix} is a keyword indicating the type of product, which is mostly
2195     # valuable for libraries since they come in two forms.
2196     #
2197     # This also reorganises the {sources} and {shared_sources} so that the
2198     # former only contains ALL object files that are supposed to end up in
2199     # static libraries and programs, while the latter contains ALL object files
2200     # that are supposed to end up in shared libraries and DSOs.
2201     # The main reason for having two different source structures is to allow
2202     # the same name to be used for the static and the shared variants of a
2203     # library.
2204     {
2205         # Take copies so we don't get interference from added stuff
2206         my %unified_copy = ();
2207         foreach (('sources', 'shared_sources')) {
2208             $unified_copy{$_} = { %{$unified_info{$_}} }
2209                 if defined($unified_info{$_});
2210             delete $unified_info{$_};
2211         }
2212         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2213             # $intent serves multi purposes:
2214             # - give a prefix for the new object files names
2215             # - in the case of libraries, rearrange the object files so static
2216             #   libraries use the 'sources' structure exclusively, while shared
2217             #   libraries use the 'shared_sources' structure exclusively.
2218             my $intent = {
2219                 programs  => { bin    => { src => [ 'sources' ],
2220                                            dst => 'sources' } },
2221                 libraries => { lib    => { src => [ 'sources' ],
2222                                            dst => 'sources' },
2223                                shlib  => { prodselect =>
2224                                                sub { grep !/\.a$/, @_ },
2225                                            src => [ 'sources',
2226                                                     'shared_sources' ],
2227                                            dst => 'shared_sources' } },
2228                 modules   => { dso    => { src => [ 'sources' ],
2229                                            dst => 'sources' } },
2230                 scripts   => { script => { src => [ 'sources' ],
2231                                            dst => 'sources' } }
2232                } -> {$prodtype};
2233             foreach my $kind (keys %$intent) {
2234                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2235                              && $disabled{shared});
2236
2237                 my @src = @{$intent->{$kind}->{src}};
2238                 my $dst = $intent->{$kind}->{dst};
2239                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2240                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2241                     # %prod_sources has all applicable objects as keys, and
2242                     # their corresponding sources as values
2243                     my %prod_sources =
2244                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2245                         map { keys %{$unified_copy{$_}->{$prod}} }
2246                         @src;
2247                     foreach (keys %prod_sources) {
2248                         # Only affect object files and resource files,
2249                         # the others simply get a new value
2250                         # (+1 instead of -1)
2251                         if ($_ =~ /\.(o|res)$/) {
2252                             (my $prodname = $prod) =~ s|\.a$||;
2253                             my $newobj =
2254                                 catfile(dirname($_),
2255                                         basename($prodname)
2256                                             . '-' . $kind
2257                                             . '-' . basename($_));
2258                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2259                             foreach my $src (@{$prod_sources{$_}}) {
2260                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2261                             }
2262                             # Adjust dependencies
2263                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2264                                 $unified_info{depends}->{$_}->{$deps} = -1;
2265                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2266                             }
2267                             # Adjust includes
2268                             foreach my $k (('source', 'build')) {
2269                                 next unless
2270                                     defined($unified_info{includes}->{$_}->{$k});
2271                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2272                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2273                             }
2274                         } else {
2275                             $unified_info{$dst}->{$prod}->{$_} = 1;
2276                         }
2277                     }
2278                 }
2279             }
2280         }
2281     }
2282
2283     # At this point, we have a number of sources with the value -1.  They
2284     # aren't part of the local build and are probably meant for a different
2285     # platform, and can therefore be cleaned away.  That happens when making
2286     # %unified_info more efficient below.
2287
2288     ### Make unified_info a bit more efficient
2289     # One level structures
2290     foreach (("programs", "libraries", "modules", "scripts")) {
2291         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2292     }
2293     # Two level structures
2294     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2295         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2296             my @items =
2297                 sort
2298                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2299                 keys %{$unified_info{$l1}->{$l2}};
2300             if (@items) {
2301                 $unified_info{$l1}->{$l2} = [ @items ];
2302             } else {
2303                 delete $unified_info{$l1}->{$l2};
2304             }
2305         }
2306     }
2307     # Defines
2308     foreach my $dest (sort keys %{$unified_info{defines}}) {
2309         $unified_info{defines}->{$dest}
2310             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2311                 sort keys %{$unified_info{defines}->{$dest}} ];
2312     }
2313     # Includes
2314     foreach my $dest (sort keys %{$unified_info{includes}}) {
2315         if (defined($unified_info{includes}->{$dest}->{build})) {
2316             my @source_includes = ();
2317             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2318                 if defined($unified_info{includes}->{$dest}->{source});
2319             $unified_info{includes}->{$dest} =
2320                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2321             foreach my $inc (@source_includes) {
2322                 push @{$unified_info{includes}->{$dest}}, $inc
2323                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2324             }
2325         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2326             $unified_info{includes}->{$dest} =
2327                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2328         } else {
2329             delete $unified_info{includes}->{$dest};
2330         }
2331     }
2332
2333     # For convenience collect information regarding directories where
2334     # files are generated, those generated files and the end product
2335     # they end up in where applicable.  Then, add build rules for those
2336     # directories
2337     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2338                      "dso" => [ @{$unified_info{modules}} ],
2339                      "bin" => [ @{$unified_info{programs}} ],
2340                      "script" => [ @{$unified_info{scripts}} ] );
2341     foreach my $type (keys %loopinfo) {
2342         foreach my $product (@{$loopinfo{$type}}) {
2343             my %dirs = ();
2344             my $pd = dirname($product);
2345
2346             foreach (@{$unified_info{sources}->{$product} // []},
2347                      @{$unified_info{shared_sources}->{$product} // []}) {
2348                 my $d = dirname($_);
2349
2350                 # We don't want to create targets for source directories
2351                 # when building out of source
2352                 next if ($config{sourcedir} ne $config{builddir}
2353                              && $d =~ m|^\Q$config{sourcedir}\E|);
2354                 # We already have a "test" target, and the current directory
2355                 # is just silly to make a target for
2356                 next if $d eq "test" || $d eq ".";
2357
2358                 $dirs{$d} = 1;
2359                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2360                     if $d ne $pd;
2361             }
2362             foreach (keys %dirs) {
2363                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2364                     $product;
2365             }
2366         }
2367     }
2368 }
2369
2370 # For the schemes that need it, we provide the old *_obj configs
2371 # from the *_asm_obj ones
2372 foreach (grep /_(asm|aux)_src$/, keys %target) {
2373     my $src = $_;
2374     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2375     $target{$obj} = $target{$src};
2376     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2377     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2378 }
2379
2380 # Write down our configuration where it fits #########################
2381
2382 print "Creating configdata.pm\n";
2383 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2384 print OUT <<"EOF";
2385 #! $config{HASHBANGPERL}
2386
2387 package configdata;
2388
2389 use strict;
2390 use warnings;
2391
2392 use Exporter;
2393 #use vars qw(\@ISA \@EXPORT);
2394 our \@ISA = qw(Exporter);
2395 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2396
2397 EOF
2398 print OUT "our %config = (\n";
2399 foreach (sort keys %config) {
2400     if (ref($config{$_}) eq "ARRAY") {
2401         print OUT "  ", $_, " => [ ", join(", ",
2402                                            map { quotify("perl", $_) }
2403                                            @{$config{$_}}), " ],\n";
2404     } elsif (ref($config{$_}) eq "HASH") {
2405         print OUT "  ", $_, " => {";
2406         if (scalar keys %{$config{$_}} > 0) {
2407             print OUT "\n";
2408             foreach my $key (sort keys %{$config{$_}}) {
2409                 print OUT "      ",
2410                     join(" => ",
2411                          quotify("perl", $key),
2412                          defined $config{$_}->{$key}
2413                              ? quotify("perl", $config{$_}->{$key})
2414                              : "undef");
2415                 print OUT ",\n";
2416             }
2417             print OUT "  ";
2418         }
2419         print OUT "},\n";
2420     } else {
2421         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2422     }
2423 }
2424 print OUT <<"EOF";
2425 );
2426
2427 EOF
2428 print OUT "our %target = (\n";
2429 foreach (sort keys %target) {
2430     if (ref($target{$_}) eq "ARRAY") {
2431         print OUT "  ", $_, " => [ ", join(", ",
2432                                            map { quotify("perl", $_) }
2433                                            @{$target{$_}}), " ],\n";
2434     } else {
2435         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2436     }
2437 }
2438 print OUT <<"EOF";
2439 );
2440
2441 EOF
2442 print OUT "our \%available_protocols = (\n";
2443 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2444 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2445 print OUT <<"EOF";
2446 );
2447
2448 EOF
2449 print OUT "our \@disablables = (\n";
2450 foreach (@disablables) {
2451     print OUT "  ", quotify("perl", $_), ",\n";
2452 }
2453 print OUT <<"EOF";
2454 );
2455
2456 EOF
2457 print OUT "# The following come from Configure's @disablables_int\n";
2458 print OUT "our \@disablables_int = (\n";
2459 foreach (@disablables_int) {
2460     print OUT "  ", quotify("perl", $_), ",\n";
2461 }
2462 print OUT <<"EOF";
2463 );
2464
2465 EOF
2466 print OUT "our \%disabled = (\n";
2467 foreach (sort keys %disabled) {
2468     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2469 }
2470 print OUT <<"EOF";
2471 );
2472
2473 EOF
2474 print OUT "our %withargs = (\n";
2475 foreach (sort keys %withargs) {
2476     if (ref($withargs{$_}) eq "ARRAY") {
2477         print OUT "  ", $_, " => [ ", join(", ",
2478                                            map { quotify("perl", $_) }
2479                                            @{$withargs{$_}}), " ],\n";
2480     } else {
2481         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2482     }
2483 }
2484 print OUT <<"EOF";
2485 );
2486
2487 EOF
2488 if ($builder eq "unified") {
2489     my $recurse;
2490     $recurse = sub {
2491         my $indent = shift;
2492         foreach (@_) {
2493             if (ref $_ eq "ARRAY") {
2494                 print OUT " "x$indent, "[\n";
2495                 foreach (@$_) {
2496                     $recurse->($indent + 4, $_);
2497                 }
2498                 print OUT " "x$indent, "],\n";
2499             } elsif (ref $_ eq "HASH") {
2500                 my %h = %$_;
2501                 print OUT " "x$indent, "{\n";
2502                 foreach (sort keys %h) {
2503                     if (ref $h{$_} eq "") {
2504                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2505                     } else {
2506                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2507                         $recurse->($indent + 8, $h{$_});
2508                     }
2509                 }
2510                 print OUT " "x$indent, "},\n";
2511             } else {
2512                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2513             }
2514         }
2515     };
2516     print OUT "our %unified_info = (\n";
2517     foreach (sort keys %unified_info) {
2518         if (ref $unified_info{$_} eq "") {
2519             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2520         } else {
2521             print OUT " "x4, quotify("perl", $_), " =>\n";
2522             $recurse->(8, $unified_info{$_});
2523         }
2524     }
2525     print OUT <<"EOF";
2526 );
2527
2528 EOF
2529 }
2530 print OUT
2531     "# The following data is only used when this files is use as a script\n";
2532 print OUT "my \@makevars = (\n";
2533 foreach (sort keys %user) {
2534     print OUT "    '",$_,"',\n";
2535 }
2536 print OUT ");\n";
2537 print OUT "my \%disabled_info = (\n";
2538 foreach my $what (sort keys %disabled_info) {
2539     print OUT "    '$what' => {\n";
2540     foreach my $info (sort keys %{$disabled_info{$what}}) {
2541         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2542             print OUT "        $info => [ ",
2543                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2544                 " ],\n";
2545         } else {
2546             print OUT "        $info => '", $disabled_info{$what}->{$info},
2547                 "',\n";
2548         }
2549     }
2550     print OUT "    },\n";
2551 }
2552 print OUT ");\n";
2553 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2554 print OUT << 'EOF';
2555 # If run directly, we can give some answers, and even reconfigure
2556 unless (caller) {
2557     use Getopt::Long;
2558     use File::Spec::Functions;
2559     use File::Basename;
2560     use Pod::Usage;
2561
2562     my $here = dirname($0);
2563
2564     my $dump = undef;
2565     my $cmdline = undef;
2566     my $options = undef;
2567     my $target = undef;
2568     my $envvars = undef;
2569     my $makevars = undef;
2570     my $buildparams = undef;
2571     my $reconf = undef;
2572     my $verbose = undef;
2573     my $help = undef;
2574     my $man = undef;
2575     GetOptions('dump|d'                 => \$dump,
2576                'command-line|c'         => \$cmdline,
2577                'options|o'              => \$options,
2578                'target|t'               => \$target,
2579                'environment|e'          => \$envvars,
2580                'make-variables|m'       => \$makevars,
2581                'build-parameters|b'     => \$buildparams,
2582                'reconfigure|reconf|r'   => \$reconf,
2583                'verbose|v'              => \$verbose,
2584                'help'                   => \$help,
2585                'man'                    => \$man)
2586         or die "Errors in command line arguments\n";
2587
2588     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2589             || $buildparams || $reconf || $verbose || $help || $man) {
2590         print STDERR <<"_____";
2591 You must give at least one option.
2592 For more information, do '$0 --help'
2593 _____
2594         exit(2);
2595     }
2596
2597     if ($help) {
2598         pod2usage(-exitval => 0,
2599                   -verbose => 1);
2600     }
2601     if ($man) {
2602         pod2usage(-exitval => 0,
2603                   -verbose => 2);
2604     }
2605     if ($dump || $cmdline) {
2606         print "\nCommand line (with current working directory = $here):\n\n";
2607         print '    ',join(' ',
2608                           $config{PERL},
2609                           catfile($config{sourcedir}, 'Configure'),
2610                           @{$config{perlargv}}), "\n";
2611         print "\nPerl information:\n\n";
2612         print '    ',$config{perl_cmd},"\n";
2613         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2614     }
2615     if ($dump || $options) {
2616         my $longest = 0;
2617         my $longest2 = 0;
2618         foreach my $what (@disablables) {
2619             $longest = length($what) if $longest < length($what);
2620             $longest2 = length($disabled{$what})
2621                 if $disabled{$what} && $longest2 < length($disabled{$what});
2622         }
2623         print "\nEnabled features:\n\n";
2624         foreach my $what (@disablables) {
2625             print "    $what\n" unless $disabled{$what};
2626         }
2627         print "\nDisabled features:\n\n";
2628         foreach my $what (@disablables) {
2629             if ($disabled{$what}) {
2630                 print "    $what", ' ' x ($longest - length($what) + 1),
2631                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2632                 print $disabled_info{$what}->{macro}
2633                     if $disabled_info{$what}->{macro};
2634                 print ' (skip ',
2635                     join(', ', @{$disabled_info{$what}->{skipped}}),
2636                     ')'
2637                     if $disabled_info{$what}->{skipped};
2638                 print "\n";
2639             }
2640         }
2641     }
2642     if ($dump || $target) {
2643         print "\nConfig target attributes:\n\n";
2644         foreach (sort keys %target) {
2645             next if $_ =~ m|^_| || $_ eq 'template';
2646             my $quotify = sub {
2647                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2648             };
2649             print '    ', $_, ' => ';
2650             if (ref($target{$_}) eq "ARRAY") {
2651                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2652             } else {
2653                 print $quotify->($target{$_}), ",\n"
2654             }
2655         }
2656     }
2657     if ($dump || $envvars) {
2658         print "\nRecorded environment:\n\n";
2659         foreach (sort keys %{$config{perlenv}}) {
2660             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2661         }
2662     }
2663     if ($dump || $makevars) {
2664         print "\nMakevars:\n\n";
2665         foreach my $var (@makevars) {
2666             my $prefix = '';
2667             $prefix = $config{CROSS_COMPILE}
2668                 if grep { $var eq $_ } @user_crossable;
2669             $prefix //= '';
2670             print '    ',$var,' ' x (16 - length $var),'= ',
2671                 (ref $config{$var} eq 'ARRAY'
2672                  ? join(' ', @{$config{$var}})
2673                  : $prefix.$config{$var}),
2674                 "\n"
2675                 if defined $config{$var};
2676         }
2677
2678         my @buildfile = ($config{builddir}, $config{build_file});
2679         unshift @buildfile, $here
2680             unless file_name_is_absolute($config{builddir});
2681         my $buildfile = canonpath(catdir(@buildfile));
2682         print <<"_____";
2683
2684 NOTE: These variables only represent the configuration view.  The build file
2685 template may have processed these variables further, please have a look at the
2686 build file for more exact data:
2687     $buildfile
2688 _____
2689     }
2690     if ($dump || $buildparams) {
2691         my @buildfile = ($config{builddir}, $config{build_file});
2692         unshift @buildfile, $here
2693             unless file_name_is_absolute($config{builddir});
2694         print "\nbuild file:\n\n";
2695         print "    ", canonpath(catfile(@buildfile)),"\n";
2696
2697         print "\nbuild file templates:\n\n";
2698         foreach (@{$config{build_file_templates}}) {
2699             my @tmpl = ($_);
2700             unshift @tmpl, $here
2701                 unless file_name_is_absolute($config{sourcedir});
2702             print '    ',canonpath(catfile(@tmpl)),"\n";
2703         }
2704     }
2705     if ($reconf) {
2706         if ($verbose) {
2707             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2708             foreach (sort keys %{$config{perlenv}}) {
2709                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2710             }
2711         }
2712
2713         chdir $here;
2714         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2715     }
2716 }
2717
2718 1;
2719
2720 __END__
2721
2722 =head1 NAME
2723
2724 configdata.pm - configuration data for OpenSSL builds
2725
2726 =head1 SYNOPSIS
2727
2728 Interactive:
2729
2730   perl configdata.pm [options]
2731
2732 As data bank module:
2733
2734   use configdata;
2735
2736 =head1 DESCRIPTION
2737
2738 This module can be used in two modes, interactively and as a module containing
2739 all the data recorded by OpenSSL's Configure script.
2740
2741 When used interactively, simply run it as any perl script, with at least one
2742 option, and you will get the information you ask for.  See L</OPTIONS> below.
2743
2744 When loaded as a module, you get a few databanks with useful information to
2745 perform build related tasks.  The databanks are:
2746
2747     %config             Configured things.
2748     %target             The OpenSSL config target with all inheritances
2749                         resolved.
2750     %disabled           The features that are disabled.
2751     @disablables        The list of features that can be disabled.
2752     %withargs           All data given through --with-THING options.
2753     %unified_info       All information that was computed from the build.info
2754                         files.
2755
2756 =head1 OPTIONS
2757
2758 =over 4
2759
2760 =item B<--help>
2761
2762 Print a brief help message and exit.
2763
2764 =item B<--man>
2765
2766 Print the manual page and exit.
2767
2768 =item B<--dump> | B<-d>
2769
2770 Print all relevant configuration data.  This is equivalent to B<--command-line>
2771 B<--options> B<--target> B<--environment> B<--make-variables>
2772 B<--build-parameters>.
2773
2774 =item B<--command-line> | B<-c>
2775
2776 Print the current configuration command line.
2777
2778 =item B<--options> | B<-o>
2779
2780 Print the features, both enabled and disabled, and display defined macro and
2781 skipped directories where applicable.
2782
2783 =item B<--target> | B<-t>
2784
2785 Print the config attributes for this config target.
2786
2787 =item B<--environment> | B<-e>
2788
2789 Print the environment variables and their values at the time of configuration.
2790
2791 =item B<--make-variables> | B<-m>
2792
2793 Print the main make variables generated in the current configuration
2794
2795 =item B<--build-parameters> | B<-b>
2796
2797 Print the build parameters, i.e. build file and build file templates.
2798
2799 =item B<--reconfigure> | B<--reconf> | B<-r>
2800
2801 Redo the configuration.
2802
2803 =item B<--verbose> | B<-v>
2804
2805 Verbose output.
2806
2807 =back
2808
2809 =cut
2810
2811 EOF
2812 close(OUT);
2813 if ($builder_platform eq 'unix') {
2814     my $mode = (0755 & ~umask);
2815     chmod $mode, 'configdata.pm'
2816         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2817 }
2818
2819 my %builders = (
2820     unified => sub {
2821         print 'Creating ',$target{build_file},"\n";
2822         run_dofile(catfile($blddir, $target{build_file}),
2823                    @{$config{build_file_templates}});
2824     },
2825     );
2826
2827 $builders{$builder}->($builder_platform, @builder_opts);
2828
2829 $SIG{__DIE__} = $orig_death_handler;
2830
2831 print <<"EOF" if ($disabled{threads} eq "unavailable");
2832
2833 The library could not be configured for supporting multi-threaded
2834 applications as the compiler options required on this system are not known.
2835 See file INSTALL for details if you need multi-threading.
2836 EOF
2837
2838 print <<"EOF" if ($no_shared_warn);
2839
2840 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2841 platform, so we will pretend you gave the option 'no-pic', which also disables
2842 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2843 or position independent code, please let us know (but please first make sure
2844 you have tried with a current version of OpenSSL).
2845 EOF
2846
2847 print <<"EOF";
2848
2849 **********************************************************************
2850 ***                                                                ***
2851 ***   OpenSSL has been successfully configured                     ***
2852 ***                                                                ***
2853 ***   If you encounter a problem while building, please open an    ***
2854 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2855 ***   and include the output from the following command:           ***
2856 ***                                                                ***
2857 ***       perl configdata.pm --dump                                ***
2858 ***                                                                ***
2859 ***   (If you are new to OpenSSL, you might want to consult the    ***
2860 ***   'Troubleshooting' section in the INSTALL file first)         ***
2861 ***                                                                ***
2862 **********************************************************************
2863 EOF
2864
2865 exit(0);
2866
2867 ######################################################################
2868 #
2869 # Helpers and utility functions
2870 #
2871
2872 # Death handler, to print a helpful message in case of failure #######
2873 #
2874 sub death_handler {
2875     die @_ if $^S;              # To prevent the added message in eval blocks
2876     my $build_file = $target{build_file} // "build file";
2877     my @message = ( <<"_____", @_ );
2878
2879 Failure!  $build_file wasn't produced.
2880 Please read INSTALL and associated NOTES files.  You may also have to look over
2881 your available compiler tool chain or change your configuration.
2882
2883 _____
2884
2885     # Dying is terminal, so it's ok to reset the signal handler here.
2886     $SIG{__DIE__} = $orig_death_handler;
2887     die @message;
2888 }
2889
2890 # Configuration file reading #########################################
2891
2892 # Note: All of the helper functions are for lazy evaluation.  They all
2893 # return a CODE ref, which will return the intended value when evaluated.
2894 # Thus, whenever there's mention of a returned value, it's about that
2895 # intended value.
2896
2897 # Helper function to implement conditional value variants, with a default
2898 # plus additional values based on the value of $config{build_type}.
2899 # Arguments are given in hash table form:
2900 #
2901 #       picker(default => "Basic string: ",
2902 #              debug   => "debug",
2903 #              release => "release")
2904 #
2905 # When configuring with --debug, the resulting string will be
2906 # "Basic string: debug", and when not, it will be "Basic string: release"
2907 #
2908 # This can be used to create variants of sets of flags according to the
2909 # build type:
2910 #
2911 #       cflags => picker(default => "-Wall",
2912 #                        debug   => "-g -O0",
2913 #                        release => "-O3")
2914 #
2915 sub picker {
2916     my %opts = @_;
2917     return sub { add($opts{default} || (),
2918                      $opts{$config{build_type}} || ())->(); }
2919 }
2920
2921 # Helper function to combine several values of different types into one.
2922 # This is useful if you want to combine a string with the result of a
2923 # lazy function, such as:
2924 #
2925 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2926 #
2927 sub combine {
2928     my @stuff = @_;
2929     return sub { add(@stuff)->(); }
2930 }
2931
2932 # Helper function to implement conditional values depending on the value
2933 # of $disabled{threads}.  Can be used as follows:
2934 #
2935 #       cflags => combine("-Wall", threads("-pthread"))
2936 #
2937 sub threads {
2938     my @flags = @_;
2939     return sub { add($disabled{threads} ? () : @flags)->(); }
2940 }
2941
2942 sub shared {
2943     my @flags = @_;
2944     return sub { add($disabled{shared} ? () : @flags)->(); }
2945 }
2946
2947 our $add_called = 0;
2948 # Helper function to implement adding values to already existing configuration
2949 # values.  It handles elements that are ARRAYs, CODEs and scalars
2950 sub _add {
2951     my $separator = shift;
2952
2953     # If there's any ARRAY in the collection of values OR the separator
2954     # is undef, we will return an ARRAY of combined values, otherwise a
2955     # string of joined values with $separator as the separator.
2956     my $found_array = !defined($separator);
2957
2958     my @values =
2959         map {
2960             my $res = $_;
2961             while (ref($res) eq "CODE") {
2962                 $res = $res->();
2963             }
2964             if (defined($res)) {
2965                 if (ref($res) eq "ARRAY") {
2966                     $found_array = 1;
2967                     @$res;
2968                 } else {
2969                     $res;
2970                 }
2971             } else {
2972                 ();
2973             }
2974     } (@_);
2975
2976     $add_called = 1;
2977
2978     if ($found_array) {
2979         [ @values ];
2980     } else {
2981         join($separator, grep { defined($_) && $_ ne "" } @values);
2982     }
2983 }
2984 sub add_before {
2985     my $separator = " ";
2986     if (ref($_[$#_]) eq "HASH") {
2987         my $opts = pop;
2988         $separator = $opts->{separator};
2989     }
2990     my @x = @_;
2991     sub { _add($separator, @x, @_) };
2992 }
2993 sub add {
2994     my $separator = " ";
2995     if (ref($_[$#_]) eq "HASH") {
2996         my $opts = pop;
2997         $separator = $opts->{separator};
2998     }
2999     my @x = @_;
3000     sub { _add($separator, @_, @x) };
3001 }
3002
3003 sub read_eval_file {
3004     my $fname = shift;
3005     my $content;
3006     my @result;
3007
3008     open F, "< $fname" or die "Can't open '$fname': $!\n";
3009     {
3010         undef local $/;
3011         $content = <F>;
3012     }
3013     close F;
3014     {
3015         local $@;
3016
3017         @result = ( eval $content );
3018         warn $@ if $@;
3019     }
3020     return wantarray ? @result : $result[0];
3021 }
3022
3023 # configuration reader, evaluates the input file as a perl script and expects
3024 # it to fill %targets with target configurations.  Those are then added to
3025 # %table.
3026 sub read_config {
3027     my $fname = shift;
3028     my %targets;
3029
3030     {
3031         # Protect certain tables from tampering
3032         local %table = ();
3033
3034         %targets = read_eval_file($fname);
3035     }
3036     my %preexisting = ();
3037     foreach (sort keys %targets) {
3038         $preexisting{$_} = 1 if $table{$_};
3039     }
3040     die <<"EOF",
3041 The following config targets from $fname
3042 shadow pre-existing config targets with the same name:
3043 EOF
3044         map { "  $_\n" } sort keys %preexisting
3045         if %preexisting;
3046
3047
3048     # For each target, check that it's configured with a hash table.
3049     foreach (keys %targets) {
3050         if (ref($targets{$_}) ne "HASH") {
3051             if (ref($targets{$_}) eq "") {
3052                 warn "Deprecated target configuration for $_, ignoring...\n";
3053             } else {
3054                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3055             }
3056             delete $targets{$_};
3057         } else {
3058             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3059         }
3060     }
3061
3062     %table = (%table, %targets);
3063
3064 }
3065
3066 # configuration resolver.  Will only resolve all the lazy evaluation
3067 # codeblocks for the chosen target and all those it inherits from,
3068 # recursively
3069 sub resolve_config {
3070     my $target = shift;
3071     my @breadcrumbs = @_;
3072
3073 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3074
3075     if (grep { $_ eq $target } @breadcrumbs) {
3076         die "inherit_from loop!  target backtrace:\n  "
3077             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3078     }
3079
3080     if (!defined($table{$target})) {
3081         warn "Warning! target $target doesn't exist!\n";
3082         return ();
3083     }
3084     # Recurse through all inheritances.  They will be resolved on the
3085     # fly, so when this operation is done, they will all just be a
3086     # bunch of attributes with string values.
3087     # What we get here, though, are keys with references to lists of
3088     # the combined values of them all.  We will deal with lists after
3089     # this stage is done.
3090     my %combined_inheritance = ();
3091     if ($table{$target}->{inherit_from}) {
3092         my @inherit_from =
3093             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3094         foreach (@inherit_from) {
3095             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3096
3097             # 'template' is a marker that's considered private to
3098             # the config that had it.
3099             delete $inherited_config{template};
3100
3101             foreach (keys %inherited_config) {
3102                 if (!$combined_inheritance{$_}) {
3103                     $combined_inheritance{$_} = [];
3104                 }
3105                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3106             }
3107         }
3108     }
3109
3110     # We won't need inherit_from in this target any more, since we've
3111     # resolved all the inheritances that lead to this
3112     delete $table{$target}->{inherit_from};
3113
3114     # Now is the time to deal with those lists.  Here's the place to
3115     # decide what shall be done with those lists, all based on the
3116     # values of the target we're currently dealing with.
3117     # - If a value is a coderef, it will be executed with the list of
3118     #   inherited values as arguments.
3119     # - If the corresponding key doesn't have a value at all or is the
3120     #   empty string, the inherited value list will be run through the
3121     #   default combiner (below), and the result becomes this target's
3122     #   value.
3123     # - Otherwise, this target's value is assumed to be a string that
3124     #   will simply override the inherited list of values.
3125     my $default_combiner = add();
3126
3127     my %all_keys =
3128         map { $_ => 1 } (keys %combined_inheritance,
3129                          keys %{$table{$target}});
3130
3131     sub process_values {
3132         my $object    = shift;
3133         my $inherited = shift;  # Always a [ list ]
3134         my $target    = shift;
3135         my $entry     = shift;
3136
3137         $add_called = 0;
3138
3139         while(ref($object) eq "CODE") {
3140             $object = $object->(@$inherited);
3141         }
3142         if (!defined($object)) {
3143             return ();
3144         }
3145         elsif (ref($object) eq "ARRAY") {
3146             local $add_called;  # To make sure recursive calls don't affect it
3147             return [ map { process_values($_, $inherited, $target, $entry) }
3148                      @$object ];
3149         } elsif (ref($object) eq "") {
3150             return $object;
3151         } else {
3152             die "cannot handle reference type ",ref($object)
3153                 ," found in target ",$target," -> ",$entry,"\n";
3154         }
3155     }
3156
3157     foreach (sort keys %all_keys) {
3158         my $previous = $combined_inheritance{$_};
3159
3160         # Current target doesn't have a value for the current key?
3161         # Assign it the default combiner, the rest of this loop body
3162         # will handle it just like any other coderef.
3163         if (!exists $table{$target}->{$_}) {
3164             $table{$target}->{$_} = $default_combiner;
3165         }
3166
3167         $table{$target}->{$_} = process_values($table{$target}->{$_},
3168                                                $combined_inheritance{$_},
3169                                                $target, $_);
3170         unless(defined($table{$target}->{$_})) {
3171             delete $table{$target}->{$_};
3172         }
3173 #        if ($extra_checks &&
3174 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3175 #            warn "$_ got replaced in $target\n";
3176 #        }
3177     }
3178
3179     # Finally done, return the result.
3180     return %{$table{$target}};
3181 }
3182
3183 sub usage
3184         {
3185         print STDERR $usage;
3186         print STDERR "\npick os/compiler from:\n";
3187         my $j=0;
3188         my $i;
3189         my $k=0;
3190         foreach $i (sort keys %table)
3191                 {
3192                 next if $table{$i}->{template};
3193                 next if $i =~ /^debug/;
3194                 $k += length($i) + 1;
3195                 if ($k > 78)
3196                         {
3197                         print STDERR "\n";
3198                         $k=length($i);
3199                         }
3200                 print STDERR $i . " ";
3201                 }
3202         foreach $i (sort keys %table)
3203                 {
3204                 next if $table{$i}->{template};
3205                 next if $i !~ /^debug/;
3206                 $k += length($i) + 1;
3207                 if ($k > 78)
3208                         {
3209                         print STDERR "\n";
3210                         $k=length($i);
3211                         }
3212                 print STDERR $i . " ";
3213                 }
3214         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3215         exit(1);
3216         }
3217
3218 sub run_dofile
3219 {
3220     my $out = shift;
3221     my @templates = @_;
3222
3223     unlink $out || warn "Can't remove $out, $!"
3224         if -f $out;
3225     foreach (@templates) {
3226         die "Can't open $_, $!" unless -f $_;
3227     }
3228     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3229     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3230     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3231     system($cmd);
3232     exit 1 if $? != 0;
3233     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3234 }
3235
3236 sub compiler_predefined {
3237     state %predefined;
3238     my $cc = shift;
3239
3240     return () if $^O eq 'VMS';
3241
3242     die 'compiler_predefined called without a compiler command'
3243         unless $cc;
3244
3245     if (! $predefined{$cc}) {
3246
3247         $predefined{$cc} = {};
3248
3249         # collect compiler pre-defines from gcc or gcc-alike...
3250         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3251         while (my $l = <PIPE>) {
3252             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3253             $predefined{$cc}->{$1} = $2 // '';
3254         }
3255         close(PIPE);
3256     }
3257
3258     return %{$predefined{$cc}};
3259 }
3260
3261 sub which
3262 {
3263     my ($name)=@_;
3264
3265     if (eval { require IPC::Cmd; 1; }) {
3266         IPC::Cmd->import();
3267         return scalar IPC::Cmd::can_run($name);
3268     } else {
3269         # if there is $directories component in splitpath,
3270         # then it's not something to test with $PATH...
3271         return $name if (File::Spec->splitpath($name))[1];
3272
3273         foreach (File::Spec->path()) {
3274             my $fullpath = catfile($_, "$name$target{exe_extension}");
3275             if (-f $fullpath and -x $fullpath) {
3276                 return $fullpath;
3277             }
3278         }
3279     }
3280 }
3281
3282 sub env
3283 {
3284     my $name = shift;
3285     my %opts = @_;
3286
3287     unless ($opts{cacheonly}) {
3288         # Note that if $ENV{$name} doesn't exist or is undefined,
3289         # $config{perlenv}->{$name} will be created with the value
3290         # undef.  This is intentional.
3291
3292         $config{perlenv}->{$name} = $ENV{$name}
3293             if ! exists $config{perlenv}->{$name};
3294     }
3295     return $config{perlenv}->{$name};
3296 }
3297
3298 # Configuration printer ##############################################
3299
3300 sub print_table_entry
3301 {
3302     local $now_printing = shift;
3303     my %target = resolve_config($now_printing);
3304     my $type = shift;
3305
3306     # Don't print the templates
3307     return if $target{template};
3308
3309     my @sequence = (
3310         "sys_id",
3311         "cpp",
3312         "cppflags",
3313         "defines",
3314         "includes",
3315         "cc",
3316         "cflags",
3317         "unistd",
3318         "ld",
3319         "lflags",
3320         "loutflag",
3321         "ex_libs",
3322         "bn_ops",
3323         "poly1035_asm_src",
3324         "thread_scheme",
3325         "perlasm_scheme",
3326         "dso_scheme",
3327         "shared_target",
3328         "shared_cflag",
3329         "shared_defines",
3330         "shared_ldflag",
3331         "shared_rcflag",
3332         "shared_extension",
3333         "dso_extension",
3334         "obj_extension",
3335         "exe_extension",
3336         "ranlib",
3337         "ar",
3338         "arflags",
3339         "aroutflag",
3340         "rc",
3341         "rcflags",
3342         "rcoutflag",
3343         "mt",
3344         "mtflags",
3345         "mtinflag",
3346         "mtoutflag",
3347         "multilib",
3348         "build_scheme",
3349         );
3350
3351     if ($type eq "TABLE") {
3352         print "\n";
3353         print "*** $now_printing\n";
3354         foreach (@sequence) {
3355             if (ref($target{$_}) eq "ARRAY") {
3356                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3357             } else {
3358                 printf "\$%-12s = %s\n", $_, $target{$_};
3359             }
3360         }
3361     } elsif ($type eq "HASH") {
3362         my $largest =
3363             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3364         print "    '$now_printing' => {\n";
3365         foreach (@sequence) {
3366             if ($target{$_}) {
3367                 if (ref($target{$_}) eq "ARRAY") {
3368                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3369                 } else {
3370                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3371                 }
3372             }
3373         }
3374         print "    },\n";
3375     }
3376 }
3377
3378 # Utility routines ###################################################
3379
3380 # On VMS, if the given file is a logical name, File::Spec::Functions
3381 # will consider it an absolute path.  There are cases when we want a
3382 # purely syntactic check without checking the environment.
3383 sub isabsolute {
3384     my $file = shift;
3385
3386     # On non-platforms, we just use file_name_is_absolute().
3387     return file_name_is_absolute($file) unless $^O eq "VMS";
3388
3389     # If the file spec includes a device or a directory spec,
3390     # file_name_is_absolute() is perfectly safe.
3391     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3392
3393     # Here, we know the given file spec isn't absolute
3394     return 0;
3395 }
3396
3397 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3398 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3399 # realpath() requires that at least all path components except the last is an
3400 # existing directory.  On VMS, the last component of the directory spec must
3401 # exist.
3402 sub absolutedir {
3403     my $dir = shift;
3404
3405     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3406     # will return the volume name for the device, no matter what.  Also,
3407     # it will return an incorrect directory spec if the argument is a
3408     # directory that doesn't exist.
3409     if ($^O eq "VMS") {
3410         return rel2abs($dir);
3411     }
3412
3413     # We use realpath() on Unix, since no other will properly clean out
3414     # a directory spec.
3415     use Cwd qw/realpath/;
3416
3417     return realpath($dir);
3418 }
3419
3420 sub quotify {
3421     my %processors = (
3422         perl    => sub { my $x = shift;
3423                          $x =~ s/([\\\$\@"])/\\$1/g;
3424                          return '"'.$x.'"'; },
3425         maybeshell => sub { my $x = shift;
3426                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3427                             if ($x ne $y || $x =~ m|\s|) {
3428                                 return '"'.$y.'"';
3429                             } else {
3430                                 return $x;
3431                             }
3432                         },
3433         );
3434     my $for = shift;
3435     my $processor =
3436         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3437
3438     return map { $processor->($_); } @_;
3439 }
3440
3441 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3442 # $filename is a file name to read from
3443 # $line_concat_cond_re is a regexp detecting a line continuation ending
3444 # $line_concat is a CODEref that takes care of concatenating two lines
3445 sub collect_from_file {
3446     my $filename = shift;
3447     my $line_concat_cond_re = shift;
3448     my $line_concat = shift;
3449
3450     open my $fh, $filename || die "unable to read $filename: $!\n";
3451     return sub {
3452         my $saved_line = "";
3453         $_ = "";
3454         while (<$fh>) {
3455             s|\R$||;
3456             if (defined $line_concat) {
3457                 $_ = $line_concat->($saved_line, $_);
3458                 $saved_line = "";
3459             }
3460             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3461                 $saved_line = $_;
3462                 next;
3463             }
3464             return $_;
3465         }
3466         die "$filename ending with continuation line\n" if $_;
3467         close $fh;
3468         return undef;
3469     }
3470 }
3471
3472 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3473 # $array is an ARRAYref of lines
3474 # $line_concat_cond_re is a regexp detecting a line continuation ending
3475 # $line_concat is a CODEref that takes care of concatenating two lines
3476 sub collect_from_array {
3477     my $array = shift;
3478     my $line_concat_cond_re = shift;
3479     my $line_concat = shift;
3480     my @array = (@$array);
3481
3482     return sub {
3483         my $saved_line = "";
3484         $_ = "";
3485         while (defined($_ = shift @array)) {
3486             s|\R$||;
3487             if (defined $line_concat) {
3488                 $_ = $line_concat->($saved_line, $_);
3489                 $saved_line = "";
3490             }
3491             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3492                 $saved_line = $_;
3493                 next;
3494             }
3495             return $_;
3496         }
3497         die "input text ending with continuation line\n" if $_;
3498         return undef;
3499     }
3500 }
3501
3502 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3503 # $lineiterator is a CODEref that delivers one line at a time.
3504 # All following arguments are regex/CODEref pairs, where the regexp detects a
3505 # line and the CODEref does something with the result of the regexp.
3506 sub collect_information {
3507     my $lineiterator = shift;
3508     my %collectors = @_;
3509
3510     while(defined($_ = $lineiterator->())) {
3511         s|\R$||;
3512         my $found = 0;
3513         if ($collectors{"BEFORE"}) {
3514             $collectors{"BEFORE"}->($_);
3515         }
3516         foreach my $re (keys %collectors) {
3517             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3518                 $collectors{$re}->($lineiterator);
3519                 $found = 1;
3520             };
3521         }
3522         if ($collectors{"OTHERWISE"}) {
3523             $collectors{"OTHERWISE"}->($lineiterator, $_)
3524                 unless $found || !defined $collectors{"OTHERWISE"};
3525         }
3526         if ($collectors{"AFTER"}) {
3527             $collectors{"AFTER"}->($_);
3528         }
3529     }
3530 }
3531
3532 # tokenize($line)
3533 # tokenize($line,$separator)
3534 # $line is a line of text to split up into tokens
3535 # $separator [optional] is a regular expression that separates the tokens,
3536 # the default being spaces.  Do not use quotes of any kind as separators,
3537 # that will give undefined results.
3538 # Returns a list of tokens.
3539 #
3540 # Tokens are divided by separator (spaces by default).  If the tokens include
3541 # the separators, they have to be quoted with single or double quotes.
3542 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3543 # with backslash.
3544 # Basically, the same quoting rules apply for " and ' as in any
3545 # Unix shell.
3546 sub tokenize {
3547     my $line = my $debug_line = shift;
3548     my $separator = shift // qr|\s+|;
3549     my @result = ();
3550
3551     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3552         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3553     }
3554
3555     while ($line =~ s|^${separator}||, $line ne "") {
3556         my $token = "";
3557     again:
3558         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3559         $token .= $1;
3560         $line = $2.$';
3561
3562         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3563             $token .= $1;
3564             $line = $';
3565             goto again;
3566         } elsif ($line =~ m/^'([^']*)'/) {
3567             $token .= $1;
3568             $line = $';
3569             goto again;
3570         }
3571         push @result, $token;
3572     }
3573
3574     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3575         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3576         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3577     }
3578     return @result;
3579 }