Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Collect version numbers
 269 my %version = ();
 270
 271 collect_information(
 272     collect_from_file(catfile($srcdir,'VERSION')),
 273     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 274         sub {
 275             # Only define it if there is a value at all
 276             $version{uc $1} = $2 if $2 ne '';
 277         },
 278     "OTHERWISE" =>
 279         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 280     );
 281
 282 $config{major} = $version{MAJOR} // 'unknown';
 283 $config{minor} = $version{MINOR} // 'unknown';
 284 $config{patch} = $version{PATCH} // 'unknown';
 285 $config{prerelease} =
 286     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 287 $config{build_metadata} =
 288     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 289 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 290 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 291
 292 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 293 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 294
 295 die "erroneous version information in VERSION: ",
 296     "$config{version}, $config{shlib_version}\n"
 297     unless (defined $version{MAJOR}
 298             && defined $version{MINOR}
 299             && defined $version{PATCH}
 300             && defined $version{SHLIB_VERSION});
 301
 302 # Collect target configurations
 303
 304 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 305 foreach (sort glob($pattern)) {
 306     &read_config($_);
 307 }
 308
 309 if (defined env($local_config_envname)) {
 310     if ($^O eq 'VMS') {
 311         # VMS environment variables are logical names,
 312         # which can be used as is
 313         $pattern = $local_config_envname . ':' . '*.conf';
 314     } else {
 315         $pattern = catfile(env($local_config_envname), '*.conf');
 316     }
 317
 318     foreach (sort glob($pattern)) {
 319         &read_config($_);
 320     }
 321 }
 322
 323 # Save away perl command information
 324 $config{perl_cmd} = $^X;
 325 $config{perl_version} = $Config{version};
 326 $config{perl_archname} = $Config{archname};
 327
 328 $config{prefix}="";
 329 $config{openssldir}="";
 330 $config{processor}="";
 331 $config{libdir}="";
 332 my $auto_threads=1;    # enable threads automatically? true by default
 333 my $default_ranlib;
 334
 335 # Known TLS and DTLS protocols
 336 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 337 my @dtls = qw(dtls1 dtls1_2);
 338
 339 # Explicitly known options that are possible to disable.  They can
 340 # be regexps, and will be used like this: /^no-${option}$/
 341 # For developers: keep it sorted alphabetically
 342
 343 my @disablables = (
 344     "afalgeng",
 345     "aria",
 346     "asan",
 347     "asm",
 348     "async",
 349     "autoalginit",
 350     "autoerrinit",
 351     "autoload-config",
 352     "bf",
 353     "blake2",
 354     "buildtest-c++",
 355     "camellia",
 356     "capieng",
 357     "cast",
 358     "chacha",
 359     "cmac",
 360     "cmp",
 361     "cms",
 362     "comp",
 363     "crypto-mdebug",
 364     "ct",
 365     "deprecated",
 366     "des",
 367     "devcryptoeng",
 368     "dgram",
 369     "dh",
 370     "dsa",
 371     "dso",
 372     "dtls",
 373     "dynamic-engine",
 374     "ec",
 375     "ec2m",
 376     "ecdh",
 377     "ecdsa",
 378     "ec_nistp_64_gcc_128",
 379     "egd",
 380     "engine",
 381     "err",
 382     "external-tests",
 383     "filenames",
 384     "fips",
 385     "fuzz-libfuzzer",
 386     "fuzz-afl",
 387     "gost",
 388     "idea",
 389     "ktls",
 390     "legacy",
 391     "makedepend",
 392     "md2",
 393     "md4",
 394     "mdc2",
 395     "module",
 396     "msan",
 397     "multiblock",
 398     "nextprotoneg",
 399     "pinshared",
 400     "ocb",
 401     "ocsp",
 402     "padlockeng",
 403     "pic",
 404     "poly1305",
 405     "posix-io",
 406     "psk",
 407     "rc2",
 408     "rc4",
 409     "rc5",
 410     "rdrand",
 411     "rfc3779",
 412     "rmd160",
 413     "scrypt",
 414     "sctp",
 415     "seed",
 416     "shared",
 417     "siphash",
 418     "siv",
 419     "sm2",
 420     "sm3",
 421     "sm4",
 422     "sock",
 423     "srp",
 424     "srtp",
 425     "sse2",
 426     "ssl",
 427     "ssl-trace",
 428     "static-engine",
 429     "stdio",
 430     "tests",
 431     "threads",
 432     "tls",
 433     "trace",
 434     "ts",
 435     "ubsan",
 436     "ui-console",
 437     "unit-test",
 438     "uplink",
 439     "whirlpool",
 440     "weak-ssl-ciphers",
 441     "zlib",
 442     "zlib-dynamic",
 443     );
 444 foreach my $proto ((@tls, @dtls))
 445         {
 446         push(@disablables, $proto);
 447         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 448         }
 449
 450 # Internal disablables, for aliasing purposes.  They serve no special
 451 # purpose here, but allow scripts to get to know them through configdata.pm,
 452 # where these are merged with @disablables.
 453 # The actual aliasing mechanism is done via %disable_cascades
 454 my @disablables_int = qw(
 455     crmf
 456     );
 457
 458 my %deprecated_disablables = (
 459     "ssl2" => undef,
 460     "buf-freelists" => undef,
 461     "crypto-mdebug-backtrace" => undef,
 462     "hw" => "hw",               # causes cascade, but no macro
 463     "hw-padlock" => "padlockeng",
 464     "ripemd" => "rmd160",
 465     "ui" => "ui-console",
 466     "heartbeats" => undef,
 467     );
 468
 469 # All of the following are disabled by default:
 470
 471 our %disabled = ( # "what"         => "comment"
 472                   "asan"                => "default",
 473                   "buildtest-c++"       => "default",
 474                   "crypto-mdebug"       => "default",
 475                   "crypto-mdebug-backtrace" => "default",
 476                   "devcryptoeng"        => "default",
 477                   "ec_nistp_64_gcc_128" => "default",
 478                   "egd"                 => "default",
 479                   "external-tests"      => "default",
 480                   "fuzz-libfuzzer"      => "default",
 481                   "fuzz-afl"            => "default",
 482                   "md2"                 => "default",
 483                   "msan"                => "default",
 484                   "rc5"                 => "default",
 485                   "sctp"                => "default",
 486                   "ssl-trace"           => "default",
 487                   "ssl3"                => "default",
 488                   "ssl3-method"         => "default",
 489                   "trace"               => "default",
 490                   "ubsan"               => "default",
 491                   "unit-test"           => "default",
 492                   "weak-ssl-ciphers"    => "default",
 493                   "zlib"                => "default",
 494                   "zlib-dynamic"        => "default",
 495                   "ktls"                => "default",
 496                 );
 497
 498 # Note: => pair form used for aesthetics, not to truly make a hash table
 499 my @disable_cascades = (
 500     # "what"            => [ "cascade", ... ]
 501     sub { $config{processor} eq "386" }
 502                         => [ "sse2" ],
 503     "ssl"               => [ "ssl3" ],
 504     "ssl3-method"       => [ "ssl3" ],
 505     "zlib"              => [ "zlib-dynamic" ],
 506     "des"               => [ "mdc2" ],
 507     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 508     sub { $disabled{"ec"} && $disabled{"dh"} }
 509                         => [ "tls1_3" ],
 510     "dgram"             => [ "dtls", "sctp" ],
 511     "sock"              => [ "dgram" ],
 512     "dtls"              => [ @dtls ],
 513     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 514                         => [ "dtls" ],
 515
 516     "tls"               => [ @tls ],
 517     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 518                         => [ "tls" ],
 519
 520     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 521
 522     # If no modules, then no dynamic engines either
 523     "module"            => [ "dynamic-engine" ],
 524
 525     # Without shared libraries, dynamic engines aren't possible.
 526     # This is due to them having to link with libcrypto and register features
 527     # using the ENGINE functionality, and since that relies on global tables,
 528     # those *have* to be exacty the same as the ones accessed from the app,
 529     # which cannot be guaranteed if shared libraries aren't present.
 530     # (note that even with shared libraries, both the app and dynamic engines
 531     # must be linked with the same library)
 532     "shared"            => [ "dynamic-engine", "uplink" ],
 533     "dso"               => [ "dynamic-engine", "module" ],
 534     # Other modules don't necessarily have to link with libcrypto, so shared
 535     # libraries do not have to be a condition to produce those.
 536
 537     # Without position independent code, there can be no shared libraries
 538     # or modules.
 539     "pic"               => [ "shared", "module" ],
 540
 541     "module"            => [ "fips" ],
 542
 543     "engine"            => [ grep /eng$/, @disablables ],
 544     "hw"                => [ "padlockeng" ],
 545
 546     # no-autoalginit is only useful when building non-shared
 547     "autoalginit"       => [ "shared", "apps" ],
 548
 549     "stdio"             => [ "apps", "capieng", "egd" ],
 550     "apps"              => [ "tests" ],
 551     "tests"             => [ "external-tests" ],
 552     "comp"              => [ "zlib" ],
 553     "sm3"               => [ "sm2" ],
 554     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 555
 556     sub { !$disabled{"msan"} } => [ "asm" ],
 557
 558     sub { $disabled{cmac}; } => [ "siv" ],
 559     "legacy"                 => [ "md2" ],
 560
 561     "cmp"               => [ "crmf" ],
 562
 563     # Padlock engine uses low-level AES APIs which are deprecated
 564     sub { $disabled{"deprecated"}
 565           && (!defined $config{"api"} || $config{"api"} >= 30000) }
 566           => [ "padlockeng" ]
 567     );
 568
 569 # Avoid protocol support holes.  Also disable all versions below N, if version
 570 # N is disabled while N+1 is enabled.
 571 #
 572 my @list = (reverse @tls);
 573 while ((my $first, my $second) = (shift @list, shift @list)) {
 574     last unless @list;
 575     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 576                               => [ @list ] );
 577     unshift @list, $second;
 578 }
 579 my @list = (reverse @dtls);
 580 while ((my $first, my $second) = (shift @list, shift @list)) {
 581     last unless @list;
 582     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 583                               => [ @list ] );
 584     unshift @list, $second;
 585 }
 586
 587 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 588 # To remove something from %disabled, use "enable-foo".
 589 # For symmetry, "disable-foo" is a synonym for "no-foo".
 590
 591 &usage if ($#ARGV < 0);
 592
 593 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 594 # platform specific list separators.  Users from those platforms should
 595 # recognise those separators from how you set up the PATH to find executables.
 596 # The default is the Unix like separator, :, but as an exception, we also
 597 # support the space as separator.
 598 my $list_separator_re =
 599     { VMS           => qr/(?<!\^),/,
 600       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 601 # All the "make variables" we support
 602 # Some get pre-populated for the sake of backward compatibility
 603 # (we supported those before the change to "make variable" support.
 604 my %user = (
 605     AR          => env('AR'),
 606     ARFLAGS     => [],
 607     AS          => undef,
 608     ASFLAGS     => [],
 609     CC          => env('CC'),
 610     CFLAGS      => [ env('CFLAGS') || () ],
 611     CXX         => env('CXX'),
 612     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 613     CPP         => undef,
 614     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 615     CPPDEFINES  => [],  # Alternative for -D
 616     CPPINCLUDES => [],  # Alternative for -I
 617     CROSS_COMPILE => env('CROSS_COMPILE'),
 618     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 619     LD          => undef,
 620     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 621     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 622     MT          => undef,
 623     MTFLAGS     => [],
 624     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 625     RANLIB      => env('RANLIB'),
 626     RC          => env('RC') || env('WINDRES'),
 627     RCFLAGS     => [ env('RCFLAGS') || () ],
 628     RM          => undef,
 629    );
 630 # Info about what "make variables" may be prefixed with the cross compiler
 631 # prefix.  This should NEVER mention any such variable with a list for value.
 632 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 633 # The same but for flags given as Configure options.  These are *additional*
 634 # input, as opposed to the VAR=string option that override the corresponding
 635 # config target attributes
 636 my %useradd = (
 637     CPPDEFINES  => [],
 638     CPPINCLUDES => [],
 639     CPPFLAGS    => [],
 640     CFLAGS      => [],
 641     CXXFLAGS    => [],
 642     LDFLAGS     => [],
 643     LDLIBS      => [],
 644     RCFLAGS     => [],
 645    );
 646
 647 my %user_synonyms = (
 648     HASHBANGPERL=> 'PERL',
 649     RC          => 'WINDRES',
 650    );
 651
 652 # Some target attributes have been renamed, this is the translation table
 653 my %target_attr_translate =(
 654     ar          => 'AR',
 655     as          => 'AS',
 656     cc          => 'CC',
 657     cxx         => 'CXX',
 658     cpp         => 'CPP',
 659     hashbangperl => 'HASHBANGPERL',
 660     ld          => 'LD',
 661     mt          => 'MT',
 662     ranlib      => 'RANLIB',
 663     rc          => 'RC',
 664     rm          => 'RM',
 665    );
 666
 667 # Initialisers coming from 'config' scripts
 668 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 669 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 670 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 671 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 672 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 673 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 674 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 675
 676 $config{openssl_api_defines}=[];
 677 $config{openssl_sys_defines}=[];
 678 $config{openssl_feature_defines}=[];
 679 $config{options}="";
 680 $config{build_type} = "release";
 681 my $target="";
 682
 683 my %cmdvars = ();               # Stores FOO='blah' type arguments
 684 my %unsupported_options = ();
 685 my %deprecated_options = ();
 686 # If you change this, update apps/version.c
 687 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 688 my @seed_sources = ();
 689 while (@argvcopy)
 690         {
 691         $_ = shift @argvcopy;
 692
 693         # Support env variable assignments among the options
 694         if (m|^(\w+)=(.+)?$|)
 695                 {
 696                 $cmdvars{$1} = $2;
 697                 # Every time a variable is given as a configuration argument,
 698                 # it acts as a reset if the variable.
 699                 if (exists $user{$1})
 700                         {
 701                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 702                         }
 703                 #if (exists $useradd{$1})
 704                 #       {
 705                 #       $useradd{$1} = [];
 706                 #       }
 707                 next;
 708                 }
 709
 710         # VMS is a case insensitive environment, and depending on settings
 711         # out of our control, we may receive options uppercased.  Let's
 712         # downcase at least the part before any equal sign.
 713         if ($^O eq "VMS")
 714                 {
 715                 s/^([^=]*)/lc($1)/e;
 716                 }
 717
 718         # some people just can't read the instructions, clang people have to...
 719         s/^-no-(?!integrated-as)/no-/;
 720
 721         # rewrite some options in "enable-..." form
 722         s /^-?-?shared$/enable-shared/;
 723         s /^sctp$/enable-sctp/;
 724         s /^threads$/enable-threads/;
 725         s /^zlib$/enable-zlib/;
 726         s /^zlib-dynamic$/enable-zlib-dynamic/;
 727
 728         if (/^(no|disable|enable)-(.+)$/)
 729                 {
 730                 my $word = $2;
 731                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 732                         && !exists $deprecated_disablables{$word}
 733                         && !grep { $word eq $_ } @disablables)
 734                         {
 735                         $unsupported_options{$_} = 1;
 736                         next;
 737                         }
 738                 }
 739         if (/^no-(.+)$/ || /^disable-(.+)$/)
 740                 {
 741                 foreach my $proto ((@tls, @dtls))
 742                         {
 743                         if ($1 eq "$proto-method")
 744                                 {
 745                                 $disabled{"$proto"} = "option($proto-method)";
 746                                 last;
 747                                 }
 748                         }
 749                 if ($1 eq "dtls")
 750                         {
 751                         foreach my $proto (@dtls)
 752                                 {
 753                                 $disabled{$proto} = "option(dtls)";
 754                                 }
 755                         $disabled{"dtls"} = "option(dtls)";
 756                         }
 757                 elsif ($1 eq "ssl")
 758                         {
 759                         # Last one of its kind
 760                         $disabled{"ssl3"} = "option(ssl)";
 761                         }
 762                 elsif ($1 eq "tls")
 763                         {
 764                         # XXX: Tests will fail if all SSL/TLS
 765                         # protocols are disabled.
 766                         foreach my $proto (@tls)
 767                                 {
 768                                 $disabled{$proto} = "option(tls)";
 769                                 }
 770                         }
 771                 elsif ($1 eq "static-engine")
 772                         {
 773                         delete $disabled{"dynamic-engine"};
 774                         }
 775                 elsif ($1 eq "dynamic-engine")
 776                         {
 777                         $disabled{"dynamic-engine"} = "option";
 778                         }
 779                 elsif (exists $deprecated_disablables{$1})
 780                         {
 781                         $deprecated_options{$_} = 1;
 782                         if (defined $deprecated_disablables{$1})
 783                                 {
 784                                 $disabled{$deprecated_disablables{$1}} = "option";
 785                                 }
 786                         }
 787                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 788                         {
 789                         $deprecated_options{$_} = 1;
 790                         }
 791                 else
 792                         {
 793                         $disabled{$1} = "option";
 794                         }
 795                 # No longer an automatic choice
 796                 $auto_threads = 0 if ($1 eq "threads");
 797                 }
 798         elsif (/^enable-(.+)$/)
 799                 {
 800                 if ($1 eq "static-engine")
 801                         {
 802                         $disabled{"dynamic-engine"} = "option";
 803                         }
 804                 elsif ($1 eq "dynamic-engine")
 805                         {
 806                         delete $disabled{"dynamic-engine"};
 807                         }
 808                 elsif ($1 eq "zlib-dynamic")
 809                         {
 810                         delete $disabled{"zlib"};
 811                         }
 812                 my $algo = $1;
 813                 delete $disabled{$algo};
 814
 815                 # No longer an automatic choice
 816                 $auto_threads = 0 if ($1 eq "threads");
 817                 }
 818         elsif (/^--strict-warnings$/)
 819                 {
 820                 # Pretend that our strict flags is a C flag, and replace it
 821                 # with the proper flags later on
 822                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 823                 $strict_warnings=1;
 824                 }
 825         elsif (/^--debug$/)
 826                 {
 827                 $config{build_type} = "debug";
 828                 }
 829         elsif (/^--release$/)
 830                 {
 831                 $config{build_type} = "release";
 832                 }
 833         elsif (/^386$/)
 834                 { $config{processor}=386; }
 835         elsif (/^fips$/)
 836                 {
 837                 die "FIPS mode not supported\n";
 838                 }
 839         elsif (/^rsaref$/)
 840                 {
 841                 # No RSAref support any more since it's not needed.
 842                 # The check for the option is there so scripts aren't
 843                 # broken
 844                 }
 845         elsif (/^nofipscanistercheck$/)
 846                 {
 847                 die "FIPS mode not supported\n";
 848                 }
 849         elsif (m|^[-+/]|)
 850                 {
 851                 if (/^--prefix=(.*)$/)
 852                         {
 853                         $config{prefix}=$1;
 854                         die "Directory given with --prefix MUST be absolute\n"
 855                                 unless file_name_is_absolute($config{prefix});
 856                         }
 857                 elsif (/^--api=(.*)$/)
 858                         {
 859                         my $api = $1;
 860                         die "Unknown API compatibility level $api"
 861                                 unless defined $apitable->{$api};
 862                         $config{api}=$apitable->{$api};
 863                         }
 864                 elsif (/^--libdir=(.*)$/)
 865                         {
 866                         $config{libdir}=$1;
 867                         }
 868                 elsif (/^--openssldir=(.*)$/)
 869                         {
 870                         $config{openssldir}=$1;
 871                         }
 872                 elsif (/^--with-zlib-lib=(.*)$/)
 873                         {
 874                         $withargs{zlib_lib}=$1;
 875                         }
 876                 elsif (/^--with-zlib-include=(.*)$/)
 877                         {
 878                         $withargs{zlib_include}=$1;
 879                         }
 880                 elsif (/^--with-fuzzer-lib=(.*)$/)
 881                         {
 882                         $withargs{fuzzer_lib}=$1;
 883                         }
 884                 elsif (/^--with-fuzzer-include=(.*)$/)
 885                         {
 886                         $withargs{fuzzer_include}=$1;
 887                         }
 888                 elsif (/^--with-rand-seed=(.*)$/)
 889                         {
 890                         foreach my $x (split(m|,|, $1))
 891                             {
 892                             die "Unknown --with-rand-seed choice $x\n"
 893                                 if ! grep { $x eq $_ } @known_seed_sources;
 894                             push @seed_sources, $x;
 895                             }
 896                         }
 897                 elsif (/^--cross-compile-prefix=(.*)$/)
 898                         {
 899                         $user{CROSS_COMPILE}=$1;
 900                         }
 901                 elsif (/^--config=(.*)$/)
 902                         {
 903                         read_config $1;
 904                         }
 905                 elsif (/^-l(.*)$/)
 906                         {
 907                         push @{$useradd{LDLIBS}}, $_;
 908                         }
 909                 elsif (/^-framework$/)
 910                         {
 911                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 912                         }
 913                 elsif (/^-L(.*)$/ or /^-Wl,/)
 914                         {
 915                         push @{$useradd{LDFLAGS}}, $_;
 916                         }
 917                 elsif (/^-rpath$/ or /^-R$/)
 918                         # -rpath is the OSF1 rpath flag
 919                         # -R is the old Solaris rpath flag
 920                         {
 921                         my $rpath = shift(@argvcopy) || "";
 922                         $rpath .= " " if $rpath ne "";
 923                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 924                         }
 925                 elsif (/^-static$/)
 926                         {
 927                         push @{$useradd{LDFLAGS}}, $_;
 928                         }
 929                 elsif (m|^[-/]D(.*)$|)
 930                         {
 931                         push @{$useradd{CPPDEFINES}}, $1;
 932                         }
 933                 elsif (m|^[-/]I(.*)$|)
 934                         {
 935                         push @{$useradd{CPPINCLUDES}}, $1;
 936                         }
 937                 elsif (/^-Wp,$/)
 938                         {
 939                         push @{$useradd{CPPFLAGS}}, $1;
 940                         }
 941                 else    # common if (/^[-+]/), just pass down...
 942                         {
 943                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 944                         # This provides a simple way to pass options with arguments separated
 945                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 946                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 947                         push @{$useradd{CFLAGS}}, $_;
 948                         push @{$useradd{CXXFLAGS}}, $_;
 949                         }
 950                 }
 951         elsif (m|^/|)
 952                 {
 953                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 954                 # This provides a simple way to pass options with arguments separated
 955                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 956                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 957                 push @{$useradd{CFLAGS}}, $_;
 958                 push @{$useradd{CXXFLAGS}}, $_;
 959                 }
 960         else
 961                 {
 962                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 963                 $target=$_;
 964                 }
 965         unless ($_ eq $target || /^no-/ || /^disable-/)
 966                 {
 967                 # "no-..." follows later after implied deactivations
 968                 # have been derived.  (Don't take this too seriously,
 969                 # we really only write OPTIONS to the Makefile out of
 970                 # nostalgia.)
 971
 972                 if ($config{options} eq "")
 973                         { $config{options} = $_; }
 974                 else
 975                         { $config{options} .= " ".$_; }
 976                 }
 977         }
 978
 979 if (keys %deprecated_options)
 980         {
 981         warn "***** Deprecated options: ",
 982                 join(", ", keys %deprecated_options), "\n";
 983         }
 984 if (keys %unsupported_options)
 985         {
 986         die "***** Unsupported options: ",
 987                 join(", ", keys %unsupported_options), "\n";
 988         }
 989
 990 # If any %useradd entry has been set, we must check that the "make
 991 # variables" haven't been set.  We start by checking of any %useradd entry
 992 # is set.
 993 if (grep { scalar @$_ > 0 } values %useradd) {
 994     # Hash of env / make variables names.  The possible values are:
 995     # 1 - "make vars"
 996     # 2 - %useradd entry set
 997     # 3 - both set
 998     my %detected_vars =
 999         map { my $v = 0;
1000               $v += 1 if $cmdvars{$_};
1001               $v += 2 if @{$useradd{$_}};
1002               $_ => $v }
1003         keys %useradd;
1004
1005     # If any of the corresponding "make variables" is set, we error
1006     if (grep { $_ & 1 } values %detected_vars) {
1007         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1008                                sort keys %detected_vars);
1009         die <<"_____";
1010 ***** Mixing make variables and additional compiler/linker flags as
1011 ***** configure command line option is not permitted.
1012 ***** Affected make variables: $names
1013 _____
1014     }
1015 }
1016
1017 # Check through all supported command line variables to see if any of them
1018 # were set, and canonicalise the values we got.  If no compiler or linker
1019 # flag or anything else that affects %useradd was set, we also check the
1020 # environment for values.
1021 my $anyuseradd =
1022     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1023 foreach (keys %user) {
1024     my $value = $cmdvars{$_};
1025     $value //= env($_) unless $anyuseradd;
1026     $value //=
1027         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1028     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1029         unless $anyuseradd;
1030
1031     if (defined $value) {
1032         if (ref $user{$_} eq 'ARRAY') {
1033             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1034                 $user{$_} = [ split /$list_separator_re/, $value ];
1035             } else {
1036                 $user{$_} = [ $value ];
1037             }
1038         } elsif (!defined $user{$_}) {
1039             $user{$_} = $value;
1040         }
1041     }
1042 }
1043
1044 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1045     && !$disabled{shared}
1046     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1047     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1048         "***** any of asan, msan or ubsan\n";
1049 }
1050
1051 sub disable {
1052     my $disable_type = shift;
1053
1054     for (@_) {
1055         $disabled{$_} = $disable_type;
1056     }
1057
1058     my @tocheckfor = (@_ ? @_ : keys %disabled);
1059     while (@tocheckfor) {
1060         my %new_tocheckfor = ();
1061         my @cascade_copy = (@disable_cascades);
1062         while (@cascade_copy) {
1063             my ($test, $descendents) =
1064                 (shift @cascade_copy, shift @cascade_copy);
1065             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1066                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1067                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1068                 }
1069             }
1070         }
1071         @tocheckfor = (keys %new_tocheckfor);
1072     }
1073 }
1074 disable();                     # First cascade run
1075
1076 our $die = sub { die @_; };
1077 if ($target eq "TABLE") {
1078     local $die = sub { warn @_; };
1079     foreach (sort keys %table) {
1080         print_table_entry($_, "TABLE");
1081     }
1082     exit 0;
1083 }
1084
1085 if ($target eq "LIST") {
1086     foreach (sort keys %table) {
1087         print $_,"\n" unless $table{$_}->{template};
1088     }
1089     exit 0;
1090 }
1091
1092 if ($target eq "HASH") {
1093     local $die = sub { warn @_; };
1094     print "%table = (\n";
1095     foreach (sort keys %table) {
1096         print_table_entry($_, "HASH");
1097     }
1098     exit 0;
1099 }
1100
1101 print "Configuring OpenSSL version $config{full_version} ";
1102 print "for target $target\n";
1103
1104 if (scalar(@seed_sources) == 0) {
1105     print "Using os-specific seed configuration\n";
1106     push @seed_sources, 'os';
1107 }
1108 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1109     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1110     warn <<_____ if scalar(@seed_sources) == 1;
1111
1112 ============================== WARNING ===============================
1113 You have selected the --with-rand-seed=none option, which effectively
1114 disables automatic reseeding of the OpenSSL random generator.
1115 All operations depending on the random generator such as creating keys
1116 will not work unless the random generator is seeded manually by the
1117 application.
1118
1119 Please read the 'Note on random number generation' section in the
1120 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1121 ============================== WARNING ===============================
1122
1123 _____
1124 }
1125 push @{$config{openssl_feature_defines}},
1126      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1127         @seed_sources;
1128
1129 # Backward compatibility?
1130 if ($target =~ m/^CygWin32(-.*)$/) {
1131     $target = "Cygwin".$1;
1132 }
1133
1134 # Support for legacy targets having a name starting with 'debug-'
1135 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1136 if ($d) {
1137     $config{build_type} = "debug";
1138
1139     # If we do not find debug-foo in the table, the target is set to foo.
1140     if (!$table{$target}) {
1141         $target = $t;
1142     }
1143 }
1144
1145 &usage if !$table{$target} || $table{$target}->{template};
1146
1147 $config{target} = $target;
1148 my %target = resolve_config($target);
1149
1150 foreach (keys %target_attr_translate) {
1151     $target{$target_attr_translate{$_}} = $target{$_}
1152         if $target{$_};
1153     delete $target{$_};
1154 }
1155
1156 %target = ( %{$table{DEFAULTS}}, %target );
1157
1158 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1159 $config{conf_files} = [ sort keys %conf_files ];
1160
1161 # Using sub disable within these loops may prove fragile, so we run
1162 # a cascade afterwards
1163 foreach my $feature (@{$target{disable}}) {
1164     if (exists $deprecated_disablables{$feature}) {
1165         warn "***** config $target disables deprecated feature $feature\n";
1166     } elsif (!grep { $feature eq $_ } @disablables) {
1167         die "***** config $target disables unknown feature $feature\n";
1168     }
1169     $disabled{$feature} = 'config';
1170 }
1171 foreach my $feature (@{$target{enable}}) {
1172     if ("default" eq ($disabled{$feature} // "")) {
1173         if (exists $deprecated_disablables{$feature}) {
1174             warn "***** config $target enables deprecated feature $feature\n";
1175         } elsif (!grep { $feature eq $_ } @disablables) {
1176             die "***** config $target enables unknown feature $feature\n";
1177         }
1178         delete $disabled{$feature};
1179     }
1180 }
1181
1182 # If uplink_arch isn't defined, disable uplink
1183 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1184 # If asm_arch isn't defined, disable asm
1185 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1186
1187 disable();                      # Run a cascade now
1188
1189 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1190 $target{cxxflags}//=$target{cflags} if $target{CXX};
1191 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1192 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1193
1194 # Fill %config with values from %user, and in case those are undefined or
1195 # empty, use values from %target (acting as a default).
1196 foreach (keys %user) {
1197     my $ref_type = ref $user{$_};
1198
1199     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1200     # and a value that's to be coerced into that type.
1201     my $mkvalue = sub {
1202         my $type = shift;
1203         my $value = shift;
1204         my $undef_p = shift;
1205
1206         die "Too many arguments for \$mkvalue" if @_;
1207
1208         while (ref $value eq 'CODE') {
1209             $value = $value->();
1210         }
1211
1212         if ($type eq 'ARRAY') {
1213             return undef unless defined $value;
1214             return undef if ref $value ne 'ARRAY' && !$value;
1215             return undef if ref $value eq 'ARRAY' && !@$value;
1216             return [ $value ] unless ref $value eq 'ARRAY';
1217         }
1218         return undef unless $value;
1219         return $value;
1220     };
1221
1222     $config{$_} =
1223         $mkvalue->($ref_type, $user{$_})
1224         || $mkvalue->($ref_type, $target{$_});
1225     delete $config{$_} unless defined $config{$_};
1226 }
1227
1228 # Finish up %config by appending things the user gave us on the command line
1229 # apart from "make variables"
1230 foreach (keys %useradd) {
1231     # The must all be lists, so we assert that here
1232     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1233         unless ref $useradd{$_} eq 'ARRAY';
1234
1235     if (defined $config{$_}) {
1236         push @{$config{$_}}, @{$useradd{$_}};
1237     } else {
1238         $config{$_} = [ @{$useradd{$_}} ];
1239     }
1240 }
1241 # At this point, we can forget everything about %user and %useradd,
1242 # because it's now all been merged into the corresponding $config entry
1243
1244 # Allow overriding the build file name
1245 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1246
1247 # Make sure build_scheme is consistent.
1248 $target{build_scheme} = [ $target{build_scheme} ]
1249     if ref($target{build_scheme}) ne "ARRAY";
1250
1251 my ($builder, $builder_platform, @builder_opts) =
1252     @{$target{build_scheme}};
1253
1254 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1255                       $builder_platform."-checker.pm")) {
1256     my $checker_path = catfile($srcdir, "Configurations", $checker);
1257     if (-f $checker_path) {
1258         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1259             ? sub { warn $@; } : sub { die $@; };
1260         if (! do $checker_path) {
1261             if ($@) {
1262                 $fn->($@);
1263             } elsif ($!) {
1264                 $fn->($!);
1265             } else {
1266                 $fn->("The detected tools didn't match the platform\n");
1267             }
1268         }
1269         last;
1270     }
1271 }
1272
1273 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1274
1275 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1276         {
1277         push @{$config{cflags}}, "-mno-cygwin";
1278         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1279         push @{$config{shared_ldflag}}, "-mno-cygwin";
1280         }
1281
1282 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1283         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1284         # minimally required architecture flags for assembly modules
1285         my $value;
1286         $value = '-mips2' if ($target =~ /mips32/);
1287         $value = '-mips3' if ($target =~ /mips64/);
1288         unshift @{$config{cflags}}, $value;
1289         unshift @{$config{cxxflags}}, $value if $config{CXX};
1290 }
1291
1292 # If threads aren't disabled, check how possible they are
1293 unless ($disabled{threads}) {
1294     if ($auto_threads) {
1295         # Enabled by default, disable it forcibly if unavailable
1296         if ($target{thread_scheme} eq "(unknown)") {
1297             disable("unavailable", 'threads');
1298         }
1299     } else {
1300         # The user chose to enable threads explicitly, let's see
1301         # if there's a chance that's possible
1302         if ($target{thread_scheme} eq "(unknown)") {
1303             # If the user asked for "threads" and we don't have internal
1304             # knowledge how to do it, [s]he is expected to provide any
1305             # system-dependent compiler options that are necessary.  We
1306             # can't truly check that the given options are correct, but
1307             # we expect the user to know what [s]He is doing.
1308             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1309                 die "You asked for multi-threading support, but didn't\n"
1310                     ,"provide any system-specific compiler options\n";
1311             }
1312         }
1313     }
1314 }
1315
1316 # Find out if clang's sanitizers have been enabled with -fsanitize
1317 # flags and ensure that the corresponding %disabled elements area
1318 # removed to reflect that the sanitizers are indeed enabled.
1319 my %detected_sanitizers = ();
1320 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1321     (my $checks = $_) =~ s/^-fsanitize=//;
1322     foreach (split /,/, $checks) {
1323         my $d = { address       => 'asan',
1324                   undefined     => 'ubsan',
1325                   memory        => 'msan' } -> {$_};
1326         next unless defined $d;
1327
1328         $detected_sanitizers{$d} = 1;
1329         if (defined $disabled{$d}) {
1330             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1331                 if $disabled{$d} ne "default";
1332             delete $disabled{$d};
1333         }
1334     }
1335 }
1336
1337 # If threads still aren't disabled, add a C macro to ensure the source
1338 # code knows about it.  Any other flag is taken care of by the configs.
1339 unless($disabled{threads}) {
1340     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1341 }
1342
1343 my $no_shared_warn=0;
1344 if ($target{shared_target} eq "")
1345         {
1346         $no_shared_warn = 1
1347             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1348         disable('no-shared-target', 'pic');
1349         }
1350
1351 if ($disabled{"dynamic-engine"}) {
1352         $config{dynamic_engines} = 0;
1353 } else {
1354         $config{dynamic_engines} = 1;
1355 }
1356
1357 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1358     push @{$config{cflags}}, "-fsanitize=address";
1359 }
1360
1361 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1362     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1363     # platforms.
1364     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1365 }
1366
1367 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1368   push @{$config{cflags}}, "-fsanitize=memory";
1369 }
1370
1371 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1372         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1373     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1374     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1375 }
1376 #
1377 # Platform fix-ups
1378 #
1379
1380 # This saves the build files from having to check
1381 if ($disabled{pic})
1382         {
1383         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1384                     shared_defines shared_includes shared_ldflag
1385                     module_cflags module_cxxflags module_cppflags
1386                     module_defines module_includes module_lflags))
1387                 {
1388                 delete $config{$_};
1389                 $target{$_} = "";
1390                 }
1391         }
1392 else
1393         {
1394         push @{$config{lib_defines}}, "OPENSSL_PIC";
1395         }
1396
1397 if ($target{sys_id} ne "")
1398         {
1399         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1400         }
1401
1402 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1403 my %predefined_CXX = $config{CXX}
1404     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1405     : ();
1406
1407 unless ($disabled{asm}) {
1408     # big endian systems can use ELFv2 ABI
1409     if ($target eq "linux-ppc64") {
1410         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1411     }
1412 }
1413
1414 # Check for makedepend capabilities.
1415 if (!$disabled{makedepend}) {
1416     if ($config{target} =~ /^(VC|vms)-/) {
1417         # For VC- and vms- targets, there's nothing more to do here.  The
1418         # functionality is hard coded in the corresponding build files for
1419         # cl (Windows) and CC/DECC (VMS).
1420     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1421              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1422         # We know that GNU C version 3 and up as well as all clang
1423         # versions support dependency generation, but Xcode did not
1424         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1425         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1426     } else {
1427         # In all other cases, we look for 'makedepend', and disable the
1428         # capability if not found.
1429         $config{makedepprog} = which('makedepend');
1430         disable('unavailable', 'makedepend') unless $config{makedepprog};
1431     }
1432 }
1433
1434 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1435     # probe for -Wa,--noexecstack option...
1436     if ($predefined_C{__clang__}) {
1437         # clang has builtin assembler, which doesn't recognize --help,
1438         # but it apparently recognizes the option in question on all
1439         # supported platforms even when it's meaningless. In other words
1440         # probe would fail, but probed option always accepted...
1441         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1442     } else {
1443         my $cc = $config{CROSS_COMPILE}.$config{CC};
1444         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1445         while(<PIPE>) {
1446             if (m/--noexecstack/) {
1447                 push @{$config{cflags}}, "-Wa,--noexecstack";
1448                 last;
1449             }
1450         }
1451         close(PIPE);
1452         unlink("null.$$.o");
1453     }
1454 }
1455
1456 # Deal with bn_ops ###################################################
1457
1458 $config{bn_ll}                  =0;
1459 my $def_int="unsigned int";
1460 $config{rc4_int}                =$def_int;
1461 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1462
1463 my $count = 0;
1464 foreach (sort split(/\s+/,$target{bn_ops})) {
1465     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1466     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1467     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1468     ($config{b64l},$config{b64},$config{b32})
1469         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1470     ($config{b64l},$config{b64},$config{b32})
1471         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1472     ($config{b64l},$config{b64},$config{b32})
1473         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1474 }
1475 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1476     if $count > 1;
1477
1478 $config{api} = $config{major} * 10000 + $config{minor} * 100
1479     unless $config{api};
1480
1481 # Hack cflags for better warnings (dev option) #######################
1482
1483 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1484 # a string and works as well on command lines.
1485 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1486                         @{$config{cflags}} ];
1487 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1488                           @{$config{cxxflags}} ] if $config{CXX};
1489
1490 $config{openssl_api_defines} = [
1491     "OPENSSL_CONFIGURED_API=".$config{api}
1492 ];
1493
1494 my @strict_warnings_collection=();
1495 if ($strict_warnings)
1496         {
1497         my $wopt;
1498         my $gccver = $predefined_C{__GNUC__} // -1;
1499
1500         if ($gccver >= 4)
1501                 {
1502                 push @strict_warnings_collection, @gcc_devteam_warn;
1503                 push @strict_warnings_collection, @clang_devteam_warn
1504                     if (defined($predefined_C{__clang__}));
1505                 }
1506         elsif ($config{target} =~ /^VC-/)
1507                 {
1508                 push @strict_warnings_collection, @cl_devteam_warn;
1509                 }
1510         else
1511                 {
1512                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1513                 }
1514         }
1515
1516 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1517     disable('static', 'pic', 'threads');
1518 }
1519
1520 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1521                               ? @strict_warnings_collection
1522                               : ( $_ ) }
1523                     @{$config{CFLAGS}} ];
1524
1525 unless ($disabled{afalgeng}) {
1526     $config{afalgeng}="";
1527     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1528         my $minver = 4*10000 + 1*100 + 0;
1529         if ($config{CROSS_COMPILE} eq "") {
1530             my $verstr = `uname -r`;
1531             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1532             ($mi2) = $mi2 =~ /(\d+)/;
1533             my $ver = $ma*10000 + $mi1*100 + $mi2;
1534             if ($ver < $minver) {
1535                 disable('too-old-kernel', 'afalgeng');
1536             } else {
1537                 push @{$config{engdirs}}, "afalg";
1538             }
1539         } else {
1540             disable('cross-compiling', 'afalgeng');
1541         }
1542     } else {
1543         disable('not-linux', 'afalgeng');
1544     }
1545 }
1546
1547 unless ($disabled{devcryptoeng}) {
1548     if ($target =~ m/^BSD/) {
1549         my $maxver = 5*100 + 7;
1550         my $sysstr = `uname -s`;
1551         my $verstr = `uname -r`;
1552         $sysstr =~ s|\R$||;
1553         $verstr =~ s|\R$||;
1554         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1555         my $ver = $ma*100 + $mi;
1556         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1557             disable('too-new-kernel', 'devcryptoeng');
1558         }
1559     }
1560 }
1561
1562 unless ($disabled{ktls}) {
1563     $config{ktls}="";
1564     if ($target =~ m/^linux/) {
1565         my $usr = "/usr/$config{cross_compile_prefix}";
1566         chop($usr);
1567         if ($config{cross_compile_prefix} eq "") {
1568             $usr = "/usr";
1569         }
1570         my $minver = (4 << 16) + (13 << 8) + 0;
1571         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1572
1573         if ($verstr[2] < $minver) {
1574             disable('too-old-kernel', 'ktls');
1575         }
1576     } elsif ($target =~ m/^BSD/) {
1577         my $cc = $config{CROSS_COMPILE}.$config{CC};
1578         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1579         if ($? != 0) {
1580             disable('too-old-freebsd', 'ktls');
1581         }
1582     } else {
1583         disable('not-linux-or-freebsd', 'ktls');
1584     }
1585 }
1586
1587 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1588
1589 # Get the extra flags used when building shared libraries and modules.  We
1590 # do this late because some of them depend on %disabled.
1591
1592 # Make the flags to build DSOs the same as for shared libraries unless they
1593 # are already defined
1594 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1595 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1596 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1597 {
1598     my $shared_info_pl =
1599         catfile(dirname($0), "Configurations", "shared-info.pl");
1600     my %shared_info = read_eval_file($shared_info_pl);
1601     push @{$target{_conf_fname_int}}, $shared_info_pl;
1602     my $si = $target{shared_target};
1603     while (ref $si ne "HASH") {
1604         last if ! defined $si;
1605         if (ref $si eq "CODE") {
1606             $si = $si->();
1607         } else {
1608             $si = $shared_info{$si};
1609         }
1610     }
1611
1612     # Some of the 'shared_target' values don't have any entries in
1613     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1614     # template knows how to handle this.  That is currently the case for
1615     # Windows and VMS.
1616     if (defined $si) {
1617         # Just as above, copy certain shared_* attributes to the corresponding
1618         # module_ attribute unless the latter is already defined
1619         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1620         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1621         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1622         foreach (sort keys %$si) {
1623             $target{$_} = defined $target{$_}
1624                 ? add($si->{$_})->($target{$_})
1625                 : $si->{$_};
1626         }
1627     }
1628 }
1629
1630 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1631
1632 ######################################################################
1633 # Build up information for skipping certain directories depending on disabled
1634 # features, as well as setting up macros for disabled features.
1635
1636 # This is a tentative database of directories to skip.  Some entries may not
1637 # correspond to anything real, but that's ok, they will simply be ignored.
1638 # The actual processing of these entries is done in the build.info lookup
1639 # loop further down.
1640 #
1641 # The key is a Unix formatted path in the source tree, the value is an index
1642 # into %disabled_info, so any existing path gets added to a corresponding
1643 # 'skipped' entry in there with the list of skipped directories.
1644 my %skipdir = ();
1645 my %disabled_info = ();         # For configdata.pm
1646 foreach my $what (sort keys %disabled) {
1647     # There are deprecated disablables that translate to themselves.
1648     # They cause disabling cascades, but should otherwise not regiter.
1649     next if $deprecated_disablables{$what};
1650
1651     $config{options} .= " no-$what";
1652
1653     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1654                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1655                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1656         (my $WHAT = uc $what) =~ s|-|_|g;
1657         my $skipdir = $what;
1658
1659         # fix-up crypto/directory name(s)
1660         $skipdir = "ripemd" if $what eq "rmd160";
1661         $skipdir = "whrlpool" if $what eq "whirlpool";
1662
1663         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1664         push @{$config{openssl_feature_defines}}, $macro;
1665
1666         $skipdir{engines} = $what if $what eq 'engine';
1667         $skipdir{"crypto/$skipdir"} = $what
1668             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1669     }
1670 }
1671
1672 if ($disabled{"dynamic-engine"}) {
1673     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1674 } else {
1675     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1676 }
1677
1678 # If we use the unified build, collect information from build.info files
1679 my %unified_info = ();
1680
1681 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1682 if ($builder eq "unified") {
1683     use Text::Template 1.46;
1684
1685     sub cleandir {
1686         my $base = shift;
1687         my $dir = shift;
1688         my $relativeto = shift || ".";
1689
1690         $dir = catdir($base,$dir) unless isabsolute($dir);
1691
1692         # Make sure the directories we're building in exists
1693         mkpath($dir);
1694
1695         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1696         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1697         return $res;
1698     }
1699
1700     sub cleanfile {
1701         my $base = shift;
1702         my $file = shift;
1703         my $relativeto = shift || ".";
1704
1705         $file = catfile($base,$file) unless isabsolute($file);
1706
1707         my $d = dirname($file);
1708         my $f = basename($file);
1709
1710         # Make sure the directories we're building in exists
1711         mkpath($d);
1712
1713         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1714         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1715         return $res;
1716     }
1717
1718     # Store the name of the template file we will build the build file from
1719     # in %config.  This may be useful for the build file itself.
1720     my @build_file_template_names =
1721         ( $builder_platform."-".$target{build_file}.".tmpl",
1722           $target{build_file}.".tmpl" );
1723     my @build_file_templates = ();
1724
1725     # First, look in the user provided directory, if given
1726     if (defined env($local_config_envname)) {
1727         @build_file_templates =
1728             map {
1729                 if ($^O eq 'VMS') {
1730                     # VMS environment variables are logical names,
1731                     # which can be used as is
1732                     $local_config_envname . ':' . $_;
1733                 } else {
1734                     catfile(env($local_config_envname), $_);
1735                 }
1736             }
1737             @build_file_template_names;
1738     }
1739     # Then, look in our standard directory
1740     push @build_file_templates,
1741         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1742           @build_file_template_names );
1743
1744     my $build_file_template;
1745     for $_ (@build_file_templates) {
1746         $build_file_template = $_;
1747         last if -f $build_file_template;
1748
1749         $build_file_template = undef;
1750     }
1751     if (!defined $build_file_template) {
1752         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1753     }
1754     $config{build_file_templates}
1755       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1756                     $blddir),
1757           $build_file_template,
1758           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1759                     $blddir) ];
1760
1761     my @build_dirs = ( [ ] );   # current directory
1762
1763     $config{build_infos} = [ ];
1764
1765     my %ordinals = ();
1766     while (@build_dirs) {
1767         my @curd = @{shift @build_dirs};
1768         my $sourced = catdir($srcdir, @curd);
1769         my $buildd = catdir($blddir, @curd);
1770
1771         my $unixdir = join('/', @curd);
1772         if (exists $skipdir{$unixdir}) {
1773             my $what = $skipdir{$unixdir};
1774             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1775             next;
1776         }
1777
1778         mkpath($buildd);
1779
1780         my $f = 'build.info';
1781         # The basic things we're trying to build
1782         my @programs = ();
1783         my @libraries = ();
1784         my @modules = ();
1785         my @scripts = ();
1786
1787         my %sources = ();
1788         my %shared_sources = ();
1789         my %includes = ();
1790         my %defines = ();
1791         my %depends = ();
1792         my %generate = ();
1793         my %htmldocs = ();
1794         my %mandocs = ();
1795
1796         # Support for $variablename in build.info files.
1797         # Embedded perl code is the ultimate master, still.  If its output
1798         # contains a dollar sign, it had better be escaped, or it will be
1799         # taken for a variable name prefix.
1800         my %variables = ();
1801         my $variable_re = qr/\$(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1802         my $expand_variables = sub {
1803             my $value = '';
1804             my $value_rest = shift;
1805
1806             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1807                 print STDERR
1808                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1809             }
1810             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1811                 $value .= $`;
1812                 $value .= $variables{$+{VARIABLE}};
1813                 $value_rest = $';
1814             }
1815             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1816                 print STDERR
1817                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1818             }
1819             return $value . $value_rest;
1820         };
1821
1822         # Support for attributes in build.info files
1823         my %attributes = ();
1824         my $handle_attributes = sub {
1825             my $attr_str = shift;
1826             my $ref = shift;
1827             my @goals = @_;
1828
1829             return unless defined $attr_str;
1830
1831             my @a = tokenize($attr_str, qr|\s*,\s*|);
1832             foreach my $a (@a) {
1833                 my $ac = 1;
1834                 my $ak = $a;
1835                 my $av = 1;
1836                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1837                     $ac = ! $1;
1838                     $ak = $1;
1839                     $av = $2;
1840                 }
1841                 foreach my $g (@goals) {
1842                     if ($ac) {
1843                         $$ref->{$g}->{$ak} = $av;
1844                     } else {
1845                         delete $$ref->{$g}->{$ak};
1846                     }
1847                 }
1848             }
1849         };
1850
1851         # We want to detect configdata.pm in the source tree, so we
1852         # don't use it if the build tree is different.
1853         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1854
1855
1856         if ($buildinfo_debug) {
1857             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1858         }
1859         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1860         my $template =
1861             Text::Template->new(TYPE => 'FILE',
1862                                 SOURCE => catfile($sourced, $f),
1863                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1864         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1865         my @text =
1866             split /^/m,
1867             $template->fill_in(HASH => { config => \%config,
1868                                          target => \%target,
1869                                          disabled => \%disabled,
1870                                          withargs => \%withargs,
1871                                          builddir => abs2rel($buildd, $blddir),
1872                                          sourcedir => abs2rel($sourced, $blddir),
1873                                          buildtop => abs2rel($blddir, $blddir),
1874                                          sourcetop => abs2rel($srcdir, $blddir) },
1875                                DELIMITERS => [ "{-", "-}" ]);
1876
1877         # The top item of this stack has the following values
1878         # -2 positive already run and we found ELSE (following ELSIF should fail)
1879         # -1 positive already run (skip until ENDIF)
1880         # 0 negatives so far (if we're at a condition, check it)
1881         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1882         # 2 positive ELSE (following ELSIF should fail)
1883         my @skip = ();
1884
1885         # A few useful generic regexps
1886         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1887         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1888         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1889         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1890         collect_information(
1891             collect_from_array([ @text ],
1892                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1893                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1894             # Info we're looking for
1895             qr/^\s* IF ${cond_re} \s*$/x
1896             => sub {
1897                 if (! @skip || $skip[$#skip] > 0) {
1898                     push @skip, !! $expand_variables->($+{COND});
1899                 } else {
1900                     push @skip, -1;
1901                 }
1902             },
1903             qr/^\s* ELSIF ${cond_re} \s*$/x
1904             => sub { die "ELSIF out of scope" if ! @skip;
1905                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1906                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1907                      $skip[$#skip] = !! $expand_variables->($+{COND})
1908                          if $skip[$#skip] == 0; },
1909             qr/^\s* ELSE \s*$/x
1910             => sub { die "ELSE out of scope" if ! @skip;
1911                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1912                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1913             qr/^\s* ENDIF \s*$/x
1914             => sub { die "ENDIF out of scope" if ! @skip;
1915                      pop @skip; },
1916             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1917             => sub {
1918                 if (!@skip || $skip[$#skip] > 0) {
1919                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1920                 }
1921             },
1922             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1923             => sub {
1924                 if (!@skip || $skip[$#skip] > 0) {
1925                     foreach (tokenize($expand_variables->($+{VALUE}))) {
1926                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1927                     }
1928                 }
1929             },
1930             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
1931             => sub {
1932                 if (!@skip || $skip[$#skip] > 0) {
1933                     my @p = tokenize($expand_variables->($+{VALUE}));
1934                     push @programs, @p;
1935                     $handle_attributes->($+{ATTRIBS},
1936                                          \$attributes{programs},
1937                                          @p);
1938                 }
1939             },
1940             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
1941             => sub {
1942                 if (!@skip || $skip[$#skip] > 0) {
1943                     my @l = tokenize($expand_variables->($+{VALUE}));
1944                     push @libraries, @l;
1945                     $handle_attributes->($+{ATTRIBS},
1946                                          \$attributes{libraries},
1947                                          @l);
1948                 }
1949             },
1950             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
1951             => sub {
1952                 if (!@skip || $skip[$#skip] > 0) {
1953                     my @m = tokenize($expand_variables->($+{VALUE}));
1954                     push @modules, @m;
1955                     $handle_attributes->($+{ATTRIBS},
1956                                          \$attributes{modules},
1957                                          @m);
1958                 }
1959             },
1960             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
1961             => sub {
1962                 if (!@skip || $skip[$#skip] > 0) {
1963                     my @s = tokenize($expand_variables->($+{VALUE}));
1964                     push @scripts, @s;
1965                     $handle_attributes->($+{ATTRIBS},
1966                                          \$attributes{scripts},
1967                                          @s);
1968                 }
1969             },
1970             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
1971             => sub { push @{$htmldocs{$expand_variables->($+{INDEX})}},
1972                          tokenize($expand_variables->($+{VALUE}))
1973                          if !@skip || $skip[$#skip] > 0 },
1974             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
1975             => sub { push @{$mandocs{$expand_variables->($+{INDEX})}},
1976                          tokenize($expand_variables->($+{VALUE}))
1977                          if !@skip || $skip[$#skip] > 0 },
1978             qr/^\s* ORDINALS ${index_re} = ${value_re} $/x
1979             => sub { push @{$ordinals{$expand_variables->($+{INDEX})}},
1980                          tokenize($expand_variables->($+{VALUE}))
1981                          if !@skip || $skip[$#skip] > 0 },
1982             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
1983             => sub { push @{$sources{$expand_variables->($+{INDEX})}},
1984                          tokenize($expand_variables->($+{VALUE}))
1985                          if !@skip || $skip[$#skip] > 0 },
1986             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
1987             => sub { push @{$shared_sources{$expand_variables->($+{INDEX})}},
1988                          tokenize($expand_variables->($+{VALUE}))
1989                          if !@skip || $skip[$#skip] > 0 },
1990             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
1991             => sub { push @{$includes{$expand_variables->($+{INDEX})}},
1992                          tokenize($expand_variables->($+{VALUE}))
1993                          if !@skip || $skip[$#skip] > 0 },
1994             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
1995             => sub { push @{$defines{$expand_variables->($+{INDEX})}},
1996                          tokenize($expand_variables->($+{VALUE}))
1997                          if !@skip || $skip[$#skip] > 0 },
1998             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
1999             => sub {
2000                 if (!@skip || $skip[$#skip] > 0) {
2001                     my $i = $expand_variables->($+{INDEX});
2002                     my @d = tokenize($expand_variables->($+{VALUE}));
2003                     push @{$depends{$i}}, @d;
2004                     $handle_attributes->($+{ATTRIBS},
2005                                          \$attributes{depends}->{$i},
2006                                          @d);
2007                 }
2008             },
2009             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2010             => sub { push @{$generate{$expand_variables->($+{INDEX})}},
2011                          $+{VALUE}
2012                          if !@skip || $skip[$#skip] > 0 },
2013             qr/^\s* (?:\#.*)? $/x => sub { },
2014             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2015             "BEFORE" => sub {
2016                 if ($buildinfo_debug) {
2017                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2018                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2019                 }
2020             },
2021             "AFTER" => sub {
2022                 if ($buildinfo_debug) {
2023                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2024                 }
2025             },
2026             );
2027         die "runaway IF?" if (@skip);
2028
2029         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2030                 and !$config{dynamic_engines}) {
2031             die <<"EOF"
2032 ENGINES can only be used if configured with 'dynamic-engine'.
2033 This is usually a fault in a build.info file.
2034 EOF
2035         }
2036
2037         {
2038             my %infos = ( programs  => [ @programs  ],
2039                           libraries => [ @libraries ],
2040                           modules   => [ @modules   ],
2041                           scripts   => [ @scripts   ] );
2042             foreach my $k (keys %infos) {
2043                 foreach (@{$infos{$k}}) {
2044                     my $item = cleanfile($buildd, $_, $blddir);
2045                     $unified_info{$k}->{$item} = 1;
2046
2047                     # Fix up associated attributes
2048                     $unified_info{attributes}->{$k}->{$item} =
2049                         $attributes{$k}->{$_}
2050                         if defined $attributes{$k}->{$_};
2051                 }
2052             }
2053         }
2054
2055         # Check that we haven't defined any library as both shared and
2056         # explicitly static.  That is forbidden.
2057         my @doubles = ();
2058         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2059             (my $l = $_) =~ s/\.a$//;
2060             push @doubles, $l if defined $unified_info{libraries}->{$l};
2061         }
2062         die "these libraries are both explicitly static and shared:\n  ",
2063             join(" ", @doubles), "\n"
2064             if @doubles;
2065
2066         foreach (keys %sources) {
2067             my $dest = $_;
2068             my $ddest = cleanfile($buildd, $_, $blddir);
2069             foreach (@{$sources{$dest}}) {
2070                 my $s = cleanfile($sourced, $_, $blddir);
2071
2072                 # If it isn't in the source tree, we assume it's generated
2073                 # in the build tree
2074                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2075                     $s = cleanfile($buildd, $_, $blddir);
2076                 }
2077                 # We recognise C++, C and asm files
2078                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2079                     my $o = $_;
2080                     $o =~ s/\.[csS]$/.o/; # C and assembler
2081                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2082                     $o = cleanfile($buildd, $o, $blddir);
2083                     $unified_info{sources}->{$ddest}->{$o} = -1;
2084                     $unified_info{sources}->{$o}->{$s} = -1;
2085                 } elsif ($s =~ /\.rc$/) {
2086                     # We also recognise resource files
2087                     my $o = $_;
2088                     $o =~ s/\.rc$/.res/; # Resource configuration
2089                     my $o = cleanfile($buildd, $o, $blddir);
2090                     $unified_info{sources}->{$ddest}->{$o} = -1;
2091                     $unified_info{sources}->{$o}->{$s} = -1;
2092                 } else {
2093                     $unified_info{sources}->{$ddest}->{$s} = 1;
2094                 }
2095             }
2096         }
2097
2098         foreach (keys %shared_sources) {
2099             my $dest = $_;
2100             my $ddest = cleanfile($buildd, $_, $blddir);
2101             foreach (@{$shared_sources{$dest}}) {
2102                 my $s = cleanfile($sourced, $_, $blddir);
2103
2104                 # If it isn't in the source tree, we assume it's generated
2105                 # in the build tree
2106                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2107                     $s = cleanfile($buildd, $_, $blddir);
2108                 }
2109
2110                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2111                     # We recognise C++, C and asm files
2112                     my $o = $_;
2113                     $o =~ s/\.[csS]$/.o/; # C and assembler
2114                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2115                     $o = cleanfile($buildd, $o, $blddir);
2116                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2117                     $unified_info{sources}->{$o}->{$s} = -1;
2118                 } elsif ($s =~ /\.rc$/) {
2119                     # We also recognise resource files
2120                     my $o = $_;
2121                     $o =~ s/\.rc$/.res/; # Resource configuration
2122                     my $o = cleanfile($buildd, $o, $blddir);
2123                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2124                     $unified_info{sources}->{$o}->{$s} = -1;
2125                 } elsif ($s =~ /\.ld$/) {
2126                     # We also recognise linker scripts (or corresponding)
2127                     # We know they are generated files
2128                     my $ld = cleanfile($buildd, $_, $blddir);
2129                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2130                 } else {
2131                     die "unrecognised source file type for shared library: $s\n";
2132                 }
2133             }
2134         }
2135
2136         foreach (keys %generate) {
2137             my $dest = $_;
2138             my $ddest = cleanfile($buildd, $_, $blddir);
2139             die "more than one generator for $dest: "
2140                 ,join(" ", @{$generate{$_}}),"\n"
2141                 if scalar @{$generate{$_}} > 1;
2142             my @generator = split /\s+/, $generate{$dest}->[0];
2143             my $gen = $generator[0];
2144             $generator[0] = cleanfile($sourced, $gen, $blddir);
2145
2146             # If the generator isn't in the source tree, we assume it's
2147             # generated in the build tree
2148             if ($generate{$gen}) {
2149                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2150             }
2151
2152             $unified_info{generate}->{$ddest} = [ @generator ];
2153         }
2154
2155         foreach (keys %depends) {
2156             my $dest = $_;
2157             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2158
2159             # If the destination doesn't exist in source, it can only be
2160             # a generated file in the build tree.
2161             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2162                 $ddest = cleanfile($buildd, $_, $blddir);
2163             }
2164             foreach (@{$depends{$dest}}) {
2165                 my $d = cleanfile($sourced, $_, $blddir);
2166
2167                 # If we know it's generated, or assume it is because we can't
2168                 # find it in the source tree, we set file we depend on to be
2169                 # in the build tree rather than the source tree, and assume
2170                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2171                 # section or in the Makefile template.
2172                 if ($d eq $src_configdata
2173                     || ! -f $d
2174                     || (grep { $d eq $_ }
2175                         map { cleanfile($srcdir, $_, $blddir) }
2176                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2177                     $d = cleanfile($buildd, $_, $blddir);
2178                 }
2179                 # Take note if the file to depend on is being renamed
2180                 # Take extra care with files ending with .a, they should
2181                 # be treated without that extension, and the extension
2182                 # should be added back after treatment.
2183                 $d =~ /(\.a)?$/;
2184                 my $e = $1 // "";
2185                 $d = $`.$e;
2186                 $unified_info{depends}->{$ddest}->{$d} = 1;
2187
2188                 # Fix up associated attributes
2189                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2190                     $attributes{depends}->{$dest}->{$_}
2191                     if defined $attributes{depends}->{$dest}->{$_};
2192             }
2193         }
2194
2195         foreach (keys %includes) {
2196             my $dest = $_;
2197             my $ddest = cleanfile($sourced, $_, $blddir);
2198
2199             # If the destination doesn't exist in source, it can only be
2200             # a generated file in the build tree.
2201             if ($ddest eq $src_configdata || ! -f $ddest) {
2202                 $ddest = cleanfile($buildd, $_, $blddir);
2203             }
2204             foreach (@{$includes{$dest}}) {
2205                 my $is = cleandir($sourced, $_, $blddir);
2206                 my $ib = cleandir($buildd, $_, $blddir);
2207                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2208                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2209                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2210                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2211             }
2212         }
2213
2214         foreach my $dest (keys %defines) {
2215             my $ddest;
2216
2217             if ($dest ne "") {
2218                 $ddest = cleanfile($sourced, $dest, $blddir);
2219
2220                 # If the destination doesn't exist in source, it can only
2221                 # be a generated file in the build tree.
2222                 if (! -f $ddest) {
2223                     $ddest = cleanfile($buildd, $dest, $blddir);
2224                     if ($unified_info{rename}->{$ddest}) {
2225                         $ddest = $unified_info{rename}->{$ddest};
2226                     }
2227                 }
2228             }
2229             foreach my $v (@{$defines{$dest}}) {
2230                 $v =~ m|^([^=]*)(=.*)?$|;
2231                 die "0 length macro name not permitted\n" if $1 eq "";
2232                 if ($dest ne "") {
2233                     die "$1 defined more than once\n"
2234                         if defined $unified_info{defines}->{$ddest}->{$1};
2235                     $unified_info{defines}->{$ddest}->{$1} = $2;
2236                 } else {
2237                     die "$1 defined more than once\n"
2238                         if grep { $v eq $_ } @{$config{defines}};
2239                     push @{$config{defines}}, $v;
2240                 }
2241             }
2242         }
2243
2244         foreach my $section (keys %htmldocs) {
2245             foreach (@{$htmldocs{$section}}) {
2246                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2247                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2248             }
2249         }
2250
2251         foreach my $section (keys %mandocs) {
2252             foreach (@{$mandocs{$section}}) {
2253                 my $mandocs = cleanfile($buildd, $_, $blddir);
2254                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2255             }
2256         }
2257     }
2258
2259     my $ordinals_text = join(', ', sort keys %ordinals);
2260     warn <<"EOF" if $ordinals_text;
2261
2262 WARNING: ORDINALS were specified for $ordinals_text
2263 They are ignored and should be replaced with a combination of GENERATE,
2264 DEPEND and SHARED_SOURCE.
2265 EOF
2266
2267
2268     # Go through the sources of all libraries and check that the same basename
2269     # doesn't appear more than once.  Some static library archivers depend on
2270     # them being unique.
2271     {
2272         my $err = 0;
2273         foreach my $prod (keys %{$unified_info{libraries}}) {
2274             my @prod_sources =
2275                 map { keys %{$unified_info{sources}->{$_}} }
2276                 keys %{$unified_info{sources}->{$prod}};
2277             my %srccnt = ();
2278
2279             # Count how many times a given each source basename
2280             # appears for each product.
2281             foreach my $src (@prod_sources) {
2282                 $srccnt{basename $src}++;
2283             }
2284
2285             foreach my $src (keys %srccnt) {
2286                 if ((my $cnt = $srccnt{$src}) > 1) {
2287                     print STDERR "$src appears $cnt times for the product $prod\n";
2288                     $err++
2289                 }
2290             }
2291         }
2292         die if $err > 0;
2293     }
2294
2295     # Massage the result
2296
2297     # If we depend on a header file or a perl module, add an inclusion of
2298     # its directory to allow smoothe inclusion
2299     foreach my $dest (keys %{$unified_info{depends}}) {
2300         next if $dest eq "";
2301         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2302             next unless $d =~ /\.(h|pm)$/;
2303             my $i = dirname($d);
2304             my $spot =
2305                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2306                 ? 'build' : 'source';
2307             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2308                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2309         }
2310     }
2311
2312     # Go through all intermediary files and change their names to something that
2313     # reflects what they will be built for.  Note that for some source files,
2314     # this leads to duplicate object files because they are used multiple times.
2315     # the goal is to rename all object files according to this scheme:
2316     #    {productname}-{midfix}-{origobjname}.[o|res]
2317     # the {midfix} is a keyword indicating the type of product, which is mostly
2318     # valuable for libraries since they come in two forms.
2319     #
2320     # This also reorganises the {sources} and {shared_sources} so that the
2321     # former only contains ALL object files that are supposed to end up in
2322     # static libraries and programs, while the latter contains ALL object files
2323     # that are supposed to end up in shared libraries and DSOs.
2324     # The main reason for having two different source structures is to allow
2325     # the same name to be used for the static and the shared variants of a
2326     # library.
2327     {
2328         # Take copies so we don't get interference from added stuff
2329         my %unified_copy = ();
2330         foreach (('sources', 'shared_sources')) {
2331             $unified_copy{$_} = { %{$unified_info{$_}} }
2332                 if defined($unified_info{$_});
2333             delete $unified_info{$_};
2334         }
2335         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2336             # $intent serves multi purposes:
2337             # - give a prefix for the new object files names
2338             # - in the case of libraries, rearrange the object files so static
2339             #   libraries use the 'sources' structure exclusively, while shared
2340             #   libraries use the 'shared_sources' structure exclusively.
2341             my $intent = {
2342                 programs  => { bin    => { src => [ 'sources' ],
2343                                            dst => 'sources' } },
2344                 libraries => { lib    => { src => [ 'sources' ],
2345                                            dst => 'sources' },
2346                                shlib  => { prodselect =>
2347                                                sub { grep !/\.a$/, @_ },
2348                                            src => [ 'sources',
2349                                                     'shared_sources' ],
2350                                            dst => 'shared_sources' } },
2351                 modules   => { dso    => { src => [ 'sources' ],
2352                                            dst => 'sources' } },
2353                 scripts   => { script => { src => [ 'sources' ],
2354                                            dst => 'sources' } }
2355                } -> {$prodtype};
2356             foreach my $kind (keys %$intent) {
2357                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2358                              && $disabled{shared});
2359
2360                 my @src = @{$intent->{$kind}->{src}};
2361                 my $dst = $intent->{$kind}->{dst};
2362                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2363                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2364                     # %prod_sources has all applicable objects as keys, and
2365                     # their corresponding sources as values
2366                     my %prod_sources =
2367                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2368                         map { keys %{$unified_copy{$_}->{$prod}} }
2369                         @src;
2370                     foreach (keys %prod_sources) {
2371                         # Only affect object files and resource files,
2372                         # the others simply get a new value
2373                         # (+1 instead of -1)
2374                         if ($_ =~ /\.(o|res)$/) {
2375                             (my $prodname = $prod) =~ s|\.a$||;
2376                             my $newobj =
2377                                 catfile(dirname($_),
2378                                         basename($prodname)
2379                                             . '-' . $kind
2380                                             . '-' . basename($_));
2381                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2382                             foreach my $src (@{$prod_sources{$_}}) {
2383                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2384                             }
2385                             # Adjust dependencies
2386                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2387                                 $unified_info{depends}->{$_}->{$deps} = -1;
2388                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2389                             }
2390                             # Adjust includes
2391                             foreach my $k (('source', 'build')) {
2392                                 next unless
2393                                     defined($unified_info{includes}->{$_}->{$k});
2394                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2395                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2396                             }
2397                         } else {
2398                             $unified_info{$dst}->{$prod}->{$_} = 1;
2399                         }
2400                     }
2401                 }
2402             }
2403         }
2404     }
2405
2406     # At this point, we have a number of sources with the value -1.  They
2407     # aren't part of the local build and are probably meant for a different
2408     # platform, and can therefore be cleaned away.  That happens when making
2409     # %unified_info more efficient below.
2410
2411     ### Make unified_info a bit more efficient
2412     # One level structures
2413     foreach (("programs", "libraries", "modules", "scripts")) {
2414         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2415     }
2416     # Two level structures
2417     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2418                      "htmldocs", "mandocs")) {
2419         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2420             my @items =
2421                 sort
2422                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2423                 keys %{$unified_info{$l1}->{$l2}};
2424             if (@items) {
2425                 $unified_info{$l1}->{$l2} = [ @items ];
2426             } else {
2427                 delete $unified_info{$l1}->{$l2};
2428             }
2429         }
2430     }
2431     # Defines
2432     foreach my $dest (sort keys %{$unified_info{defines}}) {
2433         $unified_info{defines}->{$dest}
2434             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2435                 sort keys %{$unified_info{defines}->{$dest}} ];
2436     }
2437     # Includes
2438     foreach my $dest (sort keys %{$unified_info{includes}}) {
2439         if (defined($unified_info{includes}->{$dest}->{build})) {
2440             my @source_includes = ();
2441             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2442                 if defined($unified_info{includes}->{$dest}->{source});
2443             $unified_info{includes}->{$dest} =
2444                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2445             foreach my $inc (@source_includes) {
2446                 push @{$unified_info{includes}->{$dest}}, $inc
2447                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2448             }
2449         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2450             $unified_info{includes}->{$dest} =
2451                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2452         } else {
2453             delete $unified_info{includes}->{$dest};
2454         }
2455     }
2456
2457     # For convenience collect information regarding directories where
2458     # files are generated, those generated files and the end product
2459     # they end up in where applicable.  Then, add build rules for those
2460     # directories
2461     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2462                      "dso" => [ @{$unified_info{modules}} ],
2463                      "bin" => [ @{$unified_info{programs}} ],
2464                      "script" => [ @{$unified_info{scripts}} ],
2465                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2466                                   keys %{$unified_info{htmldocs} // {}}),
2467                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2468                                   keys %{$unified_info{mandocs} // {}}) ] );
2469     foreach my $type (keys %loopinfo) {
2470         foreach my $product (@{$loopinfo{$type}}) {
2471             my %dirs = ();
2472             my $pd = dirname($product);
2473
2474             foreach (@{$unified_info{sources}->{$product} // []},
2475                      @{$unified_info{shared_sources}->{$product} // []}) {
2476                 my $d = dirname($_);
2477
2478                 # We don't want to create targets for source directories
2479                 # when building out of source
2480                 next if ($config{sourcedir} ne $config{builddir}
2481                              && $d =~ m|^\Q$config{sourcedir}\E|);
2482                 # We already have a "test" target, and the current directory
2483                 # is just silly to make a target for
2484                 next if $d eq "test" || $d eq ".";
2485
2486                 $dirs{$d} = 1;
2487                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2488                     if $d ne $pd;
2489             }
2490             foreach (keys %dirs) {
2491                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2492                     $product;
2493             }
2494         }
2495     }
2496 }
2497
2498 # For the schemes that need it, we provide the old *_obj configs
2499 # from the *_asm_obj ones
2500 foreach (grep /_(asm|aux)_src$/, keys %target) {
2501     my $src = $_;
2502     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2503     $target{$obj} = $target{$src};
2504     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2505     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2506 }
2507
2508 # Write down our configuration where it fits #########################
2509
2510 my %template_vars = (
2511     config => \%config,
2512     target => \%target,
2513     disablables => \@disablables,
2514     disablables_int => \@disablables_int,
2515     disabled => \%disabled,
2516     withargs => \%withargs,
2517     unified_info => \%unified_info,
2518     tls => \@tls,
2519     dtls => \@dtls,
2520     makevars => [ sort keys %user ],
2521     disabled_info => \%disabled_info,
2522     user_crossable => \@user_crossable,
2523 );
2524 my $configdata_outname = 'configdata.pm';
2525 print "Creating $configdata_outname\n";
2526 open CONFIGDATA, ">$configdata_outname.new"
2527             or die "Trying to create $configdata_outname.new: $!";
2528 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2529 my $configdata_tmpl =
2530     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2531 $configdata_tmpl->fill_in(
2532     FILENAME => $configdata_tmplname,
2533     OUTPUT => \*CONFIGDATA,
2534     HASH => { %template_vars,
2535               autowarntext => [
2536                   'WARNING: do not edit!',
2537                   "Generated by Configure from $configdata_tmplname",
2538               ] }
2539 ) or die $Text::Template::ERROR;
2540 close CONFIGDATA;
2541 rename "$configdata_outname.new", $configdata_outname;
2542 if ($builder_platform eq 'unix') {
2543     my $mode = (0755 & ~umask);
2544     chmod $mode, 'configdata.pm'
2545         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2546 }
2547
2548 print "Running $configdata_outname\n";
2549 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2550 my $cmd = "$perlcmd $configdata_outname";
2551 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2552 system($cmd);
2553 exit 1 if $? != 0;
2554
2555 $SIG{__DIE__} = $orig_death_handler;
2556
2557 print <<"EOF" if ($disabled{threads} eq "unavailable");
2558
2559 The library could not be configured for supporting multi-threaded
2560 applications as the compiler options required on this system are not known.
2561 See file INSTALL for details if you need multi-threading.
2562 EOF
2563
2564 print <<"EOF" if ($no_shared_warn);
2565
2566 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2567 platform, so we will pretend you gave the option 'no-pic', which also disables
2568 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2569 or position independent code, please let us know (but please first make sure
2570 you have tried with a current version of OpenSSL).
2571 EOF
2572
2573 print <<"EOF";
2574
2575 **********************************************************************
2576 ***                                                                ***
2577 ***   OpenSSL has been successfully configured                     ***
2578 ***                                                                ***
2579 ***   If you encounter a problem while building, please open an    ***
2580 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2581 ***   and include the output from the following command:           ***
2582 ***                                                                ***
2583 ***       perl configdata.pm --dump                                ***
2584 ***                                                                ***
2585 ***   (If you are new to OpenSSL, you might want to consult the    ***
2586 ***   'Troubleshooting' section in the INSTALL file first)         ***
2587 ***                                                                ***
2588 **********************************************************************
2589 EOF
2590
2591 exit(0);
2592
2593 ######################################################################
2594 #
2595 # Helpers and utility functions
2596 #
2597
2598 # Death handler, to print a helpful message in case of failure #######
2599 #
2600 sub death_handler {
2601     die @_ if $^S;              # To prevent the added message in eval blocks
2602     my $build_file = $target{build_file} // "build file";
2603     my @message = ( <<"_____", @_ );
2604
2605 Failure!  $build_file wasn't produced.
2606 Please read INSTALL and associated NOTES files.  You may also have to look over
2607 your available compiler tool chain or change your configuration.
2608
2609 _____
2610
2611     # Dying is terminal, so it's ok to reset the signal handler here.
2612     $SIG{__DIE__} = $orig_death_handler;
2613     die @message;
2614 }
2615
2616 # Configuration file reading #########################################
2617
2618 # Note: All of the helper functions are for lazy evaluation.  They all
2619 # return a CODE ref, which will return the intended value when evaluated.
2620 # Thus, whenever there's mention of a returned value, it's about that
2621 # intended value.
2622
2623 # Helper function to implement conditional value variants, with a default
2624 # plus additional values based on the value of $config{build_type}.
2625 # Arguments are given in hash table form:
2626 #
2627 #       picker(default => "Basic string: ",
2628 #              debug   => "debug",
2629 #              release => "release")
2630 #
2631 # When configuring with --debug, the resulting string will be
2632 # "Basic string: debug", and when not, it will be "Basic string: release"
2633 #
2634 # This can be used to create variants of sets of flags according to the
2635 # build type:
2636 #
2637 #       cflags => picker(default => "-Wall",
2638 #                        debug   => "-g -O0",
2639 #                        release => "-O3")
2640 #
2641 sub picker {
2642     my %opts = @_;
2643     return sub { add($opts{default} || (),
2644                      $opts{$config{build_type}} || ())->(); }
2645 }
2646
2647 # Helper function to combine several values of different types into one.
2648 # This is useful if you want to combine a string with the result of a
2649 # lazy function, such as:
2650 #
2651 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2652 #
2653 sub combine {
2654     my @stuff = @_;
2655     return sub { add(@stuff)->(); }
2656 }
2657
2658 # Helper function to implement conditional values depending on the value
2659 # of $disabled{threads}.  Can be used as follows:
2660 #
2661 #       cflags => combine("-Wall", threads("-pthread"))
2662 #
2663 sub threads {
2664     my @flags = @_;
2665     return sub { add($disabled{threads} ? () : @flags)->(); }
2666 }
2667
2668 sub shared {
2669     my @flags = @_;
2670     return sub { add($disabled{shared} ? () : @flags)->(); }
2671 }
2672
2673 our $add_called = 0;
2674 # Helper function to implement adding values to already existing configuration
2675 # values.  It handles elements that are ARRAYs, CODEs and scalars
2676 sub _add {
2677     my $separator = shift;
2678
2679     # If there's any ARRAY in the collection of values OR the separator
2680     # is undef, we will return an ARRAY of combined values, otherwise a
2681     # string of joined values with $separator as the separator.
2682     my $found_array = !defined($separator);
2683
2684     my @values =
2685         map {
2686             my $res = $_;
2687             while (ref($res) eq "CODE") {
2688                 $res = $res->();
2689             }
2690             if (defined($res)) {
2691                 if (ref($res) eq "ARRAY") {
2692                     $found_array = 1;
2693                     @$res;
2694                 } else {
2695                     $res;
2696                 }
2697             } else {
2698                 ();
2699             }
2700     } (@_);
2701
2702     $add_called = 1;
2703
2704     if ($found_array) {
2705         [ @values ];
2706     } else {
2707         join($separator, grep { defined($_) && $_ ne "" } @values);
2708     }
2709 }
2710 sub add_before {
2711     my $separator = " ";
2712     if (ref($_[$#_]) eq "HASH") {
2713         my $opts = pop;
2714         $separator = $opts->{separator};
2715     }
2716     my @x = @_;
2717     sub { _add($separator, @x, @_) };
2718 }
2719 sub add {
2720     my $separator = " ";
2721     if (ref($_[$#_]) eq "HASH") {
2722         my $opts = pop;
2723         $separator = $opts->{separator};
2724     }
2725     my @x = @_;
2726     sub { _add($separator, @_, @x) };
2727 }
2728
2729 sub read_eval_file {
2730     my $fname = shift;
2731     my $content;
2732     my @result;
2733
2734     open F, "< $fname" or die "Can't open '$fname': $!\n";
2735     {
2736         undef local $/;
2737         $content = <F>;
2738     }
2739     close F;
2740     {
2741         local $@;
2742
2743         @result = ( eval $content );
2744         warn $@ if $@;
2745     }
2746     return wantarray ? @result : $result[0];
2747 }
2748
2749 # configuration reader, evaluates the input file as a perl script and expects
2750 # it to fill %targets with target configurations.  Those are then added to
2751 # %table.
2752 sub read_config {
2753     my $fname = shift;
2754     my %targets;
2755
2756     {
2757         # Protect certain tables from tampering
2758         local %table = ();
2759
2760         %targets = read_eval_file($fname);
2761     }
2762     my %preexisting = ();
2763     foreach (sort keys %targets) {
2764         $preexisting{$_} = 1 if $table{$_};
2765     }
2766     die <<"EOF",
2767 The following config targets from $fname
2768 shadow pre-existing config targets with the same name:
2769 EOF
2770         map { "  $_\n" } sort keys %preexisting
2771         if %preexisting;
2772
2773
2774     # For each target, check that it's configured with a hash table.
2775     foreach (keys %targets) {
2776         if (ref($targets{$_}) ne "HASH") {
2777             if (ref($targets{$_}) eq "") {
2778                 warn "Deprecated target configuration for $_, ignoring...\n";
2779             } else {
2780                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2781             }
2782             delete $targets{$_};
2783         } else {
2784             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2785         }
2786     }
2787
2788     %table = (%table, %targets);
2789
2790 }
2791
2792 # configuration resolver.  Will only resolve all the lazy evaluation
2793 # codeblocks for the chosen target and all those it inherits from,
2794 # recursively
2795 sub resolve_config {
2796     my $target = shift;
2797     my @breadcrumbs = @_;
2798
2799 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2800
2801     if (grep { $_ eq $target } @breadcrumbs) {
2802         die "inherit_from loop!  target backtrace:\n  "
2803             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2804     }
2805
2806     if (!defined($table{$target})) {
2807         warn "Warning! target $target doesn't exist!\n";
2808         return ();
2809     }
2810     # Recurse through all inheritances.  They will be resolved on the
2811     # fly, so when this operation is done, they will all just be a
2812     # bunch of attributes with string values.
2813     # What we get here, though, are keys with references to lists of
2814     # the combined values of them all.  We will deal with lists after
2815     # this stage is done.
2816     my %combined_inheritance = ();
2817     if ($table{$target}->{inherit_from}) {
2818         my @inherit_from =
2819             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2820         foreach (@inherit_from) {
2821             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2822
2823             # 'template' is a marker that's considered private to
2824             # the config that had it.
2825             delete $inherited_config{template};
2826
2827             foreach (keys %inherited_config) {
2828                 if (!$combined_inheritance{$_}) {
2829                     $combined_inheritance{$_} = [];
2830                 }
2831                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2832             }
2833         }
2834     }
2835
2836     # We won't need inherit_from in this target any more, since we've
2837     # resolved all the inheritances that lead to this
2838     delete $table{$target}->{inherit_from};
2839
2840     # Now is the time to deal with those lists.  Here's the place to
2841     # decide what shall be done with those lists, all based on the
2842     # values of the target we're currently dealing with.
2843     # - If a value is a coderef, it will be executed with the list of
2844     #   inherited values as arguments.
2845     # - If the corresponding key doesn't have a value at all or is the
2846     #   empty string, the inherited value list will be run through the
2847     #   default combiner (below), and the result becomes this target's
2848     #   value.
2849     # - Otherwise, this target's value is assumed to be a string that
2850     #   will simply override the inherited list of values.
2851     my $default_combiner = add();
2852
2853     my %all_keys =
2854         map { $_ => 1 } (keys %combined_inheritance,
2855                          keys %{$table{$target}});
2856
2857     sub process_values {
2858         my $object    = shift;
2859         my $inherited = shift;  # Always a [ list ]
2860         my $target    = shift;
2861         my $entry     = shift;
2862
2863         $add_called = 0;
2864
2865         while(ref($object) eq "CODE") {
2866             $object = $object->(@$inherited);
2867         }
2868         if (!defined($object)) {
2869             return ();
2870         }
2871         elsif (ref($object) eq "ARRAY") {
2872             local $add_called;  # To make sure recursive calls don't affect it
2873             return [ map { process_values($_, $inherited, $target, $entry) }
2874                      @$object ];
2875         } elsif (ref($object) eq "") {
2876             return $object;
2877         } else {
2878             die "cannot handle reference type ",ref($object)
2879                 ," found in target ",$target," -> ",$entry,"\n";
2880         }
2881     }
2882
2883     foreach (sort keys %all_keys) {
2884         my $previous = $combined_inheritance{$_};
2885
2886         # Current target doesn't have a value for the current key?
2887         # Assign it the default combiner, the rest of this loop body
2888         # will handle it just like any other coderef.
2889         if (!exists $table{$target}->{$_}) {
2890             $table{$target}->{$_} = $default_combiner;
2891         }
2892
2893         $table{$target}->{$_} = process_values($table{$target}->{$_},
2894                                                $combined_inheritance{$_},
2895                                                $target, $_);
2896         unless(defined($table{$target}->{$_})) {
2897             delete $table{$target}->{$_};
2898         }
2899 #        if ($extra_checks &&
2900 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2901 #            warn "$_ got replaced in $target\n";
2902 #        }
2903     }
2904
2905     # Finally done, return the result.
2906     return %{$table{$target}};
2907 }
2908
2909 sub usage
2910         {
2911         print STDERR $usage;
2912         print STDERR "\npick os/compiler from:\n";
2913         my $j=0;
2914         my $i;
2915         my $k=0;
2916         foreach $i (sort keys %table)
2917                 {
2918                 next if $table{$i}->{template};
2919                 next if $i =~ /^debug/;
2920                 $k += length($i) + 1;
2921                 if ($k > 78)
2922                         {
2923                         print STDERR "\n";
2924                         $k=length($i);
2925                         }
2926                 print STDERR $i . " ";
2927                 }
2928         foreach $i (sort keys %table)
2929                 {
2930                 next if $table{$i}->{template};
2931                 next if $i !~ /^debug/;
2932                 $k += length($i) + 1;
2933                 if ($k > 78)
2934                         {
2935                         print STDERR "\n";
2936                         $k=length($i);
2937                         }
2938                 print STDERR $i . " ";
2939                 }
2940         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2941         exit(1);
2942         }
2943
2944 sub compiler_predefined {
2945     state %predefined;
2946     my $cc = shift;
2947
2948     return () if $^O eq 'VMS';
2949
2950     die 'compiler_predefined called without a compiler command'
2951         unless $cc;
2952
2953     if (! $predefined{$cc}) {
2954
2955         $predefined{$cc} = {};
2956
2957         # collect compiler pre-defines from gcc or gcc-alike...
2958         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2959         while (my $l = <PIPE>) {
2960             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2961             $predefined{$cc}->{$1} = $2 // '';
2962         }
2963         close(PIPE);
2964     }
2965
2966     return %{$predefined{$cc}};
2967 }
2968
2969 sub which
2970 {
2971     my ($name)=@_;
2972
2973     if (eval { require IPC::Cmd; 1; }) {
2974         IPC::Cmd->import();
2975         return scalar IPC::Cmd::can_run($name);
2976     } else {
2977         # if there is $directories component in splitpath,
2978         # then it's not something to test with $PATH...
2979         return $name if (File::Spec->splitpath($name))[1];
2980
2981         foreach (File::Spec->path()) {
2982             my $fullpath = catfile($_, "$name$target{exe_extension}");
2983             if (-f $fullpath and -x $fullpath) {
2984                 return $fullpath;
2985             }
2986         }
2987     }
2988 }
2989
2990 sub env
2991 {
2992     my $name = shift;
2993     my %opts = @_;
2994
2995     unless ($opts{cacheonly}) {
2996         # Note that if $ENV{$name} doesn't exist or is undefined,
2997         # $config{perlenv}->{$name} will be created with the value
2998         # undef.  This is intentional.
2999
3000         $config{perlenv}->{$name} = $ENV{$name}
3001             if ! exists $config{perlenv}->{$name};
3002     }
3003     return $config{perlenv}->{$name};
3004 }
3005
3006 # Configuration printer ##############################################
3007
3008 sub print_table_entry
3009 {
3010     local $now_printing = shift;
3011     my %target = resolve_config($now_printing);
3012     my $type = shift;
3013
3014     # Don't print the templates
3015     return if $target{template};
3016
3017     my @sequence = (
3018         "sys_id",
3019         "cpp",
3020         "cppflags",
3021         "defines",
3022         "includes",
3023         "cc",
3024         "cflags",
3025         "ld",
3026         "lflags",
3027         "loutflag",
3028         "ex_libs",
3029         "bn_ops",
3030         "poly1035_asm_src",
3031         "thread_scheme",
3032         "perlasm_scheme",
3033         "dso_scheme",
3034         "shared_target",
3035         "shared_cflag",
3036         "shared_defines",
3037         "shared_ldflag",
3038         "shared_rcflag",
3039         "shared_extension",
3040         "dso_extension",
3041         "obj_extension",
3042         "exe_extension",
3043         "ranlib",
3044         "ar",
3045         "arflags",
3046         "aroutflag",
3047         "rc",
3048         "rcflags",
3049         "rcoutflag",
3050         "mt",
3051         "mtflags",
3052         "mtinflag",
3053         "mtoutflag",
3054         "multilib",
3055         "build_scheme",
3056         );
3057
3058     if ($type eq "TABLE") {
3059         print "\n";
3060         print "*** $now_printing\n";
3061         foreach (@sequence) {
3062             if (ref($target{$_}) eq "ARRAY") {
3063                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3064             } else {
3065                 printf "\$%-12s = %s\n", $_, $target{$_};
3066             }
3067         }
3068     } elsif ($type eq "HASH") {
3069         my $largest =
3070             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3071         print "    '$now_printing' => {\n";
3072         foreach (@sequence) {
3073             if ($target{$_}) {
3074                 if (ref($target{$_}) eq "ARRAY") {
3075                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3076                 } else {
3077                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3078                 }
3079             }
3080         }
3081         print "    },\n";
3082     }
3083 }
3084
3085 # Utility routines ###################################################
3086
3087 # On VMS, if the given file is a logical name, File::Spec::Functions
3088 # will consider it an absolute path.  There are cases when we want a
3089 # purely syntactic check without checking the environment.
3090 sub isabsolute {
3091     my $file = shift;
3092
3093     # On non-platforms, we just use file_name_is_absolute().
3094     return file_name_is_absolute($file) unless $^O eq "VMS";
3095
3096     # If the file spec includes a device or a directory spec,
3097     # file_name_is_absolute() is perfectly safe.
3098     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3099
3100     # Here, we know the given file spec isn't absolute
3101     return 0;
3102 }
3103
3104 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3105 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3106 # realpath() requires that at least all path components except the last is an
3107 # existing directory.  On VMS, the last component of the directory spec must
3108 # exist.
3109 sub absolutedir {
3110     my $dir = shift;
3111
3112     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3113     # will return the volume name for the device, no matter what.  Also,
3114     # it will return an incorrect directory spec if the argument is a
3115     # directory that doesn't exist.
3116     if ($^O eq "VMS") {
3117         return rel2abs($dir);
3118     }
3119
3120     # We use realpath() on Unix, since no other will properly clean out
3121     # a directory spec.
3122     use Cwd qw/realpath/;
3123
3124     return realpath($dir);
3125 }
3126
3127 sub quotify {
3128     my %processors = (
3129         perl    => sub { my $x = shift;
3130                          $x =~ s/([\\\$\@"])/\\$1/g;
3131                          return '"'.$x.'"'; },
3132         maybeshell => sub { my $x = shift;
3133                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3134                             if ($x ne $y || $x =~ m|\s|) {
3135                                 return '"'.$y.'"';
3136                             } else {
3137                                 return $x;
3138                             }
3139                         },
3140         );
3141     my $for = shift;
3142     my $processor =
3143         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3144
3145     return map { $processor->($_); } @_;
3146 }
3147
3148 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3149 # $filename is a file name to read from
3150 # $line_concat_cond_re is a regexp detecting a line continuation ending
3151 # $line_concat is a CODEref that takes care of concatenating two lines
3152 sub collect_from_file {
3153     my $filename = shift;
3154     my $line_concat_cond_re = shift;
3155     my $line_concat = shift;
3156
3157     open my $fh, $filename || die "unable to read $filename: $!\n";
3158     return sub {
3159         my $saved_line = "";
3160         $_ = "";
3161         while (<$fh>) {
3162             s|\R$||;
3163             if (defined $line_concat) {
3164                 $_ = $line_concat->($saved_line, $_);
3165                 $saved_line = "";
3166             }
3167             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3168                 $saved_line = $_;
3169                 next;
3170             }
3171             return $_;
3172         }
3173         die "$filename ending with continuation line\n" if $_;
3174         close $fh;
3175         return undef;
3176     }
3177 }
3178
3179 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3180 # $array is an ARRAYref of lines
3181 # $line_concat_cond_re is a regexp detecting a line continuation ending
3182 # $line_concat is a CODEref that takes care of concatenating two lines
3183 sub collect_from_array {
3184     my $array = shift;
3185     my $line_concat_cond_re = shift;
3186     my $line_concat = shift;
3187     my @array = (@$array);
3188
3189     return sub {
3190         my $saved_line = "";
3191         $_ = "";
3192         while (defined($_ = shift @array)) {
3193             s|\R$||;
3194             if (defined $line_concat) {
3195                 $_ = $line_concat->($saved_line, $_);
3196                 $saved_line = "";
3197             }
3198             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3199                 $saved_line = $_;
3200                 next;
3201             }
3202             return $_;
3203         }
3204         die "input text ending with continuation line\n" if $_;
3205         return undef;
3206     }
3207 }
3208
3209 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3210 # $lineiterator is a CODEref that delivers one line at a time.
3211 # All following arguments are regex/CODEref pairs, where the regexp detects a
3212 # line and the CODEref does something with the result of the regexp.
3213 sub collect_information {
3214     my $lineiterator = shift;
3215     my %collectors = @_;
3216
3217     while(defined($_ = $lineiterator->())) {
3218         s|\R$||;
3219         my $found = 0;
3220         if ($collectors{"BEFORE"}) {
3221             $collectors{"BEFORE"}->($_);
3222         }
3223         foreach my $re (keys %collectors) {
3224             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3225                 $collectors{$re}->($lineiterator);
3226                 $found = 1;
3227             };
3228         }
3229         if ($collectors{"OTHERWISE"}) {
3230             $collectors{"OTHERWISE"}->($lineiterator, $_)
3231                 unless $found || !defined $collectors{"OTHERWISE"};
3232         }
3233         if ($collectors{"AFTER"}) {
3234             $collectors{"AFTER"}->($_);
3235         }
3236     }
3237 }
3238
3239 # tokenize($line)
3240 # tokenize($line,$separator)
3241 # $line is a line of text to split up into tokens
3242 # $separator [optional] is a regular expression that separates the tokens,
3243 # the default being spaces.  Do not use quotes of any kind as separators,
3244 # that will give undefined results.
3245 # Returns a list of tokens.
3246 #
3247 # Tokens are divided by separator (spaces by default).  If the tokens include
3248 # the separators, they have to be quoted with single or double quotes.
3249 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3250 # with backslash.
3251 # Basically, the same quoting rules apply for " and ' as in any
3252 # Unix shell.
3253 sub tokenize {
3254     my $line = my $debug_line = shift;
3255     my $separator = shift // qr|\s+|;
3256     my @result = ();
3257
3258     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3259         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3260     }
3261
3262     while ($line =~ s|^${separator}||, $line ne "") {
3263         my $token = "";
3264     again:
3265         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3266         $token .= $1;
3267         $line = $2.$';
3268
3269         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3270             $token .= $1;
3271             $line = $';
3272             goto again;
3273         } elsif ($line =~ m/^'([^']*)'/) {
3274             $token .= $1;
3275             $line = $';
3276             goto again;
3277         }
3278         push @result, $token;
3279     }
3280
3281     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3282         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3283         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3284     }
3285     return @result;
3286 }