Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  25
  26 # Options:
  27 #
  28 # --config      add the given configuration file, which will be read after
  29 #               any "Configurations*" files that are found in the same
  30 #               directory as this script.
  31 # --prefix      prefix for the OpenSSL installation, which includes the
  32 #               directories bin, lib, include, share/man, share/doc/openssl
  33 #               This becomes the value of INSTALLTOP in Makefile
  34 #               (Default: /usr/local)
  35 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  36 #               If it's a relative directory, it will be added on the directory
  37 #               given with --prefix.
  38 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  39 #               (Default: PREFIX/ssl)
  40 #
  41 # --cross-compile-prefix Add specified prefix to binutils components.
  42 #
  43 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  44 #               interfaces deprecated as of the specified OpenSSL version.
  45 #
  46 # no-hw-xxx     do not compile support for specific crypto hardware.
  47 #               Generic OpenSSL-style methods relating to this support
  48 #               are always compiled but return NULL if the hardware
  49 #               support isn't compiled.
  50 # no-hw         do not compile support for any crypto hardware.
  51 # [no-]threads  [don't] try to create a library that is suitable for
  52 #               multithreaded applications (default is "threads" if we
  53 #               know how to do it)
  54 # [no-]shared   [don't] try to create shared libraries when supported.
  55 # [no-]pic      [don't] try to build position independent code when supported.
  56 #               If disabled, it also disables shared and dynamic-engine.
  57 # no-asm        do not use assembler
  58 # no-dso        do not compile in any native shared-library methods. This
  59 #               will ensure that all methods just return NULL.
  60 # no-egd        do not compile support for the entropy-gathering daemon APIs
  61 # [no-]zlib     [don't] compile support for zlib compression.
  62 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  63 #               library and will be loaded in run-time by the OpenSSL library.
  64 # sctp          include SCTP support
  65 # enable-weak-ssl-ciphers
  66 #               Enable weak ciphers that are disabled by default.
  67 # 386           generate 80386 code in assembly modules
  68 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  69 #               mentioned '386' option implies this one
  70 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  71 # -<xxx> +<xxx> compiler options are passed through
  72 # -static       while -static is also a pass-through compiler option (and
  73 #               as such is limited to environments where it's actually
  74 #               meaningful), it triggers a number configuration options,
  75 #               namely no-dso, no-pic, no-shared and no-threads. It is
  76 #               argued that the only reason to produce statically linked
  77 #               binaries (and in context it means executables linked with
  78 #               -static flag, and not just executables linked with static
  79 #               libcrypto.a) is to eliminate dependency on specific run-time,
  80 #               a.k.a. libc version. The mentioned config options are meant
  81 #               to achieve just that. Unfortunately on Linux it's impossible
  82 #               to eliminate the dependency completely for openssl executable
  83 #               because of getaddrinfo and gethostbyname calls, which can
  84 #               invoke dynamically loadable library facility anyway to meet
  85 #               the lookup requests. For this reason on Linux statically
  86 #               linked openssl executable has rather debugging value than
  87 #               production quality.
  88 #
  89 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  90 #               provided to stack calls. Generates unique stack functions for
  91 #               each possible stack type.
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least get
 104 # past these.
 105
 106 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 107 # -DPEDANTIC complements -pedantic and is meant to mask code that
 108 # is not strictly standard-compliant and/or implementation-specific,
 109 # e.g. inline assembly, disregards to alignment requirements, such
 110 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 111 # to be used even in sanitized builds, because sanitizer too is
 112 # supposed to and does take notice of non-standard behaviour. Then
 113 # -pedantic with pre-C9x compiler would also complain about 'long
 114 # long' not being supported. As 64-bit algorithms are common now,
 115 # it grew impossible to resolve this without sizeable additional
 116 # code, so we just tell compiler to be pedantic about everything
 117 # but 'long long' type.
 118
 119 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 120         . " -DPEDANTIC -pedantic -Wno-long-long"
 121         . " -Wall"
 122         . " -Wextra"
 123         . " -Wno-unused-parameter"
 124         . " -Wno-missing-field-initializers"
 125         . " -Wswitch"
 126         . " -Wsign-compare"
 127         . " -Wmissing-prototypes"
 128         . " -Wshadow"
 129         . " -Wformat"
 130         . " -Wtype-limits"
 131         . " -Wundef"
 132         . " -Werror"
 133         ;
 134
 135 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 136 # TODO(openssl-team): fix problems and investigate if (at least) the
 137 # following warnings can also be enabled:
 138 #       -Wcast-align
 139 #       -Wunreachable-code -- no, too ugly/compiler-specific
 140 #       -Wlanguage-extension-token -- no, we use asm()
 141 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 142 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 143 my $clang_devteam_warn = ""
 144         . " -Wswitch-default"
 145         . " -Wno-parentheses-equality"
 146         . " -Wno-language-extension-token"
 147         . " -Wno-extended-offsetof"
 148         . " -Wconditional-uninitialized"
 149         . " -Wincompatible-pointer-types-discards-qualifiers"
 150         . " -Wmissing-variable-declarations"
 151         . " -Wno-unknown-warning-option"
 152         ;
 153
 154 # This adds backtrace information to the memory leak info.  Is only used
 155 # when crypto-mdebug-backtrace is enabled.
 156 my $memleak_devteam_backtrace = "-rdynamic";
 157
 158 my $strict_warnings = 0;
 159
 160 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 161 # which would cover all BSD flavors. -pthread applies to them all,
 162 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 163 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 164 # which has to be accompanied by explicit -D_THREAD_SAFE and
 165 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 166 # seems to be sufficient?
 167 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 168
 169 #
 170 # API compatibility name to version number mapping.
 171 #
 172 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 173 my $apitable = {
 174     "1.1.0" => "0x10100000L",
 175     "1.0.0" => "0x10000000L",
 176     "0.9.8" => "0x00908000L",
 177 };
 178
 179 our %table = ();
 180 our %config = ();
 181 our %withargs = ();
 182 our $now_printing;      # set to current entry's name in print_table_entry
 183                         # (todo: right thing would be to encapsulate name
 184                         # into %target [class] and make print_table_entry
 185                         # a method)
 186
 187 # Forward declarations ###############################################
 188
 189 # read_config(filename)
 190 #
 191 # Reads a configuration file and populates %table with the contents
 192 # (which the configuration file places in %targets).
 193 sub read_config;
 194
 195 # resolve_config(target)
 196 #
 197 # Resolves all the late evaluations, inheritances and so on for the
 198 # chosen target and any target it inherits from.
 199 sub resolve_config;
 200
 201
 202 # Information collection #############################################
 203
 204 # Unified build supports separate build dir
 205 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 206 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 207 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 208
 209 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 210
 211 $config{sourcedir} = abs2rel($srcdir);
 212 $config{builddir} = abs2rel($blddir);
 213
 214 # Collect reconfiguration information if needed
 215 my @argvcopy=@ARGV;
 216
 217 if (grep /^reconf(igure)?$/, @argvcopy) {
 218     die "reconfiguring with other arguments present isn't supported"
 219         if scalar @argvcopy > 1;
 220     if (-f "./configdata.pm") {
 221         my $file = "./configdata.pm";
 222         unless (my $return = do $file) {
 223             die "couldn't parse $file: $@" if $@;
 224             die "couldn't do $file: $!"    unless defined $return;
 225             die "couldn't run $file"       unless $return;
 226         }
 227
 228         @argvcopy = defined($configdata::config{perlargv}) ?
 229             @{$configdata::config{perlargv}} : ();
 230         die "Incorrect data to reconfigure, please do a normal configuration\n"
 231             if (grep(/^reconf/,@argvcopy));
 232         $config{perlenv} = $configdata::config{perlenv} // {};
 233     } else {
 234         die "Insufficient data to reconfigure, please do a normal configuration\n";
 235     }
 236 }
 237
 238 $config{perlargv} = [ @argvcopy ];
 239
 240 # Collect version numbers
 241 $config{version} = "unknown";
 242 $config{version_num} = "unknown";
 243 $config{shlib_version_number} = "unknown";
 244 $config{shlib_version_history} = "unknown";
 245
 246 collect_information(
 247     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 248     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 249     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 250     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 251     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 252     );
 253 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 254
 255 ($config{major}, $config{minor})
 256     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 257 ($config{shlib_major}, $config{shlib_minor})
 258     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 259 die "erroneous version information in opensslv.h: ",
 260     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 261     if ($config{major} eq "" || $config{minor} eq ""
 262         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 263
 264 # Collect target configurations
 265
 266 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 267 foreach (sort glob($pattern)) {
 268     &read_config($_);
 269 }
 270
 271 if (defined env($local_config_envname)) {
 272     if ($^O eq 'VMS') {
 273         # VMS environment variables are logical names,
 274         # which can be used as is
 275         $pattern = $local_config_envname . ':' . '*.conf';
 276     } else {
 277         $pattern = catfile(env($local_config_envname), '*.conf');
 278     }
 279
 280     foreach (sort glob($pattern)) {
 281         &read_config($_);
 282     }
 283 }
 284
 285 # Save away perl command information
 286 $config{perl_cmd} = $^X;
 287 $config{perl_version} = $Config{version};
 288 $config{perl_archname} = $Config{archname};
 289
 290 $config{prefix}="";
 291 $config{openssldir}="";
 292 $config{processor}="";
 293 $config{libdir}="";
 294 my $auto_threads=1;    # enable threads automatically? true by default
 295 my $default_ranlib;
 296
 297 # Top level directories to build
 298 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 299 # crypto/ subdirectories to build
 300 $config{sdirs} = [
 301     "objects",
 302     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash", "sm3",
 303     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "sm4", "chacha", "modes",
 304     "bn", "ec", "rsa", "dsa", "dh", "sm2", "dso", "engine",
 305     "buffer", "bio", "stack", "lhash", "rand", "err",
 306     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 307     "cms", "ts", "srp", "cmac", "ct", "async", "kdf", "store"
 308     ];
 309 # test/ subdirectories to build
 310 $config{tdirs} = [ "ossl_shim" ];
 311
 312 # Known TLS and DTLS protocols
 313 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 314 my @dtls = qw(dtls1 dtls1_2);
 315
 316 # Explicitly known options that are possible to disable.  They can
 317 # be regexps, and will be used like this: /^no-${option}$/
 318 # For developers: keep it sorted alphabetically
 319
 320 my @disablables = (
 321     "afalgeng",
 322     "aria",
 323     "asan",
 324     "asm",
 325     "async",
 326     "autoalginit",
 327     "autoerrinit",
 328     "autoload-config",
 329     "bf",
 330     "blake2",
 331     "camellia",
 332     "capieng",
 333     "cast",
 334     "chacha",
 335     "cmac",
 336     "cms",
 337     "comp",
 338     "crypto-mdebug",
 339     "crypto-mdebug-backtrace",
 340     "ct",
 341     "deprecated",
 342     "des",
 343     "devcryptoeng",
 344     "dgram",
 345     "dh",
 346     "dsa",
 347     "dso",
 348     "dtls",
 349     "dynamic-engine",
 350     "ec",
 351     "ec2m",
 352     "ecdh",
 353     "ecdsa",
 354     "ec_nistp_64_gcc_128",
 355     "egd",
 356     "engine",
 357     "err",
 358     "external-tests",
 359     "filenames",
 360     "fuzz-libfuzzer",
 361     "fuzz-afl",
 362     "gost",
 363     "heartbeats",
 364     "hw(-.+)?",
 365     "idea",
 366     "makedepend",
 367     "md2",
 368     "md4",
 369     "mdc2",
 370     "msan",
 371     "multiblock",
 372     "nextprotoneg",
 373     "ocb",
 374     "ocsp",
 375     "pic",
 376     "poly1305",
 377     "posix-io",
 378     "psk",
 379     "rc2",
 380     "rc4",
 381     "rc5",
 382     "rdrand",
 383     "rfc3779",
 384     "rmd160",
 385     "scrypt",
 386     "sctp",
 387     "seed",
 388     "shared",
 389     "siphash",
 390     "sm2",
 391     "sm3",
 392     "sm4",
 393     "sock",
 394     "srp",
 395     "srtp",
 396     "sse2",
 397     "ssl",
 398     "ssl-trace",
 399     "static-engine",
 400     "stdio",
 401     "tests",
 402     "threads",
 403     "tls",
 404     "tls13downgrade",
 405     "ts",
 406     "ubsan",
 407     "ui-console",
 408     "unit-test",
 409     "whirlpool",
 410     "weak-ssl-ciphers",
 411     "zlib",
 412     "zlib-dynamic",
 413     );
 414 foreach my $proto ((@tls, @dtls))
 415         {
 416         push(@disablables, $proto);
 417         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 418         }
 419
 420 my %deprecated_disablables = (
 421     "ssl2" => undef,
 422     "buf-freelists" => undef,
 423     "ripemd" => "rmd160",
 424     "ui" => "ui-console",
 425     );
 426
 427 # All of the following are disabled by default:
 428
 429 our %disabled = ( # "what"         => "comment"
 430                   "asan"                => "default",
 431                   "crypto-mdebug"       => "default",
 432                   "crypto-mdebug-backtrace" => "default",
 433                   "devcryptoeng"        => "default",
 434                   "ec_nistp_64_gcc_128" => "default",
 435                   "egd"                 => "default",
 436                   "external-tests"      => "default",
 437                   "fuzz-libfuzzer"      => "default",
 438                   "fuzz-afl"            => "default",
 439                   "heartbeats"          => "default",
 440                   "md2"                 => "default",
 441                   "msan"                => "default",
 442                   "rc5"                 => "default",
 443                   "sctp"                => "default",
 444                   "ssl-trace"           => "default",
 445                   "ssl3"                => "default",
 446                   "ssl3-method"         => "default",
 447                   "ubsan"               => "default",
 448                   "tls13downgrade"      => "default",
 449                   "unit-test"           => "default",
 450                   "weak-ssl-ciphers"    => "default",
 451                   "zlib"                => "default",
 452                   "zlib-dynamic"        => "default",
 453                 );
 454
 455 # Note: => pair form used for aesthetics, not to truly make a hash table
 456 my @disable_cascades = (
 457     # "what"            => [ "cascade", ... ]
 458     sub { $config{processor} eq "386" }
 459                         => [ "sse2" ],
 460     "ssl"               => [ "ssl3" ],
 461     "ssl3-method"       => [ "ssl3" ],
 462     "zlib"              => [ "zlib-dynamic" ],
 463     "des"               => [ "mdc2" ],
 464     "ec"                => [ "ecdsa", "ecdh" ],
 465
 466     "dgram"             => [ "dtls", "sctp" ],
 467     "sock"              => [ "dgram" ],
 468     "dtls"              => [ @dtls ],
 469     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 470                         => [ "dtls" ],
 471
 472     "tls"               => [ @tls ],
 473     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 474                         => [ "tls" ],
 475
 476     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 477
 478     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 479     "dso"               => [ "dynamic-engine" ],
 480
 481     # Without position independent code, there can be no shared libraries or DSOs
 482     "pic"               => [ "shared" ],
 483     "shared"            => [ "dynamic-engine" ],
 484     "engine"            => [ "afalgeng", "devcryptoeng" ],
 485
 486     # no-autoalginit is only useful when building non-shared
 487     "autoalginit"       => [ "shared", "apps" ],
 488
 489     "stdio"             => [ "apps", "capieng", "egd" ],
 490     "apps"              => [ "tests" ],
 491     "tests"             => [ "external-tests" ],
 492     "comp"              => [ "zlib" ],
 493     "ec"                => [ "tls1_3", "sm2" ],
 494     "sm3"               => [ "sm2" ],
 495     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 496
 497     sub { !$disabled{"msan"} } => [ "asm" ],
 498     );
 499
 500 # Avoid protocol support holes.  Also disable all versions below N, if version
 501 # N is disabled while N+1 is enabled.
 502 #
 503 my @list = (reverse @tls);
 504 while ((my $first, my $second) = (shift @list, shift @list)) {
 505     last unless @list;
 506     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 507                               => [ @list ] );
 508     unshift @list, $second;
 509 }
 510 my @list = (reverse @dtls);
 511 while ((my $first, my $second) = (shift @list, shift @list)) {
 512     last unless @list;
 513     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 514                               => [ @list ] );
 515     unshift @list, $second;
 516 }
 517
 518 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 519 # To remove something from %disabled, use "enable-foo".
 520 # For symmetry, "disable-foo" is a synonym for "no-foo".
 521
 522 &usage if ($#ARGV < 0);
 523
 524 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 525 # platform specific list separators.  Users from those platforms should
 526 # recognise those separators from how you set up the PATH to find executables.
 527 # The default is the Unix like separator, :, but as an exception, we also
 528 # support the space as separator.
 529 my $list_separator_re =
 530     { VMS           => qr/(?<!\^),/,
 531       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 532 # All the "make variables" we support
 533 # Some get pre-populated for the sake of backward compatibility
 534 # (we supported those before the change to "make variable" support.
 535 my %user = (
 536     AR          => env('AR'),
 537     ARFLAGS     => [],
 538     AS          => undef,
 539     ASFLAGS     => [],
 540     CC          => env('CC'),
 541     CFLAGS      => [],
 542     CXX         => env('CXX'),
 543     CXXFLAGS    => [],
 544     CPP         => undef,
 545     CPPFLAGS    => [],  # -D, -I, -Wp,
 546     CPPDEFINES  => [],  # Alternative for -D
 547     CPPINCLUDES => [],  # Alternative for -I
 548     CROSS_COMPILE => env('CROSS_COMPILE'),
 549     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 550     LD          => undef,
 551     LDFLAGS     => [],  # -L, -Wl,
 552     LDLIBS      => [],  # -l
 553     MT          => undef,
 554     MTFLAGS     => [],
 555     RANLIB      => env('RANLIB'),
 556     RC          => env('RC') || env('WINDRES'),
 557     RCFLAGS     => [],
 558     RM          => undef,
 559    );
 560 # Info about what "make variables" may be prefixed with the cross compiler
 561 # prefix.  This should NEVER mention any such variable with a list for value.
 562 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 563 # The same but for flags given as Configure options.  These are *additional*
 564 # input, as opposed to the VAR=string option that override the corresponding
 565 # config target attributes
 566 my %useradd = (
 567     CPPDEFINES  => [],
 568     CPPINCLUDES => [],
 569     CPPFLAGS    => [],
 570     CFLAGS      => [],
 571     CXXFLAGS    => [],
 572     LDFLAGS     => [],
 573     LDLIBS      => [],
 574    );
 575
 576 my %user_synonyms = (
 577     HASHBANGPERL=> 'PERL',
 578     RC          => 'WINDRES',
 579    );
 580
 581 # Some target attributes have been renamed, this is the translation table
 582 my %target_attr_translate =(
 583     ar          => 'AR',
 584     as          => 'AS',
 585     cc          => 'CC',
 586     cxx         => 'CXX',
 587     cpp         => 'CPP',
 588     hashbangperl => 'HASHBANGPERL',
 589     ld          => 'LD',
 590     mt          => 'MT',
 591     ranlib      => 'RANLIB',
 592     rc          => 'RC',
 593     rm          => 'RM',
 594    );
 595
 596 # Initialisers coming from 'config' scripts
 597 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 598 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 599 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 600 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 601 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 602 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 603 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 604
 605 $config{openssl_api_defines}=[];
 606 $config{openssl_algorithm_defines}=[];
 607 $config{openssl_thread_defines}=[];
 608 $config{openssl_sys_defines}=[];
 609 $config{openssl_other_defines}=[];
 610 $config{options}="";
 611 $config{build_type} = "release";
 612 my $target="";
 613
 614 my %cmdvars = ();               # Stores FOO='blah' type arguments
 615 my %unsupported_options = ();
 616 my %deprecated_options = ();
 617 # If you change this, update apps/version.c
 618 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 619 my @seed_sources = ();
 620 while (@argvcopy)
 621         {
 622         $_ = shift @argvcopy;
 623
 624         # Support env variable assignments among the options
 625         if (m|^(\w+)=(.+)?$|)
 626                 {
 627                 $cmdvars{$1} = $2;
 628                 # Every time a variable is given as a configuration argument,
 629                 # it acts as a reset if the variable.
 630                 if (exists $user{$1})
 631                         {
 632                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 633                         }
 634                 #if (exists $useradd{$1})
 635                 #       {
 636                 #       $useradd{$1} = [];
 637                 #       }
 638                 next;
 639                 }
 640
 641         # VMS is a case insensitive environment, and depending on settings
 642         # out of our control, we may receive options uppercased.  Let's
 643         # downcase at least the part before any equal sign.
 644         if ($^O eq "VMS")
 645                 {
 646                 s/^([^=]*)/lc($1)/e;
 647                 }
 648
 649         # some people just can't read the instructions, clang people have to...
 650         s/^-no-(?!integrated-as)/no-/;
 651
 652         # rewrite some options in "enable-..." form
 653         s /^-?-?shared$/enable-shared/;
 654         s /^sctp$/enable-sctp/;
 655         s /^threads$/enable-threads/;
 656         s /^zlib$/enable-zlib/;
 657         s /^zlib-dynamic$/enable-zlib-dynamic/;
 658
 659         if (/^(no|disable|enable)-(.+)$/)
 660                 {
 661                 my $word = $2;
 662                 if (!exists $deprecated_disablables{$word}
 663                         && !grep { $word =~ /^${_}$/ } @disablables)
 664                         {
 665                         $unsupported_options{$_} = 1;
 666                         next;
 667                         }
 668                 }
 669         if (/^no-(.+)$/ || /^disable-(.+)$/)
 670                 {
 671                 foreach my $proto ((@tls, @dtls))
 672                         {
 673                         if ($1 eq "$proto-method")
 674                                 {
 675                                 $disabled{"$proto"} = "option($proto-method)";
 676                                 last;
 677                                 }
 678                         }
 679                 if ($1 eq "dtls")
 680                         {
 681                         foreach my $proto (@dtls)
 682                                 {
 683                                 $disabled{$proto} = "option(dtls)";
 684                                 }
 685                         $disabled{"dtls"} = "option(dtls)";
 686                         }
 687                 elsif ($1 eq "ssl")
 688                         {
 689                         # Last one of its kind
 690                         $disabled{"ssl3"} = "option(ssl)";
 691                         }
 692                 elsif ($1 eq "tls")
 693                         {
 694                         # XXX: Tests will fail if all SSL/TLS
 695                         # protocols are disabled.
 696                         foreach my $proto (@tls)
 697                                 {
 698                                 $disabled{$proto} = "option(tls)";
 699                                 }
 700                         }
 701                 elsif ($1 eq "static-engine")
 702                         {
 703                         delete $disabled{"dynamic-engine"};
 704                         }
 705                 elsif ($1 eq "dynamic-engine")
 706                         {
 707                         $disabled{"dynamic-engine"} = "option";
 708                         }
 709                 elsif (exists $deprecated_disablables{$1})
 710                         {
 711                         $deprecated_options{$_} = 1;
 712                         if (defined $deprecated_disablables{$1})
 713                                 {
 714                                 $disabled{$deprecated_disablables{$1}} = "option";
 715                                 }
 716                         }
 717                 else
 718                         {
 719                         $disabled{$1} = "option";
 720                         }
 721                 # No longer an automatic choice
 722                 $auto_threads = 0 if ($1 eq "threads");
 723                 }
 724         elsif (/^enable-(.+)$/)
 725                 {
 726                 if ($1 eq "static-engine")
 727                         {
 728                         $disabled{"dynamic-engine"} = "option";
 729                         }
 730                 elsif ($1 eq "dynamic-engine")
 731                         {
 732                         delete $disabled{"dynamic-engine"};
 733                         }
 734                 elsif ($1 eq "zlib-dynamic")
 735                         {
 736                         delete $disabled{"zlib"};
 737                         }
 738                 my $algo = $1;
 739                 delete $disabled{$algo};
 740
 741                 # No longer an automatic choice
 742                 $auto_threads = 0 if ($1 eq "threads");
 743                 }
 744         elsif (/^--strict-warnings$/)
 745                 {
 746                 $strict_warnings = 1;
 747                 }
 748         elsif (/^--debug$/)
 749                 {
 750                 $config{build_type} = "debug";
 751                 }
 752         elsif (/^--release$/)
 753                 {
 754                 $config{build_type} = "release";
 755                 }
 756         elsif (/^386$/)
 757                 { $config{processor}=386; }
 758         elsif (/^fips$/)
 759                 {
 760                 die "FIPS mode not supported\n";
 761                 }
 762         elsif (/^rsaref$/)
 763                 {
 764                 # No RSAref support any more since it's not needed.
 765                 # The check for the option is there so scripts aren't
 766                 # broken
 767                 }
 768         elsif (/^nofipscanistercheck$/)
 769                 {
 770                 die "FIPS mode not supported\n";
 771                 }
 772         elsif (/^[-+]/)
 773                 {
 774                 if (/^--prefix=(.*)$/)
 775                         {
 776                         $config{prefix}=$1;
 777                         die "Directory given with --prefix MUST be absolute\n"
 778                                 unless file_name_is_absolute($config{prefix});
 779                         }
 780                 elsif (/^--api=(.*)$/)
 781                         {
 782                         $config{api}=$1;
 783                         }
 784                 elsif (/^--libdir=(.*)$/)
 785                         {
 786                         $config{libdir}=$1;
 787                         }
 788                 elsif (/^--openssldir=(.*)$/)
 789                         {
 790                         $config{openssldir}=$1;
 791                         }
 792                 elsif (/^--with-zlib-lib=(.*)$/)
 793                         {
 794                         $withargs{zlib_lib}=$1;
 795                         }
 796                 elsif (/^--with-zlib-include=(.*)$/)
 797                         {
 798                         $withargs{zlib_include}=$1;
 799                         }
 800                 elsif (/^--with-fuzzer-lib=(.*)$/)
 801                         {
 802                         $withargs{fuzzer_lib}=$1;
 803                         }
 804                 elsif (/^--with-fuzzer-include=(.*)$/)
 805                         {
 806                         $withargs{fuzzer_include}=$1;
 807                         }
 808                 elsif (/^--with-rand-seed=(.*)$/)
 809                         {
 810                         foreach my $x (split(m|,|, $1))
 811                             {
 812                             die "Unknown --with-rand-seed choice $x\n"
 813                                 if ! grep { $x eq $_ } @known_seed_sources;
 814                             push @seed_sources, $x;
 815                             }
 816                         }
 817                 elsif (/^--cross-compile-prefix=(.*)$/)
 818                         {
 819                         $user{CROSS_COMPILE}=$1;
 820                         }
 821                 elsif (/^--config=(.*)$/)
 822                         {
 823                         read_config $1;
 824                         }
 825                 elsif (/^-L(.*)$/)
 826                         {
 827                         push @{$useradd{LDFLAGS}}, $_;
 828                         }
 829                 elsif (/^-l(.*)$/ or /^-Wl,/)
 830                         {
 831                         push @{$useradd{LDLIBS}}, $_;
 832                         }
 833                 elsif (/^-framework$/)
 834                         {
 835                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 836                         }
 837                 elsif (/^-rpath$/ or /^-R$/)
 838                         # -rpath is the OSF1 rpath flag
 839                         # -R is the old Solaris rpath flag
 840                         {
 841                         my $rpath = shift(@argvcopy) || "";
 842                         $rpath .= " " if $rpath ne "";
 843                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 844                         }
 845                 elsif (/^-static$/)
 846                         {
 847                         push @{$useradd{LDFLAGS}}, $_;
 848                         $disabled{"dso"} = "forced";
 849                         $disabled{"pic"} = "forced";
 850                         $disabled{"shared"} = "forced";
 851                         $disabled{"threads"} = "forced";
 852                         }
 853                 elsif (/^-D(.*)$/)
 854                         {
 855                         push @{$useradd{CPPDEFINES}}, $1;
 856                         }
 857                 elsif (/^-I(.*)$/)
 858                         {
 859                         push @{$useradd{CPPINCLUDES}}, $1;
 860                         }
 861                 elsif (/^-Wp,$/)
 862                         {
 863                         push @{$useradd{CPPFLAGS}}, $1;
 864                         }
 865                 else    # common if (/^[-+]/), just pass down...
 866                         {
 867                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 868                         push @{$useradd{CFLAGS}}, $_;
 869                         push @{$useradd{CXXFLAGS}}, $_;
 870                         }
 871                 }
 872         else
 873                 {
 874                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 875                 $target=$_;
 876                 }
 877         unless ($_ eq $target || /^no-/ || /^disable-/)
 878                 {
 879                 # "no-..." follows later after implied deactivations
 880                 # have been derived.  (Don't take this too seriously,
 881                 # we really only write OPTIONS to the Makefile out of
 882                 # nostalgia.)
 883
 884                 if ($config{options} eq "")
 885                         { $config{options} = $_; }
 886                 else
 887                         { $config{options} .= " ".$_; }
 888                 }
 889
 890         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 891                 die "***** Unsupported api compatibility level: $config{api}\n",
 892         }
 893
 894         if (keys %deprecated_options)
 895                 {
 896                 warn "***** Deprecated options: ",
 897                         join(", ", keys %deprecated_options), "\n";
 898                 }
 899         if (keys %unsupported_options)
 900                 {
 901                 die "***** Unsupported options: ",
 902                         join(", ", keys %unsupported_options), "\n";
 903                 }
 904         }
 905
 906 # If any %useradd entry has been set, we must check that the "make
 907 # variables" haven't been set.  We start by checking of any %useradd entry
 908 # is set.
 909 if (grep { scalar @$_ > 0 } values %useradd) {
 910     # Hash of env / make variables names.  The possible values are:
 911     # 1 - "make vars"
 912     # 2 - %useradd entry set
 913     # 3 - both set
 914     my %detected_vars =
 915         map { my $v = 0;
 916               $v += 1 if $cmdvars{$_};
 917               $v += 2 if @{$useradd{$_}};
 918               $_ => $v }
 919         keys %useradd;
 920
 921     # If any of the corresponding "make variables" is set, we error
 922     if (grep { $_ & 1 } values %detected_vars) {
 923         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 924                                sort keys %detected_vars);
 925         die <<"_____";
 926 ***** Mixing make variables and additional compiler/linker flags as
 927 ***** configure command line option is not permitted.
 928 ***** Affected make variables: $names
 929 _____
 930     }
 931 }
 932
 933 # Check through all supported command line variables to see if any of them
 934 # were set, and canonicalise the values we got.  If no compiler or linker
 935 # flag or anything else that affects %useradd was set, we also check the
 936 # environment for values.
 937 my $anyuseradd =
 938     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 939 foreach (keys %user) {
 940     my $value = $cmdvars{$_};
 941     $value //= env($_) unless $anyuseradd;
 942     $value //=
 943         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 944     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 945         unless $anyuseradd;
 946
 947     if (defined $value) {
 948         if (ref $user{$_} eq 'ARRAY') {
 949             $user{$_} = [ split /$list_separator_re/, $value ];
 950         } elsif (!defined $user{$_}) {
 951             $user{$_} = $value;
 952         }
 953     }
 954 }
 955
 956 if (grep { $_ =~ /(^|\s)-Wl,-rpath,/ } ($user{LDLIBS} ? @{$user{LDLIBS}} : ())
 957     && !$disabled{shared}
 958     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 959     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 960         "***** any of asan, msan or ubsan\n";
 961 }
 962
 963 my @tocheckfor = (keys %disabled);
 964 while (@tocheckfor) {
 965     my %new_tocheckfor = ();
 966     my @cascade_copy = (@disable_cascades);
 967     while (@cascade_copy) {
 968         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 969         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 970             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 971                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 972             }
 973         }
 974     }
 975     @tocheckfor = (keys %new_tocheckfor);
 976 }
 977
 978 our $die = sub { die @_; };
 979 if ($target eq "TABLE") {
 980     local $die = sub { warn @_; };
 981     foreach (sort keys %table) {
 982         print_table_entry($_, "TABLE");
 983     }
 984     exit 0;
 985 }
 986
 987 if ($target eq "LIST") {
 988     foreach (sort keys %table) {
 989         print $_,"\n" unless $table{$_}->{template};
 990     }
 991     exit 0;
 992 }
 993
 994 if ($target eq "HASH") {
 995     local $die = sub { warn @_; };
 996     print "%table = (\n";
 997     foreach (sort keys %table) {
 998         print_table_entry($_, "HASH");
 999     }
1000     exit 0;
1001 }
1002
1003 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
1004 print "for $target\n";
1005
1006 if (scalar(@seed_sources) == 0) {
1007     print "Using os-specific seed configuration\n";
1008     push @seed_sources, 'os';
1009 }
1010 die "Cannot seed with none and anything else"
1011     if scalar(grep { $_ eq 'none' } @seed_sources) > 0
1012         && scalar(@seed_sources) > 1;
1013 push @{$config{openssl_other_defines}},
1014      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1015         @seed_sources;
1016
1017 # Backward compatibility?
1018 if ($target =~ m/^CygWin32(-.*)$/) {
1019     $target = "Cygwin".$1;
1020 }
1021
1022 # Support for legacy targets having a name starting with 'debug-'
1023 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1024 if ($d) {
1025     $config{build_type} = "debug";
1026
1027     # If we do not find debug-foo in the table, the target is set to foo.
1028     if (!$table{$target}) {
1029         $target = $t;
1030     }
1031 }
1032 $config{target} = $target;
1033 my %target = resolve_config($target);
1034
1035 &usage if (!%target || $target{template});
1036
1037 foreach (keys %target_attr_translate) {
1038     $target{$target_attr_translate{$_}} = $target{$_}
1039         if $target{$_};
1040     delete $target{$_};
1041 }
1042
1043 %target = ( %{$table{DEFAULTS}}, %target );
1044
1045 # Make the flags to build DSOs the same as for shared libraries unless they
1046 # are already defined
1047 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1048 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1049 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1050 {
1051     my $shared_info_pl =
1052         catfile(dirname($0), "Configurations", "shared-info.pl");
1053     my %shared_info = read_eval_file($shared_info_pl);
1054     push @{$target{_conf_fname_int}}, $shared_info_pl;
1055     my $si = $target{shared_target};
1056     while (ref $si ne "HASH") {
1057         last if ! defined $si;
1058         if (ref $si eq "CODE") {
1059             $si = $si->();
1060         } else {
1061             $si = $shared_info{$si};
1062         }
1063     }
1064
1065     # Some of the 'shared_target' values don't have any entried in
1066     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1067     # template knows how to handle this.  That is currently the case for
1068     # Windows and VMS.
1069     if (defined $si) {
1070         # Just as above, copy certain shared_* attributes to the corresponding
1071         # module_ attribute unless the latter is already defined
1072         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1073         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1074         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1075         foreach (sort keys %$si) {
1076             $target{$_} = defined $target{$_}
1077                 ? add($si->{$_})->($target{$_})
1078                 : $si->{$_};
1079         }
1080     }
1081 }
1082
1083 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1084 $config{conf_files} = [ sort keys %conf_files ];
1085
1086 foreach my $feature (@{$target{disable}}) {
1087     if (exists $deprecated_disablables{$feature}) {
1088         warn "***** config $target disables deprecated feature $feature\n";
1089     } elsif (!grep { $feature eq $_ } @disablables) {
1090         die "***** config $target disables unknown feature $feature\n";
1091     }
1092     $disabled{$feature} = 'config';
1093 }
1094 foreach my $feature (@{$target{enable}}) {
1095     if ("default" eq ($disabled{$_} // "")) {
1096         if (exists $deprecated_disablables{$feature}) {
1097             warn "***** config $target enables deprecated feature $feature\n";
1098         } elsif (!grep { $feature eq $_ } @disablables) {
1099             die "***** config $target enables unknown feature $feature\n";
1100         }
1101         delete $disabled{$_};
1102     }
1103 }
1104
1105 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1106 $target{cxxflags}//=$target{cflags} if $target{CXX};
1107 $target{exe_extension}="";
1108 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1109                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1110 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1111
1112 ($target{shared_extension_simple}=$target{shared_extension})
1113     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||;
1114 $target{dso_extension}=$target{shared_extension_simple};
1115 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1116     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1117
1118 # Allow overriding the names of some tools.  USE WITH CARE
1119 # Note: only Unix cares about HASHBANGPERL...  that explains
1120 # the default string.
1121 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
1122 foreach (keys %user) {
1123     my $ref_type = ref $user{$_};
1124
1125     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1126     # and a value that's to be coerced into that type.
1127     my $mkvalue = sub {
1128         my $type = shift;
1129         my $value = shift;
1130         my $undef_p = shift;
1131
1132         die "Too many arguments for \$mkvalue" if @_;
1133
1134         while (ref $value eq 'CODE') {
1135             $value = $value->();
1136         }
1137
1138         if ($type eq 'ARRAY') {
1139             return undef unless defined $value;
1140             return undef if ref $value ne 'ARRAY' && !$value;
1141             return undef if ref $value eq 'ARRAY' && !@$value;
1142             return [ $value ] unless ref $value eq 'ARRAY';
1143         }
1144         return undef unless $value;
1145         return $value;
1146     };
1147
1148     $config{$_} =
1149         $mkvalue->($ref_type, $user{$_})
1150         || $mkvalue->($ref_type, $target{$_});
1151     delete $config{$_} unless defined $config{$_};
1152 }
1153
1154 # Allow overriding the build file name
1155 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1156
1157 my %disabled_info = ();         # For configdata.pm
1158 foreach my $what (sort keys %disabled) {
1159     $config{options} .= " no-$what";
1160
1161     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1162                                 'dynamic-engine', 'makedepend',
1163                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1164         (my $WHAT = uc $what) =~ s|-|_|g;
1165
1166         # Fix up C macro end names
1167         $WHAT = "RMD160" if $what eq "ripemd";
1168
1169         # fix-up crypto/directory name(s)
1170         $what = "ripemd" if $what eq "rmd160";
1171         $what = "whrlpool" if $what eq "whirlpool";
1172
1173         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1174
1175         if ((grep { $what eq $_ } @{$config{sdirs}})
1176                 && $what ne 'async' && $what ne 'err') {
1177             @{$config{sdirs}} = grep { $what ne $_} @{$config{sdirs}};
1178             $disabled_info{$what}->{skipped} = [ catdir('crypto', $what) ];
1179
1180             if ($what ne 'engine') {
1181                 push @{$config{openssl_algorithm_defines}}, $macro;
1182             } else {
1183                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
1184                 push @{$disabled_info{engine}->{skipped}}, catdir('engines');
1185                 push @{$config{openssl_other_defines}}, $macro;
1186             }
1187         } else {
1188             push @{$config{openssl_other_defines}}, $macro;
1189         }
1190
1191     }
1192 }
1193
1194 # Make sure build_scheme is consistent.
1195 $target{build_scheme} = [ $target{build_scheme} ]
1196     if ref($target{build_scheme}) ne "ARRAY";
1197
1198 my ($builder, $builder_platform, @builder_opts) =
1199     @{$target{build_scheme}};
1200
1201 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1202                       $builder_platform."-checker.pm")) {
1203     my $checker_path = catfile($srcdir, "Configurations", $checker);
1204     if (-f $checker_path) {
1205         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1206             ? sub { warn $@; } : sub { die $@; };
1207         if (! do $checker_path) {
1208             if ($@) {
1209                 $fn->($@);
1210             } elsif ($!) {
1211                 $fn->($!);
1212             } else {
1213                 $fn->("The detected tools didn't match the platform\n");
1214             }
1215         }
1216         last;
1217     }
1218 }
1219
1220 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1221
1222 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1223         {
1224         push @{$config{cflags}}, "-mno-cygwin";
1225         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1226         push @{$config{shared_ldflag}}, "-mno-cygwin";
1227         }
1228
1229 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1230         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1231                                             @{$useradd{CFLAGS}})) {
1232         # minimally required architecture flags for assembly modules
1233         my $value;
1234         $value = '-mips2' if ($target =~ /mips32/);
1235         $value = '-mips3' if ($target =~ /mips64/);
1236         unshift @{$config{cflags}}, $value;
1237         unshift @{$config{cxxflags}}, $value if $config{CXX};
1238 }
1239
1240 # If threads aren't disabled, check how possible they are
1241 unless ($disabled{threads}) {
1242     if ($auto_threads) {
1243         # Enabled by default, disable it forcibly if unavailable
1244         if ($target{thread_scheme} eq "(unknown)") {
1245             $disabled{threads} = "unavailable";
1246         }
1247     } else {
1248         # The user chose to enable threads explicitly, let's see
1249         # if there's a chance that's possible
1250         if ($target{thread_scheme} eq "(unknown)") {
1251             # If the user asked for "threads" and we don't have internal
1252             # knowledge how to do it, [s]he is expected to provide any
1253             # system-dependent compiler options that are necessary.  We
1254             # can't truly check that the given options are correct, but
1255             # we expect the user to know what [s]He is doing.
1256             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1257                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1258                 die "You asked for multi-threading support, but didn't\n"
1259                     ,"provide any system-specific compiler options\n";
1260             }
1261         }
1262     }
1263 }
1264
1265 # If threads still aren't disabled, add a C macro to ensure the source
1266 # code knows about it.  Any other flag is taken care of by the configs.
1267 unless($disabled{threads}) {
1268     push @{$config{openssl_thread_defines}}, "OPENSSL_THREADS";
1269 }
1270
1271 # With "deprecated" disable all deprecated features.
1272 if (defined($disabled{"deprecated"})) {
1273         $config{api} = $maxapi;
1274 }
1275
1276 my $no_shared_warn=0;
1277 if ($target{shared_target} eq "")
1278         {
1279         $no_shared_warn = 1
1280             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1281         $disabled{shared} = "no-shared-target";
1282         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1283             "no-shared-target";
1284         }
1285
1286 if ($disabled{"dynamic-engine"}) {
1287         push @{$config{openssl_other_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1288         $config{dynamic_engines} = 0;
1289 } else {
1290         push @{$config{openssl_other_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1291         $config{dynamic_engines} = 1;
1292 }
1293
1294 unless ($disabled{asan}) {
1295     push @{$config{cflags}}, "-fsanitize=address";
1296     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1297 }
1298
1299 unless ($disabled{ubsan}) {
1300     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1301     # platforms.
1302     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1303     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1304         if $config{CXX};
1305 }
1306
1307 unless ($disabled{msan}) {
1308   push @{$config{cflags}}, "-fsanitize=memory";
1309   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1310 }
1311
1312 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1313         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1314     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1315     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1316 }
1317 #
1318 # Platform fix-ups
1319 #
1320
1321 # This saves the build files from having to check
1322 if ($disabled{pic})
1323         {
1324         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1325                     shared_defines shared_includes shared_ldflag
1326                     module_cflags module_cxxflags module_cppflags
1327                     module_defines module_includes module_lflags))
1328                 {
1329                 delete $config{$_};
1330                 $target{$_} = "";
1331                 }
1332         }
1333 else
1334         {
1335         push @{$config{lib_defines}}, "OPENSSL_PIC";
1336         }
1337
1338 if ($target{sys_id} ne "")
1339         {
1340         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1341         }
1342
1343 unless ($disabled{asm}) {
1344     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1345     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1346
1347     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1348
1349     # bn-586 is the only one implementing bn_*_part_words
1350     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1351     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1352
1353     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1354     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1355     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1356
1357     if ($target{sha1_asm_src}) {
1358         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1359         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1360         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1361     }
1362     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1363         push @{$config{lib_defines}}, "RC4_ASM";
1364     }
1365     if ($target{md5_asm_src}) {
1366         push @{$config{lib_defines}}, "MD5_ASM";
1367     }
1368     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1369     if ($target{rmd160_asm_src}) {
1370         push @{$config{lib_defines}}, "RMD160_ASM";
1371     }
1372     if ($target{aes_asm_src}) {
1373         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1374         # aes-ctr.fake is not a real file, only indication that assembler
1375         # module implements AES_ctr32_encrypt...
1376         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1377         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1378         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1379         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1380         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1381         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1382     }
1383     if ($target{wp_asm_src} =~ /mmx/) {
1384         if ($config{processor} eq "386") {
1385             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1386         } elsif (!$disabled{"whirlpool"}) {
1387             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1388         }
1389     }
1390     if ($target{modes_asm_src} =~ /ghash-/) {
1391         push @{$config{lib_defines}}, "GHASH_ASM";
1392     }
1393     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1394         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1395     }
1396     if ($target{ec_asm_src} =~ /x25519/) {
1397         push @{$config{lib_defines}}, "X25519_ASM";
1398     }
1399     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1400         push @{$config{lib_defines}}, "PADLOCK_ASM";
1401     }
1402     if ($target{poly1305_asm_src} ne "") {
1403         push @{$config{lib_defines}}, "POLY1305_ASM";
1404     }
1405 }
1406
1407 my %predefined = compiler_predefined($config{CC});
1408
1409 # Check for makedepend capabilities.
1410 if (!$disabled{makedepend}) {
1411     if ($config{target} =~ /^(VC|vms)-/) {
1412         # For VC- and vms- targets, there's nothing more to do here.  The
1413         # functionality is hard coded in the corresponding build files for
1414         # cl (Windows) and CC/DECC (VMS).
1415     } elsif ($predefined{__GNUC__} >= 3) {
1416         # We know that GNU C version 3 and up as well as all clang
1417         # versions support dependency generation
1418         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1419     } else {
1420         # In all other cases, we look for 'makedepend', and disable the
1421         # capability if not found.
1422         $config{makedepprog} = which('makedepend');
1423         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1424     }
1425 }
1426
1427
1428 # Deal with bn_ops ###################################################
1429
1430 $config{bn_ll}                  =0;
1431 $config{export_var_as_fn}       =0;
1432 my $def_int="unsigned int";
1433 $config{rc4_int}                =$def_int;
1434 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1435
1436 my $count = 0;
1437 foreach (sort split(/\s+/,$target{bn_ops})) {
1438     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1439     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1440     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1441     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1442     ($config{b64l},$config{b64},$config{b32})
1443         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1444     ($config{b64l},$config{b64},$config{b32})
1445         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1446     ($config{b64l},$config{b64},$config{b32})
1447         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1448 }
1449 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1450     if $count > 1;
1451
1452
1453 # Hack cflags for better warnings (dev option) #######################
1454
1455 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1456 # a string and works as well on command lines.
1457 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1458                         @{$config{cflags}} ];
1459 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1460                           @{$config{cxxflags}} ] if $config{CXX};
1461
1462 if (defined($config{api})) {
1463     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1464     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1465     push @{$config{defines}}, $apiflag;
1466 }
1467
1468 if (defined($predefined{__clang__}) && !$disabled{asm}) {
1469     push @{$config{cflags}}, "-Qunused-arguments";
1470     push @{$config{cxxflags}}, "-Qunused-arguments" if $config{CXX};
1471 }
1472
1473 if ($strict_warnings)
1474         {
1475         my $wopt;
1476         my $gccver = $predefined{__GNUC__} // -1;
1477
1478         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1479             unless $gccver >= 4;
1480         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1481                 {
1482                 push @{$config{cflags}}, $wopt
1483                         unless grep { $_ eq $wopt } @{$config{cflags}};
1484                 push @{$config{cxxflags}}, $wopt
1485                         if ($config{CXX}
1486                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1487                 }
1488         if (defined($predefined{__clang__}))
1489                 {
1490                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1491                         {
1492                         push @{$config{cflags}}, $wopt
1493                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1494                         push @{$config{cxxflags}}, $wopt
1495                                 if ($config{CXX}
1496                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1497                         }
1498                 }
1499         }
1500
1501 unless ($disabled{"crypto-mdebug-backtrace"})
1502         {
1503         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1504                 {
1505                 push @{$config{cflags}}, $wopt
1506                         unless grep { $_ eq $wopt } @{$config{cflags}};
1507                 push @{$config{cxxflags}}, $wopt
1508                         if ($config{CXX}
1509                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1510                 }
1511         if ($target =~ /^BSD-/)
1512                 {
1513                 push @{$config{ex_libs}}, "-lexecinfo";
1514                 }
1515         }
1516
1517 unless ($disabled{afalgeng}) {
1518     $config{afalgeng}="";
1519     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1520         my $minver = 4*10000 + 1*100 + 0;
1521         if ($config{CROSS_COMPILE} eq "") {
1522             my $verstr = `uname -r`;
1523             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1524             ($mi2) = $mi2 =~ /(\d+)/;
1525             my $ver = $ma*10000 + $mi1*100 + $mi2;
1526             if ($ver < $minver) {
1527                 $disabled{afalgeng} = "too-old-kernel";
1528             } else {
1529                 push @{$config{engdirs}}, "afalg";
1530             }
1531         } else {
1532             $disabled{afalgeng} = "cross-compiling";
1533         }
1534     } else {
1535         $disabled{afalgeng}  = "not-linux";
1536     }
1537 }
1538
1539 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1540
1541 # Finish up %config by appending things the user gave us on the command line
1542 # apart from "make variables"
1543 foreach (keys %useradd) {
1544     # The must all be lists, so we assert that here
1545     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1546         unless ref $useradd{$_} eq 'ARRAY';
1547
1548     if (defined $config{$_}) {
1549         push @{$config{$_}}, @{$useradd{$_}};
1550     } else {
1551         $config{$_} = [ @{$useradd{$_}} ];
1552     }
1553 }
1554
1555 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1556
1557 # If we use the unified build, collect information from build.info files
1558 my %unified_info = ();
1559
1560 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1561 if ($builder eq "unified") {
1562     use with_fallback qw(Text::Template);
1563
1564     sub cleandir {
1565         my $base = shift;
1566         my $dir = shift;
1567         my $relativeto = shift || ".";
1568
1569         $dir = catdir($base,$dir) unless isabsolute($dir);
1570
1571         # Make sure the directories we're building in exists
1572         mkpath($dir);
1573
1574         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1575         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1576         return $res;
1577     }
1578
1579     sub cleanfile {
1580         my $base = shift;
1581         my $file = shift;
1582         my $relativeto = shift || ".";
1583
1584         $file = catfile($base,$file) unless isabsolute($file);
1585
1586         my $d = dirname($file);
1587         my $f = basename($file);
1588
1589         # Make sure the directories we're building in exists
1590         mkpath($d);
1591
1592         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1593         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1594         return $res;
1595     }
1596
1597     # Store the name of the template file we will build the build file from
1598     # in %config.  This may be useful for the build file itself.
1599     my @build_file_template_names =
1600         ( $builder_platform."-".$target{build_file}.".tmpl",
1601           $target{build_file}.".tmpl" );
1602     my @build_file_templates = ();
1603
1604     # First, look in the user provided directory, if given
1605     if (defined env($local_config_envname)) {
1606         @build_file_templates =
1607             map {
1608                 if ($^O eq 'VMS') {
1609                     # VMS environment variables are logical names,
1610                     # which can be used as is
1611                     $local_config_envname . ':' . $_;
1612                 } else {
1613                     catfile(env($local_config_envname), $_);
1614                 }
1615             }
1616             @build_file_template_names;
1617     }
1618     # Then, look in our standard directory
1619     push @build_file_templates,
1620         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1621           @build_file_template_names );
1622
1623     my $build_file_template;
1624     for $_ (@build_file_templates) {
1625         $build_file_template = $_;
1626         last if -f $build_file_template;
1627
1628         $build_file_template = undef;
1629     }
1630     if (!defined $build_file_template) {
1631         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1632     }
1633     $config{build_file_templates}
1634       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1635                     $blddir),
1636           $build_file_template,
1637           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1638                     $blddir) ];
1639
1640     my @build_infos = ( [ ".", "build.info" ] );
1641     foreach (@{$config{dirs}}) {
1642         push @build_infos, [ $_, "build.info" ]
1643             if (-f catfile($srcdir, $_, "build.info"));
1644     }
1645     foreach (@{$config{sdirs}}) {
1646         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1647             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1648     }
1649     foreach (@{$config{engdirs}}) {
1650         push @build_infos, [ catdir("engines", $_), "build.info" ]
1651             if (-f catfile($srcdir, "engines", $_, "build.info"));
1652     }
1653     foreach (@{$config{tdirs}}) {
1654         push @build_infos, [ catdir("test", $_), "build.info" ]
1655             if (-f catfile($srcdir, "test", $_, "build.info"));
1656     }
1657
1658     $config{build_infos} = [ ];
1659
1660     my %ordinals = ();
1661     foreach (@build_infos) {
1662         my $sourced = catdir($srcdir, $_->[0]);
1663         my $buildd = catdir($blddir, $_->[0]);
1664
1665         mkpath($buildd);
1666
1667         my $f = $_->[1];
1668         # The basic things we're trying to build
1669         my @programs = ();
1670         my @programs_install = ();
1671         my @libraries = ();
1672         my @libraries_install = ();
1673         my @engines = ();
1674         my @engines_install = ();
1675         my @scripts = ();
1676         my @scripts_install = ();
1677         my @extra = ();
1678         my @overrides = ();
1679         my @intermediates = ();
1680         my @rawlines = ();
1681
1682         my %sources = ();
1683         my %shared_sources = ();
1684         my %includes = ();
1685         my %depends = ();
1686         my %renames = ();
1687         my %sharednames = ();
1688         my %generate = ();
1689
1690         # We want to detect configdata.pm in the source tree, so we
1691         # don't use it if the build tree is different.
1692         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1693
1694         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1695         my $template =
1696             Text::Template->new(TYPE => 'FILE',
1697                                 SOURCE => catfile($sourced, $f),
1698                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1699         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1700         my @text =
1701             split /^/m,
1702             $template->fill_in(HASH => { config => \%config,
1703                                          target => \%target,
1704                                          disabled => \%disabled,
1705                                          withargs => \%withargs,
1706                                          builddir => abs2rel($buildd, $blddir),
1707                                          sourcedir => abs2rel($sourced, $blddir),
1708                                          buildtop => abs2rel($blddir, $blddir),
1709                                          sourcetop => abs2rel($srcdir, $blddir) },
1710                                DELIMITERS => [ "{-", "-}" ]);
1711
1712         # The top item of this stack has the following values
1713         # -2 positive already run and we found ELSE (following ELSIF should fail)
1714         # -1 positive already run (skip until ENDIF)
1715         # 0 negatives so far (if we're at a condition, check it)
1716         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1717         # 2 positive ELSE (following ELSIF should fail)
1718         my @skip = ();
1719         collect_information(
1720             collect_from_array([ @text ],
1721                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1722                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1723             # Info we're looking for
1724             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1725             => sub {
1726                 if (! @skip || $skip[$#skip] > 0) {
1727                     push @skip, !! $1;
1728                 } else {
1729                     push @skip, -1;
1730                 }
1731             },
1732             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1733             => sub { die "ELSIF out of scope" if ! @skip;
1734                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1735                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1736                      $skip[$#skip] = !! $1
1737                          if $skip[$#skip] == 0; },
1738             qr/^\s*ELSE\s*$/
1739             => sub { die "ELSE out of scope" if ! @skip;
1740                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1741                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1742             qr/^\s*ENDIF\s*$/
1743             => sub { die "ENDIF out of scope" if ! @skip;
1744                      pop @skip; },
1745             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1746             => sub {
1747                 if (!@skip || $skip[$#skip] > 0) {
1748                     my $install = $1;
1749                     my @x = tokenize($2);
1750                     push @programs, @x;
1751                     push @programs_install, @x unless $install;
1752                 }
1753             },
1754             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1755             => sub {
1756                 if (!@skip || $skip[$#skip] > 0) {
1757                     my $install = $1;
1758                     my @x = tokenize($2);
1759                     push @libraries, @x;
1760                     push @libraries_install, @x unless $install;
1761                 }
1762             },
1763             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1764             => sub {
1765                 if (!@skip || $skip[$#skip] > 0) {
1766                     my $install = $1;
1767                     my @x = tokenize($2);
1768                     push @engines, @x;
1769                     push @engines_install, @x unless $install;
1770                 }
1771             },
1772             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1773             => sub {
1774                 if (!@skip || $skip[$#skip] > 0) {
1775                     my $install = $1;
1776                     my @x = tokenize($2);
1777                     push @scripts, @x;
1778                     push @scripts_install, @x unless $install;
1779                 }
1780             },
1781             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1782             => sub { push @extra, tokenize($1)
1783                          if !@skip || $skip[$#skip] > 0 },
1784             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1785             => sub { push @overrides, tokenize($1)
1786                          if !@skip || $skip[$#skip] > 0 },
1787
1788             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1789             => sub { push @{$ordinals{$1}}, tokenize($2)
1790                          if !@skip || $skip[$#skip] > 0 },
1791             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1792             => sub { push @{$sources{$1}}, tokenize($2)
1793                          if !@skip || $skip[$#skip] > 0 },
1794             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1795             => sub { push @{$shared_sources{$1}}, tokenize($2)
1796                          if !@skip || $skip[$#skip] > 0 },
1797             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1798             => sub { push @{$includes{$1}}, tokenize($2)
1799                          if !@skip || $skip[$#skip] > 0 },
1800             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1801             => sub { push @{$depends{$1}}, tokenize($2)
1802                          if !@skip || $skip[$#skip] > 0 },
1803             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1804             => sub { push @{$generate{$1}}, $2
1805                          if !@skip || $skip[$#skip] > 0 },
1806             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1807             => sub { push @{$renames{$1}}, tokenize($2)
1808                          if !@skip || $skip[$#skip] > 0 },
1809             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1810             => sub { push @{$sharednames{$1}}, tokenize($2)
1811                          if !@skip || $skip[$#skip] > 0 },
1812             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1813             => sub {
1814                 my $lineiterator = shift;
1815                 my $target_kind = $1;
1816                 while (defined $lineiterator->()) {
1817                     s|\R$||;
1818                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1819                         die "ENDRAW doesn't match BEGINRAW"
1820                             if $1 ne $target_kind;
1821                         last;
1822                     }
1823                     next if @skip && $skip[$#skip] <= 0;
1824                     push @rawlines,  $_
1825                         if ($target_kind eq $target{build_file}
1826                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1827                 }
1828             },
1829             qr/^\s*(?:#.*)?$/ => sub { },
1830             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1831             "BEFORE" => sub {
1832                 if ($buildinfo_debug) {
1833                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1834                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1835                 }
1836             },
1837             "AFTER" => sub {
1838                 if ($buildinfo_debug) {
1839                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1840                 }
1841             },
1842             );
1843         die "runaway IF?" if (@skip);
1844
1845         foreach (keys %renames) {
1846             die "$_ renamed to more than one thing: "
1847                 ,join(" ", @{$renames{$_}}),"\n"
1848                 if scalar @{$renames{$_}} > 1;
1849             my $dest = cleanfile($buildd, $_, $blddir);
1850             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1851             die "$dest renamed to more than one thing: "
1852                 ,$unified_info{rename}->{$dest}, $to
1853                 unless !defined($unified_info{rename}->{$dest})
1854                 or $unified_info{rename}->{$dest} eq $to;
1855             $unified_info{rename}->{$dest} = $to;
1856         }
1857
1858         foreach (@programs) {
1859             my $program = cleanfile($buildd, $_, $blddir);
1860             if ($unified_info{rename}->{$program}) {
1861                 $program = $unified_info{rename}->{$program};
1862             }
1863             $unified_info{programs}->{$program} = 1;
1864         }
1865
1866         foreach (@programs_install) {
1867             my $program = cleanfile($buildd, $_, $blddir);
1868             if ($unified_info{rename}->{$program}) {
1869                 $program = $unified_info{rename}->{$program};
1870             }
1871             $unified_info{install}->{programs}->{$program} = 1;
1872         }
1873
1874         foreach (@libraries) {
1875             my $library = cleanfile($buildd, $_, $blddir);
1876             if ($unified_info{rename}->{$library}) {
1877                 $library = $unified_info{rename}->{$library};
1878             }
1879             $unified_info{libraries}->{$library} = 1;
1880         }
1881
1882         foreach (@libraries_install) {
1883             my $library = cleanfile($buildd, $_, $blddir);
1884             if ($unified_info{rename}->{$library}) {
1885                 $library = $unified_info{rename}->{$library};
1886             }
1887             $unified_info{install}->{libraries}->{$library} = 1;
1888         }
1889
1890         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1891 ENGINES can only be used if configured with 'dynamic-engine'.
1892 This is usually a fault in a build.info file.
1893 EOF
1894         foreach (@engines) {
1895             my $library = cleanfile($buildd, $_, $blddir);
1896             if ($unified_info{rename}->{$library}) {
1897                 $library = $unified_info{rename}->{$library};
1898             }
1899             $unified_info{engines}->{$library} = 1;
1900         }
1901
1902         foreach (@engines_install) {
1903             my $library = cleanfile($buildd, $_, $blddir);
1904             if ($unified_info{rename}->{$library}) {
1905                 $library = $unified_info{rename}->{$library};
1906             }
1907             $unified_info{install}->{engines}->{$library} = 1;
1908         }
1909
1910         foreach (@scripts) {
1911             my $script = cleanfile($buildd, $_, $blddir);
1912             if ($unified_info{rename}->{$script}) {
1913                 $script = $unified_info{rename}->{$script};
1914             }
1915             $unified_info{scripts}->{$script} = 1;
1916         }
1917
1918         foreach (@scripts_install) {
1919             my $script = cleanfile($buildd, $_, $blddir);
1920             if ($unified_info{rename}->{$script}) {
1921                 $script = $unified_info{rename}->{$script};
1922             }
1923             $unified_info{install}->{scripts}->{$script} = 1;
1924         }
1925
1926         foreach (@extra) {
1927             my $extra = cleanfile($buildd, $_, $blddir);
1928             $unified_info{extra}->{$extra} = 1;
1929         }
1930
1931         foreach (@overrides) {
1932             my $override = cleanfile($buildd, $_, $blddir);
1933             $unified_info{overrides}->{$override} = 1;
1934         }
1935
1936         push @{$unified_info{rawlines}}, @rawlines;
1937
1938         unless ($disabled{shared}) {
1939             # Check sharednames.
1940             foreach (keys %sharednames) {
1941                 my $dest = cleanfile($buildd, $_, $blddir);
1942                 if ($unified_info{rename}->{$dest}) {
1943                     $dest = $unified_info{rename}->{$dest};
1944                 }
1945                 die "shared_name for $dest with multiple values: "
1946                     ,join(" ", @{$sharednames{$_}}),"\n"
1947                     if scalar @{$sharednames{$_}} > 1;
1948                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1949                 die "shared_name found for a library $dest that isn't defined\n"
1950                     unless $unified_info{libraries}->{$dest};
1951                 die "shared_name for $dest with multiple values: "
1952                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1953                     unless !defined($unified_info{sharednames}->{$dest})
1954                     or $unified_info{sharednames}->{$dest} eq $to;
1955                 $unified_info{sharednames}->{$dest} = $to;
1956             }
1957
1958             # Additionally, we set up sharednames for libraries that don't
1959             # have any, as themselves.  Only for libraries that aren't
1960             # explicitly static.
1961             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1962                 if (!defined $unified_info{sharednames}->{$_}) {
1963                     $unified_info{sharednames}->{$_} = $_
1964                 }
1965             }
1966
1967             # Check that we haven't defined any library as both shared and
1968             # explicitly static.  That is forbidden.
1969             my @doubles = ();
1970             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1971                 (my $l = $_) =~ s/\.a$//;
1972                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1973             }
1974             die "these libraries are both explicitly static and shared:\n  ",
1975                 join(" ", @doubles), "\n"
1976                 if @doubles;
1977         }
1978
1979         foreach (keys %sources) {
1980             my $dest = $_;
1981             my $ddest = cleanfile($buildd, $_, $blddir);
1982             if ($unified_info{rename}->{$ddest}) {
1983                 $ddest = $unified_info{rename}->{$ddest};
1984             }
1985             foreach (@{$sources{$dest}}) {
1986                 my $s = cleanfile($sourced, $_, $blddir);
1987
1988                 # If it isn't in the source tree, we assume it's generated
1989                 # in the build tree
1990                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1991                     $s = cleanfile($buildd, $_, $blddir);
1992                 }
1993                 # We recognise C++, C and asm files
1994                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1995                     my $o = $_;
1996                     $o =~ s/\.[csS]$/.o/; # C and assembler
1997                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1998                     $o = cleanfile($buildd, $o, $blddir);
1999                     $unified_info{sources}->{$ddest}->{$o} = 1;
2000                     $unified_info{sources}->{$o}->{$s} = 1;
2001                 } elsif ($s =~ /\.rc$/) {
2002                     # We also recognise resource files
2003                     my $o = $_;
2004                     $o =~ s/\.rc$/.res/; # Resource configuration
2005                     my $o = cleanfile($buildd, $o, $blddir);
2006                     $unified_info{sources}->{$ddest}->{$o} = 1;
2007                     $unified_info{sources}->{$o}->{$s} = 1;
2008                 } else {
2009                     $unified_info{sources}->{$ddest}->{$s} = 1;
2010                 }
2011             }
2012         }
2013
2014         foreach (keys %shared_sources) {
2015             my $dest = $_;
2016             my $ddest = cleanfile($buildd, $_, $blddir);
2017             if ($unified_info{rename}->{$ddest}) {
2018                 $ddest = $unified_info{rename}->{$ddest};
2019             }
2020             foreach (@{$shared_sources{$dest}}) {
2021                 my $s = cleanfile($sourced, $_, $blddir);
2022
2023                 # If it isn't in the source tree, we assume it's generated
2024                 # in the build tree
2025                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2026                     $s = cleanfile($buildd, $_, $blddir);
2027                 }
2028
2029                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2030                     # We recognise C++, C and asm files
2031                     my $o = $_;
2032                     $o =~ s/\.[csS]$/.o/; # C and assembler
2033                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2034                     $o = cleanfile($buildd, $o, $blddir);
2035                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2036                     $unified_info{sources}->{$o}->{$s} = 1;
2037                 } elsif ($s =~ /\.rc$/) {
2038                     # We also recognise resource files
2039                     my $o = $_;
2040                     $o =~ s/\.rc$/.res/; # Resource configuration
2041                     my $o = cleanfile($buildd, $o, $blddir);
2042                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2043                     $unified_info{sources}->{$o}->{$s} = 1;
2044                 } elsif ($s =~ /\.(def|map|opt)$/) {
2045                     # We also recognise .def / .map / .opt files
2046                     # We know they are generated files
2047                     my $def = cleanfile($buildd, $s, $blddir);
2048                     $unified_info{shared_sources}->{$ddest}->{$def} = 1;
2049                 } else {
2050                     die "unrecognised source file type for shared library: $s\n";
2051                 }
2052             }
2053         }
2054
2055         foreach (keys %generate) {
2056             my $dest = $_;
2057             my $ddest = cleanfile($buildd, $_, $blddir);
2058             if ($unified_info{rename}->{$ddest}) {
2059                 $ddest = $unified_info{rename}->{$ddest};
2060             }
2061             die "more than one generator for $dest: "
2062                     ,join(" ", @{$generate{$_}}),"\n"
2063                     if scalar @{$generate{$_}} > 1;
2064             my @generator = split /\s+/, $generate{$dest}->[0];
2065             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2066             $unified_info{generate}->{$ddest} = [ @generator ];
2067         }
2068
2069         foreach (keys %depends) {
2070             my $dest = $_;
2071             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2072
2073             # If the destination doesn't exist in source, it can only be
2074             # a generated file in the build tree.
2075             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2076                 $ddest = cleanfile($buildd, $_, $blddir);
2077                 if ($unified_info{rename}->{$ddest}) {
2078                     $ddest = $unified_info{rename}->{$ddest};
2079                 }
2080             }
2081             foreach (@{$depends{$dest}}) {
2082                 my $d = cleanfile($sourced, $_, $blddir);
2083
2084                 # If we know it's generated, or assume it is because we can't
2085                 # find it in the source tree, we set file we depend on to be
2086                 # in the build tree rather than the source tree, and assume
2087                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2088                 # section or in the Makefile template.
2089                 if ($d eq $src_configdata
2090                     || ! -f $d
2091                     || (grep { $d eq $_ }
2092                         map { cleanfile($srcdir, $_, $blddir) }
2093                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2094                     $d = cleanfile($buildd, $_, $blddir);
2095                 }
2096                 # Take note if the file to depend on is being renamed
2097                 # Take extra care with files ending with .a, they should
2098                 # be treated without that extension, and the extension
2099                 # should be added back after treatment.
2100                 $d =~ /(\.a)?$/;
2101                 my $e = $1 // "";
2102                 $d = $`;
2103                 if ($unified_info{rename}->{$d}) {
2104                     $d = $unified_info{rename}->{$d};
2105                 }
2106                 $d .= $e;
2107                 $unified_info{depends}->{$ddest}->{$d} = 1;
2108             }
2109         }
2110
2111         foreach (keys %includes) {
2112             my $dest = $_;
2113             my $ddest = cleanfile($sourced, $_, $blddir);
2114
2115             # If the destination doesn't exist in source, it can only be
2116             # a generated file in the build tree.
2117             if ($ddest eq $src_configdata || ! -f $ddest) {
2118                 $ddest = cleanfile($buildd, $_, $blddir);
2119                 if ($unified_info{rename}->{$ddest}) {
2120                     $ddest = $unified_info{rename}->{$ddest};
2121                 }
2122             }
2123             foreach (@{$includes{$dest}}) {
2124                 my $is = cleandir($sourced, $_, $blddir);
2125                 my $ib = cleandir($buildd, $_, $blddir);
2126                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2127                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2128                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2129                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2130             }
2131         }
2132     }
2133
2134     my $ordinals_text = join(', ', sort keys %ordinals);
2135     warn <<"EOF" if $ordinals_text;
2136
2137 WARNING: ORDINALS were specified for $ordinals_text
2138 They are ignored and should be replaced with a combination of GENERATE,
2139 DEPEND and SHARED_SOURCE.
2140 EOF
2141
2142     # Massage the result
2143
2144     # If we depend on a header file or a perl module, add an inclusion of
2145     # its directory to allow smoothe inclusion
2146     foreach my $dest (keys %{$unified_info{depends}}) {
2147         next if $dest eq "";
2148         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2149             next unless $d =~ /\.(h|pm)$/;
2150             my $i = dirname($d);
2151             my $spot =
2152                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2153                 ? 'build' : 'source';
2154             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2155                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2156         }
2157     }
2158
2159     # Trickle down includes placed on libraries, engines and programs to
2160     # their sources (i.e. object files)
2161     foreach my $dest (keys %{$unified_info{engines}},
2162                       keys %{$unified_info{libraries}},
2163                       keys %{$unified_info{programs}}) {
2164         foreach my $k (("source", "build")) {
2165             next unless defined($unified_info{includes}->{$dest}->{$k});
2166             my @incs = reverse @{$unified_info{includes}->{$dest}->{$k}};
2167             foreach my $obj (grep /\.o$/,
2168                              (keys %{$unified_info{sources}->{$dest}},
2169                               keys %{$unified_info{shared_sources}->{$dest}})) {
2170                 foreach my $inc (@incs) {
2171                     unshift @{$unified_info{includes}->{$obj}->{$k}}, $inc
2172                         unless grep { $_ eq $inc } @{$unified_info{includes}->{$obj}->{$k}};
2173                 }
2174             }
2175         }
2176         delete $unified_info{includes}->{$dest};
2177     }
2178
2179     ### Make unified_info a bit more efficient
2180     # One level structures
2181     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2182         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2183     }
2184     # Two level structures
2185     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2186         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2187             $unified_info{$l1}->{$l2} =
2188                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
2189         }
2190     }
2191     # Includes
2192     foreach my $dest (sort keys %{$unified_info{includes}}) {
2193         if (defined($unified_info{includes}->{$dest}->{build})) {
2194             my @source_includes = ();
2195             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2196                 if defined($unified_info{includes}->{$dest}->{source});
2197             $unified_info{includes}->{$dest} =
2198                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2199             foreach my $inc (@source_includes) {
2200                 push @{$unified_info{includes}->{$dest}}, $inc
2201                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2202             }
2203         } else {
2204             $unified_info{includes}->{$dest} =
2205                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2206         }
2207     }
2208 }
2209
2210 # For the schemes that need it, we provide the old *_obj configs
2211 # from the *_asm_obj ones
2212 foreach (grep /_(asm|aux)_src$/, keys %target) {
2213     my $src = $_;
2214     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2215     $target{$obj} = $target{$src};
2216     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2217     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2218 }
2219
2220 # Write down our configuration where it fits #########################
2221
2222 print "Creating configdata.pm\n";
2223 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2224 print OUT <<"EOF";
2225 #! $config{HASHBANGPERL}
2226
2227 package configdata;
2228
2229 use strict;
2230 use warnings;
2231
2232 use Exporter;
2233 #use vars qw(\@ISA \@EXPORT);
2234 our \@ISA = qw(Exporter);
2235 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2236
2237 EOF
2238 print OUT "our %config = (\n";
2239 foreach (sort keys %config) {
2240     if (ref($config{$_}) eq "ARRAY") {
2241         print OUT "  ", $_, " => [ ", join(", ",
2242                                            map { quotify("perl", $_) }
2243                                            @{$config{$_}}), " ],\n";
2244     } elsif (ref($config{$_}) eq "HASH") {
2245         print OUT "  ", $_, " => {";
2246         if (scalar keys %{$config{$_}} > 0) {
2247             print OUT "\n";
2248             foreach my $key (sort keys %{$config{$_}}) {
2249                 print OUT "      ",
2250                     join(" => ",
2251                          quotify("perl", $key),
2252                          defined $config{$_}->{$key}
2253                              ? quotify("perl", $config{$_}->{$key})
2254                              : "undef");
2255                 print OUT ",\n";
2256             }
2257             print OUT "  ";
2258         }
2259         print OUT "},\n";
2260     } else {
2261         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2262     }
2263 }
2264 print OUT <<"EOF";
2265 );
2266
2267 EOF
2268 print OUT "our %target = (\n";
2269 foreach (sort keys %target) {
2270     if (ref($target{$_}) eq "ARRAY") {
2271         print OUT "  ", $_, " => [ ", join(", ",
2272                                            map { quotify("perl", $_) }
2273                                            @{$target{$_}}), " ],\n";
2274     } else {
2275         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2276     }
2277 }
2278 print OUT <<"EOF";
2279 );
2280
2281 EOF
2282 print OUT "our \%available_protocols = (\n";
2283 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2284 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2285 print OUT <<"EOF";
2286 );
2287
2288 EOF
2289 print OUT "our \@disablables = (\n";
2290 foreach (@disablables) {
2291     print OUT "  ", quotify("perl", $_), ",\n";
2292 }
2293 print OUT <<"EOF";
2294 );
2295
2296 EOF
2297 print OUT "our \%disabled = (\n";
2298 foreach (sort keys %disabled) {
2299     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2300 }
2301 print OUT <<"EOF";
2302 );
2303
2304 EOF
2305 print OUT "our %withargs = (\n";
2306 foreach (sort keys %withargs) {
2307     if (ref($withargs{$_}) eq "ARRAY") {
2308         print OUT "  ", $_, " => [ ", join(", ",
2309                                            map { quotify("perl", $_) }
2310                                            @{$withargs{$_}}), " ],\n";
2311     } else {
2312         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2313     }
2314 }
2315 print OUT <<"EOF";
2316 );
2317
2318 EOF
2319 if ($builder eq "unified") {
2320     my $recurse;
2321     $recurse = sub {
2322         my $indent = shift;
2323         foreach (@_) {
2324             if (ref $_ eq "ARRAY") {
2325                 print OUT " "x$indent, "[\n";
2326                 foreach (@$_) {
2327                     $recurse->($indent + 4, $_);
2328                 }
2329                 print OUT " "x$indent, "],\n";
2330             } elsif (ref $_ eq "HASH") {
2331                 my %h = %$_;
2332                 print OUT " "x$indent, "{\n";
2333                 foreach (sort keys %h) {
2334                     if (ref $h{$_} eq "") {
2335                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2336                     } else {
2337                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2338                         $recurse->($indent + 8, $h{$_});
2339                     }
2340                 }
2341                 print OUT " "x$indent, "},\n";
2342             } else {
2343                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2344             }
2345         }
2346     };
2347     print OUT "our %unified_info = (\n";
2348     foreach (sort keys %unified_info) {
2349         if (ref $unified_info{$_} eq "") {
2350             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2351         } else {
2352             print OUT " "x4, quotify("perl", $_), " =>\n";
2353             $recurse->(8, $unified_info{$_});
2354         }
2355     }
2356     print OUT <<"EOF";
2357 );
2358
2359 EOF
2360 }
2361 print OUT
2362     "# The following data is only used when this files is use as a script\n";
2363 print OUT "my \@makevars = (\n";
2364 foreach (sort keys %user) {
2365     print OUT "    '",$_,"',\n";
2366 }
2367 print OUT ");\n";
2368 print OUT "my \%disabled_info = (\n";
2369 foreach my $what (sort keys %disabled_info) {
2370     print OUT "    '$what' => {\n";
2371     foreach my $info (sort keys %{$disabled_info{$what}}) {
2372         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2373             print OUT "        $info => [ ",
2374                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2375                 " ],\n";
2376         } else {
2377             print OUT "        $info => '", $disabled_info{$what}->{$info},
2378                 "',\n";
2379         }
2380     }
2381     print OUT "    },\n";
2382 }
2383 print OUT ");\n";
2384 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2385 print OUT << 'EOF';
2386 # If run directly, we can give some answers, and even reconfigure
2387 unless (caller) {
2388     use Getopt::Long;
2389     use File::Spec::Functions;
2390     use File::Basename;
2391     use Pod::Usage;
2392
2393     my $here = dirname($0);
2394
2395     my $dump = undef;
2396     my $cmdline = undef;
2397     my $options = undef;
2398     my $target = undef;
2399     my $envvars = undef;
2400     my $makevars = undef;
2401     my $buildparams = undef;
2402     my $reconf = undef;
2403     my $verbose = undef;
2404     my $help = undef;
2405     my $man = undef;
2406     GetOptions('dump|d'                 => \$dump,
2407                'command-line|c'         => \$cmdline,
2408                'options|o'              => \$options,
2409                'target|t'               => \$target,
2410                'environment|e'          => \$envvars,
2411                'make-variables|m'       => \$makevars,
2412                'build-parameters|b'     => \$buildparams,
2413                'reconfigure|reconf|r'   => \$reconf,
2414                'verbose|v'              => \$verbose,
2415                'help'                   => \$help,
2416                'man'                    => \$man)
2417         or die "Errors in command line arguments\n";
2418
2419     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2420             || $buildparams || $reconf || $verbose || $help || $man) {
2421         print STDERR <<"_____";
2422 You must give at least one option.
2423 For more information, do '$0 --help'
2424 _____
2425         exit(2);
2426     }
2427
2428     if ($help) {
2429         pod2usage(-exitval => 0,
2430                   -verbose => 1);
2431     }
2432     if ($man) {
2433         pod2usage(-exitval => 0,
2434                   -verbose => 2);
2435     }
2436     if ($dump || $cmdline) {
2437         print "\nCommand line (with current working directory = $here):\n\n";
2438         print '    ',join(' ',
2439                           $config{perl},
2440                           catfile($config{sourcedir}, 'Configure'),
2441                           @{$config{perlargv}}), "\n";
2442         print "\nPerl information:\n\n";
2443         print '    ',$config{perl_cmd},"\n";
2444         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2445     }
2446     if ($dump || $options) {
2447         my $longest = 0;
2448         my $longest2 = 0;
2449         foreach my $what (@disablables) {
2450             $longest = length($what) if $longest < length($what);
2451             $longest2 = length($disabled{$what})
2452                 if $disabled{$what} && $longest2 < length($disabled{$what});
2453         }
2454         print "\nEnabled features:\n\n";
2455         foreach my $what (@disablables) {
2456             print "    $what\n" unless $disabled{$what};
2457         }
2458         print "\nDisabled features:\n\n";
2459         foreach my $what (@disablables) {
2460             if ($disabled{$what}) {
2461                 print "    $what", ' ' x ($longest - length($what) + 1),
2462                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2463                 print $disabled_info{$what}->{macro}
2464                     if $disabled_info{$what}->{macro};
2465                 print ' (skip ',
2466                     join(', ', @{$disabled_info{$what}->{skipped}}),
2467                     ')'
2468                     if $disabled_info{$what}->{skipped};
2469                 print "\n";
2470             }
2471         }
2472     }
2473     if ($dump || $target) {
2474         print "\nConfig target attributes:\n\n";
2475         foreach (sort keys %target) {
2476             next if $_ =~ m|^_| || $_ eq 'template';
2477             my $quotify = sub {
2478                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2479             };
2480             print '    ', $_, ' => ';
2481             if (ref($target{$_}) eq "ARRAY") {
2482                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2483             } else {
2484                 print $quotify->($target{$_}), ",\n"
2485             }
2486         }
2487     }
2488     if ($dump || $envvars) {
2489         print "\nRecorded environment:\n\n";
2490         foreach (sort keys %{$config{perlenv}}) {
2491             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2492         }
2493     }
2494     if ($dump || $makevars) {
2495         print "\nMakevars:\n\n";
2496         foreach my $var (@makevars) {
2497             my $prefix = '';
2498             $prefix = $config{CROSS_COMPILE}
2499                 if grep { $var eq $_ } @user_crossable;
2500             $prefix //= '';
2501             print '    ',$var,' ' x (16 - length $var),'= ',
2502                 (ref $config{$var} eq 'ARRAY'
2503                  ? join(' ', @{$config{$var}})
2504                  : $prefix.$config{$var}),
2505                 "\n"
2506                 if defined $config{$var};
2507         }
2508
2509         my @buildfile = ($config{builddir}, $config{build_file});
2510         unshift @buildfile, $here
2511             unless file_name_is_absolute($config{builddir});
2512         my $buildfile = canonpath(catdir(@buildfile));
2513         print <<"_____";
2514
2515 NOTE: These variables only represent the configuration view.  The build file
2516 template may have processed these variables further, please have a look at the
2517 build file for more exact data:
2518     $buildfile
2519 _____
2520     }
2521     if ($dump || $buildparams) {
2522         my @buildfile = ($config{builddir}, $config{build_file});
2523         unshift @buildfile, $here
2524             unless file_name_is_absolute($config{builddir});
2525         print "\nbuild file:\n\n";
2526         print "    ", canonpath(catfile(@buildfile)),"\n";
2527
2528         print "\nbuild file templates:\n\n";
2529         foreach (@{$config{build_file_templates}}) {
2530             my @tmpl = ($_);
2531             unshift @tmpl, $here
2532                 unless file_name_is_absolute($config{sourcedir});
2533             print '    ',canonpath(catfile(@tmpl)),"\n";
2534         }
2535     }
2536     if ($reconf) {
2537         if ($verbose) {
2538             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2539             foreach (sort keys %{$config{perlenv}}) {
2540                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2541             }
2542         }
2543
2544         chdir $here;
2545         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2546     }
2547 }
2548
2549 1;
2550
2551 __END__
2552
2553 =head1 NAME
2554
2555 configdata.pm - configuration data for OpenSSL builds
2556
2557 =head1 SYNOPSIS
2558
2559 Interactive:
2560
2561   perl configdata.pm [options]
2562
2563 As data bank module:
2564
2565   use configdata;
2566
2567 =head1 DESCRIPTION
2568
2569 This module can be used in two modes, interactively and as a module containing
2570 all the data recorded by OpenSSL's Configure script.
2571
2572 When used interactively, simply run it as any perl script, with at least one
2573 option, and you will get the information you ask for.  See L</OPTIONS> below.
2574
2575 When loaded as a module, you get a few databanks with useful information to
2576 perform build related tasks.  The databanks are:
2577
2578     %config             Configured things.
2579     %target             The OpenSSL config target with all inheritances
2580                         resolved.
2581     %disabled           The features that are disabled.
2582     @disablables        The list of features that can be disabled.
2583     %withargs           All data given through --with-THING options.
2584     %unified_info       All information that was computed from the build.info
2585                         files.
2586
2587 =head1 OPTIONS
2588
2589 =over 4
2590
2591 =item B<--help>
2592
2593 Print a brief help message and exit.
2594
2595 =item B<--man>
2596
2597 Print the manual page and exit.
2598
2599 =item B<--dump> | B<-d>
2600
2601 Print all relevant configuration data.  This is equivalent to B<--command-line>
2602 B<--options> B<--target> B<--environment> B<--make-variables>
2603 B<--build-parameters>.
2604
2605 =item B<--command-line> | B<-c>
2606
2607 Print the current configuration command line.
2608
2609 =item B<--options> | B<-o>
2610
2611 Print the features, both enabled and disabled, and display defined macro and
2612 skipped directories where applicable.
2613
2614 =item B<--target> | B<-t>
2615
2616 Print the config attributes for this config target.
2617
2618 =item B<--environment> | B<-e>
2619
2620 Print the environment variables and their values at the time of configuration.
2621
2622 =item B<--make-variables> | B<-m>
2623
2624 Print the main make variables generated in the current configuration
2625
2626 =item B<--build-parameters> | B<-b>
2627
2628 Print the build parameters, i.e. build file and build file templates.
2629
2630 =item B<--reconfigure> | B<--reconf> | B<-r>
2631
2632 Redo the configuration.
2633
2634 =item B<--verbose> | B<-v>
2635
2636 Verbose output.
2637
2638 =back
2639
2640 =cut
2641
2642 EOF
2643 close(OUT);
2644 if ($builder_platform eq 'unix') {
2645     my $mode = (0755 & ~umask);
2646     chmod $mode, 'configdata.pm'
2647         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2648 }
2649
2650 my %builders = (
2651     unified => sub {
2652         print 'Creating ',$target{build_file},"\n";
2653         run_dofile(catfile($blddir, $target{build_file}),
2654                    @{$config{build_file_templates}});
2655     },
2656     );
2657
2658 $builders{$builder}->($builder_platform, @builder_opts);
2659
2660 print <<"EOF" if ($disabled{threads} eq "unavailable");
2661
2662 The library could not be configured for supporting multi-threaded
2663 applications as the compiler options required on this system are not known.
2664 See file INSTALL for details if you need multi-threading.
2665 EOF
2666
2667 print <<"EOF" if ($no_shared_warn);
2668
2669 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2670 platform, so we will pretend you gave the option 'no-pic', which also disables
2671 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2672 or position independent code, please let us know (but please first make sure
2673 you have tried with a current version of OpenSSL).
2674 EOF
2675
2676 print <<"EOF";
2677
2678 **********************************************************************
2679 ***                                                                ***
2680 ***   If you want to report a building issue, please include the   ***
2681 ***   output from this command:                                    ***
2682 ***                                                                ***
2683 ***     perl configdata.pm --dump                                  ***
2684 ***                                                                ***
2685 **********************************************************************
2686 EOF
2687
2688 exit(0);
2689
2690 ######################################################################
2691 #
2692 # Helpers and utility functions
2693 #
2694
2695 # Configuration file reading #########################################
2696
2697 # Note: All of the helper functions are for lazy evaluation.  They all
2698 # return a CODE ref, which will return the intended value when evaluated.
2699 # Thus, whenever there's mention of a returned value, it's about that
2700 # intended value.
2701
2702 # Helper function to implement conditional inheritance depending on the
2703 # value of $disabled{asm}.  Used in inherit_from values as follows:
2704 #
2705 #      inherit_from => [ "template", asm("asm_tmpl") ]
2706 #
2707 sub asm {
2708     my @x = @_;
2709     sub {
2710         $disabled{asm} ? () : @x;
2711     }
2712 }
2713
2714 # Helper function to implement conditional value variants, with a default
2715 # plus additional values based on the value of $config{build_type}.
2716 # Arguments are given in hash table form:
2717 #
2718 #       picker(default => "Basic string: ",
2719 #              debug   => "debug",
2720 #              release => "release")
2721 #
2722 # When configuring with --debug, the resulting string will be
2723 # "Basic string: debug", and when not, it will be "Basic string: release"
2724 #
2725 # This can be used to create variants of sets of flags according to the
2726 # build type:
2727 #
2728 #       cflags => picker(default => "-Wall",
2729 #                        debug   => "-g -O0",
2730 #                        release => "-O3")
2731 #
2732 sub picker {
2733     my %opts = @_;
2734     return sub { add($opts{default} || (),
2735                      $opts{$config{build_type}} || ())->(); }
2736 }
2737
2738 # Helper function to combine several values of different types into one.
2739 # This is useful if you want to combine a string with the result of a
2740 # lazy function, such as:
2741 #
2742 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2743 #
2744 sub combine {
2745     my @stuff = @_;
2746     return sub { add(@stuff)->(); }
2747 }
2748
2749 # Helper function to implement conditional values depending on the value
2750 # of $disabled{threads}.  Can be used as follows:
2751 #
2752 #       cflags => combine("-Wall", threads("-pthread"))
2753 #
2754 sub threads {
2755     my @flags = @_;
2756     return sub { add($disabled{threads} ? () : @flags)->(); }
2757 }
2758
2759
2760
2761 our $add_called = 0;
2762 # Helper function to implement adding values to already existing configuration
2763 # values.  It handles elements that are ARRAYs, CODEs and scalars
2764 sub _add {
2765     my $separator = shift;
2766
2767     # If there's any ARRAY in the collection of values OR the separator
2768     # is undef, we will return an ARRAY of combined values, otherwise a
2769     # string of joined values with $separator as the separator.
2770     my $found_array = !defined($separator);
2771
2772     my @values =
2773         map {
2774             my $res = $_;
2775             while (ref($res) eq "CODE") {
2776                 $res = $res->();
2777             }
2778             if (defined($res)) {
2779                 if (ref($res) eq "ARRAY") {
2780                     $found_array = 1;
2781                     @$res;
2782                 } else {
2783                     $res;
2784                 }
2785             } else {
2786                 ();
2787             }
2788     } (@_);
2789
2790     $add_called = 1;
2791
2792     if ($found_array) {
2793         [ @values ];
2794     } else {
2795         join($separator, grep { defined($_) && $_ ne "" } @values);
2796     }
2797 }
2798 sub add_before {
2799     my $separator = " ";
2800     if (ref($_[$#_]) eq "HASH") {
2801         my $opts = pop;
2802         $separator = $opts->{separator};
2803     }
2804     my @x = @_;
2805     sub { _add($separator, @x, @_) };
2806 }
2807 sub add {
2808     my $separator = " ";
2809     if (ref($_[$#_]) eq "HASH") {
2810         my $opts = pop;
2811         $separator = $opts->{separator};
2812     }
2813     my @x = @_;
2814     sub { _add($separator, @_, @x) };
2815 }
2816
2817 sub read_eval_file {
2818     my $fname = shift;
2819     my $content;
2820     my @result;
2821
2822     open F, "< $fname" or die "Can't open '$fname': $!\n";
2823     {
2824         undef local $/;
2825         $content = <F>;
2826     }
2827     close F;
2828     {
2829         local $@;
2830
2831         @result = ( eval $content );
2832         warn $@ if $@;
2833     }
2834     return wantarray ? @result : $result[0];
2835 }
2836
2837 # configuration reader, evaluates the input file as a perl script and expects
2838 # it to fill %targets with target configurations.  Those are then added to
2839 # %table.
2840 sub read_config {
2841     my $fname = shift;
2842     my %targets;
2843
2844     {
2845         # Protect certain tables from tampering
2846         local %table = ();
2847
2848         %targets = read_eval_file($fname);
2849     }
2850     my %preexisting = ();
2851     foreach (sort keys %targets) {
2852         $preexisting{$_} = 1 if $table{$_};
2853     }
2854     die <<"EOF",
2855 The following config targets from $fname
2856 shadow pre-existing config targets with the same name:
2857 EOF
2858         map { "  $_\n" } sort keys %preexisting
2859         if %preexisting;
2860
2861
2862     # For each target, check that it's configured with a hash table.
2863     foreach (keys %targets) {
2864         if (ref($targets{$_}) ne "HASH") {
2865             if (ref($targets{$_}) eq "") {
2866                 warn "Deprecated target configuration for $_, ignoring...\n";
2867             } else {
2868                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2869             }
2870             delete $targets{$_};
2871         } else {
2872             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2873         }
2874     }
2875
2876     %table = (%table, %targets);
2877
2878 }
2879
2880 # configuration resolver.  Will only resolve all the lazy evaluation
2881 # codeblocks for the chosen target and all those it inherits from,
2882 # recursively
2883 sub resolve_config {
2884     my $target = shift;
2885     my @breadcrumbs = @_;
2886
2887 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2888
2889     if (grep { $_ eq $target } @breadcrumbs) {
2890         die "inherit_from loop!  target backtrace:\n  "
2891             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2892     }
2893
2894     if (!defined($table{$target})) {
2895         warn "Warning! target $target doesn't exist!\n";
2896         return ();
2897     }
2898     # Recurse through all inheritances.  They will be resolved on the
2899     # fly, so when this operation is done, they will all just be a
2900     # bunch of attributes with string values.
2901     # What we get here, though, are keys with references to lists of
2902     # the combined values of them all.  We will deal with lists after
2903     # this stage is done.
2904     my %combined_inheritance = ();
2905     if ($table{$target}->{inherit_from}) {
2906         my @inherit_from =
2907             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2908         foreach (@inherit_from) {
2909             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2910
2911             # 'template' is a marker that's considered private to
2912             # the config that had it.
2913             delete $inherited_config{template};
2914
2915             foreach (keys %inherited_config) {
2916                 if (!$combined_inheritance{$_}) {
2917                     $combined_inheritance{$_} = [];
2918                 }
2919                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2920             }
2921         }
2922     }
2923
2924     # We won't need inherit_from in this target any more, since we've
2925     # resolved all the inheritances that lead to this
2926     delete $table{$target}->{inherit_from};
2927
2928     # Now is the time to deal with those lists.  Here's the place to
2929     # decide what shall be done with those lists, all based on the
2930     # values of the target we're currently dealing with.
2931     # - If a value is a coderef, it will be executed with the list of
2932     #   inherited values as arguments.
2933     # - If the corresponding key doesn't have a value at all or is the
2934     #   empty string, the inherited value list will be run through the
2935     #   default combiner (below), and the result becomes this target's
2936     #   value.
2937     # - Otherwise, this target's value is assumed to be a string that
2938     #   will simply override the inherited list of values.
2939     my $default_combiner = add();
2940
2941     my %all_keys =
2942         map { $_ => 1 } (keys %combined_inheritance,
2943                          keys %{$table{$target}});
2944
2945     sub process_values {
2946         my $object    = shift;
2947         my $inherited = shift;  # Always a [ list ]
2948         my $target    = shift;
2949         my $entry     = shift;
2950
2951         $add_called = 0;
2952
2953         while(ref($object) eq "CODE") {
2954             $object = $object->(@$inherited);
2955         }
2956         if (!defined($object)) {
2957             return ();
2958         }
2959         elsif (ref($object) eq "ARRAY") {
2960             local $add_called;  # To make sure recursive calls don't affect it
2961             return [ map { process_values($_, $inherited, $target, $entry) }
2962                      @$object ];
2963         } elsif (ref($object) eq "") {
2964             return $object;
2965         } else {
2966             die "cannot handle reference type ",ref($object)
2967                 ," found in target ",$target," -> ",$entry,"\n";
2968         }
2969     }
2970
2971     foreach (sort keys %all_keys) {
2972         my $previous = $combined_inheritance{$_};
2973
2974         # Current target doesn't have a value for the current key?
2975         # Assign it the default combiner, the rest of this loop body
2976         # will handle it just like any other coderef.
2977         if (!exists $table{$target}->{$_}) {
2978             $table{$target}->{$_} = $default_combiner;
2979         }
2980
2981         $table{$target}->{$_} = process_values($table{$target}->{$_},
2982                                                $combined_inheritance{$_},
2983                                                $target, $_);
2984         unless(defined($table{$target}->{$_})) {
2985             delete $table{$target}->{$_};
2986         }
2987 #        if ($extra_checks &&
2988 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2989 #            warn "$_ got replaced in $target\n";
2990 #        }
2991     }
2992
2993     # Finally done, return the result.
2994     return %{$table{$target}};
2995 }
2996
2997 sub usage
2998         {
2999         print STDERR $usage;
3000         print STDERR "\npick os/compiler from:\n";
3001         my $j=0;
3002         my $i;
3003         my $k=0;
3004         foreach $i (sort keys %table)
3005                 {
3006                 next if $table{$i}->{template};
3007                 next if $i =~ /^debug/;
3008                 $k += length($i) + 1;
3009                 if ($k > 78)
3010                         {
3011                         print STDERR "\n";
3012                         $k=length($i);
3013                         }
3014                 print STDERR $i . " ";
3015                 }
3016         foreach $i (sort keys %table)
3017                 {
3018                 next if $table{$i}->{template};
3019                 next if $i !~ /^debug/;
3020                 $k += length($i) + 1;
3021                 if ($k > 78)
3022                         {
3023                         print STDERR "\n";
3024                         $k=length($i);
3025                         }
3026                 print STDERR $i . " ";
3027                 }
3028         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3029         exit(1);
3030         }
3031
3032 sub run_dofile
3033 {
3034     my $out = shift;
3035     my @templates = @_;
3036
3037     unlink $out || warn "Can't remove $out, $!"
3038         if -f $out;
3039     foreach (@templates) {
3040         die "Can't open $_, $!" unless -f $_;
3041     }
3042     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
3043     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3044     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3045     system($cmd);
3046     exit 1 if $? != 0;
3047     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3048 }
3049
3050 sub compiler_predefined {
3051     state %predefined;
3052     my $default_compiler = shift;
3053
3054     return () if $^O eq 'VMS';
3055
3056     die 'compiler_predefined called without a default compiler'
3057         unless $default_compiler;
3058
3059     if (! $predefined{$default_compiler}) {
3060         my $cc = "$config{CROSS_COMPILE}$default_compiler";
3061
3062         $predefined{$default_compiler} = {};
3063
3064         # collect compiler pre-defines from gcc or gcc-alike...
3065         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3066         while (my $l = <PIPE>) {
3067             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3068             $predefined{$default_compiler}->{$1} = $2 // '';
3069         }
3070         close(PIPE);
3071     }
3072
3073     return %{$predefined{$default_compiler}};
3074 }
3075
3076 sub which
3077 {
3078     my ($name)=@_;
3079
3080     if (eval { require IPC::Cmd; 1; }) {
3081         IPC::Cmd->import();
3082         return scalar IPC::Cmd::can_run($name);
3083     } else {
3084         # if there is $directories component in splitpath,
3085         # then it's not something to test with $PATH...
3086         return $name if (File::Spec->splitpath($name))[1];
3087
3088         foreach (File::Spec->path()) {
3089             my $fullpath = catfile($_, "$name$target{exe_extension}");
3090             if (-f $fullpath and -x $fullpath) {
3091                 return $fullpath;
3092             }
3093         }
3094     }
3095 }
3096
3097 sub env
3098 {
3099     my $name = shift;
3100     my %opts = @_;
3101
3102     unless ($opts{cacheonly}) {
3103         # Note that if $ENV{$name} doesn't exist or is undefined,
3104         # $config{perlenv}->{$name} will be created with the value
3105         # undef.  This is intentional.
3106
3107         $config{perlenv}->{$name} = $ENV{$name}
3108             if ! exists $config{perlenv}->{$name};
3109     }
3110     return $config{perlenv}->{$name};
3111 }
3112
3113 # Configuration printer ##############################################
3114
3115 sub print_table_entry
3116 {
3117     local $now_printing = shift;
3118     my %target = resolve_config($now_printing);
3119     my $type = shift;
3120
3121     # Don't print the templates
3122     return if $target{template};
3123
3124     my @sequence = (
3125         "sys_id",
3126         "cpp",
3127         "cppflags",
3128         "defines",
3129         "includes",
3130         "cc",
3131         "cflags",
3132         "unistd",
3133         "ld",
3134         "lflags",
3135         "loutflag",
3136         "ex_libs",
3137         "bn_ops",
3138         "apps_aux_src",
3139         "cpuid_asm_src",
3140         "uplink_aux_src",
3141         "bn_asm_src",
3142         "ec_asm_src",
3143         "des_asm_src",
3144         "aes_asm_src",
3145         "bf_asm_src",
3146         "md5_asm_src",
3147         "cast_asm_src",
3148         "sha1_asm_src",
3149         "rc4_asm_src",
3150         "rmd160_asm_src",
3151         "rc5_asm_src",
3152         "wp_asm_src",
3153         "cmll_asm_src",
3154         "modes_asm_src",
3155         "padlock_asm_src",
3156         "chacha_asm_src",
3157         "poly1035_asm_src",
3158         "thread_scheme",
3159         "perlasm_scheme",
3160         "dso_scheme",
3161         "shared_target",
3162         "shared_cflag",
3163         "shared_defines",
3164         "shared_ldflag",
3165         "shared_rcflag",
3166         "shared_extension",
3167         "dso_extension",
3168         "obj_extension",
3169         "exe_extension",
3170         "ranlib",
3171         "ar",
3172         "arflags",
3173         "aroutflag",
3174         "rc",
3175         "rcflags",
3176         "rcoutflag",
3177         "mt",
3178         "mtflags",
3179         "mtinflag",
3180         "mtoutflag",
3181         "multilib",
3182         "build_scheme",
3183         );
3184
3185     if ($type eq "TABLE") {
3186         print "\n";
3187         print "*** $now_printing\n";
3188         foreach (@sequence) {
3189             if (ref($target{$_}) eq "ARRAY") {
3190                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3191             } else {
3192                 printf "\$%-12s = %s\n", $_, $target{$_};
3193             }
3194         }
3195     } elsif ($type eq "HASH") {
3196         my $largest =
3197             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3198         print "    '$now_printing' => {\n";
3199         foreach (@sequence) {
3200             if ($target{$_}) {
3201                 if (ref($target{$_}) eq "ARRAY") {
3202                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3203                 } else {
3204                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3205                 }
3206             }
3207         }
3208         print "    },\n";
3209     }
3210 }
3211
3212 # Utility routines ###################################################
3213
3214 # On VMS, if the given file is a logical name, File::Spec::Functions
3215 # will consider it an absolute path.  There are cases when we want a
3216 # purely syntactic check without checking the environment.
3217 sub isabsolute {
3218     my $file = shift;
3219
3220     # On non-platforms, we just use file_name_is_absolute().
3221     return file_name_is_absolute($file) unless $^O eq "VMS";
3222
3223     # If the file spec includes a device or a directory spec,
3224     # file_name_is_absolute() is perfectly safe.
3225     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3226
3227     # Here, we know the given file spec isn't absolute
3228     return 0;
3229 }
3230
3231 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3232 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3233 # realpath() requires that at least all path components except the last is an
3234 # existing directory.  On VMS, the last component of the directory spec must
3235 # exist.
3236 sub absolutedir {
3237     my $dir = shift;
3238
3239     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3240     # will return the volume name for the device, no matter what.  Also,
3241     # it will return an incorrect directory spec if the argument is a
3242     # directory that doesn't exist.
3243     if ($^O eq "VMS") {
3244         return rel2abs($dir);
3245     }
3246
3247     # We use realpath() on Unix, since no other will properly clean out
3248     # a directory spec.
3249     use Cwd qw/realpath/;
3250
3251     return realpath($dir);
3252 }
3253
3254 sub quotify {
3255     my %processors = (
3256         perl    => sub { my $x = shift;
3257                          $x =~ s/([\\\$\@"])/\\$1/g;
3258                          return '"'.$x.'"'; },
3259         maybeshell => sub { my $x = shift;
3260                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3261                             if ($x ne $y || $x =~ m|\s|) {
3262                                 return '"'.$y.'"';
3263                             } else {
3264                                 return $x;
3265                             }
3266                         },
3267         );
3268     my $for = shift;
3269     my $processor =
3270         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3271
3272     return map { $processor->($_); } @_;
3273 }
3274
3275 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3276 # $filename is a file name to read from
3277 # $line_concat_cond_re is a regexp detecting a line continuation ending
3278 # $line_concat is a CODEref that takes care of concatenating two lines
3279 sub collect_from_file {
3280     my $filename = shift;
3281     my $line_concat_cond_re = shift;
3282     my $line_concat = shift;
3283
3284     open my $fh, $filename || die "unable to read $filename: $!\n";
3285     return sub {
3286         my $saved_line = "";
3287         $_ = "";
3288         while (<$fh>) {
3289             s|\R$||;
3290             if (defined $line_concat) {
3291                 $_ = $line_concat->($saved_line, $_);
3292                 $saved_line = "";
3293             }
3294             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3295                 $saved_line = $_;
3296                 next;
3297             }
3298             return $_;
3299         }
3300         die "$filename ending with continuation line\n" if $_;
3301         close $fh;
3302         return undef;
3303     }
3304 }
3305
3306 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3307 # $array is an ARRAYref of lines
3308 # $line_concat_cond_re is a regexp detecting a line continuation ending
3309 # $line_concat is a CODEref that takes care of concatenating two lines
3310 sub collect_from_array {
3311     my $array = shift;
3312     my $line_concat_cond_re = shift;
3313     my $line_concat = shift;
3314     my @array = (@$array);
3315
3316     return sub {
3317         my $saved_line = "";
3318         $_ = "";
3319         while (defined($_ = shift @array)) {
3320             s|\R$||;
3321             if (defined $line_concat) {
3322                 $_ = $line_concat->($saved_line, $_);
3323                 $saved_line = "";
3324             }
3325             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3326                 $saved_line = $_;
3327                 next;
3328             }
3329             return $_;
3330         }
3331         die "input text ending with continuation line\n" if $_;
3332         return undef;
3333     }
3334 }
3335
3336 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3337 # $lineiterator is a CODEref that delivers one line at a time.
3338 # All following arguments are regex/CODEref pairs, where the regexp detects a
3339 # line and the CODEref does something with the result of the regexp.
3340 sub collect_information {
3341     my $lineiterator = shift;
3342     my %collectors = @_;
3343
3344     while(defined($_ = $lineiterator->())) {
3345         s|\R$||;
3346         my $found = 0;
3347         if ($collectors{"BEFORE"}) {
3348             $collectors{"BEFORE"}->($_);
3349         }
3350         foreach my $re (keys %collectors) {
3351             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3352                 $collectors{$re}->($lineiterator);
3353                 $found = 1;
3354             };
3355         }
3356         if ($collectors{"OTHERWISE"}) {
3357             $collectors{"OTHERWISE"}->($lineiterator, $_)
3358                 unless $found || !defined $collectors{"OTHERWISE"};
3359         }
3360         if ($collectors{"AFTER"}) {
3361             $collectors{"AFTER"}->($_);
3362         }
3363     }
3364 }
3365
3366 # tokenize($line)
3367 # $line is a line of text to split up into tokens
3368 # returns a list of tokens
3369 #
3370 # Tokens are divided by spaces.  If the tokens include spaces, they
3371 # have to be quoted with single or double quotes.  Double quotes
3372 # inside a double quoted token must be escaped.  Escaping is done
3373 # with backslash.
3374 # Basically, the same quoting rules apply for " and ' as in any
3375 # Unix shell.
3376 sub tokenize {
3377     my $line = my $debug_line = shift;
3378     my @result = ();
3379
3380     while ($line =~ s|^\s+||, $line ne "") {
3381         my $token = "";
3382         while ($line ne "" && $line !~ m|^\s|) {
3383             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3384                 $token .= $1;
3385                 $line = $';
3386             } elsif ($line =~ m/^'([^']*)'/) {
3387                 $token .= $1;
3388                 $line = $';
3389             } elsif ($line =~ m/^(\S+)/) {
3390                 $token .= $1;
3391                 $line = $';
3392             }
3393         }
3394         push @result, $token;
3395     }
3396
3397     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3398         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3399         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3400     }
3401     return @result;
3402 }