coverity 1462580 Improper use of negative value
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2020 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
21 use OpenSSL::Glob;
22 use OpenSSL::Template;
23
24 # see INSTALL.md for instructions.
25
26 my $orig_death_handler = $SIG{__DIE__};
27 $SIG{__DIE__} = \&death_handler;
28
29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
30
31 # Options:
32 #
33 # --config      add the given configuration file, which will be read after
34 #               any "Configurations*" files that are found in the same
35 #               directory as this script.
36 # --prefix      prefix for the OpenSSL installation, which includes the
37 #               directories bin, lib, include, share/man, share/doc/openssl
38 #               This becomes the value of INSTALLTOP in Makefile
39 #               (Default: /usr/local)
40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
41 #               If it's a relative directory, it will be added on the directory
42 #               given with --prefix.
43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
44 #               (Default: PREFIX/ssl)
45 #
46 # --cross-compile-prefix Add specified prefix to binutils components.
47 #
48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
49 #               Define the public APIs as they were for that version
50 #               including patch releases.  If 'no-deprecated' is also
51 #               given, do not compile support for interfaces deprecated
52 #               up to and including the specified OpenSSL version.
53 #
54 # no-hw-xxx     do not compile support for specific crypto hardware.
55 #               Generic OpenSSL-style methods relating to this support
56 #               are always compiled but return NULL if the hardware
57 #               support isn't compiled.
58 # no-hw         do not compile support for any crypto hardware.
59 # [no-]threads  [don't] try to create a library that is suitable for
60 #               multithreaded applications (default is "threads" if we
61 #               know how to do it)
62 # [no-]shared   [don't] try to create shared libraries when supported.
63 # [no-]pic      [don't] try to build position independent code when supported.
64 #               If disabled, it also disables shared and dynamic-engine.
65 # no-asm        do not use assembler
66 # no-egd        do not compile support for the entropy-gathering daemon APIs
67 # [no-]zlib     [don't] compile support for zlib compression.
68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
69 #               library and will be loaded in run-time by the OpenSSL library.
70 # sctp          include SCTP support
71 # no-uplink     Don't build support for UPLINK interface.
72 # enable-weak-ssl-ciphers
73 #               Enable weak ciphers that are disabled by default.
74 # 386           generate 80386 code in assembly modules
75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
76 #               mentioned '386' option implies this one
77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
79 # /<xxx>        passed through to the compiler. Unix-style options beginning
80 #               with a '-' or '+' are recognized, as well as Windows-style
81 #               options beginning with a '/'. If the option contains arguments
82 #               separated by spaces, then the URL-style notation %20 can be
83 #               used for the space character in order to avoid having to quote
84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
85 #               In fact, any ASCII character can be encoded as %xx using its
86 #               hexadecimal encoding.
87 # -static       while -static is also a pass-through compiler option (and
88 #               as such is limited to environments where it's actually
89 #               meaningful), it triggers a number configuration options,
90 #               namely no-pic, no-shared and no-threads. It is
91 #               argued that the only reason to produce statically linked
92 #               binaries (and in context it means executables linked with
93 #               -static flag, and not just executables linked with static
94 #               libcrypto.a) is to eliminate dependency on specific run-time,
95 #               a.k.a. libc version. The mentioned config options are meant
96 #               to achieve just that. Unfortunately on Linux it's impossible
97 #               to eliminate the dependency completely for openssl executable
98 #               because of getaddrinfo and gethostbyname calls, which can
99 #               invoke dynamically loadable library facility anyway to meet
100 #               the lookup requests. For this reason on Linux statically
101 #               linked openssl executable has rather debugging value than
102 #               production quality.
103 #
104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
106 # Following are set automatically by this script
107 #
108 # MD5_ASM       use some extra md5 assembler,
109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
110 # RMD160_ASM    use some extra ripemd160 assembler,
111 # SHA256_ASM    sha256_block is implemented in assembler
112 # SHA512_ASM    sha512_block is implemented in assembler
113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
114
115 # Minimum warning options... any contributions to OpenSSL should at least
116 # get past these.  Note that we only use these with C compilers, not with
117 # C++ compilers.
118
119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
120 # -DPEDANTIC complements -pedantic and is meant to mask code that
121 # is not strictly standard-compliant and/or implementation-specific,
122 # e.g. inline assembly, disregards to alignment requirements, such
123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
124 # to be used even in sanitized builds, because sanitizer too is
125 # supposed to and does take notice of non-standard behaviour. Then
126 # -pedantic with pre-C9x compiler would also complain about 'long
127 # long' not being supported. As 64-bit algorithms are common now,
128 # it grew impossible to resolve this without sizeable additional
129 # code, so we just tell compiler to be pedantic about everything
130 # but 'long long' type.
131
132 my @gcc_devteam_warn = qw(
133     -DDEBUG_UNUSED
134     -DPEDANTIC -pedantic -Wno-long-long
135     -Wall
136     -Wextra
137     -Wno-unused-parameter
138     -Wno-missing-field-initializers
139     -Wswitch
140     -Wsign-compare
141     -Wshadow
142     -Wformat
143     -Wtype-limits
144     -Wundef
145     -Werror
146     -Wmissing-prototypes
147     -Wstrict-prototypes
148 );
149
150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
151 # TODO(openssl-team): fix problems and investigate if (at least) the
152 # following warnings can also be enabled:
153 #       -Wcast-align
154 #       -Wunreachable-code -- no, too ugly/compiler-specific
155 #       -Wlanguage-extension-token -- no, we use asm()
156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
158 my @clang_devteam_warn = qw(
159     -Wno-unknown-warning-option
160     -Wswitch-default
161     -Wno-parentheses-equality
162     -Wno-language-extension-token
163     -Wno-extended-offsetof
164     -Wconditional-uninitialized
165     -Wincompatible-pointer-types-discards-qualifiers
166     -Wmissing-variable-declarations
167 );
168
169 my @cl_devteam_warn = qw(
170     /WX
171 );
172
173 my $strict_warnings = 0;
174
175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
176 # which would cover all BSD flavors. -pthread applies to them all,
177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
179 # which has to be accompanied by explicit -D_THREAD_SAFE and
180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
181 # seems to be sufficient?
182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
183
184 #
185 # API compatibility name to version number mapping.
186 #
187 my $apitable = {
188     # This table expresses when API additions or changes can occur.
189     # The numbering used changes from 3.0 and on because we updated
190     # (solidified) our version numbering scheme at that point.
191
192     # From 3.0 and on, we internalise the given version number in dedcimal
193     # as MAJOR * 10000 + MINOR * 100 + 0
194     "3.0.0" => 30000,
195     "3.0"   => 30000,
196
197     # Note that before 3.0, we didn't have the same version number scheme.
198     # Still, the numbering we use here covers what we need.
199     "1.1.1" => 10101,
200     "1.1.0" => 10100,
201     "1.0.2" => 10002,
202     "1.0.1" => 10001,
203     "1.0.0" => 10000,
204     "0.9.8" =>   908,
205 };
206
207 our %table = ();
208 our %config = ();
209 our %withargs = ();
210 our $now_printing;      # set to current entry's name in print_table_entry
211                         # (todo: right thing would be to encapsulate name
212                         # into %target [class] and make print_table_entry
213                         # a method)
214
215 # Forward declarations ###############################################
216
217 # read_config(filename)
218 #
219 # Reads a configuration file and populates %table with the contents
220 # (which the configuration file places in %targets).
221 sub read_config;
222
223 # resolve_config(target)
224 #
225 # Resolves all the late evaluations, inheritances and so on for the
226 # chosen target and any target it inherits from.
227 sub resolve_config;
228
229
230 # Information collection #############################################
231
232 # Unified build supports separate build dir
233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
236
237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
238
239 $config{sourcedir} = abs2rel($srcdir);
240 $config{builddir} = abs2rel($blddir);
241
242 # Collect reconfiguration information if needed
243 my @argvcopy=@ARGV;
244
245 if (grep /^reconf(igure)?$/, @argvcopy) {
246     die "reconfiguring with other arguments present isn't supported"
247         if scalar @argvcopy > 1;
248     if (-f "./configdata.pm") {
249         my $file = "./configdata.pm";
250         unless (my $return = do $file) {
251             die "couldn't parse $file: $@" if $@;
252             die "couldn't do $file: $!"    unless defined $return;
253             die "couldn't run $file"       unless $return;
254         }
255
256         @argvcopy = defined($configdata::config{perlargv}) ?
257             @{$configdata::config{perlargv}} : ();
258         die "Incorrect data to reconfigure, please do a normal configuration\n"
259             if (grep(/^reconf/,@argvcopy));
260         $config{perlenv} = $configdata::config{perlenv} // {};
261     } else {
262         die "Insufficient data to reconfigure, please do a normal configuration\n";
263     }
264 }
265
266 $config{perlargv} = [ @argvcopy ];
267
268 # Historical: if known directories in crypto/ have been removed, it means
269 # that those sub-systems are disabled.
270 # (the other option would be to removed them from the SUBDIRS statement in
271 # crypto/build.info)
272 # We reverse the input list for cosmetic purely reasons, to compensate that
273 # 'unshift' adds at the front of the list (i.e. in reverse input order).
274 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
275                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
276                         'rc2', 'rc4', 'rc5', 'ripemd', 'rsa', 'seed', 'sha',
277                         'sm2', 'sm3', 'sm4') ) {
278     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
279 }
280
281 # Collect version numbers
282 my %version = ();
283
284 collect_information(
285     collect_from_file(catfile($srcdir,'VERSION')),
286     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
287         sub {
288             # Only define it if there is a value at all
289             if ($2 ne '') {
290                 my $k = $1;
291                 my $v = $2;
292                 # Some values are quoted.  Trim the quotes
293                 $v = $1 if $v =~ /^"(.*)"$/;
294                 $version{uc $k} = $v;
295             }
296         },
297     "OTHERWISE" =>
298         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
299     );
300
301 $config{major} = $version{MAJOR} // 'unknown';
302 $config{minor} = $version{MINOR} // 'unknown';
303 $config{patch} = $version{PATCH} // 'unknown';
304 $config{prerelease} =
305     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
306 $config{build_metadata} =
307     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
308 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
309 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
310
311 $config{version} = "$config{major}.$config{minor}.$config{patch}";
312 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
313
314 die "erroneous version information in VERSION: ",
315     "$config{version}, $config{shlib_version}\n"
316     unless (defined $version{MAJOR}
317             && defined $version{MINOR}
318             && defined $version{PATCH}
319             && defined $version{SHLIB_VERSION});
320
321 # Collect target configurations
322
323 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
324 foreach (sort glob($pattern)) {
325     &read_config($_);
326 }
327
328 if (defined env($local_config_envname)) {
329     if ($^O eq 'VMS') {
330         # VMS environment variables are logical names,
331         # which can be used as is
332         $pattern = $local_config_envname . ':' . '*.conf';
333     } else {
334         $pattern = catfile(env($local_config_envname), '*.conf');
335     }
336
337     foreach (sort glob($pattern)) {
338         &read_config($_);
339     }
340 }
341
342 # Save away perl command information
343 $config{perl_cmd} = $^X;
344 $config{perl_version} = $Config{version};
345 $config{perl_archname} = $Config{archname};
346
347 $config{prefix}="";
348 $config{openssldir}="";
349 $config{processor}="";
350 $config{libdir}="";
351 my $auto_threads=1;    # enable threads automatically? true by default
352 my $default_ranlib;
353
354 # Known TLS and DTLS protocols
355 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
356 my @dtls = qw(dtls1 dtls1_2);
357
358 # Explicitly known options that are possible to disable.  They can
359 # be regexps, and will be used like this: /^no-${option}$/
360 # For developers: keep it sorted alphabetically
361
362 my @disablables = (
363     "afalgeng",
364     "aria",
365     "asan",
366     "asm",
367     "async",
368     "autoalginit",
369     "autoerrinit",
370     "autoload-config",
371     "bf",
372     "blake2",
373     "buildtest-c++",
374     "camellia",
375     "capieng",
376     "cast",
377     "chacha",
378     "cmac",
379     "cmp",
380     "cms",
381     "comp",
382     "crypto-mdebug",
383     "ct",
384     "deprecated",
385     "des",
386     "devcryptoeng",
387     "dgram",
388     "dh",
389     "dsa",
390     "dso",
391     "dtls",
392     "dynamic-engine",
393     "ec",
394     "ec2m",
395     "ecdh",
396     "ecdsa",
397     "ec_nistp_64_gcc_128",
398     "egd",
399     "engine",
400     "err",
401     "external-tests",
402     "filenames",
403     "fips",
404     "fuzz-libfuzzer",
405     "fuzz-afl",
406     "gost",
407     "idea",
408     "ktls",
409     "legacy",
410     "makedepend",
411     "md2",
412     "md4",
413     "mdc2",
414     "module",
415     "msan",
416     "multiblock",
417     "nextprotoneg",
418     "pinshared",
419     "ocb",
420     "ocsp",
421     "padlockeng",
422     "pic",
423     "poly1305",
424     "posix-io",
425     "psk",
426     "rc2",
427     "rc4",
428     "rc5",
429     "rdrand",
430     "rfc3779",
431     "rmd160",
432     "scrypt",
433     "sctp",
434     "secure-memory",
435     "seed",
436     "shared",
437     "siphash",
438     "siv",
439     "sm2",
440     "sm3",
441     "sm4",
442     "sock",
443     "srp",
444     "srtp",
445     "sse2",
446     "ssl",
447     "ssl-trace",
448     "static-engine",
449     "stdio",
450     "tests",
451     "threads",
452     "tls",
453     "trace",
454     "ts",
455     "ubsan",
456     "ui-console",
457     "unit-test",
458     "uplink",
459     "whirlpool",
460     "weak-ssl-ciphers",
461     "zlib",
462     "zlib-dynamic",
463     );
464 foreach my $proto ((@tls, @dtls))
465         {
466         push(@disablables, $proto);
467         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
468         }
469
470 # Internal disablables, for aliasing purposes.  They serve no special
471 # purpose here, but allow scripts to get to know them through configdata.pm,
472 # where these are merged with @disablables.
473 # The actual aliasing mechanism is done via %disable_cascades
474 my @disablables_int = qw(
475     crmf
476     );
477
478 my %deprecated_disablables = (
479     "ssl2" => undef,
480     "buf-freelists" => undef,
481     "crypto-mdebug-backtrace" => undef,
482     "hw" => "hw",               # causes cascade, but no macro
483     "hw-padlock" => "padlockeng",
484     "ripemd" => "rmd160",
485     "ui" => "ui-console",
486     "heartbeats" => undef,
487     );
488
489 # All of the following are disabled by default:
490
491 our %disabled = ( # "what"         => "comment"
492                   "asan"                => "default",
493                   "buildtest-c++"       => "default",
494                   "crypto-mdebug"       => "default",
495                   "crypto-mdebug-backtrace" => "default",
496                   "devcryptoeng"        => "default",
497                   "ec_nistp_64_gcc_128" => "default",
498                   "egd"                 => "default",
499                   "external-tests"      => "default",
500                   "fuzz-libfuzzer"      => "default",
501                   "fuzz-afl"            => "default",
502                   "md2"                 => "default",
503                   "msan"                => "default",
504                   "rc5"                 => "default",
505                   "sctp"                => "default",
506                   "ssl-trace"           => "default",
507                   "ssl3"                => "default",
508                   "ssl3-method"         => "default",
509                   "trace"               => "default",
510                   "ubsan"               => "default",
511                   "unit-test"           => "default",
512                   "weak-ssl-ciphers"    => "default",
513                   "zlib"                => "default",
514                   "zlib-dynamic"        => "default",
515                   "ktls"                => "default",
516                 );
517
518 # Note: => pair form used for aesthetics, not to truly make a hash table
519 my @disable_cascades = (
520     # "what"            => [ "cascade", ... ]
521     sub { $config{processor} eq "386" }
522                         => [ "sse2" ],
523     "ssl"               => [ "ssl3" ],
524     "ssl3-method"       => [ "ssl3" ],
525     "zlib"              => [ "zlib-dynamic" ],
526     "des"               => [ "mdc2" ],
527     "ec"                => [ "ecdsa", "ecdh", "sm2", "gost" ],
528     sub { $disabled{"ec"} && $disabled{"dh"} }
529                         => [ "tls1_3" ],
530     "dgram"             => [ "dtls", "sctp" ],
531     "sock"              => [ "dgram" ],
532     "dtls"              => [ @dtls ],
533     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
534                         => [ "dtls" ],
535
536     "tls"               => [ @tls ],
537     sub { 0 == scalar grep { !$disabled{$_} } @tls }
538                         => [ "tls" ],
539
540     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
541
542     # If no modules, then no dynamic engines either
543     "module"            => [ "dynamic-engine" ],
544
545     # Without shared libraries, dynamic engines aren't possible.
546     # This is due to them having to link with libcrypto and register features
547     # using the ENGINE functionality, and since that relies on global tables,
548     # those *have* to be exacty the same as the ones accessed from the app,
549     # which cannot be guaranteed if shared libraries aren't present.
550     # (note that even with shared libraries, both the app and dynamic engines
551     # must be linked with the same library)
552     "shared"            => [ "dynamic-engine", "uplink" ],
553     "dso"               => [ "dynamic-engine", "module" ],
554     # Other modules don't necessarily have to link with libcrypto, so shared
555     # libraries do not have to be a condition to produce those.
556
557     # Without position independent code, there can be no shared libraries
558     # or modules.
559     "pic"               => [ "shared", "module" ],
560
561     "module"            => [ "fips" ],
562
563     "engine"            => [ grep /eng$/, @disablables ],
564     "hw"                => [ "padlockeng" ],
565
566     # no-autoalginit is only useful when building non-shared
567     "autoalginit"       => [ "shared", "apps" ],
568
569     "stdio"             => [ "apps", "capieng", "egd" ],
570     "apps"              => [ "tests" ],
571     "tests"             => [ "external-tests" ],
572     "comp"              => [ "zlib" ],
573     "sm3"               => [ "sm2" ],
574     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
575
576     sub { !$disabled{"msan"} } => [ "asm" ],
577
578     sub { $disabled{cmac}; } => [ "siv" ],
579     "legacy"                 => [ "md2" ],
580
581     "cmp"               => [ "crmf" ],
582
583     # Padlock engine uses low-level AES APIs which are deprecated
584     sub { $disabled{"deprecated-3.0"} }
585           => [ "padlockeng" ]
586     );
587
588 # Avoid protocol support holes.  Also disable all versions below N, if version
589 # N is disabled while N+1 is enabled.
590 #
591 my @list = (reverse @tls);
592 while ((my $first, my $second) = (shift @list, shift @list)) {
593     last unless @list;
594     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
595                               => [ @list ] );
596     unshift @list, $second;
597 }
598 my @list = (reverse @dtls);
599 while ((my $first, my $second) = (shift @list, shift @list)) {
600     last unless @list;
601     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
602                               => [ @list ] );
603     unshift @list, $second;
604 }
605
606 # Explicit "no-..." options will be collected in %disabled along with the defaults.
607 # To remove something from %disabled, use "enable-foo".
608 # For symmetry, "disable-foo" is a synonym for "no-foo".
609
610 &usage if ($#ARGV < 0);
611
612 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
613 # platform specific list separators.  Users from those platforms should
614 # recognise those separators from how you set up the PATH to find executables.
615 # The default is the Unix like separator, :, but as an exception, we also
616 # support the space as separator.
617 my $list_separator_re =
618     { VMS           => qr/(?<!\^),/,
619       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
620 # All the "make variables" we support
621 # Some get pre-populated for the sake of backward compatibility
622 # (we supported those before the change to "make variable" support.
623 my %user = (
624     AR          => env('AR'),
625     ARFLAGS     => [],
626     AS          => undef,
627     ASFLAGS     => [],
628     CC          => env('CC'),
629     CFLAGS      => [ env('CFLAGS') || () ],
630     CXX         => env('CXX'),
631     CXXFLAGS    => [ env('CXXFLAGS') || () ],
632     CPP         => undef,
633     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
634     CPPDEFINES  => [],  # Alternative for -D
635     CPPINCLUDES => [],  # Alternative for -I
636     CROSS_COMPILE => env('CROSS_COMPILE'),
637     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
638     LD          => undef,
639     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
640     LDLIBS      => [ env('LDLIBS') || () ],  # -l
641     MT          => undef,
642     MTFLAGS     => [],
643     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
644     RANLIB      => env('RANLIB'),
645     RC          => env('RC') || env('WINDRES'),
646     RCFLAGS     => [ env('RCFLAGS') || () ],
647     RM          => undef,
648    );
649 # Info about what "make variables" may be prefixed with the cross compiler
650 # prefix.  This should NEVER mention any such variable with a list for value.
651 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
652 # The same but for flags given as Configure options.  These are *additional*
653 # input, as opposed to the VAR=string option that override the corresponding
654 # config target attributes
655 my %useradd = (
656     CPPDEFINES  => [],
657     CPPINCLUDES => [],
658     CPPFLAGS    => [],
659     CFLAGS      => [],
660     CXXFLAGS    => [],
661     LDFLAGS     => [],
662     LDLIBS      => [],
663     RCFLAGS     => [],
664    );
665
666 my %user_synonyms = (
667     HASHBANGPERL=> 'PERL',
668     RC          => 'WINDRES',
669    );
670
671 # Some target attributes have been renamed, this is the translation table
672 my %target_attr_translate =(
673     ar          => 'AR',
674     as          => 'AS',
675     cc          => 'CC',
676     cxx         => 'CXX',
677     cpp         => 'CPP',
678     hashbangperl => 'HASHBANGPERL',
679     ld          => 'LD',
680     mt          => 'MT',
681     ranlib      => 'RANLIB',
682     rc          => 'RC',
683     rm          => 'RM',
684    );
685
686 # Initialisers coming from 'config' scripts
687 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
688 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
689 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
690 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
691 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
692 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
693 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
694
695 $config{openssl_api_defines}=[];
696 $config{openssl_sys_defines}=[];
697 $config{openssl_feature_defines}=[];
698 $config{options}="";
699 $config{build_type} = "release";
700 my $target="";
701
702 my %cmdvars = ();               # Stores FOO='blah' type arguments
703 my %unsupported_options = ();
704 my %deprecated_options = ();
705 # If you change this, update apps/version.c
706 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
707 my @seed_sources = ();
708 while (@argvcopy)
709         {
710         $_ = shift @argvcopy;
711
712         # Support env variable assignments among the options
713         if (m|^(\w+)=(.+)?$|)
714                 {
715                 $cmdvars{$1} = $2;
716                 # Every time a variable is given as a configuration argument,
717                 # it acts as a reset if the variable.
718                 if (exists $user{$1})
719                         {
720                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
721                         }
722                 #if (exists $useradd{$1})
723                 #       {
724                 #       $useradd{$1} = [];
725                 #       }
726                 next;
727                 }
728
729         # VMS is a case insensitive environment, and depending on settings
730         # out of our control, we may receive options uppercased.  Let's
731         # downcase at least the part before any equal sign.
732         if ($^O eq "VMS")
733                 {
734                 s/^([^=]*)/lc($1)/e;
735                 }
736
737         # some people just can't read the instructions, clang people have to...
738         s/^-no-(?!integrated-as)/no-/;
739
740         # rewrite some options in "enable-..." form
741         s /^-?-?shared$/enable-shared/;
742         s /^sctp$/enable-sctp/;
743         s /^threads$/enable-threads/;
744         s /^zlib$/enable-zlib/;
745         s /^zlib-dynamic$/enable-zlib-dynamic/;
746
747         if (/^(no|disable|enable)-(.+)$/)
748                 {
749                 my $word = $2;
750                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
751                         && !exists $deprecated_disablables{$word}
752                         && !grep { $word eq $_ } @disablables)
753                         {
754                         $unsupported_options{$_} = 1;
755                         next;
756                         }
757                 }
758         if (/^no-(.+)$/ || /^disable-(.+)$/)
759                 {
760                 foreach my $proto ((@tls, @dtls))
761                         {
762                         if ($1 eq "$proto-method")
763                                 {
764                                 $disabled{"$proto"} = "option($proto-method)";
765                                 last;
766                                 }
767                         }
768                 if ($1 eq "dtls")
769                         {
770                         foreach my $proto (@dtls)
771                                 {
772                                 $disabled{$proto} = "option(dtls)";
773                                 }
774                         $disabled{"dtls"} = "option(dtls)";
775                         }
776                 elsif ($1 eq "ssl")
777                         {
778                         # Last one of its kind
779                         $disabled{"ssl3"} = "option(ssl)";
780                         }
781                 elsif ($1 eq "tls")
782                         {
783                         # XXX: Tests will fail if all SSL/TLS
784                         # protocols are disabled.
785                         foreach my $proto (@tls)
786                                 {
787                                 $disabled{$proto} = "option(tls)";
788                                 }
789                         }
790                 elsif ($1 eq "static-engine")
791                         {
792                         delete $disabled{"dynamic-engine"};
793                         }
794                 elsif ($1 eq "dynamic-engine")
795                         {
796                         $disabled{"dynamic-engine"} = "option";
797                         }
798                 elsif (exists $deprecated_disablables{$1})
799                         {
800                         $deprecated_options{$_} = 1;
801                         if (defined $deprecated_disablables{$1})
802                                 {
803                                 $disabled{$deprecated_disablables{$1}} = "option";
804                                 }
805                         }
806                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
807                         {
808                         $deprecated_options{$_} = 1;
809                         }
810                 else
811                         {
812                         $disabled{$1} = "option";
813                         }
814                 # No longer an automatic choice
815                 $auto_threads = 0 if ($1 eq "threads");
816                 }
817         elsif (/^enable-(.+)$/)
818                 {
819                 if ($1 eq "static-engine")
820                         {
821                         $disabled{"dynamic-engine"} = "option";
822                         }
823                 elsif ($1 eq "dynamic-engine")
824                         {
825                         delete $disabled{"dynamic-engine"};
826                         }
827                 elsif ($1 eq "zlib-dynamic")
828                         {
829                         delete $disabled{"zlib"};
830                         }
831                 my $algo = $1;
832                 delete $disabled{$algo};
833
834                 # No longer an automatic choice
835                 $auto_threads = 0 if ($1 eq "threads");
836                 }
837         elsif (/^--strict-warnings$/)
838                 {
839                 # Pretend that our strict flags is a C flag, and replace it
840                 # with the proper flags later on
841                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
842                 $strict_warnings=1;
843                 }
844         elsif (/^--debug$/)
845                 {
846                 $config{build_type} = "debug";
847                 }
848         elsif (/^--release$/)
849                 {
850                 $config{build_type} = "release";
851                 }
852         elsif (/^386$/)
853                 { $config{processor}=386; }
854         elsif (/^fips$/)
855                 {
856                 die "FIPS mode not supported\n";
857                 }
858         elsif (/^rsaref$/)
859                 {
860                 # No RSAref support any more since it's not needed.
861                 # The check for the option is there so scripts aren't
862                 # broken
863                 }
864         elsif (/^nofipscanistercheck$/)
865                 {
866                 die "FIPS mode not supported\n";
867                 }
868         elsif (m|^[-+/]|)
869                 {
870                 if (/^--prefix=(.*)$/)
871                         {
872                         $config{prefix}=$1;
873                         die "Directory given with --prefix MUST be absolute\n"
874                                 unless file_name_is_absolute($config{prefix});
875                         }
876                 elsif (/^--api=(.*)$/)
877                         {
878                         my $api = $1;
879                         die "Unknown API compatibility level $api"
880                                 unless defined $apitable->{$api};
881                         $config{api}=$apitable->{$api};
882                         }
883                 elsif (/^--libdir=(.*)$/)
884                         {
885                         $config{libdir}=$1;
886                         }
887                 elsif (/^--openssldir=(.*)$/)
888                         {
889                         $config{openssldir}=$1;
890                         }
891                 elsif (/^--with-zlib-lib=(.*)$/)
892                         {
893                         $withargs{zlib_lib}=$1;
894                         }
895                 elsif (/^--with-zlib-include=(.*)$/)
896                         {
897                         $withargs{zlib_include}=$1;
898                         }
899                 elsif (/^--with-fuzzer-lib=(.*)$/)
900                         {
901                         $withargs{fuzzer_lib}=$1;
902                         }
903                 elsif (/^--with-fuzzer-include=(.*)$/)
904                         {
905                         $withargs{fuzzer_include}=$1;
906                         }
907                 elsif (/^--with-rand-seed=(.*)$/)
908                         {
909                         foreach my $x (split(m|,|, $1))
910                             {
911                             die "Unknown --with-rand-seed choice $x\n"
912                                 if ! grep { $x eq $_ } @known_seed_sources;
913                             push @seed_sources, $x;
914                             }
915                         }
916                 elsif (/^--cross-compile-prefix=(.*)$/)
917                         {
918                         $user{CROSS_COMPILE}=$1;
919                         }
920                 elsif (/^--config=(.*)$/)
921                         {
922                         read_config $1;
923                         }
924                 elsif (/^-l(.*)$/)
925                         {
926                         push @{$useradd{LDLIBS}}, $_;
927                         }
928                 elsif (/^-framework$/)
929                         {
930                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
931                         }
932                 elsif (/^-L(.*)$/ or /^-Wl,/)
933                         {
934                         push @{$useradd{LDFLAGS}}, $_;
935                         }
936                 elsif (/^-rpath$/ or /^-R$/)
937                         # -rpath is the OSF1 rpath flag
938                         # -R is the old Solaris rpath flag
939                         {
940                         my $rpath = shift(@argvcopy) || "";
941                         $rpath .= " " if $rpath ne "";
942                         push @{$useradd{LDFLAGS}}, $_, $rpath;
943                         }
944                 elsif (/^-static$/)
945                         {
946                         push @{$useradd{LDFLAGS}}, $_;
947                         }
948                 elsif (m|^[-/]D(.*)$|)
949                         {
950                         push @{$useradd{CPPDEFINES}}, $1;
951                         }
952                 elsif (m|^[-/]I(.*)$|)
953                         {
954                         push @{$useradd{CPPINCLUDES}}, $1;
955                         }
956                 elsif (/^-Wp,$/)
957                         {
958                         push @{$useradd{CPPFLAGS}}, $1;
959                         }
960                 else    # common if (/^[-+]/), just pass down...
961                         {
962                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
963                         # This provides a simple way to pass options with arguments separated
964                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
965                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
966                         push @{$useradd{CFLAGS}}, $_;
967                         push @{$useradd{CXXFLAGS}}, $_;
968                         }
969                 }
970         elsif (m|^/|)
971                 {
972                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
973                 # This provides a simple way to pass options with arguments separated
974                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
975                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
976                 push @{$useradd{CFLAGS}}, $_;
977                 push @{$useradd{CXXFLAGS}}, $_;
978                 }
979         else
980                 {
981                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
982                 $target=$_;
983                 }
984         unless ($_ eq $target || /^no-/ || /^disable-/)
985                 {
986                 # "no-..." follows later after implied deactivations
987                 # have been derived.  (Don't take this too seriously,
988                 # we really only write OPTIONS to the Makefile out of
989                 # nostalgia.)
990
991                 if ($config{options} eq "")
992                         { $config{options} = $_; }
993                 else
994                         { $config{options} .= " ".$_; }
995                 }
996         }
997
998 if (keys %deprecated_options)
999         {
1000         warn "***** Deprecated options: ",
1001                 join(", ", keys %deprecated_options), "\n";
1002         }
1003 if (keys %unsupported_options)
1004         {
1005         die "***** Unsupported options: ",
1006                 join(", ", keys %unsupported_options), "\n";
1007         }
1008
1009 # If any %useradd entry has been set, we must check that the "make
1010 # variables" haven't been set.  We start by checking of any %useradd entry
1011 # is set.
1012 if (grep { scalar @$_ > 0 } values %useradd) {
1013     # Hash of env / make variables names.  The possible values are:
1014     # 1 - "make vars"
1015     # 2 - %useradd entry set
1016     # 3 - both set
1017     my %detected_vars =
1018         map { my $v = 0;
1019               $v += 1 if $cmdvars{$_};
1020               $v += 2 if @{$useradd{$_}};
1021               $_ => $v }
1022         keys %useradd;
1023
1024     # If any of the corresponding "make variables" is set, we error
1025     if (grep { $_ & 1 } values %detected_vars) {
1026         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1027                                sort keys %detected_vars);
1028         die <<"_____";
1029 ***** Mixing make variables and additional compiler/linker flags as
1030 ***** configure command line option is not permitted.
1031 ***** Affected make variables: $names
1032 _____
1033     }
1034 }
1035
1036 # Check through all supported command line variables to see if any of them
1037 # were set, and canonicalise the values we got.  If no compiler or linker
1038 # flag or anything else that affects %useradd was set, we also check the
1039 # environment for values.
1040 my $anyuseradd =
1041     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1042 foreach (keys %user) {
1043     my $value = $cmdvars{$_};
1044     $value //= env($_) unless $anyuseradd;
1045     $value //=
1046         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1047     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1048         unless $anyuseradd;
1049
1050     if (defined $value) {
1051         if (ref $user{$_} eq 'ARRAY') {
1052             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1053                 $user{$_} = [ split /$list_separator_re/, $value ];
1054             } else {
1055                 $user{$_} = [ $value ];
1056             }
1057         } elsif (!defined $user{$_}) {
1058             $user{$_} = $value;
1059         }
1060     }
1061 }
1062
1063 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1064     && !$disabled{shared}
1065     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1066     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1067         "***** any of asan, msan or ubsan\n";
1068 }
1069
1070 sub disable {
1071     my $disable_type = shift;
1072
1073     for (@_) {
1074         $disabled{$_} = $disable_type;
1075     }
1076
1077     my @tocheckfor = (@_ ? @_ : keys %disabled);
1078     while (@tocheckfor) {
1079         my %new_tocheckfor = ();
1080         my @cascade_copy = (@disable_cascades);
1081         while (@cascade_copy) {
1082             my ($test, $descendents) =
1083                 (shift @cascade_copy, shift @cascade_copy);
1084             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1085                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1086                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1087                 }
1088             }
1089         }
1090         @tocheckfor = (keys %new_tocheckfor);
1091     }
1092 }
1093 disable();                     # First cascade run
1094
1095 our $die = sub { die @_; };
1096 if ($target eq "TABLE") {
1097     local $die = sub { warn @_; };
1098     foreach (sort keys %table) {
1099         print_table_entry($_, "TABLE");
1100     }
1101     exit 0;
1102 }
1103
1104 if ($target eq "LIST") {
1105     foreach (sort keys %table) {
1106         print $_,"\n" unless $table{$_}->{template};
1107     }
1108     exit 0;
1109 }
1110
1111 if ($target eq "HASH") {
1112     local $die = sub { warn @_; };
1113     print "%table = (\n";
1114     foreach (sort keys %table) {
1115         print_table_entry($_, "HASH");
1116     }
1117     exit 0;
1118 }
1119
1120 print "Configuring OpenSSL version $config{full_version} ";
1121 print "for target $target\n";
1122
1123 if (scalar(@seed_sources) == 0) {
1124     print "Using os-specific seed configuration\n";
1125     push @seed_sources, 'os';
1126 }
1127 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1128     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1129     warn <<_____ if scalar(@seed_sources) == 1;
1130
1131 ============================== WARNING ===============================
1132 You have selected the --with-rand-seed=none option, which effectively
1133 disables automatic reseeding of the OpenSSL random generator.
1134 All operations depending on the random generator such as creating keys
1135 will not work unless the random generator is seeded manually by the
1136 application.
1137
1138 Please read the 'Note on random number generation' section in the
1139 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1140 details.
1141 ============================== WARNING ===============================
1142
1143 _____
1144 }
1145 push @{$config{openssl_feature_defines}},
1146      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1147         @seed_sources;
1148
1149 # Backward compatibility?
1150 if ($target =~ m/^CygWin32(-.*)$/) {
1151     $target = "Cygwin".$1;
1152 }
1153
1154 # Support for legacy targets having a name starting with 'debug-'
1155 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1156 if ($d) {
1157     $config{build_type} = "debug";
1158
1159     # If we do not find debug-foo in the table, the target is set to foo.
1160     if (!$table{$target}) {
1161         $target = $t;
1162     }
1163 }
1164
1165 &usage if !$table{$target} || $table{$target}->{template};
1166
1167 $config{target} = $target;
1168 my %target = resolve_config($target);
1169
1170 foreach (keys %target_attr_translate) {
1171     $target{$target_attr_translate{$_}} = $target{$_}
1172         if $target{$_};
1173     delete $target{$_};
1174 }
1175
1176 %target = ( %{$table{DEFAULTS}}, %target );
1177
1178 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1179 $config{conf_files} = [ sort keys %conf_files ];
1180
1181 # Using sub disable within these loops may prove fragile, so we run
1182 # a cascade afterwards
1183 foreach my $feature (@{$target{disable}}) {
1184     if (exists $deprecated_disablables{$feature}) {
1185         warn "***** config $target disables deprecated feature $feature\n";
1186     } elsif (!grep { $feature eq $_ } @disablables) {
1187         die "***** config $target disables unknown feature $feature\n";
1188     }
1189     $disabled{$feature} = 'config';
1190 }
1191 foreach my $feature (@{$target{enable}}) {
1192     if ("default" eq ($disabled{$feature} // "")) {
1193         if (exists $deprecated_disablables{$feature}) {
1194             warn "***** config $target enables deprecated feature $feature\n";
1195         } elsif (!grep { $feature eq $_ } @disablables) {
1196             die "***** config $target enables unknown feature $feature\n";
1197         }
1198         delete $disabled{$feature};
1199     }
1200 }
1201
1202 # If uplink_arch isn't defined, disable uplink
1203 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1204 # If asm_arch isn't defined, disable asm
1205 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1206
1207 disable();                      # Run a cascade now
1208
1209 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1210 $target{cxxflags}//=$target{cflags} if $target{CXX};
1211 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1212 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1213
1214 # Fill %config with values from %user, and in case those are undefined or
1215 # empty, use values from %target (acting as a default).
1216 foreach (keys %user) {
1217     my $ref_type = ref $user{$_};
1218
1219     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1220     # and a value that's to be coerced into that type.
1221     my $mkvalue = sub {
1222         my $type = shift;
1223         my $value = shift;
1224         my $undef_p = shift;
1225
1226         die "Too many arguments for \$mkvalue" if @_;
1227
1228         while (ref $value eq 'CODE') {
1229             $value = $value->();
1230         }
1231
1232         if ($type eq 'ARRAY') {
1233             return undef unless defined $value;
1234             return undef if ref $value ne 'ARRAY' && !$value;
1235             return undef if ref $value eq 'ARRAY' && !@$value;
1236             return [ $value ] unless ref $value eq 'ARRAY';
1237         }
1238         return undef unless $value;
1239         return $value;
1240     };
1241
1242     $config{$_} =
1243         $mkvalue->($ref_type, $user{$_})
1244         || $mkvalue->($ref_type, $target{$_});
1245     delete $config{$_} unless defined $config{$_};
1246 }
1247
1248 # Finish up %config by appending things the user gave us on the command line
1249 # apart from "make variables"
1250 foreach (keys %useradd) {
1251     # The must all be lists, so we assert that here
1252     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1253         unless ref $useradd{$_} eq 'ARRAY';
1254
1255     if (defined $config{$_}) {
1256         push @{$config{$_}}, @{$useradd{$_}};
1257     } else {
1258         $config{$_} = [ @{$useradd{$_}} ];
1259     }
1260 }
1261 # At this point, we can forget everything about %user and %useradd,
1262 # because it's now all been merged into the corresponding $config entry
1263
1264 # Allow overriding the build file name
1265 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1266
1267 # Make sure build_scheme is consistent.
1268 $target{build_scheme} = [ $target{build_scheme} ]
1269     if ref($target{build_scheme}) ne "ARRAY";
1270
1271 my ($builder, $builder_platform, @builder_opts) =
1272     @{$target{build_scheme}};
1273
1274 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1275                       $builder_platform."-checker.pm")) {
1276     my $checker_path = catfile($srcdir, "Configurations", $checker);
1277     if (-f $checker_path) {
1278         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1279             ? sub { warn $@; } : sub { die $@; };
1280         if (! do $checker_path) {
1281             if ($@) {
1282                 $fn->($@);
1283             } elsif ($!) {
1284                 $fn->($!);
1285             } else {
1286                 $fn->("The detected tools didn't match the platform\n");
1287             }
1288         }
1289         last;
1290     }
1291 }
1292
1293 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1294
1295 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1296         {
1297         push @{$config{cflags}}, "-mno-cygwin";
1298         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1299         push @{$config{shared_ldflag}}, "-mno-cygwin";
1300         }
1301
1302 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1303         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1304         # minimally required architecture flags for assembly modules
1305         my $value;
1306         $value = '-mips2' if ($target =~ /mips32/);
1307         $value = '-mips3' if ($target =~ /mips64/);
1308         unshift @{$config{cflags}}, $value;
1309         unshift @{$config{cxxflags}}, $value if $config{CXX};
1310 }
1311
1312 # If threads aren't disabled, check how possible they are
1313 unless ($disabled{threads}) {
1314     if ($auto_threads) {
1315         # Enabled by default, disable it forcibly if unavailable
1316         if ($target{thread_scheme} eq "(unknown)") {
1317             disable("unavailable", 'threads');
1318         }
1319     } else {
1320         # The user chose to enable threads explicitly, let's see
1321         # if there's a chance that's possible
1322         if ($target{thread_scheme} eq "(unknown)") {
1323             # If the user asked for "threads" and we don't have internal
1324             # knowledge how to do it, [s]he is expected to provide any
1325             # system-dependent compiler options that are necessary.  We
1326             # can't truly check that the given options are correct, but
1327             # we expect the user to know what [s]He is doing.
1328             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1329                 die "You asked for multi-threading support, but didn't\n"
1330                     ,"provide any system-specific compiler options\n";
1331             }
1332         }
1333     }
1334 }
1335
1336 # Find out if clang's sanitizers have been enabled with -fsanitize
1337 # flags and ensure that the corresponding %disabled elements area
1338 # removed to reflect that the sanitizers are indeed enabled.
1339 my %detected_sanitizers = ();
1340 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1341     (my $checks = $_) =~ s/^-fsanitize=//;
1342     foreach (split /,/, $checks) {
1343         my $d = { address       => 'asan',
1344                   undefined     => 'ubsan',
1345                   memory        => 'msan' } -> {$_};
1346         next unless defined $d;
1347
1348         $detected_sanitizers{$d} = 1;
1349         if (defined $disabled{$d}) {
1350             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1351                 if $disabled{$d} ne "default";
1352             delete $disabled{$d};
1353         }
1354     }
1355 }
1356
1357 # If threads still aren't disabled, add a C macro to ensure the source
1358 # code knows about it.  Any other flag is taken care of by the configs.
1359 unless($disabled{threads}) {
1360     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1361 }
1362
1363 my $no_shared_warn=0;
1364 if ($target{shared_target} eq "")
1365         {
1366         $no_shared_warn = 1
1367             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1368         disable('no-shared-target', 'pic');
1369         }
1370
1371 if ($disabled{"dynamic-engine"}) {
1372         $config{dynamic_engines} = 0;
1373 } else {
1374         $config{dynamic_engines} = 1;
1375 }
1376
1377 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1378     push @{$config{cflags}}, "-fsanitize=address";
1379 }
1380
1381 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1382     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1383     # platforms.
1384     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1385 }
1386
1387 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1388   push @{$config{cflags}}, "-fsanitize=memory";
1389 }
1390
1391 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1392         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1393     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1394     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1395 }
1396 #
1397 # Platform fix-ups
1398 #
1399
1400 # This saves the build files from having to check
1401 if ($disabled{pic})
1402         {
1403         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1404                     shared_defines shared_includes shared_ldflag
1405                     module_cflags module_cxxflags module_cppflags
1406                     module_defines module_includes module_lflags))
1407                 {
1408                 delete $config{$_};
1409                 $target{$_} = "";
1410                 }
1411         }
1412 else
1413         {
1414         push @{$config{lib_defines}}, "OPENSSL_PIC";
1415         }
1416
1417 if ($target{sys_id} ne "")
1418         {
1419         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1420         }
1421
1422 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1423 my %predefined_CXX = $config{CXX}
1424     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1425     : ();
1426
1427 unless ($disabled{asm}) {
1428     # big endian systems can use ELFv2 ABI
1429     if ($target eq "linux-ppc64") {
1430         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1431     }
1432 }
1433
1434 # Check for makedepend capabilities.
1435 if (!$disabled{makedepend}) {
1436     if ($config{target} =~ /^(VC|vms)-/) {
1437         # For VC- and vms- targets, there's nothing more to do here.  The
1438         # functionality is hard coded in the corresponding build files for
1439         # cl (Windows) and CC/DECC (VMS).
1440     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1441              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1442         # We know that GNU C version 3 and up as well as all clang
1443         # versions support dependency generation, but Xcode did not
1444         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1445         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1446     } else {
1447         # In all other cases, we look for 'makedepend', and disable the
1448         # capability if not found.
1449         $config{makedepprog} = which('makedepend');
1450         disable('unavailable', 'makedepend') unless $config{makedepprog};
1451     }
1452 }
1453
1454 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1455     # probe for -Wa,--noexecstack option...
1456     if ($predefined_C{__clang__}) {
1457         # clang has builtin assembler, which doesn't recognize --help,
1458         # but it apparently recognizes the option in question on all
1459         # supported platforms even when it's meaningless. In other words
1460         # probe would fail, but probed option always accepted...
1461         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1462     } else {
1463         my $cc = $config{CROSS_COMPILE}.$config{CC};
1464         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1465         while(<PIPE>) {
1466             if (m/--noexecstack/) {
1467                 push @{$config{cflags}}, "-Wa,--noexecstack";
1468                 last;
1469             }
1470         }
1471         close(PIPE);
1472         unlink("null.$$.o");
1473     }
1474 }
1475
1476 # Deal with bn_ops ###################################################
1477
1478 $config{bn_ll}                  =0;
1479 my $def_int="unsigned int";
1480 $config{rc4_int}                =$def_int;
1481 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1482
1483 my $count = 0;
1484 foreach (sort split(/\s+/,$target{bn_ops})) {
1485     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1486     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1487     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1488     ($config{b64l},$config{b64},$config{b32})
1489         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1490     ($config{b64l},$config{b64},$config{b32})
1491         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1492     ($config{b64l},$config{b64},$config{b32})
1493         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1494 }
1495 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1496     if $count > 1;
1497
1498 $config{api} = $config{major} * 10000 + $config{minor} * 100
1499     unless $config{api};
1500 foreach (keys %$apitable) {
1501     $disabled{"deprecated-$_"} = "deprecation"
1502         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1503 }
1504
1505 disable();                      # Run a cascade now
1506
1507 # Hack cflags for better warnings (dev option) #######################
1508
1509 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1510 # a string and works as well on command lines.
1511 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1512                         @{$config{cflags}} ];
1513 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1514                           @{$config{cxxflags}} ] if $config{CXX};
1515
1516 $config{openssl_api_defines} = [
1517     "OPENSSL_CONFIGURED_API=".$config{api},
1518 ];
1519
1520 my @strict_warnings_collection=();
1521 if ($strict_warnings)
1522         {
1523         my $wopt;
1524         my $gccver = $predefined_C{__GNUC__} // -1;
1525
1526         if ($gccver >= 4)
1527                 {
1528                 push @strict_warnings_collection, @gcc_devteam_warn;
1529                 push @strict_warnings_collection, @clang_devteam_warn
1530                     if (defined($predefined_C{__clang__}));
1531                 }
1532         elsif ($config{target} =~ /^VC-/)
1533                 {
1534                 push @strict_warnings_collection, @cl_devteam_warn;
1535                 }
1536         else
1537                 {
1538                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1539                 }
1540         }
1541
1542 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1543     disable('static', 'pic', 'threads');
1544 }
1545
1546 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1547                               ? @strict_warnings_collection
1548                               : ( $_ ) }
1549                     @{$config{CFLAGS}} ];
1550
1551 unless ($disabled{afalgeng}) {
1552     $config{afalgeng}="";
1553     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1554         my $minver = 4*10000 + 1*100 + 0;
1555         if ($config{CROSS_COMPILE} eq "") {
1556             my $verstr = `uname -r`;
1557             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1558             ($mi2) = $mi2 =~ /(\d+)/;
1559             my $ver = $ma*10000 + $mi1*100 + $mi2;
1560             if ($ver < $minver) {
1561                 disable('too-old-kernel', 'afalgeng');
1562             } else {
1563                 push @{$config{engdirs}}, "afalg";
1564             }
1565         } else {
1566             disable('cross-compiling', 'afalgeng');
1567         }
1568     } else {
1569         disable('not-linux', 'afalgeng');
1570     }
1571 }
1572
1573 unless ($disabled{devcryptoeng}) {
1574     if ($target =~ m/^BSD/) {
1575         my $maxver = 5*100 + 7;
1576         my $sysstr = `uname -s`;
1577         my $verstr = `uname -r`;
1578         $sysstr =~ s|\R$||;
1579         $verstr =~ s|\R$||;
1580         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1581         my $ver = $ma*100 + $mi;
1582         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1583             disable('too-new-kernel', 'devcryptoeng');
1584         }
1585     }
1586 }
1587
1588 unless ($disabled{ktls}) {
1589     $config{ktls}="";
1590     if ($target =~ m/^linux/) {
1591         my $usr = "/usr/$config{cross_compile_prefix}";
1592         chop($usr);
1593         if ($config{cross_compile_prefix} eq "") {
1594             $usr = "/usr";
1595         }
1596         my $minver = (4 << 16) + (13 << 8) + 0;
1597         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1598
1599         if ($verstr[2] < $minver) {
1600             disable('too-old-kernel', 'ktls');
1601         }
1602     } elsif ($target =~ m/^BSD/) {
1603         my $cc = $config{CROSS_COMPILE}.$config{CC};
1604         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1605         if ($? != 0) {
1606             disable('too-old-freebsd', 'ktls');
1607         }
1608     } else {
1609         disable('not-linux-or-freebsd', 'ktls');
1610     }
1611 }
1612
1613 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1614
1615 # Get the extra flags used when building shared libraries and modules.  We
1616 # do this late because some of them depend on %disabled.
1617
1618 # Make the flags to build DSOs the same as for shared libraries unless they
1619 # are already defined
1620 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1621 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1622 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1623 {
1624     my $shared_info_pl =
1625         catfile(dirname($0), "Configurations", "shared-info.pl");
1626     my %shared_info = read_eval_file($shared_info_pl);
1627     push @{$target{_conf_fname_int}}, $shared_info_pl;
1628     my $si = $target{shared_target};
1629     while (ref $si ne "HASH") {
1630         last if ! defined $si;
1631         if (ref $si eq "CODE") {
1632             $si = $si->();
1633         } else {
1634             $si = $shared_info{$si};
1635         }
1636     }
1637
1638     # Some of the 'shared_target' values don't have any entries in
1639     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1640     # template knows how to handle this.  That is currently the case for
1641     # Windows and VMS.
1642     if (defined $si) {
1643         # Just as above, copy certain shared_* attributes to the corresponding
1644         # module_ attribute unless the latter is already defined
1645         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1646         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1647         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1648         foreach (sort keys %$si) {
1649             $target{$_} = defined $target{$_}
1650                 ? add($si->{$_})->($target{$_})
1651                 : $si->{$_};
1652         }
1653     }
1654 }
1655
1656 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1657
1658 ######################################################################
1659 # Build up information for skipping certain directories depending on disabled
1660 # features, as well as setting up macros for disabled features.
1661
1662 # This is a tentative database of directories to skip.  Some entries may not
1663 # correspond to anything real, but that's ok, they will simply be ignored.
1664 # The actual processing of these entries is done in the build.info lookup
1665 # loop further down.
1666 #
1667 # The key is a Unix formatted path in the source tree, the value is an index
1668 # into %disabled_info, so any existing path gets added to a corresponding
1669 # 'skipped' entry in there with the list of skipped directories.
1670 my %skipdir = ();
1671 my %disabled_info = ();         # For configdata.pm
1672 foreach my $what (sort keys %disabled) {
1673     # There are deprecated disablables that translate to themselves.
1674     # They cause disabling cascades, but should otherwise not regiter.
1675     next if $deprecated_disablables{$what};
1676     # The generated $disabled{"deprecated-x.y"} entries are special
1677     # and treated properly elsewhere
1678     next if $what =~ m|^deprecated-|;
1679
1680     $config{options} .= " no-$what";
1681
1682     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1683                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1684                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1685         (my $WHAT = uc $what) =~ s|-|_|g;
1686         my $skipdir = $what;
1687
1688         # fix-up crypto/directory name(s)
1689         $skipdir = "ripemd" if $what eq "rmd160";
1690         $skipdir = "whrlpool" if $what eq "whirlpool";
1691
1692         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1693         push @{$config{openssl_feature_defines}}, $macro;
1694
1695         $skipdir{engines} = $what if $what eq 'engine';
1696         $skipdir{"crypto/$skipdir"} = $what
1697             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1698     }
1699 }
1700
1701 if ($disabled{"dynamic-engine"}) {
1702     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1703 } else {
1704     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1705 }
1706
1707 # If we use the unified build, collect information from build.info files
1708 my %unified_info = ();
1709
1710 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1711 if ($builder eq "unified") {
1712     use Text::Template 1.46;
1713
1714     sub cleandir {
1715         my $base = shift;
1716         my $dir = shift;
1717         my $relativeto = shift || ".";
1718
1719         $dir = catdir($base,$dir) unless isabsolute($dir);
1720
1721         # Make sure the directories we're building in exists
1722         mkpath($dir);
1723
1724         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1725         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1726         return $res;
1727     }
1728
1729     sub cleanfile {
1730         my $base = shift;
1731         my $file = shift;
1732         my $relativeto = shift || ".";
1733
1734         $file = catfile($base,$file) unless isabsolute($file);
1735
1736         my $d = dirname($file);
1737         my $f = basename($file);
1738
1739         # Make sure the directories we're building in exists
1740         mkpath($d);
1741
1742         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1743         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1744         return $res;
1745     }
1746
1747     # Store the name of the template file we will build the build file from
1748     # in %config.  This may be useful for the build file itself.
1749     my @build_file_template_names =
1750         ( $builder_platform."-".$target{build_file}.".tmpl",
1751           $target{build_file}.".tmpl" );
1752     my @build_file_templates = ();
1753
1754     # First, look in the user provided directory, if given
1755     if (defined env($local_config_envname)) {
1756         @build_file_templates =
1757             map {
1758                 if ($^O eq 'VMS') {
1759                     # VMS environment variables are logical names,
1760                     # which can be used as is
1761                     $local_config_envname . ':' . $_;
1762                 } else {
1763                     catfile(env($local_config_envname), $_);
1764                 }
1765             }
1766             @build_file_template_names;
1767     }
1768     # Then, look in our standard directory
1769     push @build_file_templates,
1770         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1771           @build_file_template_names );
1772
1773     my $build_file_template;
1774     for $_ (@build_file_templates) {
1775         $build_file_template = $_;
1776         last if -f $build_file_template;
1777
1778         $build_file_template = undef;
1779     }
1780     if (!defined $build_file_template) {
1781         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1782     }
1783     $config{build_file_templates}
1784       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1785                     $blddir),
1786           $build_file_template,
1787           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1788                     $blddir) ];
1789
1790     my @build_dirs = ( [ ] );   # current directory
1791
1792     $config{build_infos} = [ ];
1793
1794     my %ordinals = ();
1795     while (@build_dirs) {
1796         my @curd = @{shift @build_dirs};
1797         my $sourced = catdir($srcdir, @curd);
1798         my $buildd = catdir($blddir, @curd);
1799
1800         my $unixdir = join('/', @curd);
1801         if (exists $skipdir{$unixdir}) {
1802             my $what = $skipdir{$unixdir};
1803             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1804             next;
1805         }
1806
1807         mkpath($buildd);
1808
1809         my $f = 'build.info';
1810         # The basic things we're trying to build
1811         my @programs = ();
1812         my @libraries = ();
1813         my @modules = ();
1814         my @scripts = ();
1815
1816         my %sources = ();
1817         my %shared_sources = ();
1818         my %includes = ();
1819         my %defines = ();
1820         my %depends = ();
1821         my %generate = ();
1822         my %htmldocs = ();
1823         my %mandocs = ();
1824
1825         # Support for $variablename in build.info files.
1826         # Embedded perl code is the ultimate master, still.  If its output
1827         # contains a dollar sign, it had better be escaped, or it will be
1828         # taken for a variable name prefix.
1829         my %variables = ();
1830         # Variable name syntax
1831         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1832         # Value modifier syntaxes
1833         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1834         # Put it all together
1835         my $variable_re = qr/\$
1836                              (?|
1837                                  # Simple case, just the name
1838                                  ${variable_name_re}
1839                              |
1840                                  # Expressive case, with braces and possible
1841                                  # modifier expressions
1842                                  \{
1843                                  ${variable_name_re}
1844                                  (?:
1845                                      # Pile on modifier expressions,
1846                                      # separated by |
1847                                      ${variable_subst_re}
1848                                  )
1849                                  \}
1850                              )/x;
1851         my $expand_variables = sub {
1852             my $value = '';
1853             my $value_rest = shift;
1854
1855             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1856                 print STDERR
1857                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1858             }
1859             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1860                 $value_rest = $';
1861                 $value .= $`;
1862
1863                 my $variable_value = $variables{$+{VARIABLE}};
1864
1865                 # Process modifier expressions, if present
1866                 if (defined $+{RE}) {
1867                     # We must save important %+ values, because the s///
1868                     # below clears them
1869                     my $re = $+{RE};
1870                     my $subst = $+{SUBST};
1871
1872                     $variable_value =~ s/\Q$re\E/$subst/g;
1873
1874                     if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1875                         print STDERR
1876                             "DEBUG[\$expand_variables] ... and substituted ",
1877                             "'$re' with '$subst'\n";
1878                     }
1879                 }
1880
1881                 $value .= $variable_value;
1882             }
1883             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1884                 print STDERR
1885                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
1886             }
1887             return $value . $value_rest;
1888         };
1889
1890         # Support for attributes in build.info files
1891         my %attributes = ();
1892         my $handle_attributes = sub {
1893             my $attr_str = shift;
1894             my $ref = shift;
1895             my @goals = @_;
1896
1897             return unless defined $attr_str;
1898
1899             my @a = tokenize($attr_str, qr|\s*,\s*|);
1900             foreach my $a (@a) {
1901                 my $ac = 1;
1902                 my $ak = $a;
1903                 my $av = 1;
1904                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1905                     $ac = ! $1;
1906                     $ak = $1;
1907                     $av = $2;
1908                 }
1909                 foreach my $g (@goals) {
1910                     if ($ac) {
1911                         $$ref->{$g}->{$ak} = $av;
1912                     } else {
1913                         delete $$ref->{$g}->{$ak};
1914                     }
1915                 }
1916             }
1917         };
1918
1919         # Support for pushing values on multiple indexes of a given hash
1920         # array.
1921         my $push_to = sub {
1922             my $valueref = shift;
1923             my $index_str = shift; # May be undef or empty
1924             my $attrref = shift;   # May be undef
1925             my $attr_str = shift;
1926             my @values = @_;
1927
1928             if (defined $index_str) {
1929                 my @indexes = ( '' );
1930                 if ($index_str !~ m|^\s*$|) {
1931                     @indexes = tokenize($index_str);
1932                 }
1933                 foreach (@indexes) {
1934                     push @{$valueref->{$_}}, @values;
1935                     if (defined $attrref) {
1936                         $handle_attributes->($attr_str, \$$attrref->{$_},
1937                                              @values);
1938                     }
1939                 }
1940             } else {
1941                 push @$valueref, @values;
1942                 $handle_attributes->($attr_str, $attrref, @values)
1943                     if defined $attrref;
1944             }
1945         };
1946
1947         # We want to detect configdata.pm in the source tree, so we
1948         # don't use it if the build tree is different.
1949         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1950
1951
1952         if ($buildinfo_debug) {
1953             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1954         }
1955         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1956         my $template =
1957             Text::Template->new(TYPE => 'FILE',
1958                                 SOURCE => catfile($sourced, $f),
1959                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1960         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1961         my @text =
1962             split /^/m,
1963             $template->fill_in(HASH => { config => \%config,
1964                                          target => \%target,
1965                                          disabled => \%disabled,
1966                                          withargs => \%withargs,
1967                                          builddir => abs2rel($buildd, $blddir),
1968                                          sourcedir => abs2rel($sourced, $blddir),
1969                                          buildtop => abs2rel($blddir, $blddir),
1970                                          sourcetop => abs2rel($srcdir, $blddir) },
1971                                DELIMITERS => [ "{-", "-}" ]);
1972
1973         # The top item of this stack has the following values
1974         # -2 positive already run and we found ELSE (following ELSIF should fail)
1975         # -1 positive already run (skip until ENDIF)
1976         # 0 negatives so far (if we're at a condition, check it)
1977         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1978         # 2 positive ELSE (following ELSIF should fail)
1979         my @skip = ();
1980
1981         # A few useful generic regexps
1982         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1983         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1984         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1985         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1986         collect_information(
1987             collect_from_array([ @text ],
1988                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1989                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1990             # Info we're looking for
1991             qr/^\s* IF ${cond_re} \s*$/x
1992             => sub {
1993                 if (! @skip || $skip[$#skip] > 0) {
1994                     push @skip, !! $expand_variables->($+{COND});
1995                 } else {
1996                     push @skip, -1;
1997                 }
1998             },
1999             qr/^\s* ELSIF ${cond_re} \s*$/x
2000             => sub { die "ELSIF out of scope" if ! @skip;
2001                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2002                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2003                      $skip[$#skip] = !! $expand_variables->($+{COND})
2004                          if $skip[$#skip] == 0; },
2005             qr/^\s* ELSE \s*$/x
2006             => sub { die "ELSE out of scope" if ! @skip;
2007                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2008                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2009             qr/^\s* ENDIF \s*$/x
2010             => sub { die "ENDIF out of scope" if ! @skip;
2011                      pop @skip; },
2012             qr/^\s* ${variable_re} \s* = ${value_re} $/x
2013             => sub {
2014                 if (!@skip || $skip[$#skip] > 0) {
2015                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2016                 }
2017             },
2018             qr/^\s* SUBDIRS \s* = ${value_re} $/x
2019             => sub {
2020                 if (!@skip || $skip[$#skip] > 0) {
2021                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2022                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2023                     }
2024                 }
2025             },
2026             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2027             => sub { $push_to->(\@programs, undef,
2028                                 \$attributes{programs}, $+{ATTRIBS},
2029                                 tokenize($expand_variables->($+{VALUE})))
2030                          if !@skip || $skip[$#skip] > 0; },
2031             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2032             => sub { $push_to->(\@libraries, undef,
2033                                 \$attributes{libraries}, $+{ATTRIBS},
2034                                 tokenize($expand_variables->($+{VALUE})))
2035                          if !@skip || $skip[$#skip] > 0; },
2036             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2037             => sub { $push_to->(\@modules, undef,
2038                                 \$attributes{modules}, $+{ATTRIBS},
2039                                 tokenize($expand_variables->($+{VALUE})))
2040                          if !@skip || $skip[$#skip] > 0; },
2041             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2042             => sub { $push_to->(\@scripts, undef,
2043                                 \$attributes{scripts}, $+{ATTRIBS},
2044                                 tokenize($expand_variables->($+{VALUE})))
2045                          if !@skip || $skip[$#skip] > 0; },
2046             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2047             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2048                                 undef, undef,
2049                                 tokenize($expand_variables->($+{VALUE})))
2050                          if !@skip || $skip[$#skip] > 0; },
2051             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2052             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2053                                 undef, undef,
2054                                 tokenize($expand_variables->($+{VALUE})))
2055                          if !@skip || $skip[$#skip] > 0; },
2056             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
2057             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2058                                 undef, undef,
2059                                 tokenize($expand_variables->($+{VALUE})))
2060                          if !@skip || $skip[$#skip] > 0; },
2061             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
2062             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2063                                 undef, undef,
2064                                 tokenize($expand_variables->($+{VALUE})))
2065                          if !@skip || $skip[$#skip] > 0; },
2066             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2067             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2068                                 undef, undef,
2069                                 tokenize($expand_variables->($+{VALUE})))
2070                          if !@skip || $skip[$#skip] > 0; },
2071             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2072             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2073                                 undef, undef,
2074                                 tokenize($expand_variables->($+{VALUE})))
2075                          if !@skip || $skip[$#skip] > 0; },
2076             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2077             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2078                                 \$attributes{depends}, $+{ATTRIBS},
2079                                 tokenize($expand_variables->($+{VALUE})))
2080                          if !@skip || $skip[$#skip] > 0; },
2081             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2082             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2083                                 undef, undef, $+{VALUE})
2084                          if !@skip || $skip[$#skip] > 0; },
2085             qr/^\s* (?:\#.*)? $/x => sub { },
2086             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2087             "BEFORE" => sub {
2088                 if ($buildinfo_debug) {
2089                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2090                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2091                 }
2092             },
2093             "AFTER" => sub {
2094                 if ($buildinfo_debug) {
2095                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2096                 }
2097             },
2098             );
2099         die "runaway IF?" if (@skip);
2100
2101         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2102                 and !$config{dynamic_engines}) {
2103             die <<"EOF"
2104 ENGINES can only be used if configured with 'dynamic-engine'.
2105 This is usually a fault in a build.info file.
2106 EOF
2107         }
2108
2109         {
2110             my %infos = ( programs  => [ @programs  ],
2111                           libraries => [ @libraries ],
2112                           modules   => [ @modules   ],
2113                           scripts   => [ @scripts   ] );
2114             foreach my $k (keys %infos) {
2115                 foreach (@{$infos{$k}}) {
2116                     my $item = cleanfile($buildd, $_, $blddir);
2117                     $unified_info{$k}->{$item} = 1;
2118
2119                     # Fix up associated attributes
2120                     $unified_info{attributes}->{$k}->{$item} =
2121                         $attributes{$k}->{$_}
2122                         if defined $attributes{$k}->{$_};
2123                 }
2124             }
2125         }
2126
2127         # Check that we haven't defined any library as both shared and
2128         # explicitly static.  That is forbidden.
2129         my @doubles = ();
2130         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2131             (my $l = $_) =~ s/\.a$//;
2132             push @doubles, $l if defined $unified_info{libraries}->{$l};
2133         }
2134         die "these libraries are both explicitly static and shared:\n  ",
2135             join(" ", @doubles), "\n"
2136             if @doubles;
2137
2138         foreach (keys %sources) {
2139             my $dest = $_;
2140             my $ddest = cleanfile($buildd, $_, $blddir);
2141             foreach (@{$sources{$dest}}) {
2142                 my $s = cleanfile($sourced, $_, $blddir);
2143
2144                 # If it's generated or we simply don't find it in the source
2145                 # tree, we assume it's in the build tree.
2146                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2147                     $s = cleanfile($buildd, $_, $blddir);
2148                 }
2149                 # We recognise C++, C and asm files
2150                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2151                     my $o = $_;
2152                     $o =~ s/\.[csS]$/.o/; # C and assembler
2153                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2154                     $o = cleanfile($buildd, $o, $blddir);
2155                     $unified_info{sources}->{$ddest}->{$o} = -1;
2156                     $unified_info{sources}->{$o}->{$s} = -1;
2157                 } elsif ($s =~ /\.rc$/) {
2158                     # We also recognise resource files
2159                     my $o = $_;
2160                     $o =~ s/\.rc$/.res/; # Resource configuration
2161                     my $o = cleanfile($buildd, $o, $blddir);
2162                     $unified_info{sources}->{$ddest}->{$o} = -1;
2163                     $unified_info{sources}->{$o}->{$s} = -1;
2164                 } else {
2165                     $unified_info{sources}->{$ddest}->{$s} = 1;
2166                 }
2167             }
2168         }
2169
2170         foreach (keys %shared_sources) {
2171             my $dest = $_;
2172             my $ddest = cleanfile($buildd, $_, $blddir);
2173             foreach (@{$shared_sources{$dest}}) {
2174                 my $s = cleanfile($sourced, $_, $blddir);
2175
2176                 # If it's generated or we simply don't find it in the source
2177                 # tree, we assume it's in the build tree.
2178                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2179                     $s = cleanfile($buildd, $_, $blddir);
2180                 }
2181
2182                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2183                     # We recognise C++, C and asm files
2184                     my $o = $_;
2185                     $o =~ s/\.[csS]$/.o/; # C and assembler
2186                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2187                     $o = cleanfile($buildd, $o, $blddir);
2188                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2189                     $unified_info{sources}->{$o}->{$s} = -1;
2190                 } elsif ($s =~ /\.rc$/) {
2191                     # We also recognise resource files
2192                     my $o = $_;
2193                     $o =~ s/\.rc$/.res/; # Resource configuration
2194                     my $o = cleanfile($buildd, $o, $blddir);
2195                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2196                     $unified_info{sources}->{$o}->{$s} = -1;
2197                 } elsif ($s =~ /\.ld$/) {
2198                     # We also recognise linker scripts (or corresponding)
2199                     # We know they are generated files
2200                     my $ld = cleanfile($buildd, $_, $blddir);
2201                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2202                 } else {
2203                     die "unrecognised source file type for shared library: $s\n";
2204                 }
2205             }
2206         }
2207
2208         foreach (keys %generate) {
2209             my $dest = $_;
2210             my $ddest = cleanfile($buildd, $_, $blddir);
2211             die "more than one generator for $dest: "
2212                 ,join(" ", @{$generate{$_}}),"\n"
2213                 if scalar @{$generate{$_}} > 1;
2214             my @generator = split /\s+/, $generate{$dest}->[0];
2215             my $gen = $generator[0];
2216             $generator[0] = cleanfile($sourced, $gen, $blddir);
2217
2218             # If the generator is itself generated, it's in the build tree
2219             if ($generate{$gen}) {
2220                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2221             }
2222
2223             $unified_info{generate}->{$ddest} = [ @generator ];
2224         }
2225
2226         foreach (keys %depends) {
2227             my $dest = $_;
2228             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2229
2230             # If the destination doesn't exist in source, it can only be
2231             # a generated file in the build tree.
2232             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2233                 $ddest = cleanfile($buildd, $_, $blddir);
2234             }
2235             foreach (@{$depends{$dest}}) {
2236                 my $d = cleanfile($sourced, $_, $blddir);
2237
2238                 # If we know it's generated, or assume it is because we can't
2239                 # find it in the source tree, we set file we depend on to be
2240                 # in the build tree rather than the source tree.
2241                 if ($d eq $src_configdata
2242                     || (grep { $d eq $_ }
2243                         map { cleanfile($srcdir, $_, $blddir) }
2244                         grep { /\.h$/ } keys %{$unified_info{generate}})
2245                     || ! -f $d) {
2246                     $d = cleanfile($buildd, $_, $blddir);
2247                 }
2248                 $unified_info{depends}->{$ddest}->{$d} = 1;
2249
2250                 # Fix up associated attributes
2251                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2252                     $attributes{depends}->{$dest}->{$_}
2253                     if defined $attributes{depends}->{$dest}->{$_};
2254             }
2255         }
2256
2257         foreach (keys %includes) {
2258             my $dest = $_;
2259             my $ddest = cleanfile($sourced, $_, $blddir);
2260
2261             # If the destination doesn't exist in source, it can only be
2262             # a generated file in the build tree.
2263             if ($ddest eq $src_configdata || ! -f $ddest) {
2264                 $ddest = cleanfile($buildd, $_, $blddir);
2265             }
2266             foreach (@{$includes{$dest}}) {
2267                 my $is = cleandir($sourced, $_, $blddir);
2268                 my $ib = cleandir($buildd, $_, $blddir);
2269                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2270                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2271                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2272                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2273             }
2274         }
2275
2276         foreach my $dest (keys %defines) {
2277             my $ddest;
2278
2279             if ($dest ne "") {
2280                 $ddest = cleanfile($sourced, $dest, $blddir);
2281
2282                 # If the destination doesn't exist in source, it can only
2283                 # be a generated file in the build tree.
2284                 if (! -f $ddest) {
2285                     $ddest = cleanfile($buildd, $dest, $blddir);
2286                 }
2287             }
2288             foreach my $v (@{$defines{$dest}}) {
2289                 $v =~ m|^([^=]*)(=.*)?$|;
2290                 die "0 length macro name not permitted\n" if $1 eq "";
2291                 if ($dest ne "") {
2292                     die "$1 defined more than once\n"
2293                         if defined $unified_info{defines}->{$ddest}->{$1};
2294                     $unified_info{defines}->{$ddest}->{$1} = $2;
2295                 } else {
2296                     die "$1 defined more than once\n"
2297                         if grep { $v eq $_ } @{$config{defines}};
2298                     push @{$config{defines}}, $v;
2299                 }
2300             }
2301         }
2302
2303         foreach my $section (keys %htmldocs) {
2304             foreach (@{$htmldocs{$section}}) {
2305                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2306                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2307             }
2308         }
2309
2310         foreach my $section (keys %mandocs) {
2311             foreach (@{$mandocs{$section}}) {
2312                 my $mandocs = cleanfile($buildd, $_, $blddir);
2313                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2314             }
2315         }
2316     }
2317
2318     my $ordinals_text = join(', ', sort keys %ordinals);
2319     warn <<"EOF" if $ordinals_text;
2320
2321 WARNING: ORDINALS were specified for $ordinals_text
2322 They are ignored and should be replaced with a combination of GENERATE,
2323 DEPEND and SHARED_SOURCE.
2324 EOF
2325
2326
2327     # Go through the sources of all libraries and check that the same basename
2328     # doesn't appear more than once.  Some static library archivers depend on
2329     # them being unique.
2330     {
2331         my $err = 0;
2332         foreach my $prod (keys %{$unified_info{libraries}}) {
2333             my @prod_sources =
2334                 map { keys %{$unified_info{sources}->{$_}} }
2335                 keys %{$unified_info{sources}->{$prod}};
2336             my %srccnt = ();
2337
2338             # Count how many times a given each source basename
2339             # appears for each product.
2340             foreach my $src (@prod_sources) {
2341                 $srccnt{basename $src}++;
2342             }
2343
2344             foreach my $src (keys %srccnt) {
2345                 if ((my $cnt = $srccnt{$src}) > 1) {
2346                     print STDERR "$src appears $cnt times for the product $prod\n";
2347                     $err++
2348                 }
2349             }
2350         }
2351         die if $err > 0;
2352     }
2353
2354     # Massage the result
2355
2356     # If we depend on a header file or a perl module, add an inclusion of
2357     # its directory to allow smoothe inclusion
2358     foreach my $dest (keys %{$unified_info{depends}}) {
2359         next if $dest eq "";
2360         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2361             next unless $d =~ /\.(h|pm)$/;
2362             my $i = dirname($d);
2363             my $spot =
2364                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2365                 ? 'build' : 'source';
2366             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2367                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2368         }
2369     }
2370
2371     # Go through all intermediary files and change their names to something that
2372     # reflects what they will be built for.  Note that for some source files,
2373     # this leads to duplicate object files because they are used multiple times.
2374     # the goal is to rename all object files according to this scheme:
2375     #    {productname}-{midfix}-{origobjname}.[o|res]
2376     # the {midfix} is a keyword indicating the type of product, which is mostly
2377     # valuable for libraries since they come in two forms.
2378     #
2379     # This also reorganises the {sources} and {shared_sources} so that the
2380     # former only contains ALL object files that are supposed to end up in
2381     # static libraries and programs, while the latter contains ALL object files
2382     # that are supposed to end up in shared libraries and DSOs.
2383     # The main reason for having two different source structures is to allow
2384     # the same name to be used for the static and the shared variants of a
2385     # library.
2386     {
2387         # Take copies so we don't get interference from added stuff
2388         my %unified_copy = ();
2389         foreach (('sources', 'shared_sources')) {
2390             $unified_copy{$_} = { %{$unified_info{$_}} }
2391                 if defined($unified_info{$_});
2392             delete $unified_info{$_};
2393         }
2394         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2395             # $intent serves multi purposes:
2396             # - give a prefix for the new object files names
2397             # - in the case of libraries, rearrange the object files so static
2398             #   libraries use the 'sources' structure exclusively, while shared
2399             #   libraries use the 'shared_sources' structure exclusively.
2400             my $intent = {
2401                 programs  => { bin    => { src => [ 'sources' ],
2402                                            dst => 'sources' } },
2403                 libraries => { lib    => { src => [ 'sources' ],
2404                                            dst => 'sources' },
2405                                shlib  => { prodselect =>
2406                                                sub { grep !/\.a$/, @_ },
2407                                            src => [ 'sources',
2408                                                     'shared_sources' ],
2409                                            dst => 'shared_sources' } },
2410                 modules   => { dso    => { src => [ 'sources' ],
2411                                            dst => 'sources' } },
2412                 scripts   => { script => { src => [ 'sources' ],
2413                                            dst => 'sources' } }
2414                } -> {$prodtype};
2415             foreach my $kind (keys %$intent) {
2416                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2417                              && $disabled{shared});
2418
2419                 my @src = @{$intent->{$kind}->{src}};
2420                 my $dst = $intent->{$kind}->{dst};
2421                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2422                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2423                     # %prod_sources has all applicable objects as keys, and
2424                     # their corresponding sources as values
2425                     my %prod_sources =
2426                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2427                         map { keys %{$unified_copy{$_}->{$prod}} }
2428                         @src;
2429                     foreach (keys %prod_sources) {
2430                         # Only affect object files and resource files,
2431                         # the others simply get a new value
2432                         # (+1 instead of -1)
2433                         if ($_ =~ /\.(o|res)$/) {
2434                             (my $prodname = $prod) =~ s|\.a$||;
2435                             my $newobj =
2436                                 catfile(dirname($_),
2437                                         basename($prodname)
2438                                             . '-' . $kind
2439                                             . '-' . basename($_));
2440                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2441                             foreach my $src (@{$prod_sources{$_}}) {
2442                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2443                             }
2444                             # Adjust dependencies
2445                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2446                                 $unified_info{depends}->{$_}->{$deps} = -1;
2447                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2448                             }
2449                             # Adjust includes
2450                             foreach my $k (('source', 'build')) {
2451                                 next unless
2452                                     defined($unified_info{includes}->{$_}->{$k});
2453                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2454                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2455                             }
2456                         } else {
2457                             $unified_info{$dst}->{$prod}->{$_} = 1;
2458                         }
2459                     }
2460                 }
2461             }
2462         }
2463     }
2464
2465     # At this point, we have a number of sources with the value -1.  They
2466     # aren't part of the local build and are probably meant for a different
2467     # platform, and can therefore be cleaned away.  That happens when making
2468     # %unified_info more efficient below.
2469
2470     ### Make unified_info a bit more efficient
2471     # One level structures
2472     foreach (("programs", "libraries", "modules", "scripts")) {
2473         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2474     }
2475     # Two level structures
2476     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2477                      "htmldocs", "mandocs")) {
2478         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2479             my @items =
2480                 sort
2481                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2482                 keys %{$unified_info{$l1}->{$l2}};
2483             if (@items) {
2484                 $unified_info{$l1}->{$l2} = [ @items ];
2485             } else {
2486                 delete $unified_info{$l1}->{$l2};
2487             }
2488         }
2489     }
2490     # Defines
2491     foreach my $dest (sort keys %{$unified_info{defines}}) {
2492         $unified_info{defines}->{$dest}
2493             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2494                 sort keys %{$unified_info{defines}->{$dest}} ];
2495     }
2496     # Includes
2497     foreach my $dest (sort keys %{$unified_info{includes}}) {
2498         if (defined($unified_info{includes}->{$dest}->{build})) {
2499             my @source_includes = ();
2500             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2501                 if defined($unified_info{includes}->{$dest}->{source});
2502             $unified_info{includes}->{$dest} =
2503                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2504             foreach my $inc (@source_includes) {
2505                 push @{$unified_info{includes}->{$dest}}, $inc
2506                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2507             }
2508         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2509             $unified_info{includes}->{$dest} =
2510                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2511         } else {
2512             delete $unified_info{includes}->{$dest};
2513         }
2514     }
2515
2516     # For convenience collect information regarding directories where
2517     # files are generated, those generated files and the end product
2518     # they end up in where applicable.  Then, add build rules for those
2519     # directories
2520     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2521                      "dso" => [ @{$unified_info{modules}} ],
2522                      "bin" => [ @{$unified_info{programs}} ],
2523                      "script" => [ @{$unified_info{scripts}} ],
2524                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2525                                   keys %{$unified_info{htmldocs} // {}}),
2526                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2527                                   keys %{$unified_info{mandocs} // {}}) ] );
2528     foreach my $type (keys %loopinfo) {
2529         foreach my $product (@{$loopinfo{$type}}) {
2530             my %dirs = ();
2531             my $pd = dirname($product);
2532
2533             foreach (@{$unified_info{sources}->{$product} // []},
2534                      @{$unified_info{shared_sources}->{$product} // []}) {
2535                 my $d = dirname($_);
2536
2537                 # We don't want to create targets for source directories
2538                 # when building out of source
2539                 next if ($config{sourcedir} ne $config{builddir}
2540                              && $d =~ m|^\Q$config{sourcedir}\E|);
2541                 # We already have a "test" target, and the current directory
2542                 # is just silly to make a target for
2543                 next if $d eq "test" || $d eq ".";
2544
2545                 $dirs{$d} = 1;
2546                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2547                     if $d ne $pd;
2548             }
2549             foreach (keys %dirs) {
2550                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2551                     $product;
2552             }
2553         }
2554     }
2555 }
2556
2557 # For the schemes that need it, we provide the old *_obj configs
2558 # from the *_asm_obj ones
2559 foreach (grep /_(asm|aux)_src$/, keys %target) {
2560     my $src = $_;
2561     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2562     $target{$obj} = $target{$src};
2563     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2564     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2565 }
2566
2567 # Write down our configuration where it fits #########################
2568
2569 my %template_vars = (
2570     config => \%config,
2571     target => \%target,
2572     disablables => \@disablables,
2573     disablables_int => \@disablables_int,
2574     disabled => \%disabled,
2575     withargs => \%withargs,
2576     unified_info => \%unified_info,
2577     tls => \@tls,
2578     dtls => \@dtls,
2579     makevars => [ sort keys %user ],
2580     disabled_info => \%disabled_info,
2581     user_crossable => \@user_crossable,
2582 );
2583 my $configdata_outname = 'configdata.pm';
2584 print "Creating $configdata_outname\n";
2585 open CONFIGDATA, ">$configdata_outname.new"
2586             or die "Trying to create $configdata_outname.new: $!";
2587 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2588 my $configdata_tmpl =
2589     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2590 $configdata_tmpl->fill_in(
2591     FILENAME => $configdata_tmplname,
2592     OUTPUT => \*CONFIGDATA,
2593     HASH => { %template_vars,
2594               autowarntext => [
2595                   'WARNING: do not edit!',
2596                   "Generated by Configure from $configdata_tmplname",
2597               ] }
2598 ) or die $Text::Template::ERROR;
2599 close CONFIGDATA;
2600 rename "$configdata_outname.new", $configdata_outname;
2601 if ($builder_platform eq 'unix') {
2602     my $mode = (0755 & ~umask);
2603     chmod $mode, 'configdata.pm'
2604         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2605 }
2606
2607 print "Running $configdata_outname\n";
2608 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2609 my $cmd = "$perlcmd $configdata_outname";
2610 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2611 system($cmd);
2612 exit 1 if $? != 0;
2613
2614 $SIG{__DIE__} = $orig_death_handler;
2615
2616 print <<"EOF" if ($disabled{threads} eq "unavailable");
2617
2618 The library could not be configured for supporting multi-threaded
2619 applications as the compiler options required on this system are not known.
2620 See file INSTALL.md for details if you need multi-threading.
2621 EOF
2622
2623 print <<"EOF" if ($no_shared_warn);
2624
2625 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2626 platform, so we will pretend you gave the option 'no-pic', which also disables
2627 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2628 or position independent code, please let us know (but please first make sure
2629 you have tried with a current version of OpenSSL).
2630 EOF
2631
2632 print <<"EOF";
2633
2634 **********************************************************************
2635 ***                                                                ***
2636 ***   OpenSSL has been successfully configured                     ***
2637 ***                                                                ***
2638 ***   If you encounter a problem while building, please open an    ***
2639 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2640 ***   and include the output from the following command:           ***
2641 ***                                                                ***
2642 ***       perl configdata.pm --dump                                ***
2643 ***                                                                ***
2644 ***   (If you are new to OpenSSL, you might want to consult the    ***
2645 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
2646 ***                                                                ***
2647 **********************************************************************
2648 EOF
2649
2650 exit(0);
2651
2652 ######################################################################
2653 #
2654 # Helpers and utility functions
2655 #
2656
2657 # Death handler, to print a helpful message in case of failure #######
2658 #
2659 sub death_handler {
2660     die @_ if $^S;              # To prevent the added message in eval blocks
2661     my $build_file = $target{build_file} // "build file";
2662     my @message = ( <<"_____", @_ );
2663
2664 Failure!  $build_file wasn't produced.
2665 Please read INSTALL.md and associated NOTES files.  You may also have to
2666 look over your available compiler tool chain or change your configuration.
2667
2668 _____
2669
2670     # Dying is terminal, so it's ok to reset the signal handler here.
2671     $SIG{__DIE__} = $orig_death_handler;
2672     die @message;
2673 }
2674
2675 # Configuration file reading #########################################
2676
2677 # Note: All of the helper functions are for lazy evaluation.  They all
2678 # return a CODE ref, which will return the intended value when evaluated.
2679 # Thus, whenever there's mention of a returned value, it's about that
2680 # intended value.
2681
2682 # Helper function to implement conditional value variants, with a default
2683 # plus additional values based on the value of $config{build_type}.
2684 # Arguments are given in hash table form:
2685 #
2686 #       picker(default => "Basic string: ",
2687 #              debug   => "debug",
2688 #              release => "release")
2689 #
2690 # When configuring with --debug, the resulting string will be
2691 # "Basic string: debug", and when not, it will be "Basic string: release"
2692 #
2693 # This can be used to create variants of sets of flags according to the
2694 # build type:
2695 #
2696 #       cflags => picker(default => "-Wall",
2697 #                        debug   => "-g -O0",
2698 #                        release => "-O3")
2699 #
2700 sub picker {
2701     my %opts = @_;
2702     return sub { add($opts{default} || (),
2703                      $opts{$config{build_type}} || ())->(); }
2704 }
2705
2706 # Helper function to combine several values of different types into one.
2707 # This is useful if you want to combine a string with the result of a
2708 # lazy function, such as:
2709 #
2710 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2711 #
2712 sub combine {
2713     my @stuff = @_;
2714     return sub { add(@stuff)->(); }
2715 }
2716
2717 # Helper function to implement conditional values depending on the value
2718 # of $disabled{threads}.  Can be used as follows:
2719 #
2720 #       cflags => combine("-Wall", threads("-pthread"))
2721 #
2722 sub threads {
2723     my @flags = @_;
2724     return sub { add($disabled{threads} ? () : @flags)->(); }
2725 }
2726
2727 sub shared {
2728     my @flags = @_;
2729     return sub { add($disabled{shared} ? () : @flags)->(); }
2730 }
2731
2732 our $add_called = 0;
2733 # Helper function to implement adding values to already existing configuration
2734 # values.  It handles elements that are ARRAYs, CODEs and scalars
2735 sub _add {
2736     my $separator = shift;
2737
2738     # If there's any ARRAY in the collection of values OR the separator
2739     # is undef, we will return an ARRAY of combined values, otherwise a
2740     # string of joined values with $separator as the separator.
2741     my $found_array = !defined($separator);
2742
2743     my @values =
2744         map {
2745             my $res = $_;
2746             while (ref($res) eq "CODE") {
2747                 $res = $res->();
2748             }
2749             if (defined($res)) {
2750                 if (ref($res) eq "ARRAY") {
2751                     $found_array = 1;
2752                     @$res;
2753                 } else {
2754                     $res;
2755                 }
2756             } else {
2757                 ();
2758             }
2759     } (@_);
2760
2761     $add_called = 1;
2762
2763     if ($found_array) {
2764         [ @values ];
2765     } else {
2766         join($separator, grep { defined($_) && $_ ne "" } @values);
2767     }
2768 }
2769 sub add_before {
2770     my $separator = " ";
2771     if (ref($_[$#_]) eq "HASH") {
2772         my $opts = pop;
2773         $separator = $opts->{separator};
2774     }
2775     my @x = @_;
2776     sub { _add($separator, @x, @_) };
2777 }
2778 sub add {
2779     my $separator = " ";
2780     if (ref($_[$#_]) eq "HASH") {
2781         my $opts = pop;
2782         $separator = $opts->{separator};
2783     }
2784     my @x = @_;
2785     sub { _add($separator, @_, @x) };
2786 }
2787
2788 sub read_eval_file {
2789     my $fname = shift;
2790     my $content;
2791     my @result;
2792
2793     open F, "< $fname" or die "Can't open '$fname': $!\n";
2794     {
2795         undef local $/;
2796         $content = <F>;
2797     }
2798     close F;
2799     {
2800         local $@;
2801
2802         @result = ( eval $content );
2803         warn $@ if $@;
2804     }
2805     return wantarray ? @result : $result[0];
2806 }
2807
2808 # configuration reader, evaluates the input file as a perl script and expects
2809 # it to fill %targets with target configurations.  Those are then added to
2810 # %table.
2811 sub read_config {
2812     my $fname = shift;
2813     my %targets;
2814
2815     {
2816         # Protect certain tables from tampering
2817         local %table = ();
2818
2819         %targets = read_eval_file($fname);
2820     }
2821     my %preexisting = ();
2822     foreach (sort keys %targets) {
2823         $preexisting{$_} = 1 if $table{$_};
2824     }
2825     die <<"EOF",
2826 The following config targets from $fname
2827 shadow pre-existing config targets with the same name:
2828 EOF
2829         map { "  $_\n" } sort keys %preexisting
2830         if %preexisting;
2831
2832
2833     # For each target, check that it's configured with a hash table.
2834     foreach (keys %targets) {
2835         if (ref($targets{$_}) ne "HASH") {
2836             if (ref($targets{$_}) eq "") {
2837                 warn "Deprecated target configuration for $_, ignoring...\n";
2838             } else {
2839                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2840             }
2841             delete $targets{$_};
2842         } else {
2843             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2844         }
2845     }
2846
2847     %table = (%table, %targets);
2848
2849 }
2850
2851 # configuration resolver.  Will only resolve all the lazy evaluation
2852 # codeblocks for the chosen target and all those it inherits from,
2853 # recursively
2854 sub resolve_config {
2855     my $target = shift;
2856     my @breadcrumbs = @_;
2857
2858 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2859
2860     if (grep { $_ eq $target } @breadcrumbs) {
2861         die "inherit_from loop!  target backtrace:\n  "
2862             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2863     }
2864
2865     if (!defined($table{$target})) {
2866         warn "Warning! target $target doesn't exist!\n";
2867         return ();
2868     }
2869     # Recurse through all inheritances.  They will be resolved on the
2870     # fly, so when this operation is done, they will all just be a
2871     # bunch of attributes with string values.
2872     # What we get here, though, are keys with references to lists of
2873     # the combined values of them all.  We will deal with lists after
2874     # this stage is done.
2875     my %combined_inheritance = ();
2876     if ($table{$target}->{inherit_from}) {
2877         my @inherit_from =
2878             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2879         foreach (@inherit_from) {
2880             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2881
2882             # 'template' is a marker that's considered private to
2883             # the config that had it.
2884             delete $inherited_config{template};
2885
2886             foreach (keys %inherited_config) {
2887                 if (!$combined_inheritance{$_}) {
2888                     $combined_inheritance{$_} = [];
2889                 }
2890                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2891             }
2892         }
2893     }
2894
2895     # We won't need inherit_from in this target any more, since we've
2896     # resolved all the inheritances that lead to this
2897     delete $table{$target}->{inherit_from};
2898
2899     # Now is the time to deal with those lists.  Here's the place to
2900     # decide what shall be done with those lists, all based on the
2901     # values of the target we're currently dealing with.
2902     # - If a value is a coderef, it will be executed with the list of
2903     #   inherited values as arguments.
2904     # - If the corresponding key doesn't have a value at all or is the
2905     #   empty string, the inherited value list will be run through the
2906     #   default combiner (below), and the result becomes this target's
2907     #   value.
2908     # - Otherwise, this target's value is assumed to be a string that
2909     #   will simply override the inherited list of values.
2910     my $default_combiner = add();
2911
2912     my %all_keys =
2913         map { $_ => 1 } (keys %combined_inheritance,
2914                          keys %{$table{$target}});
2915
2916     sub process_values {
2917         my $object    = shift;
2918         my $inherited = shift;  # Always a [ list ]
2919         my $target    = shift;
2920         my $entry     = shift;
2921
2922         $add_called = 0;
2923
2924         while(ref($object) eq "CODE") {
2925             $object = $object->(@$inherited);
2926         }
2927         if (!defined($object)) {
2928             return ();
2929         }
2930         elsif (ref($object) eq "ARRAY") {
2931             local $add_called;  # To make sure recursive calls don't affect it
2932             return [ map { process_values($_, $inherited, $target, $entry) }
2933                      @$object ];
2934         } elsif (ref($object) eq "") {
2935             return $object;
2936         } else {
2937             die "cannot handle reference type ",ref($object)
2938                 ," found in target ",$target," -> ",$entry,"\n";
2939         }
2940     }
2941
2942     foreach (sort keys %all_keys) {
2943         my $previous = $combined_inheritance{$_};
2944
2945         # Current target doesn't have a value for the current key?
2946         # Assign it the default combiner, the rest of this loop body
2947         # will handle it just like any other coderef.
2948         if (!exists $table{$target}->{$_}) {
2949             $table{$target}->{$_} = $default_combiner;
2950         }
2951
2952         $table{$target}->{$_} = process_values($table{$target}->{$_},
2953                                                $combined_inheritance{$_},
2954                                                $target, $_);
2955         unless(defined($table{$target}->{$_})) {
2956             delete $table{$target}->{$_};
2957         }
2958 #        if ($extra_checks &&
2959 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2960 #            warn "$_ got replaced in $target\n";
2961 #        }
2962     }
2963
2964     # Finally done, return the result.
2965     return %{$table{$target}};
2966 }
2967
2968 sub usage
2969         {
2970         print STDERR $usage;
2971         print STDERR "\npick os/compiler from:\n";
2972         my $j=0;
2973         my $i;
2974         my $k=0;
2975         foreach $i (sort keys %table)
2976                 {
2977                 next if $table{$i}->{template};
2978                 next if $i =~ /^debug/;
2979                 $k += length($i) + 1;
2980                 if ($k > 78)
2981                         {
2982                         print STDERR "\n";
2983                         $k=length($i);
2984                         }
2985                 print STDERR $i . " ";
2986                 }
2987         foreach $i (sort keys %table)
2988                 {
2989                 next if $table{$i}->{template};
2990                 next if $i !~ /^debug/;
2991                 $k += length($i) + 1;
2992                 if ($k > 78)
2993                         {
2994                         print STDERR "\n";
2995                         $k=length($i);
2996                         }
2997                 print STDERR $i . " ";
2998                 }
2999         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3000         exit(1);
3001         }
3002
3003 sub compiler_predefined {
3004     state %predefined;
3005     my $cc = shift;
3006
3007     return () if $^O eq 'VMS';
3008
3009     die 'compiler_predefined called without a compiler command'
3010         unless $cc;
3011
3012     if (! $predefined{$cc}) {
3013
3014         $predefined{$cc} = {};
3015
3016         # collect compiler pre-defines from gcc or gcc-alike...
3017         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3018         while (my $l = <PIPE>) {
3019             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3020             $predefined{$cc}->{$1} = $2 // '';
3021         }
3022         close(PIPE);
3023     }
3024
3025     return %{$predefined{$cc}};
3026 }
3027
3028 sub which
3029 {
3030     my ($name)=@_;
3031
3032     if (eval { require IPC::Cmd; 1; }) {
3033         IPC::Cmd->import();
3034         return scalar IPC::Cmd::can_run($name);
3035     } else {
3036         # if there is $directories component in splitpath,
3037         # then it's not something to test with $PATH...
3038         return $name if (File::Spec->splitpath($name))[1];
3039
3040         foreach (File::Spec->path()) {
3041             my $fullpath = catfile($_, "$name$target{exe_extension}");
3042             if (-f $fullpath and -x $fullpath) {
3043                 return $fullpath;
3044             }
3045         }
3046     }
3047 }
3048
3049 sub env
3050 {
3051     my $name = shift;
3052     my %opts = @_;
3053
3054     unless ($opts{cacheonly}) {
3055         # Note that if $ENV{$name} doesn't exist or is undefined,
3056         # $config{perlenv}->{$name} will be created with the value
3057         # undef.  This is intentional.
3058
3059         $config{perlenv}->{$name} = $ENV{$name}
3060             if ! exists $config{perlenv}->{$name};
3061     }
3062     return $config{perlenv}->{$name};
3063 }
3064
3065 # Configuration printer ##############################################
3066
3067 sub print_table_entry
3068 {
3069     local $now_printing = shift;
3070     my %target = resolve_config($now_printing);
3071     my $type = shift;
3072
3073     # Don't print the templates
3074     return if $target{template};
3075
3076     my @sequence = (
3077         "sys_id",
3078         "cpp",
3079         "cppflags",
3080         "defines",
3081         "includes",
3082         "cc",
3083         "cflags",
3084         "ld",
3085         "lflags",
3086         "loutflag",
3087         "ex_libs",
3088         "bn_ops",
3089         "poly1035_asm_src",
3090         "thread_scheme",
3091         "perlasm_scheme",
3092         "dso_scheme",
3093         "shared_target",
3094         "shared_cflag",
3095         "shared_defines",
3096         "shared_ldflag",
3097         "shared_rcflag",
3098         "shared_extension",
3099         "dso_extension",
3100         "obj_extension",
3101         "exe_extension",
3102         "ranlib",
3103         "ar",
3104         "arflags",
3105         "aroutflag",
3106         "rc",
3107         "rcflags",
3108         "rcoutflag",
3109         "mt",
3110         "mtflags",
3111         "mtinflag",
3112         "mtoutflag",
3113         "multilib",
3114         "build_scheme",
3115         );
3116
3117     if ($type eq "TABLE") {
3118         print "\n";
3119         print "*** $now_printing\n";
3120         foreach (@sequence) {
3121             if (ref($target{$_}) eq "ARRAY") {
3122                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3123             } else {
3124                 printf "\$%-12s = %s\n", $_, $target{$_};
3125             }
3126         }
3127     } elsif ($type eq "HASH") {
3128         my $largest =
3129             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3130         print "    '$now_printing' => {\n";
3131         foreach (@sequence) {
3132             if ($target{$_}) {
3133                 if (ref($target{$_}) eq "ARRAY") {
3134                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3135                 } else {
3136                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3137                 }
3138             }
3139         }
3140         print "    },\n";
3141     }
3142 }
3143
3144 # Utility routines ###################################################
3145
3146 # On VMS, if the given file is a logical name, File::Spec::Functions
3147 # will consider it an absolute path.  There are cases when we want a
3148 # purely syntactic check without checking the environment.
3149 sub isabsolute {
3150     my $file = shift;
3151
3152     # On non-platforms, we just use file_name_is_absolute().
3153     return file_name_is_absolute($file) unless $^O eq "VMS";
3154
3155     # If the file spec includes a device or a directory spec,
3156     # file_name_is_absolute() is perfectly safe.
3157     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3158
3159     # Here, we know the given file spec isn't absolute
3160     return 0;
3161 }
3162
3163 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3164 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3165 # realpath() requires that at least all path components except the last is an
3166 # existing directory.  On VMS, the last component of the directory spec must
3167 # exist.
3168 sub absolutedir {
3169     my $dir = shift;
3170
3171     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3172     # will return the volume name for the device, no matter what.  Also,
3173     # it will return an incorrect directory spec if the argument is a
3174     # directory that doesn't exist.
3175     if ($^O eq "VMS") {
3176         return rel2abs($dir);
3177     }
3178
3179     # We use realpath() on Unix, since no other will properly clean out
3180     # a directory spec.
3181     use Cwd qw/realpath/;
3182
3183     return realpath($dir);
3184 }
3185
3186 sub quotify {
3187     my %processors = (
3188         perl    => sub { my $x = shift;
3189                          $x =~ s/([\\\$\@"])/\\$1/g;
3190                          return '"'.$x.'"'; },
3191         maybeshell => sub { my $x = shift;
3192                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3193                             if ($x ne $y || $x =~ m|\s|) {
3194                                 return '"'.$y.'"';
3195                             } else {
3196                                 return $x;
3197                             }
3198                         },
3199         );
3200     my $for = shift;
3201     my $processor =
3202         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3203
3204     return map { $processor->($_); } @_;
3205 }
3206
3207 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3208 # $filename is a file name to read from
3209 # $line_concat_cond_re is a regexp detecting a line continuation ending
3210 # $line_concat is a CODEref that takes care of concatenating two lines
3211 sub collect_from_file {
3212     my $filename = shift;
3213     my $line_concat_cond_re = shift;
3214     my $line_concat = shift;
3215
3216     open my $fh, $filename || die "unable to read $filename: $!\n";
3217     return sub {
3218         my $saved_line = "";
3219         $_ = "";
3220         while (<$fh>) {
3221             s|\R$||;
3222             if (defined $line_concat) {
3223                 $_ = $line_concat->($saved_line, $_);
3224                 $saved_line = "";
3225             }
3226             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3227                 $saved_line = $_;
3228                 next;
3229             }
3230             return $_;
3231         }
3232         die "$filename ending with continuation line\n" if $_;
3233         close $fh;
3234         return undef;
3235     }
3236 }
3237
3238 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3239 # $array is an ARRAYref of lines
3240 # $line_concat_cond_re is a regexp detecting a line continuation ending
3241 # $line_concat is a CODEref that takes care of concatenating two lines
3242 sub collect_from_array {
3243     my $array = shift;
3244     my $line_concat_cond_re = shift;
3245     my $line_concat = shift;
3246     my @array = (@$array);
3247
3248     return sub {
3249         my $saved_line = "";
3250         $_ = "";
3251         while (defined($_ = shift @array)) {
3252             s|\R$||;
3253             if (defined $line_concat) {
3254                 $_ = $line_concat->($saved_line, $_);
3255                 $saved_line = "";
3256             }
3257             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3258                 $saved_line = $_;
3259                 next;
3260             }
3261             return $_;
3262         }
3263         die "input text ending with continuation line\n" if $_;
3264         return undef;
3265     }
3266 }
3267
3268 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3269 # $lineiterator is a CODEref that delivers one line at a time.
3270 # All following arguments are regex/CODEref pairs, where the regexp detects a
3271 # line and the CODEref does something with the result of the regexp.
3272 sub collect_information {
3273     my $lineiterator = shift;
3274     my %collectors = @_;
3275
3276     while(defined($_ = $lineiterator->())) {
3277         s|\R$||;
3278         my $found = 0;
3279         if ($collectors{"BEFORE"}) {
3280             $collectors{"BEFORE"}->($_);
3281         }
3282         foreach my $re (keys %collectors) {
3283             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3284                 $collectors{$re}->($lineiterator);
3285                 $found = 1;
3286             };
3287         }
3288         if ($collectors{"OTHERWISE"}) {
3289             $collectors{"OTHERWISE"}->($lineiterator, $_)
3290                 unless $found || !defined $collectors{"OTHERWISE"};
3291         }
3292         if ($collectors{"AFTER"}) {
3293             $collectors{"AFTER"}->($_);
3294         }
3295     }
3296 }
3297
3298 # tokenize($line)
3299 # tokenize($line,$separator)
3300 # $line is a line of text to split up into tokens
3301 # $separator [optional] is a regular expression that separates the tokens,
3302 # the default being spaces.  Do not use quotes of any kind as separators,
3303 # that will give undefined results.
3304 # Returns a list of tokens.
3305 #
3306 # Tokens are divided by separator (spaces by default).  If the tokens include
3307 # the separators, they have to be quoted with single or double quotes.
3308 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3309 # with backslash.
3310 # Basically, the same quoting rules apply for " and ' as in any
3311 # Unix shell.
3312 sub tokenize {
3313     my $line = my $debug_line = shift;
3314     my $separator = shift // qr|\s+|;
3315     my @result = ();
3316
3317     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3318         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3319     }
3320
3321     while ($line =~ s|^${separator}||, $line ne "") {
3322         my $token = "";
3323     again:
3324         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3325         $token .= $1;
3326         $line = $2.$';
3327
3328         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3329             $token .= $1;
3330             $line = $';
3331             goto again;
3332         } elsif ($line =~ m/^'([^']*)'/) {
3333             $token .= $1;
3334             $line = $';
3335             goto again;
3336         }
3337         push @result, $token;
3338     }
3339
3340     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3341         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3342         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3343     }
3344     return @result;
3345 }