Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-dso        do not compile in any native shared-library methods. This
  63 #               will ensure that all methods just return NULL.
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # enable-weak-ssl-ciphers
  70 #               Enable weak ciphers that are disabled by default.
  71 # 386           generate 80386 code in assembly modules
  72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  73 #               mentioned '386' option implies this one
  74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  75 # -<xxx> +<xxx> compiler options are passed through
  76 # -static       while -static is also a pass-through compiler option (and
  77 #               as such is limited to environments where it's actually
  78 #               meaningful), it triggers a number configuration options,
  79 #               namely no-dso, no-pic, no-shared and no-threads. It is
  80 #               argued that the only reason to produce statically linked
  81 #               binaries (and in context it means executables linked with
  82 #               -static flag, and not just executables linked with static
  83 #               libcrypto.a) is to eliminate dependency on specific run-time,
  84 #               a.k.a. libc version. The mentioned config options are meant
  85 #               to achieve just that. Unfortunately on Linux it's impossible
  86 #               to eliminate the dependency completely for openssl executable
  87 #               because of getaddrinfo and gethostbyname calls, which can
  88 #               invoke dynamically loadable library facility anyway to meet
  89 #               the lookup requests. For this reason on Linux statically
  90 #               linked openssl executable has rather debugging value than
  91 #               production quality.
  92 #
  93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  94 #               provided to stack calls. Generates unique stack functions for
  95 #               each possible stack type.
  96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  98 # Following are set automatically by this script
  99 #
 100 # MD5_ASM       use some extra md5 assembler,
 101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 102 # RMD160_ASM    use some extra ripemd160 assembler,
 103 # SHA256_ASM    sha256_block is implemented in assembler
 104 # SHA512_ASM    sha512_block is implemented in assembler
 105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 106
 107 # Minimum warning options... any contributions to OpenSSL should at least get
 108 # past these.
 109
 110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 111 # -DPEDANTIC complements -pedantic and is meant to mask code that
 112 # is not strictly standard-compliant and/or implementation-specific,
 113 # e.g. inline assembly, disregards to alignment requirements, such
 114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 115 # to be used even in sanitized builds, because sanitizer too is
 116 # supposed to and does take notice of non-standard behaviour. Then
 117 # -pedantic with pre-C9x compiler would also complain about 'long
 118 # long' not being supported. As 64-bit algorithms are common now,
 119 # it grew impossible to resolve this without sizeable additional
 120 # code, so we just tell compiler to be pedantic about everything
 121 # but 'long long' type.
 122
 123 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 124         . " -DPEDANTIC -pedantic -Wno-long-long"
 125         . " -Wall"
 126         . " -Wextra"
 127         . " -Wno-unused-parameter"
 128         . " -Wno-missing-field-initializers"
 129         . " -Wswitch"
 130         . " -Wsign-compare"
 131         . " -Wmissing-prototypes"
 132         . " -Wstrict-prototypes"
 133         . " -Wshadow"
 134         . " -Wformat"
 135         . " -Wtype-limits"
 136         . " -Wundef"
 137         . " -Werror"
 138         ;
 139
 140 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 141 # TODO(openssl-team): fix problems and investigate if (at least) the
 142 # following warnings can also be enabled:
 143 #       -Wcast-align
 144 #       -Wunreachable-code -- no, too ugly/compiler-specific
 145 #       -Wlanguage-extension-token -- no, we use asm()
 146 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 147 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 148 my $clang_devteam_warn = ""
 149         . " -Wswitch-default"
 150         . " -Wno-parentheses-equality"
 151         . " -Wno-language-extension-token"
 152         . " -Wno-extended-offsetof"
 153         . " -Wconditional-uninitialized"
 154         . " -Wincompatible-pointer-types-discards-qualifiers"
 155         . " -Wmissing-variable-declarations"
 156         . " -Wno-unknown-warning-option"
 157         ;
 158
 159 # This adds backtrace information to the memory leak info.  Is only used
 160 # when crypto-mdebug-backtrace is enabled.
 161 my $memleak_devteam_backtrace = "-rdynamic";
 162
 163 my $strict_warnings = 0;
 164
 165 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 166 # which would cover all BSD flavors. -pthread applies to them all,
 167 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 168 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 169 # which has to be accompanied by explicit -D_THREAD_SAFE and
 170 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 171 # seems to be sufficient?
 172 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 173
 174 #
 175 # API compatibility name to version number mapping.
 176 #
 177 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 178 my $apitable = {
 179     "3.0.0" => 3,
 180     "1.1.1" => 2,
 181     "1.1.0" => 2,
 182     "1.0.2" => 1,
 183     "1.0.1" => 1,
 184     "1.0.0" => 1,
 185     "0.9.8" => 0,
 186 };
 187
 188 our %table = ();
 189 our %config = ();
 190 our %withargs = ();
 191 our $now_printing;      # set to current entry's name in print_table_entry
 192                         # (todo: right thing would be to encapsulate name
 193                         # into %target [class] and make print_table_entry
 194                         # a method)
 195
 196 # Forward declarations ###############################################
 197
 198 # read_config(filename)
 199 #
 200 # Reads a configuration file and populates %table with the contents
 201 # (which the configuration file places in %targets).
 202 sub read_config;
 203
 204 # resolve_config(target)
 205 #
 206 # Resolves all the late evaluations, inheritances and so on for the
 207 # chosen target and any target it inherits from.
 208 sub resolve_config;
 209
 210
 211 # Information collection #############################################
 212
 213 # Unified build supports separate build dir
 214 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 215 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 216 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 217
 218 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 219
 220 $config{sourcedir} = abs2rel($srcdir);
 221 $config{builddir} = abs2rel($blddir);
 222
 223 # Collect reconfiguration information if needed
 224 my @argvcopy=@ARGV;
 225
 226 if (grep /^reconf(igure)?$/, @argvcopy) {
 227     die "reconfiguring with other arguments present isn't supported"
 228         if scalar @argvcopy > 1;
 229     if (-f "./configdata.pm") {
 230         my $file = "./configdata.pm";
 231         unless (my $return = do $file) {
 232             die "couldn't parse $file: $@" if $@;
 233             die "couldn't do $file: $!"    unless defined $return;
 234             die "couldn't run $file"       unless $return;
 235         }
 236
 237         @argvcopy = defined($configdata::config{perlargv}) ?
 238             @{$configdata::config{perlargv}} : ();
 239         die "Incorrect data to reconfigure, please do a normal configuration\n"
 240             if (grep(/^reconf/,@argvcopy));
 241         $config{perlenv} = $configdata::config{perlenv} // {};
 242     } else {
 243         die "Insufficient data to reconfigure, please do a normal configuration\n";
 244     }
 245 }
 246
 247 $config{perlargv} = [ @argvcopy ];
 248
 249 # Collect version numbers
 250 $config{major} = "unknown";
 251 $config{minor} = "unknown";
 252 $config{patch} = "unknown";
 253 $config{prerelease} = "";
 254 $config{build_metadata} = "";
 255 $config{shlib_version} = "unknown";
 256
 257 collect_information(
 258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 259     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 260         sub { $config{major} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 262         sub { $config{minor} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 264         sub { $config{patch} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{prerelease} = $1; },
 267     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 268         sub { $config{build_metadata} = $1; },
 269     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 270         sub { $config{shlib_version} = $1; },
 271     );
 272 die "erroneous version information in opensslv.h: ",
 273     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 274     if ($config{major} eq "unknown"
 275             || $config{minor} eq "unknown"
 276             || $config{patch} eq "unknown"
 277             || $config{shlib_version} eq "unknown");
 278
 279 # Collect target configurations
 280
 281 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 282 foreach (sort glob($pattern)) {
 283     &read_config($_);
 284 }
 285
 286 if (defined env($local_config_envname)) {
 287     if ($^O eq 'VMS') {
 288         # VMS environment variables are logical names,
 289         # which can be used as is
 290         $pattern = $local_config_envname . ':' . '*.conf';
 291     } else {
 292         $pattern = catfile(env($local_config_envname), '*.conf');
 293     }
 294
 295     foreach (sort glob($pattern)) {
 296         &read_config($_);
 297     }
 298 }
 299
 300 # Save away perl command information
 301 $config{perl_cmd} = $^X;
 302 $config{perl_version} = $Config{version};
 303 $config{perl_archname} = $Config{archname};
 304
 305 $config{prefix}="";
 306 $config{openssldir}="";
 307 $config{processor}="";
 308 $config{libdir}="";
 309 my $auto_threads=1;    # enable threads automatically? true by default
 310 my $default_ranlib;
 311
 312 # Known TLS and DTLS protocols
 313 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 314 my @dtls = qw(dtls1 dtls1_2);
 315
 316 # Explicitly known options that are possible to disable.  They can
 317 # be regexps, and will be used like this: /^no-${option}$/
 318 # For developers: keep it sorted alphabetically
 319
 320 my @disablables = (
 321     "ktls",
 322     "afalgeng",
 323     "aria",
 324     "asan",
 325     "asm",
 326     "async",
 327     "autoalginit",
 328     "autoerrinit",
 329     "autoload-config",
 330     "bf",
 331     "blake2",
 332     "camellia",
 333     "capieng",
 334     "cast",
 335     "chacha",
 336     "cmac",
 337     "cms",
 338     "comp",
 339     "crypto-mdebug",
 340     "crypto-mdebug-backtrace",
 341     "ct",
 342     "deprecated",
 343     "des",
 344     "devcryptoeng",
 345     "dgram",
 346     "dh",
 347     "dsa",
 348     "dso",
 349     "dtls",
 350     "dynamic-engine",
 351     "ec",
 352     "ec2m",
 353     "ecdh",
 354     "ecdsa",
 355     "ec_nistp_64_gcc_128",
 356     "egd",
 357     "engine",
 358     "err",
 359     "external-tests",
 360     "filenames",
 361     "fuzz-libfuzzer",
 362     "fuzz-afl",
 363     "gost",
 364     "heartbeats",
 365     "hw(-.+)?",
 366     "idea",
 367     "makedepend",
 368     "md2",
 369     "md4",
 370     "mdc2",
 371     "msan",
 372     "multiblock",
 373     "nextprotoneg",
 374     "ocb",
 375     "ocsp",
 376     "pic",
 377     "poly1305",
 378     "posix-io",
 379     "psk",
 380     "rc2",
 381     "rc4",
 382     "rc5",
 383     "rdrand",
 384     "rfc3779",
 385     "rmd160",
 386     "scrypt",
 387     "sctp",
 388     "seed",
 389     "shared",
 390     "siphash",
 391     "sm2",
 392     "sm3",
 393     "sm4",
 394     "sock",
 395     "srp",
 396     "srtp",
 397     "sse2",
 398     "ssl",
 399     "ssl-trace",
 400     "static-engine",
 401     "stdio",
 402     "tests",
 403     "threads",
 404     "tls",
 405     "ts",
 406     "ubsan",
 407     "ui-console",
 408     "unit-test",
 409     "whirlpool",
 410     "weak-ssl-ciphers",
 411     "zlib",
 412     "zlib-dynamic",
 413     );
 414 foreach my $proto ((@tls, @dtls))
 415         {
 416         push(@disablables, $proto);
 417         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 418         }
 419
 420 my %deprecated_disablables = (
 421     "ssl2" => undef,
 422     "buf-freelists" => undef,
 423     "ripemd" => "rmd160",
 424     "ui" => "ui-console",
 425     );
 426
 427 # All of the following are disabled by default:
 428
 429 our %disabled = ( # "what"         => "comment"
 430                   "asan"                => "default",
 431                   "crypto-mdebug"       => "default",
 432                   "crypto-mdebug-backtrace" => "default",
 433                   "devcryptoeng"        => "default",
 434                   "ec_nistp_64_gcc_128" => "default",
 435                   "egd"                 => "default",
 436                   "external-tests"      => "default",
 437                   "fuzz-libfuzzer"      => "default",
 438                   "fuzz-afl"            => "default",
 439                   "heartbeats"          => "default",
 440                   "md2"                 => "default",
 441                   "msan"                => "default",
 442                   "rc5"                 => "default",
 443                   "sctp"                => "default",
 444                   "ssl-trace"           => "default",
 445                   "ssl3"                => "default",
 446                   "ssl3-method"         => "default",
 447                   "ubsan"               => "default",
 448                   "unit-test"           => "default",
 449                   "weak-ssl-ciphers"    => "default",
 450                   "zlib"                => "default",
 451                   "zlib-dynamic"        => "default",
 452                   "ktls"                => "default",
 453                 );
 454
 455 # Note: => pair form used for aesthetics, not to truly make a hash table
 456 my @disable_cascades = (
 457     # "what"            => [ "cascade", ... ]
 458     sub { $config{processor} eq "386" }
 459                         => [ "sse2" ],
 460     "ssl"               => [ "ssl3" ],
 461     "ssl3-method"       => [ "ssl3" ],
 462     "zlib"              => [ "zlib-dynamic" ],
 463     "des"               => [ "mdc2" ],
 464     "ec"                => [ "ecdsa", "ecdh" ],
 465
 466     "dgram"             => [ "dtls", "sctp" ],
 467     "sock"              => [ "dgram" ],
 468     "dtls"              => [ @dtls ],
 469     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 470                         => [ "dtls" ],
 471
 472     "tls"               => [ @tls ],
 473     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 474                         => [ "tls" ],
 475
 476     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 477
 478     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 479     "dso"               => [ "dynamic-engine" ],
 480
 481     # Without position independent code, there can be no shared libraries or DSOs
 482     "pic"               => [ "shared" ],
 483     "shared"            => [ "dynamic-engine" ],
 484     "engine"            => [ "afalgeng", "devcryptoeng" ],
 485
 486     # no-autoalginit is only useful when building non-shared
 487     "autoalginit"       => [ "shared", "apps" ],
 488
 489     "stdio"             => [ "apps", "capieng", "egd" ],
 490     "apps"              => [ "tests" ],
 491     "tests"             => [ "external-tests" ],
 492     "comp"              => [ "zlib" ],
 493     "ec"                => [ "tls1_3", "sm2" ],
 494     "sm3"               => [ "sm2" ],
 495     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 496
 497     sub { !$disabled{"msan"} } => [ "asm" ],
 498     );
 499
 500 # Avoid protocol support holes.  Also disable all versions below N, if version
 501 # N is disabled while N+1 is enabled.
 502 #
 503 my @list = (reverse @tls);
 504 while ((my $first, my $second) = (shift @list, shift @list)) {
 505     last unless @list;
 506     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 507                               => [ @list ] );
 508     unshift @list, $second;
 509 }
 510 my @list = (reverse @dtls);
 511 while ((my $first, my $second) = (shift @list, shift @list)) {
 512     last unless @list;
 513     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 514                               => [ @list ] );
 515     unshift @list, $second;
 516 }
 517
 518 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 519 # To remove something from %disabled, use "enable-foo".
 520 # For symmetry, "disable-foo" is a synonym for "no-foo".
 521
 522 &usage if ($#ARGV < 0);
 523
 524 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 525 # platform specific list separators.  Users from those platforms should
 526 # recognise those separators from how you set up the PATH to find executables.
 527 # The default is the Unix like separator, :, but as an exception, we also
 528 # support the space as separator.
 529 my $list_separator_re =
 530     { VMS           => qr/(?<!\^),/,
 531       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 532 # All the "make variables" we support
 533 # Some get pre-populated for the sake of backward compatibility
 534 # (we supported those before the change to "make variable" support.
 535 my %user = (
 536     AR          => env('AR'),
 537     ARFLAGS     => [],
 538     AS          => undef,
 539     ASFLAGS     => [],
 540     CC          => env('CC'),
 541     CFLAGS      => [],
 542     CXX         => env('CXX'),
 543     CXXFLAGS    => [],
 544     CPP         => undef,
 545     CPPFLAGS    => [],  # -D, -I, -Wp,
 546     CPPDEFINES  => [],  # Alternative for -D
 547     CPPINCLUDES => [],  # Alternative for -I
 548     CROSS_COMPILE => env('CROSS_COMPILE'),
 549     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 550     LD          => undef,
 551     LDFLAGS     => [],  # -L, -Wl,
 552     LDLIBS      => [],  # -l
 553     MT          => undef,
 554     MTFLAGS     => [],
 555     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 556     RANLIB      => env('RANLIB'),
 557     RC          => env('RC') || env('WINDRES'),
 558     RCFLAGS     => [],
 559     RM          => undef,
 560    );
 561 # Info about what "make variables" may be prefixed with the cross compiler
 562 # prefix.  This should NEVER mention any such variable with a list for value.
 563 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 564 # The same but for flags given as Configure options.  These are *additional*
 565 # input, as opposed to the VAR=string option that override the corresponding
 566 # config target attributes
 567 my %useradd = (
 568     CPPDEFINES  => [],
 569     CPPINCLUDES => [],
 570     CPPFLAGS    => [],
 571     CFLAGS      => [],
 572     CXXFLAGS    => [],
 573     LDFLAGS     => [],
 574     LDLIBS      => [],
 575    );
 576
 577 my %user_synonyms = (
 578     HASHBANGPERL=> 'PERL',
 579     RC          => 'WINDRES',
 580    );
 581
 582 # Some target attributes have been renamed, this is the translation table
 583 my %target_attr_translate =(
 584     ar          => 'AR',
 585     as          => 'AS',
 586     cc          => 'CC',
 587     cxx         => 'CXX',
 588     cpp         => 'CPP',
 589     hashbangperl => 'HASHBANGPERL',
 590     ld          => 'LD',
 591     mt          => 'MT',
 592     ranlib      => 'RANLIB',
 593     rc          => 'RC',
 594     rm          => 'RM',
 595    );
 596
 597 # Initialisers coming from 'config' scripts
 598 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 599 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 600 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 601 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 602 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 603 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 604 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 605
 606 $config{openssl_api_defines}=[];
 607 $config{openssl_sys_defines}=[];
 608 $config{openssl_feature_defines}=[];
 609 $config{options}="";
 610 $config{build_type} = "release";
 611 my $target="";
 612
 613 my %cmdvars = ();               # Stores FOO='blah' type arguments
 614 my %unsupported_options = ();
 615 my %deprecated_options = ();
 616 # If you change this, update apps/version.c
 617 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 618 my @seed_sources = ();
 619 while (@argvcopy)
 620         {
 621         $_ = shift @argvcopy;
 622
 623         # Support env variable assignments among the options
 624         if (m|^(\w+)=(.+)?$|)
 625                 {
 626                 $cmdvars{$1} = $2;
 627                 # Every time a variable is given as a configuration argument,
 628                 # it acts as a reset if the variable.
 629                 if (exists $user{$1})
 630                         {
 631                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 632                         }
 633                 #if (exists $useradd{$1})
 634                 #       {
 635                 #       $useradd{$1} = [];
 636                 #       }
 637                 next;
 638                 }
 639
 640         # VMS is a case insensitive environment, and depending on settings
 641         # out of our control, we may receive options uppercased.  Let's
 642         # downcase at least the part before any equal sign.
 643         if ($^O eq "VMS")
 644                 {
 645                 s/^([^=]*)/lc($1)/e;
 646                 }
 647
 648         # some people just can't read the instructions, clang people have to...
 649         s/^-no-(?!integrated-as)/no-/;
 650
 651         # rewrite some options in "enable-..." form
 652         s /^-?-?shared$/enable-shared/;
 653         s /^sctp$/enable-sctp/;
 654         s /^threads$/enable-threads/;
 655         s /^zlib$/enable-zlib/;
 656         s /^zlib-dynamic$/enable-zlib-dynamic/;
 657
 658         if (/^(no|disable|enable)-(.+)$/)
 659                 {
 660                 my $word = $2;
 661                 if (!exists $deprecated_disablables{$word}
 662                         && !grep { $word =~ /^${_}$/ } @disablables)
 663                         {
 664                         $unsupported_options{$_} = 1;
 665                         next;
 666                         }
 667                 }
 668         if (/^no-(.+)$/ || /^disable-(.+)$/)
 669                 {
 670                 foreach my $proto ((@tls, @dtls))
 671                         {
 672                         if ($1 eq "$proto-method")
 673                                 {
 674                                 $disabled{"$proto"} = "option($proto-method)";
 675                                 last;
 676                                 }
 677                         }
 678                 if ($1 eq "dtls")
 679                         {
 680                         foreach my $proto (@dtls)
 681                                 {
 682                                 $disabled{$proto} = "option(dtls)";
 683                                 }
 684                         $disabled{"dtls"} = "option(dtls)";
 685                         }
 686                 elsif ($1 eq "ssl")
 687                         {
 688                         # Last one of its kind
 689                         $disabled{"ssl3"} = "option(ssl)";
 690                         }
 691                 elsif ($1 eq "tls")
 692                         {
 693                         # XXX: Tests will fail if all SSL/TLS
 694                         # protocols are disabled.
 695                         foreach my $proto (@tls)
 696                                 {
 697                                 $disabled{$proto} = "option(tls)";
 698                                 }
 699                         }
 700                 elsif ($1 eq "static-engine")
 701                         {
 702                         delete $disabled{"dynamic-engine"};
 703                         }
 704                 elsif ($1 eq "dynamic-engine")
 705                         {
 706                         $disabled{"dynamic-engine"} = "option";
 707                         }
 708                 elsif (exists $deprecated_disablables{$1})
 709                         {
 710                         $deprecated_options{$_} = 1;
 711                         if (defined $deprecated_disablables{$1})
 712                                 {
 713                                 $disabled{$deprecated_disablables{$1}} = "option";
 714                                 }
 715                         }
 716                 else
 717                         {
 718                         $disabled{$1} = "option";
 719                         }
 720                 # No longer an automatic choice
 721                 $auto_threads = 0 if ($1 eq "threads");
 722                 }
 723         elsif (/^enable-(.+)$/)
 724                 {
 725                 if ($1 eq "static-engine")
 726                         {
 727                         $disabled{"dynamic-engine"} = "option";
 728                         }
 729                 elsif ($1 eq "dynamic-engine")
 730                         {
 731                         delete $disabled{"dynamic-engine"};
 732                         }
 733                 elsif ($1 eq "zlib-dynamic")
 734                         {
 735                         delete $disabled{"zlib"};
 736                         }
 737                 my $algo = $1;
 738                 delete $disabled{$algo};
 739
 740                 # No longer an automatic choice
 741                 $auto_threads = 0 if ($1 eq "threads");
 742                 }
 743         elsif (/^--strict-warnings$/)
 744                 {
 745                 $strict_warnings = 1;
 746                 }
 747         elsif (/^--debug$/)
 748                 {
 749                 $config{build_type} = "debug";
 750                 }
 751         elsif (/^--release$/)
 752                 {
 753                 $config{build_type} = "release";
 754                 }
 755         elsif (/^386$/)
 756                 { $config{processor}=386; }
 757         elsif (/^fips$/)
 758                 {
 759                 die "FIPS mode not supported\n";
 760                 }
 761         elsif (/^rsaref$/)
 762                 {
 763                 # No RSAref support any more since it's not needed.
 764                 # The check for the option is there so scripts aren't
 765                 # broken
 766                 }
 767         elsif (/^nofipscanistercheck$/)
 768                 {
 769                 die "FIPS mode not supported\n";
 770                 }
 771         elsif (/^[-+]/)
 772                 {
 773                 if (/^--prefix=(.*)$/)
 774                         {
 775                         $config{prefix}=$1;
 776                         die "Directory given with --prefix MUST be absolute\n"
 777                                 unless file_name_is_absolute($config{prefix});
 778                         }
 779                 elsif (/^--api=(.*)$/)
 780                         {
 781                         $config{api}=$1;
 782                         }
 783                 elsif (/^--libdir=(.*)$/)
 784                         {
 785                         $config{libdir}=$1;
 786                         }
 787                 elsif (/^--openssldir=(.*)$/)
 788                         {
 789                         $config{openssldir}=$1;
 790                         }
 791                 elsif (/^--with-zlib-lib=(.*)$/)
 792                         {
 793                         $withargs{zlib_lib}=$1;
 794                         }
 795                 elsif (/^--with-zlib-include=(.*)$/)
 796                         {
 797                         $withargs{zlib_include}=$1;
 798                         }
 799                 elsif (/^--with-fuzzer-lib=(.*)$/)
 800                         {
 801                         $withargs{fuzzer_lib}=$1;
 802                         }
 803                 elsif (/^--with-fuzzer-include=(.*)$/)
 804                         {
 805                         $withargs{fuzzer_include}=$1;
 806                         }
 807                 elsif (/^--with-rand-seed=(.*)$/)
 808                         {
 809                         foreach my $x (split(m|,|, $1))
 810                             {
 811                             die "Unknown --with-rand-seed choice $x\n"
 812                                 if ! grep { $x eq $_ } @known_seed_sources;
 813                             push @seed_sources, $x;
 814                             }
 815                         }
 816                 elsif (/^--cross-compile-prefix=(.*)$/)
 817                         {
 818                         $user{CROSS_COMPILE}=$1;
 819                         }
 820                 elsif (/^--config=(.*)$/)
 821                         {
 822                         read_config $1;
 823                         }
 824                 elsif (/^-l(.*)$/)
 825                         {
 826                         push @{$useradd{LDLIBS}}, $_;
 827                         }
 828                 elsif (/^-framework$/)
 829                         {
 830                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 831                         }
 832                 elsif (/^-L(.*)$/ or /^-Wl,/)
 833                         {
 834                         push @{$useradd{LDFLAGS}}, $_;
 835                         }
 836                 elsif (/^-rpath$/ or /^-R$/)
 837                         # -rpath is the OSF1 rpath flag
 838                         # -R is the old Solaris rpath flag
 839                         {
 840                         my $rpath = shift(@argvcopy) || "";
 841                         $rpath .= " " if $rpath ne "";
 842                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 843                         }
 844                 elsif (/^-static$/)
 845                         {
 846                         push @{$useradd{LDFLAGS}}, $_;
 847                         $disabled{"dso"} = "forced";
 848                         $disabled{"pic"} = "forced";
 849                         $disabled{"shared"} = "forced";
 850                         $disabled{"threads"} = "forced";
 851                         }
 852                 elsif (/^-D(.*)$/)
 853                         {
 854                         push @{$useradd{CPPDEFINES}}, $1;
 855                         }
 856                 elsif (/^-I(.*)$/)
 857                         {
 858                         push @{$useradd{CPPINCLUDES}}, $1;
 859                         }
 860                 elsif (/^-Wp,$/)
 861                         {
 862                         push @{$useradd{CPPFLAGS}}, $1;
 863                         }
 864                 else    # common if (/^[-+]/), just pass down...
 865                         {
 866                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 867                         push @{$useradd{CFLAGS}}, $_;
 868                         push @{$useradd{CXXFLAGS}}, $_;
 869                         }
 870                 }
 871         else
 872                 {
 873                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 874                 $target=$_;
 875                 }
 876         unless ($_ eq $target || /^no-/ || /^disable-/)
 877                 {
 878                 # "no-..." follows later after implied deactivations
 879                 # have been derived.  (Don't take this too seriously,
 880                 # we really only write OPTIONS to the Makefile out of
 881                 # nostalgia.)
 882
 883                 if ($config{options} eq "")
 884                         { $config{options} = $_; }
 885                 else
 886                         { $config{options} .= " ".$_; }
 887                 }
 888         }
 889
 890 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 891         die "***** Unsupported api compatibility level: $config{api}\n",
 892 }
 893
 894 if (keys %deprecated_options)
 895         {
 896         warn "***** Deprecated options: ",
 897                 join(", ", keys %deprecated_options), "\n";
 898         }
 899 if (keys %unsupported_options)
 900         {
 901         die "***** Unsupported options: ",
 902                 join(", ", keys %unsupported_options), "\n";
 903         }
 904
 905 # If any %useradd entry has been set, we must check that the "make
 906 # variables" haven't been set.  We start by checking of any %useradd entry
 907 # is set.
 908 if (grep { scalar @$_ > 0 } values %useradd) {
 909     # Hash of env / make variables names.  The possible values are:
 910     # 1 - "make vars"
 911     # 2 - %useradd entry set
 912     # 3 - both set
 913     my %detected_vars =
 914         map { my $v = 0;
 915               $v += 1 if $cmdvars{$_};
 916               $v += 2 if @{$useradd{$_}};
 917               $_ => $v }
 918         keys %useradd;
 919
 920     # If any of the corresponding "make variables" is set, we error
 921     if (grep { $_ & 1 } values %detected_vars) {
 922         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 923                                sort keys %detected_vars);
 924         die <<"_____";
 925 ***** Mixing make variables and additional compiler/linker flags as
 926 ***** configure command line option is not permitted.
 927 ***** Affected make variables: $names
 928 _____
 929     }
 930 }
 931
 932 # Check through all supported command line variables to see if any of them
 933 # were set, and canonicalise the values we got.  If no compiler or linker
 934 # flag or anything else that affects %useradd was set, we also check the
 935 # environment for values.
 936 my $anyuseradd =
 937     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 938 foreach (keys %user) {
 939     my $value = $cmdvars{$_};
 940     $value //= env($_) unless $anyuseradd;
 941     $value //=
 942         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 943     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 944         unless $anyuseradd;
 945
 946     if (defined $value) {
 947         if (ref $user{$_} eq 'ARRAY') {
 948             $user{$_} = [ split /$list_separator_re/, $value ];
 949         } elsif (!defined $user{$_}) {
 950             $user{$_} = $value;
 951         }
 952     }
 953 }
 954
 955 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 956     && !$disabled{shared}
 957     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 958     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 959         "***** any of asan, msan or ubsan\n";
 960 }
 961
 962 my @tocheckfor = (keys %disabled);
 963 while (@tocheckfor) {
 964     my %new_tocheckfor = ();
 965     my @cascade_copy = (@disable_cascades);
 966     while (@cascade_copy) {
 967         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 968         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 969             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 970                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 971             }
 972         }
 973     }
 974     @tocheckfor = (keys %new_tocheckfor);
 975 }
 976
 977 our $die = sub { die @_; };
 978 if ($target eq "TABLE") {
 979     local $die = sub { warn @_; };
 980     foreach (sort keys %table) {
 981         print_table_entry($_, "TABLE");
 982     }
 983     exit 0;
 984 }
 985
 986 if ($target eq "LIST") {
 987     foreach (sort keys %table) {
 988         print $_,"\n" unless $table{$_}->{template};
 989     }
 990     exit 0;
 991 }
 992
 993 if ($target eq "HASH") {
 994     local $die = sub { warn @_; };
 995     print "%table = (\n";
 996     foreach (sort keys %table) {
 997         print_table_entry($_, "HASH");
 998     }
 999     exit 0;
1000 }
1001
1002 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
1003 print "for $target\n";
1004
1005 if (scalar(@seed_sources) == 0) {
1006     print "Using os-specific seed configuration\n";
1007     push @seed_sources, 'os';
1008 }
1009 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1010     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1011     warn <<_____ if scalar(@seed_sources) == 1;
1012
1013 ============================== WARNING ===============================
1014 You have selected the --with-rand-seed=none option, which effectively
1015 disables automatic reseeding of the OpenSSL random generator.
1016 All operations depending on the random generator such as creating keys
1017 will not work unless the random generator is seeded manually by the
1018 application.
1019
1020 Please read the 'Note on random number generation' section in the
1021 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1022 ============================== WARNING ===============================
1023
1024 _____
1025 }
1026 push @{$config{openssl_feature_defines}},
1027      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1028         @seed_sources;
1029
1030 # Backward compatibility?
1031 if ($target =~ m/^CygWin32(-.*)$/) {
1032     $target = "Cygwin".$1;
1033 }
1034
1035 # Support for legacy targets having a name starting with 'debug-'
1036 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1037 if ($d) {
1038     $config{build_type} = "debug";
1039
1040     # If we do not find debug-foo in the table, the target is set to foo.
1041     if (!$table{$target}) {
1042         $target = $t;
1043     }
1044 }
1045
1046 &usage if !$table{$target} || $table{$target}->{template};
1047
1048 $config{target} = $target;
1049 my %target = resolve_config($target);
1050
1051 foreach (keys %target_attr_translate) {
1052     $target{$target_attr_translate{$_}} = $target{$_}
1053         if $target{$_};
1054     delete $target{$_};
1055 }
1056
1057 %target = ( %{$table{DEFAULTS}}, %target );
1058
1059 # Make the flags to build DSOs the same as for shared libraries unless they
1060 # are already defined
1061 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1062 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1063 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1064 {
1065     my $shared_info_pl =
1066         catfile(dirname($0), "Configurations", "shared-info.pl");
1067     my %shared_info = read_eval_file($shared_info_pl);
1068     push @{$target{_conf_fname_int}}, $shared_info_pl;
1069     my $si = $target{shared_target};
1070     while (ref $si ne "HASH") {
1071         last if ! defined $si;
1072         if (ref $si eq "CODE") {
1073             $si = $si->();
1074         } else {
1075             $si = $shared_info{$si};
1076         }
1077     }
1078
1079     # Some of the 'shared_target' values don't have any entried in
1080     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1081     # template knows how to handle this.  That is currently the case for
1082     # Windows and VMS.
1083     if (defined $si) {
1084         # Just as above, copy certain shared_* attributes to the corresponding
1085         # module_ attribute unless the latter is already defined
1086         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1087         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1088         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1089         foreach (sort keys %$si) {
1090             $target{$_} = defined $target{$_}
1091                 ? add($si->{$_})->($target{$_})
1092                 : $si->{$_};
1093         }
1094     }
1095 }
1096
1097 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1098 $config{conf_files} = [ sort keys %conf_files ];
1099
1100 foreach my $feature (@{$target{disable}}) {
1101     if (exists $deprecated_disablables{$feature}) {
1102         warn "***** config $target disables deprecated feature $feature\n";
1103     } elsif (!grep { $feature eq $_ } @disablables) {
1104         die "***** config $target disables unknown feature $feature\n";
1105     }
1106     $disabled{$feature} = 'config';
1107 }
1108 foreach my $feature (@{$target{enable}}) {
1109     if ("default" eq ($disabled{$_} // "")) {
1110         if (exists $deprecated_disablables{$feature}) {
1111             warn "***** config $target enables deprecated feature $feature\n";
1112         } elsif (!grep { $feature eq $_ } @disablables) {
1113             die "***** config $target enables unknown feature $feature\n";
1114         }
1115         delete $disabled{$_};
1116     }
1117 }
1118
1119 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1120 $target{cxxflags}//=$target{cflags} if $target{CXX};
1121 $target{exe_extension}="";
1122 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1123                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1124 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1125 $target{def_extension}=".ld";
1126 $target{def_extension}=".def" if $config{target} =~ /^mingw|VC-/;
1127 $target{def_extension}=".opt" if $config{target} =~ /^vms/;
1128 ($target{shared_extension_simple}=$target{shared_extension})
1129     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||
1130     unless defined($target{shared_extension_simple});
1131 $target{dso_extension}//=$target{shared_extension_simple};
1132 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1133     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1134
1135 # Fill %config with values from %user, and in case those are undefined or
1136 # empty, use values from %target (acting as a default).
1137 foreach (keys %user) {
1138     my $ref_type = ref $user{$_};
1139
1140     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1141     # and a value that's to be coerced into that type.
1142     my $mkvalue = sub {
1143         my $type = shift;
1144         my $value = shift;
1145         my $undef_p = shift;
1146
1147         die "Too many arguments for \$mkvalue" if @_;
1148
1149         while (ref $value eq 'CODE') {
1150             $value = $value->();
1151         }
1152
1153         if ($type eq 'ARRAY') {
1154             return undef unless defined $value;
1155             return undef if ref $value ne 'ARRAY' && !$value;
1156             return undef if ref $value eq 'ARRAY' && !@$value;
1157             return [ $value ] unless ref $value eq 'ARRAY';
1158         }
1159         return undef unless $value;
1160         return $value;
1161     };
1162
1163     $config{$_} =
1164         $mkvalue->($ref_type, $user{$_})
1165         || $mkvalue->($ref_type, $target{$_});
1166     delete $config{$_} unless defined $config{$_};
1167 }
1168
1169 # Allow overriding the build file name
1170 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1171
1172 ######################################################################
1173 # Build up information for skipping certain directories depending on disabled
1174 # features, as well as setting up macros for disabled features.
1175
1176 # This is a tentative database of directories to skip.  Some entries may not
1177 # correspond to anything real, but that's ok, they will simply be ignored.
1178 # The actual processing of these entries is done in the build.info lookup
1179 # loop further down.
1180 #
1181 # The key is a Unix formated path in the source tree, the value is an index
1182 # into %disabled_info, so any existing path gets added to a corresponding
1183 # 'skipped' entry in there with the list of skipped directories.
1184 my %skipdir = ();
1185 my %disabled_info = ();         # For configdata.pm
1186 foreach my $what (sort keys %disabled) {
1187     $config{options} .= " no-$what";
1188
1189     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1190                                 'dynamic-engine', 'makedepend',
1191                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1192         (my $WHAT = uc $what) =~ s|-|_|g;
1193         my $skipdir = $what;
1194
1195         # fix-up crypto/directory name(s)
1196         $skipdir = "ripemd" if $what eq "rmd160";
1197         $skipdir = "whrlpool" if $what eq "whirlpool";
1198
1199         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1200         push @{$config{openssl_feature_defines}}, $macro;
1201
1202         $skipdir{engines} = $what if $what eq 'engine';
1203         $skipdir{"crypto/$skipdir"} = $what
1204             unless $what eq 'async' || $what eq 'err';
1205     }
1206 }
1207
1208 # Make sure build_scheme is consistent.
1209 $target{build_scheme} = [ $target{build_scheme} ]
1210     if ref($target{build_scheme}) ne "ARRAY";
1211
1212 my ($builder, $builder_platform, @builder_opts) =
1213     @{$target{build_scheme}};
1214
1215 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1216                       $builder_platform."-checker.pm")) {
1217     my $checker_path = catfile($srcdir, "Configurations", $checker);
1218     if (-f $checker_path) {
1219         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1220             ? sub { warn $@; } : sub { die $@; };
1221         if (! do $checker_path) {
1222             if ($@) {
1223                 $fn->($@);
1224             } elsif ($!) {
1225                 $fn->($!);
1226             } else {
1227                 $fn->("The detected tools didn't match the platform\n");
1228             }
1229         }
1230         last;
1231     }
1232 }
1233
1234 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1235
1236 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1237         {
1238         push @{$config{cflags}}, "-mno-cygwin";
1239         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1240         push @{$config{shared_ldflag}}, "-mno-cygwin";
1241         }
1242
1243 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1244         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1245                                             @{$useradd{CFLAGS}})) {
1246         # minimally required architecture flags for assembly modules
1247         my $value;
1248         $value = '-mips2' if ($target =~ /mips32/);
1249         $value = '-mips3' if ($target =~ /mips64/);
1250         unshift @{$config{cflags}}, $value;
1251         unshift @{$config{cxxflags}}, $value if $config{CXX};
1252 }
1253
1254 # If threads aren't disabled, check how possible they are
1255 unless ($disabled{threads}) {
1256     if ($auto_threads) {
1257         # Enabled by default, disable it forcibly if unavailable
1258         if ($target{thread_scheme} eq "(unknown)") {
1259             $disabled{threads} = "unavailable";
1260         }
1261     } else {
1262         # The user chose to enable threads explicitly, let's see
1263         # if there's a chance that's possible
1264         if ($target{thread_scheme} eq "(unknown)") {
1265             # If the user asked for "threads" and we don't have internal
1266             # knowledge how to do it, [s]he is expected to provide any
1267             # system-dependent compiler options that are necessary.  We
1268             # can't truly check that the given options are correct, but
1269             # we expect the user to know what [s]He is doing.
1270             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1271                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1272                 die "You asked for multi-threading support, but didn't\n"
1273                     ,"provide any system-specific compiler options\n";
1274             }
1275         }
1276     }
1277 }
1278
1279 # If threads still aren't disabled, add a C macro to ensure the source
1280 # code knows about it.  Any other flag is taken care of by the configs.
1281 unless($disabled{threads}) {
1282     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1283 }
1284
1285 # With "deprecated" disable all deprecated features.
1286 if (defined($disabled{"deprecated"})) {
1287         $config{api} = $maxapi;
1288 }
1289
1290 my $no_shared_warn=0;
1291 if ($target{shared_target} eq "")
1292         {
1293         $no_shared_warn = 1
1294             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1295         $disabled{shared} = "no-shared-target";
1296         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1297             "no-shared-target";
1298         }
1299
1300 if ($disabled{"dynamic-engine"}) {
1301         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1302         $config{dynamic_engines} = 0;
1303 } else {
1304         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1305         $config{dynamic_engines} = 1;
1306 }
1307
1308 unless ($disabled{asan}) {
1309     push @{$config{cflags}}, "-fsanitize=address";
1310     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1311 }
1312
1313 unless ($disabled{ubsan}) {
1314     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1315     # platforms.
1316     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1317     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1318         if $config{CXX};
1319 }
1320
1321 unless ($disabled{msan}) {
1322   push @{$config{cflags}}, "-fsanitize=memory";
1323   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1324 }
1325
1326 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1327         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1328     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1329     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1330 }
1331 #
1332 # Platform fix-ups
1333 #
1334
1335 # This saves the build files from having to check
1336 if ($disabled{pic})
1337         {
1338         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1339                     shared_defines shared_includes shared_ldflag
1340                     module_cflags module_cxxflags module_cppflags
1341                     module_defines module_includes module_lflags))
1342                 {
1343                 delete $config{$_};
1344                 $target{$_} = "";
1345                 }
1346         }
1347 else
1348         {
1349         push @{$config{lib_defines}}, "OPENSSL_PIC";
1350         }
1351
1352 if ($target{sys_id} ne "")
1353         {
1354         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1355         }
1356
1357 unless ($disabled{asm}) {
1358     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1359     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1360
1361     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1362
1363     # bn-586 is the only one implementing bn_*_part_words
1364     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1365     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1366
1367     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1368     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1369     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1370     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1371
1372     if ($target{sha1_asm_src}) {
1373         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1374         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1375         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1376     }
1377     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1378         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1379     }
1380     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1381         push @{$config{lib_defines}}, "RC4_ASM";
1382     }
1383     if ($target{md5_asm_src}) {
1384         push @{$config{lib_defines}}, "MD5_ASM";
1385     }
1386     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1387     if ($target{rmd160_asm_src}) {
1388         push @{$config{lib_defines}}, "RMD160_ASM";
1389     }
1390     if ($target{aes_asm_src}) {
1391         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1392         # aes-ctr.fake is not a real file, only indication that assembler
1393         # module implements AES_ctr32_encrypt...
1394         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1395         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1396         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1397         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1398         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1399         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1400     }
1401     if ($target{wp_asm_src} =~ /mmx/) {
1402         if ($config{processor} eq "386") {
1403             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1404         } elsif (!$disabled{"whirlpool"}) {
1405             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1406         }
1407     }
1408     if ($target{modes_asm_src} =~ /ghash-/) {
1409         push @{$config{lib_defines}}, "GHASH_ASM";
1410     }
1411     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1412         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1413     }
1414     if ($target{ec_asm_src} =~ /x25519/) {
1415         push @{$config{lib_defines}}, "X25519_ASM";
1416     }
1417     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1418         push @{$config{lib_defines}}, "PADLOCK_ASM";
1419     }
1420     if ($target{poly1305_asm_src} ne "") {
1421         push @{$config{lib_defines}}, "POLY1305_ASM";
1422     }
1423 }
1424
1425 my %predefined = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1426
1427 # Check for makedepend capabilities.
1428 if (!$disabled{makedepend}) {
1429     if ($config{target} =~ /^(VC|vms)-/) {
1430         # For VC- and vms- targets, there's nothing more to do here.  The
1431         # functionality is hard coded in the corresponding build files for
1432         # cl (Windows) and CC/DECC (VMS).
1433     } elsif (($predefined{__GNUC__} // -1) >= 3
1434              && !($predefined{__APPLE_CC__} && !$predefined{__clang__})) {
1435         # We know that GNU C version 3 and up as well as all clang
1436         # versions support dependency generation, but Xcode did not
1437         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1438         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1439     } else {
1440         # In all other cases, we look for 'makedepend', and disable the
1441         # capability if not found.
1442         $config{makedepprog} = which('makedepend');
1443         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1444     }
1445 }
1446
1447 if (!$disabled{asm} && !$predefined{__MACH__} && $^O ne 'VMS') {
1448     # probe for -Wa,--noexecstack option...
1449     if ($predefined{__clang__}) {
1450         # clang has builtin assembler, which doesn't recognize --help,
1451         # but it apparently recognizes the option in question on all
1452         # supported platforms even when it's meaningless. In other words
1453         # probe would fail, but probed option always accepted...
1454         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1455     } else {
1456         my $cc = $config{CROSS_COMPILE}.$config{CC};
1457         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1458         while(<PIPE>) {
1459             if (m/--noexecstack/) {
1460                 push @{$config{cflags}}, "-Wa,--noexecstack";
1461                 last;
1462             }
1463         }
1464         close(PIPE);
1465         unlink("null.$$.o");
1466     }
1467 }
1468
1469 # Deal with bn_ops ###################################################
1470
1471 $config{bn_ll}                  =0;
1472 $config{export_var_as_fn}       =0;
1473 my $def_int="unsigned int";
1474 $config{rc4_int}                =$def_int;
1475 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1476
1477 my $count = 0;
1478 foreach (sort split(/\s+/,$target{bn_ops})) {
1479     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1480     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1481     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1482     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1483     ($config{b64l},$config{b64},$config{b32})
1484         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1485     ($config{b64l},$config{b64},$config{b32})
1486         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1487     ($config{b64l},$config{b64},$config{b32})
1488         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1489 }
1490 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1491     if $count > 1;
1492
1493
1494 # Hack cflags for better warnings (dev option) #######################
1495
1496 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1497 # a string and works as well on command lines.
1498 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1499                         @{$config{cflags}} ];
1500 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1501                           @{$config{cxxflags}} ] if $config{CXX};
1502
1503 $config{openssl_api_defines} = [
1504     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1505 ];
1506
1507 if ($strict_warnings)
1508         {
1509         my $wopt;
1510         my $gccver = $predefined{__GNUC__} // -1;
1511
1512         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1513             unless $gccver >= 4;
1514         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1515                 {
1516                 push @{$config{cflags}}, $wopt
1517                         unless grep { $_ eq $wopt } @{$config{cflags}};
1518                 push @{$config{cxxflags}}, $wopt
1519                         if ($config{CXX}
1520                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1521                 }
1522         if (defined($predefined{__clang__}))
1523                 {
1524                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1525                         {
1526                         push @{$config{cflags}}, $wopt
1527                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1528                         push @{$config{cxxflags}}, $wopt
1529                                 if ($config{CXX}
1530                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1531                         }
1532                 }
1533         }
1534
1535 unless ($disabled{"crypto-mdebug-backtrace"})
1536         {
1537         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1538                 {
1539                 push @{$config{cflags}}, $wopt
1540                         unless grep { $_ eq $wopt } @{$config{cflags}};
1541                 push @{$config{cxxflags}}, $wopt
1542                         if ($config{CXX}
1543                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1544                 }
1545         if ($target =~ /^BSD-/)
1546                 {
1547                 push @{$config{ex_libs}}, "-lexecinfo";
1548                 }
1549         }
1550
1551 unless ($disabled{afalgeng}) {
1552     $config{afalgeng}="";
1553     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1554         my $minver = 4*10000 + 1*100 + 0;
1555         if ($config{CROSS_COMPILE} eq "") {
1556             my $verstr = `uname -r`;
1557             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1558             ($mi2) = $mi2 =~ /(\d+)/;
1559             my $ver = $ma*10000 + $mi1*100 + $mi2;
1560             if ($ver < $minver) {
1561                 $disabled{afalgeng} = "too-old-kernel";
1562             } else {
1563                 push @{$config{engdirs}}, "afalg";
1564             }
1565         } else {
1566             $disabled{afalgeng} = "cross-compiling";
1567         }
1568     } else {
1569         $disabled{afalgeng}  = "not-linux";
1570     }
1571 }
1572
1573 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1574
1575 unless ($disabled{ktls}) {
1576     $config{ktls}="";
1577     if ($target =~ m/^linux/) {
1578         my $usr = "/usr/$config{cross_compile_prefix}";
1579         chop($usr);
1580         if ($config{cross_compile_prefix} eq "") {
1581             $usr = "/usr";
1582         }
1583         my $minver = (4 << 16) + (13 << 8) + 0;
1584         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1585
1586         if ($verstr[2] < $minver) {
1587             $disabled{ktls} = "too-old-kernel";
1588         }
1589     } else {
1590         $disabled{ktls}  = "not-linux";
1591     }
1592 }
1593
1594 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1595
1596 # Finish up %config by appending things the user gave us on the command line
1597 # apart from "make variables"
1598 foreach (keys %useradd) {
1599     # The must all be lists, so we assert that here
1600     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1601         unless ref $useradd{$_} eq 'ARRAY';
1602
1603     if (defined $config{$_}) {
1604         push @{$config{$_}}, @{$useradd{$_}};
1605     } else {
1606         $config{$_} = [ @{$useradd{$_}} ];
1607     }
1608 }
1609
1610 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1611
1612 # If we use the unified build, collect information from build.info files
1613 my %unified_info = ();
1614
1615 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1616 if ($builder eq "unified") {
1617     use with_fallback qw(Text::Template);
1618
1619     sub cleandir {
1620         my $base = shift;
1621         my $dir = shift;
1622         my $relativeto = shift || ".";
1623
1624         $dir = catdir($base,$dir) unless isabsolute($dir);
1625
1626         # Make sure the directories we're building in exists
1627         mkpath($dir);
1628
1629         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1630         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1631         return $res;
1632     }
1633
1634     sub cleanfile {
1635         my $base = shift;
1636         my $file = shift;
1637         my $relativeto = shift || ".";
1638
1639         $file = catfile($base,$file) unless isabsolute($file);
1640
1641         my $d = dirname($file);
1642         my $f = basename($file);
1643
1644         # Make sure the directories we're building in exists
1645         mkpath($d);
1646
1647         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1648         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1649         return $res;
1650     }
1651
1652     # Store the name of the template file we will build the build file from
1653     # in %config.  This may be useful for the build file itself.
1654     my @build_file_template_names =
1655         ( $builder_platform."-".$target{build_file}.".tmpl",
1656           $target{build_file}.".tmpl" );
1657     my @build_file_templates = ();
1658
1659     # First, look in the user provided directory, if given
1660     if (defined env($local_config_envname)) {
1661         @build_file_templates =
1662             map {
1663                 if ($^O eq 'VMS') {
1664                     # VMS environment variables are logical names,
1665                     # which can be used as is
1666                     $local_config_envname . ':' . $_;
1667                 } else {
1668                     catfile(env($local_config_envname), $_);
1669                 }
1670             }
1671             @build_file_template_names;
1672     }
1673     # Then, look in our standard directory
1674     push @build_file_templates,
1675         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1676           @build_file_template_names );
1677
1678     my $build_file_template;
1679     for $_ (@build_file_templates) {
1680         $build_file_template = $_;
1681         last if -f $build_file_template;
1682
1683         $build_file_template = undef;
1684     }
1685     if (!defined $build_file_template) {
1686         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1687     }
1688     $config{build_file_templates}
1689       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1690                     $blddir),
1691           $build_file_template,
1692           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1693                     $blddir) ];
1694
1695     my @build_dirs = ( [ ] );   # current directory
1696
1697     $config{build_infos} = [ ];
1698
1699     my %ordinals = ();
1700     while (@build_dirs) {
1701         my @curd = @{shift @build_dirs};
1702         my $sourced = catdir($srcdir, @curd);
1703         my $buildd = catdir($blddir, @curd);
1704
1705         my $unixdir = join('/', @curd);
1706         if (exists $skipdir{$unixdir}) {
1707             my $what = $skipdir{$unixdir};
1708             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1709             next;
1710         }
1711
1712         mkpath($buildd);
1713
1714         my $f = 'build.info';
1715         # The basic things we're trying to build
1716         my @programs = ();
1717         my @programs_install = ();
1718         my @libraries = ();
1719         my @libraries_install = ();
1720         my @engines = ();
1721         my @engines_install = ();
1722         my @scripts = ();
1723         my @scripts_install = ();
1724         my @extra = ();
1725         my @overrides = ();
1726         my @intermediates = ();
1727         my @rawlines = ();
1728
1729         my %sources = ();
1730         my %shared_sources = ();
1731         my %includes = ();
1732         my %defines = ();
1733         my %depends = ();
1734         my %renames = ();
1735         my %sharednames = ();
1736         my %generate = ();
1737
1738         # We want to detect configdata.pm in the source tree, so we
1739         # don't use it if the build tree is different.
1740         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1741
1742         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1743         my $template =
1744             Text::Template->new(TYPE => 'FILE',
1745                                 SOURCE => catfile($sourced, $f),
1746                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1747         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1748         my @text =
1749             split /^/m,
1750             $template->fill_in(HASH => { config => \%config,
1751                                          target => \%target,
1752                                          disabled => \%disabled,
1753                                          withargs => \%withargs,
1754                                          builddir => abs2rel($buildd, $blddir),
1755                                          sourcedir => abs2rel($sourced, $blddir),
1756                                          buildtop => abs2rel($blddir, $blddir),
1757                                          sourcetop => abs2rel($srcdir, $blddir) },
1758                                DELIMITERS => [ "{-", "-}" ]);
1759
1760         # The top item of this stack has the following values
1761         # -2 positive already run and we found ELSE (following ELSIF should fail)
1762         # -1 positive already run (skip until ENDIF)
1763         # 0 negatives so far (if we're at a condition, check it)
1764         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1765         # 2 positive ELSE (following ELSIF should fail)
1766         my @skip = ();
1767         collect_information(
1768             collect_from_array([ @text ],
1769                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1770                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1771             # Info we're looking for
1772             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1773             => sub {
1774                 if (! @skip || $skip[$#skip] > 0) {
1775                     push @skip, !! $1;
1776                 } else {
1777                     push @skip, -1;
1778                 }
1779             },
1780             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1781             => sub { die "ELSIF out of scope" if ! @skip;
1782                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1783                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1784                      $skip[$#skip] = !! $1
1785                          if $skip[$#skip] == 0; },
1786             qr/^\s*ELSE\s*$/
1787             => sub { die "ELSE out of scope" if ! @skip;
1788                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1789                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1790             qr/^\s*ENDIF\s*$/
1791             => sub { die "ENDIF out of scope" if ! @skip;
1792                      pop @skip; },
1793             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1794             => sub {
1795                 if (!@skip || $skip[$#skip] > 0) {
1796                     foreach (tokenize($1)) {
1797                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1798                     }
1799                 }
1800             },
1801             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1802             => sub {
1803                 if (!@skip || $skip[$#skip] > 0) {
1804                     my $install = $1;
1805                     my @x = tokenize($2);
1806                     push @programs, @x;
1807                     push @programs_install, @x unless $install;
1808                 }
1809             },
1810             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1811             => sub {
1812                 if (!@skip || $skip[$#skip] > 0) {
1813                     my $install = $1;
1814                     my @x = tokenize($2);
1815                     push @libraries, @x;
1816                     push @libraries_install, @x unless $install;
1817                 }
1818             },
1819             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1820             => sub {
1821                 if (!@skip || $skip[$#skip] > 0) {
1822                     my $install = $1;
1823                     my @x = tokenize($2);
1824                     push @engines, @x;
1825                     push @engines_install, @x unless $install;
1826                 }
1827             },
1828             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1829             => sub {
1830                 if (!@skip || $skip[$#skip] > 0) {
1831                     my $install = $1;
1832                     my @x = tokenize($2);
1833                     push @scripts, @x;
1834                     push @scripts_install, @x unless $install;
1835                 }
1836             },
1837             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1838             => sub { push @extra, tokenize($1)
1839                          if !@skip || $skip[$#skip] > 0 },
1840             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1841             => sub { push @overrides, tokenize($1)
1842                          if !@skip || $skip[$#skip] > 0 },
1843
1844             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1845             => sub { push @{$ordinals{$1}}, tokenize($2)
1846                          if !@skip || $skip[$#skip] > 0 },
1847             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1848             => sub { push @{$sources{$1}}, tokenize($2)
1849                          if !@skip || $skip[$#skip] > 0 },
1850             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1851             => sub { push @{$shared_sources{$1}}, tokenize($2)
1852                          if !@skip || $skip[$#skip] > 0 },
1853             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1854             => sub { push @{$includes{$1}}, tokenize($2)
1855                          if !@skip || $skip[$#skip] > 0 },
1856             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1857             => sub { push @{$defines{$1}}, tokenize($2)
1858                          if !@skip || $skip[$#skip] > 0 },
1859             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1860             => sub { push @{$depends{$1}}, tokenize($2)
1861                          if !@skip || $skip[$#skip] > 0 },
1862             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1863             => sub { push @{$generate{$1}}, $2
1864                          if !@skip || $skip[$#skip] > 0 },
1865             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1866             => sub { push @{$renames{$1}}, tokenize($2)
1867                          if !@skip || $skip[$#skip] > 0 },
1868             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1869             => sub { push @{$sharednames{$1}}, tokenize($2)
1870                          if !@skip || $skip[$#skip] > 0 },
1871             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1872             => sub {
1873                 my $lineiterator = shift;
1874                 my $target_kind = $1;
1875                 while (defined $lineiterator->()) {
1876                     s|\R$||;
1877                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1878                         die "ENDRAW doesn't match BEGINRAW"
1879                             if $1 ne $target_kind;
1880                         last;
1881                     }
1882                     next if @skip && $skip[$#skip] <= 0;
1883                     push @rawlines,  $_
1884                         if ($target_kind eq $target{build_file}
1885                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1886                 }
1887             },
1888             qr/^\s*(?:#.*)?$/ => sub { },
1889             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1890             "BEFORE" => sub {
1891                 if ($buildinfo_debug) {
1892                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1893                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1894                 }
1895             },
1896             "AFTER" => sub {
1897                 if ($buildinfo_debug) {
1898                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1899                 }
1900             },
1901             );
1902         die "runaway IF?" if (@skip);
1903
1904         foreach (keys %renames) {
1905             die "$_ renamed to more than one thing: "
1906                 ,join(" ", @{$renames{$_}}),"\n"
1907                 if scalar @{$renames{$_}} > 1;
1908             my $dest = cleanfile($buildd, $_, $blddir);
1909             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1910             die "$dest renamed to more than one thing: "
1911                 ,$unified_info{rename}->{$dest}, $to
1912                 unless !defined($unified_info{rename}->{$dest})
1913                 or $unified_info{rename}->{$dest} eq $to;
1914             $unified_info{rename}->{$dest} = $to;
1915         }
1916
1917         foreach (@programs) {
1918             my $program = cleanfile($buildd, $_, $blddir);
1919             if ($unified_info{rename}->{$program}) {
1920                 $program = $unified_info{rename}->{$program};
1921             }
1922             $unified_info{programs}->{$program} = 1;
1923         }
1924
1925         foreach (@programs_install) {
1926             my $program = cleanfile($buildd, $_, $blddir);
1927             if ($unified_info{rename}->{$program}) {
1928                 $program = $unified_info{rename}->{$program};
1929             }
1930             $unified_info{install}->{programs}->{$program} = 1;
1931         }
1932
1933         foreach (@libraries) {
1934             my $library = cleanfile($buildd, $_, $blddir);
1935             if ($unified_info{rename}->{$library}) {
1936                 $library = $unified_info{rename}->{$library};
1937             }
1938             $unified_info{libraries}->{$library} = 1;
1939         }
1940
1941         foreach (@libraries_install) {
1942             my $library = cleanfile($buildd, $_, $blddir);
1943             if ($unified_info{rename}->{$library}) {
1944                 $library = $unified_info{rename}->{$library};
1945             }
1946             $unified_info{install}->{libraries}->{$library} = 1;
1947         }
1948
1949         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1950 ENGINES can only be used if configured with 'dynamic-engine'.
1951 This is usually a fault in a build.info file.
1952 EOF
1953         foreach (@engines) {
1954             my $library = cleanfile($buildd, $_, $blddir);
1955             if ($unified_info{rename}->{$library}) {
1956                 $library = $unified_info{rename}->{$library};
1957             }
1958             $unified_info{engines}->{$library} = 1;
1959         }
1960
1961         foreach (@engines_install) {
1962             my $library = cleanfile($buildd, $_, $blddir);
1963             if ($unified_info{rename}->{$library}) {
1964                 $library = $unified_info{rename}->{$library};
1965             }
1966             $unified_info{install}->{engines}->{$library} = 1;
1967         }
1968
1969         foreach (@scripts) {
1970             my $script = cleanfile($buildd, $_, $blddir);
1971             if ($unified_info{rename}->{$script}) {
1972                 $script = $unified_info{rename}->{$script};
1973             }
1974             $unified_info{scripts}->{$script} = 1;
1975         }
1976
1977         foreach (@scripts_install) {
1978             my $script = cleanfile($buildd, $_, $blddir);
1979             if ($unified_info{rename}->{$script}) {
1980                 $script = $unified_info{rename}->{$script};
1981             }
1982             $unified_info{install}->{scripts}->{$script} = 1;
1983         }
1984
1985         foreach (@extra) {
1986             my $extra = cleanfile($buildd, $_, $blddir);
1987             $unified_info{extra}->{$extra} = 1;
1988         }
1989
1990         foreach (@overrides) {
1991             my $override = cleanfile($buildd, $_, $blddir);
1992             $unified_info{overrides}->{$override} = 1;
1993         }
1994
1995         push @{$unified_info{rawlines}}, @rawlines;
1996
1997         unless ($disabled{shared}) {
1998             # Check sharednames.
1999             foreach (keys %sharednames) {
2000                 my $dest = cleanfile($buildd, $_, $blddir);
2001                 if ($unified_info{rename}->{$dest}) {
2002                     $dest = $unified_info{rename}->{$dest};
2003                 }
2004                 die "shared_name for $dest with multiple values: "
2005                     ,join(" ", @{$sharednames{$_}}),"\n"
2006                     if scalar @{$sharednames{$_}} > 1;
2007                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
2008                 die "shared_name found for a library $dest that isn't defined\n"
2009                     unless $unified_info{libraries}->{$dest};
2010                 die "shared_name for $dest with multiple values: "
2011                     ,$unified_info{sharednames}->{$dest}, ", ", $to
2012                     unless !defined($unified_info{sharednames}->{$dest})
2013                     or $unified_info{sharednames}->{$dest} eq $to;
2014                 $unified_info{sharednames}->{$dest} = $to;
2015             }
2016
2017             # Additionally, we set up sharednames for libraries that don't
2018             # have any, as themselves.  Only for libraries that aren't
2019             # explicitly static.
2020             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
2021                 if (!defined $unified_info{sharednames}->{$_}) {
2022                     $unified_info{sharednames}->{$_} = $_
2023                 }
2024             }
2025
2026             # Check that we haven't defined any library as both shared and
2027             # explicitly static.  That is forbidden.
2028             my @doubles = ();
2029             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2030                 (my $l = $_) =~ s/\.a$//;
2031                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
2032             }
2033             die "these libraries are both explicitly static and shared:\n  ",
2034                 join(" ", @doubles), "\n"
2035                 if @doubles;
2036         }
2037
2038         foreach (keys %sources) {
2039             my $dest = $_;
2040             my $ddest = cleanfile($buildd, $_, $blddir);
2041             if ($unified_info{rename}->{$ddest}) {
2042                 $ddest = $unified_info{rename}->{$ddest};
2043             }
2044             foreach (@{$sources{$dest}}) {
2045                 my $s = cleanfile($sourced, $_, $blddir);
2046
2047                 # If it isn't in the source tree, we assume it's generated
2048                 # in the build tree
2049                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2050                     $s = cleanfile($buildd, $_, $blddir);
2051                 }
2052                 # We recognise C++, C and asm files
2053                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2054                     my $o = $_;
2055                     $o =~ s/\.[csS]$/.o/; # C and assembler
2056                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2057                     $o = cleanfile($buildd, $o, $blddir);
2058                     $unified_info{sources}->{$ddest}->{$o} = -1;
2059                     $unified_info{sources}->{$o}->{$s} = -1;
2060                 } elsif ($s =~ /\.rc$/) {
2061                     # We also recognise resource files
2062                     my $o = $_;
2063                     $o =~ s/\.rc$/.res/; # Resource configuration
2064                     my $o = cleanfile($buildd, $o, $blddir);
2065                     $unified_info{sources}->{$ddest}->{$o} = -1;
2066                     $unified_info{sources}->{$o}->{$s} = -1;
2067                 } else {
2068                     $unified_info{sources}->{$ddest}->{$s} = 1;
2069                 }
2070             }
2071         }
2072
2073         foreach (keys %shared_sources) {
2074             my $dest = $_;
2075             my $ddest = cleanfile($buildd, $_, $blddir);
2076             if ($unified_info{rename}->{$ddest}) {
2077                 $ddest = $unified_info{rename}->{$ddest};
2078             }
2079             foreach (@{$shared_sources{$dest}}) {
2080                 my $s = cleanfile($sourced, $_, $blddir);
2081
2082                 # If it isn't in the source tree, we assume it's generated
2083                 # in the build tree
2084                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2085                     $s = cleanfile($buildd, $_, $blddir);
2086                 }
2087
2088                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2089                     # We recognise C++, C and asm files
2090                     my $o = $_;
2091                     $o =~ s/\.[csS]$/.o/; # C and assembler
2092                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2093                     $o = cleanfile($buildd, $o, $blddir);
2094                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2095                     $unified_info{sources}->{$o}->{$s} = -1;
2096                 } elsif ($s =~ /\.rc$/) {
2097                     # We also recognise resource files
2098                     my $o = $_;
2099                     $o =~ s/\.rc$/.res/; # Resource configuration
2100                     my $o = cleanfile($buildd, $o, $blddir);
2101                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2102                     $unified_info{sources}->{$o}->{$s} = -1;
2103                 } elsif ($s =~ /\.ld$/) {
2104                     # We also recognise linker scripts (or corresponding)
2105                     # We know they are generated files
2106                     my $ld = cleanfile($buildd, $_, $blddir);
2107                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2108                 } else {
2109                     die "unrecognised source file type for shared library: $s\n";
2110                 }
2111             }
2112         }
2113
2114         foreach (keys %generate) {
2115             my $dest = $_;
2116             my $ddest = cleanfile($buildd, $_, $blddir);
2117             if ($unified_info{rename}->{$ddest}) {
2118                 $ddest = $unified_info{rename}->{$ddest};
2119             }
2120             die "more than one generator for $dest: "
2121                     ,join(" ", @{$generate{$_}}),"\n"
2122                     if scalar @{$generate{$_}} > 1;
2123             my @generator = split /\s+/, $generate{$dest}->[0];
2124             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2125             $unified_info{generate}->{$ddest} = [ @generator ];
2126         }
2127
2128         foreach (keys %depends) {
2129             my $dest = $_;
2130             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2131
2132             # If the destination doesn't exist in source, it can only be
2133             # a generated file in the build tree.
2134             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2135                 $ddest = cleanfile($buildd, $_, $blddir);
2136                 if ($unified_info{rename}->{$ddest}) {
2137                     $ddest = $unified_info{rename}->{$ddest};
2138                 }
2139             }
2140             foreach (@{$depends{$dest}}) {
2141                 my $d = cleanfile($sourced, $_, $blddir);
2142
2143                 # If we know it's generated, or assume it is because we can't
2144                 # find it in the source tree, we set file we depend on to be
2145                 # in the build tree rather than the source tree, and assume
2146                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2147                 # section or in the Makefile template.
2148                 if ($d eq $src_configdata
2149                     || ! -f $d
2150                     || (grep { $d eq $_ }
2151                         map { cleanfile($srcdir, $_, $blddir) }
2152                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2153                     $d = cleanfile($buildd, $_, $blddir);
2154                 }
2155                 # Take note if the file to depend on is being renamed
2156                 # Take extra care with files ending with .a, they should
2157                 # be treated without that extension, and the extension
2158                 # should be added back after treatment.
2159                 $d =~ /(\.a)?$/;
2160                 my $e = $1 // "";
2161                 $d = $`;
2162                 if ($unified_info{rename}->{$d}) {
2163                     $d = $unified_info{rename}->{$d};
2164                 }
2165                 $d .= $e;
2166                 $unified_info{depends}->{$ddest}->{$d} = 1;
2167             }
2168         }
2169
2170         foreach (keys %includes) {
2171             my $dest = $_;
2172             my $ddest = cleanfile($sourced, $_, $blddir);
2173
2174             # If the destination doesn't exist in source, it can only be
2175             # a generated file in the build tree.
2176             if ($ddest eq $src_configdata || ! -f $ddest) {
2177                 $ddest = cleanfile($buildd, $_, $blddir);
2178                 if ($unified_info{rename}->{$ddest}) {
2179                     $ddest = $unified_info{rename}->{$ddest};
2180                 }
2181             }
2182             foreach (@{$includes{$dest}}) {
2183                 my $is = cleandir($sourced, $_, $blddir);
2184                 my $ib = cleandir($buildd, $_, $blddir);
2185                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2186                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2187                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2188                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2189             }
2190         }
2191
2192         foreach (keys %defines) {
2193             my $dest = $_;
2194             my $ddest = cleanfile($sourced, $_, $blddir);
2195
2196             # If the destination doesn't exist in source, it can only be
2197             # a generated file in the build tree.
2198             if (! -f $ddest) {
2199                 $ddest = cleanfile($buildd, $_, $blddir);
2200                 if ($unified_info{rename}->{$ddest}) {
2201                     $ddest = $unified_info{rename}->{$ddest};
2202                 }
2203             }
2204             foreach (@{$defines{$dest}}) {
2205                 m|^([^=]*)(=.*)?$|;
2206                 die "0 length macro name not permitted\n" if $1 eq "";
2207                 die "$1 defined more than once\n"
2208                     if defined $unified_info{defines}->{$ddest}->{$1};
2209                 $unified_info{defines}->{$ddest}->{$1} = $2;
2210             }
2211         }
2212     }
2213
2214     my $ordinals_text = join(', ', sort keys %ordinals);
2215     warn <<"EOF" if $ordinals_text;
2216
2217 WARNING: ORDINALS were specified for $ordinals_text
2218 They are ignored and should be replaced with a combination of GENERATE,
2219 DEPEND and SHARED_SOURCE.
2220 EOF
2221
2222     # Massage the result
2223
2224     # If we depend on a header file or a perl module, add an inclusion of
2225     # its directory to allow smoothe inclusion
2226     foreach my $dest (keys %{$unified_info{depends}}) {
2227         next if $dest eq "";
2228         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2229             next unless $d =~ /\.(h|pm)$/;
2230             my $i = dirname($d);
2231             my $spot =
2232                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2233                 ? 'build' : 'source';
2234             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2235                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2236         }
2237     }
2238
2239     # Go through all intermediary files and change their names to something that
2240     # reflects what they will be built for.  Note that for some source files,
2241     # this leads to duplicate object files because they are used multiple times.
2242     # the goal is to rename all object files according to this scheme:
2243     #    {productname}-{midfix}-{origobjname}.[o|res]
2244     # the {midfix} is a keyword indicating the type of product, which is mostly
2245     # valuable for libraries since they come in two forms.
2246     #
2247     # This also reorganises the {sources} and {shared_sources} so that the
2248     # former only contains ALL object files that are supposed to end up in
2249     # static libraries and programs, while the latter contains ALL object files
2250     # that are supposed to end up in shared libraries and DSOs.
2251     # The main reason for having two different source structures is to allow
2252     # the same name to be used for the static and the shared variants of a
2253     # library.
2254     {
2255         # Take copies so we don't get interference from added stuff
2256         my %unified_copy = ();
2257         foreach (('sources', 'shared_sources')) {
2258             $unified_copy{$_} = { %{$unified_info{$_}} }
2259                 if defined($unified_info{$_});
2260             delete $unified_info{$_};
2261         }
2262         foreach my $prodtype (('programs', 'libraries', 'engines', 'scripts')) {
2263             # $intent serves multi purposes:
2264             # - give a prefix for the new object files names
2265             # - in the case of libraries, rearrange the object files so static
2266             #   libraries use the 'sources' structure exclusively, while shared
2267             #   libraries use the 'shared_sources' structure exclusively.
2268             my $intent = {
2269                 programs  => { bin    => { src => [ 'sources' ],
2270                                            dst => 'sources' } },
2271                 libraries => { lib    => { src => [ 'sources' ],
2272                                            dst => 'sources' },
2273                                shlib  => { prodselect =>
2274                                                sub { grep !/\.a$/, @_ },
2275                                            src => [ 'sources',
2276                                                     'shared_sources' ],
2277                                            dst => 'shared_sources' } },
2278                 engines   => { dso    => { src => [ 'sources',
2279                                                     'shared_sources' ],
2280                                            dst => 'shared_sources' } },
2281                 scripts   => { script => { src => [ 'sources' ],
2282                                            dst => 'sources' } }
2283                } -> {$prodtype};
2284             foreach my $kind (keys %$intent) {
2285                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2286                              && $disabled{shared});
2287
2288                 my @src = @{$intent->{$kind}->{src}};
2289                 my $dst = $intent->{$kind}->{dst};
2290                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2291                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2292                     # %prod_sources has all applicable objects as keys, and
2293                     # their corresponding sources as values
2294                     my %prod_sources =
2295                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2296                         map { keys %{$unified_copy{$_}->{$prod}} }
2297                         @src;
2298                     foreach (keys %prod_sources) {
2299                         # Only affect object files and resource files,
2300                         # the others simply get a new value
2301                         # (+1 instead of -1)
2302                         if ($_ =~ /\.(o|res)$/) {
2303                             (my $prodname = $prod) =~ s|\.a$||;
2304                             my $newobj =
2305                                 catfile(dirname($_),
2306                                         basename($prodname)
2307                                             . '-' . $kind
2308                                             . '-' . basename($_));
2309                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2310                             foreach my $src (@{$prod_sources{$_}}) {
2311                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2312                             }
2313                             # Adjust dependencies
2314                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2315                                 $unified_info{depends}->{$_}->{$deps} = -1;
2316                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2317                             }
2318                             # Adjust includes
2319                             foreach my $k (('source', 'build')) {
2320                                 next unless
2321                                     defined($unified_info{includes}->{$_}->{$k});
2322                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2323                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2324                             }
2325                         } else {
2326                             $unified_info{$dst}->{$prod}->{$_} = 1;
2327                         }
2328                     }
2329                 }
2330             }
2331         }
2332     }
2333     # At this point, we have a number of sources with the value -1.  They
2334     # aren't part of the local build and are probably meant for a different
2335     # platform, and can therefore be cleaned away.  That happens when making
2336     # %unified_info more efficient below.
2337
2338     ### Make unified_info a bit more efficient
2339     # One level structures
2340     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2341         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2342     }
2343     # Two level structures
2344     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2345         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2346             my @items =
2347                 sort
2348                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2349                 keys %{$unified_info{$l1}->{$l2}};
2350             if (@items) {
2351                 $unified_info{$l1}->{$l2} = [ @items ];
2352             } else {
2353                 delete $unified_info{$l1}->{$l2};
2354             }
2355         }
2356     }
2357     # Defines
2358     foreach my $dest (sort keys %{$unified_info{defines}}) {
2359         $unified_info{defines}->{$dest}
2360             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2361                 sort keys %{$unified_info{defines}->{$dest}} ];
2362     }
2363     # Includes
2364     foreach my $dest (sort keys %{$unified_info{includes}}) {
2365         if (defined($unified_info{includes}->{$dest}->{build})) {
2366             my @source_includes = ();
2367             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2368                 if defined($unified_info{includes}->{$dest}->{source});
2369             $unified_info{includes}->{$dest} =
2370                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2371             foreach my $inc (@source_includes) {
2372                 push @{$unified_info{includes}->{$dest}}, $inc
2373                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2374             }
2375         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2376             $unified_info{includes}->{$dest} =
2377                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2378         } else {
2379             delete $unified_info{includes}->{$dest};
2380         }
2381     }
2382
2383     # For convenience collect information regarding directories where
2384     # files are generated, those generated files and the end product
2385     # they end up in where applicable.  Then, add build rules for those
2386     # directories
2387     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2388                      "dso" => [ @{$unified_info{engines}} ],
2389                      "bin" => [ @{$unified_info{programs}} ],
2390                      "script" => [ @{$unified_info{scripts}} ] );
2391     foreach my $type (keys %loopinfo) {
2392         foreach my $product (@{$loopinfo{$type}}) {
2393             my %dirs = ();
2394             my $pd = dirname($product);
2395
2396             foreach (@{$unified_info{sources}->{$product} // []},
2397                      @{$unified_info{shared_sources}->{$product} // []}) {
2398                 my $d = dirname($_);
2399
2400                 # We don't want to create targets for source directories
2401                 # when building out of source
2402                 next if ($config{sourcedir} ne $config{builddir}
2403                              && $d =~ m|^\Q$config{sourcedir}\E|);
2404                 # We already have a "test" target, and the current directory
2405                 # is just silly to make a target for
2406                 next if $d eq "test" || $d eq ".";
2407
2408                 $dirs{$d} = 1;
2409                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2410                     if $d ne $pd;
2411             }
2412             foreach (keys %dirs) {
2413                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2414                     $product;
2415             }
2416         }
2417     }
2418 }
2419
2420 # For the schemes that need it, we provide the old *_obj configs
2421 # from the *_asm_obj ones
2422 foreach (grep /_(asm|aux)_src$/, keys %target) {
2423     my $src = $_;
2424     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2425     $target{$obj} = $target{$src};
2426     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2427     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2428 }
2429
2430 # Write down our configuration where it fits #########################
2431
2432 print "Creating configdata.pm\n";
2433 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2434 print OUT <<"EOF";
2435 #! $config{HASHBANGPERL}
2436
2437 package configdata;
2438
2439 use strict;
2440 use warnings;
2441
2442 use Exporter;
2443 #use vars qw(\@ISA \@EXPORT);
2444 our \@ISA = qw(Exporter);
2445 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2446
2447 EOF
2448 print OUT "our %config = (\n";
2449 foreach (sort keys %config) {
2450     if (ref($config{$_}) eq "ARRAY") {
2451         print OUT "  ", $_, " => [ ", join(", ",
2452                                            map { quotify("perl", $_) }
2453                                            @{$config{$_}}), " ],\n";
2454     } elsif (ref($config{$_}) eq "HASH") {
2455         print OUT "  ", $_, " => {";
2456         if (scalar keys %{$config{$_}} > 0) {
2457             print OUT "\n";
2458             foreach my $key (sort keys %{$config{$_}}) {
2459                 print OUT "      ",
2460                     join(" => ",
2461                          quotify("perl", $key),
2462                          defined $config{$_}->{$key}
2463                              ? quotify("perl", $config{$_}->{$key})
2464                              : "undef");
2465                 print OUT ",\n";
2466             }
2467             print OUT "  ";
2468         }
2469         print OUT "},\n";
2470     } else {
2471         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2472     }
2473 }
2474 print OUT <<"EOF";
2475 );
2476
2477 EOF
2478 print OUT "our %target = (\n";
2479 foreach (sort keys %target) {
2480     if (ref($target{$_}) eq "ARRAY") {
2481         print OUT "  ", $_, " => [ ", join(", ",
2482                                            map { quotify("perl", $_) }
2483                                            @{$target{$_}}), " ],\n";
2484     } else {
2485         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2486     }
2487 }
2488 print OUT <<"EOF";
2489 );
2490
2491 EOF
2492 print OUT "our \%available_protocols = (\n";
2493 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2494 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2495 print OUT <<"EOF";
2496 );
2497
2498 EOF
2499 print OUT "our \@disablables = (\n";
2500 foreach (@disablables) {
2501     print OUT "  ", quotify("perl", $_), ",\n";
2502 }
2503 print OUT <<"EOF";
2504 );
2505
2506 EOF
2507 print OUT "our \%disabled = (\n";
2508 foreach (sort keys %disabled) {
2509     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2510 }
2511 print OUT <<"EOF";
2512 );
2513
2514 EOF
2515 print OUT "our %withargs = (\n";
2516 foreach (sort keys %withargs) {
2517     if (ref($withargs{$_}) eq "ARRAY") {
2518         print OUT "  ", $_, " => [ ", join(", ",
2519                                            map { quotify("perl", $_) }
2520                                            @{$withargs{$_}}), " ],\n";
2521     } else {
2522         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2523     }
2524 }
2525 print OUT <<"EOF";
2526 );
2527
2528 EOF
2529 if ($builder eq "unified") {
2530     my $recurse;
2531     $recurse = sub {
2532         my $indent = shift;
2533         foreach (@_) {
2534             if (ref $_ eq "ARRAY") {
2535                 print OUT " "x$indent, "[\n";
2536                 foreach (@$_) {
2537                     $recurse->($indent + 4, $_);
2538                 }
2539                 print OUT " "x$indent, "],\n";
2540             } elsif (ref $_ eq "HASH") {
2541                 my %h = %$_;
2542                 print OUT " "x$indent, "{\n";
2543                 foreach (sort keys %h) {
2544                     if (ref $h{$_} eq "") {
2545                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2546                     } else {
2547                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2548                         $recurse->($indent + 8, $h{$_});
2549                     }
2550                 }
2551                 print OUT " "x$indent, "},\n";
2552             } else {
2553                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2554             }
2555         }
2556     };
2557     print OUT "our %unified_info = (\n";
2558     foreach (sort keys %unified_info) {
2559         if (ref $unified_info{$_} eq "") {
2560             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2561         } else {
2562             print OUT " "x4, quotify("perl", $_), " =>\n";
2563             $recurse->(8, $unified_info{$_});
2564         }
2565     }
2566     print OUT <<"EOF";
2567 );
2568
2569 EOF
2570 }
2571 print OUT
2572     "# The following data is only used when this files is use as a script\n";
2573 print OUT "my \@makevars = (\n";
2574 foreach (sort keys %user) {
2575     print OUT "    '",$_,"',\n";
2576 }
2577 print OUT ");\n";
2578 print OUT "my \%disabled_info = (\n";
2579 foreach my $what (sort keys %disabled_info) {
2580     print OUT "    '$what' => {\n";
2581     foreach my $info (sort keys %{$disabled_info{$what}}) {
2582         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2583             print OUT "        $info => [ ",
2584                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2585                 " ],\n";
2586         } else {
2587             print OUT "        $info => '", $disabled_info{$what}->{$info},
2588                 "',\n";
2589         }
2590     }
2591     print OUT "    },\n";
2592 }
2593 print OUT ");\n";
2594 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2595 print OUT << 'EOF';
2596 # If run directly, we can give some answers, and even reconfigure
2597 unless (caller) {
2598     use Getopt::Long;
2599     use File::Spec::Functions;
2600     use File::Basename;
2601     use Pod::Usage;
2602
2603     my $here = dirname($0);
2604
2605     my $dump = undef;
2606     my $cmdline = undef;
2607     my $options = undef;
2608     my $target = undef;
2609     my $envvars = undef;
2610     my $makevars = undef;
2611     my $buildparams = undef;
2612     my $reconf = undef;
2613     my $verbose = undef;
2614     my $help = undef;
2615     my $man = undef;
2616     GetOptions('dump|d'                 => \$dump,
2617                'command-line|c'         => \$cmdline,
2618                'options|o'              => \$options,
2619                'target|t'               => \$target,
2620                'environment|e'          => \$envvars,
2621                'make-variables|m'       => \$makevars,
2622                'build-parameters|b'     => \$buildparams,
2623                'reconfigure|reconf|r'   => \$reconf,
2624                'verbose|v'              => \$verbose,
2625                'help'                   => \$help,
2626                'man'                    => \$man)
2627         or die "Errors in command line arguments\n";
2628
2629     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2630             || $buildparams || $reconf || $verbose || $help || $man) {
2631         print STDERR <<"_____";
2632 You must give at least one option.
2633 For more information, do '$0 --help'
2634 _____
2635         exit(2);
2636     }
2637
2638     if ($help) {
2639         pod2usage(-exitval => 0,
2640                   -verbose => 1);
2641     }
2642     if ($man) {
2643         pod2usage(-exitval => 0,
2644                   -verbose => 2);
2645     }
2646     if ($dump || $cmdline) {
2647         print "\nCommand line (with current working directory = $here):\n\n";
2648         print '    ',join(' ',
2649                           $config{PERL},
2650                           catfile($config{sourcedir}, 'Configure'),
2651                           @{$config{perlargv}}), "\n";
2652         print "\nPerl information:\n\n";
2653         print '    ',$config{perl_cmd},"\n";
2654         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2655     }
2656     if ($dump || $options) {
2657         my $longest = 0;
2658         my $longest2 = 0;
2659         foreach my $what (@disablables) {
2660             $longest = length($what) if $longest < length($what);
2661             $longest2 = length($disabled{$what})
2662                 if $disabled{$what} && $longest2 < length($disabled{$what});
2663         }
2664         print "\nEnabled features:\n\n";
2665         foreach my $what (@disablables) {
2666             print "    $what\n" unless $disabled{$what};
2667         }
2668         print "\nDisabled features:\n\n";
2669         foreach my $what (@disablables) {
2670             if ($disabled{$what}) {
2671                 print "    $what", ' ' x ($longest - length($what) + 1),
2672                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2673                 print $disabled_info{$what}->{macro}
2674                     if $disabled_info{$what}->{macro};
2675                 print ' (skip ',
2676                     join(', ', @{$disabled_info{$what}->{skipped}}),
2677                     ')'
2678                     if $disabled_info{$what}->{skipped};
2679                 print "\n";
2680             }
2681         }
2682     }
2683     if ($dump || $target) {
2684         print "\nConfig target attributes:\n\n";
2685         foreach (sort keys %target) {
2686             next if $_ =~ m|^_| || $_ eq 'template';
2687             my $quotify = sub {
2688                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2689             };
2690             print '    ', $_, ' => ';
2691             if (ref($target{$_}) eq "ARRAY") {
2692                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2693             } else {
2694                 print $quotify->($target{$_}), ",\n"
2695             }
2696         }
2697     }
2698     if ($dump || $envvars) {
2699         print "\nRecorded environment:\n\n";
2700         foreach (sort keys %{$config{perlenv}}) {
2701             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2702         }
2703     }
2704     if ($dump || $makevars) {
2705         print "\nMakevars:\n\n";
2706         foreach my $var (@makevars) {
2707             my $prefix = '';
2708             $prefix = $config{CROSS_COMPILE}
2709                 if grep { $var eq $_ } @user_crossable;
2710             $prefix //= '';
2711             print '    ',$var,' ' x (16 - length $var),'= ',
2712                 (ref $config{$var} eq 'ARRAY'
2713                  ? join(' ', @{$config{$var}})
2714                  : $prefix.$config{$var}),
2715                 "\n"
2716                 if defined $config{$var};
2717         }
2718
2719         my @buildfile = ($config{builddir}, $config{build_file});
2720         unshift @buildfile, $here
2721             unless file_name_is_absolute($config{builddir});
2722         my $buildfile = canonpath(catdir(@buildfile));
2723         print <<"_____";
2724
2725 NOTE: These variables only represent the configuration view.  The build file
2726 template may have processed these variables further, please have a look at the
2727 build file for more exact data:
2728     $buildfile
2729 _____
2730     }
2731     if ($dump || $buildparams) {
2732         my @buildfile = ($config{builddir}, $config{build_file});
2733         unshift @buildfile, $here
2734             unless file_name_is_absolute($config{builddir});
2735         print "\nbuild file:\n\n";
2736         print "    ", canonpath(catfile(@buildfile)),"\n";
2737
2738         print "\nbuild file templates:\n\n";
2739         foreach (@{$config{build_file_templates}}) {
2740             my @tmpl = ($_);
2741             unshift @tmpl, $here
2742                 unless file_name_is_absolute($config{sourcedir});
2743             print '    ',canonpath(catfile(@tmpl)),"\n";
2744         }
2745     }
2746     if ($reconf) {
2747         if ($verbose) {
2748             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2749             foreach (sort keys %{$config{perlenv}}) {
2750                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2751             }
2752         }
2753
2754         chdir $here;
2755         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2756     }
2757 }
2758
2759 1;
2760
2761 __END__
2762
2763 =head1 NAME
2764
2765 configdata.pm - configuration data for OpenSSL builds
2766
2767 =head1 SYNOPSIS
2768
2769 Interactive:
2770
2771   perl configdata.pm [options]
2772
2773 As data bank module:
2774
2775   use configdata;
2776
2777 =head1 DESCRIPTION
2778
2779 This module can be used in two modes, interactively and as a module containing
2780 all the data recorded by OpenSSL's Configure script.
2781
2782 When used interactively, simply run it as any perl script, with at least one
2783 option, and you will get the information you ask for.  See L</OPTIONS> below.
2784
2785 When loaded as a module, you get a few databanks with useful information to
2786 perform build related tasks.  The databanks are:
2787
2788     %config             Configured things.
2789     %target             The OpenSSL config target with all inheritances
2790                         resolved.
2791     %disabled           The features that are disabled.
2792     @disablables        The list of features that can be disabled.
2793     %withargs           All data given through --with-THING options.
2794     %unified_info       All information that was computed from the build.info
2795                         files.
2796
2797 =head1 OPTIONS
2798
2799 =over 4
2800
2801 =item B<--help>
2802
2803 Print a brief help message and exit.
2804
2805 =item B<--man>
2806
2807 Print the manual page and exit.
2808
2809 =item B<--dump> | B<-d>
2810
2811 Print all relevant configuration data.  This is equivalent to B<--command-line>
2812 B<--options> B<--target> B<--environment> B<--make-variables>
2813 B<--build-parameters>.
2814
2815 =item B<--command-line> | B<-c>
2816
2817 Print the current configuration command line.
2818
2819 =item B<--options> | B<-o>
2820
2821 Print the features, both enabled and disabled, and display defined macro and
2822 skipped directories where applicable.
2823
2824 =item B<--target> | B<-t>
2825
2826 Print the config attributes for this config target.
2827
2828 =item B<--environment> | B<-e>
2829
2830 Print the environment variables and their values at the time of configuration.
2831
2832 =item B<--make-variables> | B<-m>
2833
2834 Print the main make variables generated in the current configuration
2835
2836 =item B<--build-parameters> | B<-b>
2837
2838 Print the build parameters, i.e. build file and build file templates.
2839
2840 =item B<--reconfigure> | B<--reconf> | B<-r>
2841
2842 Redo the configuration.
2843
2844 =item B<--verbose> | B<-v>
2845
2846 Verbose output.
2847
2848 =back
2849
2850 =cut
2851
2852 EOF
2853 close(OUT);
2854 if ($builder_platform eq 'unix') {
2855     my $mode = (0755 & ~umask);
2856     chmod $mode, 'configdata.pm'
2857         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2858 }
2859
2860 my %builders = (
2861     unified => sub {
2862         print 'Creating ',$target{build_file},"\n";
2863         run_dofile(catfile($blddir, $target{build_file}),
2864                    @{$config{build_file_templates}});
2865     },
2866     );
2867
2868 $builders{$builder}->($builder_platform, @builder_opts);
2869
2870 $SIG{__DIE__} = $orig_death_handler;
2871
2872 print <<"EOF" if ($disabled{threads} eq "unavailable");
2873
2874 The library could not be configured for supporting multi-threaded
2875 applications as the compiler options required on this system are not known.
2876 See file INSTALL for details if you need multi-threading.
2877 EOF
2878
2879 print <<"EOF" if ($no_shared_warn);
2880
2881 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2882 platform, so we will pretend you gave the option 'no-pic', which also disables
2883 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2884 or position independent code, please let us know (but please first make sure
2885 you have tried with a current version of OpenSSL).
2886 EOF
2887
2888 print <<"EOF";
2889
2890 **********************************************************************
2891 ***                                                                ***
2892 ***   OpenSSL has been successfully configured                     ***
2893 ***                                                                ***
2894 ***   If you encounter a problem while building, please open an    ***
2895 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2896 ***   and include the output from the following command:           ***
2897 ***                                                                ***
2898 ***       perl configdata.pm --dump                                ***
2899 ***                                                                ***
2900 ***   (If you are new to OpenSSL, you might want to consult the    ***
2901 ***   'Troubleshooting' section in the INSTALL file first)         ***
2902 ***                                                                ***
2903 **********************************************************************
2904 EOF
2905
2906 exit(0);
2907
2908 ######################################################################
2909 #
2910 # Helpers and utility functions
2911 #
2912
2913 # Death handler, to print a helpful message in case of failure #######
2914 #
2915 sub death_handler {
2916     die @_ if $^S;              # To prevent the added message in eval blocks
2917     my $build_file = $target{build_file} // "build file";
2918     my @message = ( <<"_____", @_ );
2919
2920 Failure!  $build_file wasn't produced.
2921 Please read INSTALL and associated NOTES files.  You may also have to look over
2922 your available compiler tool chain or change your configuration.
2923
2924 _____
2925
2926     # Dying is terminal, so it's ok to reset the signal handler here.
2927     $SIG{__DIE__} = $orig_death_handler;
2928     die @message;
2929 }
2930
2931 # Configuration file reading #########################################
2932
2933 # Note: All of the helper functions are for lazy evaluation.  They all
2934 # return a CODE ref, which will return the intended value when evaluated.
2935 # Thus, whenever there's mention of a returned value, it's about that
2936 # intended value.
2937
2938 # Helper function to implement conditional inheritance depending on the
2939 # value of $disabled{asm}.  Used in inherit_from values as follows:
2940 #
2941 #      inherit_from => [ "template", asm("asm_tmpl") ]
2942 #
2943 sub asm {
2944     my @x = @_;
2945     sub {
2946         $disabled{asm} ? () : @x;
2947     }
2948 }
2949
2950 # Helper function to implement conditional value variants, with a default
2951 # plus additional values based on the value of $config{build_type}.
2952 # Arguments are given in hash table form:
2953 #
2954 #       picker(default => "Basic string: ",
2955 #              debug   => "debug",
2956 #              release => "release")
2957 #
2958 # When configuring with --debug, the resulting string will be
2959 # "Basic string: debug", and when not, it will be "Basic string: release"
2960 #
2961 # This can be used to create variants of sets of flags according to the
2962 # build type:
2963 #
2964 #       cflags => picker(default => "-Wall",
2965 #                        debug   => "-g -O0",
2966 #                        release => "-O3")
2967 #
2968 sub picker {
2969     my %opts = @_;
2970     return sub { add($opts{default} || (),
2971                      $opts{$config{build_type}} || ())->(); }
2972 }
2973
2974 # Helper function to combine several values of different types into one.
2975 # This is useful if you want to combine a string with the result of a
2976 # lazy function, such as:
2977 #
2978 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2979 #
2980 sub combine {
2981     my @stuff = @_;
2982     return sub { add(@stuff)->(); }
2983 }
2984
2985 # Helper function to implement conditional values depending on the value
2986 # of $disabled{threads}.  Can be used as follows:
2987 #
2988 #       cflags => combine("-Wall", threads("-pthread"))
2989 #
2990 sub threads {
2991     my @flags = @_;
2992     return sub { add($disabled{threads} ? () : @flags)->(); }
2993 }
2994
2995 sub shared {
2996     my @flags = @_;
2997     return sub { add($disabled{shared} ? () : @flags)->(); }
2998 }
2999
3000 our $add_called = 0;
3001 # Helper function to implement adding values to already existing configuration
3002 # values.  It handles elements that are ARRAYs, CODEs and scalars
3003 sub _add {
3004     my $separator = shift;
3005
3006     # If there's any ARRAY in the collection of values OR the separator
3007     # is undef, we will return an ARRAY of combined values, otherwise a
3008     # string of joined values with $separator as the separator.
3009     my $found_array = !defined($separator);
3010
3011     my @values =
3012         map {
3013             my $res = $_;
3014             while (ref($res) eq "CODE") {
3015                 $res = $res->();
3016             }
3017             if (defined($res)) {
3018                 if (ref($res) eq "ARRAY") {
3019                     $found_array = 1;
3020                     @$res;
3021                 } else {
3022                     $res;
3023                 }
3024             } else {
3025                 ();
3026             }
3027     } (@_);
3028
3029     $add_called = 1;
3030
3031     if ($found_array) {
3032         [ @values ];
3033     } else {
3034         join($separator, grep { defined($_) && $_ ne "" } @values);
3035     }
3036 }
3037 sub add_before {
3038     my $separator = " ";
3039     if (ref($_[$#_]) eq "HASH") {
3040         my $opts = pop;
3041         $separator = $opts->{separator};
3042     }
3043     my @x = @_;
3044     sub { _add($separator, @x, @_) };
3045 }
3046 sub add {
3047     my $separator = " ";
3048     if (ref($_[$#_]) eq "HASH") {
3049         my $opts = pop;
3050         $separator = $opts->{separator};
3051     }
3052     my @x = @_;
3053     sub { _add($separator, @_, @x) };
3054 }
3055
3056 sub read_eval_file {
3057     my $fname = shift;
3058     my $content;
3059     my @result;
3060
3061     open F, "< $fname" or die "Can't open '$fname': $!\n";
3062     {
3063         undef local $/;
3064         $content = <F>;
3065     }
3066     close F;
3067     {
3068         local $@;
3069
3070         @result = ( eval $content );
3071         warn $@ if $@;
3072     }
3073     return wantarray ? @result : $result[0];
3074 }
3075
3076 # configuration reader, evaluates the input file as a perl script and expects
3077 # it to fill %targets with target configurations.  Those are then added to
3078 # %table.
3079 sub read_config {
3080     my $fname = shift;
3081     my %targets;
3082
3083     {
3084         # Protect certain tables from tampering
3085         local %table = ();
3086
3087         %targets = read_eval_file($fname);
3088     }
3089     my %preexisting = ();
3090     foreach (sort keys %targets) {
3091         $preexisting{$_} = 1 if $table{$_};
3092     }
3093     die <<"EOF",
3094 The following config targets from $fname
3095 shadow pre-existing config targets with the same name:
3096 EOF
3097         map { "  $_\n" } sort keys %preexisting
3098         if %preexisting;
3099
3100
3101     # For each target, check that it's configured with a hash table.
3102     foreach (keys %targets) {
3103         if (ref($targets{$_}) ne "HASH") {
3104             if (ref($targets{$_}) eq "") {
3105                 warn "Deprecated target configuration for $_, ignoring...\n";
3106             } else {
3107                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3108             }
3109             delete $targets{$_};
3110         } else {
3111             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3112         }
3113     }
3114
3115     %table = (%table, %targets);
3116
3117 }
3118
3119 # configuration resolver.  Will only resolve all the lazy evaluation
3120 # codeblocks for the chosen target and all those it inherits from,
3121 # recursively
3122 sub resolve_config {
3123     my $target = shift;
3124     my @breadcrumbs = @_;
3125
3126 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3127
3128     if (grep { $_ eq $target } @breadcrumbs) {
3129         die "inherit_from loop!  target backtrace:\n  "
3130             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3131     }
3132
3133     if (!defined($table{$target})) {
3134         warn "Warning! target $target doesn't exist!\n";
3135         return ();
3136     }
3137     # Recurse through all inheritances.  They will be resolved on the
3138     # fly, so when this operation is done, they will all just be a
3139     # bunch of attributes with string values.
3140     # What we get here, though, are keys with references to lists of
3141     # the combined values of them all.  We will deal with lists after
3142     # this stage is done.
3143     my %combined_inheritance = ();
3144     if ($table{$target}->{inherit_from}) {
3145         my @inherit_from =
3146             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3147         foreach (@inherit_from) {
3148             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3149
3150             # 'template' is a marker that's considered private to
3151             # the config that had it.
3152             delete $inherited_config{template};
3153
3154             foreach (keys %inherited_config) {
3155                 if (!$combined_inheritance{$_}) {
3156                     $combined_inheritance{$_} = [];
3157                 }
3158                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3159             }
3160         }
3161     }
3162
3163     # We won't need inherit_from in this target any more, since we've
3164     # resolved all the inheritances that lead to this
3165     delete $table{$target}->{inherit_from};
3166
3167     # Now is the time to deal with those lists.  Here's the place to
3168     # decide what shall be done with those lists, all based on the
3169     # values of the target we're currently dealing with.
3170     # - If a value is a coderef, it will be executed with the list of
3171     #   inherited values as arguments.
3172     # - If the corresponding key doesn't have a value at all or is the
3173     #   empty string, the inherited value list will be run through the
3174     #   default combiner (below), and the result becomes this target's
3175     #   value.
3176     # - Otherwise, this target's value is assumed to be a string that
3177     #   will simply override the inherited list of values.
3178     my $default_combiner = add();
3179
3180     my %all_keys =
3181         map { $_ => 1 } (keys %combined_inheritance,
3182                          keys %{$table{$target}});
3183
3184     sub process_values {
3185         my $object    = shift;
3186         my $inherited = shift;  # Always a [ list ]
3187         my $target    = shift;
3188         my $entry     = shift;
3189
3190         $add_called = 0;
3191
3192         while(ref($object) eq "CODE") {
3193             $object = $object->(@$inherited);
3194         }
3195         if (!defined($object)) {
3196             return ();
3197         }
3198         elsif (ref($object) eq "ARRAY") {
3199             local $add_called;  # To make sure recursive calls don't affect it
3200             return [ map { process_values($_, $inherited, $target, $entry) }
3201                      @$object ];
3202         } elsif (ref($object) eq "") {
3203             return $object;
3204         } else {
3205             die "cannot handle reference type ",ref($object)
3206                 ," found in target ",$target," -> ",$entry,"\n";
3207         }
3208     }
3209
3210     foreach (sort keys %all_keys) {
3211         my $previous = $combined_inheritance{$_};
3212
3213         # Current target doesn't have a value for the current key?
3214         # Assign it the default combiner, the rest of this loop body
3215         # will handle it just like any other coderef.
3216         if (!exists $table{$target}->{$_}) {
3217             $table{$target}->{$_} = $default_combiner;
3218         }
3219
3220         $table{$target}->{$_} = process_values($table{$target}->{$_},
3221                                                $combined_inheritance{$_},
3222                                                $target, $_);
3223         unless(defined($table{$target}->{$_})) {
3224             delete $table{$target}->{$_};
3225         }
3226 #        if ($extra_checks &&
3227 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3228 #            warn "$_ got replaced in $target\n";
3229 #        }
3230     }
3231
3232     # Finally done, return the result.
3233     return %{$table{$target}};
3234 }
3235
3236 sub usage
3237         {
3238         print STDERR $usage;
3239         print STDERR "\npick os/compiler from:\n";
3240         my $j=0;
3241         my $i;
3242         my $k=0;
3243         foreach $i (sort keys %table)
3244                 {
3245                 next if $table{$i}->{template};
3246                 next if $i =~ /^debug/;
3247                 $k += length($i) + 1;
3248                 if ($k > 78)
3249                         {
3250                         print STDERR "\n";
3251                         $k=length($i);
3252                         }
3253                 print STDERR $i . " ";
3254                 }
3255         foreach $i (sort keys %table)
3256                 {
3257                 next if $table{$i}->{template};
3258                 next if $i !~ /^debug/;
3259                 $k += length($i) + 1;
3260                 if ($k > 78)
3261                         {
3262                         print STDERR "\n";
3263                         $k=length($i);
3264                         }
3265                 print STDERR $i . " ";
3266                 }
3267         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3268         exit(1);
3269         }
3270
3271 sub run_dofile
3272 {
3273     my $out = shift;
3274     my @templates = @_;
3275
3276     unlink $out || warn "Can't remove $out, $!"
3277         if -f $out;
3278     foreach (@templates) {
3279         die "Can't open $_, $!" unless -f $_;
3280     }
3281     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3282     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3283     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3284     system($cmd);
3285     exit 1 if $? != 0;
3286     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3287 }
3288
3289 sub compiler_predefined {
3290     state %predefined;
3291     my $cc = shift;
3292
3293     return () if $^O eq 'VMS';
3294
3295     die 'compiler_predefined called without a compiler command'
3296         unless $cc;
3297
3298     if (! $predefined{$cc}) {
3299
3300         $predefined{$cc} = {};
3301
3302         # collect compiler pre-defines from gcc or gcc-alike...
3303         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3304         while (my $l = <PIPE>) {
3305             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3306             $predefined{$cc}->{$1} = $2 // '';
3307         }
3308         close(PIPE);
3309     }
3310
3311     return %{$predefined{$cc}};
3312 }
3313
3314 sub which
3315 {
3316     my ($name)=@_;
3317
3318     if (eval { require IPC::Cmd; 1; }) {
3319         IPC::Cmd->import();
3320         return scalar IPC::Cmd::can_run($name);
3321     } else {
3322         # if there is $directories component in splitpath,
3323         # then it's not something to test with $PATH...
3324         return $name if (File::Spec->splitpath($name))[1];
3325
3326         foreach (File::Spec->path()) {
3327             my $fullpath = catfile($_, "$name$target{exe_extension}");
3328             if (-f $fullpath and -x $fullpath) {
3329                 return $fullpath;
3330             }
3331         }
3332     }
3333 }
3334
3335 sub env
3336 {
3337     my $name = shift;
3338     my %opts = @_;
3339
3340     unless ($opts{cacheonly}) {
3341         # Note that if $ENV{$name} doesn't exist or is undefined,
3342         # $config{perlenv}->{$name} will be created with the value
3343         # undef.  This is intentional.
3344
3345         $config{perlenv}->{$name} = $ENV{$name}
3346             if ! exists $config{perlenv}->{$name};
3347     }
3348     return $config{perlenv}->{$name};
3349 }
3350
3351 # Configuration printer ##############################################
3352
3353 sub print_table_entry
3354 {
3355     local $now_printing = shift;
3356     my %target = resolve_config($now_printing);
3357     my $type = shift;
3358
3359     # Don't print the templates
3360     return if $target{template};
3361
3362     my @sequence = (
3363         "sys_id",
3364         "cpp",
3365         "cppflags",
3366         "defines",
3367         "includes",
3368         "cc",
3369         "cflags",
3370         "unistd",
3371         "ld",
3372         "lflags",
3373         "loutflag",
3374         "ex_libs",
3375         "bn_ops",
3376         "apps_aux_src",
3377         "cpuid_asm_src",
3378         "uplink_aux_src",
3379         "bn_asm_src",
3380         "ec_asm_src",
3381         "des_asm_src",
3382         "aes_asm_src",
3383         "bf_asm_src",
3384         "md5_asm_src",
3385         "cast_asm_src",
3386         "sha1_asm_src",
3387         "rc4_asm_src",
3388         "rmd160_asm_src",
3389         "rc5_asm_src",
3390         "wp_asm_src",
3391         "cmll_asm_src",
3392         "modes_asm_src",
3393         "padlock_asm_src",
3394         "chacha_asm_src",
3395         "poly1035_asm_src",
3396         "thread_scheme",
3397         "perlasm_scheme",
3398         "dso_scheme",
3399         "shared_target",
3400         "shared_cflag",
3401         "shared_defines",
3402         "shared_ldflag",
3403         "shared_rcflag",
3404         "shared_extension",
3405         "dso_extension",
3406         "obj_extension",
3407         "exe_extension",
3408         "ranlib",
3409         "ar",
3410         "arflags",
3411         "aroutflag",
3412         "rc",
3413         "rcflags",
3414         "rcoutflag",
3415         "mt",
3416         "mtflags",
3417         "mtinflag",
3418         "mtoutflag",
3419         "multilib",
3420         "build_scheme",
3421         );
3422
3423     if ($type eq "TABLE") {
3424         print "\n";
3425         print "*** $now_printing\n";
3426         foreach (@sequence) {
3427             if (ref($target{$_}) eq "ARRAY") {
3428                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3429             } else {
3430                 printf "\$%-12s = %s\n", $_, $target{$_};
3431             }
3432         }
3433     } elsif ($type eq "HASH") {
3434         my $largest =
3435             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3436         print "    '$now_printing' => {\n";
3437         foreach (@sequence) {
3438             if ($target{$_}) {
3439                 if (ref($target{$_}) eq "ARRAY") {
3440                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3441                 } else {
3442                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3443                 }
3444             }
3445         }
3446         print "    },\n";
3447     }
3448 }
3449
3450 # Utility routines ###################################################
3451
3452 # On VMS, if the given file is a logical name, File::Spec::Functions
3453 # will consider it an absolute path.  There are cases when we want a
3454 # purely syntactic check without checking the environment.
3455 sub isabsolute {
3456     my $file = shift;
3457
3458     # On non-platforms, we just use file_name_is_absolute().
3459     return file_name_is_absolute($file) unless $^O eq "VMS";
3460
3461     # If the file spec includes a device or a directory spec,
3462     # file_name_is_absolute() is perfectly safe.
3463     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3464
3465     # Here, we know the given file spec isn't absolute
3466     return 0;
3467 }
3468
3469 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3470 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3471 # realpath() requires that at least all path components except the last is an
3472 # existing directory.  On VMS, the last component of the directory spec must
3473 # exist.
3474 sub absolutedir {
3475     my $dir = shift;
3476
3477     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3478     # will return the volume name for the device, no matter what.  Also,
3479     # it will return an incorrect directory spec if the argument is a
3480     # directory that doesn't exist.
3481     if ($^O eq "VMS") {
3482         return rel2abs($dir);
3483     }
3484
3485     # We use realpath() on Unix, since no other will properly clean out
3486     # a directory spec.
3487     use Cwd qw/realpath/;
3488
3489     return realpath($dir);
3490 }
3491
3492 sub quotify {
3493     my %processors = (
3494         perl    => sub { my $x = shift;
3495                          $x =~ s/([\\\$\@"])/\\$1/g;
3496                          return '"'.$x.'"'; },
3497         maybeshell => sub { my $x = shift;
3498                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3499                             if ($x ne $y || $x =~ m|\s|) {
3500                                 return '"'.$y.'"';
3501                             } else {
3502                                 return $x;
3503                             }
3504                         },
3505         );
3506     my $for = shift;
3507     my $processor =
3508         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3509
3510     return map { $processor->($_); } @_;
3511 }
3512
3513 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3514 # $filename is a file name to read from
3515 # $line_concat_cond_re is a regexp detecting a line continuation ending
3516 # $line_concat is a CODEref that takes care of concatenating two lines
3517 sub collect_from_file {
3518     my $filename = shift;
3519     my $line_concat_cond_re = shift;
3520     my $line_concat = shift;
3521
3522     open my $fh, $filename || die "unable to read $filename: $!\n";
3523     return sub {
3524         my $saved_line = "";
3525         $_ = "";
3526         while (<$fh>) {
3527             s|\R$||;
3528             if (defined $line_concat) {
3529                 $_ = $line_concat->($saved_line, $_);
3530                 $saved_line = "";
3531             }
3532             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3533                 $saved_line = $_;
3534                 next;
3535             }
3536             return $_;
3537         }
3538         die "$filename ending with continuation line\n" if $_;
3539         close $fh;
3540         return undef;
3541     }
3542 }
3543
3544 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3545 # $array is an ARRAYref of lines
3546 # $line_concat_cond_re is a regexp detecting a line continuation ending
3547 # $line_concat is a CODEref that takes care of concatenating two lines
3548 sub collect_from_array {
3549     my $array = shift;
3550     my $line_concat_cond_re = shift;
3551     my $line_concat = shift;
3552     my @array = (@$array);
3553
3554     return sub {
3555         my $saved_line = "";
3556         $_ = "";
3557         while (defined($_ = shift @array)) {
3558             s|\R$||;
3559             if (defined $line_concat) {
3560                 $_ = $line_concat->($saved_line, $_);
3561                 $saved_line = "";
3562             }
3563             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3564                 $saved_line = $_;
3565                 next;
3566             }
3567             return $_;
3568         }
3569         die "input text ending with continuation line\n" if $_;
3570         return undef;
3571     }
3572 }
3573
3574 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3575 # $lineiterator is a CODEref that delivers one line at a time.
3576 # All following arguments are regex/CODEref pairs, where the regexp detects a
3577 # line and the CODEref does something with the result of the regexp.
3578 sub collect_information {
3579     my $lineiterator = shift;
3580     my %collectors = @_;
3581
3582     while(defined($_ = $lineiterator->())) {
3583         s|\R$||;
3584         my $found = 0;
3585         if ($collectors{"BEFORE"}) {
3586             $collectors{"BEFORE"}->($_);
3587         }
3588         foreach my $re (keys %collectors) {
3589             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3590                 $collectors{$re}->($lineiterator);
3591                 $found = 1;
3592             };
3593         }
3594         if ($collectors{"OTHERWISE"}) {
3595             $collectors{"OTHERWISE"}->($lineiterator, $_)
3596                 unless $found || !defined $collectors{"OTHERWISE"};
3597         }
3598         if ($collectors{"AFTER"}) {
3599             $collectors{"AFTER"}->($_);
3600         }
3601     }
3602 }
3603
3604 # tokenize($line)
3605 # $line is a line of text to split up into tokens
3606 # returns a list of tokens
3607 #
3608 # Tokens are divided by spaces.  If the tokens include spaces, they
3609 # have to be quoted with single or double quotes.  Double quotes
3610 # inside a double quoted token must be escaped.  Escaping is done
3611 # with backslash.
3612 # Basically, the same quoting rules apply for " and ' as in any
3613 # Unix shell.
3614 sub tokenize {
3615     my $line = my $debug_line = shift;
3616     my @result = ();
3617
3618     while ($line =~ s|^\s+||, $line ne "") {
3619         my $token = "";
3620         while ($line ne "" && $line !~ m|^\s|) {
3621             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3622                 $token .= $1;
3623                 $line = $';
3624             } elsif ($line =~ m/^'([^']*)'/) {
3625                 $token .= $1;
3626                 $line = $';
3627             } elsif ($line =~ m/^(\S+)/) {
3628                 $token .= $1;
3629                 $line = $';
3630             }
3631         }
3632         push @result, $token;
3633     }
3634
3635     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3636         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3637         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3638     }
3639     return @result;
3640 }