List undocumented macros
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2017 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the OpenSSL license (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use File::Basename;
16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
17 use File::Path qw/mkpath/;
18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
19
20 # see INSTALL for instructions.
21
22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
23
24 # Options:
25 #
26 # --config      add the given configuration file, which will be read after
27 #               any "Configurations*" files that are found in the same
28 #               directory as this script.
29 # --prefix      prefix for the OpenSSL installation, which includes the
30 #               directories bin, lib, include, share/man, share/doc/openssl
31 #               This becomes the value of INSTALLTOP in Makefile
32 #               (Default: /usr/local)
33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
34 #               If it's a relative directory, it will be added on the directory
35 #               given with --prefix.
36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
37 #               (Default: PREFIX/ssl)
38 #
39 # --cross-compile-prefix Add specified prefix to binutils components.
40 #
41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
42 #               interfaces deprecated as of the specified OpenSSL version.
43 #
44 # no-hw-xxx     do not compile support for specific crypto hardware.
45 #               Generic OpenSSL-style methods relating to this support
46 #               are always compiled but return NULL if the hardware
47 #               support isn't compiled.
48 # no-hw         do not compile support for any crypto hardware.
49 # [no-]threads  [don't] try to create a library that is suitable for
50 #               multithreaded applications (default is "threads" if we
51 #               know how to do it)
52 # [no-]shared   [don't] try to create shared libraries when supported.
53 # [no-]pic      [don't] try to build position independent code when supported.
54 #               If disabled, it also disables shared and dynamic-engine.
55 # no-asm        do not use assembler
56 # no-dso        do not compile in any native shared-library methods. This
57 #               will ensure that all methods just return NULL.
58 # no-egd        do not compile support for the entropy-gathering daemon APIs
59 # [no-]zlib     [don't] compile support for zlib compression.
60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
61 #               library and will be loaded in run-time by the OpenSSL library.
62 # sctp          include SCTP support
63 # enable-weak-ssl-ciphers
64 #               Enable weak ciphers that are disabled by default. This currently
65 #               only includes RC4 based ciphers.
66 # 386           generate 80386 code in assembly modules
67 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
68 #               mentioned '386' option implies this one
69 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
70 # -<xxx> +<xxx> compiler options are passed through
71 # -static       while -static is also a pass-through compiler option (and
72 #               as such is limited to environments where it's actually
73 #               meaningful), it triggers a number configuration options,
74 #               namely no-dso, no-pic, no-shared and no-threads. It is
75 #               argued that the only reason to produce statically linked
76 #               binaries (and in context it means executables linked with
77 #               -static flag, and not just executables linked with static
78 #               libcrypto.a) is to eliminate dependency on specific run-time,
79 #               a.k.a. libc version. The mentioned config options are meant
80 #               to achieve just that. Unfortunately on Linux it's impossible
81 #               to eliminate the dependency completely for openssl executable
82 #               because of getaddrinfo and gethostbyname calls, which can
83 #               invoke dynamically loadable library facility anyway to meet
84 #               the lookup requests. For this reason on Linux statically
85 #               linked openssl executable has rather debugging value than
86 #               production quality.
87 #
88 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
89 #               provided to stack calls. Generates unique stack functions for
90 #               each possible stack type.
91 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
92 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
93 # Following are set automatically by this script
94 #
95 # MD5_ASM       use some extra md5 assembler,
96 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
97 # RMD160_ASM    use some extra ripemd160 assembler,
98 # SHA256_ASM    sha256_block is implemented in assembler
99 # SHA512_ASM    sha512_block is implemented in assembler
100 # AES_ASM       AES_[en|de]crypt is implemented in assembler
101
102 # Minimum warning options... any contributions to OpenSSL should at least get
103 # past these.
104
105 # DEBUG_UNUSED enables __owur (warn unused result) checks.
106 # -DPEDANTIC complements -pedantic and is meant to mask code that
107 # is not strictly standard-compliant and/or implementation-specific,
108 # e.g. inline assembly, disregards to alignment requirements, such
109 # that -pedantic would complain about. Incidentally -DPEDANTIC has
110 # to be used even in sanitized builds, because sanitizer too is
111 # supposed to and does take notice of non-standard behaviour. Then
112 # -pedantic with pre-C9x compiler would also complain about 'long
113 # long' not being supported. As 64-bit algorithms are common now,
114 # it grew impossible to resolve this without sizeable additional
115 # code, so we just tell compiler to be pedantic about everything
116 # but 'long long' type.
117
118 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
119         . " -Wswitch"
120         . " -DPEDANTIC -pedantic -Wno-long-long"
121         . " -Wall"
122         . " -Wextra"
123         . " -Wno-unused-parameter"
124         . " -Wno-missing-field-initializers"
125         . " -Wsign-compare"
126         . " -Wmissing-prototypes"
127         . " -Wshadow"
128         . " -Wformat"
129         . " -Wtype-limits"
130         . " -Wundef"
131         . " -Werror"
132         ;
133
134 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
135 # TODO(openssl-team): fix problems and investigate if (at least) the
136 # following warnings can also be enabled:
137 #       -Wcast-align
138 #       -Wunreachable-code -- no, too ugly/compiler-specific
139 #       -Wlanguage-extension-token -- no, we use asm()
140 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
141 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
142 my $clang_devteam_warn = ""
143         . " -Qunused-arguments"
144         . " -Wswitch-default"
145         . " -Wno-parentheses-equality"
146         . " -Wno-language-extension-token"
147         . " -Wno-extended-offsetof"
148         . " -Wconditional-uninitialized"
149         . " -Wincompatible-pointer-types-discards-qualifiers"
150         . " -Wmissing-variable-declarations"
151         ;
152
153 # This adds backtrace information to the memory leak info.  Is only used
154 # when crypto-mdebug-backtrace is enabled.
155 my $memleak_devteam_backtrace = "-rdynamic";
156
157 my $strict_warnings = 0;
158
159 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
160 # which would cover all BSD flavors. -pthread applies to them all,
161 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
162 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
163 # which has to be accompanied by explicit -D_THREAD_SAFE and
164 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
165 # seems to be sufficient?
166 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
167
168 #
169 # API compatibility name to version number mapping.
170 #
171 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
172 my $apitable = {
173     "1.1.0" => "0x10100000L",
174     "1.0.0" => "0x10000000L",
175     "0.9.8" => "0x00908000L",
176 };
177
178 our %table = ();
179 our %config = ();
180 our %withargs = ();
181
182 # Forward declarations ###############################################
183
184 # read_config(filename)
185 #
186 # Reads a configuration file and populates %table with the contents
187 # (which the configuration file places in %targets).
188 sub read_config;
189
190 # resolve_config(target)
191 #
192 # Resolves all the late evaluations, inheritances and so on for the
193 # chosen target and any target it inherits from.
194 sub resolve_config;
195
196
197 # Information collection #############################################
198
199 # Unified build supports separate build dir
200 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
201 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
202 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
203
204 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
205
206 $config{sourcedir} = abs2rel($srcdir);
207 $config{builddir} = abs2rel($blddir);
208
209 # Collect reconfiguration information if needed
210 my @argvcopy=@ARGV;
211
212 if (grep /^reconf(igure)?$/, @argvcopy) {
213     if (-f "./configdata.pm") {
214         my $file = "./configdata.pm";
215         unless (my $return = do $file) {
216             die "couldn't parse $file: $@" if $@;
217             die "couldn't do $file: $!"    unless defined $return;
218             die "couldn't run $file"       unless $return;
219         }
220
221         @argvcopy = defined($configdata::config{perlargv}) ?
222             @{$configdata::config{perlargv}} : ();
223         die "Incorrect data to reconfigure, please do a normal configuration\n"
224             if (grep(/^reconf/,@argvcopy));
225         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
226             if defined($configdata::config{cross_compile_prefix});
227         $ENV{CC} = $configdata::config{cc}
228             if defined($configdata::config{cc});
229         $ENV{CXX} = $configdata::config{cxx}
230             if defined($configdata::config{cxx});
231         $ENV{BUILDFILE} = $configdata::config{build_file}
232             if defined($configdata::config{build_file});
233         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
234             if defined($configdata::config{local_config_dir});
235
236         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
237         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
238             if $ENV{CROSS_COMPILE};
239         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
240         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
241         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
242         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
243             if $ENV{$local_config_envname};
244     } else {
245         die "Insufficient data to reconfigure, please do a normal configuration\n";
246     }
247 }
248
249 $config{perlargv} = [ @argvcopy ];
250
251 # Collect version numbers
252 $config{version} = "unknown";
253 $config{version_num} = "unknown";
254 $config{shlib_version_number} = "unknown";
255 $config{shlib_version_history} = "unknown";
256
257 collect_information(
258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
259     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
260     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
261     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
262     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
263     );
264 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
265
266 ($config{major}, $config{minor})
267     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
268 ($config{shlib_major}, $config{shlib_minor})
269     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
270 die "erroneous version information in opensslv.h: ",
271     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
272     if ($config{major} eq "" || $config{minor} eq ""
273         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
274
275 # Collect target configurations
276
277 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
278 foreach (sort glob($pattern)) {
279     &read_config($_);
280 }
281
282 if (defined $ENV{$local_config_envname}) {
283     if ($^O eq 'VMS') {
284         # VMS environment variables are logical names,
285         # which can be used as is
286         $pattern = $local_config_envname . ':' . '*.conf';
287     } else {
288         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
289     }
290
291     foreach (sort glob($pattern)) {
292         &read_config($_);
293     }
294 }
295
296
297 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
298
299 $config{prefix}="";
300 $config{openssldir}="";
301 $config{processor}="";
302 $config{libdir}="";
303 $config{cross_compile_prefix}="";
304 my $auto_threads=1;    # enable threads automatically? true by default
305 my $default_ranlib;
306
307 # Top level directories to build
308 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
309 # crypto/ subdirectories to build
310 $config{sdirs} = [
311     "objects",
312     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash",
313     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "chacha", "modes",
314     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
315     "buffer", "bio", "stack", "lhash", "rand", "err",
316     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
317     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
318     ];
319 # test/ subdirectories to build
320 $config{tdirs} = [ "ossl_shim" ];
321
322 # Known TLS and DTLS protocols
323 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
324 my @dtls = qw(dtls1 dtls1_2);
325
326 # Explicitly known options that are possible to disable.  They can
327 # be regexps, and will be used like this: /^no-${option}$/
328 # For developers: keep it sorted alphabetically
329
330 my @disablables = (
331     "afalgeng",
332     "aria",
333     "asan",
334     "asm",
335     "async",
336     "autoalginit",
337     "autoerrinit",
338     "bf",
339     "blake2",
340     "camellia",
341     "capieng",
342     "cast",
343     "chacha",
344     "cmac",
345     "cms",
346     "comp",
347     "crypto-mdebug",
348     "crypto-mdebug-backtrace",
349     "ct",
350     "deprecated",
351     "des",
352     "dgram",
353     "dh",
354     "dsa",
355     "dso",
356     "dtls",
357     "dynamic-engine",
358     "ec",
359     "ec2m",
360     "ecdh",
361     "ecdsa",
362     "ec_nistp_64_gcc_128",
363     "egd",
364     "engine",
365     "err",
366     "external-tests",
367     "filenames",
368     "fuzz-libfuzzer",
369     "fuzz-afl",
370     "gost",
371     "heartbeats",
372     "hw(-.+)?",
373     "idea",
374     "makedepend",
375     "md2",
376     "md4",
377     "mdc2",
378     "msan",
379     "multiblock",
380     "nextprotoneg",
381     "ocb",
382     "ocsp",
383     "pic",
384     "poly1305",
385     "posix-io",
386     "psk",
387     "rc2",
388     "rc4",
389     "rc5",
390     "rdrand",
391     "rfc3779",
392     "rmd160",
393     "scrypt",
394     "sctp",
395     "seed",
396     "shared",
397     "siphash",
398     "sock",
399     "srp",
400     "srtp",
401     "sse2",
402     "ssl",
403     "ssl-trace",
404     "static-engine",
405     "stdio",
406     "tests",
407     "threads",
408     "tls",
409     "tls13downgrade",
410     "ts",
411     "ubsan",
412     "ui",
413     "unit-test",
414     "whirlpool",
415     "weak-ssl-ciphers",
416     "zlib",
417     "zlib-dynamic",
418     );
419 foreach my $proto ((@tls, @dtls))
420         {
421         push(@disablables, $proto);
422         push(@disablables, "$proto-method");
423         }
424
425 my %deprecated_disablables = (
426     "ssl2" => undef,
427     "buf-freelists" => undef,
428     "ripemd" => "rmd160"
429     );
430
431 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
432
433 our %disabled = ( # "what"         => "comment"
434                   "aria"                => "default",
435                   "asan"                => "default",
436                   "crypto-mdebug"       => "default",
437                   "crypto-mdebug-backtrace" => "default",
438                   "ec_nistp_64_gcc_128" => "default",
439                   "egd"                 => "default",
440                   "external-tests"      => "default",
441                   "fuzz-libfuzzer"      => "default",
442                   "fuzz-afl"            => "default",
443                   "heartbeats"          => "default",
444                   "md2"                 => "default",
445                   "msan"                => "default",
446                   "rc5"                 => "default",
447                   "sctp"                => "default",
448                   "ssl-trace"           => "default",
449                   "ssl3"                => "default",
450                   "ssl3-method"         => "default",
451                   "ubsan"               => "default",
452           #TODO(TLS1.3): Temporarily disabled while this is a WIP
453                   "tls1_3"              => "default",
454                   "tls13downgrade"      => "default",
455                   "unit-test"           => "default",
456                   "weak-ssl-ciphers"    => "default",
457                   "zlib"                => "default",
458                   "zlib-dynamic"        => "default",
459                 );
460
461 # Note: => pair form used for aesthetics, not to truly make a hash table
462 my @disable_cascades = (
463     # "what"            => [ "cascade", ... ]
464     sub { $config{processor} eq "386" }
465                         => [ "sse2" ],
466     "ssl"               => [ "ssl3" ],
467     "ssl3-method"       => [ "ssl3" ],
468     "zlib"              => [ "zlib-dynamic" ],
469     "des"               => [ "mdc2" ],
470     "ec"                => [ "ecdsa", "ecdh" ],
471
472     "dgram"             => [ "dtls", "sctp" ],
473     "sock"              => [ "dgram" ],
474     "dtls"              => [ @dtls ],
475     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
476                         => [ "dtls" ],
477
478     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
479     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
480     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
481
482     # Additionally, SSL 3.0 requires either RSA or DSA+DH
483     sub { $disabled{rsa}
484           && ($disabled{dsa} || $disabled{dh}); }
485                         => [ "ssl" ],
486
487     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
488     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
489     # (XXX: We don't support PSK-only builds).
490     sub { $disabled{rsa}
491           && ($disabled{dsa} || $disabled{dh})
492           && ($disabled{ecdsa} || $disabled{ecdh}); }
493                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
494                              "dtls1", "dtls1_2" ],
495
496     "tls"               => [ @tls ],
497     sub { 0 == scalar grep { !$disabled{$_} } @tls }
498                         => [ "tls" ],
499
500     # SRP and HEARTBEATS require TLSEXT
501     "tlsext"            => [ "srp", "heartbeats" ],
502
503     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
504
505     # Without DSO, we can't load dynamic engines, so don't build them dynamic
506     "dso"               => [ "dynamic-engine" ],
507
508     # Without position independent code, there can be no shared libraries or DSOs
509     "pic"               => [ "shared" ],
510     "shared"            => [ "dynamic-engine" ],
511     "engine"            => [ "afalgeng" ],
512
513     # no-autoalginit is only useful when building non-shared
514     "autoalginit"       => [ "shared", "apps" ],
515
516     "stdio"             => [ "apps", "capieng" ],
517     "apps"              => [ "tests" ],
518     "comp"              => [ "zlib" ],
519     "ec"                => [ "tls1_3" ],
520     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
521
522     sub { !$disabled{"msan"} } => [ "asm" ],
523     );
524
525 # Avoid protocol support holes.  Also disable all versions below N, if version
526 # N is disabled while N+1 is enabled.
527 #
528 my @list = (reverse @tls);
529 while ((my $first, my $second) = (shift @list, shift @list)) {
530     last unless @list;
531     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
532                               => [ @list ] );
533     unshift @list, $second;
534 }
535 my @list = (reverse @dtls);
536 while ((my $first, my $second) = (shift @list, shift @list)) {
537     last unless @list;
538     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
539                               => [ @list ] );
540     unshift @list, $second;
541 }
542
543 # Explicit "no-..." options will be collected in %disabled along with the defaults.
544 # To remove something from %disabled, use "enable-foo".
545 # For symmetry, "disable-foo" is a synonym for "no-foo".
546
547 my $no_sse2=0;
548
549 &usage if ($#ARGV < 0);
550
551 my $user_cflags="";
552 my @user_defines=();
553 $config{openssl_api_defines}=[];
554 $config{openssl_algorithm_defines}=[];
555 $config{openssl_thread_defines}=[];
556 $config{openssl_sys_defines}=[];
557 $config{openssl_other_defines}=[];
558 my $libs="";
559 my $target="";
560 $config{options}="";
561 $config{build_type} = "release";
562
563 my %unsupported_options = ();
564 my %deprecated_options = ();
565 while (@argvcopy)
566         {
567         $_ = shift @argvcopy;
568         # VMS is a case insensitive environment, and depending on settings
569         # out of our control, we may receive options uppercased.  Let's
570         # downcase at least the part before any equal sign.
571         if ($^O eq "VMS")
572                 {
573                 s/^([^=]*)/lc($1)/e;
574                 }
575         s /^-no-/no-/; # some people just can't read the instructions
576
577         # rewrite some options in "enable-..." form
578         s /^-?-?shared$/enable-shared/;
579         s /^sctp$/enable-sctp/;
580         s /^threads$/enable-threads/;
581         s /^zlib$/enable-zlib/;
582         s /^zlib-dynamic$/enable-zlib-dynamic/;
583
584         if (/^(no|disable|enable)-(.+)$/)
585                 {
586                 my $word = $2;
587                 if (!exists $deprecated_disablables{$word}
588                         && !grep { $word =~ /^${_}$/ } @disablables)
589                         {
590                         $unsupported_options{$_} = 1;
591                         next;
592                         }
593                 }
594         if (/^no-(.+)$/ || /^disable-(.+)$/)
595                 {
596                 foreach my $proto ((@tls, @dtls))
597                         {
598                         if ($1 eq "$proto-method")
599                                 {
600                                 $disabled{"$proto"} = "option($proto-method)";
601                                 last;
602                                 }
603                         }
604                 if ($1 eq "dtls")
605                         {
606                         foreach my $proto (@dtls)
607                                 {
608                                 $disabled{$proto} = "option(dtls)";
609                                 }
610                         $disabled{"dtls"} = "option(dtls)";
611                         }
612                 elsif ($1 eq "ssl")
613                         {
614                         # Last one of its kind
615                         $disabled{"ssl3"} = "option(ssl)";
616                         }
617                 elsif ($1 eq "tls")
618                         {
619                         # XXX: Tests will fail if all SSL/TLS
620                         # protocols are disabled.
621                         foreach my $proto (@tls)
622                                 {
623                                 $disabled{$proto} = "option(tls)";
624                                 }
625                         }
626                 elsif ($1 eq "static-engine")
627                         {
628                         delete $disabled{"dynamic-engine"};
629                         }
630                 elsif ($1 eq "dynamic-engine")
631                         {
632                         $disabled{"dynamic-engine"} = "option";
633                         }
634                 elsif (exists $deprecated_disablables{$1})
635                         {
636                         $deprecated_options{$_} = 1;
637                         if (defined $deprecated_disablables{$1})
638                                 {
639                                 $disabled{$deprecated_disablables{$1}} = "option";
640                                 }
641                         }
642                 else
643                         {
644                         $disabled{$1} = "option";
645                         }
646                 # No longer an automatic choice
647                 $auto_threads = 0 if ($1 eq "threads");
648                 }
649         elsif (/^enable-(.+)$/)
650                 {
651                 if ($1 eq "static-engine")
652                         {
653                         $disabled{"dynamic-engine"} = "option";
654                         }
655                 elsif ($1 eq "dynamic-engine")
656                         {
657                         delete $disabled{"dynamic-engine"};
658                         }
659                 elsif ($1 eq "zlib-dynamic")
660                         {
661                         delete $disabled{"zlib"};
662                         }
663                 my $algo = $1;
664                 delete $disabled{$algo};
665
666                 # No longer an automatic choice
667                 $auto_threads = 0 if ($1 eq "threads");
668                 }
669         elsif (/^--strict-warnings$/)
670                 {
671                 $strict_warnings = 1;
672                 }
673         elsif (/^--debug$/)
674                 {
675                 $config{build_type} = "debug";
676                 }
677         elsif (/^--release$/)
678                 {
679                 $config{build_type} = "release";
680                 }
681         elsif (/^386$/)
682                 { $config{processor}=386; }
683         elsif (/^fips$/)
684                 {
685                 die "FIPS mode not supported\n";
686                 }
687         elsif (/^rsaref$/)
688                 {
689                 # No RSAref support any more since it's not needed.
690                 # The check for the option is there so scripts aren't
691                 # broken
692                 }
693         elsif (/^nofipscanistercheck$/)
694                 {
695                 die "FIPS mode not supported\n";
696                 }
697         elsif (/^[-+]/)
698                 {
699                 if (/^--prefix=(.*)$/)
700                         {
701                         $config{prefix}=$1;
702                         die "Directory given with --prefix MUST be absolute\n"
703                                 unless file_name_is_absolute($config{prefix});
704                         }
705                 elsif (/^--api=(.*)$/)
706                         {
707                         $config{api}=$1;
708                         }
709                 elsif (/^--libdir=(.*)$/)
710                         {
711                         $config{libdir}=$1;
712                         }
713                 elsif (/^--openssldir=(.*)$/)
714                         {
715                         $config{openssldir}=$1;
716                         }
717                 elsif (/^--with-zlib-lib=(.*)$/)
718                         {
719                         $withargs{zlib_lib}=$1;
720                         }
721                 elsif (/^--with-zlib-include=(.*)$/)
722                         {
723                         $withargs{zlib_include}=$1;
724                         }
725                 elsif (/^--with-fuzzer-lib=(.*)$/)
726                         {
727                         $withargs{fuzzer_lib}=$1;
728                         }
729                 elsif (/^--with-fuzzer-include=(.*)$/)
730                         {
731                         $withargs{fuzzer_include}=$1;
732                         }
733                 elsif (/^--cross-compile-prefix=(.*)$/)
734                         {
735                         $config{cross_compile_prefix}=$1;
736                         }
737                 elsif (/^--config=(.*)$/)
738                         {
739                         read_config $1;
740                         }
741                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
742                         {
743                         $libs.=$_." ";
744                         }
745                 elsif (/^-framework$/)
746                         {
747                         $libs.=$_." ".shift(@argvcopy)." ";
748                         }
749                 elsif (/^-rpath$/ or /^-R$/)
750                         # -rpath is the OSF1 rpath flag
751                         # -R is the old Solaris rpath flag
752                         {
753                         my $rpath = shift(@argvcopy) || "";
754                         $rpath .= " " if $rpath ne "";
755                         $libs.=$_." ".$rpath;
756                         }
757                 elsif (/^-static$/)
758                         {
759                         $libs.=$_." ";
760                         $disabled{"dso"} = "forced";
761                         $disabled{"pic"} = "forced";
762                         $disabled{"shared"} = "forced";
763                         $disabled{"threads"} = "forced";
764                         }
765                 elsif (/^-D(.*)$/)
766                         {
767                         push @user_defines, $1;
768                         }
769                 else    # common if (/^[-+]/), just pass down...
770                         {
771                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
772                         $user_cflags.=" ".$_;
773                         }
774                 }
775         else
776                 {
777                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
778                 $target=$_;
779                 }
780         unless ($_ eq $target || /^no-/ || /^disable-/)
781                 {
782                 # "no-..." follows later after implied disactivations
783                 # have been derived.  (Don't take this too seriously,
784                 # we really only write OPTIONS to the Makefile out of
785                 # nostalgia.)
786
787                 if ($config{options} eq "")
788                         { $config{options} = $_; }
789                 else
790                         { $config{options} .= " ".$_; }
791                 }
792
793         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
794                 die "***** Unsupported api compatibility level: $config{api}\n",
795         }
796
797         if (keys %deprecated_options)
798                 {
799                 warn "***** Deprecated options: ",
800                         join(", ", keys %deprecated_options), "\n";
801                 }
802         if (keys %unsupported_options)
803                 {
804                 die "***** Unsupported options: ",
805                         join(", ", keys %unsupported_options), "\n";
806                 }
807         }
808
809 if ($libs =~ /(^|\s)-Wl,-rpath,/
810     && !$disabled{shared}
811     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
812     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
813         "***** any of asan, msan or ubsan\n";
814 }
815
816 my @tocheckfor = (keys %disabled);
817 while (@tocheckfor) {
818     my %new_tocheckfor = ();
819     my @cascade_copy = (@disable_cascades);
820     while (@cascade_copy) {
821         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
822         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
823             foreach(grep { !defined($disabled{$_}) } @$descendents) {
824                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
825             }
826         }
827     }
828     @tocheckfor = (keys %new_tocheckfor);
829 }
830
831 our $die = sub { die @_; };
832 if ($target eq "TABLE") {
833     local $die = sub { warn @_; };
834     foreach (sort keys %table) {
835         print_table_entry($_, "TABLE");
836     }
837     exit 0;
838 }
839
840 if ($target eq "LIST") {
841     foreach (sort keys %table) {
842         print $_,"\n" unless $table{$_}->{template};
843     }
844     exit 0;
845 }
846
847 if ($target eq "HASH") {
848     local $die = sub { warn @_; };
849     print "%table = (\n";
850     foreach (sort keys %table) {
851         print_table_entry($_, "HASH");
852     }
853     exit 0;
854 }
855
856 # Backward compatibility?
857 if ($target =~ m/^CygWin32(-.*)$/) {
858     $target = "Cygwin".$1;
859 }
860
861 foreach (sort (keys %disabled))
862         {
863         $config{options} .= " no-$_";
864
865         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
866
867         if (/^dso$/)
868                 { }
869         elsif (/^threads$/)
870                 { }
871         elsif (/^shared$/)
872                 { }
873         elsif (/^pic$/)
874                 { }
875         elsif (/^zlib$/)
876                 { }
877         elsif (/^dynamic-engine$/)
878                 { }
879         elsif (/^makedepend$/)
880                 { }
881         elsif (/^zlib-dynamic$/)
882                 { }
883         elsif (/^sse2$/)
884                 { $no_sse2 = 1; }
885         elsif (/^engine$/)
886                 {
887                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
888                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
889                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
890                 print " OPENSSL_NO_ENGINE (skip engines)";
891                 }
892         else
893                 {
894                 my ($WHAT, $what);
895
896                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
897
898                 # Fix up C macro end names
899                 $WHAT = "RMD160" if $what eq "ripemd";
900
901                 # fix-up crypto/directory name(s)
902                 $what = "ripemd" if $what eq "rmd160";
903                 $what = "whrlpool" if $what eq "whirlpool";
904
905                 if ($what ne "async" && $what ne "err"
906                     && grep { $_ eq $what } @{$config{sdirs}})
907                         {
908                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
909                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
910
911                         print " OPENSSL_NO_$WHAT (skip dir)";
912                         }
913                 else
914                         {
915                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
916                         print " OPENSSL_NO_$WHAT";
917
918                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
919                         }
920                 }
921
922         print "\n";
923         }
924
925 print "Configuring for $target\n";
926 # Support for legacy targets having a name starting with 'debug-'
927 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
928 if ($d) {
929     $config{build_type} = "debug";
930
931     # If we do not find debug-foo in the table, the target is set to foo.
932     if (!$table{$target}) {
933         $target = $t;
934     }
935 }
936 $config{target} = $target;
937 my %target = resolve_config($target);
938
939 &usage if (!%target || $target{template});
940
941 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
942 $config{conf_files} = [ sort keys %conf_files ];
943 %target = ( %{$table{DEFAULTS}}, %target );
944
945 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
946 $target{exe_extension}="";
947 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
948                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
949 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
950
951 ($target{shared_extension_simple}=$target{shared_extension})
952     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
953 $target{dso_extension}=$target{shared_extension_simple};
954 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
955     if ($config{target} =~ /^(?:Cygwin|mingw)/);
956
957
958 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
959     if $config{cross_compile_prefix} eq "";
960
961 # Allow overriding the names of some tools.  USE WITH CARE
962 # Note: only Unix cares about HASHBANGPERL...  that explains
963 # the default string.
964 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
965 $config{hashbangperl} =
966     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
967 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
968 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
969 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
970                    (which("$config{cross_compile_prefix}ranlib") ?
971                           "\$(CROSS_COMPILE)ranlib" : "true");
972 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
973 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
974 $target{rc} =
975     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
976
977 # Allow overriding the build file name
978 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
979
980 # Cache information necessary for reconfiguration
981 $config{cc} = $target{cc};
982 $config{cxx} = $target{cxx};
983 $config{build_file} = $target{build_file};
984
985 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
986 # or release_ attributes.
987 # Do it in such a way that no spurious space is appended (hence the grep).
988 $config{defines} = [];
989 $config{cflags} = "";
990 $config{cxxflags} = "";
991 $config{ex_libs} = "";
992 $config{shared_ldflag} = "";
993
994 # Make sure build_scheme is consistent.
995 $target{build_scheme} = [ $target{build_scheme} ]
996     if ref($target{build_scheme}) ne "ARRAY";
997
998 my ($builder, $builder_platform, @builder_opts) =
999     @{$target{build_scheme}};
1000
1001 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1002                       $builder_platform."-checker.pm")) {
1003     my $checker_path = catfile($srcdir, "Configurations", $checker);
1004     if (-f $checker_path) {
1005         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1006             ? sub { warn $@; } : sub { die $@; };
1007         if (! do $checker_path) {
1008             if ($@) {
1009                 $fn->($@);
1010             } elsif ($!) {
1011                 $fn->($!);
1012             } else {
1013                 $fn->("The detected tools didn't match the platform\n");
1014             }
1015         }
1016         last;
1017     }
1018 }
1019
1020 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1021
1022 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1023         {
1024         $config{cflags} .= " -mno-cygwin";
1025         $config{shared_ldflag} .= " -mno-cygwin";
1026         }
1027
1028 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1029         # minimally required architecture flags for assembly modules
1030         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1031         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1032 }
1033
1034 my $no_shared_warn=0;
1035 my $no_user_cflags=0;
1036 my $no_user_defines=0;
1037
1038 # The DSO code currently always implements all functions so that no
1039 # applications will have to worry about that from a compilation point
1040 # of view. However, the "method"s may return zero unless that platform
1041 # has support compiled in for them. Currently each method is enabled
1042 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1043 # string entry into using the following logic;
1044 if (!$disabled{dso} && $target{dso_scheme} ne "")
1045         {
1046         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1047         if ($target{dso_scheme} eq "DLFCN")
1048                 {
1049                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1050                 }
1051         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1052                 {
1053                 unshift @{$config{defines}}, "DSO_DLFCN";
1054                 }
1055         else
1056                 {
1057                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1058                 }
1059         }
1060
1061 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1062
1063 # If threads aren't disabled, check how possible they are
1064 unless ($disabled{threads}) {
1065     if ($auto_threads) {
1066         # Enabled by default, disable it forcibly if unavailable
1067         if ($target{thread_scheme} eq "(unknown)") {
1068             $disabled{threads} = "unavailable";
1069         }
1070     } else {
1071         # The user chose to enable threads explicitly, let's see
1072         # if there's a chance that's possible
1073         if ($target{thread_scheme} eq "(unknown)") {
1074             # If the user asked for "threads" and we don't have internal
1075             # knowledge how to do it, [s]he is expected to provide any
1076             # system-dependent compiler options that are necessary.  We
1077             # can't truly check that the given options are correct, but
1078             # we expect the user to know what [s]He is doing.
1079             if ($no_user_cflags && $no_user_defines) {
1080                 die "You asked for multi-threading support, but didn't\n"
1081                     ,"provide any system-specific compiler options\n";
1082             }
1083         }
1084     }
1085 }
1086
1087 # If threads still aren't disabled, add a C macro to ensure the source
1088 # code knows about it.  Any other flag is taken care of by the configs.
1089 unless($disabled{threads}) {
1090     foreach (("defines", "openssl_thread_defines")) {
1091         push @{$config{$_}}, "OPENSSL_THREADS";
1092     }
1093 }
1094
1095 # With "deprecated" disable all deprecated features.
1096 if (defined($disabled{"deprecated"})) {
1097         $config{api} = $maxapi;
1098 }
1099
1100 if ($target{shared_target} eq "")
1101         {
1102         $no_shared_warn = 1
1103             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1104         $disabled{shared} = "no-shared-target";
1105         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1106             "no-shared-target";
1107         }
1108
1109 if ($disabled{"dynamic-engine"}) {
1110         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1111         $config{dynamic_engines} = 0;
1112 } else {
1113         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1114         $config{dynamic_engines} = 1;
1115 }
1116
1117 unless ($disabled{asan}) {
1118     $config{cflags} .= "-fsanitize=address ";
1119 }
1120
1121 unless ($disabled{ubsan}) {
1122     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1123     # platforms.
1124     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1125 }
1126
1127 unless ($disabled{msan}) {
1128   $config{cflags} .= "-fsanitize=memory ";
1129 }
1130
1131 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1132         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1133     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1134 }
1135 #
1136 # Platform fix-ups
1137 #
1138
1139 # This saves the build files from having to check
1140 if ($disabled{pic})
1141         {
1142         $target{shared_cflag} = $target{shared_ldflag} =
1143                 $target{shared_rcflag} = "";
1144         }
1145 else
1146         {
1147         push @{$config{defines}}, "OPENSSL_PIC";
1148         }
1149
1150 if ($target{sys_id} ne "")
1151         {
1152         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1153         }
1154
1155 unless ($disabled{asm}) {
1156     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1157     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1158
1159     # bn-586 is the only one implementing bn_*_part_words
1160     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1161     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1162
1163     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1164     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1165     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1166
1167     if ($target{sha1_asm_src}) {
1168         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1169         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1170         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1171     }
1172     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1173         push @{$config{defines}}, "RC4_ASM";
1174     }
1175     if ($target{md5_asm_src}) {
1176         push @{$config{defines}}, "MD5_ASM";
1177     }
1178     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1179     if ($target{rmd160_asm_src}) {
1180         push @{$config{defines}}, "RMD160_ASM";
1181     }
1182     if ($target{aes_asm_src}) {
1183         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1184         # aes-ctr.fake is not a real file, only indication that assembler
1185         # module implements AES_ctr32_encrypt...
1186         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1187         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1188         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1189         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1190         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1191         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1192     }
1193     if ($target{wp_asm_src} =~ /mmx/) {
1194         if ($config{processor} eq "386") {
1195             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1196         } elsif (!$disabled{"whirlpool"}) {
1197             push @{$config{defines}}, "WHIRLPOOL_ASM";
1198         }
1199     }
1200     if ($target{modes_asm_src} =~ /ghash-/) {
1201         push @{$config{defines}}, "GHASH_ASM";
1202     }
1203     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1204         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1205     }
1206     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1207         push @{$config{defines}}, "PADLOCK_ASM";
1208     }
1209     if ($target{poly1305_asm_src} ne "") {
1210         push @{$config{defines}}, "POLY1305_ASM";
1211     }
1212 }
1213
1214 my $ecc = $target{cc};
1215 if ($^O ne "VMS" && !$disabled{makedepend}) {
1216     # Is the compiler gcc or clang?  $ecc is used below to see if
1217     # error-checking can be turned on.
1218     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1219     open(PIPE, "$ccpcc --version 2>&1 |");
1220     my $lines = 2;
1221     while ( <PIPE> ) {
1222         # Find the version number and save the major.
1223         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1224         my $compiler_major = $1;
1225         # We know that GNU C version 3 and up as well as all clang
1226         # versions support dependency generation
1227         $config{makedepprog} = $ccpcc
1228             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1229         $ecc = "clang" if /clang/;
1230         $ecc = "gcc" if /gcc/;
1231         last if ($config{makedepprog} || !$lines--);
1232     }
1233     close(PIPE);
1234
1235     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1236     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1237 }
1238
1239
1240
1241 # Deal with bn_ops ###################################################
1242
1243 $config{bn_ll}                  =0;
1244 $config{export_var_as_fn}       =0;
1245 my $def_int="unsigned int";
1246 $config{rc4_int}                =$def_int;
1247 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1248
1249 my $count = 0;
1250 foreach (sort split(/\s+/,$target{bn_ops})) {
1251     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1252     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1253     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1254     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1255     ($config{b64l},$config{b64},$config{b32})
1256         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1257     ($config{b64l},$config{b64},$config{b32})
1258         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1259     ($config{b64l},$config{b64},$config{b32})
1260         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1261 }
1262 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1263     if $count > 1;
1264
1265
1266 # Hack cflags for better warnings (dev option) #######################
1267
1268 # "Stringify" the C flags string.  This permits it to be made part of a string
1269 # and works as well on command lines.
1270 $config{cflags} =~ s/([\\\"])/\\$1/g;
1271
1272 if (defined($config{api})) {
1273     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1274     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1275     push @{$config{defines}}, $apiflag;
1276 }
1277
1278 if ($strict_warnings)
1279         {
1280         my $wopt;
1281         die "ERROR --strict-warnings requires gcc or clang"
1282             unless $ecc eq 'gcc' || $ecc eq 'clang';
1283         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1284                 {
1285                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1286                 }
1287         if ($ecc eq "clang")
1288                 {
1289                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1290                         {
1291                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1292                         }
1293                 }
1294         }
1295
1296 unless ($disabled{"crypto-mdebug-backtrace"})
1297         {
1298         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1299                 {
1300                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1301                 }
1302         if ($target =~ /^BSD-/)
1303                 {
1304                 $config{ex_libs} .= " -lexecinfo";
1305                 }
1306         }
1307
1308 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1309 else                    { $no_user_cflags=1;  }
1310 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1311 else               { $no_user_defines=1;    }
1312
1313 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1314
1315 unless ($disabled{afalgeng}) {
1316     $config{afalgeng}="";
1317     if ($target =~ m/^linux/) {
1318         my $minver = 4*10000 + 1*100 + 0;
1319         if ($config{cross_compile_prefix} eq "") {
1320             my $verstr = `uname -r`;
1321             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1322             ($mi2) = $mi2 =~ /(\d+)/;
1323             my $ver = $ma*10000 + $mi1*100 + $mi2;
1324             if ($ver < $minver) {
1325                 $disabled{afalgeng} = "too-old-kernel";
1326             } else {
1327                 push @{$config{engdirs}}, "afalg";
1328             }
1329         } else {
1330             $disabled{afalgeng} = "cross-compiling";
1331         }
1332     } else {
1333         $disabled{afalgeng}  = "not-linux";
1334     }
1335 }
1336
1337 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1338
1339 # If we use the unified build, collect information from build.info files
1340 my %unified_info = ();
1341
1342 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1343 if ($builder eq "unified") {
1344     use lib catdir(dirname(__FILE__),"util");
1345     use with_fallback qw(Text::Template);
1346
1347     sub cleandir {
1348         my $base = shift;
1349         my $dir = shift;
1350         my $relativeto = shift || ".";
1351
1352         $dir = catdir($base,$dir) unless isabsolute($dir);
1353
1354         # Make sure the directories we're building in exists
1355         mkpath($dir);
1356
1357         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1358         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1359         return $res;
1360     }
1361
1362     sub cleanfile {
1363         my $base = shift;
1364         my $file = shift;
1365         my $relativeto = shift || ".";
1366
1367         $file = catfile($base,$file) unless isabsolute($file);
1368
1369         my $d = dirname($file);
1370         my $f = basename($file);
1371
1372         # Make sure the directories we're building in exists
1373         mkpath($d);
1374
1375         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1376         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1377         return $res;
1378     }
1379
1380     # Store the name of the template file we will build the build file from
1381     # in %config.  This may be useful for the build file itself.
1382     my @build_file_template_names =
1383         ( $builder_platform."-".$target{build_file}.".tmpl",
1384           $target{build_file}.".tmpl" );
1385     my @build_file_templates = ();
1386
1387     # First, look in the user provided directory, if given
1388     if (defined $ENV{$local_config_envname}) {
1389         @build_file_templates =
1390             map {
1391                 if ($^O eq 'VMS') {
1392                     # VMS environment variables are logical names,
1393                     # which can be used as is
1394                     $local_config_envname . ':' . $_;
1395                 } else {
1396                     catfile($ENV{$local_config_envname}, $_);
1397                 }
1398             }
1399             @build_file_template_names;
1400     }
1401     # Then, look in our standard directory
1402     push @build_file_templates,
1403         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1404           @build_file_template_names );
1405
1406     my $build_file_template;
1407     for $_ (@build_file_templates) {
1408         $build_file_template = $_;
1409         last if -f $build_file_template;
1410
1411         $build_file_template = undef;
1412     }
1413     if (!defined $build_file_template) {
1414         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1415     }
1416     $config{build_file_templates}
1417       = [ $build_file_template,
1418           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1419                     $blddir) ];
1420
1421     my @build_infos = ( [ ".", "build.info" ] );
1422     foreach (@{$config{dirs}}) {
1423         push @build_infos, [ $_, "build.info" ]
1424             if (-f catfile($srcdir, $_, "build.info"));
1425     }
1426     foreach (@{$config{sdirs}}) {
1427         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1428             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1429     }
1430     foreach (@{$config{engdirs}}) {
1431         push @build_infos, [ catdir("engines", $_), "build.info" ]
1432             if (-f catfile($srcdir, "engines", $_, "build.info"));
1433     }
1434     foreach (@{$config{tdirs}}) {
1435         push @build_infos, [ catdir("test", $_), "build.info" ]
1436             if (-f catfile($srcdir, "test", $_, "build.info"));
1437     }
1438
1439     $config{build_infos} = [ ];
1440
1441     foreach (@build_infos) {
1442         my $sourced = catdir($srcdir, $_->[0]);
1443         my $buildd = catdir($blddir, $_->[0]);
1444
1445         mkpath($buildd);
1446
1447         my $f = $_->[1];
1448         # The basic things we're trying to build
1449         my @programs = ();
1450         my @programs_install = ();
1451         my @libraries = ();
1452         my @libraries_install = ();
1453         my @engines = ();
1454         my @engines_install = ();
1455         my @scripts = ();
1456         my @scripts_install = ();
1457         my @extra = ();
1458         my @overrides = ();
1459         my @intermediates = ();
1460         my @rawlines = ();
1461
1462         my %ordinals = ();
1463         my %sources = ();
1464         my %shared_sources = ();
1465         my %includes = ();
1466         my %depends = ();
1467         my %renames = ();
1468         my %sharednames = ();
1469         my %generate = ();
1470
1471         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1472         my $template = Text::Template->new(TYPE => 'FILE',
1473                                            SOURCE => catfile($sourced, $f));
1474         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1475         my @text =
1476             split /^/m,
1477             $template->fill_in(HASH => { config => \%config,
1478                                          target => \%target,
1479                                          disabled => \%disabled,
1480                                          withargs => \%withargs,
1481                                          builddir => abs2rel($buildd, $blddir),
1482                                          sourcedir => abs2rel($sourced, $blddir),
1483                                          buildtop => abs2rel($blddir, $blddir),
1484                                          sourcetop => abs2rel($srcdir, $blddir) },
1485                                DELIMITERS => [ "{-", "-}" ]);
1486
1487         # The top item of this stack has the following values
1488         # -2 positive already run and we found ELSE (following ELSIF should fail)
1489         # -1 positive already run (skip until ENDIF)
1490         # 0 negatives so far (if we're at a condition, check it)
1491         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1492         # 2 positive ELSE (following ELSIF should fail)
1493         my @skip = ();
1494         collect_information(
1495             collect_from_array([ @text ],
1496                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1497                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1498             # Info we're looking for
1499             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1500             => sub {
1501                 if (! @skip || $skip[$#skip] > 0) {
1502                     push @skip, !! $1;
1503                 } else {
1504                     push @skip, -1;
1505                 }
1506             },
1507             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1508             => sub { die "ELSIF out of scope" if ! @skip;
1509                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1510                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1511                      $skip[$#skip] = !! $1
1512                          if $skip[$#skip] == 0; },
1513             qr/^\s*ELSE\s*$/
1514             => sub { die "ELSE out of scope" if ! @skip;
1515                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1516                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1517             qr/^\s*ENDIF\s*$/
1518             => sub { die "ENDIF out of scope" if ! @skip;
1519                      pop @skip; },
1520             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1521             => sub {
1522                 if (!@skip || $skip[$#skip] > 0) {
1523                     my $install = $1;
1524                     my @x = tokenize($2);
1525                     push @programs, @x;
1526                     push @programs_install, @x unless $install;
1527                 }
1528             },
1529             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1530             => sub {
1531                 if (!@skip || $skip[$#skip] > 0) {
1532                     my $install = $1;
1533                     my @x = tokenize($2);
1534                     push @libraries, @x;
1535                     push @libraries_install, @x unless $install;
1536                 }
1537             },
1538             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1539             => sub {
1540                 if (!@skip || $skip[$#skip] > 0) {
1541                     my $install = $1;
1542                     my @x = tokenize($2);
1543                     push @engines, @x;
1544                     push @engines_install, @x unless $install;
1545                 }
1546             },
1547             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1548             => sub {
1549                 if (!@skip || $skip[$#skip] > 0) {
1550                     my $install = $1;
1551                     my @x = tokenize($2);
1552                     push @scripts, @x;
1553                     push @scripts_install, @x unless $install;
1554                 }
1555             },
1556             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1557             => sub { push @extra, tokenize($1)
1558                          if !@skip || $skip[$#skip] > 0 },
1559             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1560             => sub { push @overrides, tokenize($1)
1561                          if !@skip || $skip[$#skip] > 0 },
1562
1563             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1564             => sub { push @{$ordinals{$1}}, tokenize($2)
1565                          if !@skip || $skip[$#skip] > 0 },
1566             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1567             => sub { push @{$sources{$1}}, tokenize($2)
1568                          if !@skip || $skip[$#skip] > 0 },
1569             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1570             => sub { push @{$shared_sources{$1}}, tokenize($2)
1571                          if !@skip || $skip[$#skip] > 0 },
1572             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1573             => sub { push @{$includes{$1}}, tokenize($2)
1574                          if !@skip || $skip[$#skip] > 0 },
1575             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1576             => sub { push @{$depends{$1}}, tokenize($2)
1577                          if !@skip || $skip[$#skip] > 0 },
1578             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1579             => sub { push @{$generate{$1}}, $2
1580                          if !@skip || $skip[$#skip] > 0 },
1581             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1582             => sub { push @{$renames{$1}}, tokenize($2)
1583                          if !@skip || $skip[$#skip] > 0 },
1584             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1585             => sub { push @{$sharednames{$1}}, tokenize($2)
1586                          if !@skip || $skip[$#skip] > 0 },
1587             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1588             => sub {
1589                 my $lineiterator = shift;
1590                 my $target_kind = $1;
1591                 while (defined $lineiterator->()) {
1592                     s|\R$||;
1593                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1594                         die "ENDRAW doesn't match BEGINRAW"
1595                             if $1 ne $target_kind;
1596                         last;
1597                     }
1598                     next if @skip && $skip[$#skip] <= 0;
1599                     push @rawlines,  $_
1600                         if ($target_kind eq $target{build_file}
1601                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1602                 }
1603             },
1604             qr/^\s*(?:#.*)?$/ => sub { },
1605             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1606             "BEFORE" => sub {
1607                 if ($buildinfo_debug) {
1608                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1609                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1610                 }
1611             },
1612             "AFTER" => sub {
1613                 if ($buildinfo_debug) {
1614                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1615                 }
1616             },
1617             );
1618         die "runaway IF?" if (@skip);
1619
1620         foreach (keys %renames) {
1621             die "$_ renamed to more than one thing: "
1622                 ,join(" ", @{$renames{$_}}),"\n"
1623                 if scalar @{$renames{$_}} > 1;
1624             my $dest = cleanfile($buildd, $_, $blddir);
1625             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1626             die "$dest renamed to more than one thing: "
1627                 ,$unified_info{rename}->{$dest}, $to
1628                 unless !defined($unified_info{rename}->{$dest})
1629                 or $unified_info{rename}->{$dest} eq $to;
1630             $unified_info{rename}->{$dest} = $to;
1631         }
1632
1633         foreach (@programs) {
1634             my $program = cleanfile($buildd, $_, $blddir);
1635             if ($unified_info{rename}->{$program}) {
1636                 $program = $unified_info{rename}->{$program};
1637             }
1638             $unified_info{programs}->{$program} = 1;
1639         }
1640
1641         foreach (@programs_install) {
1642             my $program = cleanfile($buildd, $_, $blddir);
1643             if ($unified_info{rename}->{$program}) {
1644                 $program = $unified_info{rename}->{$program};
1645             }
1646             $unified_info{install}->{programs}->{$program} = 1;
1647         }
1648
1649         foreach (@libraries) {
1650             my $library = cleanfile($buildd, $_, $blddir);
1651             if ($unified_info{rename}->{$library}) {
1652                 $library = $unified_info{rename}->{$library};
1653             }
1654             $unified_info{libraries}->{$library} = 1;
1655         }
1656
1657         foreach (@libraries_install) {
1658             my $library = cleanfile($buildd, $_, $blddir);
1659             if ($unified_info{rename}->{$library}) {
1660                 $library = $unified_info{rename}->{$library};
1661             }
1662             $unified_info{install}->{libraries}->{$library} = 1;
1663         }
1664
1665         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1666 ENGINES can only be used if configured with 'dynamic-engine'.
1667 This is usually a fault in a build.info file.
1668 EOF
1669         foreach (@engines) {
1670             my $library = cleanfile($buildd, $_, $blddir);
1671             if ($unified_info{rename}->{$library}) {
1672                 $library = $unified_info{rename}->{$library};
1673             }
1674             $unified_info{engines}->{$library} = 1;
1675         }
1676
1677         foreach (@engines_install) {
1678             my $library = cleanfile($buildd, $_, $blddir);
1679             if ($unified_info{rename}->{$library}) {
1680                 $library = $unified_info{rename}->{$library};
1681             }
1682             $unified_info{install}->{engines}->{$library} = 1;
1683         }
1684
1685         foreach (@scripts) {
1686             my $script = cleanfile($buildd, $_, $blddir);
1687             if ($unified_info{rename}->{$script}) {
1688                 $script = $unified_info{rename}->{$script};
1689             }
1690             $unified_info{scripts}->{$script} = 1;
1691         }
1692
1693         foreach (@scripts_install) {
1694             my $script = cleanfile($buildd, $_, $blddir);
1695             if ($unified_info{rename}->{$script}) {
1696                 $script = $unified_info{rename}->{$script};
1697             }
1698             $unified_info{install}->{scripts}->{$script} = 1;
1699         }
1700
1701         foreach (@extra) {
1702             my $extra = cleanfile($buildd, $_, $blddir);
1703             $unified_info{extra}->{$extra} = 1;
1704         }
1705
1706         foreach (@overrides) {
1707             my $override = cleanfile($buildd, $_, $blddir);
1708             $unified_info{overrides}->{$override} = 1;
1709         }
1710
1711         push @{$unified_info{rawlines}}, @rawlines;
1712
1713         unless ($disabled{shared}) {
1714             # Check sharednames.
1715             foreach (keys %sharednames) {
1716                 my $dest = cleanfile($buildd, $_, $blddir);
1717                 if ($unified_info{rename}->{$dest}) {
1718                     $dest = $unified_info{rename}->{$dest};
1719                 }
1720                 die "shared_name for $dest with multiple values: "
1721                     ,join(" ", @{$sharednames{$_}}),"\n"
1722                     if scalar @{$sharednames{$_}} > 1;
1723                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1724                 die "shared_name found for a library $dest that isn't defined\n"
1725                     unless $unified_info{libraries}->{$dest};
1726                 die "shared_name for $dest with multiple values: "
1727                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1728                     unless !defined($unified_info{sharednames}->{$dest})
1729                     or $unified_info{sharednames}->{$dest} eq $to;
1730                 $unified_info{sharednames}->{$dest} = $to;
1731             }
1732
1733             # Additionally, we set up sharednames for libraries that don't
1734             # have any, as themselves.  Only for libraries that aren't
1735             # explicitely static.
1736             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1737                 if (!defined $unified_info{sharednames}->{$_}) {
1738                     $unified_info{sharednames}->{$_} = $_
1739                 }
1740             }
1741
1742             # Check that we haven't defined any library as both shared and
1743             # explicitely static.  That is forbidden.
1744             my @doubles = ();
1745             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1746                 (my $l = $_) =~ s/\.a$//;
1747                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1748             }
1749             die "these libraries are both explicitely static and shared:\n  ",
1750                 join(" ", @doubles), "\n"
1751                 if @doubles;
1752         }
1753
1754         foreach (keys %ordinals) {
1755             my $dest = $_;
1756             my $ddest = cleanfile($buildd, $_, $blddir);
1757             if ($unified_info{rename}->{$ddest}) {
1758                 $ddest = $unified_info{rename}->{$ddest};
1759             }
1760             foreach (@{$ordinals{$dest}}) {
1761                 my %known_ordinals =
1762                     (
1763                      crypto =>
1764                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1765                      ssl =>
1766                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1767                     );
1768                 my $o = $known_ordinals{$_};
1769                 die "Ordinals for $ddest defined more than once\n"
1770                     if $unified_info{ordinals}->{$ddest};
1771                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1772             }
1773         }
1774
1775         foreach (keys %sources) {
1776             my $dest = $_;
1777             my $ddest = cleanfile($buildd, $_, $blddir);
1778             if ($unified_info{rename}->{$ddest}) {
1779                 $ddest = $unified_info{rename}->{$ddest};
1780             }
1781             foreach (@{$sources{$dest}}) {
1782                 my $s = cleanfile($sourced, $_, $blddir);
1783
1784                 # If it isn't in the source tree, we assume it's generated
1785                 # in the build tree
1786                 if (! -f $s) {
1787                     $s = cleanfile($buildd, $_, $blddir);
1788                 }
1789                 # We recognise C++, C and asm files
1790                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1791                     my $o = $_;
1792                     $o =~ s/\.[csS]$/.o/; # C and assembler
1793                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1794                     $o = cleanfile($buildd, $o, $blddir);
1795                     $unified_info{sources}->{$ddest}->{$o} = 1;
1796                     $unified_info{sources}->{$o}->{$s} = 1;
1797                 } else {
1798                     $unified_info{sources}->{$ddest}->{$s} = 1;
1799                 }
1800             }
1801         }
1802
1803         foreach (keys %shared_sources) {
1804             my $dest = $_;
1805             my $ddest = cleanfile($buildd, $_, $blddir);
1806             if ($unified_info{rename}->{$ddest}) {
1807                 $ddest = $unified_info{rename}->{$ddest};
1808             }
1809             foreach (@{$shared_sources{$dest}}) {
1810                 my $s = cleanfile($sourced, $_, $blddir);
1811
1812                 # If it isn't in the source tree, we assume it's generated
1813                 # in the build tree
1814                 if (! -f $s) {
1815                     $s = cleanfile($buildd, $_, $blddir);
1816                 }
1817                 # We recognise C++, C and asm files
1818                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1819                     my $o = $_;
1820                     $o =~ s/\.[csS]$/.o/; # C and assembler
1821                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1822                     $o = cleanfile($buildd, $o, $blddir);
1823                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1824                     $unified_info{sources}->{$o}->{$s} = 1;
1825                 } else {
1826                     die "unrecognised source file type for shared library: $s\n";
1827                 }
1828             }
1829         }
1830
1831         foreach (keys %generate) {
1832             my $dest = $_;
1833             my $ddest = cleanfile($buildd, $_, $blddir);
1834             if ($unified_info{rename}->{$ddest}) {
1835                 $ddest = $unified_info{rename}->{$ddest};
1836             }
1837             die "more than one generator for $dest: "
1838                     ,join(" ", @{$generate{$_}}),"\n"
1839                     if scalar @{$generate{$_}} > 1;
1840             my @generator = split /\s+/, $generate{$dest}->[0];
1841             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1842             $unified_info{generate}->{$ddest} = [ @generator ];
1843         }
1844
1845         foreach (keys %depends) {
1846             my $dest = $_;
1847             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1848
1849             # If the destination doesn't exist in source, it can only be
1850             # a generated file in the build tree.
1851             if ($ddest ne "" && ! -f $ddest) {
1852                 $ddest = cleanfile($buildd, $_, $blddir);
1853                 if ($unified_info{rename}->{$ddest}) {
1854                     $ddest = $unified_info{rename}->{$ddest};
1855                 }
1856             }
1857             foreach (@{$depends{$dest}}) {
1858                 my $d = cleanfile($sourced, $_, $blddir);
1859
1860                 # If we know it's generated, or assume it is because we can't
1861                 # find it in the source tree, we set file we depend on to be
1862                 # in the build tree rather than the source tree, and assume
1863                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1864                 # section or in the Makefile template.
1865                 if (! -f $d
1866                     || (grep { $d eq $_ }
1867                         map { cleanfile($srcdir, $_, $blddir) }
1868                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1869                     $d = cleanfile($buildd, $_, $blddir);
1870                 }
1871                 # Take note if the file to depend on is being renamed
1872                 # Take extra care with files ending with .a, they should
1873                 # be treated without that extension, and the extension
1874                 # should be added back after treatment.
1875                 $d =~ /(\.a)?$/;
1876                 my $e = $1 // "";
1877                 $d = $`;
1878                 if ($unified_info{rename}->{$d}) {
1879                     $d = $unified_info{rename}->{$d};
1880                 }
1881                 $d .= $e;
1882                 $unified_info{depends}->{$ddest}->{$d} = 1;
1883                 # If we depend on a header file or a perl module, let's make
1884                 # sure it can get included
1885                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1886                     my $i = dirname($d);
1887                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1888                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1889                 }
1890             }
1891         }
1892
1893         foreach (keys %includes) {
1894             my $dest = $_;
1895             my $ddest = cleanfile($sourced, $_, $blddir);
1896
1897             # If the destination doesn't exist in source, it can only be
1898             # a generated file in the build tree.
1899             if (! -f $ddest) {
1900                 $ddest = cleanfile($buildd, $_, $blddir);
1901                 if ($unified_info{rename}->{$ddest}) {
1902                     $ddest = $unified_info{rename}->{$ddest};
1903                 }
1904             }
1905             foreach (@{$includes{$dest}}) {
1906                 my $is = cleandir($sourced, $_, $blddir);
1907                 my $ib = cleandir($buildd, $_, $blddir);
1908                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1909                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1910                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1911                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1912             }
1913         }
1914     }
1915
1916     ### Make unified_info a bit more efficient
1917     # One level structures
1918     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1919         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1920     }
1921     # Two level structures
1922     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1923         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1924             $unified_info{$l1}->{$l2} =
1925                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1926         }
1927     }
1928     # Includes
1929     foreach my $dest (sort keys %{$unified_info{includes}}) {
1930         if (defined($unified_info{includes}->{$dest}->{build})) {
1931             my @source_includes =
1932                 ( @{$unified_info{includes}->{$dest}->{source}} );
1933             $unified_info{includes}->{$dest} =
1934                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1935             foreach my $inc (@source_includes) {
1936                 push @{$unified_info{includes}->{$dest}}, $inc
1937                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1938             }
1939         } else {
1940             $unified_info{includes}->{$dest} =
1941                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1942         }
1943     }
1944 }
1945
1946 # For the schemes that need it, we provide the old *_obj configs
1947 # from the *_asm_obj ones
1948 foreach (grep /_(asm|aux)_src$/, keys %target) {
1949     my $src = $_;
1950     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1951     $target{$obj} = $target{$src};
1952     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1953     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1954 }
1955
1956 # Write down our configuration where it fits #########################
1957
1958 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1959 print OUT <<"EOF";
1960 package configdata;
1961
1962 use strict;
1963 use warnings;
1964
1965 use Exporter;
1966 #use vars qw(\@ISA \@EXPORT);
1967 our \@ISA = qw(Exporter);
1968 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1969
1970 EOF
1971 print OUT "our %config = (\n";
1972 foreach (sort keys %config) {
1973     if (ref($config{$_}) eq "ARRAY") {
1974         print OUT "  ", $_, " => [ ", join(", ",
1975                                            map { quotify("perl", $_) }
1976                                            @{$config{$_}}), " ],\n";
1977     } else {
1978         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1979     }
1980 }
1981 print OUT <<"EOF";
1982 );
1983
1984 EOF
1985 print OUT "our %target = (\n";
1986 foreach (sort keys %target) {
1987     if (ref($target{$_}) eq "ARRAY") {
1988         print OUT "  ", $_, " => [ ", join(", ",
1989                                            map { quotify("perl", $_) }
1990                                            @{$target{$_}}), " ],\n";
1991     } else {
1992         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1993     }
1994 }
1995 print OUT <<"EOF";
1996 );
1997
1998 EOF
1999 print OUT "our \%available_protocols = (\n";
2000 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2001 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2002 print OUT <<"EOF";
2003 );
2004
2005 EOF
2006 print OUT "our \@disablables = (\n";
2007 foreach (@disablables) {
2008     print OUT "  ", quotify("perl", $_), ",\n";
2009 }
2010 print OUT <<"EOF";
2011 );
2012
2013 EOF
2014 print OUT "our \%disabled = (\n";
2015 foreach (sort keys %disabled) {
2016     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2017 }
2018 print OUT <<"EOF";
2019 );
2020
2021 EOF
2022 print OUT "our %withargs = (\n";
2023 foreach (sort keys %withargs) {
2024     if (ref($withargs{$_}) eq "ARRAY") {
2025         print OUT "  ", $_, " => [ ", join(", ",
2026                                            map { quotify("perl", $_) }
2027                                            @{$withargs{$_}}), " ],\n";
2028     } else {
2029         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2030     }
2031 }
2032 print OUT <<"EOF";
2033 );
2034
2035 EOF
2036 if ($builder eq "unified") {
2037     my $recurse;
2038     $recurse = sub {
2039         my $indent = shift;
2040         foreach (@_) {
2041             if (ref $_ eq "ARRAY") {
2042                 print OUT " "x$indent, "[\n";
2043                 foreach (@$_) {
2044                     $recurse->($indent + 4, $_);
2045                 }
2046                 print OUT " "x$indent, "],\n";
2047             } elsif (ref $_ eq "HASH") {
2048                 my %h = %$_;
2049                 print OUT " "x$indent, "{\n";
2050                 foreach (sort keys %h) {
2051                     if (ref $h{$_} eq "") {
2052                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2053                     } else {
2054                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2055                         $recurse->($indent + 8, $h{$_});
2056                     }
2057                 }
2058                 print OUT " "x$indent, "},\n";
2059             } else {
2060                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2061             }
2062         }
2063     };
2064     print OUT "our %unified_info = (\n";
2065     foreach (sort keys %unified_info) {
2066         if (ref $unified_info{$_} eq "") {
2067             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2068         } else {
2069             print OUT " "x4, quotify("perl", $_), " =>\n";
2070             $recurse->(8, $unified_info{$_});
2071         }
2072     }
2073     print OUT <<"EOF";
2074 );
2075
2076 EOF
2077 }
2078 print OUT "1;\n";
2079 close(OUT);
2080
2081 print "\n";
2082 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2083 print "PERL          =$config{perl}\n";
2084 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2085 print "HASHBANGPERL  =$config{hashbangperl}\n";
2086 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2087 print "CFLAG         =$target{cflags} $config{cflags}\n";
2088 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2089     if defined $target{cxx};
2090 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2091     if defined $target{cxx};
2092 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2093 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2094 #                             "$config{cross_compile_prefix}ranlib" :
2095 #                             "$target{ranlib}", "\n";
2096 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2097
2098 my %builders = (
2099     unified => sub {
2100         run_dofile(catfile($blddir, $target{build_file}),
2101                    @{$config{build_file_templates}});
2102     },
2103     );
2104
2105 $builders{$builder}->($builder_platform, @builder_opts);
2106
2107 print <<"EOF" if ($disabled{threads} eq "unavailable");
2108
2109 The library could not be configured for supporting multi-threaded
2110 applications as the compiler options required on this system are not known.
2111 See file INSTALL for details if you need multi-threading.
2112 EOF
2113
2114 print <<"EOF" if ($no_shared_warn);
2115
2116 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2117 platform, so we will pretend you gave the option 'no-pic', which also disables
2118 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2119 or position independent code, please let us know (but please first make sure
2120 you have tried with a current version of OpenSSL).
2121 EOF
2122
2123 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2124
2125 WARNING: there are indications that another build was made in the source
2126 directory.  This build may have picked up artifacts from that build, the
2127 safest course of action is to clean the source directory and redo this
2128 configuration.
2129 EOF
2130
2131 exit(0);
2132
2133 ######################################################################
2134 #
2135 # Helpers and utility functions
2136 #
2137
2138 # Configuration file reading #########################################
2139
2140 # Note: All of the helper functions are for lazy evaluation.  They all
2141 # return a CODE ref, which will return the intended value when evaluated.
2142 # Thus, whenever there's mention of a returned value, it's about that
2143 # intended value.
2144
2145 # Helper function to implement conditional inheritance depending on the
2146 # value of $disabled{asm}.  Used in inherit_from values as follows:
2147 #
2148 #      inherit_from => [ "template", asm("asm_tmpl") ]
2149 #
2150 sub asm {
2151     my @x = @_;
2152     sub {
2153         $disabled{asm} ? () : @x;
2154     }
2155 }
2156
2157 # Helper function to implement conditional value variants, with a default
2158 # plus additional values based on the value of $config{build_type}.
2159 # Arguments are given in hash table form:
2160 #
2161 #       picker(default => "Basic string: ",
2162 #              debug   => "debug",
2163 #              release => "release")
2164 #
2165 # When configuring with --debug, the resulting string will be
2166 # "Basic string: debug", and when not, it will be "Basic string: release"
2167 #
2168 # This can be used to create variants of sets of flags according to the
2169 # build type:
2170 #
2171 #       cflags => picker(default => "-Wall",
2172 #                        debug   => "-g -O0",
2173 #                        release => "-O3")
2174 #
2175 sub picker {
2176     my %opts = @_;
2177     return sub { add($opts{default} || (),
2178                      $opts{$config{build_type}} || ())->(); }
2179 }
2180
2181 # Helper function to combine several values of different types into one.
2182 # This is useful if you want to combine a string with the result of a
2183 # lazy function, such as:
2184 #
2185 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2186 #
2187 sub combine {
2188     my @stuff = @_;
2189     return sub { add(@stuff)->(); }
2190 }
2191
2192 # Helper function to implement conditional values depending on the value
2193 # of $disabled{threads}.  Can be used as follows:
2194 #
2195 #       cflags => combine("-Wall", threads("-pthread"))
2196 #
2197 sub threads {
2198     my @flags = @_;
2199     return sub { add($disabled{threads} ? () : @flags)->(); }
2200 }
2201
2202
2203
2204 our $add_called = 0;
2205 # Helper function to implement adding values to already existing configuration
2206 # values.  It handles elements that are ARRAYs, CODEs and scalars
2207 sub _add {
2208     my $separator = shift;
2209
2210     # If there's any ARRAY in the collection of values OR the separator
2211     # is undef, we will return an ARRAY of combined values, otherwise a
2212     # string of joined values with $separator as the separator.
2213     my $found_array = !defined($separator);
2214
2215     my @values =
2216         map {
2217             my $res = $_;
2218             while (ref($res) eq "CODE") {
2219                 $res = $res->();
2220             }
2221             if (defined($res)) {
2222                 if (ref($res) eq "ARRAY") {
2223                     $found_array = 1;
2224                     @$res;
2225                 } else {
2226                     $res;
2227                 }
2228             } else {
2229                 ();
2230             }
2231     } (@_);
2232
2233     $add_called = 1;
2234
2235     if ($found_array) {
2236         [ @values ];
2237     } else {
2238         join($separator, grep { defined($_) && $_ ne "" } @values);
2239     }
2240 }
2241 sub add_before {
2242     my $separator = " ";
2243     if (ref($_[$#_]) eq "HASH") {
2244         my $opts = pop;
2245         $separator = $opts->{separator};
2246     }
2247     my @x = @_;
2248     sub { _add($separator, @x, @_) };
2249 }
2250 sub add {
2251     my $separator = " ";
2252     if (ref($_[$#_]) eq "HASH") {
2253         my $opts = pop;
2254         $separator = $opts->{separator};
2255     }
2256     my @x = @_;
2257     sub { _add($separator, @_, @x) };
2258 }
2259
2260 # configuration reader, evaluates the input file as a perl script and expects
2261 # it to fill %targets with target configurations.  Those are then added to
2262 # %table.
2263 sub read_config {
2264     my $fname = shift;
2265     open(CONFFILE, "< $fname")
2266         or die "Can't open configuration file '$fname'!\n";
2267     my $x = $/;
2268     undef $/;
2269     my $content = <CONFFILE>;
2270     $/ = $x;
2271     close(CONFFILE);
2272     my %targets = ();
2273     {
2274         # Protect certain tables from tampering
2275         local %table = %::table;
2276
2277         eval $content;
2278         warn $@ if $@;
2279     }
2280
2281     # For each target, check that it's configured with a hash table.
2282     foreach (keys %targets) {
2283         if (ref($targets{$_}) ne "HASH") {
2284             if (ref($targets{$_}) eq "") {
2285                 warn "Deprecated target configuration for $_, ignoring...\n";
2286             } else {
2287                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2288             }
2289             delete $targets{$_};
2290         } else {
2291             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2292         }
2293     }
2294
2295     %table = (%table, %targets);
2296
2297 }
2298
2299 # configuration resolver.  Will only resolve all the lazy evaluation
2300 # codeblocks for the chosen target and all those it inherits from,
2301 # recursively
2302 sub resolve_config {
2303     my $target = shift;
2304     my @breadcrumbs = @_;
2305
2306 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2307
2308     if (grep { $_ eq $target } @breadcrumbs) {
2309         die "inherit_from loop!  target backtrace:\n  "
2310             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2311     }
2312
2313     if (!defined($table{$target})) {
2314         warn "Warning! target $target doesn't exist!\n";
2315         return ();
2316     }
2317     # Recurse through all inheritances.  They will be resolved on the
2318     # fly, so when this operation is done, they will all just be a
2319     # bunch of attributes with string values.
2320     # What we get here, though, are keys with references to lists of
2321     # the combined values of them all.  We will deal with lists after
2322     # this stage is done.
2323     my %combined_inheritance = ();
2324     if ($table{$target}->{inherit_from}) {
2325         my @inherit_from =
2326             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2327         foreach (@inherit_from) {
2328             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2329
2330             # 'template' is a marker that's considered private to
2331             # the config that had it.
2332             delete $inherited_config{template};
2333
2334             foreach (keys %inherited_config) {
2335                 if (!$combined_inheritance{$_}) {
2336                     $combined_inheritance{$_} = [];
2337                 }
2338                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2339             }
2340         }
2341     }
2342
2343     # We won't need inherit_from in this target any more, since we've
2344     # resolved all the inheritances that lead to this
2345     delete $table{$target}->{inherit_from};
2346
2347     # Now is the time to deal with those lists.  Here's the place to
2348     # decide what shall be done with those lists, all based on the
2349     # values of the target we're currently dealing with.
2350     # - If a value is a coderef, it will be executed with the list of
2351     #   inherited values as arguments.
2352     # - If the corresponding key doesn't have a value at all or is the
2353     #   empty string, the inherited value list will be run through the
2354     #   default combiner (below), and the result becomes this target's
2355     #   value.
2356     # - Otherwise, this target's value is assumed to be a string that
2357     #   will simply override the inherited list of values.
2358     my $default_combiner = add();
2359
2360     my %all_keys =
2361         map { $_ => 1 } (keys %combined_inheritance,
2362                          keys %{$table{$target}});
2363
2364     sub process_values {
2365         my $object    = shift;
2366         my $inherited = shift;  # Always a [ list ]
2367         my $target    = shift;
2368         my $entry     = shift;
2369
2370         $add_called = 0;
2371
2372         while(ref($object) eq "CODE") {
2373             $object = $object->(@$inherited);
2374         }
2375         if (!defined($object)) {
2376             return ();
2377         }
2378         elsif (ref($object) eq "ARRAY") {
2379             local $add_called;  # To make sure recursive calls don't affect it
2380             return [ map { process_values($_, $inherited, $target, $entry) }
2381                      @$object ];
2382         } elsif (ref($object) eq "") {
2383             return $object;
2384         } else {
2385             die "cannot handle reference type ",ref($object)
2386                 ," found in target ",$target," -> ",$entry,"\n";
2387         }
2388     }
2389
2390     foreach (sort keys %all_keys) {
2391         my $previous = $combined_inheritance{$_};
2392
2393         # Current target doesn't have a value for the current key?
2394         # Assign it the default combiner, the rest of this loop body
2395         # will handle it just like any other coderef.
2396         if (!exists $table{$target}->{$_}) {
2397             $table{$target}->{$_} = $default_combiner;
2398         }
2399
2400         $table{$target}->{$_} = process_values($table{$target}->{$_},
2401                                                $combined_inheritance{$_},
2402                                                $target, $_);
2403         unless(defined($table{$target}->{$_})) {
2404             delete $table{$target}->{$_};
2405         }
2406 #        if ($extra_checks &&
2407 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2408 #            warn "$_ got replaced in $target\n";
2409 #        }
2410     }
2411
2412     # Finally done, return the result.
2413     return %{$table{$target}};
2414 }
2415
2416 sub usage
2417         {
2418         print STDERR $usage;
2419         print STDERR "\npick os/compiler from:\n";
2420         my $j=0;
2421         my $i;
2422         my $k=0;
2423         foreach $i (sort keys %table)
2424                 {
2425                 next if $table{$i}->{template};
2426                 next if $i =~ /^debug/;
2427                 $k += length($i) + 1;
2428                 if ($k > 78)
2429                         {
2430                         print STDERR "\n";
2431                         $k=length($i);
2432                         }
2433                 print STDERR $i . " ";
2434                 }
2435         foreach $i (sort keys %table)
2436                 {
2437                 next if $table{$i}->{template};
2438                 next if $i !~ /^debug/;
2439                 $k += length($i) + 1;
2440                 if ($k > 78)
2441                         {
2442                         print STDERR "\n";
2443                         $k=length($i);
2444                         }
2445                 print STDERR $i . " ";
2446                 }
2447         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2448         exit(1);
2449         }
2450
2451 sub run_dofile
2452 {
2453     my $out = shift;
2454     my @templates = @_;
2455
2456     unlink $out || warn "Can't remove $out, $!"
2457         if -f $out;
2458     foreach (@templates) {
2459         die "Can't open $_, $!" unless -f $_;
2460     }
2461     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2462     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2463     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2464     system($cmd);
2465     exit 1 if $? != 0;
2466     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2467 }
2468
2469 sub which
2470 {
2471     my ($name)=@_;
2472
2473     if (eval { require IPC::Cmd; 1; }) {
2474         IPC::Cmd->import();
2475         return scalar IPC::Cmd::can_run($name);
2476     } else {
2477         # if there is $directories component in splitpath,
2478         # then it's not something to test with $PATH...
2479         return $name if (File::Spec->splitpath($name))[1];
2480
2481         foreach (File::Spec->path()) {
2482             my $fullpath = catfile($_, "$name$target{exe_extension}");
2483             if (-f $fullpath and -x $fullpath) {
2484                 return $fullpath;
2485             }
2486         }
2487     }
2488 }
2489
2490 # Configuration printer ##############################################
2491
2492 sub print_table_entry
2493 {
2494     my $target = shift;
2495     my %target = resolve_config($target);
2496     my $type = shift;
2497
2498     # Don't print the templates
2499     return if $target{template};
2500
2501     my @sequence = (
2502         "sys_id",
2503         "cc",
2504         "cflags",
2505         "defines",
2506         "unistd",
2507         "ld",
2508         "lflags",
2509         "loutflag",
2510         "plib_lflags",
2511         "ex_libs",
2512         "bn_ops",
2513         "apps_aux_src",
2514         "cpuid_asm_src",
2515         "uplink_aux_src",
2516         "bn_asm_src",
2517         "ec_asm_src",
2518         "des_asm_src",
2519         "aes_asm_src",
2520         "bf_asm_src",
2521         "md5_asm_src",
2522         "cast_asm_src",
2523         "sha1_asm_src",
2524         "rc4_asm_src",
2525         "rmd160_asm_src",
2526         "rc5_asm_src",
2527         "wp_asm_src",
2528         "cmll_asm_src",
2529         "modes_asm_src",
2530         "padlock_asm_src",
2531         "chacha_asm_src",
2532         "poly1035_asm_src",
2533         "thread_scheme",
2534         "perlasm_scheme",
2535         "dso_scheme",
2536         "shared_target",
2537         "shared_cflag",
2538         "shared_defines",
2539         "shared_ldflag",
2540         "shared_rcflag",
2541         "shared_extension",
2542         "dso_extension",
2543         "obj_extension",
2544         "exe_extension",
2545         "ranlib",
2546         "ar",
2547         "arflags",
2548         "aroutflag",
2549         "rc",
2550         "rcflags",
2551         "rcoutflag",
2552         "mt",
2553         "mtflags",
2554         "mtinflag",
2555         "mtoutflag",
2556         "multilib",
2557         "build_scheme",
2558         );
2559
2560     if ($type eq "TABLE") {
2561         print "\n";
2562         print "*** $target\n";
2563         foreach (@sequence) {
2564             if (ref($target{$_}) eq "ARRAY") {
2565                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2566             } else {
2567                 printf "\$%-12s = %s\n", $_, $target{$_};
2568             }
2569         }
2570     } elsif ($type eq "HASH") {
2571         my $largest =
2572             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2573         print "    '$target' => {\n";
2574         foreach (@sequence) {
2575             if ($target{$_}) {
2576                 if (ref($target{$_}) eq "ARRAY") {
2577                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2578                 } else {
2579                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2580                 }
2581             }
2582         }
2583         print "    },\n";
2584     }
2585 }
2586
2587 # Utility routines ###################################################
2588
2589 # On VMS, if the given file is a logical name, File::Spec::Functions
2590 # will consider it an absolute path.  There are cases when we want a
2591 # purely syntactic check without checking the environment.
2592 sub isabsolute {
2593     my $file = shift;
2594
2595     # On non-platforms, we just use file_name_is_absolute().
2596     return file_name_is_absolute($file) unless $^O eq "VMS";
2597
2598     # If the file spec includes a device or a directory spec,
2599     # file_name_is_absolute() is perfectly safe.
2600     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2601
2602     # Here, we know the given file spec isn't absolute
2603     return 0;
2604 }
2605
2606 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2607 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2608 # realpath() requires that at least all path components except the last is an
2609 # existing directory.  On VMS, the last component of the directory spec must
2610 # exist.
2611 sub absolutedir {
2612     my $dir = shift;
2613
2614     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2615     # will return the volume name for the device, no matter what.  Also,
2616     # it will return an incorrect directory spec if the argument is a
2617     # directory that doesn't exist.
2618     if ($^O eq "VMS") {
2619         return rel2abs($dir);
2620     }
2621
2622     # We use realpath() on Unix, since no other will properly clean out
2623     # a directory spec.
2624     use Cwd qw/realpath/;
2625
2626     return realpath($dir);
2627 }
2628
2629 sub quotify {
2630     my %processors = (
2631         perl    => sub { my $x = shift;
2632                          $x =~ s/([\\\$\@"])/\\$1/g;
2633                          return '"'.$x.'"'; },
2634         maybeshell => sub { my $x = shift;
2635                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2636                             if ($x ne $y || $x =~ m|\s|) {
2637                                 return '"'.$y.'"';
2638                             } else {
2639                                 return $x;
2640                             }
2641                         },
2642         );
2643     my $for = shift;
2644     my $processor =
2645         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2646
2647     return map { $processor->($_); } @_;
2648 }
2649
2650 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2651 # $filename is a file name to read from
2652 # $line_concat_cond_re is a regexp detecting a line continuation ending
2653 # $line_concat is a CODEref that takes care of concatenating two lines
2654 sub collect_from_file {
2655     my $filename = shift;
2656     my $line_concat_cond_re = shift;
2657     my $line_concat = shift;
2658
2659     open my $fh, $filename || die "unable to read $filename: $!\n";
2660     return sub {
2661         my $saved_line = "";
2662         $_ = "";
2663         while (<$fh>) {
2664             s|\R$||;
2665             if (defined $line_concat) {
2666                 $_ = $line_concat->($saved_line, $_);
2667                 $saved_line = "";
2668             }
2669             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2670                 $saved_line = $_;
2671                 next;
2672             }
2673             return $_;
2674         }
2675         die "$filename ending with continuation line\n" if $_;
2676         close $fh;
2677         return undef;
2678     }
2679 }
2680
2681 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2682 # $array is an ARRAYref of lines
2683 # $line_concat_cond_re is a regexp detecting a line continuation ending
2684 # $line_concat is a CODEref that takes care of concatenating two lines
2685 sub collect_from_array {
2686     my $array = shift;
2687     my $line_concat_cond_re = shift;
2688     my $line_concat = shift;
2689     my @array = (@$array);
2690
2691     return sub {
2692         my $saved_line = "";
2693         $_ = "";
2694         while (defined($_ = shift @array)) {
2695             s|\R$||;
2696             if (defined $line_concat) {
2697                 $_ = $line_concat->($saved_line, $_);
2698                 $saved_line = "";
2699             }
2700             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2701                 $saved_line = $_;
2702                 next;
2703             }
2704             return $_;
2705         }
2706         die "input text ending with continuation line\n" if $_;
2707         return undef;
2708     }
2709 }
2710
2711 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2712 # $lineiterator is a CODEref that delivers one line at a time.
2713 # All following arguments are regex/CODEref pairs, where the regexp detects a
2714 # line and the CODEref does something with the result of the regexp.
2715 sub collect_information {
2716     my $lineiterator = shift;
2717     my %collectors = @_;
2718
2719     while(defined($_ = $lineiterator->())) {
2720         s|\R$||;
2721         my $found = 0;
2722         if ($collectors{"BEFORE"}) {
2723             $collectors{"BEFORE"}->($_);
2724         }
2725         foreach my $re (keys %collectors) {
2726             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2727                 $collectors{$re}->($lineiterator);
2728                 $found = 1;
2729             };
2730         }
2731         if ($collectors{"OTHERWISE"}) {
2732             $collectors{"OTHERWISE"}->($lineiterator, $_)
2733                 unless $found || !defined $collectors{"OTHERWISE"};
2734         }
2735         if ($collectors{"AFTER"}) {
2736             $collectors{"AFTER"}->($_);
2737         }
2738     }
2739 }
2740
2741 # tokenize($line)
2742 # $line is a line of text to split up into tokens
2743 # returns a list of tokens
2744 #
2745 # Tokens are divided by spaces.  If the tokens include spaces, they
2746 # have to be quoted with single or double quotes.  Double quotes
2747 # inside a double quoted token must be escaped.  Escaping is done
2748 # with backslash.
2749 # Basically, the same quoting rules apply for " and ' as in any
2750 # Unix shell.
2751 sub tokenize {
2752     my $line = my $debug_line = shift;
2753     my @result = ();
2754
2755     while ($line =~ s|^\s+||, $line ne "") {
2756         my $token = "";
2757         while ($line ne "" && $line !~ m|^\s|) {
2758             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2759                 $token .= $1;
2760                 $line = $';
2761             } elsif ($line =~ m/^'([^']*)'/) {
2762                 $token .= $1;
2763                 $line = $';
2764             } elsif ($line =~ m/^(\S+)/) {
2765                 $token .= $1;
2766                 $line = $';
2767             }
2768         }
2769         push @result, $token;
2770     }
2771
2772     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2773         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2774         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2775     }
2776     return @result;
2777 }