Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2017 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 require 5.10.0;
  13 use strict;
  14 use Config;
  15 use File::Basename;
  16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  17 use File::Path qw/mkpath/;
  18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  19
  20 # see INSTALL for instructions.
  21
  22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  23
  24 # Options:
  25 #
  26 # --config      add the given configuration file, which will be read after
  27 #               any "Configurations*" files that are found in the same
  28 #               directory as this script.
  29 # --prefix      prefix for the OpenSSL installation, which includes the
  30 #               directories bin, lib, include, share/man, share/doc/openssl
  31 #               This becomes the value of INSTALLTOP in Makefile
  32 #               (Default: /usr/local)
  33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  34 #               If it's a relative directory, it will be added on the directory
  35 #               given with --prefix.
  36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  37 #               (Default: PREFIX/ssl)
  38 #
  39 # --cross-compile-prefix Add specified prefix to binutils components.
  40 #
  41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  42 #               interfaces deprecated as of the specified OpenSSL version.
  43 #
  44 # no-hw-xxx     do not compile support for specific crypto hardware.
  45 #               Generic OpenSSL-style methods relating to this support
  46 #               are always compiled but return NULL if the hardware
  47 #               support isn't compiled.
  48 # no-hw         do not compile support for any crypto hardware.
  49 # [no-]threads  [don't] try to create a library that is suitable for
  50 #               multithreaded applications (default is "threads" if we
  51 #               know how to do it)
  52 # [no-]shared   [don't] try to create shared libraries when supported.
  53 # [no-]pic      [don't] try to build position independent code when supported.
  54 #               If disabled, it also disables shared and dynamic-engine.
  55 # no-asm        do not use assembler
  56 # no-dso        do not compile in any native shared-library methods. This
  57 #               will ensure that all methods just return NULL.
  58 # no-egd        do not compile support for the entropy-gathering daemon APIs
  59 # [no-]zlib     [don't] compile support for zlib compression.
  60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  61 #               library and will be loaded in run-time by the OpenSSL library.
  62 # sctp          include SCTP support
  63 # enable-weak-ssl-ciphers
  64 #               Enable weak ciphers that are disabled by default. This currently
  65 #               only includes RC4 based ciphers.
  66 # 386           generate 80386 code in assembly modules
  67 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  68 #               mentioned '386' option implies this one
  69 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  70 # -<xxx> +<xxx> compiler options are passed through
  71 # -static       while -static is also a pass-through compiler option (and
  72 #               as such is limited to environments where it's actually
  73 #               meaningful), it triggers a number configuration options,
  74 #               namely no-dso, no-pic, no-shared and no-threads. It is
  75 #               argued that the only reason to produce statically linked
  76 #               binaries (and in context it means executables linked with
  77 #               -static flag, and not just executables linked with static
  78 #               libcrypto.a) is to eliminate dependency on specific run-time,
  79 #               a.k.a. libc version. The mentioned config options are meant
  80 #               to achieve just that. Unfortunately on Linux it's impossible
  81 #               to eliminate the dependency completely for openssl executable
  82 #               because of getaddrinfo and gethostbyname calls, which can
  83 #               invoke dynamically loadable library facility anyway to meet
  84 #               the lookup requests. For this reason on Linux statically
  85 #               linked openssl executable has rather debugging value than
  86 #               production quality.
  87 #
  88 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  89 #               provided to stack calls. Generates unique stack functions for
  90 #               each possible stack type.
  91 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  92 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  93 # Following are set automatically by this script
  94 #
  95 # MD5_ASM       use some extra md5 assembler,
  96 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  97 # RMD160_ASM    use some extra ripemd160 assembler,
  98 # SHA256_ASM    sha256_block is implemented in assembler
  99 # SHA512_ASM    sha512_block is implemented in assembler
 100 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 101
 102 # Minimum warning options... any contributions to OpenSSL should at least get
 103 # past these.
 104
 105 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 106 # -DPEDANTIC complements -pedantic and is meant to mask code that
 107 # is not strictly standard-compliant and/or implementation-specific,
 108 # e.g. inline assembly, disregards to alignment requirements, such
 109 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 110 # to be used even in sanitized builds, because sanitizer too is
 111 # supposed to and does take notice of non-standard behaviour. Then
 112 # -pedantic with pre-C9x compiler would also complain about 'long
 113 # long' not being supported. As 64-bit algorithms are common now,
 114 # it grew impossible to resolve this without sizeable additional
 115 # code, so we just tell compiler to be pedantic about everything
 116 # but 'long long' type.
 117
 118 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 119         . " -Wswitch"
 120         . " -DPEDANTIC -pedantic -Wno-long-long"
 121         . " -Wall"
 122         . " -Wsign-compare"
 123         . " -Wmissing-prototypes"
 124         . " -Wshadow"
 125         . " -Wformat"
 126         . " -Wtype-limits"
 127         . " -Wno-parentheses-equality"
 128         . " -Werror"
 129         ;
 130
 131 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 132 # TODO(openssl-team): fix problems and investigate if (at least) the
 133 # following warnings can also be enabled:
 134 #       -Wcast-align
 135 #       -Wunreachable-code -- no, too ugly/compiler-specific
 136 #       -Wlanguage-extension-token -- no, we use asm()
 137 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 138 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 139 my $clang_devteam_warn = ""
 140         . " -Qunused-arguments"
 141         . " -Wextra"
 142         . " -Wswitch -Wswitch-default"
 143         . " -Wno-unused-parameter"
 144         . " -Wno-parentheses-equality"
 145         . " -Wno-missing-field-initializers"
 146         . " -Wno-language-extension-token"
 147         . " -Wno-extended-offsetof"
 148         . " -Wconditional-uninitialized"
 149         . " -Wincompatible-pointer-types-discards-qualifiers"
 150         . " -Wmissing-variable-declarations"
 151         ;
 152
 153 # This adds backtrace information to the memory leak info.  Is only used
 154 # when crypto-mdebug-backtrace is enabled.
 155 my $memleak_devteam_backtrace = "-rdynamic";
 156
 157 my $strict_warnings = 0;
 158
 159 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 160 # which would cover all BSD flavors. -pthread applies to them all,
 161 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 162 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 163 # which has to be accompanied by explicit -D_THREAD_SAFE and
 164 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 165 # seems to be sufficient?
 166 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 167
 168 #
 169 # API compatibility name to version number mapping.
 170 #
 171 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 172 my $apitable = {
 173     "1.1.0" => "0x10100000L",
 174     "1.0.0" => "0x10000000L",
 175     "0.9.8" => "0x00908000L",
 176 };
 177
 178 our %table = ();
 179 our %config = ();
 180 our %withargs = ();
 181
 182 # Forward declarations ###############################################
 183
 184 # read_config(filename)
 185 #
 186 # Reads a configuration file and populates %table with the contents
 187 # (which the configuration file places in %targets).
 188 sub read_config;
 189
 190 # resolve_config(target)
 191 #
 192 # Resolves all the late evaluations, inheritances and so on for the
 193 # chosen target and any target it inherits from.
 194 sub resolve_config;
 195
 196
 197 # Information collection #############################################
 198
 199 # Unified build supports separate build dir
 200 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 201 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 202 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 203
 204 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 205
 206 $config{sourcedir} = abs2rel($srcdir);
 207 $config{builddir} = abs2rel($blddir);
 208
 209 # Collect reconfiguration information if needed
 210 my @argvcopy=@ARGV;
 211
 212 if (grep /^reconf(igure)?$/, @argvcopy) {
 213     if (-f "./configdata.pm") {
 214         my $file = "./configdata.pm";
 215         unless (my $return = do $file) {
 216             die "couldn't parse $file: $@" if $@;
 217             die "couldn't do $file: $!"    unless defined $return;
 218             die "couldn't run $file"       unless $return;
 219         }
 220
 221         @argvcopy = defined($configdata::config{perlargv}) ?
 222             @{$configdata::config{perlargv}} : ();
 223         die "Incorrect data to reconfigure, please do a normal configuration\n"
 224             if (grep(/^reconf/,@argvcopy));
 225         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 226             if defined($configdata::config{cross_compile_prefix});
 227         $ENV{CC} = $configdata::config{cc}
 228             if defined($configdata::config{cc});
 229         $ENV{CXX} = $configdata::config{cxx}
 230             if defined($configdata::config{cxx});
 231         $ENV{BUILDFILE} = $configdata::config{build_file}
 232             if defined($configdata::config{build_file});
 233         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 234             if defined($configdata::config{local_config_dir});
 235
 236         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 237         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 238             if $ENV{CROSS_COMPILE};
 239         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 240         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
 241         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 242         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 243             if $ENV{$local_config_envname};
 244     } else {
 245         die "Insufficient data to reconfigure, please do a normal configuration\n";
 246     }
 247 }
 248
 249 $config{perlargv} = [ @argvcopy ];
 250
 251 # Collect version numbers
 252 $config{version} = "unknown";
 253 $config{version_num} = "unknown";
 254 $config{shlib_version_number} = "unknown";
 255 $config{shlib_version_history} = "unknown";
 256
 257 collect_information(
 258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 259     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 260     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 261     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 262     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 263     );
 264 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 265
 266 ($config{major}, $config{minor})
 267     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 268 ($config{shlib_major}, $config{shlib_minor})
 269     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 272     if ($config{major} eq "" || $config{minor} eq ""
 273         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 274
 275 # Collect target configurations
 276
 277 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 278 foreach (sort glob($pattern)) {
 279     &read_config($_);
 280 }
 281
 282 if (defined $ENV{$local_config_envname}) {
 283     if ($^O eq 'VMS') {
 284         # VMS environment variables are logical names,
 285         # which can be used as is
 286         $pattern = $local_config_envname . ':' . '*.conf';
 287     } else {
 288         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 289     }
 290
 291     foreach (sort glob($pattern)) {
 292         &read_config($_);
 293     }
 294 }
 295
 296
 297 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 298
 299 $config{prefix}="";
 300 $config{openssldir}="";
 301 $config{processor}="";
 302 $config{libdir}="";
 303 $config{cross_compile_prefix}="";
 304 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 305 my $nofipscanistercheck=0;
 306 $config{baseaddr}="0xFB00000";
 307 my $auto_threads=1;    # enable threads automatically? true by default
 308 my $default_ranlib;
 309 $config{fips}=0;
 310
 311 # Top level directories to build
 312 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 313 # crypto/ subdirectories to build
 314 $config{sdirs} = [
 315     "objects",
 316     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash",
 317     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "chacha", "modes",
 318     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 319     "buffer", "bio", "stack", "lhash", "rand", "err",
 320     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 321     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 322     ];
 323 # test/ subdirectories to build
 324 $config{tdirs} = [ "ossl_shim" ];
 325
 326 # Known TLS and DTLS protocols
 327 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 328 my @dtls = qw(dtls1 dtls1_2);
 329
 330 # Explicitly known options that are possible to disable.  They can
 331 # be regexps, and will be used like this: /^no-${option}$/
 332 # For developers: keep it sorted alphabetically
 333
 334 my @disablables = (
 335     "afalgeng",
 336     "aria",
 337     "asan",
 338     "asm",
 339     "async",
 340     "autoalginit",
 341     "autoerrinit",
 342     "bf",
 343     "blake2",
 344     "camellia",
 345     "capieng",
 346     "cast",
 347     "chacha",
 348     "cmac",
 349     "cms",
 350     "comp",
 351     "crypto-mdebug",
 352     "crypto-mdebug-backtrace",
 353     "ct",
 354     "deprecated",
 355     "des",
 356     "dgram",
 357     "dh",
 358     "dsa",
 359     "dso",
 360     "dtls",
 361     "dynamic-engine",
 362     "ec",
 363     "ec2m",
 364     "ecdh",
 365     "ecdsa",
 366     "ec_nistp_64_gcc_128",
 367     "egd",
 368     "engine",
 369     "err",
 370     "external-tests",
 371     "filenames",
 372     "fuzz-libfuzzer",
 373     "fuzz-afl",
 374     "gost",
 375     "heartbeats",
 376     "hw(-.+)?",
 377     "idea",
 378     "makedepend",
 379     "md2",
 380     "md4",
 381     "mdc2",
 382     "msan",
 383     "multiblock",
 384     "nextprotoneg",
 385     "ocb",
 386     "ocsp",
 387     "pic",
 388     "poly1305",
 389     "posix-io",
 390     "psk",
 391     "rc2",
 392     "rc4",
 393     "rc5",
 394     "rdrand",
 395     "rfc3779",
 396     "rmd160",
 397     "scrypt",
 398     "sctp",
 399     "seed",
 400     "shared",
 401     "siphash",
 402     "sock",
 403     "srp",
 404     "srtp",
 405     "sse2",
 406     "ssl",
 407     "ssl-trace",
 408     "static-engine",
 409     "stdio",
 410     "tests",
 411     "threads",
 412     "tls",
 413     "ts",
 414     "ubsan",
 415     "ui",
 416     "unit-test",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method");
 426         }
 427
 428 my %deprecated_disablables = (
 429     "ssl2" => undef,
 430     "buf-freelists" => undef,
 431     "ripemd" => "rmd160"
 432     );
 433
 434 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 435
 436 our %disabled = ( # "what"         => "comment"
 437                   "aria"                => "default",
 438                   "asan"                => "default",
 439                   "crypto-mdebug"       => "default",
 440                   "crypto-mdebug-backtrace" => "default",
 441                   "ec_nistp_64_gcc_128" => "default",
 442                   "egd"                 => "default",
 443                   "external-tests"      => "default",
 444                   "fuzz-libfuzzer"      => "default",
 445                   "fuzz-afl"            => "default",
 446                   "heartbeats"          => "default",
 447                   "md2"                 => "default",
 448                   "msan"                => "default",
 449                   "rc5"                 => "default",
 450                   "sctp"                => "default",
 451                   "ssl-trace"           => "default",
 452                   "ssl3"                => "default",
 453                   "ssl3-method"         => "default",
 454                   "ubsan"               => "default",
 455           #TODO(TLS1.3): Temporarily disabled while this is a WIP
 456                   "tls1_3"              => "default",
 457                   "unit-test"           => "default",
 458                   "weak-ssl-ciphers"    => "default",
 459                   "zlib"                => "default",
 460                   "zlib-dynamic"        => "default",
 461                 );
 462
 463 # Note: => pair form used for aesthetics, not to truly make a hash table
 464 my @disable_cascades = (
 465     # "what"            => [ "cascade", ... ]
 466     sub { $config{processor} eq "386" }
 467                         => [ "sse2" ],
 468     "ssl"               => [ "ssl3" ],
 469     "ssl3-method"       => [ "ssl3" ],
 470     "zlib"              => [ "zlib-dynamic" ],
 471     "des"               => [ "mdc2" ],
 472     "ec"                => [ "ecdsa", "ecdh" ],
 473
 474     "dgram"             => [ "dtls", "sctp" ],
 475     "sock"              => [ "dgram" ],
 476     "dtls"              => [ @dtls ],
 477     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 478                         => [ "dtls" ],
 479
 480     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 481     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 482     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 483
 484     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 485     sub { $disabled{rsa}
 486           && ($disabled{dsa} || $disabled{dh}); }
 487                         => [ "ssl" ],
 488
 489     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 490     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 491     # (XXX: We don't support PSK-only builds).
 492     sub { $disabled{rsa}
 493           && ($disabled{dsa} || $disabled{dh})
 494           && ($disabled{ecdsa} || $disabled{ecdh}); }
 495                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
 496                              "dtls1", "dtls1_2" ],
 497
 498     "tls"               => [ @tls ],
 499     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 500                         => [ "tls" ],
 501
 502     # SRP and HEARTBEATS require TLSEXT
 503     "tlsext"            => [ "srp", "heartbeats" ],
 504
 505     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 506
 507     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 508     "dso"               => [ "dynamic-engine" ],
 509
 510     # Without position independent code, there can be no shared libraries or DSOs
 511     "pic"               => [ "shared" ],
 512     "shared"            => [ "dynamic-engine" ],
 513     "engine"            => [ "afalgeng" ],
 514
 515     # no-autoalginit is only useful when building non-shared
 516     "autoalginit"       => [ "shared", "apps" ],
 517
 518     "stdio"             => [ "apps", "capieng" ],
 519     "apps"              => [ "tests" ],
 520     "comp"              => [ "zlib" ],
 521     "ec"                => [ "tls1_3" ],
 522     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 523
 524     sub { !$disabled{"msan"} } => [ "asm" ],
 525     );
 526
 527 # Avoid protocol support holes.  Also disable all versions below N, if version
 528 # N is disabled while N+1 is enabled.
 529 #
 530 my @list = (reverse @tls);
 531 while ((my $first, my $second) = (shift @list, shift @list)) {
 532     last unless @list;
 533     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 534                               => [ @list ] );
 535     unshift @list, $second;
 536 }
 537 my @list = (reverse @dtls);
 538 while ((my $first, my $second) = (shift @list, shift @list)) {
 539     last unless @list;
 540     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 541                               => [ @list ] );
 542     unshift @list, $second;
 543 }
 544
 545 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 546 # To remove something from %disabled, use "enable-foo".
 547 # For symmetry, "disable-foo" is a synonym for "no-foo".
 548
 549 my $no_sse2=0;
 550
 551 &usage if ($#ARGV < 0);
 552
 553 my $user_cflags="";
 554 my @user_defines=();
 555 $config{openssl_api_defines}=[];
 556 $config{openssl_algorithm_defines}=[];
 557 $config{openssl_thread_defines}=[];
 558 $config{openssl_sys_defines}=[];
 559 $config{openssl_other_defines}=[];
 560 my $libs="";
 561 my $target="";
 562 $config{options}="";
 563 $config{build_type} = "release";
 564
 565 my %unsupported_options = ();
 566 my %deprecated_options = ();
 567 while (@argvcopy)
 568         {
 569         $_ = shift @argvcopy;
 570         # VMS is a case insensitive environment, and depending on settings
 571         # out of our control, we may receive options uppercased.  Let's
 572         # downcase at least the part before any equal sign.
 573         if ($^O eq "VMS")
 574                 {
 575                 s/^([^=]*)/lc($1)/e;
 576                 }
 577         s /^-no-/no-/; # some people just can't read the instructions
 578
 579         # rewrite some options in "enable-..." form
 580         s /^-?-?shared$/enable-shared/;
 581         s /^sctp$/enable-sctp/;
 582         s /^threads$/enable-threads/;
 583         s /^zlib$/enable-zlib/;
 584         s /^zlib-dynamic$/enable-zlib-dynamic/;
 585
 586         if (/^(no|disable|enable)-(.+)$/)
 587                 {
 588                 my $word = $2;
 589                 if (!exists $deprecated_disablables{$word}
 590                         && !grep { $word =~ /^${_}$/ } @disablables)
 591                         {
 592                         $unsupported_options{$_} = 1;
 593                         next;
 594                         }
 595                 }
 596         if (/^no-(.+)$/ || /^disable-(.+)$/)
 597                 {
 598                 foreach my $proto ((@tls, @dtls))
 599                         {
 600                         if ($1 eq "$proto-method")
 601                                 {
 602                                 $disabled{"$proto"} = "option($proto-method)";
 603                                 last;
 604                                 }
 605                         }
 606                 if ($1 eq "dtls")
 607                         {
 608                         foreach my $proto (@dtls)
 609                                 {
 610                                 $disabled{$proto} = "option(dtls)";
 611                                 }
 612                         $disabled{"dtls"} = "option(dtls)";
 613                         }
 614                 elsif ($1 eq "ssl")
 615                         {
 616                         # Last one of its kind
 617                         $disabled{"ssl3"} = "option(ssl)";
 618                         }
 619                 elsif ($1 eq "tls")
 620                         {
 621                         # XXX: Tests will fail if all SSL/TLS
 622                         # protocols are disabled.
 623                         foreach my $proto (@tls)
 624                                 {
 625                                 $disabled{$proto} = "option(tls)";
 626                                 }
 627                         }
 628                 elsif ($1 eq "static-engine")
 629                         {
 630                         delete $disabled{"dynamic-engine"};
 631                         }
 632                 elsif ($1 eq "dynamic-engine")
 633                         {
 634                         $disabled{"dynamic-engine"} = "option";
 635                         }
 636                 elsif (exists $deprecated_disablables{$1})
 637                         {
 638                         $deprecated_options{$_} = 1;
 639                         if (defined $deprecated_disablables{$1})
 640                                 {
 641                                 $disabled{$deprecated_disablables{$1}} = "option";
 642                                 }
 643                         }
 644                 else
 645                         {
 646                         $disabled{$1} = "option";
 647                         }
 648                 # No longer an automatic choice
 649                 $auto_threads = 0 if ($1 eq "threads");
 650                 }
 651         elsif (/^enable-(.+)$/)
 652                 {
 653                 if ($1 eq "static-engine")
 654                         {
 655                         $disabled{"dynamic-engine"} = "option";
 656                         }
 657                 elsif ($1 eq "dynamic-engine")
 658                         {
 659                         delete $disabled{"dynamic-engine"};
 660                         }
 661                 elsif ($1 eq "zlib-dynamic")
 662                         {
 663                         delete $disabled{"zlib"};
 664                         }
 665                 my $algo = $1;
 666                 delete $disabled{$algo};
 667
 668                 # No longer an automatic choice
 669                 $auto_threads = 0 if ($1 eq "threads");
 670                 }
 671         elsif (/^--strict-warnings$/)
 672                 {
 673                 $strict_warnings = 1;
 674                 }
 675         elsif (/^--debug$/)
 676                 {
 677                 $config{build_type} = "debug";
 678                 }
 679         elsif (/^--release$/)
 680                 {
 681                 $config{build_type} = "release";
 682                 }
 683         elsif (/^386$/)
 684                 { $config{processor}=386; }
 685         elsif (/^fips$/)
 686                 {
 687                 $config{fips}=1;
 688                 }
 689         elsif (/^rsaref$/)
 690                 {
 691                 # No RSAref support any more since it's not needed.
 692                 # The check for the option is there so scripts aren't
 693                 # broken
 694                 }
 695         elsif (/^nofipscanistercheck$/)
 696                 {
 697                 $config{fips} = 1;
 698                 $nofipscanistercheck = 1;
 699                 }
 700         elsif (/^[-+]/)
 701                 {
 702                 if (/^--prefix=(.*)$/)
 703                         {
 704                         $config{prefix}=$1;
 705                         die "Directory given with --prefix MUST be absolute\n"
 706                                 unless file_name_is_absolute($config{prefix});
 707                         }
 708                 elsif (/^--api=(.*)$/)
 709                         {
 710                         $config{api}=$1;
 711                         }
 712                 elsif (/^--libdir=(.*)$/)
 713                         {
 714                         $config{libdir}=$1;
 715                         }
 716                 elsif (/^--openssldir=(.*)$/)
 717                         {
 718                         $config{openssldir}=$1;
 719                         }
 720                 elsif (/^--with-zlib-lib=(.*)$/)
 721                         {
 722                         $withargs{zlib_lib}=$1;
 723                         }
 724                 elsif (/^--with-zlib-include=(.*)$/)
 725                         {
 726                         $withargs{zlib_include}=$1;
 727                         }
 728                 elsif (/^--with-fuzzer-lib=(.*)$/)
 729                         {
 730                         $withargs{fuzzer_lib}=$1;
 731                         }
 732                 elsif (/^--with-fuzzer-include=(.*)$/)
 733                         {
 734                         $withargs{fuzzer_include}=$1;
 735                         }
 736                 elsif (/^--with-fipslibdir=(.*)$/)
 737                         {
 738                         $config{fipslibdir}="$1/";
 739                         }
 740                 elsif (/^--with-baseaddr=(.*)$/)
 741                         {
 742                         $config{baseaddr}="$1";
 743                         }
 744                 elsif (/^--cross-compile-prefix=(.*)$/)
 745                         {
 746                         $config{cross_compile_prefix}=$1;
 747                         }
 748                 elsif (/^--config=(.*)$/)
 749                         {
 750                         read_config $1;
 751                         }
 752                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 753                         {
 754                         $libs.=$_." ";
 755                         }
 756                 elsif (/^-rpath$/ or /^-R$/)
 757                         # -rpath is the OSF1 rpath flag
 758                         # -R is the old Solaris rpath flag
 759                         {
 760                         my $rpath = shift(@argvcopy) || "";
 761                         $rpath .= " " if $rpath ne "";
 762                         $libs.=$_." ".$rpath;
 763                         }
 764                 elsif (/^-static$/)
 765                         {
 766                         $libs.=$_." ";
 767                         $disabled{"dso"} = "forced";
 768                         $disabled{"pic"} = "forced";
 769                         $disabled{"shared"} = "forced";
 770                         $disabled{"threads"} = "forced";
 771                         }
 772                 elsif (/^-D(.*)$/)
 773                         {
 774                         push @user_defines, $1;
 775                         }
 776                 else    # common if (/^[-+]/), just pass down...
 777                         {
 778                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 779                         $user_cflags.=" ".$_;
 780                         }
 781                 }
 782         else
 783                 {
 784                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 785                 $target=$_;
 786                 }
 787         unless ($_ eq $target || /^no-/ || /^disable-/)
 788                 {
 789                 # "no-..." follows later after implied disactivations
 790                 # have been derived.  (Don't take this too seriously,
 791                 # we really only write OPTIONS to the Makefile out of
 792                 # nostalgia.)
 793
 794                 if ($config{options} eq "")
 795                         { $config{options} = $_; }
 796                 else
 797                         { $config{options} .= " ".$_; }
 798                 }
 799
 800         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 801                 die "***** Unsupported api compatibility level: $config{api}\n",
 802         }
 803
 804         if (keys %deprecated_options)
 805                 {
 806                 warn "***** Deprecated options: ",
 807                         join(", ", keys %deprecated_options), "\n";
 808                 }
 809         if (keys %unsupported_options)
 810                 {
 811                 die "***** Unsupported options: ",
 812                         join(", ", keys %unsupported_options), "\n";
 813                 }
 814         }
 815
 816 if ($libs =~ /(^|\s)-Wl,-rpath,/
 817     && !$disabled{shared}
 818     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 819     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 820         "***** any of asan, msan or ubsan\n";
 821 }
 822
 823 if ($config{fips})
 824         {
 825         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 826         }
 827 else
 828         {
 829         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 830         }
 831
 832 my @tocheckfor = (keys %disabled);
 833 while (@tocheckfor) {
 834     my %new_tocheckfor = ();
 835     my @cascade_copy = (@disable_cascades);
 836     while (@cascade_copy) {
 837         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 838         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 839             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 840                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 841             }
 842         }
 843     }
 844     @tocheckfor = (keys %new_tocheckfor);
 845 }
 846
 847 our $die = sub { die @_; };
 848 if ($target eq "TABLE") {
 849     local $die = sub { warn @_; };
 850     foreach (sort keys %table) {
 851         print_table_entry($_, "TABLE");
 852     }
 853     exit 0;
 854 }
 855
 856 if ($target eq "LIST") {
 857     foreach (sort keys %table) {
 858         print $_,"\n" unless $table{$_}->{template};
 859     }
 860     exit 0;
 861 }
 862
 863 if ($target eq "HASH") {
 864     local $die = sub { warn @_; };
 865     print "%table = (\n";
 866     foreach (sort keys %table) {
 867         print_table_entry($_, "HASH");
 868     }
 869     exit 0;
 870 }
 871
 872 # Backward compatibility?
 873 if ($target =~ m/^CygWin32(-.*)$/) {
 874     $target = "Cygwin".$1;
 875 }
 876
 877 foreach (sort (keys %disabled))
 878         {
 879         $config{options} .= " no-$_";
 880
 881         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 882
 883         if (/^dso$/)
 884                 { }
 885         elsif (/^threads$/)
 886                 { }
 887         elsif (/^shared$/)
 888                 { }
 889         elsif (/^pic$/)
 890                 { }
 891         elsif (/^zlib$/)
 892                 { }
 893         elsif (/^dynamic-engine$/)
 894                 { }
 895         elsif (/^makedepend$/)
 896                 { }
 897         elsif (/^zlib-dynamic$/)
 898                 { }
 899         elsif (/^sse2$/)
 900                 { $no_sse2 = 1; }
 901         elsif (/^engine$/)
 902                 {
 903                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 904                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 905                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 906                 print " OPENSSL_NO_ENGINE (skip engines)";
 907                 }
 908         else
 909                 {
 910                 my ($WHAT, $what);
 911
 912                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 913
 914                 # Fix up C macro end names
 915                 $WHAT = "RMD160" if $what eq "ripemd";
 916
 917                 # fix-up crypto/directory name(s)
 918                 $what = "ripemd" if $what eq "rmd160";
 919                 $what = "whrlpool" if $what eq "whirlpool";
 920
 921                 if ($what ne "async" && $what ne "err"
 922                     && grep { $_ eq $what } @{$config{sdirs}})
 923                         {
 924                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 925                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 926
 927                         print " OPENSSL_NO_$WHAT (skip dir)";
 928                         }
 929                 else
 930                         {
 931                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 932                         print " OPENSSL_NO_$WHAT";
 933
 934                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 935                         }
 936                 }
 937
 938         print "\n";
 939         }
 940
 941 print "Configuring for $target\n";
 942 # Support for legacy targets having a name starting with 'debug-'
 943 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 944 if ($d) {
 945     $config{build_type} = "debug";
 946
 947     # If we do not find debug-foo in the table, the target is set to foo.
 948     if (!$table{$target}) {
 949         $target = $t;
 950     }
 951 }
 952 $config{target} = $target;
 953 my %target = resolve_config($target);
 954
 955 &usage if (!%target || $target{template});
 956
 957 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 958 $config{conf_files} = [ sort keys %conf_files ];
 959 %target = ( %{$table{DEFAULTS}}, %target );
 960
 961 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
 962 $target{exe_extension}="";
 963 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 964                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 965 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 966
 967 ($target{shared_extension_simple}=$target{shared_extension})
 968     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 969 $target{dso_extension}=$target{shared_extension_simple};
 970 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 971     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 972
 973
 974 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 975     if $config{cross_compile_prefix} eq "";
 976
 977 # Allow overriding the names of some tools.  USE WITH CARE
 978 # Note: only Unix cares about HASHBANGPERL...  that explains
 979 # the default string.
 980 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
 981 $config{hashbangperl} =
 982     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 983 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 984 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
 985 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 986                    (which("$config{cross_compile_prefix}ranlib") ?
 987                           "\$(CROSS_COMPILE)ranlib" : "true");
 988 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 989 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 990 $target{rc} =
 991     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 992
 993 # Allow overriding the build file name
 994 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 995
 996 # Cache information necessary for reconfiguration
 997 $config{cc} = $target{cc};
 998 $config{cxx} = $target{cxx};
 999 $config{build_file} = $target{build_file};
1000
1001 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
1002 # or release_ attributes.
1003 # Do it in such a way that no spurious space is appended (hence the grep).
1004 $config{defines} = [];
1005 $config{cflags} = "";
1006 $config{cxxflags} = "";
1007 $config{ex_libs} = "";
1008 $config{shared_ldflag} = "";
1009
1010 # Make sure build_scheme is consistent.
1011 $target{build_scheme} = [ $target{build_scheme} ]
1012     if ref($target{build_scheme}) ne "ARRAY";
1013
1014 my ($builder, $builder_platform, @builder_opts) =
1015     @{$target{build_scheme}};
1016
1017 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1018
1019 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1020         {
1021         $config{cflags} .= " -mno-cygwin";
1022         $config{shared_ldflag} .= " -mno-cygwin";
1023         }
1024
1025 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1026         # minimally required architecture flags for assembly modules
1027         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1028         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1029 }
1030
1031 my $no_shared_warn=0;
1032 my $no_user_cflags=0;
1033 my $no_user_defines=0;
1034
1035 # The DSO code currently always implements all functions so that no
1036 # applications will have to worry about that from a compilation point
1037 # of view. However, the "method"s may return zero unless that platform
1038 # has support compiled in for them. Currently each method is enabled
1039 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1040 # string entry into using the following logic;
1041 if (!$disabled{dso} && $target{dso_scheme} ne "")
1042         {
1043         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1044         if ($target{dso_scheme} eq "DLFCN")
1045                 {
1046                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1047                 }
1048         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1049                 {
1050                 unshift @{$config{defines}}, "DSO_DLFCN";
1051                 }
1052         else
1053                 {
1054                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1055                 }
1056         }
1057
1058 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1059
1060 if ($disabled{asm})
1061         {
1062         if ($config{fips})
1063                 {
1064                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
1065                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
1066                 }
1067         }
1068
1069 # If threads aren't disabled, check how possible they are
1070 unless ($disabled{threads}) {
1071     if ($auto_threads) {
1072         # Enabled by default, disable it forcibly if unavailable
1073         if ($target{thread_scheme} eq "(unknown)") {
1074             $disabled{threads} = "unavailable";
1075         }
1076     } else {
1077         # The user chose to enable threads explicitly, let's see
1078         # if there's a chance that's possible
1079         if ($target{thread_scheme} eq "(unknown)") {
1080             # If the user asked for "threads" and we don't have internal
1081             # knowledge how to do it, [s]he is expected to provide any
1082             # system-dependent compiler options that are necessary.  We
1083             # can't truly check that the given options are correct, but
1084             # we expect the user to know what [s]He is doing.
1085             if ($no_user_cflags && $no_user_defines) {
1086                 die "You asked for multi-threading support, but didn't\n"
1087                     ,"provide any system-specific compiler options\n";
1088             }
1089         }
1090     }
1091 }
1092
1093 # If threads still aren't disabled, add a C macro to ensure the source
1094 # code knows about it.  Any other flag is taken care of by the configs.
1095 unless($disabled{threads}) {
1096     foreach (("defines", "openssl_thread_defines")) {
1097         push @{$config{$_}}, "OPENSSL_THREADS";
1098     }
1099 }
1100
1101 # With "deprecated" disable all deprecated features.
1102 if (defined($disabled{"deprecated"})) {
1103         $config{api} = $maxapi;
1104 }
1105
1106 if ($target{shared_target} eq "")
1107         {
1108         $no_shared_warn = 1
1109             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1110                 && !$config{fips});
1111         $disabled{shared} = "no-shared-target";
1112         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1113             "no-shared-target";
1114         }
1115
1116 if ($disabled{"dynamic-engine"}) {
1117         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1118         $config{dynamic_engines} = 0;
1119 } else {
1120         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1121         $config{dynamic_engines} = 1;
1122 }
1123
1124 unless ($disabled{asan}) {
1125     $config{cflags} .= "-fsanitize=address ";
1126 }
1127
1128 unless ($disabled{ubsan}) {
1129     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1130     # platforms.
1131     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1132 }
1133
1134 unless ($disabled{msan}) {
1135   $config{cflags} .= "-fsanitize=memory ";
1136 }
1137
1138 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1139         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1140     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1141 }
1142 #
1143 # Platform fix-ups
1144 #
1145
1146 # This saves the build files from having to check
1147 if ($disabled{pic})
1148         {
1149         $target{shared_cflag} = $target{shared_ldflag} =
1150                 $target{shared_rcflag} = "";
1151         }
1152 else
1153         {
1154         push @{$config{defines}}, "OPENSSL_PIC";
1155         }
1156
1157 if ($target{sys_id} ne "")
1158         {
1159         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1160         }
1161
1162 unless ($disabled{asm}) {
1163     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1164     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1165
1166     # bn-586 is the only one implementing bn_*_part_words
1167     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1168     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1169
1170     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1171     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1172     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1173
1174     if ($config{fips}) {
1175         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1176     }
1177
1178     if ($target{sha1_asm_src}) {
1179         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1180         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1181         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1182     }
1183     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1184         push @{$config{defines}}, "RC4_ASM";
1185     }
1186     if ($target{md5_asm_src}) {
1187         push @{$config{defines}}, "MD5_ASM";
1188     }
1189     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1190     if ($target{rmd160_asm_src}) {
1191         push @{$config{defines}}, "RMD160_ASM";
1192     }
1193     if ($target{aes_asm_src}) {
1194         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1195         # aes-ctr.fake is not a real file, only indication that assembler
1196         # module implements AES_ctr32_encrypt...
1197         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1198         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1199         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1200         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1201         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1202         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1203     }
1204     if ($target{wp_asm_src} =~ /mmx/) {
1205         if ($config{processor} eq "386") {
1206             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1207         } elsif (!$disabled{"whirlpool"}) {
1208             push @{$config{defines}}, "WHIRLPOOL_ASM";
1209         }
1210     }
1211     if ($target{modes_asm_src} =~ /ghash-/) {
1212         push @{$config{defines}}, "GHASH_ASM";
1213     }
1214     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1215         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1216     }
1217     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1218         push @{$config{defines}}, "PADLOCK_ASM";
1219     }
1220     if ($target{poly1305_asm_src} ne "") {
1221         push @{$config{defines}}, "POLY1305_ASM";
1222     }
1223 }
1224
1225 my $ecc = $target{cc};
1226 if ($^O ne "VMS" && !$disabled{makedepend}) {
1227     # Is the compiler gcc or clang?  $ecc is used below to see if
1228     # error-checking can be turned on.
1229     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1230     open(PIPE, "$ccpcc --version 2>&1 |");
1231     my $lines = 2;
1232     while ( <PIPE> ) {
1233         # Find the version number and save the major.
1234         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1235         my $compiler_major = $1;
1236         # We know that GNU C version 3 and up as well as all clang
1237         # versions support dependency generation
1238         $config{makedepprog} = $ccpcc
1239             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1240         $ecc = "clang" if /clang/;
1241         $ecc = "gcc" if /gcc/;
1242         last if ($config{makedepprog} || !$lines--);
1243     }
1244     close(PIPE);
1245
1246     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1247     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1248 }
1249
1250
1251
1252 # Deal with bn_ops ###################################################
1253
1254 $config{bn_ll}                  =0;
1255 $config{export_var_as_fn}       =0;
1256 my $def_int="unsigned int";
1257 $config{rc4_int}                =$def_int;
1258 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1259
1260 my $count = 0;
1261 foreach (sort split(/\s+/,$target{bn_ops})) {
1262     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1263     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1264     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1265     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1266     ($config{b64l},$config{b64},$config{b32})
1267         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1268     ($config{b64l},$config{b64},$config{b32})
1269         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1270     ($config{b64l},$config{b64},$config{b32})
1271         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1272 }
1273 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1274     if $count > 1;
1275
1276
1277 # Hack cflags for better warnings (dev option) #######################
1278
1279 # "Stringify" the C flags string.  This permits it to be made part of a string
1280 # and works as well on command lines.
1281 $config{cflags} =~ s/([\\\"])/\\$1/g;
1282
1283 if (defined($config{api})) {
1284     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1285     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1286     push @{$config{defines}}, $apiflag;
1287 }
1288
1289 if ($strict_warnings)
1290         {
1291         my $wopt;
1292         die "ERROR --strict-warnings requires gcc or clang"
1293             unless $ecc eq 'gcc' || $ecc eq 'clang';
1294         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1295                 {
1296                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1297                 }
1298         if ($ecc eq "clang")
1299                 {
1300                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1301                         {
1302                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1303                         }
1304                 }
1305         }
1306
1307 unless ($disabled{"crypto-mdebug-backtrace"})
1308         {
1309         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1310                 {
1311                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1312                 }
1313         if ($target =~ /^BSD-/)
1314                 {
1315                 $config{ex_libs} .= " -lexecinfo";
1316                 }
1317         }
1318
1319 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1320 else                    { $no_user_cflags=1;  }
1321 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1322 else               { $no_user_defines=1;    }
1323
1324 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1325
1326 unless ($disabled{afalgeng}) {
1327     $config{afalgeng}="";
1328     if ($target =~ m/^linux/) {
1329         my $minver = 4*10000 + 1*100 + 0;
1330         if ($config{cross_compile_prefix} eq "") {
1331             my $verstr = `uname -r`;
1332             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1333             ($mi2) = $mi2 =~ /(\d+)/;
1334             my $ver = $ma*10000 + $mi1*100 + $mi2;
1335             if ($ver < $minver) {
1336                 $disabled{afalgeng} = "too-old-kernel";
1337             } else {
1338                 push @{$config{engdirs}}, "afalg";
1339             }
1340         } else {
1341             $disabled{afalgeng} = "cross-compiling";
1342         }
1343     } else {
1344         $disabled{afalgeng}  = "not-linux";
1345     }
1346 }
1347
1348 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1349
1350 # If we use the unified build, collect information from build.info files
1351 my %unified_info = ();
1352
1353 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1354 if ($builder eq "unified") {
1355     use lib catdir(dirname(__FILE__),"util");
1356     use with_fallback qw(Text::Template);
1357
1358     sub cleandir {
1359         my $base = shift;
1360         my $dir = shift;
1361         my $relativeto = shift || ".";
1362
1363         $dir = catdir($base,$dir) unless isabsolute($dir);
1364
1365         # Make sure the directories we're building in exists
1366         mkpath($dir);
1367
1368         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1369         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1370         return $res;
1371     }
1372
1373     sub cleanfile {
1374         my $base = shift;
1375         my $file = shift;
1376         my $relativeto = shift || ".";
1377
1378         $file = catfile($base,$file) unless isabsolute($file);
1379
1380         my $d = dirname($file);
1381         my $f = basename($file);
1382
1383         # Make sure the directories we're building in exists
1384         mkpath($d);
1385
1386         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1387         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1388         return $res;
1389     }
1390
1391     # Store the name of the template file we will build the build file from
1392     # in %config.  This may be useful for the build file itself.
1393     my @build_file_template_names =
1394         ( $builder_platform."-".$target{build_file}.".tmpl",
1395           $target{build_file}.".tmpl" );
1396     my @build_file_templates = ();
1397
1398     # First, look in the user provided directory, if given
1399     if (defined $ENV{$local_config_envname}) {
1400         @build_file_templates =
1401             map {
1402                 if ($^O eq 'VMS') {
1403                     # VMS environment variables are logical names,
1404                     # which can be used as is
1405                     $local_config_envname . ':' . $_;
1406                 } else {
1407                     catfile($ENV{$local_config_envname}, $_);
1408                 }
1409             }
1410             @build_file_template_names;
1411     }
1412     # Then, look in our standard directory
1413     push @build_file_templates,
1414         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1415           @build_file_template_names );
1416
1417     my $build_file_template;
1418     for $_ (@build_file_templates) {
1419         $build_file_template = $_;
1420         last if -f $build_file_template;
1421
1422         $build_file_template = undef;
1423     }
1424     if (!defined $build_file_template) {
1425         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1426     }
1427     $config{build_file_templates}
1428       = [ $build_file_template,
1429           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1430                     $blddir) ];
1431
1432     my @build_infos = ( [ ".", "build.info" ] );
1433     foreach (@{$config{dirs}}) {
1434         push @build_infos, [ $_, "build.info" ]
1435             if (-f catfile($srcdir, $_, "build.info"));
1436     }
1437     foreach (@{$config{sdirs}}) {
1438         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1439             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1440     }
1441     foreach (@{$config{engdirs}}) {
1442         push @build_infos, [ catdir("engines", $_), "build.info" ]
1443             if (-f catfile($srcdir, "engines", $_, "build.info"));
1444     }
1445     foreach (@{$config{tdirs}}) {
1446         push @build_infos, [ catdir("test", $_), "build.info" ]
1447             if (-f catfile($srcdir, "test", $_, "build.info"));
1448     }
1449
1450     $config{build_infos} = [ ];
1451
1452     foreach (@build_infos) {
1453         my $sourced = catdir($srcdir, $_->[0]);
1454         my $buildd = catdir($blddir, $_->[0]);
1455
1456         mkpath($buildd);
1457
1458         my $f = $_->[1];
1459         # The basic things we're trying to build
1460         my @programs = ();
1461         my @programs_install = ();
1462         my @libraries = ();
1463         my @libraries_install = ();
1464         my @engines = ();
1465         my @engines_install = ();
1466         my @scripts = ();
1467         my @scripts_install = ();
1468         my @extra = ();
1469         my @overrides = ();
1470         my @intermediates = ();
1471         my @rawlines = ();
1472
1473         my %ordinals = ();
1474         my %sources = ();
1475         my %shared_sources = ();
1476         my %includes = ();
1477         my %depends = ();
1478         my %renames = ();
1479         my %sharednames = ();
1480         my %generate = ();
1481
1482         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1483         my $template = Text::Template->new(TYPE => 'FILE',
1484                                            SOURCE => catfile($sourced, $f));
1485         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1486         my @text =
1487             split /^/m,
1488             $template->fill_in(HASH => { config => \%config,
1489                                          target => \%target,
1490                                          disabled => \%disabled,
1491                                          withargs => \%withargs,
1492                                          builddir => abs2rel($buildd, $blddir),
1493                                          sourcedir => abs2rel($sourced, $blddir),
1494                                          buildtop => abs2rel($blddir, $blddir),
1495                                          sourcetop => abs2rel($srcdir, $blddir) },
1496                                DELIMITERS => [ "{-", "-}" ]);
1497
1498         # The top item of this stack has the following values
1499         # -2 positive already run and we found ELSE (following ELSIF should fail)
1500         # -1 positive already run (skip until ENDIF)
1501         # 0 negatives so far (if we're at a condition, check it)
1502         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1503         # 2 positive ELSE (following ELSIF should fail)
1504         my @skip = ();
1505         collect_information(
1506             collect_from_array([ @text ],
1507                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1508                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1509             # Info we're looking for
1510             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1511             => sub {
1512                 if (! @skip || $skip[$#skip] > 0) {
1513                     push @skip, !! $1;
1514                 } else {
1515                     push @skip, -1;
1516                 }
1517             },
1518             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1519             => sub { die "ELSIF out of scope" if ! @skip;
1520                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1521                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1522                      $skip[$#skip] = !! $1
1523                          if $skip[$#skip] == 0; },
1524             qr/^\s*ELSE\s*$/
1525             => sub { die "ELSE out of scope" if ! @skip;
1526                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1527                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1528             qr/^\s*ENDIF\s*$/
1529             => sub { die "ENDIF out of scope" if ! @skip;
1530                      pop @skip; },
1531             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1532             => sub {
1533                 if (!@skip || $skip[$#skip] > 0) {
1534                     my $install = $1;
1535                     my @x = tokenize($2);
1536                     push @programs, @x;
1537                     push @programs_install, @x unless $install;
1538                 }
1539             },
1540             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1541             => sub {
1542                 if (!@skip || $skip[$#skip] > 0) {
1543                     my $install = $1;
1544                     my @x = tokenize($2);
1545                     push @libraries, @x;
1546                     push @libraries_install, @x unless $install;
1547                 }
1548             },
1549             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1550             => sub {
1551                 if (!@skip || $skip[$#skip] > 0) {
1552                     my $install = $1;
1553                     my @x = tokenize($2);
1554                     push @engines, @x;
1555                     push @engines_install, @x unless $install;
1556                 }
1557             },
1558             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1559             => sub {
1560                 if (!@skip || $skip[$#skip] > 0) {
1561                     my $install = $1;
1562                     my @x = tokenize($2);
1563                     push @scripts, @x;
1564                     push @scripts_install, @x unless $install;
1565                 }
1566             },
1567             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1568             => sub { push @extra, tokenize($1)
1569                          if !@skip || $skip[$#skip] > 0 },
1570             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1571             => sub { push @overrides, tokenize($1)
1572                          if !@skip || $skip[$#skip] > 0 },
1573
1574             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1575             => sub { push @{$ordinals{$1}}, tokenize($2)
1576                          if !@skip || $skip[$#skip] > 0 },
1577             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1578             => sub { push @{$sources{$1}}, tokenize($2)
1579                          if !@skip || $skip[$#skip] > 0 },
1580             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1581             => sub { push @{$shared_sources{$1}}, tokenize($2)
1582                          if !@skip || $skip[$#skip] > 0 },
1583             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1584             => sub { push @{$includes{$1}}, tokenize($2)
1585                          if !@skip || $skip[$#skip] > 0 },
1586             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1587             => sub { push @{$depends{$1}}, tokenize($2)
1588                          if !@skip || $skip[$#skip] > 0 },
1589             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1590             => sub { push @{$generate{$1}}, $2
1591                          if !@skip || $skip[$#skip] > 0 },
1592             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1593             => sub { push @{$renames{$1}}, tokenize($2)
1594                          if !@skip || $skip[$#skip] > 0 },
1595             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1596             => sub { push @{$sharednames{$1}}, tokenize($2)
1597                          if !@skip || $skip[$#skip] > 0 },
1598             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1599             => sub {
1600                 my $lineiterator = shift;
1601                 my $target_kind = $1;
1602                 while (defined $lineiterator->()) {
1603                     s|\R$||;
1604                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1605                         die "ENDRAW doesn't match BEGINRAW"
1606                             if $1 ne $target_kind;
1607                         last;
1608                     }
1609                     next if @skip && $skip[$#skip] <= 0;
1610                     push @rawlines,  $_
1611                         if ($target_kind eq $target{build_file}
1612                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1613                 }
1614             },
1615             qr/^\s*(?:#.*)?$/ => sub { },
1616             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1617             "BEFORE" => sub {
1618                 if ($buildinfo_debug) {
1619                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1620                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1621                 }
1622             },
1623             "AFTER" => sub {
1624                 if ($buildinfo_debug) {
1625                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1626                 }
1627             },
1628             );
1629         die "runaway IF?" if (@skip);
1630
1631         foreach (keys %renames) {
1632             die "$_ renamed to more than one thing: "
1633                 ,join(" ", @{$renames{$_}}),"\n"
1634                 if scalar @{$renames{$_}} > 1;
1635             my $dest = cleanfile($buildd, $_, $blddir);
1636             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1637             die "$dest renamed to more than one thing: "
1638                 ,$unified_info{rename}->{$dest}, $to
1639                 unless !defined($unified_info{rename}->{$dest})
1640                 or $unified_info{rename}->{$dest} eq $to;
1641             $unified_info{rename}->{$dest} = $to;
1642         }
1643
1644         foreach (@programs) {
1645             my $program = cleanfile($buildd, $_, $blddir);
1646             if ($unified_info{rename}->{$program}) {
1647                 $program = $unified_info{rename}->{$program};
1648             }
1649             $unified_info{programs}->{$program} = 1;
1650         }
1651
1652         foreach (@programs_install) {
1653             my $program = cleanfile($buildd, $_, $blddir);
1654             if ($unified_info{rename}->{$program}) {
1655                 $program = $unified_info{rename}->{$program};
1656             }
1657             $unified_info{install}->{programs}->{$program} = 1;
1658         }
1659
1660         foreach (@libraries) {
1661             my $library = cleanfile($buildd, $_, $blddir);
1662             if ($unified_info{rename}->{$library}) {
1663                 $library = $unified_info{rename}->{$library};
1664             }
1665             $unified_info{libraries}->{$library} = 1;
1666         }
1667
1668         foreach (@libraries_install) {
1669             my $library = cleanfile($buildd, $_, $blddir);
1670             if ($unified_info{rename}->{$library}) {
1671                 $library = $unified_info{rename}->{$library};
1672             }
1673             $unified_info{install}->{libraries}->{$library} = 1;
1674         }
1675
1676         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1677 ENGINES can only be used if configured with 'dynamic-engine'.
1678 This is usually a fault in a build.info file.
1679 EOF
1680         foreach (@engines) {
1681             my $library = cleanfile($buildd, $_, $blddir);
1682             if ($unified_info{rename}->{$library}) {
1683                 $library = $unified_info{rename}->{$library};
1684             }
1685             $unified_info{engines}->{$library} = 1;
1686         }
1687
1688         foreach (@engines_install) {
1689             my $library = cleanfile($buildd, $_, $blddir);
1690             if ($unified_info{rename}->{$library}) {
1691                 $library = $unified_info{rename}->{$library};
1692             }
1693             $unified_info{install}->{engines}->{$library} = 1;
1694         }
1695
1696         foreach (@scripts) {
1697             my $script = cleanfile($buildd, $_, $blddir);
1698             if ($unified_info{rename}->{$script}) {
1699                 $script = $unified_info{rename}->{$script};
1700             }
1701             $unified_info{scripts}->{$script} = 1;
1702         }
1703
1704         foreach (@scripts_install) {
1705             my $script = cleanfile($buildd, $_, $blddir);
1706             if ($unified_info{rename}->{$script}) {
1707                 $script = $unified_info{rename}->{$script};
1708             }
1709             $unified_info{install}->{scripts}->{$script} = 1;
1710         }
1711
1712         foreach (@extra) {
1713             my $extra = cleanfile($buildd, $_, $blddir);
1714             $unified_info{extra}->{$extra} = 1;
1715         }
1716
1717         foreach (@overrides) {
1718             my $override = cleanfile($buildd, $_, $blddir);
1719             $unified_info{overrides}->{$override} = 1;
1720         }
1721
1722         push @{$unified_info{rawlines}}, @rawlines;
1723
1724         unless ($disabled{shared}) {
1725             # Check sharednames.
1726             foreach (keys %sharednames) {
1727                 my $dest = cleanfile($buildd, $_, $blddir);
1728                 if ($unified_info{rename}->{$dest}) {
1729                     $dest = $unified_info{rename}->{$dest};
1730                 }
1731                 die "shared_name for $dest with multiple values: "
1732                     ,join(" ", @{$sharednames{$_}}),"\n"
1733                     if scalar @{$sharednames{$_}} > 1;
1734                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1735                 die "shared_name found for a library $dest that isn't defined\n"
1736                     unless $unified_info{libraries}->{$dest};
1737                 die "shared_name for $dest with multiple values: "
1738                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1739                     unless !defined($unified_info{sharednames}->{$dest})
1740                     or $unified_info{sharednames}->{$dest} eq $to;
1741                 $unified_info{sharednames}->{$dest} = $to;
1742             }
1743
1744             # Additionally, we set up sharednames for libraries that don't
1745             # have any, as themselves.
1746             foreach (keys %{$unified_info{libraries}}) {
1747                 if (!defined $unified_info{sharednames}->{$_}) {
1748                     $unified_info{sharednames}->{$_} = $_
1749                 }
1750             }
1751         }
1752
1753         foreach (keys %ordinals) {
1754             my $dest = $_;
1755             my $ddest = cleanfile($buildd, $_, $blddir);
1756             if ($unified_info{rename}->{$ddest}) {
1757                 $ddest = $unified_info{rename}->{$ddest};
1758             }
1759             foreach (@{$ordinals{$dest}}) {
1760                 my %known_ordinals =
1761                     (
1762                      crypto =>
1763                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1764                      ssl =>
1765                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1766                     );
1767                 my $o = $known_ordinals{$_};
1768                 die "Ordinals for $ddest defined more than once\n"
1769                     if $unified_info{ordinals}->{$ddest};
1770                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1771             }
1772         }
1773
1774         foreach (keys %sources) {
1775             my $dest = $_;
1776             my $ddest = cleanfile($buildd, $_, $blddir);
1777             if ($unified_info{rename}->{$ddest}) {
1778                 $ddest = $unified_info{rename}->{$ddest};
1779             }
1780             foreach (@{$sources{$dest}}) {
1781                 my $s = cleanfile($sourced, $_, $blddir);
1782
1783                 # If it isn't in the source tree, we assume it's generated
1784                 # in the build tree
1785                 if (! -f $s) {
1786                     $s = cleanfile($buildd, $_, $blddir);
1787                 }
1788                 # We recognise C++, C and asm files
1789                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1790                     my $o = $_;
1791                     $o =~ s/\.[csS]$/.o/; # C and assembler
1792                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1793                     $o = cleanfile($buildd, $o, $blddir);
1794                     $unified_info{sources}->{$ddest}->{$o} = 1;
1795                     $unified_info{sources}->{$o}->{$s} = 1;
1796                 } else {
1797                     $unified_info{sources}->{$ddest}->{$s} = 1;
1798                 }
1799             }
1800         }
1801
1802         foreach (keys %shared_sources) {
1803             my $dest = $_;
1804             my $ddest = cleanfile($buildd, $_, $blddir);
1805             if ($unified_info{rename}->{$ddest}) {
1806                 $ddest = $unified_info{rename}->{$ddest};
1807             }
1808             foreach (@{$shared_sources{$dest}}) {
1809                 my $s = cleanfile($sourced, $_, $blddir);
1810
1811                 # If it isn't in the source tree, we assume it's generated
1812                 # in the build tree
1813                 if (! -f $s) {
1814                     $s = cleanfile($buildd, $_, $blddir);
1815                 }
1816                 # We recognise C++, C and asm files
1817                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1818                     my $o = $_;
1819                     $o =~ s/\.[csS]$/.o/; # C and assembler
1820                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1821                     $o = cleanfile($buildd, $o, $blddir);
1822                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1823                     $unified_info{sources}->{$o}->{$s} = 1;
1824                 } else {
1825                     die "unrecognised source file type for shared library: $s\n";
1826                 }
1827             }
1828         }
1829
1830         foreach (keys %generate) {
1831             my $dest = $_;
1832             my $ddest = cleanfile($buildd, $_, $blddir);
1833             if ($unified_info{rename}->{$ddest}) {
1834                 $ddest = $unified_info{rename}->{$ddest};
1835             }
1836             die "more than one generator for $dest: "
1837                     ,join(" ", @{$generate{$_}}),"\n"
1838                     if scalar @{$generate{$_}} > 1;
1839             my @generator = split /\s+/, $generate{$dest}->[0];
1840             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1841             $unified_info{generate}->{$ddest} = [ @generator ];
1842         }
1843
1844         foreach (keys %depends) {
1845             my $dest = $_;
1846             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1847
1848             # If the destination doesn't exist in source, it can only be
1849             # a generated file in the build tree.
1850             if ($ddest ne "" && ! -f $ddest) {
1851                 $ddest = cleanfile($buildd, $_, $blddir);
1852                 if ($unified_info{rename}->{$ddest}) {
1853                     $ddest = $unified_info{rename}->{$ddest};
1854                 }
1855             }
1856             foreach (@{$depends{$dest}}) {
1857                 my $d = cleanfile($sourced, $_, $blddir);
1858
1859                 # If we know it's generated, or assume it is because we can't
1860                 # find it in the source tree, we set file we depend on to be
1861                 # in the build tree rather than the source tree, and assume
1862                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1863                 # section or in the Makefile template.
1864                 if (! -f $d
1865                     || (grep { $d eq $_ }
1866                         map { cleanfile($srcdir, $_, $blddir) }
1867                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1868                     $d = cleanfile($buildd, $_, $blddir);
1869                 }
1870                 # Take note if the file to depend on is being renamed
1871                 # Take extra care with files ending with .a, they should
1872                 # be treated without that extension, and the extension
1873                 # should be added back after treatment.
1874                 $d =~ /(\.a)?$/;
1875                 my $e = $1 // "";
1876                 $d = $`;
1877                 if ($unified_info{rename}->{$d}) {
1878                     $d = $unified_info{rename}->{$d};
1879                 }
1880                 $d .= $e;
1881                 $unified_info{depends}->{$ddest}->{$d} = 1;
1882                 # If we depend on a header file or a perl module, let's make
1883                 # sure it can get included
1884                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1885                     my $i = dirname($d);
1886                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1887                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1888                 }
1889             }
1890         }
1891
1892         foreach (keys %includes) {
1893             my $dest = $_;
1894             my $ddest = cleanfile($sourced, $_, $blddir);
1895
1896             # If the destination doesn't exist in source, it can only be
1897             # a generated file in the build tree.
1898             if (! -f $ddest) {
1899                 $ddest = cleanfile($buildd, $_, $blddir);
1900                 if ($unified_info{rename}->{$ddest}) {
1901                     $ddest = $unified_info{rename}->{$ddest};
1902                 }
1903             }
1904             foreach (@{$includes{$dest}}) {
1905                 my $is = cleandir($sourced, $_, $blddir);
1906                 my $ib = cleandir($buildd, $_, $blddir);
1907                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1908                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1909                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1910                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1911             }
1912         }
1913     }
1914
1915     ### Make unified_info a bit more efficient
1916     # One level structures
1917     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1918         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1919     }
1920     # Two level structures
1921     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1922         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1923             $unified_info{$l1}->{$l2} =
1924                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1925         }
1926     }
1927     # Includes
1928     foreach my $dest (sort keys %{$unified_info{includes}}) {
1929         if (defined($unified_info{includes}->{$dest}->{build})) {
1930             my @source_includes =
1931                 ( @{$unified_info{includes}->{$dest}->{source}} );
1932             $unified_info{includes}->{$dest} =
1933                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1934             foreach my $inc (@source_includes) {
1935                 push @{$unified_info{includes}->{$dest}}, $inc
1936                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1937             }
1938         } else {
1939             $unified_info{includes}->{$dest} =
1940                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1941         }
1942     }
1943 }
1944
1945 # For the schemes that need it, we provide the old *_obj configs
1946 # from the *_asm_obj ones
1947 foreach (grep /_(asm|aux)_src$/, keys %target) {
1948     my $src = $_;
1949     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1950     $target{$obj} = $target{$src};
1951     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1952     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1953 }
1954
1955 # Write down our configuration where it fits #########################
1956
1957 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1958 print OUT <<"EOF";
1959 package configdata;
1960
1961 use strict;
1962 use warnings;
1963
1964 use Exporter;
1965 #use vars qw(\@ISA \@EXPORT);
1966 our \@ISA = qw(Exporter);
1967 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1968
1969 EOF
1970 print OUT "our %config = (\n";
1971 foreach (sort keys %config) {
1972     if (ref($config{$_}) eq "ARRAY") {
1973         print OUT "  ", $_, " => [ ", join(", ",
1974                                            map { quotify("perl", $_) }
1975                                            @{$config{$_}}), " ],\n";
1976     } else {
1977         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1978     }
1979 }
1980 print OUT <<"EOF";
1981 );
1982
1983 EOF
1984 print OUT "our %target = (\n";
1985 foreach (sort keys %target) {
1986     if (ref($target{$_}) eq "ARRAY") {
1987         print OUT "  ", $_, " => [ ", join(", ",
1988                                            map { quotify("perl", $_) }
1989                                            @{$target{$_}}), " ],\n";
1990     } else {
1991         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1992     }
1993 }
1994 print OUT <<"EOF";
1995 );
1996
1997 EOF
1998 print OUT "our \%available_protocols = (\n";
1999 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2000 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2001 print OUT <<"EOF";
2002 );
2003
2004 EOF
2005 print OUT "our \@disablables = (\n";
2006 foreach (@disablables) {
2007     print OUT "  ", quotify("perl", $_), ",\n";
2008 }
2009 print OUT <<"EOF";
2010 );
2011
2012 EOF
2013 print OUT "our \%disabled = (\n";
2014 foreach (sort keys %disabled) {
2015     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2016 }
2017 print OUT <<"EOF";
2018 );
2019
2020 EOF
2021 print OUT "our %withargs = (\n";
2022 foreach (sort keys %withargs) {
2023     if (ref($withargs{$_}) eq "ARRAY") {
2024         print OUT "  ", $_, " => [ ", join(", ",
2025                                            map { quotify("perl", $_) }
2026                                            @{$withargs{$_}}), " ],\n";
2027     } else {
2028         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2029     }
2030 }
2031 print OUT <<"EOF";
2032 );
2033
2034 EOF
2035 if ($builder eq "unified") {
2036     my $recurse;
2037     $recurse = sub {
2038         my $indent = shift;
2039         foreach (@_) {
2040             if (ref $_ eq "ARRAY") {
2041                 print OUT " "x$indent, "[\n";
2042                 foreach (@$_) {
2043                     $recurse->($indent + 4, $_);
2044                 }
2045                 print OUT " "x$indent, "],\n";
2046             } elsif (ref $_ eq "HASH") {
2047                 my %h = %$_;
2048                 print OUT " "x$indent, "{\n";
2049                 foreach (sort keys %h) {
2050                     if (ref $h{$_} eq "") {
2051                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2052                     } else {
2053                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2054                         $recurse->($indent + 8, $h{$_});
2055                     }
2056                 }
2057                 print OUT " "x$indent, "},\n";
2058             } else {
2059                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2060             }
2061         }
2062     };
2063     print OUT "our %unified_info = (\n";
2064     foreach (sort keys %unified_info) {
2065         if (ref $unified_info{$_} eq "") {
2066             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2067         } else {
2068             print OUT " "x4, quotify("perl", $_), " =>\n";
2069             $recurse->(8, $unified_info{$_});
2070         }
2071     }
2072     print OUT <<"EOF";
2073 );
2074
2075 EOF
2076 }
2077 print OUT "1;\n";
2078 close(OUT);
2079
2080 print "\n";
2081 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2082 print "PERL          =$config{perl}\n";
2083 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2084 print "HASHBANGPERL  =$config{hashbangperl}\n";
2085 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2086 print "CFLAG         =$target{cflags} $config{cflags}\n";
2087 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2088     if defined $target{cxx};
2089 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2090     if defined $target{cxx};
2091 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2092 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2093 #                             "$config{cross_compile_prefix}ranlib" :
2094 #                             "$target{ranlib}", "\n";
2095 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2096
2097 my %builders = (
2098     unified => sub {
2099         run_dofile(catfile($blddir, $target{build_file}),
2100                    @{$config{build_file_templates}});
2101     },
2102     );
2103
2104 $builders{$builder}->($builder_platform, @builder_opts);
2105
2106 print <<"EOF" if ($disabled{threads} eq "unavailable");
2107
2108 The library could not be configured for supporting multi-threaded
2109 applications as the compiler options required on this system are not known.
2110 See file INSTALL for details if you need multi-threading.
2111 EOF
2112
2113 print <<"EOF" if ($no_shared_warn);
2114
2115 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2116 platform, so we will pretend you gave the option 'no-pic', which also disables
2117 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2118 or position independent code, please let us know (but please first make sure
2119 you have tried with a current version of OpenSSL).
2120 EOF
2121
2122 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2123
2124 WARNING: there are indications that another build was made in the source
2125 directory.  This build may have picked up artifacts from that build, the
2126 safest course of action is to clean the source directory and redo this
2127 configuration.
2128 EOF
2129
2130 exit(0);
2131
2132 ######################################################################
2133 #
2134 # Helpers and utility functions
2135 #
2136
2137 # Configuration file reading #########################################
2138
2139 # Note: All of the helper functions are for lazy evaluation.  They all
2140 # return a CODE ref, which will return the intended value when evaluated.
2141 # Thus, whenever there's mention of a returned value, it's about that
2142 # intended value.
2143
2144 # Helper function to implement conditional inheritance depending on the
2145 # value of $disabled{asm}.  Used in inherit_from values as follows:
2146 #
2147 #      inherit_from => [ "template", asm("asm_tmpl") ]
2148 #
2149 sub asm {
2150     my @x = @_;
2151     sub {
2152         $disabled{asm} ? () : @x;
2153     }
2154 }
2155
2156 # Helper function to implement conditional value variants, with a default
2157 # plus additional values based on the value of $config{build_type}.
2158 # Arguments are given in hash table form:
2159 #
2160 #       picker(default => "Basic string: ",
2161 #              debug   => "debug",
2162 #              release => "release")
2163 #
2164 # When configuring with --debug, the resulting string will be
2165 # "Basic string: debug", and when not, it will be "Basic string: release"
2166 #
2167 # This can be used to create variants of sets of flags according to the
2168 # build type:
2169 #
2170 #       cflags => picker(default => "-Wall",
2171 #                        debug   => "-g -O0",
2172 #                        release => "-O3")
2173 #
2174 sub picker {
2175     my %opts = @_;
2176     return sub { add($opts{default} || (),
2177                      $opts{$config{build_type}} || ())->(); }
2178 }
2179
2180 # Helper function to combine several values of different types into one.
2181 # This is useful if you want to combine a string with the result of a
2182 # lazy function, such as:
2183 #
2184 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2185 #
2186 sub combine {
2187     my @stuff = @_;
2188     return sub { add(@stuff)->(); }
2189 }
2190
2191 # Helper function to implement conditional values depending on the value
2192 # of $disabled{threads}.  Can be used as follows:
2193 #
2194 #       cflags => combine("-Wall", threads("-pthread"))
2195 #
2196 sub threads {
2197     my @flags = @_;
2198     return sub { add($disabled{threads} ? () : @flags)->(); }
2199 }
2200
2201
2202
2203 our $add_called = 0;
2204 # Helper function to implement adding values to already existing configuration
2205 # values.  It handles elements that are ARRAYs, CODEs and scalars
2206 sub _add {
2207     my $separator = shift;
2208
2209     # If there's any ARRAY in the collection of values OR the separator
2210     # is undef, we will return an ARRAY of combined values, otherwise a
2211     # string of joined values with $separator as the separator.
2212     my $found_array = !defined($separator);
2213
2214     my @values =
2215         map {
2216             my $res = $_;
2217             while (ref($res) eq "CODE") {
2218                 $res = $res->();
2219             }
2220             if (defined($res)) {
2221                 if (ref($res) eq "ARRAY") {
2222                     $found_array = 1;
2223                     @$res;
2224                 } else {
2225                     $res;
2226                 }
2227             } else {
2228                 ();
2229             }
2230     } (@_);
2231
2232     $add_called = 1;
2233
2234     if ($found_array) {
2235         [ @values ];
2236     } else {
2237         join($separator, grep { defined($_) && $_ ne "" } @values);
2238     }
2239 }
2240 sub add_before {
2241     my $separator = " ";
2242     if (ref($_[$#_]) eq "HASH") {
2243         my $opts = pop;
2244         $separator = $opts->{separator};
2245     }
2246     my @x = @_;
2247     sub { _add($separator, @x, @_) };
2248 }
2249 sub add {
2250     my $separator = " ";
2251     if (ref($_[$#_]) eq "HASH") {
2252         my $opts = pop;
2253         $separator = $opts->{separator};
2254     }
2255     my @x = @_;
2256     sub { _add($separator, @_, @x) };
2257 }
2258
2259 # configuration reader, evaluates the input file as a perl script and expects
2260 # it to fill %targets with target configurations.  Those are then added to
2261 # %table.
2262 sub read_config {
2263     my $fname = shift;
2264     open(CONFFILE, "< $fname")
2265         or die "Can't open configuration file '$fname'!\n";
2266     my $x = $/;
2267     undef $/;
2268     my $content = <CONFFILE>;
2269     $/ = $x;
2270     close(CONFFILE);
2271     my %targets = ();
2272     {
2273         # Protect certain tables from tampering
2274         local %table = %::table;
2275
2276         eval $content;
2277         warn $@ if $@;
2278     }
2279
2280     # For each target, check that it's configured with a hash table.
2281     foreach (keys %targets) {
2282         if (ref($targets{$_}) ne "HASH") {
2283             if (ref($targets{$_}) eq "") {
2284                 warn "Deprecated target configuration for $_, ignoring...\n";
2285             } else {
2286                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2287             }
2288             delete $targets{$_};
2289         } else {
2290             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2291         }
2292     }
2293
2294     %table = (%table, %targets);
2295
2296 }
2297
2298 # configuration resolver.  Will only resolve all the lazy evaluation
2299 # codeblocks for the chosen target and all those it inherits from,
2300 # recursively
2301 sub resolve_config {
2302     my $target = shift;
2303     my @breadcrumbs = @_;
2304
2305 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2306
2307     if (grep { $_ eq $target } @breadcrumbs) {
2308         die "inherit_from loop!  target backtrace:\n  "
2309             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2310     }
2311
2312     if (!defined($table{$target})) {
2313         warn "Warning! target $target doesn't exist!\n";
2314         return ();
2315     }
2316     # Recurse through all inheritances.  They will be resolved on the
2317     # fly, so when this operation is done, they will all just be a
2318     # bunch of attributes with string values.
2319     # What we get here, though, are keys with references to lists of
2320     # the combined values of them all.  We will deal with lists after
2321     # this stage is done.
2322     my %combined_inheritance = ();
2323     if ($table{$target}->{inherit_from}) {
2324         my @inherit_from =
2325             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2326         foreach (@inherit_from) {
2327             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2328
2329             # 'template' is a marker that's considered private to
2330             # the config that had it.
2331             delete $inherited_config{template};
2332
2333             foreach (keys %inherited_config) {
2334                 if (!$combined_inheritance{$_}) {
2335                     $combined_inheritance{$_} = [];
2336                 }
2337                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2338             }
2339         }
2340     }
2341
2342     # We won't need inherit_from in this target any more, since we've
2343     # resolved all the inheritances that lead to this
2344     delete $table{$target}->{inherit_from};
2345
2346     # Now is the time to deal with those lists.  Here's the place to
2347     # decide what shall be done with those lists, all based on the
2348     # values of the target we're currently dealing with.
2349     # - If a value is a coderef, it will be executed with the list of
2350     #   inherited values as arguments.
2351     # - If the corresponding key doesn't have a value at all or is the
2352     #   empty string, the inherited value list will be run through the
2353     #   default combiner (below), and the result becomes this target's
2354     #   value.
2355     # - Otherwise, this target's value is assumed to be a string that
2356     #   will simply override the inherited list of values.
2357     my $default_combiner = add();
2358
2359     my %all_keys =
2360         map { $_ => 1 } (keys %combined_inheritance,
2361                          keys %{$table{$target}});
2362
2363     sub process_values {
2364         my $object    = shift;
2365         my $inherited = shift;  # Always a [ list ]
2366         my $target    = shift;
2367         my $entry     = shift;
2368
2369         $add_called = 0;
2370
2371         while(ref($object) eq "CODE") {
2372             $object = $object->(@$inherited);
2373         }
2374         if (!defined($object)) {
2375             return ();
2376         }
2377         elsif (ref($object) eq "ARRAY") {
2378             local $add_called;  # To make sure recursive calls don't affect it
2379             return [ map { process_values($_, $inherited, $target, $entry) }
2380                      @$object ];
2381         } elsif (ref($object) eq "") {
2382             return $object;
2383         } else {
2384             die "cannot handle reference type ",ref($object)
2385                 ," found in target ",$target," -> ",$entry,"\n";
2386         }
2387     }
2388
2389     foreach (sort keys %all_keys) {
2390         my $previous = $combined_inheritance{$_};
2391
2392         # Current target doesn't have a value for the current key?
2393         # Assign it the default combiner, the rest of this loop body
2394         # will handle it just like any other coderef.
2395         if (!exists $table{$target}->{$_}) {
2396             $table{$target}->{$_} = $default_combiner;
2397         }
2398
2399         $table{$target}->{$_} = process_values($table{$target}->{$_},
2400                                                $combined_inheritance{$_},
2401                                                $target, $_);
2402         unless(defined($table{$target}->{$_})) {
2403             delete $table{$target}->{$_};
2404         }
2405 #        if ($extra_checks &&
2406 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2407 #            warn "$_ got replaced in $target\n";
2408 #        }
2409     }
2410
2411     # Finally done, return the result.
2412     return %{$table{$target}};
2413 }
2414
2415 sub usage
2416         {
2417         print STDERR $usage;
2418         print STDERR "\npick os/compiler from:\n";
2419         my $j=0;
2420         my $i;
2421         my $k=0;
2422         foreach $i (sort keys %table)
2423                 {
2424                 next if $table{$i}->{template};
2425                 next if $i =~ /^debug/;
2426                 $k += length($i) + 1;
2427                 if ($k > 78)
2428                         {
2429                         print STDERR "\n";
2430                         $k=length($i);
2431                         }
2432                 print STDERR $i . " ";
2433                 }
2434         foreach $i (sort keys %table)
2435                 {
2436                 next if $table{$i}->{template};
2437                 next if $i !~ /^debug/;
2438                 $k += length($i) + 1;
2439                 if ($k > 78)
2440                         {
2441                         print STDERR "\n";
2442                         $k=length($i);
2443                         }
2444                 print STDERR $i . " ";
2445                 }
2446         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2447         exit(1);
2448         }
2449
2450 sub run_dofile
2451 {
2452     my $out = shift;
2453     my @templates = @_;
2454
2455     unlink $out || warn "Can't remove $out, $!"
2456         if -f $out;
2457     foreach (@templates) {
2458         die "Can't open $_, $!" unless -f $_;
2459     }
2460     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2461     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2462     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2463     system($cmd);
2464     exit 1 if $? != 0;
2465     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2466 }
2467
2468 sub which
2469 {
2470     my ($name)=@_;
2471
2472     if (eval { require IPC::Cmd; 1; }) {
2473         IPC::Cmd->import();
2474         return scalar IPC::Cmd::can_run($name);
2475     } else {
2476         # if there is $directories component in splitpath,
2477         # then it's not something to test with $PATH...
2478         return $name if (File::Spec->splitpath($name))[1];
2479
2480         foreach (File::Spec->path()) {
2481             my $fullpath = catfile($_, "$name$target{exe_extension}");
2482             if (-f $fullpath and -x $fullpath) {
2483                 return $fullpath;
2484             }
2485         }
2486     }
2487 }
2488
2489 # Configuration printer ##############################################
2490
2491 sub print_table_entry
2492 {
2493     my $target = shift;
2494     my %target = resolve_config($target);
2495     my $type = shift;
2496
2497     # Don't print the templates
2498     return if $target{template};
2499
2500     my @sequence = (
2501         "sys_id",
2502         "cc",
2503         "cflags",
2504         "defines",
2505         "unistd",
2506         "ld",
2507         "lflags",
2508         "loutflag",
2509         "plib_lflags",
2510         "ex_libs",
2511         "bn_ops",
2512         "apps_aux_src",
2513         "cpuid_asm_src",
2514         "uplink_aux_src",
2515         "bn_asm_src",
2516         "ec_asm_src",
2517         "des_asm_src",
2518         "aes_asm_src",
2519         "bf_asm_src",
2520         "md5_asm_src",
2521         "cast_asm_src",
2522         "sha1_asm_src",
2523         "rc4_asm_src",
2524         "rmd160_asm_src",
2525         "rc5_asm_src",
2526         "wp_asm_src",
2527         "cmll_asm_src",
2528         "modes_asm_src",
2529         "padlock_asm_src",
2530         "chacha_asm_src",
2531         "poly1035_asm_src",
2532         "thread_scheme",
2533         "perlasm_scheme",
2534         "dso_scheme",
2535         "shared_target",
2536         "shared_cflag",
2537         "shared_defines",
2538         "shared_ldflag",
2539         "shared_rcflag",
2540         "shared_extension",
2541         "dso_extension",
2542         "obj_extension",
2543         "exe_extension",
2544         "ranlib",
2545         "ar",
2546         "arflags",
2547         "aroutflag",
2548         "rc",
2549         "rcflags",
2550         "rcoutflag",
2551         "mt",
2552         "mtflags",
2553         "mtinflag",
2554         "mtoutflag",
2555         "multilib",
2556         "build_scheme",
2557         );
2558
2559     if ($type eq "TABLE") {
2560         print "\n";
2561         print "*** $target\n";
2562         foreach (@sequence) {
2563             if (ref($target{$_}) eq "ARRAY") {
2564                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2565             } else {
2566                 printf "\$%-12s = %s\n", $_, $target{$_};
2567             }
2568         }
2569     } elsif ($type eq "HASH") {
2570         my $largest =
2571             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2572         print "    '$target' => {\n";
2573         foreach (@sequence) {
2574             if ($target{$_}) {
2575                 if (ref($target{$_}) eq "ARRAY") {
2576                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2577                 } else {
2578                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2579                 }
2580             }
2581         }
2582         print "    },\n";
2583     }
2584 }
2585
2586 # Utility routines ###################################################
2587
2588 # On VMS, if the given file is a logical name, File::Spec::Functions
2589 # will consider it an absolute path.  There are cases when we want a
2590 # purely syntactic check without checking the environment.
2591 sub isabsolute {
2592     my $file = shift;
2593
2594     # On non-platforms, we just use file_name_is_absolute().
2595     return file_name_is_absolute($file) unless $^O eq "VMS";
2596
2597     # If the file spec includes a device or a directpry spec,
2598     # file_name_is_absolute() is perfectly safe.
2599     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2600
2601     # Here, we know the given file spec isn't absolute
2602     return 0;
2603 }
2604
2605 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2606 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2607 # realpath() requires that at least all path components except the last is an
2608 # existing directory.  On VMS, the last component of the directory spec must
2609 # exist.
2610 sub absolutedir {
2611     my $dir = shift;
2612
2613     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2614     # will return the volume name for the device, no matter what.  Also,
2615     # it will return an incorrect directory spec if the argument is a
2616     # directory that doesn't exist.
2617     if ($^O eq "VMS") {
2618         return rel2abs($dir);
2619     }
2620
2621     # We use realpath() on Unix, since no other will properly clean out
2622     # a directory spec.
2623     use Cwd qw/realpath/;
2624
2625     return realpath($dir);
2626 }
2627
2628 sub quotify {
2629     my %processors = (
2630         perl    => sub { my $x = shift;
2631                          $x =~ s/([\\\$\@"])/\\$1/g;
2632                          return '"'.$x.'"'; },
2633         maybeshell => sub { my $x = shift;
2634                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2635                             if ($x ne $y || $x =~ m|\s|) {
2636                                 return '"'.$y.'"';
2637                             } else {
2638                                 return $x;
2639                             }
2640                         },
2641         );
2642     my $for = shift;
2643     my $processor =
2644         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2645
2646     return map { $processor->($_); } @_;
2647 }
2648
2649 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2650 # $filename is a file name to read from
2651 # $line_concat_cond_re is a regexp detecting a line continuation ending
2652 # $line_concat is a CODEref that takes care of concatenating two lines
2653 sub collect_from_file {
2654     my $filename = shift;
2655     my $line_concat_cond_re = shift;
2656     my $line_concat = shift;
2657
2658     open my $fh, $filename || die "unable to read $filename: $!\n";
2659     return sub {
2660         my $saved_line = "";
2661         $_ = "";
2662         while (<$fh>) {
2663             s|\R$||;
2664             if (defined $line_concat) {
2665                 $_ = $line_concat->($saved_line, $_);
2666                 $saved_line = "";
2667             }
2668             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2669                 $saved_line = $_;
2670                 next;
2671             }
2672             return $_;
2673         }
2674         die "$filename ending with continuation line\n" if $_;
2675         close $fh;
2676         return undef;
2677     }
2678 }
2679
2680 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2681 # $array is an ARRAYref of lines
2682 # $line_concat_cond_re is a regexp detecting a line continuation ending
2683 # $line_concat is a CODEref that takes care of concatenating two lines
2684 sub collect_from_array {
2685     my $array = shift;
2686     my $line_concat_cond_re = shift;
2687     my $line_concat = shift;
2688     my @array = (@$array);
2689
2690     return sub {
2691         my $saved_line = "";
2692         $_ = "";
2693         while (defined($_ = shift @array)) {
2694             s|\R$||;
2695             if (defined $line_concat) {
2696                 $_ = $line_concat->($saved_line, $_);
2697                 $saved_line = "";
2698             }
2699             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2700                 $saved_line = $_;
2701                 next;
2702             }
2703             return $_;
2704         }
2705         die "input text ending with continuation line\n" if $_;
2706         return undef;
2707     }
2708 }
2709
2710 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2711 # $lineiterator is a CODEref that delivers one line at a time.
2712 # All following arguments are regex/CODEref pairs, where the regexp detects a
2713 # line and the CODEref does something with the result of the regexp.
2714 sub collect_information {
2715     my $lineiterator = shift;
2716     my %collectors = @_;
2717
2718     while(defined($_ = $lineiterator->())) {
2719         s|\R$||;
2720         my $found = 0;
2721         if ($collectors{"BEFORE"}) {
2722             $collectors{"BEFORE"}->($_);
2723         }
2724         foreach my $re (keys %collectors) {
2725             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2726                 $collectors{$re}->($lineiterator);
2727                 $found = 1;
2728             };
2729         }
2730         if ($collectors{"OTHERWISE"}) {
2731             $collectors{"OTHERWISE"}->($lineiterator, $_)
2732                 unless $found || !defined $collectors{"OTHERWISE"};
2733         }
2734         if ($collectors{"AFTER"}) {
2735             $collectors{"AFTER"}->($_);
2736         }
2737     }
2738 }
2739
2740 # tokenize($line)
2741 # $line is a line of text to split up into tokens
2742 # returns a list of tokens
2743 #
2744 # Tokens are divided by spaces.  If the tokens include spaces, they
2745 # have to be quoted with single or double quotes.  Double quotes
2746 # inside a double quoted token must be escaped.  Escaping is done
2747 # with backslash.
2748 # Basically, the same quoting rules apply for " and ' as in any
2749 # Unix shell.
2750 sub tokenize {
2751     my $line = my $debug_line = shift;
2752     my @result = ();
2753
2754     while ($line =~ s|^\s+||, $line ne "") {
2755         my $token = "";
2756         while ($line ne "" && $line !~ m|^\s|) {
2757             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2758                 $token .= $1;
2759                 $line = $';
2760             } elsif ($line =~ m/^'([^']*)'/) {
2761                 $token .= $1;
2762                 $line = $';
2763             } elsif ($line =~ m/^(\S+)/) {
2764                 $token .= $1;
2765                 $line = $';
2766             }
2767         }
2768         push @result, $token;
2769     }
2770
2771     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2772         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2773         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2774     }
2775     return @result;
2776 }