Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  47 #               interfaces deprecated as of the specified OpenSSL version.
  48 #
  49 # no-hw-xxx     do not compile support for specific crypto hardware.
  50 #               Generic OpenSSL-style methods relating to this support
  51 #               are always compiled but return NULL if the hardware
  52 #               support isn't compiled.
  53 # no-hw         do not compile support for any crypto hardware.
  54 # [no-]threads  [don't] try to create a library that is suitable for
  55 #               multithreaded applications (default is "threads" if we
  56 #               know how to do it)
  57 # [no-]shared   [don't] try to create shared libraries when supported.
  58 # [no-]pic      [don't] try to build position independent code when supported.
  59 #               If disabled, it also disables shared and dynamic-engine.
  60 # no-asm        do not use assembler
  61 # no-dso        do not compile in any native shared-library methods. This
  62 #               will ensure that all methods just return NULL.
  63 # no-egd        do not compile support for the entropy-gathering daemon APIs
  64 # [no-]zlib     [don't] compile support for zlib compression.
  65 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  66 #               library and will be loaded in run-time by the OpenSSL library.
  67 # sctp          include SCTP support
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-dso, no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  93 #               provided to stack calls. Generates unique stack functions for
  94 #               each possible stack type.
  95 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  96 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  97 # Following are set automatically by this script
  98 #
  99 # MD5_ASM       use some extra md5 assembler,
 100 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 101 # RMD160_ASM    use some extra ripemd160 assembler,
 102 # SHA256_ASM    sha256_block is implemented in assembler
 103 # SHA512_ASM    sha512_block is implemented in assembler
 104 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 105
 106 # Minimum warning options... any contributions to OpenSSL should at least get
 107 # past these.
 108
 109 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 110 # -DPEDANTIC complements -pedantic and is meant to mask code that
 111 # is not strictly standard-compliant and/or implementation-specific,
 112 # e.g. inline assembly, disregards to alignment requirements, such
 113 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 114 # to be used even in sanitized builds, because sanitizer too is
 115 # supposed to and does take notice of non-standard behaviour. Then
 116 # -pedantic with pre-C9x compiler would also complain about 'long
 117 # long' not being supported. As 64-bit algorithms are common now,
 118 # it grew impossible to resolve this without sizeable additional
 119 # code, so we just tell compiler to be pedantic about everything
 120 # but 'long long' type.
 121
 122 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 123         . " -DPEDANTIC -pedantic -Wno-long-long"
 124         . " -Wall"
 125         . " -Wextra"
 126         . " -Wno-unused-parameter"
 127         . " -Wno-missing-field-initializers"
 128         . " -Wswitch"
 129         . " -Wsign-compare"
 130         . " -Wmissing-prototypes"
 131         . " -Wstrict-prototypes"
 132         . " -Wshadow"
 133         . " -Wformat"
 134         . " -Wtype-limits"
 135         . " -Wundef"
 136         . " -Werror"
 137         ;
 138
 139 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 140 # TODO(openssl-team): fix problems and investigate if (at least) the
 141 # following warnings can also be enabled:
 142 #       -Wcast-align
 143 #       -Wunreachable-code -- no, too ugly/compiler-specific
 144 #       -Wlanguage-extension-token -- no, we use asm()
 145 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 146 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 147 my $clang_devteam_warn = ""
 148         . " -Wswitch-default"
 149         . " -Wno-parentheses-equality"
 150         . " -Wno-language-extension-token"
 151         . " -Wno-extended-offsetof"
 152         . " -Wconditional-uninitialized"
 153         . " -Wincompatible-pointer-types-discards-qualifiers"
 154         . " -Wmissing-variable-declarations"
 155         . " -Wno-unknown-warning-option"
 156         ;
 157
 158 # This adds backtrace information to the memory leak info.  Is only used
 159 # when crypto-mdebug-backtrace is enabled.
 160 my $memleak_devteam_backtrace = "-rdynamic";
 161
 162 my $strict_warnings = 0;
 163
 164 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 165 # which would cover all BSD flavors. -pthread applies to them all,
 166 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 167 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 168 # which has to be accompanied by explicit -D_THREAD_SAFE and
 169 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 170 # seems to be sufficient?
 171 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 172
 173 #
 174 # API compatibility name to version number mapping.
 175 #
 176 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 177 my $apitable = {
 178     "1.1.0" => "0x10100000L",
 179     "1.0.0" => "0x10000000L",
 180     "0.9.8" => "0x00908000L",
 181 };
 182
 183 our %table = ();
 184 our %config = ();
 185 our %withargs = ();
 186 our $now_printing;      # set to current entry's name in print_table_entry
 187                         # (todo: right thing would be to encapsulate name
 188                         # into %target [class] and make print_table_entry
 189                         # a method)
 190
 191 # Forward declarations ###############################################
 192
 193 # read_config(filename)
 194 #
 195 # Reads a configuration file and populates %table with the contents
 196 # (which the configuration file places in %targets).
 197 sub read_config;
 198
 199 # resolve_config(target)
 200 #
 201 # Resolves all the late evaluations, inheritances and so on for the
 202 # chosen target and any target it inherits from.
 203 sub resolve_config;
 204
 205
 206 # Information collection #############################################
 207
 208 # Unified build supports separate build dir
 209 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 210 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 211 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 212
 213 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 214
 215 $config{sourcedir} = abs2rel($srcdir);
 216 $config{builddir} = abs2rel($blddir);
 217
 218 # Collect reconfiguration information if needed
 219 my @argvcopy=@ARGV;
 220
 221 if (grep /^reconf(igure)?$/, @argvcopy) {
 222     die "reconfiguring with other arguments present isn't supported"
 223         if scalar @argvcopy > 1;
 224     if (-f "./configdata.pm") {
 225         my $file = "./configdata.pm";
 226         unless (my $return = do $file) {
 227             die "couldn't parse $file: $@" if $@;
 228             die "couldn't do $file: $!"    unless defined $return;
 229             die "couldn't run $file"       unless $return;
 230         }
 231
 232         @argvcopy = defined($configdata::config{perlargv}) ?
 233             @{$configdata::config{perlargv}} : ();
 234         die "Incorrect data to reconfigure, please do a normal configuration\n"
 235             if (grep(/^reconf/,@argvcopy));
 236         $config{perlenv} = $configdata::config{perlenv} // {};
 237     } else {
 238         die "Insufficient data to reconfigure, please do a normal configuration\n";
 239     }
 240 }
 241
 242 $config{perlargv} = [ @argvcopy ];
 243
 244 # Collect version numbers
 245 $config{version} = "unknown";
 246 $config{version_num} = "unknown";
 247 $config{shlib_version_number} = "unknown";
 248 $config{shlib_version_history} = "unknown";
 249
 250 collect_information(
 251     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 252     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 253     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 254     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 255     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 256     );
 257 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 258
 259 ($config{major}, $config{minor})
 260     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 261 ($config{shlib_major}, $config{shlib_minor})
 262     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 263 die "erroneous version information in opensslv.h: ",
 264     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 265     if ($config{major} eq "" || $config{minor} eq ""
 266         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 267
 268 # Collect target configurations
 269
 270 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 271 foreach (sort glob($pattern)) {
 272     &read_config($_);
 273 }
 274
 275 if (defined env($local_config_envname)) {
 276     if ($^O eq 'VMS') {
 277         # VMS environment variables are logical names,
 278         # which can be used as is
 279         $pattern = $local_config_envname . ':' . '*.conf';
 280     } else {
 281         $pattern = catfile(env($local_config_envname), '*.conf');
 282     }
 283
 284     foreach (sort glob($pattern)) {
 285         &read_config($_);
 286     }
 287 }
 288
 289 # Save away perl command information
 290 $config{perl_cmd} = $^X;
 291 $config{perl_version} = $Config{version};
 292 $config{perl_archname} = $Config{archname};
 293
 294 $config{prefix}="";
 295 $config{openssldir}="";
 296 $config{processor}="";
 297 $config{libdir}="";
 298 my $auto_threads=1;    # enable threads automatically? true by default
 299 my $default_ranlib;
 300
 301 # Top level directories to build
 302 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 303 # crypto/ subdirectories to build
 304 $config{sdirs} = [
 305     "objects",
 306     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash", "sm3",
 307     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "sm4", "chacha", "modes",
 308     "bn", "ec", "rsa", "dsa", "dh", "sm2", "dso", "engine",
 309     "buffer", "bio", "stack", "lhash", "rand", "err",
 310     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 311     "cms", "ts", "srp", "gmac", "cmac", "ct", "async", "kdf", "store"
 312     ];
 313 # test/ subdirectories to build
 314 $config{tdirs} = [ "ossl_shim" ];
 315
 316 # Known TLS and DTLS protocols
 317 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 318 my @dtls = qw(dtls1 dtls1_2);
 319
 320 # Explicitly known options that are possible to disable.  They can
 321 # be regexps, and will be used like this: /^no-${option}$/
 322 # For developers: keep it sorted alphabetically
 323
 324 my @disablables = (
 325     "afalgeng",
 326     "aria",
 327     "asan",
 328     "asm",
 329     "async",
 330     "autoalginit",
 331     "autoerrinit",
 332     "autoload-config",
 333     "bf",
 334     "blake2",
 335     "camellia",
 336     "capieng",
 337     "cast",
 338     "chacha",
 339     "cmac",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dso",
 352     "dtls",
 353     "dynamic-engine",
 354     "ec",
 355     "ec2m",
 356     "ecdh",
 357     "ecdsa",
 358     "ec_nistp_64_gcc_128",
 359     "egd",
 360     "engine",
 361     "err",
 362     "external-tests",
 363     "filenames",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "heartbeats",
 368     "hw(-.+)?",
 369     "idea",
 370     "makedepend",
 371     "md2",
 372     "md4",
 373     "mdc2",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "ocb",
 378     "ocsp",
 379     "pic",
 380     "poly1305",
 381     "posix-io",
 382     "psk",
 383     "rc2",
 384     "rc4",
 385     "rc5",
 386     "rdrand",
 387     "rfc3779",
 388     "rmd160",
 389     "scrypt",
 390     "sctp",
 391     "seed",
 392     "shared",
 393     "siphash",
 394     "sm2",
 395     "sm3",
 396     "sm4",
 397     "sock",
 398     "srp",
 399     "srtp",
 400     "sse2",
 401     "ssl",
 402     "ssl-trace",
 403     "static-engine",
 404     "stdio",
 405     "tests",
 406     "threads",
 407     "tls",
 408     "ts",
 409     "ubsan",
 410     "ui-console",
 411     "unit-test",
 412     "whirlpool",
 413     "weak-ssl-ciphers",
 414     "zlib",
 415     "zlib-dynamic",
 416     );
 417 foreach my $proto ((@tls, @dtls))
 418         {
 419         push(@disablables, $proto);
 420         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 421         }
 422
 423 my %deprecated_disablables = (
 424     "ssl2" => undef,
 425     "buf-freelists" => undef,
 426     "ripemd" => "rmd160",
 427     "ui" => "ui-console",
 428     );
 429
 430 # All of the following are disabled by default:
 431
 432 our %disabled = ( # "what"         => "comment"
 433                   "asan"                => "default",
 434                   "crypto-mdebug"       => "default",
 435                   "crypto-mdebug-backtrace" => "default",
 436                   "devcryptoeng"        => "default",
 437                   "ec_nistp_64_gcc_128" => "default",
 438                   "egd"                 => "default",
 439                   "external-tests"      => "default",
 440                   "fuzz-libfuzzer"      => "default",
 441                   "fuzz-afl"            => "default",
 442                   "heartbeats"          => "default",
 443                   "md2"                 => "default",
 444                   "msan"                => "default",
 445                   "rc5"                 => "default",
 446                   "sctp"                => "default",
 447                   "ssl-trace"           => "default",
 448                   "ssl3"                => "default",
 449                   "ssl3-method"         => "default",
 450                   "ubsan"               => "default",
 451                   "unit-test"           => "default",
 452                   "weak-ssl-ciphers"    => "default",
 453                   "zlib"                => "default",
 454                   "zlib-dynamic"        => "default",
 455                 );
 456
 457 # Note: => pair form used for aesthetics, not to truly make a hash table
 458 my @disable_cascades = (
 459     # "what"            => [ "cascade", ... ]
 460     sub { $config{processor} eq "386" }
 461                         => [ "sse2" ],
 462     "ssl"               => [ "ssl3" ],
 463     "ssl3-method"       => [ "ssl3" ],
 464     "zlib"              => [ "zlib-dynamic" ],
 465     "des"               => [ "mdc2" ],
 466     "ec"                => [ "ecdsa", "ecdh" ],
 467
 468     "dgram"             => [ "dtls", "sctp" ],
 469     "sock"              => [ "dgram" ],
 470     "dtls"              => [ @dtls ],
 471     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 472                         => [ "dtls" ],
 473
 474     "tls"               => [ @tls ],
 475     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 476                         => [ "tls" ],
 477
 478     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 479
 480     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 481     "dso"               => [ "dynamic-engine" ],
 482
 483     # Without position independent code, there can be no shared libraries or DSOs
 484     "pic"               => [ "shared" ],
 485     "shared"            => [ "dynamic-engine" ],
 486     "engine"            => [ "afalgeng", "devcryptoeng" ],
 487
 488     # no-autoalginit is only useful when building non-shared
 489     "autoalginit"       => [ "shared", "apps" ],
 490
 491     "stdio"             => [ "apps", "capieng", "egd" ],
 492     "apps"              => [ "tests" ],
 493     "tests"             => [ "external-tests" ],
 494     "comp"              => [ "zlib" ],
 495     "ec"                => [ "tls1_3", "sm2" ],
 496     "sm3"               => [ "sm2" ],
 497     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 498
 499     sub { !$disabled{"msan"} } => [ "asm" ],
 500     );
 501
 502 # Avoid protocol support holes.  Also disable all versions below N, if version
 503 # N is disabled while N+1 is enabled.
 504 #
 505 my @list = (reverse @tls);
 506 while ((my $first, my $second) = (shift @list, shift @list)) {
 507     last unless @list;
 508     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 509                               => [ @list ] );
 510     unshift @list, $second;
 511 }
 512 my @list = (reverse @dtls);
 513 while ((my $first, my $second) = (shift @list, shift @list)) {
 514     last unless @list;
 515     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 516                               => [ @list ] );
 517     unshift @list, $second;
 518 }
 519
 520 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 521 # To remove something from %disabled, use "enable-foo".
 522 # For symmetry, "disable-foo" is a synonym for "no-foo".
 523
 524 &usage if ($#ARGV < 0);
 525
 526 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 527 # platform specific list separators.  Users from those platforms should
 528 # recognise those separators from how you set up the PATH to find executables.
 529 # The default is the Unix like separator, :, but as an exception, we also
 530 # support the space as separator.
 531 my $list_separator_re =
 532     { VMS           => qr/(?<!\^),/,
 533       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 534 # All the "make variables" we support
 535 # Some get pre-populated for the sake of backward compatibility
 536 # (we supported those before the change to "make variable" support.
 537 my %user = (
 538     AR          => env('AR'),
 539     ARFLAGS     => [],
 540     AS          => undef,
 541     ASFLAGS     => [],
 542     CC          => env('CC'),
 543     CFLAGS      => [],
 544     CXX         => env('CXX'),
 545     CXXFLAGS    => [],
 546     CPP         => undef,
 547     CPPFLAGS    => [],  # -D, -I, -Wp,
 548     CPPDEFINES  => [],  # Alternative for -D
 549     CPPINCLUDES => [],  # Alternative for -I
 550     CROSS_COMPILE => env('CROSS_COMPILE'),
 551     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 552     LD          => undef,
 553     LDFLAGS     => [],  # -L, -Wl,
 554     LDLIBS      => [],  # -l
 555     MT          => undef,
 556     MTFLAGS     => [],
 557     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 558     RANLIB      => env('RANLIB'),
 559     RC          => env('RC') || env('WINDRES'),
 560     RCFLAGS     => [],
 561     RM          => undef,
 562    );
 563 # Info about what "make variables" may be prefixed with the cross compiler
 564 # prefix.  This should NEVER mention any such variable with a list for value.
 565 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 566 # The same but for flags given as Configure options.  These are *additional*
 567 # input, as opposed to the VAR=string option that override the corresponding
 568 # config target attributes
 569 my %useradd = (
 570     CPPDEFINES  => [],
 571     CPPINCLUDES => [],
 572     CPPFLAGS    => [],
 573     CFLAGS      => [],
 574     CXXFLAGS    => [],
 575     LDFLAGS     => [],
 576     LDLIBS      => [],
 577    );
 578
 579 my %user_synonyms = (
 580     HASHBANGPERL=> 'PERL',
 581     RC          => 'WINDRES',
 582    );
 583
 584 # Some target attributes have been renamed, this is the translation table
 585 my %target_attr_translate =(
 586     ar          => 'AR',
 587     as          => 'AS',
 588     cc          => 'CC',
 589     cxx         => 'CXX',
 590     cpp         => 'CPP',
 591     hashbangperl => 'HASHBANGPERL',
 592     ld          => 'LD',
 593     mt          => 'MT',
 594     ranlib      => 'RANLIB',
 595     rc          => 'RC',
 596     rm          => 'RM',
 597    );
 598
 599 # Initialisers coming from 'config' scripts
 600 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 601 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 602 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 603 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 604 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 605 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 606 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 607
 608 $config{openssl_api_defines}=[];
 609 $config{openssl_algorithm_defines}=[];
 610 $config{openssl_thread_defines}=[];
 611 $config{openssl_sys_defines}=[];
 612 $config{openssl_other_defines}=[];
 613 $config{options}="";
 614 $config{build_type} = "release";
 615 my $target="";
 616
 617 my %cmdvars = ();               # Stores FOO='blah' type arguments
 618 my %unsupported_options = ();
 619 my %deprecated_options = ();
 620 # If you change this, update apps/version.c
 621 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 622 my @seed_sources = ();
 623 while (@argvcopy)
 624         {
 625         $_ = shift @argvcopy;
 626
 627         # Support env variable assignments among the options
 628         if (m|^(\w+)=(.+)?$|)
 629                 {
 630                 $cmdvars{$1} = $2;
 631                 # Every time a variable is given as a configuration argument,
 632                 # it acts as a reset if the variable.
 633                 if (exists $user{$1})
 634                         {
 635                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 636                         }
 637                 #if (exists $useradd{$1})
 638                 #       {
 639                 #       $useradd{$1} = [];
 640                 #       }
 641                 next;
 642                 }
 643
 644         # VMS is a case insensitive environment, and depending on settings
 645         # out of our control, we may receive options uppercased.  Let's
 646         # downcase at least the part before any equal sign.
 647         if ($^O eq "VMS")
 648                 {
 649                 s/^([^=]*)/lc($1)/e;
 650                 }
 651
 652         # some people just can't read the instructions, clang people have to...
 653         s/^-no-(?!integrated-as)/no-/;
 654
 655         # rewrite some options in "enable-..." form
 656         s /^-?-?shared$/enable-shared/;
 657         s /^sctp$/enable-sctp/;
 658         s /^threads$/enable-threads/;
 659         s /^zlib$/enable-zlib/;
 660         s /^zlib-dynamic$/enable-zlib-dynamic/;
 661
 662         if (/^(no|disable|enable)-(.+)$/)
 663                 {
 664                 my $word = $2;
 665                 if (!exists $deprecated_disablables{$word}
 666                         && !grep { $word =~ /^${_}$/ } @disablables)
 667                         {
 668                         $unsupported_options{$_} = 1;
 669                         next;
 670                         }
 671                 }
 672         if (/^no-(.+)$/ || /^disable-(.+)$/)
 673                 {
 674                 foreach my $proto ((@tls, @dtls))
 675                         {
 676                         if ($1 eq "$proto-method")
 677                                 {
 678                                 $disabled{"$proto"} = "option($proto-method)";
 679                                 last;
 680                                 }
 681                         }
 682                 if ($1 eq "dtls")
 683                         {
 684                         foreach my $proto (@dtls)
 685                                 {
 686                                 $disabled{$proto} = "option(dtls)";
 687                                 }
 688                         $disabled{"dtls"} = "option(dtls)";
 689                         }
 690                 elsif ($1 eq "ssl")
 691                         {
 692                         # Last one of its kind
 693                         $disabled{"ssl3"} = "option(ssl)";
 694                         }
 695                 elsif ($1 eq "tls")
 696                         {
 697                         # XXX: Tests will fail if all SSL/TLS
 698                         # protocols are disabled.
 699                         foreach my $proto (@tls)
 700                                 {
 701                                 $disabled{$proto} = "option(tls)";
 702                                 }
 703                         }
 704                 elsif ($1 eq "static-engine")
 705                         {
 706                         delete $disabled{"dynamic-engine"};
 707                         }
 708                 elsif ($1 eq "dynamic-engine")
 709                         {
 710                         $disabled{"dynamic-engine"} = "option";
 711                         }
 712                 elsif (exists $deprecated_disablables{$1})
 713                         {
 714                         $deprecated_options{$_} = 1;
 715                         if (defined $deprecated_disablables{$1})
 716                                 {
 717                                 $disabled{$deprecated_disablables{$1}} = "option";
 718                                 }
 719                         }
 720                 else
 721                         {
 722                         $disabled{$1} = "option";
 723                         }
 724                 # No longer an automatic choice
 725                 $auto_threads = 0 if ($1 eq "threads");
 726                 }
 727         elsif (/^enable-(.+)$/)
 728                 {
 729                 if ($1 eq "static-engine")
 730                         {
 731                         $disabled{"dynamic-engine"} = "option";
 732                         }
 733                 elsif ($1 eq "dynamic-engine")
 734                         {
 735                         delete $disabled{"dynamic-engine"};
 736                         }
 737                 elsif ($1 eq "zlib-dynamic")
 738                         {
 739                         delete $disabled{"zlib"};
 740                         }
 741                 my $algo = $1;
 742                 delete $disabled{$algo};
 743
 744                 # No longer an automatic choice
 745                 $auto_threads = 0 if ($1 eq "threads");
 746                 }
 747         elsif (/^--strict-warnings$/)
 748                 {
 749                 $strict_warnings = 1;
 750                 }
 751         elsif (/^--debug$/)
 752                 {
 753                 $config{build_type} = "debug";
 754                 }
 755         elsif (/^--release$/)
 756                 {
 757                 $config{build_type} = "release";
 758                 }
 759         elsif (/^386$/)
 760                 { $config{processor}=386; }
 761         elsif (/^fips$/)
 762                 {
 763                 die "FIPS mode not supported\n";
 764                 }
 765         elsif (/^rsaref$/)
 766                 {
 767                 # No RSAref support any more since it's not needed.
 768                 # The check for the option is there so scripts aren't
 769                 # broken
 770                 }
 771         elsif (/^nofipscanistercheck$/)
 772                 {
 773                 die "FIPS mode not supported\n";
 774                 }
 775         elsif (/^[-+]/)
 776                 {
 777                 if (/^--prefix=(.*)$/)
 778                         {
 779                         $config{prefix}=$1;
 780                         die "Directory given with --prefix MUST be absolute\n"
 781                                 unless file_name_is_absolute($config{prefix});
 782                         }
 783                 elsif (/^--api=(.*)$/)
 784                         {
 785                         $config{api}=$1;
 786                         }
 787                 elsif (/^--libdir=(.*)$/)
 788                         {
 789                         $config{libdir}=$1;
 790                         }
 791                 elsif (/^--openssldir=(.*)$/)
 792                         {
 793                         $config{openssldir}=$1;
 794                         }
 795                 elsif (/^--with-zlib-lib=(.*)$/)
 796                         {
 797                         $withargs{zlib_lib}=$1;
 798                         }
 799                 elsif (/^--with-zlib-include=(.*)$/)
 800                         {
 801                         $withargs{zlib_include}=$1;
 802                         }
 803                 elsif (/^--with-fuzzer-lib=(.*)$/)
 804                         {
 805                         $withargs{fuzzer_lib}=$1;
 806                         }
 807                 elsif (/^--with-fuzzer-include=(.*)$/)
 808                         {
 809                         $withargs{fuzzer_include}=$1;
 810                         }
 811                 elsif (/^--with-rand-seed=(.*)$/)
 812                         {
 813                         foreach my $x (split(m|,|, $1))
 814                             {
 815                             die "Unknown --with-rand-seed choice $x\n"
 816                                 if ! grep { $x eq $_ } @known_seed_sources;
 817                             push @seed_sources, $x;
 818                             }
 819                         }
 820                 elsif (/^--cross-compile-prefix=(.*)$/)
 821                         {
 822                         $user{CROSS_COMPILE}=$1;
 823                         }
 824                 elsif (/^--config=(.*)$/)
 825                         {
 826                         read_config $1;
 827                         }
 828                 elsif (/^-l(.*)$/)
 829                         {
 830                         push @{$useradd{LDLIBS}}, $_;
 831                         }
 832                 elsif (/^-framework$/)
 833                         {
 834                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 835                         }
 836                 elsif (/^-L(.*)$/ or /^-Wl,/)
 837                         {
 838                         push @{$useradd{LDFLAGS}}, $_;
 839                         }
 840                 elsif (/^-rpath$/ or /^-R$/)
 841                         # -rpath is the OSF1 rpath flag
 842                         # -R is the old Solaris rpath flag
 843                         {
 844                         my $rpath = shift(@argvcopy) || "";
 845                         $rpath .= " " if $rpath ne "";
 846                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 847                         }
 848                 elsif (/^-static$/)
 849                         {
 850                         push @{$useradd{LDFLAGS}}, $_;
 851                         $disabled{"dso"} = "forced";
 852                         $disabled{"pic"} = "forced";
 853                         $disabled{"shared"} = "forced";
 854                         $disabled{"threads"} = "forced";
 855                         }
 856                 elsif (/^-D(.*)$/)
 857                         {
 858                         push @{$useradd{CPPDEFINES}}, $1;
 859                         }
 860                 elsif (/^-I(.*)$/)
 861                         {
 862                         push @{$useradd{CPPINCLUDES}}, $1;
 863                         }
 864                 elsif (/^-Wp,$/)
 865                         {
 866                         push @{$useradd{CPPFLAGS}}, $1;
 867                         }
 868                 else    # common if (/^[-+]/), just pass down...
 869                         {
 870                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 871                         push @{$useradd{CFLAGS}}, $_;
 872                         push @{$useradd{CXXFLAGS}}, $_;
 873                         }
 874                 }
 875         else
 876                 {
 877                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 878                 $target=$_;
 879                 }
 880         unless ($_ eq $target || /^no-/ || /^disable-/)
 881                 {
 882                 # "no-..." follows later after implied deactivations
 883                 # have been derived.  (Don't take this too seriously,
 884                 # we really only write OPTIONS to the Makefile out of
 885                 # nostalgia.)
 886
 887                 if ($config{options} eq "")
 888                         { $config{options} = $_; }
 889                 else
 890                         { $config{options} .= " ".$_; }
 891                 }
 892         }
 893
 894 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 895         die "***** Unsupported api compatibility level: $config{api}\n",
 896 }
 897
 898 if (keys %deprecated_options)
 899         {
 900         warn "***** Deprecated options: ",
 901                 join(", ", keys %deprecated_options), "\n";
 902         }
 903 if (keys %unsupported_options)
 904         {
 905         die "***** Unsupported options: ",
 906                 join(", ", keys %unsupported_options), "\n";
 907         }
 908
 909 # If any %useradd entry has been set, we must check that the "make
 910 # variables" haven't been set.  We start by checking of any %useradd entry
 911 # is set.
 912 if (grep { scalar @$_ > 0 } values %useradd) {
 913     # Hash of env / make variables names.  The possible values are:
 914     # 1 - "make vars"
 915     # 2 - %useradd entry set
 916     # 3 - both set
 917     my %detected_vars =
 918         map { my $v = 0;
 919               $v += 1 if $cmdvars{$_};
 920               $v += 2 if @{$useradd{$_}};
 921               $_ => $v }
 922         keys %useradd;
 923
 924     # If any of the corresponding "make variables" is set, we error
 925     if (grep { $_ & 1 } values %detected_vars) {
 926         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 927                                sort keys %detected_vars);
 928         die <<"_____";
 929 ***** Mixing make variables and additional compiler/linker flags as
 930 ***** configure command line option is not permitted.
 931 ***** Affected make variables: $names
 932 _____
 933     }
 934 }
 935
 936 # Check through all supported command line variables to see if any of them
 937 # were set, and canonicalise the values we got.  If no compiler or linker
 938 # flag or anything else that affects %useradd was set, we also check the
 939 # environment for values.
 940 my $anyuseradd =
 941     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 942 foreach (keys %user) {
 943     my $value = $cmdvars{$_};
 944     $value //= env($_) unless $anyuseradd;
 945     $value //=
 946         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 947     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 948         unless $anyuseradd;
 949
 950     if (defined $value) {
 951         if (ref $user{$_} eq 'ARRAY') {
 952             $user{$_} = [ split /$list_separator_re/, $value ];
 953         } elsif (!defined $user{$_}) {
 954             $user{$_} = $value;
 955         }
 956     }
 957 }
 958
 959 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 960     && !$disabled{shared}
 961     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 962     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 963         "***** any of asan, msan or ubsan\n";
 964 }
 965
 966 my @tocheckfor = (keys %disabled);
 967 while (@tocheckfor) {
 968     my %new_tocheckfor = ();
 969     my @cascade_copy = (@disable_cascades);
 970     while (@cascade_copy) {
 971         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 972         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 973             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 974                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 975             }
 976         }
 977     }
 978     @tocheckfor = (keys %new_tocheckfor);
 979 }
 980
 981 our $die = sub { die @_; };
 982 if ($target eq "TABLE") {
 983     local $die = sub { warn @_; };
 984     foreach (sort keys %table) {
 985         print_table_entry($_, "TABLE");
 986     }
 987     exit 0;
 988 }
 989
 990 if ($target eq "LIST") {
 991     foreach (sort keys %table) {
 992         print $_,"\n" unless $table{$_}->{template};
 993     }
 994     exit 0;
 995 }
 996
 997 if ($target eq "HASH") {
 998     local $die = sub { warn @_; };
 999     print "%table = (\n";
1000     foreach (sort keys %table) {
1001         print_table_entry($_, "HASH");
1002     }
1003     exit 0;
1004 }
1005
1006 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
1007 print "for $target\n";
1008
1009 if (scalar(@seed_sources) == 0) {
1010     print "Using os-specific seed configuration\n";
1011     push @seed_sources, 'os';
1012 }
1013 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1014     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1015     warn <<_____ if scalar(@seed_sources) == 1;
1016
1017 ============================== WARNING ===============================
1018 You have selected the --with-rand-seed=none option, which effectively
1019 disables automatic reseeding of the OpenSSL random generator.
1020 All operations depending on the random generator such as creating keys
1021 will not work unless the random generator is seeded manually by the
1022 application.
1023
1024 Please read the 'Note on random number generation' section in the
1025 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1026 ============================== WARNING ===============================
1027
1028 _____
1029 }
1030 push @{$config{openssl_other_defines}},
1031      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1032         @seed_sources;
1033
1034 # Backward compatibility?
1035 if ($target =~ m/^CygWin32(-.*)$/) {
1036     $target = "Cygwin".$1;
1037 }
1038
1039 # Support for legacy targets having a name starting with 'debug-'
1040 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1041 if ($d) {
1042     $config{build_type} = "debug";
1043
1044     # If we do not find debug-foo in the table, the target is set to foo.
1045     if (!$table{$target}) {
1046         $target = $t;
1047     }
1048 }
1049
1050 &usage if !$table{$target} || $table{$target}->{template};
1051
1052 $config{target} = $target;
1053 my %target = resolve_config($target);
1054
1055 foreach (keys %target_attr_translate) {
1056     $target{$target_attr_translate{$_}} = $target{$_}
1057         if $target{$_};
1058     delete $target{$_};
1059 }
1060
1061 %target = ( %{$table{DEFAULTS}}, %target );
1062
1063 # Make the flags to build DSOs the same as for shared libraries unless they
1064 # are already defined
1065 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1066 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1067 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1068 {
1069     my $shared_info_pl =
1070         catfile(dirname($0), "Configurations", "shared-info.pl");
1071     my %shared_info = read_eval_file($shared_info_pl);
1072     push @{$target{_conf_fname_int}}, $shared_info_pl;
1073     my $si = $target{shared_target};
1074     while (ref $si ne "HASH") {
1075         last if ! defined $si;
1076         if (ref $si eq "CODE") {
1077             $si = $si->();
1078         } else {
1079             $si = $shared_info{$si};
1080         }
1081     }
1082
1083     # Some of the 'shared_target' values don't have any entried in
1084     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1085     # template knows how to handle this.  That is currently the case for
1086     # Windows and VMS.
1087     if (defined $si) {
1088         # Just as above, copy certain shared_* attributes to the corresponding
1089         # module_ attribute unless the latter is already defined
1090         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1091         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1092         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1093         foreach (sort keys %$si) {
1094             $target{$_} = defined $target{$_}
1095                 ? add($si->{$_})->($target{$_})
1096                 : $si->{$_};
1097         }
1098     }
1099 }
1100
1101 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1102 $config{conf_files} = [ sort keys %conf_files ];
1103
1104 foreach my $feature (@{$target{disable}}) {
1105     if (exists $deprecated_disablables{$feature}) {
1106         warn "***** config $target disables deprecated feature $feature\n";
1107     } elsif (!grep { $feature eq $_ } @disablables) {
1108         die "***** config $target disables unknown feature $feature\n";
1109     }
1110     $disabled{$feature} = 'config';
1111 }
1112 foreach my $feature (@{$target{enable}}) {
1113     if ("default" eq ($disabled{$_} // "")) {
1114         if (exists $deprecated_disablables{$feature}) {
1115             warn "***** config $target enables deprecated feature $feature\n";
1116         } elsif (!grep { $feature eq $_ } @disablables) {
1117             die "***** config $target enables unknown feature $feature\n";
1118         }
1119         delete $disabled{$_};
1120     }
1121 }
1122
1123 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1124 $target{cxxflags}//=$target{cflags} if $target{CXX};
1125 $target{exe_extension}="";
1126 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1127                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1128 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1129 $target{def_extension}=".ld";
1130 $target{def_extension}=".def" if $config{target} =~ /^mingw|VC-/;
1131 $target{def_extension}=".opt" if $config{target} =~ /^vms/;
1132 ($target{shared_extension_simple}=$target{shared_extension})
1133     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||
1134     unless defined($target{shared_extension_simple});
1135 $target{dso_extension}//=$target{shared_extension_simple};
1136 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1137     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1138
1139 # Fill %config with values from %user, and in case those are undefined or
1140 # empty, use values from %target (acting as a default).
1141 foreach (keys %user) {
1142     my $ref_type = ref $user{$_};
1143
1144     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1145     # and a value that's to be coerced into that type.
1146     my $mkvalue = sub {
1147         my $type = shift;
1148         my $value = shift;
1149         my $undef_p = shift;
1150
1151         die "Too many arguments for \$mkvalue" if @_;
1152
1153         while (ref $value eq 'CODE') {
1154             $value = $value->();
1155         }
1156
1157         if ($type eq 'ARRAY') {
1158             return undef unless defined $value;
1159             return undef if ref $value ne 'ARRAY' && !$value;
1160             return undef if ref $value eq 'ARRAY' && !@$value;
1161             return [ $value ] unless ref $value eq 'ARRAY';
1162         }
1163         return undef unless $value;
1164         return $value;
1165     };
1166
1167     $config{$_} =
1168         $mkvalue->($ref_type, $user{$_})
1169         || $mkvalue->($ref_type, $target{$_});
1170     delete $config{$_} unless defined $config{$_};
1171 }
1172
1173 # Allow overriding the build file name
1174 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1175
1176 my %disabled_info = ();         # For configdata.pm
1177 foreach my $what (sort keys %disabled) {
1178     $config{options} .= " no-$what";
1179
1180     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1181                                 'dynamic-engine', 'makedepend',
1182                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1183         (my $WHAT = uc $what) =~ s|-|_|g;
1184
1185         # Fix up C macro end names
1186         $WHAT = "RMD160" if $what eq "ripemd";
1187
1188         # fix-up crypto/directory name(s)
1189         $what = "ripemd" if $what eq "rmd160";
1190         $what = "whrlpool" if $what eq "whirlpool";
1191
1192         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1193
1194         if ((grep { $what eq $_ } @{$config{sdirs}})
1195                 && $what ne 'async' && $what ne 'err') {
1196             @{$config{sdirs}} = grep { $what ne $_} @{$config{sdirs}};
1197             $disabled_info{$what}->{skipped} = [ catdir('crypto', $what) ];
1198
1199             if ($what ne 'engine') {
1200                 push @{$config{openssl_algorithm_defines}}, $macro;
1201             } else {
1202                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
1203                 push @{$disabled_info{engine}->{skipped}}, catdir('engines');
1204                 push @{$config{openssl_other_defines}}, $macro;
1205             }
1206         } else {
1207             push @{$config{openssl_other_defines}}, $macro;
1208         }
1209
1210     }
1211 }
1212
1213 # Make sure build_scheme is consistent.
1214 $target{build_scheme} = [ $target{build_scheme} ]
1215     if ref($target{build_scheme}) ne "ARRAY";
1216
1217 my ($builder, $builder_platform, @builder_opts) =
1218     @{$target{build_scheme}};
1219
1220 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1221                       $builder_platform."-checker.pm")) {
1222     my $checker_path = catfile($srcdir, "Configurations", $checker);
1223     if (-f $checker_path) {
1224         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1225             ? sub { warn $@; } : sub { die $@; };
1226         if (! do $checker_path) {
1227             if ($@) {
1228                 $fn->($@);
1229             } elsif ($!) {
1230                 $fn->($!);
1231             } else {
1232                 $fn->("The detected tools didn't match the platform\n");
1233             }
1234         }
1235         last;
1236     }
1237 }
1238
1239 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1240
1241 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1242         {
1243         push @{$config{cflags}}, "-mno-cygwin";
1244         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1245         push @{$config{shared_ldflag}}, "-mno-cygwin";
1246         }
1247
1248 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1249         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1250                                             @{$useradd{CFLAGS}})) {
1251         # minimally required architecture flags for assembly modules
1252         my $value;
1253         $value = '-mips2' if ($target =~ /mips32/);
1254         $value = '-mips3' if ($target =~ /mips64/);
1255         unshift @{$config{cflags}}, $value;
1256         unshift @{$config{cxxflags}}, $value if $config{CXX};
1257 }
1258
1259 # If threads aren't disabled, check how possible they are
1260 unless ($disabled{threads}) {
1261     if ($auto_threads) {
1262         # Enabled by default, disable it forcibly if unavailable
1263         if ($target{thread_scheme} eq "(unknown)") {
1264             $disabled{threads} = "unavailable";
1265         }
1266     } else {
1267         # The user chose to enable threads explicitly, let's see
1268         # if there's a chance that's possible
1269         if ($target{thread_scheme} eq "(unknown)") {
1270             # If the user asked for "threads" and we don't have internal
1271             # knowledge how to do it, [s]he is expected to provide any
1272             # system-dependent compiler options that are necessary.  We
1273             # can't truly check that the given options are correct, but
1274             # we expect the user to know what [s]He is doing.
1275             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1276                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1277                 die "You asked for multi-threading support, but didn't\n"
1278                     ,"provide any system-specific compiler options\n";
1279             }
1280         }
1281     }
1282 }
1283
1284 # If threads still aren't disabled, add a C macro to ensure the source
1285 # code knows about it.  Any other flag is taken care of by the configs.
1286 unless($disabled{threads}) {
1287     push @{$config{openssl_thread_defines}}, "OPENSSL_THREADS";
1288 }
1289
1290 # With "deprecated" disable all deprecated features.
1291 if (defined($disabled{"deprecated"})) {
1292         $config{api} = $maxapi;
1293 }
1294
1295 my $no_shared_warn=0;
1296 if ($target{shared_target} eq "")
1297         {
1298         $no_shared_warn = 1
1299             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1300         $disabled{shared} = "no-shared-target";
1301         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1302             "no-shared-target";
1303         }
1304
1305 if ($disabled{"dynamic-engine"}) {
1306         push @{$config{openssl_other_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1307         $config{dynamic_engines} = 0;
1308 } else {
1309         push @{$config{openssl_other_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1310         $config{dynamic_engines} = 1;
1311 }
1312
1313 unless ($disabled{asan}) {
1314     push @{$config{cflags}}, "-fsanitize=address";
1315     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1316 }
1317
1318 unless ($disabled{ubsan}) {
1319     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1320     # platforms.
1321     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1322     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1323         if $config{CXX};
1324 }
1325
1326 unless ($disabled{msan}) {
1327   push @{$config{cflags}}, "-fsanitize=memory";
1328   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1329 }
1330
1331 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1332         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1333     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1334     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1335 }
1336 #
1337 # Platform fix-ups
1338 #
1339
1340 # This saves the build files from having to check
1341 if ($disabled{pic})
1342         {
1343         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1344                     shared_defines shared_includes shared_ldflag
1345                     module_cflags module_cxxflags module_cppflags
1346                     module_defines module_includes module_lflags))
1347                 {
1348                 delete $config{$_};
1349                 $target{$_} = "";
1350                 }
1351         }
1352 else
1353         {
1354         push @{$config{lib_defines}}, "OPENSSL_PIC";
1355         }
1356
1357 if ($target{sys_id} ne "")
1358         {
1359         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1360         }
1361
1362 unless ($disabled{asm}) {
1363     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1364     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1365
1366     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1367
1368     # bn-586 is the only one implementing bn_*_part_words
1369     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1370     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1371
1372     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1373     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1374     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1375
1376     if ($target{sha1_asm_src}) {
1377         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1378         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1379         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1380     }
1381     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1382         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1383     }
1384     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1385         push @{$config{lib_defines}}, "RC4_ASM";
1386     }
1387     if ($target{md5_asm_src}) {
1388         push @{$config{lib_defines}}, "MD5_ASM";
1389     }
1390     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1391     if ($target{rmd160_asm_src}) {
1392         push @{$config{lib_defines}}, "RMD160_ASM";
1393     }
1394     if ($target{aes_asm_src}) {
1395         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1396         # aes-ctr.fake is not a real file, only indication that assembler
1397         # module implements AES_ctr32_encrypt...
1398         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1399         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1400         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1401         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1402         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1403         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1404     }
1405     if ($target{wp_asm_src} =~ /mmx/) {
1406         if ($config{processor} eq "386") {
1407             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1408         } elsif (!$disabled{"whirlpool"}) {
1409             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1410         }
1411     }
1412     if ($target{modes_asm_src} =~ /ghash-/) {
1413         push @{$config{lib_defines}}, "GHASH_ASM";
1414     }
1415     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1416         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1417     }
1418     if ($target{ec_asm_src} =~ /x25519/) {
1419         push @{$config{lib_defines}}, "X25519_ASM";
1420     }
1421     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1422         push @{$config{lib_defines}}, "PADLOCK_ASM";
1423     }
1424     if ($target{poly1305_asm_src} ne "") {
1425         push @{$config{lib_defines}}, "POLY1305_ASM";
1426     }
1427 }
1428
1429 my %predefined = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1430
1431 # Check for makedepend capabilities.
1432 if (!$disabled{makedepend}) {
1433     if ($config{target} =~ /^(VC|vms)-/) {
1434         # For VC- and vms- targets, there's nothing more to do here.  The
1435         # functionality is hard coded in the corresponding build files for
1436         # cl (Windows) and CC/DECC (VMS).
1437     } elsif (($predefined{__GNUC__} // -1) >= 3
1438              && !($predefined{__APPLE_CC__} && !$predefined{__clang__})) {
1439         # We know that GNU C version 3 and up as well as all clang
1440         # versions support dependency generation, but Xcode did not
1441         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1442         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1443     } else {
1444         # In all other cases, we look for 'makedepend', and disable the
1445         # capability if not found.
1446         $config{makedepprog} = which('makedepend');
1447         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1448     }
1449 }
1450
1451 if (!$disabled{asm} && !$predefined{__MACH__} && $^O ne 'VMS') {
1452     # probe for -Wa,--noexecstack option...
1453     if ($predefined{__clang__}) {
1454         # clang has builtin assembler, which doesn't recognize --help,
1455         # but it apparently recognizes the option in question on all
1456         # supported platforms even when it's meaningless. In other words
1457         # probe would fail, but probed option always accepted...
1458         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1459     } else {
1460         my $cc = $config{CROSS_COMPILE}.$config{CC};
1461         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1462         while(<PIPE>) {
1463             if (m/--noexecstack/) {
1464                 push @{$config{cflags}}, "-Wa,--noexecstack";
1465                 last;
1466             }
1467         }
1468         close(PIPE);
1469         unlink("null.$$.o");
1470     }
1471 }
1472
1473 # Deal with bn_ops ###################################################
1474
1475 $config{bn_ll}                  =0;
1476 $config{export_var_as_fn}       =0;
1477 my $def_int="unsigned int";
1478 $config{rc4_int}                =$def_int;
1479 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1480
1481 my $count = 0;
1482 foreach (sort split(/\s+/,$target{bn_ops})) {
1483     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1484     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1485     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1486     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1487     ($config{b64l},$config{b64},$config{b32})
1488         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1489     ($config{b64l},$config{b64},$config{b32})
1490         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1491     ($config{b64l},$config{b64},$config{b32})
1492         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1493 }
1494 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1495     if $count > 1;
1496
1497
1498 # Hack cflags for better warnings (dev option) #######################
1499
1500 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1501 # a string and works as well on command lines.
1502 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1503                         @{$config{cflags}} ];
1504 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1505                           @{$config{cxxflags}} ] if $config{CXX};
1506
1507 if (defined($config{api})) {
1508     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1509     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1510     push @{$config{defines}}, $apiflag;
1511 }
1512
1513 if ($strict_warnings)
1514         {
1515         my $wopt;
1516         my $gccver = $predefined{__GNUC__} // -1;
1517
1518         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1519             unless $gccver >= 4;
1520         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1521                 {
1522                 push @{$config{cflags}}, $wopt
1523                         unless grep { $_ eq $wopt } @{$config{cflags}};
1524                 push @{$config{cxxflags}}, $wopt
1525                         if ($config{CXX}
1526                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1527                 }
1528         if (defined($predefined{__clang__}))
1529                 {
1530                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1531                         {
1532                         push @{$config{cflags}}, $wopt
1533                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1534                         push @{$config{cxxflags}}, $wopt
1535                                 if ($config{CXX}
1536                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1537                         }
1538                 }
1539         }
1540
1541 unless ($disabled{"crypto-mdebug-backtrace"})
1542         {
1543         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1544                 {
1545                 push @{$config{cflags}}, $wopt
1546                         unless grep { $_ eq $wopt } @{$config{cflags}};
1547                 push @{$config{cxxflags}}, $wopt
1548                         if ($config{CXX}
1549                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1550                 }
1551         if ($target =~ /^BSD-/)
1552                 {
1553                 push @{$config{ex_libs}}, "-lexecinfo";
1554                 }
1555         }
1556
1557 unless ($disabled{afalgeng}) {
1558     $config{afalgeng}="";
1559     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1560         my $minver = 4*10000 + 1*100 + 0;
1561         if ($config{CROSS_COMPILE} eq "") {
1562             my $verstr = `uname -r`;
1563             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1564             ($mi2) = $mi2 =~ /(\d+)/;
1565             my $ver = $ma*10000 + $mi1*100 + $mi2;
1566             if ($ver < $minver) {
1567                 $disabled{afalgeng} = "too-old-kernel";
1568             } else {
1569                 push @{$config{engdirs}}, "afalg";
1570             }
1571         } else {
1572             $disabled{afalgeng} = "cross-compiling";
1573         }
1574     } else {
1575         $disabled{afalgeng}  = "not-linux";
1576     }
1577 }
1578
1579 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1580
1581 # Finish up %config by appending things the user gave us on the command line
1582 # apart from "make variables"
1583 foreach (keys %useradd) {
1584     # The must all be lists, so we assert that here
1585     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1586         unless ref $useradd{$_} eq 'ARRAY';
1587
1588     if (defined $config{$_}) {
1589         push @{$config{$_}}, @{$useradd{$_}};
1590     } else {
1591         $config{$_} = [ @{$useradd{$_}} ];
1592     }
1593 }
1594
1595 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1596
1597 # If we use the unified build, collect information from build.info files
1598 my %unified_info = ();
1599
1600 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1601 if ($builder eq "unified") {
1602     use with_fallback qw(Text::Template);
1603
1604     sub cleandir {
1605         my $base = shift;
1606         my $dir = shift;
1607         my $relativeto = shift || ".";
1608
1609         $dir = catdir($base,$dir) unless isabsolute($dir);
1610
1611         # Make sure the directories we're building in exists
1612         mkpath($dir);
1613
1614         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1615         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1616         return $res;
1617     }
1618
1619     sub cleanfile {
1620         my $base = shift;
1621         my $file = shift;
1622         my $relativeto = shift || ".";
1623
1624         $file = catfile($base,$file) unless isabsolute($file);
1625
1626         my $d = dirname($file);
1627         my $f = basename($file);
1628
1629         # Make sure the directories we're building in exists
1630         mkpath($d);
1631
1632         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1633         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1634         return $res;
1635     }
1636
1637     # Store the name of the template file we will build the build file from
1638     # in %config.  This may be useful for the build file itself.
1639     my @build_file_template_names =
1640         ( $builder_platform."-".$target{build_file}.".tmpl",
1641           $target{build_file}.".tmpl" );
1642     my @build_file_templates = ();
1643
1644     # First, look in the user provided directory, if given
1645     if (defined env($local_config_envname)) {
1646         @build_file_templates =
1647             map {
1648                 if ($^O eq 'VMS') {
1649                     # VMS environment variables are logical names,
1650                     # which can be used as is
1651                     $local_config_envname . ':' . $_;
1652                 } else {
1653                     catfile(env($local_config_envname), $_);
1654                 }
1655             }
1656             @build_file_template_names;
1657     }
1658     # Then, look in our standard directory
1659     push @build_file_templates,
1660         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1661           @build_file_template_names );
1662
1663     my $build_file_template;
1664     for $_ (@build_file_templates) {
1665         $build_file_template = $_;
1666         last if -f $build_file_template;
1667
1668         $build_file_template = undef;
1669     }
1670     if (!defined $build_file_template) {
1671         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1672     }
1673     $config{build_file_templates}
1674       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1675                     $blddir),
1676           $build_file_template,
1677           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1678                     $blddir) ];
1679
1680     my @build_infos = ( [ ".", "build.info" ] );
1681     foreach (@{$config{dirs}}) {
1682         push @build_infos, [ $_, "build.info" ]
1683             if (-f catfile($srcdir, $_, "build.info"));
1684     }
1685     foreach (@{$config{sdirs}}) {
1686         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1687             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1688     }
1689     foreach (@{$config{engdirs}}) {
1690         push @build_infos, [ catdir("engines", $_), "build.info" ]
1691             if (-f catfile($srcdir, "engines", $_, "build.info"));
1692     }
1693     foreach (@{$config{tdirs}}) {
1694         push @build_infos, [ catdir("test", $_), "build.info" ]
1695             if (-f catfile($srcdir, "test", $_, "build.info"));
1696     }
1697
1698     $config{build_infos} = [ ];
1699
1700     my %ordinals = ();
1701     foreach (@build_infos) {
1702         my $sourced = catdir($srcdir, $_->[0]);
1703         my $buildd = catdir($blddir, $_->[0]);
1704
1705         mkpath($buildd);
1706
1707         my $f = $_->[1];
1708         # The basic things we're trying to build
1709         my @programs = ();
1710         my @programs_install = ();
1711         my @libraries = ();
1712         my @libraries_install = ();
1713         my @engines = ();
1714         my @engines_install = ();
1715         my @scripts = ();
1716         my @scripts_install = ();
1717         my @extra = ();
1718         my @overrides = ();
1719         my @intermediates = ();
1720         my @rawlines = ();
1721
1722         my %sources = ();
1723         my %shared_sources = ();
1724         my %includes = ();
1725         my %defines = ();
1726         my %depends = ();
1727         my %renames = ();
1728         my %sharednames = ();
1729         my %generate = ();
1730
1731         # We want to detect configdata.pm in the source tree, so we
1732         # don't use it if the build tree is different.
1733         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1734
1735         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1736         my $template =
1737             Text::Template->new(TYPE => 'FILE',
1738                                 SOURCE => catfile($sourced, $f),
1739                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1740         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1741         my @text =
1742             split /^/m,
1743             $template->fill_in(HASH => { config => \%config,
1744                                          target => \%target,
1745                                          disabled => \%disabled,
1746                                          withargs => \%withargs,
1747                                          builddir => abs2rel($buildd, $blddir),
1748                                          sourcedir => abs2rel($sourced, $blddir),
1749                                          buildtop => abs2rel($blddir, $blddir),
1750                                          sourcetop => abs2rel($srcdir, $blddir) },
1751                                DELIMITERS => [ "{-", "-}" ]);
1752
1753         # The top item of this stack has the following values
1754         # -2 positive already run and we found ELSE (following ELSIF should fail)
1755         # -1 positive already run (skip until ENDIF)
1756         # 0 negatives so far (if we're at a condition, check it)
1757         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1758         # 2 positive ELSE (following ELSIF should fail)
1759         my @skip = ();
1760         collect_information(
1761             collect_from_array([ @text ],
1762                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1763                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1764             # Info we're looking for
1765             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1766             => sub {
1767                 if (! @skip || $skip[$#skip] > 0) {
1768                     push @skip, !! $1;
1769                 } else {
1770                     push @skip, -1;
1771                 }
1772             },
1773             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1774             => sub { die "ELSIF out of scope" if ! @skip;
1775                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1776                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1777                      $skip[$#skip] = !! $1
1778                          if $skip[$#skip] == 0; },
1779             qr/^\s*ELSE\s*$/
1780             => sub { die "ELSE out of scope" if ! @skip;
1781                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1782                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1783             qr/^\s*ENDIF\s*$/
1784             => sub { die "ENDIF out of scope" if ! @skip;
1785                      pop @skip; },
1786             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1787             => sub {
1788                 if (!@skip || $skip[$#skip] > 0) {
1789                     my $install = $1;
1790                     my @x = tokenize($2);
1791                     push @programs, @x;
1792                     push @programs_install, @x unless $install;
1793                 }
1794             },
1795             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1796             => sub {
1797                 if (!@skip || $skip[$#skip] > 0) {
1798                     my $install = $1;
1799                     my @x = tokenize($2);
1800                     push @libraries, @x;
1801                     push @libraries_install, @x unless $install;
1802                 }
1803             },
1804             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1805             => sub {
1806                 if (!@skip || $skip[$#skip] > 0) {
1807                     my $install = $1;
1808                     my @x = tokenize($2);
1809                     push @engines, @x;
1810                     push @engines_install, @x unless $install;
1811                 }
1812             },
1813             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1814             => sub {
1815                 if (!@skip || $skip[$#skip] > 0) {
1816                     my $install = $1;
1817                     my @x = tokenize($2);
1818                     push @scripts, @x;
1819                     push @scripts_install, @x unless $install;
1820                 }
1821             },
1822             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1823             => sub { push @extra, tokenize($1)
1824                          if !@skip || $skip[$#skip] > 0 },
1825             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1826             => sub { push @overrides, tokenize($1)
1827                          if !@skip || $skip[$#skip] > 0 },
1828
1829             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1830             => sub { push @{$ordinals{$1}}, tokenize($2)
1831                          if !@skip || $skip[$#skip] > 0 },
1832             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1833             => sub { push @{$sources{$1}}, tokenize($2)
1834                          if !@skip || $skip[$#skip] > 0 },
1835             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1836             => sub { push @{$shared_sources{$1}}, tokenize($2)
1837                          if !@skip || $skip[$#skip] > 0 },
1838             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1839             => sub { push @{$includes{$1}}, tokenize($2)
1840                          if !@skip || $skip[$#skip] > 0 },
1841             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1842             => sub { push @{$defines{$1}}, tokenize($2)
1843                          if !@skip || $skip[$#skip] > 0 },
1844             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1845             => sub { push @{$depends{$1}}, tokenize($2)
1846                          if !@skip || $skip[$#skip] > 0 },
1847             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1848             => sub { push @{$generate{$1}}, $2
1849                          if !@skip || $skip[$#skip] > 0 },
1850             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1851             => sub { push @{$renames{$1}}, tokenize($2)
1852                          if !@skip || $skip[$#skip] > 0 },
1853             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1854             => sub { push @{$sharednames{$1}}, tokenize($2)
1855                          if !@skip || $skip[$#skip] > 0 },
1856             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1857             => sub {
1858                 my $lineiterator = shift;
1859                 my $target_kind = $1;
1860                 while (defined $lineiterator->()) {
1861                     s|\R$||;
1862                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1863                         die "ENDRAW doesn't match BEGINRAW"
1864                             if $1 ne $target_kind;
1865                         last;
1866                     }
1867                     next if @skip && $skip[$#skip] <= 0;
1868                     push @rawlines,  $_
1869                         if ($target_kind eq $target{build_file}
1870                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1871                 }
1872             },
1873             qr/^\s*(?:#.*)?$/ => sub { },
1874             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1875             "BEFORE" => sub {
1876                 if ($buildinfo_debug) {
1877                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1878                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1879                 }
1880             },
1881             "AFTER" => sub {
1882                 if ($buildinfo_debug) {
1883                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1884                 }
1885             },
1886             );
1887         die "runaway IF?" if (@skip);
1888
1889         foreach (keys %renames) {
1890             die "$_ renamed to more than one thing: "
1891                 ,join(" ", @{$renames{$_}}),"\n"
1892                 if scalar @{$renames{$_}} > 1;
1893             my $dest = cleanfile($buildd, $_, $blddir);
1894             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1895             die "$dest renamed to more than one thing: "
1896                 ,$unified_info{rename}->{$dest}, $to
1897                 unless !defined($unified_info{rename}->{$dest})
1898                 or $unified_info{rename}->{$dest} eq $to;
1899             $unified_info{rename}->{$dest} = $to;
1900         }
1901
1902         foreach (@programs) {
1903             my $program = cleanfile($buildd, $_, $blddir);
1904             if ($unified_info{rename}->{$program}) {
1905                 $program = $unified_info{rename}->{$program};
1906             }
1907             $unified_info{programs}->{$program} = 1;
1908         }
1909
1910         foreach (@programs_install) {
1911             my $program = cleanfile($buildd, $_, $blddir);
1912             if ($unified_info{rename}->{$program}) {
1913                 $program = $unified_info{rename}->{$program};
1914             }
1915             $unified_info{install}->{programs}->{$program} = 1;
1916         }
1917
1918         foreach (@libraries) {
1919             my $library = cleanfile($buildd, $_, $blddir);
1920             if ($unified_info{rename}->{$library}) {
1921                 $library = $unified_info{rename}->{$library};
1922             }
1923             $unified_info{libraries}->{$library} = 1;
1924         }
1925
1926         foreach (@libraries_install) {
1927             my $library = cleanfile($buildd, $_, $blddir);
1928             if ($unified_info{rename}->{$library}) {
1929                 $library = $unified_info{rename}->{$library};
1930             }
1931             $unified_info{install}->{libraries}->{$library} = 1;
1932         }
1933
1934         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1935 ENGINES can only be used if configured with 'dynamic-engine'.
1936 This is usually a fault in a build.info file.
1937 EOF
1938         foreach (@engines) {
1939             my $library = cleanfile($buildd, $_, $blddir);
1940             if ($unified_info{rename}->{$library}) {
1941                 $library = $unified_info{rename}->{$library};
1942             }
1943             $unified_info{engines}->{$library} = 1;
1944         }
1945
1946         foreach (@engines_install) {
1947             my $library = cleanfile($buildd, $_, $blddir);
1948             if ($unified_info{rename}->{$library}) {
1949                 $library = $unified_info{rename}->{$library};
1950             }
1951             $unified_info{install}->{engines}->{$library} = 1;
1952         }
1953
1954         foreach (@scripts) {
1955             my $script = cleanfile($buildd, $_, $blddir);
1956             if ($unified_info{rename}->{$script}) {
1957                 $script = $unified_info{rename}->{$script};
1958             }
1959             $unified_info{scripts}->{$script} = 1;
1960         }
1961
1962         foreach (@scripts_install) {
1963             my $script = cleanfile($buildd, $_, $blddir);
1964             if ($unified_info{rename}->{$script}) {
1965                 $script = $unified_info{rename}->{$script};
1966             }
1967             $unified_info{install}->{scripts}->{$script} = 1;
1968         }
1969
1970         foreach (@extra) {
1971             my $extra = cleanfile($buildd, $_, $blddir);
1972             $unified_info{extra}->{$extra} = 1;
1973         }
1974
1975         foreach (@overrides) {
1976             my $override = cleanfile($buildd, $_, $blddir);
1977             $unified_info{overrides}->{$override} = 1;
1978         }
1979
1980         push @{$unified_info{rawlines}}, @rawlines;
1981
1982         unless ($disabled{shared}) {
1983             # Check sharednames.
1984             foreach (keys %sharednames) {
1985                 my $dest = cleanfile($buildd, $_, $blddir);
1986                 if ($unified_info{rename}->{$dest}) {
1987                     $dest = $unified_info{rename}->{$dest};
1988                 }
1989                 die "shared_name for $dest with multiple values: "
1990                     ,join(" ", @{$sharednames{$_}}),"\n"
1991                     if scalar @{$sharednames{$_}} > 1;
1992                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1993                 die "shared_name found for a library $dest that isn't defined\n"
1994                     unless $unified_info{libraries}->{$dest};
1995                 die "shared_name for $dest with multiple values: "
1996                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1997                     unless !defined($unified_info{sharednames}->{$dest})
1998                     or $unified_info{sharednames}->{$dest} eq $to;
1999                 $unified_info{sharednames}->{$dest} = $to;
2000             }
2001
2002             # Additionally, we set up sharednames for libraries that don't
2003             # have any, as themselves.  Only for libraries that aren't
2004             # explicitly static.
2005             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
2006                 if (!defined $unified_info{sharednames}->{$_}) {
2007                     $unified_info{sharednames}->{$_} = $_
2008                 }
2009             }
2010
2011             # Check that we haven't defined any library as both shared and
2012             # explicitly static.  That is forbidden.
2013             my @doubles = ();
2014             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2015                 (my $l = $_) =~ s/\.a$//;
2016                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
2017             }
2018             die "these libraries are both explicitly static and shared:\n  ",
2019                 join(" ", @doubles), "\n"
2020                 if @doubles;
2021         }
2022
2023         foreach (keys %sources) {
2024             my $dest = $_;
2025             my $ddest = cleanfile($buildd, $_, $blddir);
2026             if ($unified_info{rename}->{$ddest}) {
2027                 $ddest = $unified_info{rename}->{$ddest};
2028             }
2029             foreach (@{$sources{$dest}}) {
2030                 my $s = cleanfile($sourced, $_, $blddir);
2031
2032                 # If it isn't in the source tree, we assume it's generated
2033                 # in the build tree
2034                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2035                     $s = cleanfile($buildd, $_, $blddir);
2036                 }
2037                 # We recognise C++, C and asm files
2038                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2039                     my $o = $_;
2040                     $o =~ s/\.[csS]$/.o/; # C and assembler
2041                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2042                     $o = cleanfile($buildd, $o, $blddir);
2043                     $unified_info{sources}->{$ddest}->{$o} = -1;
2044                     $unified_info{sources}->{$o}->{$s} = -1;
2045                 } elsif ($s =~ /\.rc$/) {
2046                     # We also recognise resource files
2047                     my $o = $_;
2048                     $o =~ s/\.rc$/.res/; # Resource configuration
2049                     my $o = cleanfile($buildd, $o, $blddir);
2050                     $unified_info{sources}->{$ddest}->{$o} = -1;
2051                     $unified_info{sources}->{$o}->{$s} = -1;
2052                 } else {
2053                     $unified_info{sources}->{$ddest}->{$s} = 1;
2054                 }
2055             }
2056         }
2057
2058         foreach (keys %shared_sources) {
2059             my $dest = $_;
2060             my $ddest = cleanfile($buildd, $_, $blddir);
2061             if ($unified_info{rename}->{$ddest}) {
2062                 $ddest = $unified_info{rename}->{$ddest};
2063             }
2064             foreach (@{$shared_sources{$dest}}) {
2065                 my $s = cleanfile($sourced, $_, $blddir);
2066
2067                 # If it isn't in the source tree, we assume it's generated
2068                 # in the build tree
2069                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2070                     $s = cleanfile($buildd, $_, $blddir);
2071                 }
2072
2073                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2074                     # We recognise C++, C and asm files
2075                     my $o = $_;
2076                     $o =~ s/\.[csS]$/.o/; # C and assembler
2077                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2078                     $o = cleanfile($buildd, $o, $blddir);
2079                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2080                     $unified_info{sources}->{$o}->{$s} = -1;
2081                 } elsif ($s =~ /\.rc$/) {
2082                     # We also recognise resource files
2083                     my $o = $_;
2084                     $o =~ s/\.rc$/.res/; # Resource configuration
2085                     my $o = cleanfile($buildd, $o, $blddir);
2086                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2087                     $unified_info{sources}->{$o}->{$s} = -1;
2088                 } elsif ($s =~ /\.ld$/) {
2089                     # We also recognise linker scripts (or corresponding)
2090                     # We know they are generated files
2091                     my $ld = cleanfile($buildd, $_, $blddir);
2092                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2093                 } else {
2094                     die "unrecognised source file type for shared library: $s\n";
2095                 }
2096             }
2097         }
2098
2099         foreach (keys %generate) {
2100             my $dest = $_;
2101             my $ddest = cleanfile($buildd, $_, $blddir);
2102             if ($unified_info{rename}->{$ddest}) {
2103                 $ddest = $unified_info{rename}->{$ddest};
2104             }
2105             die "more than one generator for $dest: "
2106                     ,join(" ", @{$generate{$_}}),"\n"
2107                     if scalar @{$generate{$_}} > 1;
2108             my @generator = split /\s+/, $generate{$dest}->[0];
2109             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2110             $unified_info{generate}->{$ddest} = [ @generator ];
2111         }
2112
2113         foreach (keys %depends) {
2114             my $dest = $_;
2115             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2116
2117             # If the destination doesn't exist in source, it can only be
2118             # a generated file in the build tree.
2119             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2120                 $ddest = cleanfile($buildd, $_, $blddir);
2121                 if ($unified_info{rename}->{$ddest}) {
2122                     $ddest = $unified_info{rename}->{$ddest};
2123                 }
2124             }
2125             foreach (@{$depends{$dest}}) {
2126                 my $d = cleanfile($sourced, $_, $blddir);
2127
2128                 # If we know it's generated, or assume it is because we can't
2129                 # find it in the source tree, we set file we depend on to be
2130                 # in the build tree rather than the source tree, and assume
2131                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2132                 # section or in the Makefile template.
2133                 if ($d eq $src_configdata
2134                     || ! -f $d
2135                     || (grep { $d eq $_ }
2136                         map { cleanfile($srcdir, $_, $blddir) }
2137                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2138                     $d = cleanfile($buildd, $_, $blddir);
2139                 }
2140                 # Take note if the file to depend on is being renamed
2141                 # Take extra care with files ending with .a, they should
2142                 # be treated without that extension, and the extension
2143                 # should be added back after treatment.
2144                 $d =~ /(\.a)?$/;
2145                 my $e = $1 // "";
2146                 $d = $`;
2147                 if ($unified_info{rename}->{$d}) {
2148                     $d = $unified_info{rename}->{$d};
2149                 }
2150                 $d .= $e;
2151                 $unified_info{depends}->{$ddest}->{$d} = 1;
2152             }
2153         }
2154
2155         foreach (keys %includes) {
2156             my $dest = $_;
2157             my $ddest = cleanfile($sourced, $_, $blddir);
2158
2159             # If the destination doesn't exist in source, it can only be
2160             # a generated file in the build tree.
2161             if ($ddest eq $src_configdata || ! -f $ddest) {
2162                 $ddest = cleanfile($buildd, $_, $blddir);
2163                 if ($unified_info{rename}->{$ddest}) {
2164                     $ddest = $unified_info{rename}->{$ddest};
2165                 }
2166             }
2167             foreach (@{$includes{$dest}}) {
2168                 my $is = cleandir($sourced, $_, $blddir);
2169                 my $ib = cleandir($buildd, $_, $blddir);
2170                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2171                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2172                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2173                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2174             }
2175         }
2176
2177         foreach (keys %defines) {
2178             my $dest = $_;
2179             my $ddest = cleanfile($sourced, $_, $blddir);
2180
2181             # If the destination doesn't exist in source, it can only be
2182             # a generated file in the build tree.
2183             if (! -f $ddest) {
2184                 $ddest = cleanfile($buildd, $_, $blddir);
2185                 if ($unified_info{rename}->{$ddest}) {
2186                     $ddest = $unified_info{rename}->{$ddest};
2187                 }
2188             }
2189             foreach (@{$defines{$dest}}) {
2190                 m|^([^=]*)(=.*)?$|;
2191                 die "0 length macro name not permitted\n" if $1 eq "";
2192                 die "$1 defined more than once\n"
2193                     if defined $unified_info{defines}->{$ddest}->{$1};
2194                 $unified_info{defines}->{$ddest}->{$1} = $2;
2195             }
2196         }
2197     }
2198
2199     my $ordinals_text = join(', ', sort keys %ordinals);
2200     warn <<"EOF" if $ordinals_text;
2201
2202 WARNING: ORDINALS were specified for $ordinals_text
2203 They are ignored and should be replaced with a combination of GENERATE,
2204 DEPEND and SHARED_SOURCE.
2205 EOF
2206
2207     # Massage the result
2208
2209     # If we depend on a header file or a perl module, add an inclusion of
2210     # its directory to allow smoothe inclusion
2211     foreach my $dest (keys %{$unified_info{depends}}) {
2212         next if $dest eq "";
2213         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2214             next unless $d =~ /\.(h|pm)$/;
2215             my $i = dirname($d);
2216             my $spot =
2217                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2218                 ? 'build' : 'source';
2219             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2220                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2221         }
2222     }
2223
2224     # Go through all intermediary files and change their names to something that
2225     # reflects what they will be built for.  Note that for some source files,
2226     # this leads to duplicate object files because they are used multiple times.
2227     # the goal is to rename all object files according to this scheme:
2228     #    {productname}-{midfix}-{origobjname}.[o|res]
2229     # the {midfix} is a keyword indicating the type of product, which is mostly
2230     # valuable for libraries since they come in two forms.
2231     #
2232     # This also reorganises the {sources} and {shared_sources} so that the
2233     # former only contains ALL object files that are supposed to end up in
2234     # static libraries and programs, while the latter contains ALL object files
2235     # that are supposed to end up in shared libraries and DSOs.
2236     # The main reason for having two different source structures is to allow
2237     # the same name to be used for the static and the shared variants of a
2238     # library.
2239     {
2240         # Take copies so we don't get interference from added stuff
2241         my %unified_copy = ();
2242         foreach (('sources', 'shared_sources')) {
2243             $unified_copy{$_} = { %{$unified_info{$_}} }
2244                 if defined($unified_info{$_});
2245             delete $unified_info{$_};
2246         }
2247         foreach my $prodtype (('programs', 'libraries', 'engines', 'scripts')) {
2248             # $intent serves multi purposes:
2249             # - give a prefix for the new object files names
2250             # - in the case of libraries, rearrange the object files so static
2251             #   libraries use the 'sources' structure exclusively, while shared
2252             #   libraries use the 'shared_sources' structure exclusively.
2253             my $intent = {
2254                 programs  => { bin    => { src => [ 'sources' ],
2255                                            dst => 'sources' } },
2256                 libraries => { lib    => { src => [ 'sources' ],
2257                                            dst => 'sources' },
2258                                shlib  => { prodselect =>
2259                                                sub { grep !/\.a$/, @_ },
2260                                            src => [ 'sources',
2261                                                     'shared_sources' ],
2262                                            dst => 'shared_sources' } },
2263                 engines   => { dso    => { src => [ 'sources',
2264                                                     'shared_sources' ],
2265                                            dst => 'shared_sources' } },
2266                 scripts   => { script => { src => [ 'sources' ],
2267                                            dst => 'sources' } }
2268                } -> {$prodtype};
2269             foreach my $kind (keys %$intent) {
2270                 my @src = @{$intent->{$kind}->{src}};
2271                 my $dst = $intent->{$kind}->{dst};
2272                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2273                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2274                     # %prod_sources has all applicable objects as keys, and
2275                     # their corresponding sources as values
2276                     my %prod_sources =
2277                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2278                         map { keys %{$unified_copy{$_}->{$prod}} }
2279                         @src;
2280                     foreach (keys %prod_sources) {
2281                         # Only affect object files and resource files,
2282                         # the others simply get a new value
2283                         # (+1 instead of -1)
2284                         if ($_ =~ /\.(o|res)$/) {
2285                             (my $prodname = $prod) =~ s|\.a$||;
2286                             my $newobj =
2287                                 catfile(dirname($_),
2288                                         basename($prodname)
2289                                             . '-' . $kind
2290                                             . '-' . basename($_));
2291                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2292                             foreach my $src (@{$prod_sources{$_}}) {
2293                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2294                             }
2295                             # Adjust dependencies
2296                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2297                                 $unified_info{depends}->{$_}->{$deps} = -1;
2298                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2299                             }
2300                             # Adjust includes
2301                             foreach my $k (('source', 'build')) {
2302                                 next unless
2303                                     defined($unified_info{includes}->{$_}->{$k});
2304                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2305                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2306                             }
2307                         } else {
2308                             $unified_info{$dst}->{$prod}->{$_} = 1;
2309                         }
2310                     }
2311                 }
2312             }
2313         }
2314     }
2315     # At this point, we have a number of sources with the value -1.  They
2316     # aren't part of the local build and are probably meant for a different
2317     # platform, and can therefore be cleaned away.  That happens when making
2318     # %unified_info more efficient below.
2319
2320     ### Make unified_info a bit more efficient
2321     # One level structures
2322     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2323         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2324     }
2325     # Two level structures
2326     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2327         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2328             my @items =
2329                 sort
2330                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2331                 keys %{$unified_info{$l1}->{$l2}};
2332             if (@items) {
2333                 $unified_info{$l1}->{$l2} = [ @items ];
2334             } else {
2335                 delete $unified_info{$l1}->{$l2};
2336             }
2337         }
2338     }
2339     # Defines
2340     foreach my $dest (sort keys %{$unified_info{defines}}) {
2341         $unified_info{defines}->{$dest}
2342             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2343                 sort keys %{$unified_info{defines}->{$dest}} ];
2344     }
2345     # Includes
2346     foreach my $dest (sort keys %{$unified_info{includes}}) {
2347         if (defined($unified_info{includes}->{$dest}->{build})) {
2348             my @source_includes = ();
2349             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2350                 if defined($unified_info{includes}->{$dest}->{source});
2351             $unified_info{includes}->{$dest} =
2352                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2353             foreach my $inc (@source_includes) {
2354                 push @{$unified_info{includes}->{$dest}}, $inc
2355                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2356             }
2357         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2358             $unified_info{includes}->{$dest} =
2359                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2360         } else {
2361             delete $unified_info{includes}->{$dest};
2362         }
2363     }
2364
2365     # For convenience collect information regarding directories where
2366     # files are generated, those generated files and the end product
2367     # they end up in where applicable.  Then, add build rules for those
2368     # directories
2369     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2370                      "dso" => [ @{$unified_info{engines}} ],
2371                      "bin" => [ @{$unified_info{programs}} ],
2372                      "script" => [ @{$unified_info{scripts}} ] );
2373     foreach my $type (keys %loopinfo) {
2374         foreach my $product (@{$loopinfo{$type}}) {
2375             my %dirs = ();
2376             my $pd = dirname($product);
2377
2378             foreach (@{$unified_info{sources}->{$product} // []},
2379                      @{$unified_info{shared_sources}->{$product} // []}) {
2380                 my $d = dirname($_);
2381
2382                 # We don't want to create targets for source directories
2383                 # when building out of source
2384                 next if ($config{sourcedir} ne $config{builddir}
2385                              && $d =~ m|^\Q$config{sourcedir}\E|);
2386                 # We already have a "test" target, and the current directory
2387                 # is just silly to make a target for
2388                 next if $d eq "test" || $d eq ".";
2389
2390                 $dirs{$d} = 1;
2391                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2392                     if $d ne $pd;
2393             }
2394             foreach (keys %dirs) {
2395                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2396                     $product;
2397             }
2398         }
2399     }
2400 }
2401
2402 # For the schemes that need it, we provide the old *_obj configs
2403 # from the *_asm_obj ones
2404 foreach (grep /_(asm|aux)_src$/, keys %target) {
2405     my $src = $_;
2406     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2407     $target{$obj} = $target{$src};
2408     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2409     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2410 }
2411
2412 # Write down our configuration where it fits #########################
2413
2414 print "Creating configdata.pm\n";
2415 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2416 print OUT <<"EOF";
2417 #! $config{HASHBANGPERL}
2418
2419 package configdata;
2420
2421 use strict;
2422 use warnings;
2423
2424 use Exporter;
2425 #use vars qw(\@ISA \@EXPORT);
2426 our \@ISA = qw(Exporter);
2427 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2428
2429 EOF
2430 print OUT "our %config = (\n";
2431 foreach (sort keys %config) {
2432     if (ref($config{$_}) eq "ARRAY") {
2433         print OUT "  ", $_, " => [ ", join(", ",
2434                                            map { quotify("perl", $_) }
2435                                            @{$config{$_}}), " ],\n";
2436     } elsif (ref($config{$_}) eq "HASH") {
2437         print OUT "  ", $_, " => {";
2438         if (scalar keys %{$config{$_}} > 0) {
2439             print OUT "\n";
2440             foreach my $key (sort keys %{$config{$_}}) {
2441                 print OUT "      ",
2442                     join(" => ",
2443                          quotify("perl", $key),
2444                          defined $config{$_}->{$key}
2445                              ? quotify("perl", $config{$_}->{$key})
2446                              : "undef");
2447                 print OUT ",\n";
2448             }
2449             print OUT "  ";
2450         }
2451         print OUT "},\n";
2452     } else {
2453         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2454     }
2455 }
2456 print OUT <<"EOF";
2457 );
2458
2459 EOF
2460 print OUT "our %target = (\n";
2461 foreach (sort keys %target) {
2462     if (ref($target{$_}) eq "ARRAY") {
2463         print OUT "  ", $_, " => [ ", join(", ",
2464                                            map { quotify("perl", $_) }
2465                                            @{$target{$_}}), " ],\n";
2466     } else {
2467         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2468     }
2469 }
2470 print OUT <<"EOF";
2471 );
2472
2473 EOF
2474 print OUT "our \%available_protocols = (\n";
2475 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2476 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2477 print OUT <<"EOF";
2478 );
2479
2480 EOF
2481 print OUT "our \@disablables = (\n";
2482 foreach (@disablables) {
2483     print OUT "  ", quotify("perl", $_), ",\n";
2484 }
2485 print OUT <<"EOF";
2486 );
2487
2488 EOF
2489 print OUT "our \%disabled = (\n";
2490 foreach (sort keys %disabled) {
2491     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2492 }
2493 print OUT <<"EOF";
2494 );
2495
2496 EOF
2497 print OUT "our %withargs = (\n";
2498 foreach (sort keys %withargs) {
2499     if (ref($withargs{$_}) eq "ARRAY") {
2500         print OUT "  ", $_, " => [ ", join(", ",
2501                                            map { quotify("perl", $_) }
2502                                            @{$withargs{$_}}), " ],\n";
2503     } else {
2504         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2505     }
2506 }
2507 print OUT <<"EOF";
2508 );
2509
2510 EOF
2511 if ($builder eq "unified") {
2512     my $recurse;
2513     $recurse = sub {
2514         my $indent = shift;
2515         foreach (@_) {
2516             if (ref $_ eq "ARRAY") {
2517                 print OUT " "x$indent, "[\n";
2518                 foreach (@$_) {
2519                     $recurse->($indent + 4, $_);
2520                 }
2521                 print OUT " "x$indent, "],\n";
2522             } elsif (ref $_ eq "HASH") {
2523                 my %h = %$_;
2524                 print OUT " "x$indent, "{\n";
2525                 foreach (sort keys %h) {
2526                     if (ref $h{$_} eq "") {
2527                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2528                     } else {
2529                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2530                         $recurse->($indent + 8, $h{$_});
2531                     }
2532                 }
2533                 print OUT " "x$indent, "},\n";
2534             } else {
2535                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2536             }
2537         }
2538     };
2539     print OUT "our %unified_info = (\n";
2540     foreach (sort keys %unified_info) {
2541         if (ref $unified_info{$_} eq "") {
2542             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2543         } else {
2544             print OUT " "x4, quotify("perl", $_), " =>\n";
2545             $recurse->(8, $unified_info{$_});
2546         }
2547     }
2548     print OUT <<"EOF";
2549 );
2550
2551 EOF
2552 }
2553 print OUT
2554     "# The following data is only used when this files is use as a script\n";
2555 print OUT "my \@makevars = (\n";
2556 foreach (sort keys %user) {
2557     print OUT "    '",$_,"',\n";
2558 }
2559 print OUT ");\n";
2560 print OUT "my \%disabled_info = (\n";
2561 foreach my $what (sort keys %disabled_info) {
2562     print OUT "    '$what' => {\n";
2563     foreach my $info (sort keys %{$disabled_info{$what}}) {
2564         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2565             print OUT "        $info => [ ",
2566                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2567                 " ],\n";
2568         } else {
2569             print OUT "        $info => '", $disabled_info{$what}->{$info},
2570                 "',\n";
2571         }
2572     }
2573     print OUT "    },\n";
2574 }
2575 print OUT ");\n";
2576 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2577 print OUT << 'EOF';
2578 # If run directly, we can give some answers, and even reconfigure
2579 unless (caller) {
2580     use Getopt::Long;
2581     use File::Spec::Functions;
2582     use File::Basename;
2583     use Pod::Usage;
2584
2585     my $here = dirname($0);
2586
2587     my $dump = undef;
2588     my $cmdline = undef;
2589     my $options = undef;
2590     my $target = undef;
2591     my $envvars = undef;
2592     my $makevars = undef;
2593     my $buildparams = undef;
2594     my $reconf = undef;
2595     my $verbose = undef;
2596     my $help = undef;
2597     my $man = undef;
2598     GetOptions('dump|d'                 => \$dump,
2599                'command-line|c'         => \$cmdline,
2600                'options|o'              => \$options,
2601                'target|t'               => \$target,
2602                'environment|e'          => \$envvars,
2603                'make-variables|m'       => \$makevars,
2604                'build-parameters|b'     => \$buildparams,
2605                'reconfigure|reconf|r'   => \$reconf,
2606                'verbose|v'              => \$verbose,
2607                'help'                   => \$help,
2608                'man'                    => \$man)
2609         or die "Errors in command line arguments\n";
2610
2611     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2612             || $buildparams || $reconf || $verbose || $help || $man) {
2613         print STDERR <<"_____";
2614 You must give at least one option.
2615 For more information, do '$0 --help'
2616 _____
2617         exit(2);
2618     }
2619
2620     if ($help) {
2621         pod2usage(-exitval => 0,
2622                   -verbose => 1);
2623     }
2624     if ($man) {
2625         pod2usage(-exitval => 0,
2626                   -verbose => 2);
2627     }
2628     if ($dump || $cmdline) {
2629         print "\nCommand line (with current working directory = $here):\n\n";
2630         print '    ',join(' ',
2631                           $config{PERL},
2632                           catfile($config{sourcedir}, 'Configure'),
2633                           @{$config{perlargv}}), "\n";
2634         print "\nPerl information:\n\n";
2635         print '    ',$config{perl_cmd},"\n";
2636         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2637     }
2638     if ($dump || $options) {
2639         my $longest = 0;
2640         my $longest2 = 0;
2641         foreach my $what (@disablables) {
2642             $longest = length($what) if $longest < length($what);
2643             $longest2 = length($disabled{$what})
2644                 if $disabled{$what} && $longest2 < length($disabled{$what});
2645         }
2646         print "\nEnabled features:\n\n";
2647         foreach my $what (@disablables) {
2648             print "    $what\n" unless $disabled{$what};
2649         }
2650         print "\nDisabled features:\n\n";
2651         foreach my $what (@disablables) {
2652             if ($disabled{$what}) {
2653                 print "    $what", ' ' x ($longest - length($what) + 1),
2654                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2655                 print $disabled_info{$what}->{macro}
2656                     if $disabled_info{$what}->{macro};
2657                 print ' (skip ',
2658                     join(', ', @{$disabled_info{$what}->{skipped}}),
2659                     ')'
2660                     if $disabled_info{$what}->{skipped};
2661                 print "\n";
2662             }
2663         }
2664     }
2665     if ($dump || $target) {
2666         print "\nConfig target attributes:\n\n";
2667         foreach (sort keys %target) {
2668             next if $_ =~ m|^_| || $_ eq 'template';
2669             my $quotify = sub {
2670                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2671             };
2672             print '    ', $_, ' => ';
2673             if (ref($target{$_}) eq "ARRAY") {
2674                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2675             } else {
2676                 print $quotify->($target{$_}), ",\n"
2677             }
2678         }
2679     }
2680     if ($dump || $envvars) {
2681         print "\nRecorded environment:\n\n";
2682         foreach (sort keys %{$config{perlenv}}) {
2683             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2684         }
2685     }
2686     if ($dump || $makevars) {
2687         print "\nMakevars:\n\n";
2688         foreach my $var (@makevars) {
2689             my $prefix = '';
2690             $prefix = $config{CROSS_COMPILE}
2691                 if grep { $var eq $_ } @user_crossable;
2692             $prefix //= '';
2693             print '    ',$var,' ' x (16 - length $var),'= ',
2694                 (ref $config{$var} eq 'ARRAY'
2695                  ? join(' ', @{$config{$var}})
2696                  : $prefix.$config{$var}),
2697                 "\n"
2698                 if defined $config{$var};
2699         }
2700
2701         my @buildfile = ($config{builddir}, $config{build_file});
2702         unshift @buildfile, $here
2703             unless file_name_is_absolute($config{builddir});
2704         my $buildfile = canonpath(catdir(@buildfile));
2705         print <<"_____";
2706
2707 NOTE: These variables only represent the configuration view.  The build file
2708 template may have processed these variables further, please have a look at the
2709 build file for more exact data:
2710     $buildfile
2711 _____
2712     }
2713     if ($dump || $buildparams) {
2714         my @buildfile = ($config{builddir}, $config{build_file});
2715         unshift @buildfile, $here
2716             unless file_name_is_absolute($config{builddir});
2717         print "\nbuild file:\n\n";
2718         print "    ", canonpath(catfile(@buildfile)),"\n";
2719
2720         print "\nbuild file templates:\n\n";
2721         foreach (@{$config{build_file_templates}}) {
2722             my @tmpl = ($_);
2723             unshift @tmpl, $here
2724                 unless file_name_is_absolute($config{sourcedir});
2725             print '    ',canonpath(catfile(@tmpl)),"\n";
2726         }
2727     }
2728     if ($reconf) {
2729         if ($verbose) {
2730             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2731             foreach (sort keys %{$config{perlenv}}) {
2732                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2733             }
2734         }
2735
2736         chdir $here;
2737         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2738     }
2739 }
2740
2741 1;
2742
2743 __END__
2744
2745 =head1 NAME
2746
2747 configdata.pm - configuration data for OpenSSL builds
2748
2749 =head1 SYNOPSIS
2750
2751 Interactive:
2752
2753   perl configdata.pm [options]
2754
2755 As data bank module:
2756
2757   use configdata;
2758
2759 =head1 DESCRIPTION
2760
2761 This module can be used in two modes, interactively and as a module containing
2762 all the data recorded by OpenSSL's Configure script.
2763
2764 When used interactively, simply run it as any perl script, with at least one
2765 option, and you will get the information you ask for.  See L</OPTIONS> below.
2766
2767 When loaded as a module, you get a few databanks with useful information to
2768 perform build related tasks.  The databanks are:
2769
2770     %config             Configured things.
2771     %target             The OpenSSL config target with all inheritances
2772                         resolved.
2773     %disabled           The features that are disabled.
2774     @disablables        The list of features that can be disabled.
2775     %withargs           All data given through --with-THING options.
2776     %unified_info       All information that was computed from the build.info
2777                         files.
2778
2779 =head1 OPTIONS
2780
2781 =over 4
2782
2783 =item B<--help>
2784
2785 Print a brief help message and exit.
2786
2787 =item B<--man>
2788
2789 Print the manual page and exit.
2790
2791 =item B<--dump> | B<-d>
2792
2793 Print all relevant configuration data.  This is equivalent to B<--command-line>
2794 B<--options> B<--target> B<--environment> B<--make-variables>
2795 B<--build-parameters>.
2796
2797 =item B<--command-line> | B<-c>
2798
2799 Print the current configuration command line.
2800
2801 =item B<--options> | B<-o>
2802
2803 Print the features, both enabled and disabled, and display defined macro and
2804 skipped directories where applicable.
2805
2806 =item B<--target> | B<-t>
2807
2808 Print the config attributes for this config target.
2809
2810 =item B<--environment> | B<-e>
2811
2812 Print the environment variables and their values at the time of configuration.
2813
2814 =item B<--make-variables> | B<-m>
2815
2816 Print the main make variables generated in the current configuration
2817
2818 =item B<--build-parameters> | B<-b>
2819
2820 Print the build parameters, i.e. build file and build file templates.
2821
2822 =item B<--reconfigure> | B<--reconf> | B<-r>
2823
2824 Redo the configuration.
2825
2826 =item B<--verbose> | B<-v>
2827
2828 Verbose output.
2829
2830 =back
2831
2832 =cut
2833
2834 EOF
2835 close(OUT);
2836 if ($builder_platform eq 'unix') {
2837     my $mode = (0755 & ~umask);
2838     chmod $mode, 'configdata.pm'
2839         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2840 }
2841
2842 my %builders = (
2843     unified => sub {
2844         print 'Creating ',$target{build_file},"\n";
2845         run_dofile(catfile($blddir, $target{build_file}),
2846                    @{$config{build_file_templates}});
2847     },
2848     );
2849
2850 $builders{$builder}->($builder_platform, @builder_opts);
2851
2852 $SIG{__DIE__} = $orig_death_handler;
2853
2854 print <<"EOF" if ($disabled{threads} eq "unavailable");
2855
2856 The library could not be configured for supporting multi-threaded
2857 applications as the compiler options required on this system are not known.
2858 See file INSTALL for details if you need multi-threading.
2859 EOF
2860
2861 print <<"EOF" if ($no_shared_warn);
2862
2863 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2864 platform, so we will pretend you gave the option 'no-pic', which also disables
2865 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2866 or position independent code, please let us know (but please first make sure
2867 you have tried with a current version of OpenSSL).
2868 EOF
2869
2870 print <<"EOF";
2871
2872 **********************************************************************
2873 ***                                                                ***
2874 ***   OpenSSL has been successfully configured                     ***
2875 ***                                                                ***
2876 ***   If you encounter a problem while building, please open an    ***
2877 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2878 ***   and include the output from the following command:           ***
2879 ***                                                                ***
2880 ***       perl configdata.pm --dump                                ***
2881 ***                                                                ***
2882 ***   (If you are new to OpenSSL, you might want to consult the    ***
2883 ***   'Troubleshooting' section in the INSTALL file first)         ***
2884 ***                                                                ***
2885 **********************************************************************
2886 EOF
2887
2888 exit(0);
2889
2890 ######################################################################
2891 #
2892 # Helpers and utility functions
2893 #
2894
2895 # Death handler, to print a helpful message in case of failure #######
2896 #
2897 sub death_handler {
2898     die @_ if $^S;              # To prevent the added message in eval blocks
2899     my $build_file = $target{build_file} // "build file";
2900     my @message = ( <<"_____", @_ );
2901
2902 Failure!  $build_file wasn't produced.
2903 Please read INSTALL and associated NOTES files.  You may also have to look over
2904 your available compiler tool chain or change your configuration.
2905
2906 _____
2907
2908     # Dying is terminal, so it's ok to reset the signal handler here.
2909     $SIG{__DIE__} = $orig_death_handler;
2910     die @message;
2911 }
2912
2913 # Configuration file reading #########################################
2914
2915 # Note: All of the helper functions are for lazy evaluation.  They all
2916 # return a CODE ref, which will return the intended value when evaluated.
2917 # Thus, whenever there's mention of a returned value, it's about that
2918 # intended value.
2919
2920 # Helper function to implement conditional inheritance depending on the
2921 # value of $disabled{asm}.  Used in inherit_from values as follows:
2922 #
2923 #      inherit_from => [ "template", asm("asm_tmpl") ]
2924 #
2925 sub asm {
2926     my @x = @_;
2927     sub {
2928         $disabled{asm} ? () : @x;
2929     }
2930 }
2931
2932 # Helper function to implement conditional value variants, with a default
2933 # plus additional values based on the value of $config{build_type}.
2934 # Arguments are given in hash table form:
2935 #
2936 #       picker(default => "Basic string: ",
2937 #              debug   => "debug",
2938 #              release => "release")
2939 #
2940 # When configuring with --debug, the resulting string will be
2941 # "Basic string: debug", and when not, it will be "Basic string: release"
2942 #
2943 # This can be used to create variants of sets of flags according to the
2944 # build type:
2945 #
2946 #       cflags => picker(default => "-Wall",
2947 #                        debug   => "-g -O0",
2948 #                        release => "-O3")
2949 #
2950 sub picker {
2951     my %opts = @_;
2952     return sub { add($opts{default} || (),
2953                      $opts{$config{build_type}} || ())->(); }
2954 }
2955
2956 # Helper function to combine several values of different types into one.
2957 # This is useful if you want to combine a string with the result of a
2958 # lazy function, such as:
2959 #
2960 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2961 #
2962 sub combine {
2963     my @stuff = @_;
2964     return sub { add(@stuff)->(); }
2965 }
2966
2967 # Helper function to implement conditional values depending on the value
2968 # of $disabled{threads}.  Can be used as follows:
2969 #
2970 #       cflags => combine("-Wall", threads("-pthread"))
2971 #
2972 sub threads {
2973     my @flags = @_;
2974     return sub { add($disabled{threads} ? () : @flags)->(); }
2975 }
2976
2977 sub shared {
2978     my @flags = @_;
2979     return sub { add($disabled{shared} ? () : @flags)->(); }
2980 }
2981
2982 our $add_called = 0;
2983 # Helper function to implement adding values to already existing configuration
2984 # values.  It handles elements that are ARRAYs, CODEs and scalars
2985 sub _add {
2986     my $separator = shift;
2987
2988     # If there's any ARRAY in the collection of values OR the separator
2989     # is undef, we will return an ARRAY of combined values, otherwise a
2990     # string of joined values with $separator as the separator.
2991     my $found_array = !defined($separator);
2992
2993     my @values =
2994         map {
2995             my $res = $_;
2996             while (ref($res) eq "CODE") {
2997                 $res = $res->();
2998             }
2999             if (defined($res)) {
3000                 if (ref($res) eq "ARRAY") {
3001                     $found_array = 1;
3002                     @$res;
3003                 } else {
3004                     $res;
3005                 }
3006             } else {
3007                 ();
3008             }
3009     } (@_);
3010
3011     $add_called = 1;
3012
3013     if ($found_array) {
3014         [ @values ];
3015     } else {
3016         join($separator, grep { defined($_) && $_ ne "" } @values);
3017     }
3018 }
3019 sub add_before {
3020     my $separator = " ";
3021     if (ref($_[$#_]) eq "HASH") {
3022         my $opts = pop;
3023         $separator = $opts->{separator};
3024     }
3025     my @x = @_;
3026     sub { _add($separator, @x, @_) };
3027 }
3028 sub add {
3029     my $separator = " ";
3030     if (ref($_[$#_]) eq "HASH") {
3031         my $opts = pop;
3032         $separator = $opts->{separator};
3033     }
3034     my @x = @_;
3035     sub { _add($separator, @_, @x) };
3036 }
3037
3038 sub read_eval_file {
3039     my $fname = shift;
3040     my $content;
3041     my @result;
3042
3043     open F, "< $fname" or die "Can't open '$fname': $!\n";
3044     {
3045         undef local $/;
3046         $content = <F>;
3047     }
3048     close F;
3049     {
3050         local $@;
3051
3052         @result = ( eval $content );
3053         warn $@ if $@;
3054     }
3055     return wantarray ? @result : $result[0];
3056 }
3057
3058 # configuration reader, evaluates the input file as a perl script and expects
3059 # it to fill %targets with target configurations.  Those are then added to
3060 # %table.
3061 sub read_config {
3062     my $fname = shift;
3063     my %targets;
3064
3065     {
3066         # Protect certain tables from tampering
3067         local %table = ();
3068
3069         %targets = read_eval_file($fname);
3070     }
3071     my %preexisting = ();
3072     foreach (sort keys %targets) {
3073         $preexisting{$_} = 1 if $table{$_};
3074     }
3075     die <<"EOF",
3076 The following config targets from $fname
3077 shadow pre-existing config targets with the same name:
3078 EOF
3079         map { "  $_\n" } sort keys %preexisting
3080         if %preexisting;
3081
3082
3083     # For each target, check that it's configured with a hash table.
3084     foreach (keys %targets) {
3085         if (ref($targets{$_}) ne "HASH") {
3086             if (ref($targets{$_}) eq "") {
3087                 warn "Deprecated target configuration for $_, ignoring...\n";
3088             } else {
3089                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3090             }
3091             delete $targets{$_};
3092         } else {
3093             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3094         }
3095     }
3096
3097     %table = (%table, %targets);
3098
3099 }
3100
3101 # configuration resolver.  Will only resolve all the lazy evaluation
3102 # codeblocks for the chosen target and all those it inherits from,
3103 # recursively
3104 sub resolve_config {
3105     my $target = shift;
3106     my @breadcrumbs = @_;
3107
3108 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3109
3110     if (grep { $_ eq $target } @breadcrumbs) {
3111         die "inherit_from loop!  target backtrace:\n  "
3112             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3113     }
3114
3115     if (!defined($table{$target})) {
3116         warn "Warning! target $target doesn't exist!\n";
3117         return ();
3118     }
3119     # Recurse through all inheritances.  They will be resolved on the
3120     # fly, so when this operation is done, they will all just be a
3121     # bunch of attributes with string values.
3122     # What we get here, though, are keys with references to lists of
3123     # the combined values of them all.  We will deal with lists after
3124     # this stage is done.
3125     my %combined_inheritance = ();
3126     if ($table{$target}->{inherit_from}) {
3127         my @inherit_from =
3128             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3129         foreach (@inherit_from) {
3130             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3131
3132             # 'template' is a marker that's considered private to
3133             # the config that had it.
3134             delete $inherited_config{template};
3135
3136             foreach (keys %inherited_config) {
3137                 if (!$combined_inheritance{$_}) {
3138                     $combined_inheritance{$_} = [];
3139                 }
3140                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3141             }
3142         }
3143     }
3144
3145     # We won't need inherit_from in this target any more, since we've
3146     # resolved all the inheritances that lead to this
3147     delete $table{$target}->{inherit_from};
3148
3149     # Now is the time to deal with those lists.  Here's the place to
3150     # decide what shall be done with those lists, all based on the
3151     # values of the target we're currently dealing with.
3152     # - If a value is a coderef, it will be executed with the list of
3153     #   inherited values as arguments.
3154     # - If the corresponding key doesn't have a value at all or is the
3155     #   empty string, the inherited value list will be run through the
3156     #   default combiner (below), and the result becomes this target's
3157     #   value.
3158     # - Otherwise, this target's value is assumed to be a string that
3159     #   will simply override the inherited list of values.
3160     my $default_combiner = add();
3161
3162     my %all_keys =
3163         map { $_ => 1 } (keys %combined_inheritance,
3164                          keys %{$table{$target}});
3165
3166     sub process_values {
3167         my $object    = shift;
3168         my $inherited = shift;  # Always a [ list ]
3169         my $target    = shift;
3170         my $entry     = shift;
3171
3172         $add_called = 0;
3173
3174         while(ref($object) eq "CODE") {
3175             $object = $object->(@$inherited);
3176         }
3177         if (!defined($object)) {
3178             return ();
3179         }
3180         elsif (ref($object) eq "ARRAY") {
3181             local $add_called;  # To make sure recursive calls don't affect it
3182             return [ map { process_values($_, $inherited, $target, $entry) }
3183                      @$object ];
3184         } elsif (ref($object) eq "") {
3185             return $object;
3186         } else {
3187             die "cannot handle reference type ",ref($object)
3188                 ," found in target ",$target," -> ",$entry,"\n";
3189         }
3190     }
3191
3192     foreach (sort keys %all_keys) {
3193         my $previous = $combined_inheritance{$_};
3194
3195         # Current target doesn't have a value for the current key?
3196         # Assign it the default combiner, the rest of this loop body
3197         # will handle it just like any other coderef.
3198         if (!exists $table{$target}->{$_}) {
3199             $table{$target}->{$_} = $default_combiner;
3200         }
3201
3202         $table{$target}->{$_} = process_values($table{$target}->{$_},
3203                                                $combined_inheritance{$_},
3204                                                $target, $_);
3205         unless(defined($table{$target}->{$_})) {
3206             delete $table{$target}->{$_};
3207         }
3208 #        if ($extra_checks &&
3209 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3210 #            warn "$_ got replaced in $target\n";
3211 #        }
3212     }
3213
3214     # Finally done, return the result.
3215     return %{$table{$target}};
3216 }
3217
3218 sub usage
3219         {
3220         print STDERR $usage;
3221         print STDERR "\npick os/compiler from:\n";
3222         my $j=0;
3223         my $i;
3224         my $k=0;
3225         foreach $i (sort keys %table)
3226                 {
3227                 next if $table{$i}->{template};
3228                 next if $i =~ /^debug/;
3229                 $k += length($i) + 1;
3230                 if ($k > 78)
3231                         {
3232                         print STDERR "\n";
3233                         $k=length($i);
3234                         }
3235                 print STDERR $i . " ";
3236                 }
3237         foreach $i (sort keys %table)
3238                 {
3239                 next if $table{$i}->{template};
3240                 next if $i !~ /^debug/;
3241                 $k += length($i) + 1;
3242                 if ($k > 78)
3243                         {
3244                         print STDERR "\n";
3245                         $k=length($i);
3246                         }
3247                 print STDERR $i . " ";
3248                 }
3249         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3250         exit(1);
3251         }
3252
3253 sub run_dofile
3254 {
3255     my $out = shift;
3256     my @templates = @_;
3257
3258     unlink $out || warn "Can't remove $out, $!"
3259         if -f $out;
3260     foreach (@templates) {
3261         die "Can't open $_, $!" unless -f $_;
3262     }
3263     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3264     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3265     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3266     system($cmd);
3267     exit 1 if $? != 0;
3268     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3269 }
3270
3271 sub compiler_predefined {
3272     state %predefined;
3273     my $cc = shift;
3274
3275     return () if $^O eq 'VMS';
3276
3277     die 'compiler_predefined called without a compiler command'
3278         unless $cc;
3279
3280     if (! $predefined{$cc}) {
3281
3282         $predefined{$cc} = {};
3283
3284         # collect compiler pre-defines from gcc or gcc-alike...
3285         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3286         while (my $l = <PIPE>) {
3287             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3288             $predefined{$cc}->{$1} = $2 // '';
3289         }
3290         close(PIPE);
3291     }
3292
3293     return %{$predefined{$cc}};
3294 }
3295
3296 sub which
3297 {
3298     my ($name)=@_;
3299
3300     if (eval { require IPC::Cmd; 1; }) {
3301         IPC::Cmd->import();
3302         return scalar IPC::Cmd::can_run($name);
3303     } else {
3304         # if there is $directories component in splitpath,
3305         # then it's not something to test with $PATH...
3306         return $name if (File::Spec->splitpath($name))[1];
3307
3308         foreach (File::Spec->path()) {
3309             my $fullpath = catfile($_, "$name$target{exe_extension}");
3310             if (-f $fullpath and -x $fullpath) {
3311                 return $fullpath;
3312             }
3313         }
3314     }
3315 }
3316
3317 sub env
3318 {
3319     my $name = shift;
3320     my %opts = @_;
3321
3322     unless ($opts{cacheonly}) {
3323         # Note that if $ENV{$name} doesn't exist or is undefined,
3324         # $config{perlenv}->{$name} will be created with the value
3325         # undef.  This is intentional.
3326
3327         $config{perlenv}->{$name} = $ENV{$name}
3328             if ! exists $config{perlenv}->{$name};
3329     }
3330     return $config{perlenv}->{$name};
3331 }
3332
3333 # Configuration printer ##############################################
3334
3335 sub print_table_entry
3336 {
3337     local $now_printing = shift;
3338     my %target = resolve_config($now_printing);
3339     my $type = shift;
3340
3341     # Don't print the templates
3342     return if $target{template};
3343
3344     my @sequence = (
3345         "sys_id",
3346         "cpp",
3347         "cppflags",
3348         "defines",
3349         "includes",
3350         "cc",
3351         "cflags",
3352         "unistd",
3353         "ld",
3354         "lflags",
3355         "loutflag",
3356         "ex_libs",
3357         "bn_ops",
3358         "apps_aux_src",
3359         "cpuid_asm_src",
3360         "uplink_aux_src",
3361         "bn_asm_src",
3362         "ec_asm_src",
3363         "des_asm_src",
3364         "aes_asm_src",
3365         "bf_asm_src",
3366         "md5_asm_src",
3367         "cast_asm_src",
3368         "sha1_asm_src",
3369         "rc4_asm_src",
3370         "rmd160_asm_src",
3371         "rc5_asm_src",
3372         "wp_asm_src",
3373         "cmll_asm_src",
3374         "modes_asm_src",
3375         "padlock_asm_src",
3376         "chacha_asm_src",
3377         "poly1035_asm_src",
3378         "thread_scheme",
3379         "perlasm_scheme",
3380         "dso_scheme",
3381         "shared_target",
3382         "shared_cflag",
3383         "shared_defines",
3384         "shared_ldflag",
3385         "shared_rcflag",
3386         "shared_extension",
3387         "dso_extension",
3388         "obj_extension",
3389         "exe_extension",
3390         "ranlib",
3391         "ar",
3392         "arflags",
3393         "aroutflag",
3394         "rc",
3395         "rcflags",
3396         "rcoutflag",
3397         "mt",
3398         "mtflags",
3399         "mtinflag",
3400         "mtoutflag",
3401         "multilib",
3402         "build_scheme",
3403         );
3404
3405     if ($type eq "TABLE") {
3406         print "\n";
3407         print "*** $now_printing\n";
3408         foreach (@sequence) {
3409             if (ref($target{$_}) eq "ARRAY") {
3410                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3411             } else {
3412                 printf "\$%-12s = %s\n", $_, $target{$_};
3413             }
3414         }
3415     } elsif ($type eq "HASH") {
3416         my $largest =
3417             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3418         print "    '$now_printing' => {\n";
3419         foreach (@sequence) {
3420             if ($target{$_}) {
3421                 if (ref($target{$_}) eq "ARRAY") {
3422                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3423                 } else {
3424                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3425                 }
3426             }
3427         }
3428         print "    },\n";
3429     }
3430 }
3431
3432 # Utility routines ###################################################
3433
3434 # On VMS, if the given file is a logical name, File::Spec::Functions
3435 # will consider it an absolute path.  There are cases when we want a
3436 # purely syntactic check without checking the environment.
3437 sub isabsolute {
3438     my $file = shift;
3439
3440     # On non-platforms, we just use file_name_is_absolute().
3441     return file_name_is_absolute($file) unless $^O eq "VMS";
3442
3443     # If the file spec includes a device or a directory spec,
3444     # file_name_is_absolute() is perfectly safe.
3445     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3446
3447     # Here, we know the given file spec isn't absolute
3448     return 0;
3449 }
3450
3451 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3452 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3453 # realpath() requires that at least all path components except the last is an
3454 # existing directory.  On VMS, the last component of the directory spec must
3455 # exist.
3456 sub absolutedir {
3457     my $dir = shift;
3458
3459     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3460     # will return the volume name for the device, no matter what.  Also,
3461     # it will return an incorrect directory spec if the argument is a
3462     # directory that doesn't exist.
3463     if ($^O eq "VMS") {
3464         return rel2abs($dir);
3465     }
3466
3467     # We use realpath() on Unix, since no other will properly clean out
3468     # a directory spec.
3469     use Cwd qw/realpath/;
3470
3471     return realpath($dir);
3472 }
3473
3474 sub quotify {
3475     my %processors = (
3476         perl    => sub { my $x = shift;
3477                          $x =~ s/([\\\$\@"])/\\$1/g;
3478                          return '"'.$x.'"'; },
3479         maybeshell => sub { my $x = shift;
3480                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3481                             if ($x ne $y || $x =~ m|\s|) {
3482                                 return '"'.$y.'"';
3483                             } else {
3484                                 return $x;
3485                             }
3486                         },
3487         );
3488     my $for = shift;
3489     my $processor =
3490         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3491
3492     return map { $processor->($_); } @_;
3493 }
3494
3495 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3496 # $filename is a file name to read from
3497 # $line_concat_cond_re is a regexp detecting a line continuation ending
3498 # $line_concat is a CODEref that takes care of concatenating two lines
3499 sub collect_from_file {
3500     my $filename = shift;
3501     my $line_concat_cond_re = shift;
3502     my $line_concat = shift;
3503
3504     open my $fh, $filename || die "unable to read $filename: $!\n";
3505     return sub {
3506         my $saved_line = "";
3507         $_ = "";
3508         while (<$fh>) {
3509             s|\R$||;
3510             if (defined $line_concat) {
3511                 $_ = $line_concat->($saved_line, $_);
3512                 $saved_line = "";
3513             }
3514             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3515                 $saved_line = $_;
3516                 next;
3517             }
3518             return $_;
3519         }
3520         die "$filename ending with continuation line\n" if $_;
3521         close $fh;
3522         return undef;
3523     }
3524 }
3525
3526 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3527 # $array is an ARRAYref of lines
3528 # $line_concat_cond_re is a regexp detecting a line continuation ending
3529 # $line_concat is a CODEref that takes care of concatenating two lines
3530 sub collect_from_array {
3531     my $array = shift;
3532     my $line_concat_cond_re = shift;
3533     my $line_concat = shift;
3534     my @array = (@$array);
3535
3536     return sub {
3537         my $saved_line = "";
3538         $_ = "";
3539         while (defined($_ = shift @array)) {
3540             s|\R$||;
3541             if (defined $line_concat) {
3542                 $_ = $line_concat->($saved_line, $_);
3543                 $saved_line = "";
3544             }
3545             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3546                 $saved_line = $_;
3547                 next;
3548             }
3549             return $_;
3550         }
3551         die "input text ending with continuation line\n" if $_;
3552         return undef;
3553     }
3554 }
3555
3556 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3557 # $lineiterator is a CODEref that delivers one line at a time.
3558 # All following arguments are regex/CODEref pairs, where the regexp detects a
3559 # line and the CODEref does something with the result of the regexp.
3560 sub collect_information {
3561     my $lineiterator = shift;
3562     my %collectors = @_;
3563
3564     while(defined($_ = $lineiterator->())) {
3565         s|\R$||;
3566         my $found = 0;
3567         if ($collectors{"BEFORE"}) {
3568             $collectors{"BEFORE"}->($_);
3569         }
3570         foreach my $re (keys %collectors) {
3571             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3572                 $collectors{$re}->($lineiterator);
3573                 $found = 1;
3574             };
3575         }
3576         if ($collectors{"OTHERWISE"}) {
3577             $collectors{"OTHERWISE"}->($lineiterator, $_)
3578                 unless $found || !defined $collectors{"OTHERWISE"};
3579         }
3580         if ($collectors{"AFTER"}) {
3581             $collectors{"AFTER"}->($_);
3582         }
3583     }
3584 }
3585
3586 # tokenize($line)
3587 # $line is a line of text to split up into tokens
3588 # returns a list of tokens
3589 #
3590 # Tokens are divided by spaces.  If the tokens include spaces, they
3591 # have to be quoted with single or double quotes.  Double quotes
3592 # inside a double quoted token must be escaped.  Escaping is done
3593 # with backslash.
3594 # Basically, the same quoting rules apply for " and ' as in any
3595 # Unix shell.
3596 sub tokenize {
3597     my $line = my $debug_line = shift;
3598     my @result = ();
3599
3600     while ($line =~ s|^\s+||, $line ne "") {
3601         my $token = "";
3602         while ($line ne "" && $line !~ m|^\s|) {
3603             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3604                 $token .= $1;
3605                 $line = $';
3606             } elsif ($line =~ m/^'([^']*)'/) {
3607                 $token .= $1;
3608                 $line = $';
3609             } elsif ($line =~ m/^(\S+)/) {
3610                 $token .= $1;
3611                 $line = $';
3612             }
3613         }
3614         push @result, $token;
3615     }
3616
3617     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3618         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3619         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3620     }
3621     return @result;
3622 }