Build: make it possible to assign macro definitions for specific outputs
[openssl.git] / Configurations / common.tmpl
1 {- # -*- Mode: perl -*-
2
3  use File::Basename;
4
5  # A cache of objects for which a recipe has already been generated
6  my %cache;
7
8  # resolvedepends and reducedepends work in tandem to make sure
9  # there are no duplicate dependencies and that they are in the
10  # right order.  This is especially used to sort the list of
11  # libraries that a build depends on.
12  sub extensionlesslib {
13      my @result = map { $_ =~ /(\.a)?$/; $` } @_;
14      return @result if wantarray;
15      return $result[0];
16  }
17  sub resolvedepends {
18      my $thing = shift;
19      my $extensionlessthing = extensionlesslib($thing);
20      my @listsofar = @_;    # to check if we're looping
21      my @list = @{$unified_info{depends}->{$thing} //
22                       $unified_info{depends}->{$extensionlessthing}};
23      my @newlist = ();
24      if (scalar @list) {
25          foreach my $item (@list) {
26              my $extensionlessitem = extensionlesslib($item);
27              # It's time to break off when the dependency list starts looping
28              next if grep { extensionlesslib($_) eq $extensionlessitem } @listsofar;
29              push @newlist, $item, resolvedepends($item, @listsofar, $item);
30          }
31      }
32      @newlist;
33  }
34  sub reducedepends {
35      my @list = @_;
36      my @newlist = ();
37      my %replace = ();
38      while (@list) {
39          my $item = shift @list;
40          my $extensionlessitem = extensionlesslib($item);
41          if (grep { $extensionlessitem eq extensionlesslib($_) } @list) {
42              if ($item ne $extensionlessitem) {
43                  # If this instance of the library is explicitly static, we
44                  # prefer that to any shared library name, since it must have
45                  # been done on purpose.
46                  $replace{$extensionlessitem} = $item;
47              }
48          } else {
49              push @newlist, $item;
50          }
51      }
52      map { $replace{$_} // $_; } @newlist;
53  }
54
55  # is_installed checks if a given file will be installed (i.e. they are
56  # not defined _NO_INST in build.info)
57  sub is_installed {
58      my $product = shift;
59      if (grep { $product eq $_ }
60          map { (@{$unified_info{install}->{$_}}) }
61          keys %{$unified_info{install}}) {
62          return 1;
63      }
64      return 0;
65  }
66
67  # dogenerate is responsible for producing all the recipes that build
68  # generated source files.  It recurses in case a dependency is also a
69  # generated source file.
70  sub dogenerate {
71      my $src = shift;
72      return "" if $cache{$src};
73      my $obj = shift;
74      my $bin = shift;
75      my %opts = @_;
76      if ($unified_info{generate}->{$src}) {
77          die "$src is generated by Configure, should not appear in build file\n"
78              if ref $unified_info{generate}->{$src} eq "";
79          my $script = $unified_info{generate}->{$src}->[0];
80          $OUT .= generatesrc(src => $src,
81                              product => $bin,
82                              generator => $unified_info{generate}->{$src},
83                              generator_incs => $unified_info{includes}->{$script},
84                              generator_deps => $unified_info{depends}->{$script},
85                              deps => $unified_info{depends}->{$src},
86                              incs => [ @{$unified_info{includes}->{$obj}},
87                                        @{$unified_info{includes}->{$bin}} ],
88                              defs => $unified_info{defines}->{$obj},
89                              %opts);
90          foreach (@{$unified_info{depends}->{$src}}) {
91              dogenerate($_, $obj, $bin, %opts);
92          }
93      }
94      $cache{$src} = 1;
95  }
96
97  # doobj is responsible for producing all the recipes that build
98  # object files as well as dependency files.
99  sub doobj {
100      my $obj = shift;
101      return "" if $cache{$obj};
102      my $bin = shift;
103      my %opts = @_;
104      if (@{$unified_info{sources}->{$obj}}) {
105          $OUT .= src2obj(obj => $obj,
106                          product => $bin,
107                          srcs => $unified_info{sources}->{$obj},
108                          deps => $unified_info{depends}->{$obj},
109                          incs => [ @{$unified_info{includes}->{$obj}},
110                                    @{$unified_info{includes}->{$bin}} ],
111                          defs => $unified_info{defines}->{$obj},
112                          %opts);
113          foreach ((@{$unified_info{sources}->{$obj}},
114                    @{$unified_info{depends}->{$obj}})) {
115              dogenerate($_, $obj, $bin, %opts);
116          }
117      }
118      $cache{$obj} = 1;
119  }
120
121  # dolib is responsible for building libraries.  It will call
122  # obj2shlib is shared libraries are produced, and obj2lib in all
123  # cases.  It also makes sure all object files for the library are
124  # built.
125  sub dolib {
126      my $lib = shift;
127      return "" if $cache{$lib};
128      unless ($disabled{shared} || $lib =~ /\.a$/) {
129          my $obj2shlib = defined &obj2shlib ? \&obj2shlib : \&libobj2shlib;
130          $OUT .= $obj2shlib->(shlib => $unified_info{sharednames}->{$lib},
131                               lib => $lib,
132                               objs => $unified_info{shared_sources}->{$lib},
133                               deps => [ reducedepends(resolvedepends($lib)) ],
134                               installed => is_installed($lib));
135          foreach ((@{$unified_info{shared_sources}->{$lib}},
136                    @{$unified_info{sources}->{$lib}})) {
137              # If this is somehow a compiled object, take care of it that way
138              # Otherwise, it might simply be generated
139              if (defined $unified_info{sources}->{$_}) {
140                  doobj($_, $lib, intent => "shlib", installed => is_installed($lib));
141              } else {
142                  dogenerate($_, undef, undef, intent => "lib");
143              }
144          }
145      }
146      $OUT .= obj2lib(lib => $lib,
147                      objs => [ @{$unified_info{sources}->{$lib}} ]);
148      foreach (@{$unified_info{sources}->{$lib}}) {
149          doobj($_, $lib, intent => "lib", installed => is_installed($lib));
150      }
151      $cache{$lib} = 1;
152  }
153
154  # doengine is responsible for building engines.  It will call
155  # obj2dso, and also makes sure all object files for the library
156  # are built.
157  sub doengine {
158      my $lib = shift;
159      return "" if $cache{$lib};
160      $OUT .= obj2dso(lib => $lib,
161                      objs => $unified_info{shared_sources}->{$lib},
162                      deps => [ resolvedepends($lib) ],
163                      installed => is_installed($lib));
164      foreach (@{$unified_info{shared_sources}->{$lib}}) {
165          # If this is somehow a compiled object, take care of it that way
166          # Otherwise, it might simply be generated
167          if (defined $unified_info{sources}->{$_}) {
168              doobj($_, $lib, intent => "dso", installed => is_installed($lib));
169          } else {
170              dogenerate($_, undef, $lib, intent => "dso");
171          }
172      }
173      $cache{$lib} = 1;
174  }
175
176  # dobin is responsible for building programs.  It will call obj2bin,
177  # and also makes sure all object files for the library are built.
178  sub dobin {
179      my $bin = shift;
180      return "" if $cache{$bin};
181      my $deps = [ reducedepends(resolvedepends($bin)) ];
182      $OUT .= obj2bin(bin => $bin,
183                      objs => [ @{$unified_info{sources}->{$bin}} ],
184                      deps => $deps,
185                      installed => is_installed($bin));
186      foreach (@{$unified_info{sources}->{$bin}}) {
187          doobj($_, $bin, intent => "bin", installed => is_installed($bin));
188      }
189      $cache{$bin} = 1;
190  }
191
192  # dobin is responsible for building scripts from templates.  It will
193  # call in2script.
194  sub doscript {
195      my $script = shift;
196      return "" if $cache{$script};
197      $OUT .= in2script(script => $script,
198                        sources => $unified_info{sources}->{$script},
199                        installed => is_installed($script));
200      $cache{$script} = 1;
201  }
202
203  sub dodir {
204      my $dir = shift;
205      return "" if !exists(&generatedir) or $cache{$dir};
206      $OUT .= generatedir(dir => $dir,
207                          deps => $unified_info{dirinfo}->{$dir}->{deps},
208                          %{$unified_info{dirinfo}->{$_}->{products}});
209      $cache{$dir} = 1;
210  }
211
212  # Start with populating the cache with all the overrides
213  %cache = map { $_ => 1 } @{$unified_info{overrides}};
214
215  # Build mandatory generated headers
216  foreach (@{$unified_info{depends}->{""}}) { dogenerate($_); }
217
218  # Build all known libraries, engines, programs and scripts.
219  # Everything else will be handled as a consequence.
220  foreach (@{$unified_info{libraries}}) { dolib($_);    }
221  foreach (@{$unified_info{engines}})   { doengine($_); }
222  foreach (@{$unified_info{programs}})  { dobin($_);    }
223  foreach (@{$unified_info{scripts}})   { doscript($_); }
224
225  foreach (sort keys %{$unified_info{dirinfo}})  { dodir($_); }
226
227  # Finally, should there be any applicable BEGINRAW/ENDRAW sections,
228  # they are added here.
229  $OUT .= $_."\n" foreach @{$unified_info{rawlines}};
230 -}