Configurations/common.tmpl

   1 {- # -*- Mode: perl -*-
   2
   3  use File::Basename;
   4
   5  # A cache of objects for which a recipe has already been generated
   6  my %cache;
   7
   8  # resolvedepends and reducedepends work in tandem to make sure
   9  # there are no duplicate dependencies and that they are in the
  10  # right order.  This is especially used to sort the list of
  11  # libraries that a build depends on.
  12  sub extensionlesslib {
  13      my @result = map { $_ =~ /(\.a)?$/; $` } @_;
  14      return @result if wantarray;
  15      return $result[0];
  16  }
  17  sub resolvedepends {
  18      my $thing = shift;
  19      my $extensionlessthing = extensionlesslib($thing);
  20      my @listsofar = @_;    # to check if we're looping
  21      my @list = @{$unified_info{depends}->{$thing} //
  22                       $unified_info{depends}->{$extensionlessthing}};
  23      my @newlist = ();
  24      if (scalar @list) {
  25          foreach my $item (@list) {
  26              my $extensionlessitem = extensionlesslib($item);
  27              # It's time to break off when the dependency list starts looping
  28              next if grep { extensionlesslib($_) eq $extensionlessitem } @listsofar;
  29              push @newlist, $item, resolvedepends($item, @listsofar, $item);
  30          }
  31      }
  32      @newlist;
  33  }
  34  sub reducedepends {
  35      my @list = @_;
  36      my @newlist = ();
  37      my %replace = ();
  38      while (@list) {
  39          my $item = shift @list;
  40          my $extensionlessitem = extensionlesslib($item);
  41          if (grep { $extensionlessitem eq extensionlesslib($_) } @list) {
  42              if ($item ne $extensionlessitem) {
  43                  # If this instance of the library is explicitly static, we
  44                  # prefer that to any shared library name, since it must have
  45                  # been done on purpose.
  46                  $replace{$extensionlessitem} = $item;
  47              }
  48          } else {
  49              push @newlist, $item;
  50          }
  51      }
  52      map { $replace{$_} // $_; } @newlist;
  53  }
  54
  55  # is_installed checks if a given file will be installed (i.e. they are
  56  # not defined _NO_INST in build.info)
  57  sub is_installed {
  58      my $product = shift;
  59      if (grep { $product eq $_ }
  60          map { (@{$unified_info{install}->{$_}}) }
  61          keys %{$unified_info{install}}) {
  62          return 1;
  63      }
  64      return 0;
  65  }
  66
  67  # dogenerate is responsible for producing all the recipes that build
  68  # generated source files.  It recurses in case a dependency is also a
  69  # generated source file.
  70  sub dogenerate {
  71      my $src = shift;
  72      return "" if $cache{$src};
  73      my $obj = shift;
  74      my $bin = shift;
  75      my %opts = @_;
  76      if ($unified_info{generate}->{$src}) {
  77          die "$src is generated by Configure, should not appear in build file\n"
  78              if ref $unified_info{generate}->{$src} eq "";
  79          my $script = $unified_info{generate}->{$src}->[0];
  80          $OUT .= generatesrc(src => $src,
  81                              generator => $unified_info{generate}->{$src},
  82                              generator_incs => $unified_info{includes}->{$script},
  83                              generator_deps => $unified_info{depends}->{$script},
  84                              deps => $unified_info{depends}->{$src},
  85                              incs => [ @{$unified_info{includes}->{$bin}},
  86                                        @{$unified_info{includes}->{$obj}} ],
  87                              %opts);
  88          foreach (@{$unified_info{depends}->{$src}}) {
  89              dogenerate($_, $obj, $bin, %opts);
  90          }
  91      }
  92      $cache{$src} = 1;
  93  }
  94
  95  # doobj is responsible for producing all the recipes that build
  96  # object files as well as dependency files.
  97  sub doobj {
  98      my $obj = shift;
  99      return "" if $cache{$obj};
 100      (my $obj_no_o = $obj) =~ s|\.o$||;
 101      my $bin = shift;
 102      my %opts = @_;
 103      if (@{$unified_info{sources}->{$obj}}) {
 104          $OUT .= src2obj(obj => $obj_no_o,
 105                          product => $bin,
 106                          srcs => $unified_info{sources}->{$obj},
 107                          deps => $unified_info{depends}->{$obj},
 108                          incs => [ @{$unified_info{includes}->{$bin}},
 109                                    @{$unified_info{includes}->{$obj}} ],
 110                          %opts);
 111          foreach ((@{$unified_info{sources}->{$obj}},
 112                    @{$unified_info{depends}->{$obj}})) {
 113              dogenerate($_, $obj, $bin, %opts);
 114          }
 115      }
 116      $cache{$obj} = 1;
 117  }
 118
 119  # dolib is responsible for building libraries.  It will call
 120  # libobj2shlib is shared libraries are produced, and obj2lib in all
 121  # cases.  It also makes sure all object files for the library are
 122  # built.
 123  sub dolib {
 124      my $lib = shift;
 125      return "" if $cache{$lib};
 126      unless ($disabled{shared} || $lib =~ /\.a$/) {
 127          my %ordinals =
 128              $unified_info{ordinals}->{$lib}
 129              ? (ordinals => $unified_info{ordinals}->{$lib}) : ();
 130          $OUT .= libobj2shlib(shlib => $unified_info{sharednames}->{$lib},
 131                               lib => $lib,
 132                               objs => [ map { (my $x = $_) =~ s|\.o$||; $x }
 133                                         (@{$unified_info{sources}->{$lib}},
 134                                          @{$unified_info{shared_sources}->{$lib}}) ],
 135                               deps => [ reducedepends(resolvedepends($lib)) ],
 136                               installed => is_installed($lib),
 137                               %ordinals);
 138          foreach (@{$unified_info{shared_sources}->{$lib}}) {
 139              doobj($_, $lib, intent => "lib", installed => is_installed($lib));
 140          }
 141      }
 142      $OUT .= obj2lib(lib => $lib,
 143                      objs => [ map { (my $x = $_) =~ s|\.o$||; $x }
 144                                @{$unified_info{sources}->{$lib}} ]);
 145      foreach (@{$unified_info{sources}->{$lib}}) {
 146          doobj($_, $lib, intent => "lib", installed => is_installed($lib));
 147      }
 148      $cache{$lib} = 1;
 149  }
 150
 151  # doengine is responsible for building engines.  It will call
 152  # obj2dso, and also makes sure all object files for the library
 153  # are built.
 154  sub doengine {
 155      my $lib = shift;
 156      return "" if $cache{$lib};
 157      $OUT .= obj2dso(lib => $lib,
 158                      objs => [ map { (my $x = $_) =~ s|\.o$||; $x }
 159                                (@{$unified_info{sources}->{$lib}},
 160                                 @{$unified_info{shared_sources}->{$lib}}) ],
 161                      deps => [ resolvedepends($lib) ],
 162                      installed => is_installed($lib));
 163      foreach ((@{$unified_info{sources}->{$lib}},
 164                @{$unified_info{shared_sources}->{$lib}})) {
 165          doobj($_, $lib, intent => "dso", installed => is_installed($lib));
 166      }
 167      $cache{$lib} = 1;
 168  }
 169
 170  # dobin is responsible for building programs.  It will call obj2bin,
 171  # and also makes sure all object files for the library are built.
 172  sub dobin {
 173      my $bin = shift;
 174      return "" if $cache{$bin};
 175      my $deps = [ reducedepends(resolvedepends($bin)) ];
 176      $OUT .= obj2bin(bin => $bin,
 177                      objs => [ map { (my $x = $_) =~ s|\.o$||; $x }
 178                                @{$unified_info{sources}->{$bin}} ],
 179                      deps => $deps,
 180                      installed => is_installed($bin));
 181      foreach (@{$unified_info{sources}->{$bin}}) {
 182          doobj($_, $bin, intent => "bin", installed => is_installed($bin));
 183      }
 184      $cache{$bin} = 1;
 185  }
 186
 187  # dobin is responsible for building scripts from templates.  It will
 188  # call in2script.
 189  sub doscript {
 190      my $script = shift;
 191      return "" if $cache{$script};
 192      $OUT .= in2script(script => $script,
 193                        sources => $unified_info{sources}->{$script},
 194                        installed => is_installed($script));
 195      $cache{$script} = 1;
 196  }
 197
 198  sub dodir {
 199      my $dir = shift;
 200      return "" if !exists(&generatedir) or $cache{$dir};
 201      $OUT .= generatedir(dir => $dir,
 202                          deps => $unified_info{dirinfo}->{$dir}->{deps},
 203                          %{$unified_info{dirinfo}->{$_}->{products}});
 204      $cache{$dir} = 1;
 205  }
 206
 207  # Start with populating the cache with all the overrides
 208  %cache = map { $_ => 1 } @{$unified_info{overrides}};
 209
 210  # For convenience collect information regarding directories where
 211  # files are generated, those generated files and the end product
 212  # they end up in where applicable.  Then, add build rules for those
 213  # directories
 214  if (exists &generatedir) {
 215      my %loopinfo = ( "dso" => [ @{$unified_info{engines}} ],
 216                       "lib" => [ @{$unified_info{libraries}} ],
 217                       "bin" => [ @{$unified_info{programs}} ],
 218                       "script" => [ @{$unified_info{scripts}} ] );
 219      foreach my $type (keys %loopinfo) {
 220          foreach my $product (@{$loopinfo{$type}}) {
 221              my %dirs = ();
 222              my $pd = dirname($product);
 223
 224              # We already have a "test" target, and the current directory
 225              # is just silly to make a target for
 226              $dirs{$pd} = 1 unless $pd eq "test" || $pd eq ".";
 227
 228              foreach (@{$unified_info{sources}->{$product}}) {
 229                  my $d = dirname($_);
 230
 231                  # We don't want to create targets for source directories
 232                  # when building out of source
 233                  next if ($config{sourcedir} ne $config{builddir}
 234                           && $d =~ m|^\Q$config{sourcedir}\E|);
 235                  # We already have a "test" target, and the current directory
 236                  # is just silly to make a target for
 237                  next if $d eq "test" || $d eq ".";
 238
 239                  $dirs{$d} = 1;
 240                  push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
 241                      if $d ne $pd;
 242              }
 243              foreach (keys %dirs) {
 244                  push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
 245                  $product;
 246              }
 247          }
 248      }
 249  }
 250
 251  # Build mandatory generated headers
 252  foreach (@{$unified_info{depends}->{""}}) { dogenerate($_); }
 253
 254  # Build all known libraries, engines, programs and scripts.
 255  # Everything else will be handled as a consequence.
 256  foreach (@{$unified_info{libraries}}) { dolib($_);    }
 257  foreach (@{$unified_info{engines}})   { doengine($_); }
 258  foreach (@{$unified_info{programs}})  { dobin($_);    }
 259  foreach (@{$unified_info{scripts}})   { doscript($_); }
 260
 261  foreach (sort keys %{$unified_info{dirinfo}})  { dodir($_); }
 262
 263  # Finally, should there be any applicable BEGINRAW/ENDRAW sections,
 264  # they are added here.
 265  $OUT .= $_."\n" foreach @{$unified_info{rawlines}};
 266 -}