132852ce75f87d3cd0864001a0f9a433a32f1eb0
[openssl.git] / Configurations / common.tmpl
1 {- # -*- Mode: perl -*-
2
3  use File::Basename;
4
5  # A cache of objects for which a recipe has already been generated
6  my %cache;
7
8  # resolvedepends and reducedepends work in tandem to make sure
9  # there are no duplicate dependencies and that they are in the
10  # right order.  This is especially used to sort the list of
11  # libraries that a build depends on.
12  sub extensionlesslib {
13      my @result = map { $_ =~ /(\.a)?$/; $` } @_;
14      return @result if wantarray;
15      return $result[0];
16  }
17  sub resolvedepends {
18      my $thing = shift;
19      my $extensionlessthing = extensionlesslib($thing);
20      my @listsofar = @_;    # to check if we're looping
21      my @list = @{$unified_info{depends}->{$thing} //
22                       $unified_info{depends}->{$extensionlessthing}};
23      my @newlist = ();
24      if (scalar @list) {
25          foreach my $item (@list) {
26              my $extensionlessitem = extensionlesslib($item);
27              # It's time to break off when the dependency list starts looping
28              next if grep { extensionlesslib($_) eq $extensionlessitem } @listsofar;
29              push @newlist, $item, resolvedepends($item, @listsofar, $item);
30          }
31      }
32      @newlist;
33  }
34  sub reducedepends {
35      my @list = @_;
36      my @newlist = ();
37      my %replace = ();
38      while (@list) {
39          my $item = shift @list;
40          my $extensionlessitem = extensionlesslib($item);
41          if (grep { $extensionlessitem eq extensionlesslib($_) } @list) {
42              if ($item ne $extensionlessitem) {
43                  # If this instance of the library is explicitly static, we
44                  # prefer that to any shared library name, since it must have
45                  # been done on purpose.
46                  $replace{$extensionlessitem} = $item;
47              }
48          } else {
49              push @newlist, $item;
50          }
51      }
52      map { $replace{$_} // $_; } @newlist;
53  }
54
55  # is_installed checks if a given file will be installed (i.e. they are
56  # not defined _NO_INST in build.info)
57  sub is_installed {
58      my $product = shift;
59      if (grep { $product eq $_ }
60          map { (@{$unified_info{install}->{$_}}) }
61          keys %{$unified_info{install}}) {
62          return 1;
63      }
64      return 0;
65  }
66
67  # dogenerate is responsible for producing all the recipes that build
68  # generated source files.  It recurses in case a dependency is also a
69  # generated source file.
70  sub dogenerate {
71      my $src = shift;
72      return "" if $cache{$src};
73      my $obj = shift;
74      my $bin = shift;
75      my %opts = @_;
76      if ($unified_info{generate}->{$src}) {
77          die "$src is generated by Configure, should not appear in build file\n"
78              if ref $unified_info{generate}->{$src} eq "";
79          my $script = $unified_info{generate}->{$src}->[0];
80          $OUT .= generatesrc(src => $src,
81                              product => $bin,
82                              generator => $unified_info{generate}->{$src},
83                              generator_incs => $unified_info{includes}->{$script},
84                              generator_deps => $unified_info{depends}->{$script},
85                              deps => $unified_info{depends}->{$src},
86                              incs => [ @{$unified_info{includes}->{$obj}},
87                                        @{$unified_info{includes}->{$bin}} ],
88                              defs => [ @{$unified_info{defines}->{$obj}},
89                                        @{$unified_info{defines}->{$bin}} ],
90                              %opts);
91          foreach (@{$unified_info{depends}->{$src}}) {
92              dogenerate($_, $obj, $bin, %opts);
93          }
94      }
95      $cache{$src} = 1;
96  }
97
98  # doobj is responsible for producing all the recipes that build
99  # object files as well as dependency files.
100  sub doobj {
101      my $obj = shift;
102      return "" if $cache{$obj};
103      my $bin = shift;
104      my %opts = @_;
105      if (@{$unified_info{sources}->{$obj}}) {
106          $OUT .= src2obj(obj => $obj,
107                          product => $bin,
108                          srcs => $unified_info{sources}->{$obj},
109                          deps => $unified_info{depends}->{$obj},
110                          incs => [ @{$unified_info{includes}->{$obj}},
111                                    @{$unified_info{includes}->{$bin}} ],
112                          defs => [ @{$unified_info{defines}->{$obj}},
113                                    @{$unified_info{defines}->{$bin}} ],
114                          %opts);
115          foreach ((@{$unified_info{sources}->{$obj}},
116                    @{$unified_info{depends}->{$obj}})) {
117              dogenerate($_, $obj, $bin, %opts);
118          }
119      }
120      $cache{$obj} = 1;
121  }
122
123  # dolib is responsible for building libraries.  It will call
124  # obj2shlib is shared libraries are produced, and obj2lib in all
125  # cases.  It also makes sure all object files for the library are
126  # built.
127  sub dolib {
128      my $lib = shift;
129      return "" if $cache{$lib};
130      unless ($disabled{shared} || $lib =~ /\.a$/) {
131          my $obj2shlib = defined &obj2shlib ? \&obj2shlib : \&libobj2shlib;
132          $OUT .= $obj2shlib->(lib => $lib,
133                               attrs => $unified_info{attributes}->{$lib},
134                               objs => $unified_info{shared_sources}->{$lib},
135                               deps => [ reducedepends(resolvedepends($lib)) ],
136                               installed => is_installed($lib));
137          foreach ((@{$unified_info{shared_sources}->{$lib}},
138                    @{$unified_info{sources}->{$lib}})) {
139              # If this is somehow a compiled object, take care of it that way
140              # Otherwise, it might simply be generated
141              if (defined $unified_info{sources}->{$_}) {
142                  doobj($_, $lib, intent => "shlib", installed => is_installed($lib));
143              } else {
144                  dogenerate($_, undef, undef, intent => "lib");
145              }
146          }
147      }
148      $OUT .= obj2lib(lib => $lib,
149                      attrs => $unified_info{attributes}->{$lib},
150                      objs => [ @{$unified_info{sources}->{$lib}} ]);
151      foreach (@{$unified_info{sources}->{$lib}}) {
152          doobj($_, $lib, intent => "lib", installed => is_installed($lib));
153      }
154      $cache{$lib} = 1;
155  }
156
157  # doengine is responsible for building engines.  It will call
158  # obj2dso, and also makes sure all object files for the library
159  # are built.
160  sub doengine {
161      my $lib = shift;
162      return "" if $cache{$lib};
163      $OUT .= obj2dso(lib => $lib,
164                      attrs => $unified_info{attributes}->{$lib},
165                      objs => $unified_info{shared_sources}->{$lib},
166                      deps => [ resolvedepends($lib) ],
167                      installed => is_installed($lib));
168      foreach (@{$unified_info{shared_sources}->{$lib}}) {
169          # If this is somehow a compiled object, take care of it that way
170          # Otherwise, it might simply be generated
171          if (defined $unified_info{sources}->{$_}) {
172              doobj($_, $lib, intent => "dso", installed => is_installed($lib));
173          } else {
174              dogenerate($_, undef, $lib, intent => "dso");
175          }
176      }
177      $cache{$lib} = 1;
178  }
179
180  # dobin is responsible for building programs.  It will call obj2bin,
181  # and also makes sure all object files for the library are built.
182  sub dobin {
183      my $bin = shift;
184      return "" if $cache{$bin};
185      my $deps = [ reducedepends(resolvedepends($bin)) ];
186      $OUT .= obj2bin(bin => $bin,
187                      attrs => $unified_info{attributes}->{$bin},
188                      objs => [ @{$unified_info{sources}->{$bin}} ],
189                      deps => $deps,
190                      installed => is_installed($bin));
191      foreach (@{$unified_info{sources}->{$bin}}) {
192          doobj($_, $bin, intent => "bin", installed => is_installed($bin));
193      }
194      $cache{$bin} = 1;
195  }
196
197  # dobin is responsible for building scripts from templates.  It will
198  # call in2script.
199  sub doscript {
200      my $script = shift;
201      return "" if $cache{$script};
202      $OUT .= in2script(script => $script,
203                        attrs => $unified_info{attributes}->{$script},
204                        sources => $unified_info{sources}->{$script},
205                        installed => is_installed($script));
206      $cache{$script} = 1;
207  }
208
209  sub dodir {
210      my $dir = shift;
211      return "" if !exists(&generatedir) or $cache{$dir};
212      $OUT .= generatedir(dir => $dir,
213                          deps => $unified_info{dirinfo}->{$dir}->{deps},
214                          %{$unified_info{dirinfo}->{$_}->{products}});
215      $cache{$dir} = 1;
216  }
217
218  # Start with populating the cache with all the overrides
219  %cache = map { $_ => 1 } @{$unified_info{overrides}};
220
221  # Build mandatory generated headers
222  foreach (@{$unified_info{depends}->{""}}) { dogenerate($_); }
223
224  # Build all known libraries, engines, programs and scripts.
225  # Everything else will be handled as a consequence.
226  foreach (@{$unified_info{libraries}}) { dolib($_);    }
227  foreach (@{$unified_info{engines}})   { doengine($_); }
228  foreach (@{$unified_info{programs}})  { dobin($_);    }
229  foreach (@{$unified_info{scripts}})   { doscript($_); }
230
231  foreach (sort keys %{$unified_info{dirinfo}})  { dodir($_); }
232
233  # Finally, should there be any applicable BEGINRAW/ENDRAW sections,
234  # they are added here.
235  $OUT .= $_."\n" foreach @{$unified_info{rawlines}};
236 -}