Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2024 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<feature> ...] [enable-<feature> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]thread-pool] [[no-]default-thread-pool] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 #
  81 # enable-demos  Enable the building of the example code in the demos directory
  82 # enable-h3demo Enable the http3 demo, which currently only links to the
  83 #               external nghttp3 library on unix platforms
  84 # no-hw         do not compile support for any crypto hardware.
  85 # [no-]threads  [don't] try to create a library that is suitable for
  86 #               multithreaded applications (default is "threads" if we
  87 #               know how to do it)
  88 # [no-]thread-pool
  89 #               [don't] allow thread pool functionality
  90 # [no-]default-thread-pool
  91 #               [don't] allow default thread pool functionality
  92 # [no-]shared   [don't] try to create shared libraries when supported.
  93 # [no-]pic      [don't] try to build position independent code when supported.
  94 #               If disabled, it also disables shared and dynamic-engine.
  95 # no-asm        do not use assembler
  96 # no-egd        do not compile support for the entropy-gathering daemon APIs
  97 # [no-]zlib     [don't] compile support for zlib compression.
  98 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  99 #               library and will be loaded at run-time by the OpenSSL library.
 100 # sctp          include SCTP support
 101 # no-quic       disable QUIC support
 102 # no-uplink     Don't build support for UPLINK interface.
 103 # enable-weak-ssl-ciphers
 104 #               Enable weak ciphers that are disabled by default.
 105 # 386           generate 80386 code in assembly modules
 106 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
 107 #               mentioned '386' option implies this one
 108 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 109 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 110 # /<xxx>        passed through to the compiler. Unix-style options beginning
 111 #               with a '-' or '+' are recognized, as well as Windows-style
 112 #               options beginning with a '/'. If the option contains arguments
 113 #               separated by spaces, then the URL-style notation %20 can be
 114 #               used for the space character in order to avoid having to quote
 115 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 116 #               In fact, any ASCII character can be encoded as %xx using its
 117 #               hexadecimal encoding.
 118 # -static       while -static is also a pass-through compiler option (and
 119 #               as such is limited to environments where it's actually
 120 #               meaningful), it triggers a number configuration options,
 121 #               namely no-pic, no-shared and no-threads. It is
 122 #               argued that the only reason to produce statically linked
 123 #               binaries (and in context it means executables linked with
 124 #               -static flag, and not just executables linked with static
 125 #               libcrypto.a) is to eliminate dependency on specific run-time,
 126 #               a.k.a. libc version. The mentioned config options are meant
 127 #               to achieve just that. Unfortunately on Linux it's impossible
 128 #               to eliminate the dependency completely for openssl executable
 129 #               because of getaddrinfo and gethostbyname calls, which can
 130 #               invoke dynamically loadable library facility anyway to meet
 131 #               the lookup requests. For this reason on Linux statically
 132 #               linked openssl executable has rather debugging value than
 133 #               production quality.
 134 #
 135 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 136 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 137 # Following are set automatically by this script
 138 #
 139 # MD5_ASM       use some extra md5 assembler,
 140 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 141 # RMD160_ASM    use some extra ripemd160 assembler,
 142 # SHA256_ASM    sha256_block is implemented in assembler
 143 # SHA512_ASM    sha512_block is implemented in assembler
 144 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 145
 146 # Minimum warning options... any contributions to OpenSSL should at least
 147 # get past these.  Note that we only use these with C compilers, not with
 148 # C++ compilers.
 149
 150 # -DPEDANTIC complements -pedantic and is meant to mask code that
 151 # is not strictly standard-compliant and/or implementation-specific,
 152 # e.g. inline assembly, disregards to alignment requirements, such
 153 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 154 # to be used even in sanitized builds, because sanitizer too is
 155 # supposed to and does take notice of non-standard behaviour. Then
 156 # -pedantic with pre-C9x compiler would also complain about 'long
 157 # long' not being supported. As 64-bit algorithms are common now,
 158 # it grew impossible to resolve this without sizeable additional
 159 # code, so we just tell compiler to be pedantic about everything
 160 # but 'long long' type.
 161
 162 my @gcc_devteam_warn = qw(
 163     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 164     -Wall
 165     -Wmissing-declarations
 166     -Wextra
 167     -Wno-unused-parameter
 168     -Wno-missing-field-initializers
 169     -Wswitch
 170     -Wsign-compare
 171     -Wshadow
 172     -Wformat
 173     -Wno-type-limits
 174     -Wno-tautological-constant-out-of-range-compare
 175     -Wundef
 176     -Werror
 177     -Wmissing-prototypes
 178     -Wstrict-prototypes
 179 );
 180
 181 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 182 # TODO(openssl-team): fix problems and investigate if (at least) the
 183 # following warnings can also be enabled:
 184 #       -Wcast-align
 185 #       -Wunreachable-code -- no, too ugly/compiler-specific
 186 #       -Wlanguage-extension-token -- no, we use asm()
 187 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 188 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 189 my @clang_devteam_warn = qw(
 190     -Wno-unknown-warning-option
 191     -Wswitch-default
 192     -Wno-parentheses-equality
 193     -Wno-language-extension-token
 194     -Wno-extended-offsetof
 195     -Wno-missing-braces
 196     -Wconditional-uninitialized
 197     -Wincompatible-pointer-types-discards-qualifiers
 198     -Wmissing-variable-declarations
 199 );
 200
 201 my @cl_devteam_warn = qw(
 202     /WX
 203 );
 204
 205 my $strict_warnings = 0;
 206
 207 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 208 # which would cover all BSD flavors. -pthread applies to them all,
 209 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 210 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 211 # which has to be accompanied by explicit -D_THREAD_SAFE and
 212 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 213 # seems to be sufficient?
 214 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 215
 216 #
 217 # API compatibility name to version number mapping.
 218 #
 219 my $apitable = {
 220     # This table expresses when API additions or changes can occur.
 221     # The numbering used changes from 3.0 and on because we updated
 222     # (solidified) our version numbering scheme at that point.
 223
 224     # From 3.0 and on, we internalise the given version number in decimal
 225     # as MAJOR * 10000 + MINOR * 100 + 0
 226     "3.0.0" => 30000,
 227     "3.0"   => 30000,
 228
 229     # Note that before 3.0, we didn't have the same version number scheme.
 230     # Still, the numbering we use here covers what we need.
 231     "1.1.1" => 10101,
 232     "1.1.0" => 10100,
 233     "1.0.2" => 10002,
 234     "1.0.1" => 10001,
 235     "1.0.0" => 10000,
 236     "0.9.8" =>   908,
 237 };
 238
 239 # For OpenSSL::config::get_platform
 240 my %guess_opts = ();
 241
 242 my $dryrun = 0;
 243
 244 our %table = ();
 245 our %config = ();
 246 our %withargs = ();
 247 our $now_printing;      # set to current entry's name in print_table_entry
 248                         # (todo: right thing would be to encapsulate name
 249                         # into %target [class] and make print_table_entry
 250                         # a method)
 251
 252 # Forward declarations ###############################################
 253
 254 # read_config(filename)
 255 #
 256 # Reads a configuration file and populates %table with the contents
 257 # (which the configuration file places in %targets).
 258 sub read_config;
 259
 260 # resolve_config(target)
 261 #
 262 # Resolves all the late evaluations, inheritances and so on for the
 263 # chosen target and any target it inherits from.
 264 sub resolve_config;
 265
 266
 267 # Information collection #############################################
 268
 269 # Unified build supports separate build dir
 270 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 271 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 272
 273 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 274 # check if the source and build directory are really the same, and make
 275 # them so.  This avoids all kinds of confusion later on.
 276 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 277 # know if File::Spec ended up loading File::Spec::Unix.
 278 $srcdir = $blddir
 279     if (grep(/::Unix$/, @File::Spec::ISA)
 280         && samedir($srcdir, $blddir));
 281
 282 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 283
 284 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 285
 286 $config{sourcedir} = abs2rel($srcdir, $blddir);
 287 $config{builddir} = abs2rel($blddir, $blddir);
 288 # echo -n 'holy hand grenade of antioch' | openssl sha256
 289 $config{FIPSKEY} =
 290     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 291
 292 # Collect reconfiguration information if needed
 293 my @argvcopy=@ARGV;
 294
 295 if (grep /^reconf(igure)?$/, @argvcopy) {
 296     die "reconfiguring with other arguments present isn't supported"
 297         if scalar @argvcopy > 1;
 298     if (-f "./configdata.pm") {
 299         my $file = "./configdata.pm";
 300         unless (my $return = do $file) {
 301             die "couldn't parse $file: $@" if $@;
 302             die "couldn't do $file: $!"    unless defined $return;
 303             die "couldn't run $file"       unless $return;
 304         }
 305
 306         @argvcopy = defined($configdata::config{perlargv}) ?
 307             @{$configdata::config{perlargv}} : ();
 308         die "Incorrect data to reconfigure, please do a normal configuration\n"
 309             if (grep(/^reconf/,@argvcopy));
 310         $config{perlenv} = $configdata::config{perlenv} // {};
 311     } else {
 312         die "Insufficient data to reconfigure, please do a normal configuration\n";
 313     }
 314 }
 315
 316 $config{perlargv} = [ @argvcopy ];
 317
 318 # Historical: if known directories in crypto/ have been removed, it means
 319 # that those sub-systems are disabled.
 320 # (the other option would be to removed them from the SUBDIRS statement in
 321 # crypto/build.info)
 322 # We reverse the input list for cosmetic purely reasons, to compensate that
 323 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 324 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 325                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 326                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 327                         'sm2', 'sm3', 'sm4') ) {
 328     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 329 }
 330
 331 # Collect version numbers
 332 my %version = ();
 333
 334 collect_information(
 335     collect_from_file(catfile($srcdir,'VERSION.dat')),
 336     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 337         sub {
 338             # Only define it if there is a value at all
 339             if ($2 ne '') {
 340                 my $k = $1;
 341                 my $v = $2;
 342                 # Some values are quoted.  Trim the quotes
 343                 $v = $1 if $v =~ /^"(.*)"$/;
 344                 $version{uc $k} = $v;
 345             }
 346         },
 347     "OTHERWISE" =>
 348         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 349     );
 350
 351 $config{major} = $version{MAJOR} // 'unknown';
 352 $config{minor} = $version{MINOR} // 'unknown';
 353 $config{patch} = $version{PATCH} // 'unknown';
 354 $config{prerelease} =
 355     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 356 $config{build_metadata} =
 357     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 358 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 359 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 360
 361 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 362 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 363
 364 die "erroneous version information in VERSION.dat: ",
 365     "$config{version}, $config{shlib_version}\n"
 366     unless (defined $version{MAJOR}
 367             && defined $version{MINOR}
 368             && defined $version{PATCH}
 369             && defined $version{SHLIB_VERSION});
 370
 371 # Collect target configurations
 372
 373 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 374 foreach (sort glob($pattern)) {
 375     &read_config($_);
 376 }
 377
 378 if (defined env($local_config_envname)) {
 379     if ($^O eq 'VMS') {
 380         # VMS environment variables are logical names,
 381         # which can be used as is
 382         $pattern = $local_config_envname . ':' . '*.conf';
 383     } else {
 384         $pattern = catfile(env($local_config_envname), '*.conf');
 385     }
 386
 387     foreach (sort glob($pattern)) {
 388         &read_config($_);
 389     }
 390 }
 391
 392 # Fail if no configuration is apparent
 393 if (!%table) {
 394     print "Failed to find any os/compiler configurations. Please make sure the Configurations directory is included.\n";
 395     &usage;
 396 }
 397
 398 # Save away perl command information
 399 $config{perl_cmd} = $^X;
 400 $config{perl_version} = $Config{version};
 401 $config{perl_archname} = $Config{archname};
 402
 403 $config{prefix}="";
 404 $config{openssldir}="";
 405 $config{processor}="";
 406 $config{libdir}="";
 407 my $auto_threads=1;    # enable threads automatically? true by default
 408 my $default_ranlib;
 409
 410 # Known TLS and DTLS protocols
 411 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 412 my @dtls = qw(dtls1 dtls1_2);
 413
 414 # Explicitly known options that are possible to disable.  They can
 415 # be regexps, and will be used like this: /^no-${option}$/
 416 # For developers: keep it sorted alphabetically
 417
 418 my @disablables = (
 419     "acvp-tests",
 420     "afalgeng",
 421     "apps",
 422     "argon2",
 423     "aria",
 424     "asan",
 425     "asm",
 426     "async",
 427     "atexit",
 428     "autoalginit",
 429     "autoerrinit",
 430     "autoload-config",
 431     "bf",
 432     "blake2",
 433     "brotli",
 434     "brotli-dynamic",
 435     "buildtest-c++",
 436     "bulk",
 437     "cached-fetch",
 438     "camellia",
 439     "capieng",
 440     "winstore",
 441     "cast",
 442     "chacha",
 443     "cmac",
 444     "cmp",
 445     "cms",
 446     "comp",
 447     "crypto-mdebug",
 448     "ct",
 449     "default-thread-pool",
 450     "demos",
 451     "h3demo",
 452     "deprecated",
 453     "des",
 454     "devcryptoeng",
 455     "dgram",
 456     "dh",
 457     "docs",
 458     "dsa",
 459     "dso",
 460     "dtls",
 461     "dynamic-engine",
 462     "ec",
 463     "ec2m",
 464     "ec_nistp_64_gcc_128",
 465     "ecdh",
 466     "ecdsa",
 467     "ecx",
 468     "egd",
 469     "engine",
 470     "err",
 471     "external-tests",
 472     "filenames",
 473     "fips",
 474     "fips-securitychecks",
 475     "fuzz-afl",
 476     "fuzz-libfuzzer",
 477     "gost",
 478     "http",
 479     "idea",
 480     "ktls",
 481     "legacy",
 482     "loadereng",
 483     "makedepend",
 484     "md2",
 485     "md4",
 486     "mdc2",
 487     "module",
 488     "msan",
 489     "multiblock",
 490     "nextprotoneg",
 491     "ocb",
 492     "ocsp",
 493     "padlockeng",
 494     "pic",
 495     "pie",
 496     "pinshared",
 497     "poly1305",
 498     "posix-io",
 499     "psk",
 500     "quic",
 501     "unstable-qlog",
 502     "rc2",
 503     "rc4",
 504     "rc5",
 505     "rdrand",
 506     "rfc3779",
 507     "rmd160",
 508     "scrypt",
 509     "sctp",
 510     "secure-memory",
 511     "seed",
 512     "shared",
 513     "siphash",
 514     "siv",
 515     "sm2",
 516     "sm2-precomp",
 517     "sm3",
 518     "sm4",
 519     "sock",
 520     "srp",
 521     "srtp",
 522     "sse2",
 523     "ssl",
 524     "ssl-trace",
 525     "static-engine",
 526     "stdio",
 527     "tests",
 528     "tfo",
 529     "thread-pool",
 530     "threads",
 531     "tls",
 532     "integrity-only-ciphers",
 533     "trace",
 534     "ts",
 535     "ubsan",
 536     "ui-console",
 537     "unit-test",
 538     "uplink",
 539     "weak-ssl-ciphers",
 540     "whirlpool",
 541     "zlib",
 542     "zlib-dynamic",
 543     "zstd",
 544     "zstd-dynamic",
 545     );
 546 foreach my $proto ((@tls, @dtls))
 547         {
 548         push(@disablables, $proto);
 549         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 550         }
 551
 552 # Internal disablables, for aliasing purposes.  They serve no special
 553 # purpose here, but allow scripts to get to know them through configdata.pm,
 554 # where these are merged with @disablables.
 555 # The actual aliasing mechanism is done via %disable_cascades
 556 my @disablables_int = qw(
 557     crmf
 558     );
 559
 560 my %deprecated_disablables = (
 561     "ssl2" => undef,
 562     "buf-freelists" => undef,
 563     "crypto-mdebug-backtrace" => undef,
 564     "hw" => "hw",               # causes cascade, but no macro
 565     "hw-padlock" => "padlockeng",
 566     "ripemd" => "rmd160",
 567     "ui" => "ui-console",
 568     "heartbeats" => undef,
 569     );
 570
 571 # All of the following are disabled by default:
 572
 573 our %disabled = ( # "what"         => "comment"
 574                   "fips"                => "default",
 575                   "asan"                => "default",
 576                   "brotli"              => "default",
 577                   "brotli-dynamic"      => "default",
 578                   "buildtest-c++"       => "default",
 579                   "crypto-mdebug"       => "default",
 580                   "crypto-mdebug-backtrace" => "default",
 581                   "demos"               => "default",
 582                   "h3demo"              => "default",
 583                   "devcryptoeng"        => "default",
 584                   "ec_nistp_64_gcc_128" => "default",
 585                   "egd"                 => "default",
 586                   "external-tests"      => "default",
 587                   "fuzz-afl"            => "default",
 588                   "fuzz-libfuzzer"      => "default",
 589                   "pie"                 => "default",
 590                   "ktls"                => "default",
 591                   "md2"                 => "default",
 592                   "msan"                => "default",
 593                   "rc5"                 => "default",
 594                   "sctp"                => "default",
 595                   "ssl3"                => "default",
 596                   "ssl3-method"         => "default",
 597                   "tfo"                 => "default",
 598                   "trace"               => "default",
 599                   "ubsan"               => "default",
 600                   "unit-test"           => "default",
 601                   "weak-ssl-ciphers"    => "default",
 602                   "zlib"                => "default",
 603                   "zlib-dynamic"        => "default",
 604                   "zstd"                => "default",
 605                   "zstd-dynamic"        => "default",
 606                 );
 607
 608 # Note: => pair form used for aesthetics, not to truly make a hash table
 609 my @disable_cascades = (
 610     # "what"            => [ "cascade", ... ]
 611     "bulk"              => [ "shared", "dso",
 612                              "aria", "async", "atexit", "autoload-config",
 613                              "blake2", "bf", "camellia", "cast", "chacha",
 614                              "cmac", "cms", "cmp", "comp", "ct",
 615                              "des", "dgram", "dh", "dsa",
 616                              "ec", "engine",
 617                              "filenames",
 618                              "idea", "ktls",
 619                              "md4", "multiblock", "nextprotoneg",
 620                              "ocsp", "ocb", "poly1305", "psk",
 621                              "rc2", "rc4", "rmd160",
 622                              "seed", "siphash", "siv",
 623                              "sm3", "sm4", "srp",
 624                              "srtp", "ssl3-method", "ssl-trace",
 625                              "tfo",
 626                              "ts", "ui-console", "whirlpool",
 627                              "fips-securitychecks" ],
 628     sub { $config{processor} eq "386" }
 629                         => [ "sse2" ],
 630     "ssl"               => [ "ssl3" ],
 631     "ssl3-method"       => [ "ssl3" ],
 632     "zlib"              => [ "zlib-dynamic" ],
 633     "brotli"            => [ "brotli-dynamic" ],
 634     "zstd"              => [ "zstd-dynamic" ],
 635     "des"               => [ "mdc2" ],
 636     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost", "ecx" ],
 637     "dgram"             => [ "dtls", "quic", "sctp" ],
 638     "sock"              => [ "dgram", "tfo" ],
 639     "dtls"              => [ @dtls ],
 640     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 641                         => [ "dtls" ],
 642
 643     "tls"               => [ @tls ],
 644     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 645                         => [ "tls" ],
 646     "tls1_3"            => [ "quic" ],
 647     "quic"              => [ "unstable-qlog" ],
 648
 649     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 650
 651     "module"            => [ "dynamic-engine", "fips" ],
 652
 653     # Without shared libraries, dynamic engines aren't possible.
 654     # This is due to them having to link with libcrypto and register features
 655     # using the ENGINE functionality, and since that relies on global tables,
 656     # those *have* to be exactly the same as the ones accessed from the app,
 657     # which cannot be guaranteed if shared libraries aren't present.
 658     # (note that even with shared libraries, both the app and dynamic engines
 659     # must be linked with the same library)
 660     "shared"            => [ "dynamic-engine", "uplink" ],
 661     "dso"               => [ "dynamic-engine", "module" ],
 662     # Other modules don't necessarily have to link with libcrypto, so shared
 663     # libraries do not have to be a condition to produce those.
 664
 665     # Without position independent code, there can be no shared libraries
 666     # or modules.
 667     "pic"               => [ "shared", "module" ],
 668
 669     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 670     "dynamic-engine"    => [ "loadereng" ],
 671     "hw"                => [ "padlockeng" ],
 672
 673     # no-autoalginit is only useful when building non-shared
 674     "autoalginit"       => [ "shared", "apps", "fips" ],
 675
 676     "stdio"             => [ "apps", "capieng", "egd" ],
 677     "apps"              => [ "tests" ],
 678     "tests"             => [ "external-tests" ],
 679     "comp"              => [ "zlib", "brotli", "zstd" ],
 680     "sm3"               => [ "sm2" ],
 681     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 682
 683     sub { !$disabled{"msan"} } => [ "asm" ],
 684
 685     "cmac"              => [ "siv" ],
 686     "legacy"            => [ "md2" ],
 687
 688     "cmp"               => [ "crmf" ],
 689
 690     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 691
 692     "threads"           => [ "thread-pool" ],
 693     "thread-pool"       => [ "default-thread-pool" ],
 694
 695     "blake2"            => [ "argon2" ],
 696
 697     "deprecated-3.0"    => [ "engine", "srp" ],
 698
 699     "http"              => [ "ocsp" ]
 700     );
 701
 702 # Avoid protocol support holes.  Also disable all versions below N, if version
 703 # N is disabled while N+1 is enabled.
 704 #
 705 my @list = (reverse @tls);
 706 while ((my $first, my $second) = (shift @list, shift @list)) {
 707     last unless @list;
 708     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 709                               => [ @list ] );
 710     unshift @list, $second;
 711 }
 712 my @list = (reverse @dtls);
 713 while ((my $first, my $second) = (shift @list, shift @list)) {
 714     last unless @list;
 715     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 716                               => [ @list ] );
 717     unshift @list, $second;
 718 }
 719
 720 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 721 # To remove something from %disabled, use "enable-foo".
 722 # For symmetry, "disable-foo" is a synonym for "no-foo".
 723
 724 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 725 # platform specific list separators.  Users from those platforms should
 726 # recognise those separators from how you set up the PATH to find executables.
 727 # The default is the Unix like separator, :, but as an exception, we also
 728 # support the space as separator.
 729 my $list_separator_re =
 730     { VMS           => qr/(?<!\^),/,
 731       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 732 # All the "make variables" we support
 733 # Some get pre-populated for the sake of backward compatibility
 734 # (we supported those before the change to "make variable" support.
 735 my %user = (
 736     AR          => env('AR'),
 737     ARFLAGS     => [],
 738     AS          => undef,
 739     ASFLAGS     => [],
 740     CC          => env('CC'),
 741     CFLAGS      => [ env('CFLAGS') || () ],
 742     CXX         => env('CXX'),
 743     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 744     CPP         => undef,
 745     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 746     CPPDEFINES  => [],  # Alternative for -D
 747     CPPINCLUDES => [],  # Alternative for -I
 748     CROSS_COMPILE => env('CROSS_COMPILE'),
 749     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 750     LD          => undef,
 751     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 752     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 753     MT          => undef,
 754     MTFLAGS     => [],
 755     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 756     RANLIB      => env('RANLIB'),
 757     RC          => env('RC') || env('WINDRES'),
 758     RCFLAGS     => [ env('RCFLAGS') || () ],
 759     RM          => undef,
 760    );
 761 # Info about what "make variables" may be prefixed with the cross compiler
 762 # prefix.  This should NEVER mention any such variable with a list for value.
 763 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 764 # The same but for flags given as Configure options.  These are *additional*
 765 # input, as opposed to the VAR=string option that override the corresponding
 766 # config target attributes
 767 my %useradd = (
 768     ASFLAGS     => [],
 769     CPPDEFINES  => [],
 770     CPPINCLUDES => [],
 771     CPPFLAGS    => [],
 772     CFLAGS      => [],
 773     CXXFLAGS    => [],
 774     LDFLAGS     => [],
 775     LDLIBS      => [],
 776     RCFLAGS     => [],
 777    );
 778
 779 my %user_synonyms = (
 780     HASHBANGPERL=> 'PERL',
 781     RC          => 'WINDRES',
 782    );
 783
 784 # Some target attributes have been renamed, this is the translation table
 785 my %target_attr_translate =(
 786     ar          => 'AR',
 787     as          => 'AS',
 788     cc          => 'CC',
 789     cxx         => 'CXX',
 790     cpp         => 'CPP',
 791     hashbangperl => 'HASHBANGPERL',
 792     ld          => 'LD',
 793     mt          => 'MT',
 794     ranlib      => 'RANLIB',
 795     rc          => 'RC',
 796     rm          => 'RM',
 797    );
 798
 799 # Initialisers coming from 'config' scripts
 800 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 801 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 802 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 803 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 804 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 805 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 806 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 807
 808 $config{openssl_api_defines}=[];
 809 $config{openssl_sys_defines}=[];
 810 $config{openssl_feature_defines}=[];
 811 $config{options}="";
 812 $config{build_type} = "release";
 813 my $target="";
 814
 815 my %cmdvars = ();               # Stores FOO='blah' type arguments
 816 my %unsupported_options = ();
 817 my %deprecated_options = ();
 818 # If you change this, update apps/version.c
 819 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu);
 820 my @seed_sources = ();
 821 while (@argvcopy)
 822         {
 823         $_ = shift @argvcopy;
 824
 825         # Support env variable assignments among the options
 826         if (m|^(\w+)=(.+)?$|)
 827                 {
 828                 $cmdvars{$1} = $2;
 829                 # Every time a variable is given as a configuration argument,
 830                 # it acts as a reset if the variable.
 831                 if (exists $user{$1})
 832                         {
 833                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 834                         }
 835                 #if (exists $useradd{$1})
 836                 #       {
 837                 #       $useradd{$1} = [];
 838                 #       }
 839                 next;
 840                 }
 841
 842         # VMS is a case insensitive environment, and depending on settings
 843         # out of our control, we may receive options uppercased.  Let's
 844         # downcase at least the part before any equal sign.
 845         if ($^O eq "VMS")
 846                 {
 847                 s/^([^=]*)/lc($1)/e;
 848                 }
 849
 850         # some people just can't read the instructions, clang people have to...
 851         s/^-no-(?!integrated-as)/no-/;
 852
 853         # rewrite some options in "enable-..." form
 854         s /^-?-?shared$/enable-shared/;
 855         s /^sctp$/enable-sctp/;
 856         s /^threads$/enable-threads/;
 857         s /^zlib$/enable-zlib/;
 858         s /^zlib-dynamic$/enable-zlib-dynamic/;
 859         s /^fips$/enable-fips/;
 860
 861         if (/^(no|disable|enable)-(.+)$/)
 862                 {
 863                 my $word = $2;
 864                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 865                         && !exists $deprecated_disablables{$word}
 866                         && !grep { $word eq $_ } @disablables)
 867                         {
 868                         $unsupported_options{$_} = 1;
 869                         next;
 870                         }
 871                 }
 872         if (/^no-(.+)$/ || /^disable-(.+)$/)
 873                 {
 874                 foreach my $proto ((@tls, @dtls))
 875                         {
 876                         if ($1 eq "$proto-method")
 877                                 {
 878                                 $disabled{"$proto"} = "option($proto-method)";
 879                                 last;
 880                                 }
 881                         }
 882                 if ($1 eq "dtls")
 883                         {
 884                         foreach my $proto (@dtls)
 885                                 {
 886                                 $disabled{$proto} = "option(dtls)";
 887                                 }
 888                         $disabled{"dtls"} = "option(dtls)";
 889                         }
 890                 elsif ($1 eq "ssl")
 891                         {
 892                         # Last one of its kind
 893                         $disabled{"ssl3"} = "option(ssl)";
 894                         }
 895                 elsif ($1 eq "tls")
 896                         {
 897                         # XXX: Tests will fail if all SSL/TLS
 898                         # protocols are disabled.
 899                         foreach my $proto (@tls)
 900                                 {
 901                                 $disabled{$proto} = "option(tls)";
 902                                 }
 903                         }
 904                 elsif ($1 eq "static-engine")
 905                         {
 906                         delete $disabled{"dynamic-engine"};
 907                         }
 908                 elsif ($1 eq "dynamic-engine")
 909                         {
 910                         $disabled{"dynamic-engine"} = "option";
 911                         }
 912                 elsif (exists $deprecated_disablables{$1})
 913                         {
 914                         $deprecated_options{$_} = 1;
 915                         if (defined $deprecated_disablables{$1})
 916                                 {
 917                                 $disabled{$deprecated_disablables{$1}} = "option";
 918                                 }
 919                         }
 920                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 921                         {
 922                         $deprecated_options{$_} = 1;
 923                         }
 924                 else
 925                         {
 926                         $disabled{$1} = "option";
 927                         }
 928                 # No longer an automatic choice
 929                 $auto_threads = 0 if ($1 eq "threads");
 930                 }
 931         elsif (/^enable-(.+)$/)
 932                 {
 933                 if ($1 eq "static-engine")
 934                         {
 935                         $disabled{"dynamic-engine"} = "option";
 936                         }
 937                 elsif ($1 eq "dynamic-engine")
 938                         {
 939                         delete $disabled{"dynamic-engine"};
 940                         }
 941                 elsif ($1 eq "zlib-dynamic")
 942                         {
 943                         delete $disabled{"zlib"};
 944                         }
 945                 elsif ($1 eq "brotli-dynamic")
 946                         {
 947                         delete $disabled{"brotli"};
 948                         }
 949                 elsif ($1 eq "pie")
 950                         {
 951                         delete $disabled{"pie"};
 952                         }
 953                 elsif ($1 eq "zstd-dynamic")
 954                         {
 955                         delete $disabled{"zstd"};
 956                         }
 957                 my $algo = $1;
 958                 delete $disabled{$algo};
 959
 960                 # No longer an automatic choice
 961                 $auto_threads = 0 if ($1 eq "threads");
 962                 }
 963         elsif (/^-d$/)          # From older 'config'
 964                 {
 965                 $config{build_type} = "debug";
 966                 }
 967         elsif (/^-v$/)          # From older 'config'
 968                 {
 969                 $guess_opts{verbose} = 1;
 970                 }
 971         elsif (/^-w$/)
 972                 {
 973                 $guess_opts{nowait} = 1;
 974                 }
 975         elsif (/^-t$/)          # From older 'config'
 976                 {
 977                 $dryrun = 1;
 978                 }
 979         elsif (/^--strict-warnings$/)
 980                 {
 981                 # Pretend that our strict flags is a C flag, and replace it
 982                 # with the proper flags later on
 983                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 984                 $strict_warnings=1;
 985                 }
 986         elsif (/^--debug$/)
 987                 {
 988                 $config{build_type} = "debug";
 989                 }
 990         elsif (/^--release$/)
 991                 {
 992                 $config{build_type} = "release";
 993                 }
 994         elsif (/^386$/)
 995                 { $config{processor}=386; }
 996         elsif (/^rsaref$/)
 997                 {
 998                 # No RSAref support any more since it's not needed.
 999                 # The check for the option is there so scripts aren't
1000                 # broken
1001                 }
1002         elsif (m|^[-+/]|)
1003                 {
1004                 if (/^--prefix=(.*)$/)
1005                         {
1006                         $config{prefix}=$1;
1007                         }
1008                 elsif (/^--api=(.*)$/)
1009                         {
1010                         my $api = $1;
1011                         die "Unknown API compatibility level $api"
1012                                 unless defined $apitable->{$api};
1013                         $config{api}=$apitable->{$api};
1014                         }
1015                 elsif (/^--libdir=(.*)$/)
1016                         {
1017                         $config{libdir}=$1;
1018                         }
1019                 elsif (/^--openssldir=(.*)$/)
1020                         {
1021                         $config{openssldir}=$1;
1022                         }
1023                 elsif (/^--with-zlib-lib=(.*)$/)
1024                         {
1025                         $withargs{zlib_lib}=$1;
1026                         }
1027                 elsif (/^--with-zlib-include=(.*)$/)
1028                         {
1029                         $withargs{zlib_include}=$1;
1030                         }
1031                 elsif (/^--with-brotli-lib=(.*)$/)
1032                         {
1033                         $withargs{brotli_lib}=$1;
1034                         }
1035                 elsif (/^--with-brotli-include=(.*)$/)
1036                         {
1037                         $withargs{brotli_include}=$1;
1038                         }
1039                 elsif (/^--with-zstd-lib=(.*)$/)
1040                         {
1041                         $withargs{zstd_lib}=$1;
1042                         }
1043                 elsif (/^--with-zstd-include=(.*)$/)
1044                         {
1045                         $withargs{zstd_include}=$1;
1046                         }
1047                 elsif (/^--with-fuzzer-lib=(.*)$/)
1048                         {
1049                         $withargs{fuzzer_lib}=$1;
1050                         }
1051                 elsif (/^--with-fuzzer-include=(.*)$/)
1052                         {
1053                         $withargs{fuzzer_include}=$1;
1054                         }
1055                 elsif (/^--with-rand-seed=(.*)$/)
1056                         {
1057                         foreach my $x (split(m|,|, $1))
1058                             {
1059                             die "Unknown --with-rand-seed choice $x\n"
1060                                 if ! grep { $x eq $_ } @known_seed_sources;
1061                             push @seed_sources, $x;
1062                             }
1063                         }
1064                 elsif (/^--fips-key=(.*)$/)
1065                         {
1066                         $user{FIPSKEY}=lc($1);
1067                         die "Non-hex character in FIPS key\n"
1068                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
1069                         die "FIPS key must have even number of characters\n"
1070                            if length $1 & 1;
1071                         die "FIPS key too long (64 bytes max)\n"
1072                            if length $1 > 64;
1073                         }
1074                 elsif (/^--banner=(.*)$/)
1075                         {
1076                         $banner = $1 . "\n";
1077                         }
1078                 elsif (/^--cross-compile-prefix=(.*)$/)
1079                         {
1080                         $user{CROSS_COMPILE}=$1;
1081                         }
1082                 elsif (/^--config=(.*)$/)
1083                         {
1084                         read_config $1;
1085                         }
1086                 elsif (/^-l(.*)$/)
1087                         {
1088                         push @{$useradd{LDLIBS}}, $_;
1089                         }
1090                 elsif (/^-framework$/)
1091                         {
1092                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1093                         }
1094                 elsif (/^-L(.*)$/ or /^-Wl,/)
1095                         {
1096                         push @{$useradd{LDFLAGS}}, $_;
1097                         }
1098                 elsif (/^-rpath$/ or /^-R$/)
1099                         # -rpath is the OSF1 rpath flag
1100                         # -R is the old Solaris rpath flag
1101                         {
1102                         my $rpath = shift(@argvcopy) || "";
1103                         $rpath .= " " if $rpath ne "";
1104                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1105                         }
1106                 elsif (/^-static$/)
1107                         {
1108                         push @{$useradd{LDFLAGS}}, $_;
1109                         }
1110                 elsif (m|^[-/]D(.*)$|)
1111                         {
1112                         push @{$useradd{CPPDEFINES}}, $1;
1113                         }
1114                 elsif (m|^[-/]I(.*)$|)
1115                         {
1116                         push @{$useradd{CPPINCLUDES}}, $1;
1117                         }
1118                 elsif (/^-Wp,$/)
1119                         {
1120                         push @{$useradd{CPPFLAGS}}, $1;
1121                         }
1122                 else    # common if (/^[-+]/), just pass down...
1123                         {
1124                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1125                         # This provides a simple way to pass options with arguments separated
1126                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1127                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1128                         push @{$useradd{CFLAGS}}, $_;
1129                         push @{$useradd{CXXFLAGS}}, $_;
1130                         }
1131                 }
1132         elsif (m|^/|)
1133                 {
1134                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1135                 # This provides a simple way to pass options with arguments separated
1136                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1137                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1138                 push @{$useradd{CFLAGS}}, $_;
1139                 push @{$useradd{CXXFLAGS}}, $_;
1140                 }
1141         else
1142                 {
1143                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1144                 $target=$_;
1145                 }
1146         unless ($_ eq $target || /^no-/ || /^disable-/)
1147                 {
1148                 # "no-..." follows later after implied deactivations
1149                 # have been derived.  (Don't take this too seriously,
1150                 # we really only write OPTIONS to the Makefile out of
1151                 # nostalgia.)
1152
1153                 if ($config{options} eq "")
1154                         { $config{options} = $_; }
1155                 else
1156                         { $config{options} .= " ".$_; }
1157                 }
1158         }
1159
1160 if (keys %deprecated_options)
1161         {
1162         warn "***** Deprecated options: ",
1163                 join(", ", keys %deprecated_options), "\n";
1164         }
1165 if (keys %unsupported_options)
1166         {
1167         die "***** Unsupported options: ",
1168                 join(", ", keys %unsupported_options), "\n";
1169         }
1170
1171 # If any %useradd entry has been set, we must check that the "make
1172 # variables" haven't been set.  We start by checking of any %useradd entry
1173 # is set.
1174 if (grep { scalar @$_ > 0 } values %useradd) {
1175     # Hash of env / make variables names.  The possible values are:
1176     # 1 - "make vars"
1177     # 2 - %useradd entry set
1178     # 3 - both set
1179     my %detected_vars =
1180         map { my $v = 0;
1181               $v += 1 if $cmdvars{$_};
1182               $v += 2 if @{$useradd{$_}};
1183               $_ => $v }
1184         keys %useradd;
1185
1186     # If any of the corresponding "make variables" is set, we error
1187     if (grep { $_ & 1 } values %detected_vars) {
1188         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1189                                sort keys %detected_vars);
1190         die <<"_____";
1191 ***** Mixing make variables and additional compiler/linker flags as
1192 ***** configure command line option is not permitted.
1193 ***** Affected make variables: $names
1194 _____
1195     }
1196 }
1197
1198 # Check through all supported command line variables to see if any of them
1199 # were set, and canonicalise the values we got.  If no compiler or linker
1200 # flag or anything else that affects %useradd was set, we also check the
1201 # environment for values.
1202 my $anyuseradd =
1203     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1204 foreach (keys %user) {
1205     my $value = $cmdvars{$_};
1206     $value //= env($_) unless $anyuseradd;
1207     $value //=
1208         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1209     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1210         unless $anyuseradd;
1211
1212     if (defined $value) {
1213         if (ref $user{$_} eq 'ARRAY') {
1214             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1215                 $user{$_} = [ split /$list_separator_re/, $value ];
1216             } else {
1217                 $user{$_} = [ $value ];
1218             }
1219         } elsif (!defined $user{$_}) {
1220             $user{$_} = $value;
1221         }
1222     }
1223 }
1224
1225 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1226     && !$disabled{shared}
1227     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1228     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1229         "***** any of asan, msan or ubsan\n";
1230 }
1231
1232 # If no target was given, try guessing.
1233 unless ($target) {
1234     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1235
1236     # The $system_config{disable} is used to populate %disabled with
1237     # entries that aren't already there.
1238     foreach ( @{$system_config{disable} // []} ) {
1239         $disabled{$_} = 'system' unless defined $disabled{$_};
1240     }
1241     delete $system_config{disable};
1242
1243     # Override config entries with stuff from the guesser.
1244     # It's assumed that this really is nothing new.
1245     %config = ( %config, %system_config );
1246     $target = $system_config{target};
1247 }
1248
1249 sub disable {
1250     my $disable_type = shift;
1251
1252     for (@_) {
1253         $disabled{$_} = $disable_type;
1254     }
1255
1256     my @tocheckfor = (@_ ? @_ : keys %disabled);
1257     while (@tocheckfor) {
1258         my %new_tocheckfor = ();
1259         my @cascade_copy = (@disable_cascades);
1260         while (@cascade_copy) {
1261             my ($test, $descendents) =
1262                 (shift @cascade_copy, shift @cascade_copy);
1263             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1264                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1265                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1266                 }
1267             }
1268         }
1269         @tocheckfor = (keys %new_tocheckfor);
1270     }
1271 }
1272 disable();                     # First cascade run
1273
1274 our $die = sub { die @_; };
1275 if ($target eq "TABLE") {
1276     local $die = sub { warn @_; };
1277     foreach (sort keys %table) {
1278         print_table_entry($_, "TABLE");
1279     }
1280     exit 0;
1281 }
1282
1283 if ($target eq "LIST") {
1284     foreach (sort keys %table) {
1285         print $_,"\n" unless $table{$_}->{template};
1286     }
1287     exit 0;
1288 }
1289
1290 if ($target eq "HASH") {
1291     local $die = sub { warn @_; };
1292     print "%table = (\n";
1293     foreach (sort keys %table) {
1294         print_table_entry($_, "HASH");
1295     }
1296     exit 0;
1297 }
1298
1299 print "Configuring OpenSSL version $config{full_version} ";
1300 print "for target $target\n";
1301
1302 if (scalar(@seed_sources) == 0) {
1303     print "Using os-specific seed configuration\n";
1304     push @seed_sources, 'os';
1305 }
1306 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1307     delete $disabled{'egd'};
1308 }
1309 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1310     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1311     warn <<_____ if scalar(@seed_sources) == 1;
1312
1313 ============================== WARNING ===============================
1314 You have selected the --with-rand-seed=none option, which effectively
1315 disables automatic reseeding of the OpenSSL random generator.
1316 All operations depending on the random generator such as creating keys
1317 will not work unless the random generator is seeded manually by the
1318 application.
1319
1320 Please read the 'Note on random number generation' section in the
1321 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1322 details.
1323 ============================== WARNING ===============================
1324
1325 _____
1326 }
1327 push @{$config{openssl_feature_defines}},
1328      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1329         @seed_sources;
1330
1331 # Backward compatibility?
1332 if ($target =~ m/^CygWin32(-.*)$/) {
1333     $target = "Cygwin".$1;
1334 }
1335
1336 # Support for legacy targets having a name starting with 'debug-'
1337 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1338 if ($d) {
1339     $config{build_type} = "debug";
1340
1341     # If we do not find debug-foo in the table, the target is set to foo.
1342     if (!$table{$target}) {
1343         $target = $t;
1344     }
1345 }
1346
1347 if ($target) {
1348     # It's possible that we have different config targets for specific
1349     # toolchains, so we try to detect them, and go for the plain config
1350     # target if not.
1351     my $found;
1352     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1353         $found=$_ if $table{$_} && !$table{$_}->{template};
1354         last if $found;
1355     }
1356     $target = $found;
1357 } else {
1358     # If we don't have a config target now, we try the C compiler as we
1359     # fallback
1360     my $cc = $user{CC} // 'cc';
1361     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1362 }
1363
1364 &usage unless $target;
1365
1366 exit 0 if $dryrun;              # From older 'config'
1367
1368 $config{target} = $target;
1369 my %target = resolve_config($target);
1370
1371 foreach (keys %target_attr_translate) {
1372     $target{$target_attr_translate{$_}} = $target{$_}
1373         if $target{$_};
1374     delete $target{$_};
1375 }
1376
1377 %target = ( %{$table{DEFAULTS}}, %target );
1378
1379 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1380 $config{conf_files} = [ sort keys %conf_files ];
1381
1382 # Using sub disable within these loops may prove fragile, so we run
1383 # a cascade afterwards
1384 foreach my $feature (@{$target{disable}}) {
1385     if (exists $deprecated_disablables{$feature}) {
1386         warn "***** config $target disables deprecated feature $feature\n";
1387     } elsif (!grep { $feature eq $_ } @disablables) {
1388         die "***** config $target disables unknown feature $feature\n";
1389     }
1390     $disabled{$feature} = 'config';
1391 }
1392 foreach my $feature (@{$target{enable}}) {
1393     if ("default" eq ($disabled{$feature} // "")) {
1394         if (exists $deprecated_disablables{$feature}) {
1395             warn "***** config $target enables deprecated feature $feature\n";
1396         } elsif (!grep { $feature eq $_ } @disablables) {
1397             die "***** config $target enables unknown feature $feature\n";
1398         }
1399         delete $disabled{$feature};
1400     }
1401 }
1402
1403 # If uplink_arch isn't defined, disable uplink
1404 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1405 # If asm_arch isn't defined, disable asm
1406 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1407
1408 disable();                      # Run a cascade now
1409
1410 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1411 $target{cxxflags}//=$target{cflags} if $target{CXX};
1412 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1413 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1414
1415 # Fill %config with values from %user, and in case those are undefined or
1416 # empty, use values from %target (acting as a default).
1417 foreach (keys %user) {
1418     my $ref_type = ref $user{$_};
1419
1420     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1421     # and a value that's to be coerced into that type.
1422     my $mkvalue = sub {
1423         my $type = shift;
1424         my $value = shift;
1425         my $undef_p = shift;
1426
1427         die "Too many arguments for \$mkvalue" if @_;
1428
1429         while (ref $value eq 'CODE') {
1430             $value = $value->();
1431         }
1432
1433         if ($type eq 'ARRAY') {
1434             return undef unless defined $value;
1435             return undef if ref $value ne 'ARRAY' && !$value;
1436             return undef if ref $value eq 'ARRAY' && !@$value;
1437             return [ $value ] unless ref $value eq 'ARRAY';
1438         }
1439         return undef unless $value;
1440         return $value;
1441     };
1442
1443     $config{$_} =
1444         $mkvalue->($ref_type, $user{$_})
1445         || $mkvalue->($ref_type, $target{$_});
1446     delete $config{$_} unless defined $config{$_};
1447 }
1448
1449 # Finish up %config by appending things the user gave us on the command line
1450 # apart from "make variables"
1451 foreach (keys %useradd) {
1452     # The must all be lists, so we assert that here
1453     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1454         unless ref $useradd{$_} eq 'ARRAY';
1455
1456     if (defined $config{$_}) {
1457         push @{$config{$_}}, @{$useradd{$_}};
1458     } else {
1459         $config{$_} = [ @{$useradd{$_}} ];
1460     }
1461 }
1462 # At this point, we can forget everything about %user and %useradd,
1463 # because it's now all been merged into the corresponding $config entry
1464
1465 if ($config{prefix} && !$config{CROSS_COMPILE}) {
1466     die "Directory given with --prefix MUST be absolute\n"
1467         unless file_name_is_absolute($config{prefix});
1468 }
1469
1470 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1471     disable('static', 'pic', 'threads');
1472 }
1473
1474 # Allow overriding the build file name
1475 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1476
1477 # Make sure build_scheme is consistent.
1478 $target{build_scheme} = [ $target{build_scheme} ]
1479     if ref($target{build_scheme}) ne "ARRAY";
1480
1481 my ($builder, $builder_platform, @builder_opts) =
1482     @{$target{build_scheme}};
1483
1484 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1485                       $builder_platform."-checker.pm")) {
1486     my $checker_path = catfile($srcdir, "Configurations", $checker);
1487     if (-f $checker_path) {
1488         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1489             ? sub { warn $@; } : sub { die $@; };
1490         if (! do $checker_path) {
1491             if ($@) {
1492                 $fn->($@);
1493             } elsif ($!) {
1494                 $fn->($!);
1495             } else {
1496                 $fn->("The detected tools didn't match the platform\n");
1497             }
1498         }
1499         last;
1500     }
1501 }
1502
1503 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1504
1505 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1506         {
1507         push @{$config{cflags}}, "-mno-cygwin";
1508         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1509         push @{$config{shared_ldflag}}, "-mno-cygwin";
1510         }
1511
1512 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1513         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1514         # minimally required architecture flags for assembly modules
1515         my $value;
1516         $value = '-mips2' if ($target =~ /mips32/);
1517         $value = '-mips3' if ($target =~ /mips64/);
1518         unshift @{$config{cflags}}, $value;
1519         unshift @{$config{cxxflags}}, $value if $config{CXX};
1520 }
1521
1522 # If threads aren't disabled, check how possible they are
1523 unless ($disabled{threads}) {
1524     if ($auto_threads) {
1525         # Enabled by default, disable it forcibly if unavailable
1526         if ($target{thread_scheme} eq "(unknown)") {
1527             disable("unavailable", 'threads');
1528         }
1529     } else {
1530         # The user chose to enable threads explicitly, let's see
1531         # if there's a chance that's possible
1532         if ($target{thread_scheme} eq "(unknown)") {
1533             # If the user asked for "threads" and we don't have internal
1534             # knowledge how to do it, [s]he is expected to provide any
1535             # system-dependent compiler options that are necessary.  We
1536             # can't truly check that the given options are correct, but
1537             # we expect the user to know what [s]He is doing.
1538             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1539                 die "You asked for multi-threading support, but didn't\n"
1540                     ,"provide any system-specific compiler options\n";
1541             }
1542         }
1543     }
1544 }
1545
1546 # Find out if clang's sanitizers have been enabled with -fsanitize
1547 # flags and ensure that the corresponding %disabled elements area
1548 # removed to reflect that the sanitizers are indeed enabled.
1549 my %detected_sanitizers = ();
1550 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1551     (my $checks = $_) =~ s/^-fsanitize=//;
1552     foreach (split /,/, $checks) {
1553         my $d = { address       => 'asan',
1554                   undefined     => 'ubsan',
1555                   memory        => 'msan' } -> {$_};
1556         next unless defined $d;
1557
1558         $detected_sanitizers{$d} = 1;
1559         if (defined $disabled{$d}) {
1560             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1561                 if $disabled{$d} ne "default";
1562             delete $disabled{$d};
1563         }
1564     }
1565 }
1566
1567 # If threads still aren't disabled, add a C macro to ensure the source
1568 # code knows about it.  Any other flag is taken care of by the configs.
1569 unless($disabled{threads}) {
1570     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1571 }
1572
1573 if ($disabled{"unstable-qlog"}) {
1574     $disabled{"qlog"} = 1;
1575 }
1576
1577 my $no_shared_warn=0;
1578 if (($target{shared_target} // '') eq "")
1579         {
1580         $no_shared_warn = 1
1581             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1582         disable('no-shared-target', 'pic');
1583         }
1584
1585 if ($disabled{"dynamic-engine"}) {
1586         $config{dynamic_engines} = 0;
1587 } else {
1588         $config{dynamic_engines} = 1;
1589 }
1590
1591 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1592     push @{$config{cflags}}, "-fsanitize=address";
1593 }
1594
1595 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1596     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1597 }
1598
1599 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1600   push @{$config{cflags}}, "-fsanitize=memory";
1601 }
1602
1603 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1604         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1605     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1606     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1607 }
1608 #
1609 # Platform fix-ups
1610 #
1611
1612 # This saves the build files from having to check
1613 if ($disabled{pic})
1614         {
1615         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1616                     shared_defines shared_includes shared_ldflag
1617                     module_cflags module_cxxflags module_cppflags
1618                     module_defines module_includes module_lflags))
1619                 {
1620                 delete $config{$_};
1621                 $target{$_} = "";
1622                 }
1623         }
1624 else
1625         {
1626         push @{$config{lib_defines}}, "OPENSSL_PIC";
1627         }
1628
1629 if ($target{sys_id} ne "")
1630         {
1631         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1632         }
1633
1634 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1635 my %predefined_CXX = $config{CXX}
1636     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1637     : ();
1638
1639 unless ($disabled{asm}) {
1640     # big endian systems can use ELFv2 ABI
1641     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1642         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1643     }
1644 }
1645
1646 # Check for makedepend capabilities.
1647 if (!$disabled{makedepend}) {
1648     # If the attribute makedep_scheme is defined, then we assume that the
1649     # config target and its associated build file are programmed to deal
1650     # with it.
1651     # If makedep_scheme is undefined, we go looking for GCC compatible
1652     # dependency making, and if that's not available, we try to fall back
1653     # on 'makedepend'.
1654     if ($target{makedep_scheme}) {
1655         $config{makedep_scheme} = $target{makedep_scheme};
1656         # If the makedepcmd attribute is defined, copy it.  If not, the
1657         # build files will have to fend for themselves.
1658         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1659     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1660              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1661         # We know that GNU C version 3 and up as well as all clang
1662         # versions support dependency generation, but Xcode did not
1663         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1664         $config{makedep_scheme} = 'gcc';
1665     } else {
1666         # In all other cases, we look for 'makedepend', and set the
1667         # makedep_scheme value if we found it.
1668         $config{makedepcmd} = which('makedepend');
1669         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1670     }
1671
1672     # If no depend scheme is set, we disable makedepend
1673     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1674 }
1675
1676 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1677     # probe for -Wa,--noexecstack option...
1678     if ($predefined_C{__clang__}) {
1679         # clang has builtin assembler, which doesn't recognize --help,
1680         # but it apparently recognizes the option in question on all
1681         # supported platforms even when it's meaningless. In other words
1682         # probe would fail, but probed option always accepted...
1683         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1684     } else {
1685         my $cc = $config{CROSS_COMPILE}.$config{CC};
1686         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1687         while(<PIPE>) {
1688             if (m/--noexecstack/) {
1689                 push @{$config{cflags}}, "-Wa,--noexecstack";
1690                 last;
1691             }
1692         }
1693         close(PIPE);
1694         unlink("null.$$.o");
1695     }
1696 }
1697
1698 # Deal with bn_ops ###################################################
1699
1700 $config{bn_ll}                  =0;
1701 my $def_int="unsigned int";
1702 $config{rc4_int}                =$def_int;
1703 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1704
1705 my $count = 0;
1706 foreach (sort split(/\s+/,$target{bn_ops})) {
1707     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1708     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1709     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1710     ($config{b64l},$config{b64},$config{b32})
1711         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1712     ($config{b64l},$config{b64},$config{b32})
1713         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1714     ($config{b64l},$config{b64},$config{b32})
1715         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1716 }
1717 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1718     if $count > 1;
1719
1720 $config{api} = $config{major} * 10000 + $config{minor} * 100
1721     unless $config{api};
1722 foreach (keys %$apitable) {
1723     $disabled{"deprecated-$_"} = "deprecation"
1724         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1725 }
1726
1727 disable();                      # Run a cascade now
1728
1729 # Hack cflags for better warnings (dev option) #######################
1730
1731 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1732 # a string and works as well on command lines.
1733 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1734                         @{$config{cflags}} ];
1735 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1736                           @{$config{cxxflags}} ] if $config{CXX};
1737
1738 $config{openssl_api_defines} = [
1739     "OPENSSL_CONFIGURED_API=".$config{api},
1740 ];
1741
1742 my @strict_warnings_collection=();
1743 if ($strict_warnings)
1744         {
1745         my $wopt;
1746         my $gccver = $predefined_C{__GNUC__} // -1;
1747
1748         if ($gccver >= 4)
1749                 {
1750                 push @strict_warnings_collection, @gcc_devteam_warn;
1751                 push @strict_warnings_collection, @clang_devteam_warn
1752                     if (defined($predefined_C{__clang__}));
1753                 }
1754         elsif ($config{target} =~ /^VC-/)
1755                 {
1756                 push @strict_warnings_collection, @cl_devteam_warn;
1757                 }
1758         else
1759                 {
1760                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1761                 }
1762         }
1763
1764 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1765                               ? @strict_warnings_collection
1766                               : ( $_ ) }
1767                     @{$config{CFLAGS}} ];
1768
1769 unless ($disabled{afalgeng}) {
1770     $config{afalgeng}="";
1771     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1772         push @{$config{engdirs}}, "afalg";
1773     } else {
1774         disable('not-linux', 'afalgeng');
1775     }
1776 }
1777
1778 unless ($disabled{devcryptoeng}) {
1779     if ($target =~ m/^BSD/) {
1780         my $maxver = 5*100 + 7;
1781         my $sysstr = `uname -s`;
1782         my $verstr = `uname -r`;
1783         $sysstr =~ s|\R$||;
1784         $verstr =~ s|\R$||;
1785         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1786         my $ver = $ma*100 + $mi;
1787         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1788             disable('too-new-kernel', 'devcryptoeng');
1789         }
1790     }
1791 }
1792
1793 unless ($disabled{ktls}) {
1794     $config{ktls}="";
1795     my $cc = $config{CROSS_COMPILE}.$config{CC};
1796     if ($target =~ m/^linux/) {
1797         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1798         if ($? != 0) {
1799             disable('too-old-kernel', 'ktls');
1800         }
1801     } elsif ($target =~ m/^BSD/) {
1802         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1803         if ($? != 0) {
1804             disable('too-old-freebsd', 'ktls');
1805         }
1806     } else {
1807         disable('not-linux-or-freebsd', 'ktls');
1808     }
1809 }
1810
1811 unless ($disabled{winstore}) {
1812     unless ($target =~ /^(?:Cygwin|mingw|VC-|BC-)/) {
1813         disable('not-windows', 'winstore');
1814     }
1815 }
1816
1817 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1818
1819 # Get the extra flags used when building shared libraries and modules.  We
1820 # do this late because some of them depend on %disabled.
1821
1822 # Make the flags to build DSOs the same as for shared libraries unless they
1823 # are already defined
1824 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1825 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1826 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1827 {
1828     my $shared_info_pl =
1829         catfile(dirname($0), "Configurations", "shared-info.pl");
1830     my %shared_info = read_eval_file($shared_info_pl);
1831     push @{$target{_conf_fname_int}}, $shared_info_pl;
1832     my $si = $target{shared_target};
1833     while (ref $si ne "HASH") {
1834         last if ! defined $si;
1835         if (ref $si eq "CODE") {
1836             $si = $si->();
1837         } else {
1838             $si = $shared_info{$si};
1839         }
1840     }
1841
1842     # Some of the 'shared_target' values don't have any entries in
1843     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1844     # template knows how to handle this.  That is currently the case for
1845     # Windows and VMS.
1846     if (defined $si) {
1847         # Just as above, copy certain shared_* attributes to the corresponding
1848         # module_ attribute unless the latter is already defined
1849         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1850         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1851         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1852         foreach (sort keys %$si) {
1853             $target{$_} = defined $target{$_}
1854                 ? add($si->{$_})->($target{$_})
1855                 : $si->{$_};
1856         }
1857     }
1858 }
1859
1860 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1861
1862 ######################################################################
1863 # Build up information for skipping certain directories depending on disabled
1864 # features, as well as setting up macros for disabled features.
1865
1866 # This is a tentative database of directories to skip.  Some entries may not
1867 # correspond to anything real, but that's ok, they will simply be ignored.
1868 # The actual processing of these entries is done in the build.info lookup
1869 # loop further down.
1870 #
1871 # The key is a Unix formatted path in the source tree, the value is an index
1872 # into %disabled_info, so any existing path gets added to a corresponding
1873 # 'skipped' entry in there with the list of skipped directories.
1874 my %skipdir = ();
1875 my %disabled_info = ();         # For configdata.pm
1876 foreach my $what (sort keys %disabled) {
1877     # There are deprecated disablables that translate to themselves.
1878     # They cause disabling cascades, but should otherwise not register.
1879     next if $deprecated_disablables{$what};
1880     # The generated $disabled{"deprecated-x.y"} entries are special
1881     # and treated properly elsewhere
1882     next if $what =~ m|^deprecated-|;
1883
1884     $config{options} .= " no-$what";
1885
1886     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1887                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1888                                 'sse2', 'legacy' )) {
1889         (my $WHAT = uc $what) =~ s|-|_|g;
1890         my $skipdir = $what;
1891
1892         # fix-up crypto/directory name(s)
1893         $skipdir = "ripemd" if $what eq "rmd160";
1894         $skipdir = "whrlpool" if $what eq "whirlpool";
1895
1896         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1897         push @{$config{openssl_feature_defines}}, $macro;
1898
1899         $skipdir{engines} = $what if $what eq 'engine';
1900         $skipdir{"crypto/$skipdir"} = $what
1901             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1902     }
1903 }
1904
1905 if ($disabled{"dynamic-engine"}) {
1906     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1907 } else {
1908     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1909 }
1910
1911 # If we use the unified build, collect information from build.info files
1912 my %unified_info = ();
1913
1914 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1915 if ($builder eq "unified") {
1916     use Text::Template 1.46;
1917
1918     sub cleandir {
1919         my $base = shift;
1920         my $dir = shift;
1921         my $relativeto = shift || ".";
1922         my $no_mkpath = shift // 0;
1923
1924         $dir = catdir($base,$dir) unless isabsolute($dir);
1925
1926         # Make sure the directories we're building in exists
1927         mkpath($dir) unless $no_mkpath;
1928
1929         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1930         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1931         return $res;
1932     }
1933
1934     sub cleanfile {
1935         my $base = shift;
1936         my $file = shift;
1937         my $relativeto = shift || ".";
1938         my $no_mkpath = shift // 0;
1939
1940         $file = catfile($base,$file) unless isabsolute($file);
1941
1942         my $d = dirname($file);
1943         my $f = basename($file);
1944
1945         # Make sure the directories we're building in exists
1946         mkpath($d) unless $no_mkpath;
1947
1948         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1949         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1950         return $res;
1951     }
1952
1953     # Store the name of the template file we will build the build file from
1954     # in %config.  This may be useful for the build file itself.
1955     my @build_file_template_names =
1956         ( $builder_platform."-".$config{build_file}.".tmpl",
1957           $config{build_file}.".tmpl" );
1958     my @build_file_templates = ();
1959
1960     # First, look in the user provided directory, if given
1961     if (defined env($local_config_envname)) {
1962         @build_file_templates =
1963             map {
1964                 if ($^O eq 'VMS') {
1965                     # VMS environment variables are logical names,
1966                     # which can be used as is
1967                     $local_config_envname . ':' . $_;
1968                 } else {
1969                     catfile(env($local_config_envname), $_);
1970                 }
1971             }
1972             @build_file_template_names;
1973     }
1974     # Then, look in our standard directory
1975     push @build_file_templates,
1976         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir, 1) }
1977           @build_file_template_names );
1978
1979     my $build_file_template;
1980     for $_ (@build_file_templates) {
1981         $build_file_template = $_;
1982         last if -f $build_file_template;
1983
1984         $build_file_template = undef;
1985     }
1986     if (!defined $build_file_template) {
1987         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1988     }
1989     $config{build_file_templates}
1990       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1991                     $blddir, 1),
1992            $build_file_template ];
1993
1994     my @build_dirs = ( [ ] );   # current directory
1995
1996     $config{build_infos} = [ ];
1997
1998     # We want to detect configdata.pm in the source tree, so we
1999     # don't use it if the build tree is different.
2000     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir, 1);
2001
2002     # Any source file that we recognise is placed in this hash table, with
2003     # the list of its intended destinations as value.  When everything has
2004     # been collected, there's a routine that checks that these source files
2005     # exist, or if they are generated, that the generator exists.
2006     my %check_exist = ();
2007     my %check_generate = ();
2008
2009     my %ordinals = ();
2010     while (@build_dirs) {
2011         my @curd = @{shift @build_dirs};
2012         my $sourced = catdir($srcdir, @curd);
2013         my $buildd = catdir($blddir, @curd);
2014
2015         my $unixdir = join('/', @curd);
2016         if (exists $skipdir{$unixdir}) {
2017             my $what = $skipdir{$unixdir};
2018             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
2019             next;
2020         }
2021
2022         mkpath($buildd);
2023
2024         my $f = 'build.info';
2025         # The basic things we're trying to build
2026         my @programs = ();
2027         my @libraries = ();
2028         my @modules = ();
2029         my @scripts = ();
2030
2031         my %sources = ();
2032         my %shared_sources = ();
2033         my %includes = ();
2034         my %defines = ();
2035         my %depends = ();
2036         my %generate = ();
2037         my %imagedocs = ();
2038         my %htmldocs = ();
2039         my %mandocs = ();
2040
2041         # Support for $variablename in build.info files.
2042         # Embedded perl code is the ultimate master, still.  If its output
2043         # contains a dollar sign, it had better be escaped, or it will be
2044         # taken for a variable name prefix.
2045         my %variables = ();
2046         # Variable name syntax
2047         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
2048         # Value modifier syntaxes
2049         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
2050         # Variable reference
2051         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
2052         my $variable_w_mod_re =
2053             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
2054         # Tie it all together
2055         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
2056
2057         my $expand_variables = sub {
2058             my $value = '';
2059             my $value_rest = shift;
2060
2061             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2062                 print STDERR
2063                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
2064             }
2065
2066             while ($value_rest =~ /${variable_re}/) {
2067                 # We must save important regexp values, because the next
2068                 # regexp clears them
2069                 my $mod = $+{MOD};
2070                 my $variable_value = $variables{$+{VARIABLE}};
2071
2072                 $value_rest = $';
2073                 $value .= $`;
2074
2075                 # Process modifier expressions, if present
2076                 if (defined $mod) {
2077                     if ($mod =~ /^${variable_subst_re}$/) {
2078                         my $re = $+{RE};
2079                         my $subst = $+{SUBST};
2080
2081                         $variable_value =~ s/\Q$re\E/$subst/g;
2082
2083                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2084                             print STDERR
2085                                 "DEBUG[\$expand_variables] ... and substituted ",
2086                                 "'$re' with '$subst'\n";
2087                         }
2088                     }
2089                 }
2090
2091                 $value .= $variable_value;
2092             }
2093             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2094                 print STDERR
2095                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2096             }
2097             return $value . $value_rest;
2098         };
2099
2100         # Support for attributes in build.info files
2101         my %attributes = ();
2102         my $handle_attributes = sub {
2103             my $attr_str = shift;
2104             my $ref = shift;
2105             my @goals = @_;
2106
2107             return unless defined $attr_str;
2108
2109             my @a = tokenize($attr_str, qr|\s*,\s*|);
2110             foreach my $a (@a) {
2111                 my $ac = 1;
2112                 my $ak = $a;
2113                 my $av = 1;
2114                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2115                     $ac = ! $1;
2116                     $ak = $2;
2117                     $av = $3;
2118                 }
2119                 foreach my $g (@goals) {
2120                     if ($ac) {
2121                         $$ref->{$g}->{$ak} = $av;
2122                     } else {
2123                         delete $$ref->{$g}->{$ak};
2124                     }
2125                 }
2126             }
2127         };
2128
2129         # Support for pushing values on multiple indexes of a given hash
2130         # array.
2131         my $push_to = sub {
2132             my $valueref = shift;
2133             my $index_str = shift; # May be undef or empty
2134             my $attrref = shift;   # May be undef
2135             my $attr_str = shift;
2136             my @values = @_;
2137
2138             if (defined $index_str) {
2139                 my @indexes = ( '' );
2140                 if ($index_str !~ m|^\s*$|) {
2141                     @indexes = tokenize($index_str);
2142                 }
2143                 foreach (@indexes) {
2144                     push @{$valueref->{$_}}, @values;
2145                     if (defined $attrref) {
2146                         $handle_attributes->($attr_str, \$$attrref->{$_},
2147                                              @values);
2148                     }
2149                 }
2150             } else {
2151                 push @$valueref, @values;
2152                 $handle_attributes->($attr_str, $attrref, @values)
2153                     if defined $attrref;
2154             }
2155         };
2156
2157         if ($buildinfo_debug) {
2158             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2159         }
2160         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2161         my $template =
2162             Text::Template->new(TYPE => 'FILE',
2163                                 SOURCE => catfile($sourced, $f),
2164                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2165         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2166         my @text =
2167             split /^/m,
2168             $template->fill_in(HASH => { config => \%config,
2169                                          target => \%target,
2170                                          disabled => \%disabled,
2171                                          withargs => \%withargs,
2172                                          builddir => abs2rel($buildd, $blddir),
2173                                          sourcedir => abs2rel($sourced, $blddir),
2174                                          buildtop => abs2rel($blddir, $blddir),
2175                                          sourcetop => abs2rel($srcdir, $blddir) },
2176                                DELIMITERS => [ "{-", "-}" ]);
2177
2178         # The top item of this stack has the following values
2179         # -2 positive already run and we found ELSE (following ELSIF should fail)
2180         # -1 positive already run (skip until ENDIF)
2181         # 0 negatives so far (if we're at a condition, check it)
2182         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2183         # 2 positive ELSE (following ELSIF should fail)
2184         my @skip = ();
2185
2186         # A few useful generic regexps
2187         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2188         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2189         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2190         my $value_re = qr/(?P<VALUE>.*?)/;
2191         collect_information(
2192             collect_from_array([ @text ],
2193                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2194                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2195             # Info we're looking for
2196             qr/^\s* IF ${cond_re} \s*$/x
2197             => sub {
2198                 if (! @skip || $skip[$#skip] > 0) {
2199                     push @skip, !! $expand_variables->($+{COND});
2200                 } else {
2201                     push @skip, -1;
2202                 }
2203             },
2204             qr/^\s* ELSIF ${cond_re} \s*$/x
2205             => sub { die "ELSIF out of scope" if ! @skip;
2206                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2207                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2208                      $skip[$#skip] = !! $expand_variables->($+{COND})
2209                          if $skip[$#skip] == 0; },
2210             qr/^\s* ELSE \s*$/x
2211             => sub { die "ELSE out of scope" if ! @skip;
2212                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2213                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2214             qr/^\s* ENDIF \s*$/x
2215             => sub { die "ENDIF out of scope" if ! @skip;
2216                      pop @skip; },
2217             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2218             => sub {
2219                 if (!@skip || $skip[$#skip] > 0) {
2220                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2221                 }
2222             },
2223             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2224             => sub {
2225                 if (!@skip || $skip[$#skip] > 0) {
2226                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2227                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2228                     }
2229                 }
2230             },
2231             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2232             => sub { $push_to->(\@programs, undef,
2233                                 \$attributes{programs}, $+{ATTRIBS},
2234                                 tokenize($expand_variables->($+{VALUE})))
2235                          if !@skip || $skip[$#skip] > 0; },
2236             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2237             => sub { $push_to->(\@libraries, undef,
2238                                 \$attributes{libraries}, $+{ATTRIBS},
2239                                 tokenize($expand_variables->($+{VALUE})))
2240                          if !@skip || $skip[$#skip] > 0; },
2241             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2242             => sub { $push_to->(\@modules, undef,
2243                                 \$attributes{modules}, $+{ATTRIBS},
2244                                 tokenize($expand_variables->($+{VALUE})))
2245                          if !@skip || $skip[$#skip] > 0; },
2246             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2247             => sub { $push_to->(\@scripts, undef,
2248                                 \$attributes{scripts}, $+{ATTRIBS},
2249                                 tokenize($expand_variables->($+{VALUE})))
2250                          if !@skip || $skip[$#skip] > 0; },
2251             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2252             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2253                                 undef, undef,
2254                                 tokenize($expand_variables->($+{VALUE})))
2255                          if !@skip || $skip[$#skip] > 0; },
2256             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2257             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2258                                 undef, undef,
2259                                 tokenize($expand_variables->($+{VALUE})))
2260                          if !@skip || $skip[$#skip] > 0; },
2261             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2262             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2263                                 undef, undef,
2264                                 tokenize($expand_variables->($+{VALUE})))
2265                          if !@skip || $skip[$#skip] > 0; },
2266             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2267             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2268                                 \$attributes{sources}, $+{ATTRIBS},
2269                                 tokenize($expand_variables->($+{VALUE})))
2270                          if !@skip || $skip[$#skip] > 0; },
2271             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2272             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2273                                 \$attributes{sources}, $+{ATTRIBS},
2274                                 tokenize($expand_variables->($+{VALUE})))
2275                          if !@skip || $skip[$#skip] > 0; },
2276             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2277             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2278                                 undef, undef,
2279                                 tokenize($expand_variables->($+{VALUE})))
2280                          if !@skip || $skip[$#skip] > 0; },
2281             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2282             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2283                                 undef, undef,
2284                                 tokenize($expand_variables->($+{VALUE})))
2285                          if !@skip || $skip[$#skip] > 0; },
2286             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2287             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2288                                 \$attributes{depends}, $+{ATTRIBS},
2289                                 tokenize($expand_variables->($+{VALUE})))
2290                          if !@skip || $skip[$#skip] > 0; },
2291             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2292             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2293                                 \$attributes{generate}, $+{ATTRIBS},
2294                                 $expand_variables->($+{VALUE}))
2295                          if !@skip || $skip[$#skip] > 0; },
2296             qr/^\s* (?:\#.*)? $/x => sub { },
2297             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2298             "BEFORE" => sub {
2299                 if ($buildinfo_debug) {
2300                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2301                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2302                 }
2303             },
2304             "AFTER" => sub {
2305                 if ($buildinfo_debug) {
2306                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2307                 }
2308             },
2309             );
2310         die "runaway IF?" if (@skip);
2311
2312         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2313                 and !$config{dynamic_engines}) {
2314             die <<"EOF"
2315 ENGINES can only be used if configured with 'dynamic-engine'.
2316 This is usually a fault in a build.info file.
2317 EOF
2318         }
2319
2320         {
2321             my %infos = ( programs  => [ @programs  ],
2322                           libraries => [ @libraries ],
2323                           modules   => [ @modules   ],
2324                           scripts   => [ @scripts   ] );
2325             foreach my $k (keys %infos) {
2326                 foreach (@{$infos{$k}}) {
2327                     my $item = cleanfile($buildd, $_, $blddir);
2328                     $unified_info{$k}->{$item} = 1;
2329
2330                     # Fix up associated attributes
2331                     $unified_info{attributes}->{$k}->{$item} =
2332                         $attributes{$k}->{$_}
2333                         if defined $attributes{$k}->{$_};
2334                 }
2335             }
2336         }
2337
2338         # Check that we haven't defined any library as both shared and
2339         # explicitly static.  That is forbidden.
2340         my @doubles = ();
2341         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2342             (my $l = $_) =~ s/\.a$//;
2343             push @doubles, $l if defined $unified_info{libraries}->{$l};
2344         }
2345         die "these libraries are both explicitly static and shared:\n  ",
2346             join(" ", @doubles), "\n"
2347             if @doubles;
2348
2349         foreach (keys %sources) {
2350             my $dest = $_;
2351             my $ddest = cleanfile($buildd, $_, $blddir);
2352             foreach (@{$sources{$dest}}) {
2353                 my $s = cleanfile($sourced, $_, $blddir, 1);
2354
2355                 # If it's generated or we simply don't find it in the source
2356                 # tree, we assume it's in the build tree.
2357                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2358                     $s = cleanfile($buildd, $_, $blddir);
2359                 }
2360                 my $o = $_;
2361                 # We recognise C++, C and asm files
2362                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2363                     push @{$check_exist{$s}}, $ddest;
2364                     $o =~ s/\.[csS]$/.o/; # C and assembler
2365                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2366                     $o = cleanfile($buildd, $o, $blddir);
2367                     $unified_info{sources}->{$ddest}->{$o} = -1;
2368                     $unified_info{sources}->{$o}->{$s} = -1;
2369                 } elsif ($s =~ /\.rc$/) {
2370                     # We also recognise resource files
2371                     push @{$check_exist{$s}}, $ddest;
2372                     $o =~ s/\.rc$/.res/; # Resource configuration
2373                     $o = cleanfile($buildd, $o, $blddir);
2374                     $unified_info{sources}->{$ddest}->{$o} = -1;
2375                     $unified_info{sources}->{$o}->{$s} = -1;
2376                 } else {
2377                     push @{$check_exist{$s}}, $ddest;
2378                     $unified_info{sources}->{$ddest}->{$s} = 1;
2379                 }
2380                 # Fix up associated attributes
2381                 if ($o ne $_) {
2382                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2383                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2384                         $attributes{sources}->{$dest}->{$_}
2385                         if defined $attributes{sources}->{$dest}->{$_};
2386                 } else {
2387                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2388                         $attributes{sources}->{$dest}->{$_}
2389                         if defined $attributes{sources}->{$dest}->{$_};
2390                 }
2391             }
2392         }
2393
2394         foreach (keys %shared_sources) {
2395             my $dest = $_;
2396             my $ddest = cleanfile($buildd, $_, $blddir);
2397             foreach (@{$shared_sources{$dest}}) {
2398                 my $s = cleanfile($sourced, $_, $blddir, 1);
2399
2400                 # If it's generated or we simply don't find it in the source
2401                 # tree, we assume it's in the build tree.
2402                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2403                     $s = cleanfile($buildd, $_, $blddir);
2404                 }
2405
2406                 my $o = $_;
2407                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2408                     # We recognise C++, C and asm files
2409                     push @{$check_exist{$s}}, $ddest;
2410                     $o =~ s/\.[csS]$/.o/; # C and assembler
2411                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2412                     $o = cleanfile($buildd, $o, $blddir);
2413                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2414                     $unified_info{sources}->{$o}->{$s} = -1;
2415                 } elsif ($s =~ /\.rc$/) {
2416                     # We also recognise resource files
2417                     push @{$check_exist{$s}}, $ddest;
2418                     $o =~ s/\.rc$/.res/; # Resource configuration
2419                     $o = cleanfile($buildd, $o, $blddir);
2420                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2421                     $unified_info{sources}->{$o}->{$s} = -1;
2422                 } elsif ($s =~ /\.ld$/) {
2423                     # We also recognise linker scripts (or corresponding)
2424                     # We know they are generated files
2425                     push @{$check_exist{$s}}, $ddest;
2426                     $o = cleanfile($buildd, $_, $blddir);
2427                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2428                 } else {
2429                     die "unrecognised source file type for shared library: $s\n";
2430                 }
2431                 # Fix up associated attributes
2432                 if ($o ne $_) {
2433                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2434                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2435                         $attributes{sources}->{$dest}->{$_}
2436                         if defined $attributes{sources}->{$dest}->{$_};
2437                 } else {
2438                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2439                         $attributes{sources}->{$dest}->{$_}
2440                         if defined $attributes{sources}->{$dest}->{$_};
2441                 }
2442             }
2443         }
2444
2445         foreach (keys %generate) {
2446             my $dest = $_;
2447             my $ddest = cleanfile($buildd, $_, $blddir);
2448             die "more than one generator for $dest: "
2449                 ,join(" ", @{$generate{$_}}),"\n"
2450                 if scalar @{$generate{$_}} > 1;
2451             my @generator = split /\s+/, $generate{$dest}->[0];
2452             my $gen = $generator[0];
2453             $generator[0] = cleanfile($sourced, $gen, $blddir, 1);
2454
2455             # If the generator is itself generated, it's in the build tree
2456             if ($generate{$gen} || ! -f $generator[0]) {
2457                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2458             }
2459             $check_generate{$ddest}->{$generator[0]}++;
2460
2461             $unified_info{generate}->{$ddest} = [ @generator ];
2462             # Fix up associated attributes
2463             $unified_info{attributes}->{generate}->{$ddest} =
2464                 $attributes{generate}->{$dest}->{$gen}
2465                 if defined $attributes{generate}->{$dest}->{$gen};
2466         }
2467
2468         foreach (keys %depends) {
2469             my $dest = $_;
2470             my $ddest = $dest;
2471
2472             if ($dest =~ /^\|(.*)\|$/) {
2473                 # Collect the raw target
2474                 $unified_info{targets}->{$1} = 1;
2475                 $ddest = $1;
2476             } elsif ($dest eq '') {
2477                 $ddest = '';
2478             } else {
2479                 $ddest = cleanfile($sourced, $dest, $blddir, 1);
2480
2481                 # If the destination doesn't exist in source, it can only be
2482                 # a generated file in the build tree.
2483                 if ($ddest eq $src_configdata || ! -f $ddest) {
2484                     $ddest = cleanfile($buildd, $dest, $blddir);
2485                 }
2486             }
2487             foreach my $f (@{$depends{$dest}}) {
2488                 # If the dependency destination is generated, dependencies
2489                 # may have an extra syntax to separate the intended inclusion
2490                 # directory from the module to be loaded: a | instead of a
2491                 # / as directory separator.
2492                 # Do note that this has to be handled in the build file
2493                 # template as well.
2494                 # $i = inclusion path in source directory
2495                 # $i2 = inclusion path in build directory
2496                 # $m = module path (within the inclusion path)
2497                 # $i = full module path in source directory
2498                 # $i2 = full module path in build directory
2499                 my $i; my $i2; my $m; my $d; my $d2;
2500                 if ($unified_info{generate}->{$ddest}
2501                     && $f =~ m/^(.*?)\|(.*)$/) {
2502                     $i = $1;
2503                     $m = $2;
2504                     # We must be very careful to modify $i last
2505                     $d = cleanfile($sourced, "$i/$m", $blddir, 1);
2506                     $d2 = cleanfile($buildd, "$i/$m", $blddir);
2507                     $i2 = cleandir($buildd, $i, $blddir);
2508                     $i = cleandir($sourced, $i, $blddir, 1);
2509                 } else {
2510                     $d = cleanfile($sourced, $f, $blddir, 1);
2511                     $d2 = cleanfile($buildd, $f, $blddir);
2512                 }
2513
2514                 # If we know it's generated, or assume it is because we can't
2515                 # find it in the source tree, we set file we depend on to be
2516                 # in the build tree rather than the source tree.
2517                 if ($d eq $src_configdata
2518                     || (grep { $d2 eq $_ }
2519                         keys %{$unified_info{generate}})
2520                     || ! -f $d) {
2521                     $d = $d2;
2522                     $i = $i2;
2523                 }
2524                 if ($i) {
2525                     # Put together the computed inclusion dir with the
2526                     # original module name.  Do note that we conserve the
2527                     # Unixly path syntax for the module path.
2528                     $d = "$i|$m";
2529                 }
2530                 $unified_info{depends}->{$ddest}->{$d} = 1;
2531
2532                 # Fix up associated attributes
2533                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2534                     $attributes{depends}->{$dest}->{$f}
2535                     if defined $attributes{depends}->{$dest}->{$f};
2536             }
2537         }
2538
2539         foreach (keys %includes) {
2540             my $dest = $_;
2541             my $ddest = cleanfile($sourced, $_, $blddir, 1);
2542
2543             # If the destination doesn't exist in source, it can only be
2544             # a generated file in the build tree.
2545             if ($ddest eq $src_configdata || ! -f $ddest) {
2546                 $ddest = cleanfile($buildd, $_, $blddir);
2547             }
2548             foreach (@{$includes{$dest}}) {
2549                 my $is = cleandir($sourced, $_, $blddir, 1);
2550                 my $ib = cleandir($buildd, $_, $blddir);
2551                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2552                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2553                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2554                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2555             }
2556         }
2557
2558         foreach my $dest (keys %defines) {
2559             my $ddest;
2560
2561             if ($dest ne "") {
2562                 $ddest = cleanfile($sourced, $dest, $blddir, 1);
2563
2564                 # If the destination doesn't exist in source, it can only
2565                 # be a generated file in the build tree.
2566                 if (! -f $ddest) {
2567                     $ddest = cleanfile($buildd, $dest, $blddir);
2568                 }
2569             }
2570             foreach my $v (@{$defines{$dest}}) {
2571                 $v =~ m|^([^=]*)(=.*)?$|;
2572                 die "0 length macro name not permitted\n" if $1 eq "";
2573                 if ($dest ne "") {
2574                     die "$1 defined more than once\n"
2575                         if defined $unified_info{defines}->{$ddest}->{$1};
2576                     $unified_info{defines}->{$ddest}->{$1} = $2;
2577                 } else {
2578                     die "$1 defined more than once\n"
2579                         if grep { $v eq $_ } @{$config{defines}};
2580                     push @{$config{defines}}, $v;
2581                 }
2582             }
2583         }
2584
2585         foreach my $section (keys %imagedocs) {
2586             foreach (@{$imagedocs{$section}}) {
2587                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2588                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2589             }
2590         }
2591
2592         foreach my $section (keys %htmldocs) {
2593             foreach (@{$htmldocs{$section}}) {
2594                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2595                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2596             }
2597         }
2598
2599         foreach my $section (keys %mandocs) {
2600             foreach (@{$mandocs{$section}}) {
2601                 my $mandocs = cleanfile($buildd, $_, $blddir);
2602                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2603             }
2604         }
2605     }
2606
2607     my $ordinals_text = join(', ', sort keys %ordinals);
2608     warn <<"EOF" if $ordinals_text;
2609
2610 WARNING: ORDINALS were specified for $ordinals_text
2611 They are ignored and should be replaced with a combination of GENERATE,
2612 DEPEND and SHARED_SOURCE.
2613 EOF
2614
2615     # Check that each generated file is only generated once
2616     my $ambiguous_generation = 0;
2617     foreach (sort keys %check_generate) {
2618         my @generators = sort keys %{$check_generate{$_}};
2619         my $generators_txt = join(', ', @generators);
2620         if (scalar @generators > 1) {
2621             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2622             $ambiguous_generation++;
2623         }
2624         if ($check_generate{$_}->{$generators[0]} > 1) {
2625             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2626         }
2627     }
2628     die "There are ambiguous source file generations\n"
2629         if $ambiguous_generation > 0;
2630
2631     # All given source files should exist, or if generated, their
2632     # generator should exist.  This loop ensures this is true.
2633     my $missing = 0;
2634     foreach my $orig (sort keys %check_exist) {
2635         foreach my $dest (@{$check_exist{$orig}}) {
2636             if ($orig ne $src_configdata) {
2637                 if ($orig =~ /\.a$/) {
2638                     # Static library names may be used as sources, so we
2639                     # need to detect those and give them special treatment.
2640                     unless (grep { $_ eq $orig }
2641                             keys %{$unified_info{libraries}}) {
2642                         warn "$orig is given as source for $dest, but no such library is built\n";
2643                         $missing++;
2644                     }
2645                 } else {
2646                     # A source may be generated, and its generator may be
2647                     # generated as well.  We therefore loop to dig out the
2648                     # first generator.
2649                     my $gen = $orig;
2650
2651                     while (my @next = keys %{$check_generate{$gen}}) {
2652                         $gen = $next[0];
2653                     }
2654
2655                     if (! -f $gen) {
2656                         if ($gen ne $orig) {
2657                             $missing++;
2658                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2659                         } else {
2660                             $missing++;
2661                             warn "$orig is given as source for $dest, but is missing\n";
2662                         }
2663                     }
2664                 }
2665             }
2666         }
2667     }
2668     die "There are files missing\n" if $missing > 0;
2669
2670     # Go through the sources of all libraries and check that the same basename
2671     # doesn't appear more than once.  Some static library archivers depend on
2672     # them being unique.
2673     {
2674         my $err = 0;
2675         foreach my $prod (keys %{$unified_info{libraries}}) {
2676             my @prod_sources =
2677                 map { keys %{$unified_info{sources}->{$_}} }
2678                 keys %{$unified_info{sources}->{$prod}};
2679             my %srccnt = ();
2680
2681             # Count how many times a given each source basename
2682             # appears for each product.
2683             foreach my $src (@prod_sources) {
2684                 $srccnt{basename $src}++;
2685             }
2686
2687             foreach my $src (keys %srccnt) {
2688                 if ((my $cnt = $srccnt{$src}) > 1) {
2689                     print STDERR "$src appears $cnt times for the product $prod\n";
2690                     $err++
2691                 }
2692             }
2693         }
2694         die if $err > 0;
2695     }
2696
2697     # Massage the result
2698
2699     # If we depend on a header file or a perl module, add an inclusion of
2700     # its directory to allow smoothe inclusion
2701     foreach my $dest (keys %{$unified_info{depends}}) {
2702         next if $dest eq "";
2703         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2704             next unless $d =~ /\.(h|pm)$/;
2705             # Take into account when a dependency uses the inclusion|module
2706             # syntax
2707             my $i = $d =~ m/\|/ ? $` : dirname($d);
2708             my $spot =
2709                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2710                 ? 'build' : 'source';
2711             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2712                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2713         }
2714     }
2715
2716     # Go through all intermediary files and change their names to something that
2717     # reflects what they will be built for.  Note that for some source files,
2718     # this leads to duplicate object files because they are used multiple times.
2719     # the goal is to rename all object files according to this scheme:
2720     #    {productname}-{midfix}-{origobjname}.[o|res]
2721     # the {midfix} is a keyword indicating the type of product, which is mostly
2722     # valuable for libraries since they come in two forms.
2723     #
2724     # This also reorganises the {sources} and {shared_sources} so that the
2725     # former only contains ALL object files that are supposed to end up in
2726     # static libraries and programs, while the latter contains ALL object files
2727     # that are supposed to end up in shared libraries and DSOs.
2728     # The main reason for having two different source structures is to allow
2729     # the same name to be used for the static and the shared variants of a
2730     # library.
2731     {
2732         # Take copies so we don't get interference from added stuff
2733         my %unified_copy = ();
2734         foreach (('sources', 'shared_sources')) {
2735             $unified_copy{$_} = { %{$unified_info{$_}} }
2736                 if defined($unified_info{$_});
2737             delete $unified_info{$_};
2738         }
2739         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2740             # $intent serves multi purposes:
2741             # - give a prefix for the new object files names
2742             # - in the case of libraries, rearrange the object files so static
2743             #   libraries use the 'sources' structure exclusively, while shared
2744             #   libraries use the 'shared_sources' structure exclusively.
2745             my $intent = {
2746                 programs  => { bin    => { src => [ 'sources' ],
2747                                            dst => 'sources' } },
2748                 libraries => { lib    => { src => [ 'sources' ],
2749                                            dst => 'sources' },
2750                                shlib  => { prodselect =>
2751                                                sub { grep !/\.a$/, @_ },
2752                                            src => [ 'sources',
2753                                                     'shared_sources' ],
2754                                            dst => 'shared_sources' } },
2755                 modules   => { dso    => { src => [ 'sources' ],
2756                                            dst => 'sources' } },
2757                 scripts   => { script => { src => [ 'sources' ],
2758                                            dst => 'sources' } }
2759                } -> {$prodtype};
2760             foreach my $kind (keys %$intent) {
2761                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2762                              && $disabled{shared});
2763
2764                 my @src = @{$intent->{$kind}->{src}};
2765                 my $dst = $intent->{$kind}->{dst};
2766                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2767                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2768                     # %prod_sources has all applicable objects as keys, and
2769                     # their corresponding sources as values
2770                     my %prod_sources =
2771                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2772                         map { keys %{$unified_copy{$_}->{$prod}} }
2773                         @src;
2774                     foreach (keys %prod_sources) {
2775                         # Only affect object files and resource files,
2776                         # the others simply get a new value
2777                         # (+1 instead of -1)
2778                         if ($_ =~ /\.(o|res)$/) {
2779                             (my $prodname = $prod) =~ s|\.a$||;
2780                             my $newobj =
2781                                 catfile(dirname($_),
2782                                         basename($prodname)
2783                                             . '-' . $kind
2784                                             . '-' . basename($_));
2785                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2786                             foreach my $src (@{$prod_sources{$_}}) {
2787                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2788                                 # Adjust source attributes
2789                                 my $attrs = $unified_info{attributes}->{sources};
2790                                 if (defined $attrs->{$prod}
2791                                     && defined $attrs->{$prod}->{$_}) {
2792                                     $attrs->{$prod}->{$newobj} =
2793                                         $attrs->{$prod}->{$_};
2794                                     delete $attrs->{$prod}->{$_};
2795                                 }
2796                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2797                                     $attrs->{$newobj}->{$objsrc} =
2798                                         $attrs->{$_}->{$objsrc};
2799                                     delete $attrs->{$_}->{$objsrc};
2800                                 }
2801                             }
2802                             # Adjust dependencies
2803                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2804                                 $unified_info{depends}->{$_}->{$deps} = -1;
2805                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2806                             }
2807                             # Adjust includes
2808                             foreach my $k (('source', 'build')) {
2809                                 next unless
2810                                     defined($unified_info{includes}->{$_}->{$k});
2811                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2812                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2813                             }
2814                         } else {
2815                             $unified_info{$dst}->{$prod}->{$_} = 1;
2816                         }
2817                     }
2818                 }
2819             }
2820         }
2821     }
2822
2823     # At this point, we have a number of sources with the value -1.  They
2824     # aren't part of the local build and are probably meant for a different
2825     # platform, and can therefore be cleaned away.  That happens when making
2826     # %unified_info more efficient below.
2827
2828     ### Make unified_info a bit more efficient
2829     # One level structures
2830     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2831         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2832     }
2833     # Two level structures
2834     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2835                      "imagedocs", "htmldocs", "mandocs")) {
2836         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2837             my @items =
2838                 sort
2839                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2840                 keys %{$unified_info{$l1}->{$l2}};
2841             if (@items) {
2842                 $unified_info{$l1}->{$l2} = [ @items ];
2843             } else {
2844                 delete $unified_info{$l1}->{$l2};
2845             }
2846         }
2847     }
2848     # Defines
2849     foreach my $dest (sort keys %{$unified_info{defines}}) {
2850         $unified_info{defines}->{$dest}
2851             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2852                 sort keys %{$unified_info{defines}->{$dest}} ];
2853     }
2854     # Includes
2855     foreach my $dest (sort keys %{$unified_info{includes}}) {
2856         if (defined($unified_info{includes}->{$dest}->{build})) {
2857             my @source_includes = ();
2858             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2859                 if defined($unified_info{includes}->{$dest}->{source});
2860             $unified_info{includes}->{$dest} =
2861                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2862             foreach my $inc (@source_includes) {
2863                 push @{$unified_info{includes}->{$dest}}, $inc
2864                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2865             }
2866         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2867             $unified_info{includes}->{$dest} =
2868                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2869         } else {
2870             delete $unified_info{includes}->{$dest};
2871         }
2872     }
2873
2874     # For convenience collect information regarding directories where
2875     # files are generated, those generated files and the end product
2876     # they end up in where applicable.  Then, add build rules for those
2877     # directories
2878     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2879                      "dso" => [ @{$unified_info{modules}} ],
2880                      "bin" => [ @{$unified_info{programs}} ],
2881                      "script" => [ @{$unified_info{scripts}} ],
2882                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2883                                   keys %{$unified_info{imagedocs} // {}}),
2884                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2885                                   keys %{$unified_info{htmldocs} // {}}),
2886                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2887                                   keys %{$unified_info{mandocs} // {}}) ] );
2888     foreach my $type (sort keys %loopinfo) {
2889         foreach my $product (@{$loopinfo{$type}}) {
2890             my %dirs = ();
2891             my $pd = dirname($product);
2892
2893             foreach (@{$unified_info{sources}->{$product} // []},
2894                      @{$unified_info{shared_sources}->{$product} // []}) {
2895                 my $d = dirname($_);
2896
2897                 # We don't want to create targets for source directories
2898                 # when building out of source
2899                 next if ($config{sourcedir} ne $config{builddir}
2900                              && $d =~ m|^\Q$config{sourcedir}\E|);
2901                 # We already have a "test" target, and the current directory
2902                 # is just silly to make a target for
2903                 next if $d eq "test" || $d eq ".";
2904
2905                 $dirs{$d} = 1;
2906                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2907                     if $d ne $pd;
2908             }
2909             foreach (sort keys %dirs) {
2910                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2911                     $product;
2912             }
2913         }
2914     }
2915 }
2916
2917 # For the schemes that need it, we provide the old *_obj configs
2918 # from the *_asm_obj ones
2919 foreach (grep /_(asm|aux)_src$/, keys %target) {
2920     my $src = $_;
2921     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2922     $target{$obj} = $target{$src};
2923     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2924     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2925 }
2926
2927 # Write down our configuration where it fits #########################
2928
2929 my %template_vars = (
2930     config => \%config,
2931     target => \%target,
2932     disablables => \@disablables,
2933     disablables_int => \@disablables_int,
2934     disabled => \%disabled,
2935     withargs => \%withargs,
2936     unified_info => \%unified_info,
2937     tls => \@tls,
2938     dtls => \@dtls,
2939     makevars => [ sort keys %user ],
2940     disabled_info => \%disabled_info,
2941     user_crossable => \@user_crossable,
2942 );
2943 my $configdata_outname = 'configdata.pm';
2944 open CONFIGDATA, ">$configdata_outname.new"
2945     or die "Trying to create $configdata_outname.new: $!";
2946 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir, 1);
2947 my $configdata_tmpl =
2948     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2949 $configdata_tmpl->fill_in(
2950     FILENAME => $configdata_tmplname,
2951     OUTPUT => \*CONFIGDATA,
2952     HASH => { %template_vars,
2953               autowarntext => [
2954                   'WARNING: do not edit!',
2955                   "Generated by Configure from $configdata_tmplname",
2956               ] }
2957 ) or die $Text::Template::ERROR;
2958 close CONFIGDATA;
2959
2960 rename "$configdata_outname.new", $configdata_outname;
2961 if ($builder_platform eq 'unix') {
2962     my $mode = (0755 & ~umask);
2963     chmod $mode, 'configdata.pm'
2964         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2965 }
2966 print "Created $configdata_outname\n";
2967
2968 print "Running $configdata_outname\n";
2969 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2970 my $cmd = "$perlcmd $configdata_outname";
2971 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2972 system($cmd);
2973 exit 1 if $? != 0;
2974
2975 $SIG{__DIE__} = $orig_death_handler;
2976
2977 print <<"EOF" if ($disabled{threads} eq "unavailable");
2978
2979 The library could not be configured for supporting multi-threaded
2980 applications as the compiler options required on this system are not known.
2981 See file INSTALL.md for details if you need multi-threading.
2982 EOF
2983
2984 print <<"EOF" if ($no_shared_warn);
2985
2986 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2987 platform, so we will pretend you gave the option 'no-pic', which also disables
2988 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2989 or position independent code, please let us know (but please first make sure
2990 you have tried with a current version of OpenSSL).
2991 EOF
2992
2993 print $banner;
2994
2995 exit(0);
2996
2997 ######################################################################
2998 #
2999 # Helpers and utility functions
3000 #
3001
3002 # Death handler, to print a helpful message in case of failure #######
3003 #
3004 sub death_handler {
3005     die @_ if $^S;              # To prevent the added message in eval blocks
3006     my $build_file = $config{build_file} // "build file";
3007     my @message = ( <<"_____", @_ );
3008
3009 Failure!  $build_file wasn't produced.
3010 Please read INSTALL.md and associated NOTES-* files.  You may also have to
3011 look over your available compiler tool chain or change your configuration.
3012
3013 _____
3014
3015     # Dying is terminal, so it's ok to reset the signal handler here.
3016     $SIG{__DIE__} = $orig_death_handler;
3017     die @message;
3018 }
3019
3020 # Configuration file reading #########################################
3021
3022 # Note: All of the helper functions are for lazy evaluation.  They all
3023 # return a CODE ref, which will return the intended value when evaluated.
3024 # Thus, whenever there's mention of a returned value, it's about that
3025 # intended value.
3026
3027 # Helper function to implement conditional value variants, with a default
3028 # plus additional values based on the value of $config{build_type}.
3029 # Arguments are given in hash table form:
3030 #
3031 #       picker(default => "Basic string: ",
3032 #              debug   => "debug",
3033 #              release => "release")
3034 #
3035 # When configuring with --debug, the resulting string will be
3036 # "Basic string: debug", and when not, it will be "Basic string: release"
3037 #
3038 # This can be used to create variants of sets of flags according to the
3039 # build type:
3040 #
3041 #       cflags => picker(default => "-Wall",
3042 #                        debug   => "-g -O0",
3043 #                        release => "-O3")
3044 #
3045 sub picker {
3046     my %opts = @_;
3047     return sub { add($opts{default} || (),
3048                      $opts{$config{build_type}} || ())->(); }
3049 }
3050
3051 # Helper function to combine several values of different types into one.
3052 # This is useful if you want to combine a string with the result of a
3053 # lazy function, such as:
3054 #
3055 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3056 #
3057 sub combine {
3058     my @stuff = @_;
3059     return sub { add(@stuff)->(); }
3060 }
3061
3062 # Helper function to implement conditional values depending on the value
3063 # of $disabled{threads}.  Can be used as follows:
3064 #
3065 #       cflags => combine("-Wall", threads("-pthread"))
3066 #
3067 sub threads {
3068     my @flags = @_;
3069     return sub { add($disabled{threads} ? () : @flags)->(); }
3070 }
3071
3072 sub shared {
3073     my @flags = @_;
3074     return sub { add($disabled{shared} ? () : @flags)->(); }
3075 }
3076
3077 our $add_called = 0;
3078 # Helper function to implement adding values to already existing configuration
3079 # values.  It handles elements that are ARRAYs, CODEs and scalars
3080 sub _add {
3081     my $separator = shift;
3082
3083     # If there's any ARRAY in the collection of values OR the separator
3084     # is undef, we will return an ARRAY of combined values, otherwise a
3085     # string of joined values with $separator as the separator.
3086     my $found_array = !defined($separator);
3087
3088     my @values =
3089         map {
3090             my $res = $_;
3091             while (ref($res) eq "CODE") {
3092                 $res = $res->();
3093             }
3094             if (defined($res)) {
3095                 if (ref($res) eq "ARRAY") {
3096                     $found_array = 1;
3097                     @$res;
3098                 } else {
3099                     $res;
3100                 }
3101             } else {
3102                 ();
3103             }
3104     } (@_);
3105
3106     $add_called = 1;
3107
3108     if ($found_array) {
3109         [ @values ];
3110     } else {
3111         join($separator, grep { defined($_) && $_ ne "" } @values);
3112     }
3113 }
3114 sub add_before {
3115     my $separator = " ";
3116     if (ref($_[$#_]) eq "HASH") {
3117         my $opts = pop;
3118         $separator = $opts->{separator};
3119     }
3120     my @x = @_;
3121     sub { _add($separator, @x, @_) };
3122 }
3123 sub add {
3124     my $separator = " ";
3125     if (ref($_[$#_]) eq "HASH") {
3126         my $opts = pop;
3127         $separator = $opts->{separator};
3128     }
3129     my @x = @_;
3130     sub { _add($separator, @_, @x) };
3131 }
3132
3133 sub read_eval_file {
3134     my $fname = shift;
3135     my $content;
3136     my @result;
3137
3138     open F, "< $fname" or die "Can't open '$fname': $!\n";
3139     {
3140         undef local $/;
3141         $content = <F>;
3142     }
3143     close F;
3144     {
3145         local $@;
3146
3147         @result = ( eval $content );
3148         warn $@ if $@;
3149     }
3150     return wantarray ? @result : $result[0];
3151 }
3152
3153 # configuration reader, evaluates the input file as a perl script and expects
3154 # it to fill %targets with target configurations.  Those are then added to
3155 # %table.
3156 sub read_config {
3157     my $fname = shift;
3158     my %targets;
3159
3160     {
3161         # Protect certain tables from tampering
3162         local %table = ();
3163
3164         %targets = read_eval_file($fname);
3165     }
3166     my %preexisting = ();
3167     foreach (sort keys %targets) {
3168         $preexisting{$_} = 1 if $table{$_};
3169     }
3170     die <<"EOF",
3171 The following config targets from $fname
3172 shadow pre-existing config targets with the same name:
3173 EOF
3174         map { "  $_\n" } sort keys %preexisting
3175         if %preexisting;
3176
3177
3178     # For each target, check that it's configured with a hash table.
3179     foreach (keys %targets) {
3180         if (ref($targets{$_}) ne "HASH") {
3181             if (ref($targets{$_}) eq "") {
3182                 warn "Deprecated target configuration for $_, ignoring...\n";
3183             } else {
3184                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3185             }
3186             delete $targets{$_};
3187         } else {
3188             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3189         }
3190     }
3191
3192     %table = (%table, %targets);
3193
3194 }
3195
3196 # configuration resolver.  Will only resolve all the lazy evaluation
3197 # codeblocks for the chosen target and all those it inherits from,
3198 # recursively
3199 sub resolve_config {
3200     my $target = shift;
3201     my @breadcrumbs = @_;
3202
3203 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3204
3205     if (grep { $_ eq $target } @breadcrumbs) {
3206         die "inherit_from loop!  target backtrace:\n  "
3207             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3208     }
3209
3210     if (!defined($table{$target})) {
3211         warn "Warning! target $target doesn't exist!\n";
3212         return ();
3213     }
3214     # Recurse through all inheritances.  They will be resolved on the
3215     # fly, so when this operation is done, they will all just be a
3216     # bunch of attributes with string values.
3217     # What we get here, though, are keys with references to lists of
3218     # the combined values of them all.  We will deal with lists after
3219     # this stage is done.
3220     my %combined_inheritance = ();
3221     if ($table{$target}->{inherit_from}) {
3222         my @inherit_from =
3223             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3224         foreach (@inherit_from) {
3225             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3226
3227             # 'template' is a marker that's considered private to
3228             # the config that had it.
3229             delete $inherited_config{template};
3230
3231             foreach (keys %inherited_config) {
3232                 if (!$combined_inheritance{$_}) {
3233                     $combined_inheritance{$_} = [];
3234                 }
3235                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3236             }
3237         }
3238     }
3239
3240     # We won't need inherit_from in this target any more, since we've
3241     # resolved all the inheritances that lead to this
3242     delete $table{$target}->{inherit_from};
3243
3244     # Now is the time to deal with those lists.  Here's the place to
3245     # decide what shall be done with those lists, all based on the
3246     # values of the target we're currently dealing with.
3247     # - If a value is a coderef, it will be executed with the list of
3248     #   inherited values as arguments.
3249     # - If the corresponding key doesn't have a value at all or is the
3250     #   empty string, the inherited value list will be run through the
3251     #   default combiner (below), and the result becomes this target's
3252     #   value.
3253     # - Otherwise, this target's value is assumed to be a string that
3254     #   will simply override the inherited list of values.
3255     my $default_combiner = add();
3256
3257     my %all_keys =
3258         map { $_ => 1 } (keys %combined_inheritance,
3259                          keys %{$table{$target}});
3260
3261     sub process_values {
3262         my $object    = shift;
3263         my $inherited = shift;  # Always a [ list ]
3264         my $target    = shift;
3265         my $entry     = shift;
3266
3267         $add_called = 0;
3268
3269         while(ref($object) eq "CODE") {
3270             $object = $object->(@$inherited);
3271         }
3272         if (!defined($object)) {
3273             return ();
3274         }
3275         elsif (ref($object) eq "ARRAY") {
3276             local $add_called;  # To make sure recursive calls don't affect it
3277             return [ map { process_values($_, $inherited, $target, $entry) }
3278                      @$object ];
3279         } elsif (ref($object) eq "") {
3280             return $object;
3281         } else {
3282             die "cannot handle reference type ",ref($object)
3283                 ," found in target ",$target," -> ",$entry,"\n";
3284         }
3285     }
3286
3287     foreach my $key (sort keys %all_keys) {
3288         my $previous = $combined_inheritance{$key};
3289
3290         # Current target doesn't have a value for the current key?
3291         # Assign it the default combiner, the rest of this loop body
3292         # will handle it just like any other coderef.
3293         if (!exists $table{$target}->{$key}) {
3294             $table{$target}->{$key} = $default_combiner;
3295         }
3296
3297         $table{$target}->{$key} = process_values($table{$target}->{$key},
3298                                                $combined_inheritance{$key},
3299                                                $target, $key);
3300         unless(defined($table{$target}->{$key})) {
3301             delete $table{$target}->{$key};
3302         }
3303 #        if ($extra_checks &&
3304 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3305 #            warn "$key got replaced in $target\n";
3306 #        }
3307     }
3308
3309     # Finally done, return the result.
3310     return %{$table{$target}};
3311 }
3312
3313 sub usage
3314         {
3315         print STDERR $usage;
3316         print STDERR "\npick os/compiler from:\n";
3317         my $j=0;
3318         my $i;
3319         my $k=0;
3320         foreach $i (sort keys %table)
3321                 {
3322                 next if $table{$i}->{template};
3323                 next if $i =~ /^debug/;
3324                 $k += length($i) + 1;
3325                 if ($k > 78)
3326                         {
3327                         print STDERR "\n";
3328                         $k=length($i);
3329                         }
3330                 print STDERR $i . " ";
3331                 }
3332         foreach $i (sort keys %table)
3333                 {
3334                 next if $table{$i}->{template};
3335                 next if $i !~ /^debug/;
3336                 $k += length($i) + 1;
3337                 if ($k > 78)
3338                         {
3339                         print STDERR "\n";
3340                         $k=length($i);
3341                         }
3342                 print STDERR $i . " ";
3343                 }
3344         exit(1);
3345         }
3346
3347 sub compiler_predefined {
3348     state %predefined;
3349     my $cc = shift;
3350
3351     return () if $^O eq 'VMS';
3352
3353     die 'compiler_predefined called without a compiler command'
3354         unless $cc;
3355
3356     if (! $predefined{$cc}) {
3357
3358         $predefined{$cc} = {};
3359
3360         # collect compiler pre-defines from gcc or gcc-alike...
3361         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3362         while (my $l = <PIPE>) {
3363             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3364             $predefined{$cc}->{$1} = $2 // '';
3365         }
3366         close(PIPE);
3367     }
3368
3369     return %{$predefined{$cc}};
3370 }
3371
3372 sub which
3373 {
3374     my ($name)=@_;
3375
3376     if (eval { require IPC::Cmd; 1; }) {
3377         IPC::Cmd->import();
3378         return scalar IPC::Cmd::can_run($name);
3379     } else {
3380         # if there is $directories component in splitpath,
3381         # then it's not something to test with $PATH...
3382         return $name if (File::Spec->splitpath($name))[1];
3383
3384         foreach (File::Spec->path()) {
3385             my $fullpath = catfile($_, "$name$target{exe_extension}");
3386             if (-f $fullpath and -x $fullpath) {
3387                 return $fullpath;
3388             }
3389         }
3390     }
3391 }
3392
3393 sub env
3394 {
3395     my $name = shift;
3396     my %opts = @_;
3397
3398     unless ($opts{cacheonly}) {
3399         # Note that if $ENV{$name} doesn't exist or is undefined,
3400         # $config{perlenv}->{$name} will be created with the value
3401         # undef.  This is intentional.
3402
3403         $config{perlenv}->{$name} = $ENV{$name}
3404             if ! exists $config{perlenv}->{$name};
3405     }
3406     return $config{perlenv}->{$name};
3407 }
3408
3409 # Configuration printer ##############################################
3410
3411 sub print_table_entry
3412 {
3413     local $now_printing = shift;
3414     my %target = resolve_config($now_printing);
3415     my $type = shift;
3416
3417     # Don't print the templates
3418     return if $target{template};
3419
3420     my @sequence = (
3421         "sys_id",
3422         "cpp",
3423         "cppflags",
3424         "defines",
3425         "includes",
3426         "cc",
3427         "cflags",
3428         "ld",
3429         "lflags",
3430         "loutflag",
3431         "ex_libs",
3432         "bn_ops",
3433         "enable",
3434         "disable",
3435         "poly1035_asm_src",
3436         "thread_scheme",
3437         "perlasm_scheme",
3438         "dso_scheme",
3439         "shared_target",
3440         "shared_cflag",
3441         "shared_defines",
3442         "shared_ldflag",
3443         "shared_rcflag",
3444         "shared_extension",
3445         "dso_extension",
3446         "obj_extension",
3447         "exe_extension",
3448         "ranlib",
3449         "ar",
3450         "arflags",
3451         "aroutflag",
3452         "rc",
3453         "rcflags",
3454         "rcoutflag",
3455         "mt",
3456         "mtflags",
3457         "mtinflag",
3458         "mtoutflag",
3459         "multilib",
3460         "build_scheme",
3461         );
3462
3463     if ($type eq "TABLE") {
3464         print "\n";
3465         print "*** $now_printing\n";
3466         foreach (@sequence) {
3467             if (ref($target{$_}) eq "ARRAY") {
3468                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3469             } else {
3470                 printf "\$%-12s = %s\n", $_, $target{$_};
3471             }
3472         }
3473     } elsif ($type eq "HASH") {
3474         my $largest =
3475             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3476         print "    '$now_printing' => {\n";
3477         foreach (@sequence) {
3478             if ($target{$_}) {
3479                 if (ref($target{$_}) eq "ARRAY") {
3480                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3481                 } else {
3482                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3483                 }
3484             }
3485         }
3486         print "    },\n";
3487     }
3488 }
3489
3490 # Utility routines ###################################################
3491
3492 # On VMS, if the given file is a logical name, File::Spec::Functions
3493 # will consider it an absolute path.  There are cases when we want a
3494 # purely syntactic check without checking the environment.
3495 sub isabsolute {
3496     my $file = shift;
3497
3498     # On non-platforms, we just use file_name_is_absolute().
3499     return file_name_is_absolute($file) unless $^O eq "VMS";
3500
3501     # If the file spec includes a device or a directory spec,
3502     # file_name_is_absolute() is perfectly safe.
3503     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3504
3505     # Here, we know the given file spec isn't absolute
3506     return 0;
3507 }
3508
3509 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3510 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3511 # realpath() requires that at least all path components except the last is an
3512 # existing directory.  On VMS, the last component of the directory spec must
3513 # exist.
3514 sub absolutedir {
3515     my $dir = shift;
3516
3517     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3518     # will return the volume name for the device, no matter what.  Also,
3519     # it will return an incorrect directory spec if the argument is a
3520     # directory that doesn't exist.
3521     if ($^O eq "VMS") {
3522         return rel2abs($dir);
3523     }
3524
3525     # We use realpath() on Unix, since no other will properly clean out
3526     # a directory spec.
3527     use Cwd qw/realpath/;
3528
3529     return realpath($dir);
3530 }
3531
3532 # Check if all paths are one and the same, using stat.  They must both exist
3533 # We need this for the cases when File::Spec doesn't detect case insensitivity
3534 # (File::Spec::Unix assumes case sensitivity)
3535 sub samedir {
3536     die "samedir expects two arguments\n" unless scalar @_ == 2;
3537
3538     my @stat0 = stat($_[0]);    # First argument
3539     my @stat1 = stat($_[1]);    # Second argument
3540
3541     die "Couldn't stat $_[0]" unless @stat0;
3542     die "Couldn't stat $_[1]" unless @stat1;
3543
3544     # Compare device number
3545     return 0 unless ($stat0[0] == $stat1[0]);
3546     # Compare "inode".  The perl manual recommends comparing as
3547     # string rather than as number.
3548     return 0 unless ($stat0[1] eq $stat1[1]);
3549
3550     return 1;                   # All the same
3551 }
3552
3553 sub quotify {
3554     my %processors = (
3555         perl    => sub { my $x = shift;
3556                          $x =~ s/([\\\$\@"])/\\$1/g;
3557                          return '"'.$x.'"'; },
3558         maybeshell => sub { my $x = shift;
3559                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3560                             if ($x ne $y || $x =~ m|\s|) {
3561                                 return '"'.$y.'"';
3562                             } else {
3563                                 return $x;
3564                             }
3565                         },
3566         );
3567     my $for = shift;
3568     my $processor =
3569         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3570
3571     return map { $processor->($_); } @_;
3572 }
3573
3574 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3575 # $filename is a file name to read from
3576 # $line_concat_cond_re is a regexp detecting a line continuation ending
3577 # $line_concat is a CODEref that takes care of concatenating two lines
3578 sub collect_from_file {
3579     my $filename = shift;
3580     my $line_concat_cond_re = shift;
3581     my $line_concat = shift;
3582
3583     open my $fh, $filename || die "unable to read $filename: $!\n";
3584     return sub {
3585         my $saved_line = "";
3586         $_ = "";
3587         while (<$fh>) {
3588             s|\R$||;
3589             if (defined $line_concat) {
3590                 $_ = $line_concat->($saved_line, $_);
3591                 $saved_line = "";
3592             }
3593             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3594                 $saved_line = $_;
3595                 next;
3596             }
3597             return $_;
3598         }
3599         die "$filename ending with continuation line\n" if $_;
3600         close $fh;
3601         return undef;
3602     }
3603 }
3604
3605 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3606 # $array is an ARRAYref of lines
3607 # $line_concat_cond_re is a regexp detecting a line continuation ending
3608 # $line_concat is a CODEref that takes care of concatenating two lines
3609 sub collect_from_array {
3610     my $array = shift;
3611     my $line_concat_cond_re = shift;
3612     my $line_concat = shift;
3613     my @array = (@$array);
3614
3615     return sub {
3616         my $saved_line = "";
3617         $_ = "";
3618         while (defined($_ = shift @array)) {
3619             s|\R$||;
3620             if (defined $line_concat) {
3621                 $_ = $line_concat->($saved_line, $_);
3622                 $saved_line = "";
3623             }
3624             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3625                 $saved_line = $_;
3626                 next;
3627             }
3628             return $_;
3629         }
3630         die "input text ending with continuation line\n" if $_;
3631         return undef;
3632     }
3633 }
3634
3635 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3636 # $lineiterator is a CODEref that delivers one line at a time.
3637 # All following arguments are regex/CODEref pairs, where the regexp detects a
3638 # line and the CODEref does something with the result of the regexp.
3639 sub collect_information {
3640     my $lineiterator = shift;
3641     my %collectors = @_;
3642
3643     while(defined($_ = $lineiterator->())) {
3644         s|\R$||;
3645         my $found = 0;
3646         if ($collectors{"BEFORE"}) {
3647             $collectors{"BEFORE"}->($_);
3648         }
3649         foreach my $re (keys %collectors) {
3650             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3651                 $collectors{$re}->($lineiterator);
3652                 $found = 1;
3653             };
3654         }
3655         if ($collectors{"OTHERWISE"}) {
3656             $collectors{"OTHERWISE"}->($lineiterator, $_)
3657                 unless $found || !defined $collectors{"OTHERWISE"};
3658         }
3659         if ($collectors{"AFTER"}) {
3660             $collectors{"AFTER"}->($_);
3661         }
3662     }
3663 }
3664
3665 # tokenize($line)
3666 # tokenize($line,$separator)
3667 # $line is a line of text to split up into tokens
3668 # $separator [optional] is a regular expression that separates the tokens,
3669 # the default being spaces.  Do not use quotes of any kind as separators,
3670 # that will give undefined results.
3671 # Returns a list of tokens.
3672 #
3673 # Tokens are divided by separator (spaces by default).  If the tokens include
3674 # the separators, they have to be quoted with single or double quotes.
3675 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3676 # with backslash.
3677 # Basically, the same quoting rules apply for " and ' as in any
3678 # Unix shell.
3679 sub tokenize {
3680     my $line = my $debug_line = shift;
3681     my $separator = shift // qr|\s+|;
3682     my @result = ();
3683
3684     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3685         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3686     }
3687
3688     while ($line =~ s|^${separator}||, $line ne "") {
3689         my $token = "";
3690     again:
3691         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3692         $token .= $1;
3693         $line = $2.$';
3694
3695         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3696             $token .= $1;
3697             $line = $';
3698             goto again;
3699         } elsif ($line =~ m/^'([^']*)'/) {
3700             $token .= $1;
3701             $line = $';
3702             goto again;
3703         }
3704         push @result, $token;
3705     }
3706
3707     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3708         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3709         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3710     }
3711     return @result;
3712 }